configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [https://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 AC_CHECK_TOOL(READELF, readelf, false)
  54
  55 # We need the C++ compiler only for testing.
  56 AC_PROG_CXX
  57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  59 AC_LANG_PUSH([C++])
  60 # Default, dynamic case.
  61 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  62                [libc_cv_cxx_link_ok=yes],
  63                [libc_cv_cxx_link_ok=no])
  64 # Static case.
  65 old_LDFLAGS="$LDFLAGS"
  66 LDFLAGS="$LDFLAGS -static"
  67 AC_LINK_IFELSE([AC_LANG_SOURCE([
  68 #include <iostream>
  69
  70 int
  71 main()
  72 {
  73   std::cout << "Hello, world!";
  74   return 0;
  75 }
  76 ])],
  77                [],
  78                [libc_cv_cxx_link_ok=no])
  79 LDFLAGS="$old_LDFLAGS"
  80 AC_LANG_POP([C++])])
  81 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  82
  83 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  84   AC_MSG_ERROR([you must configure in a separate build directory])
  85 fi
  86
  87 # This will get text that should go into config.make.
  88 config_vars=
  89
  90 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  91 AC_ARG_WITH([gd],
  92             AC_HELP_STRING([--with-gd=DIR],
  93                            [find libgd include dir and library with prefix DIR]),
  94             [dnl
  95 case "$with_gd" in
  96 yes|''|no) ;;
  97 *) libgd_include="-I$withval/include"
  98    libgd_ldflags="-L$withval/lib" ;;
  99 esac
 100 ])
 101 AC_ARG_WITH([gd-include],
 102             AC_HELP_STRING([--with-gd-include=DIR],
 103                            [find libgd include files in DIR]),
 104             [dnl
 105 case "$with_gd_include" in
 106 ''|no) ;;
 107 *) libgd_include="-I$withval" ;;
 108 esac
 109 ])
 110 AC_ARG_WITH([gd-lib],
 111             AC_HELP_STRING([--with-gd-lib=DIR],
 112                            [find libgd library files in DIR]),
 113             [dnl
 114 case "$with_gd_lib" in
 115 ''|no) ;;
 116 *) libgd_ldflags="-L$withval" ;;
 117 esac
 118 ])
 119
 120 if test -n "$libgd_include"; then
 121   config_vars="$config_vars
 122 CFLAGS-memusagestat.c = $libgd_include"
 123 fi
 124 if test -n "$libgd_ldflags"; then
 125   config_vars="$config_vars
 126 libgd-LDFLAGS = $libgd_ldflags"
 127 fi
 128
 129 dnl Arguments to specify presence of other packages/features.
 130 AC_ARG_WITH([fp],
 131             AC_HELP_STRING([--with-fp],
 132                            [if using floating-point hardware @<:@default=yes@:>@]),
 133             [with_fp=$withval],
 134             [with_fp=yes])
 135 AC_SUBST(with_fp)
 136 AC_ARG_WITH([binutils],
 137             AC_HELP_STRING([--with-binutils=PATH],
 138                            [specify location of binutils (as and ld)]),
 139             [path_binutils=$withval],
 140             [path_binutils=''])
 141 AC_ARG_WITH([selinux],
 142             AC_HELP_STRING([--with-selinux],
 143                            [if building with SELinux support]),
 144             [with_selinux=$withval],
 145             [with_selinux=auto])
 146
 147 AC_ARG_WITH([headers],
 148             AC_HELP_STRING([--with-headers=PATH],
 149                            [location of system headers to use
 150                             (for example /usr/src/linux/include)
 151                             @<:@default=compiler default@:>@]),
 152             [sysheaders=$withval],
 153             [sysheaders=''])
 154 AC_SUBST(sysheaders)
 155
 156 AC_SUBST(use_default_link)
 157 AC_ARG_WITH([default-link],
 158             AC_HELP_STRING([--with-default-link],
 159                            [do not use explicit linker scripts]),
 160             [use_default_link=$withval],
 161             [use_default_link=default])
 162
 163 AC_ARG_ENABLE([sanity-checks],
 164               AC_HELP_STRING([--disable-sanity-checks],
 165                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 166               [enable_sanity=$enableval],
 167               [enable_sanity=yes])
 168
 169 AC_ARG_ENABLE([shared],
 170               AC_HELP_STRING([--enable-shared],
 171                              [build shared library @<:@default=yes if GNU ld@:>@]),
 172               [shared=$enableval],
 173               [shared=yes])
 174 AC_ARG_ENABLE([profile],
 175               AC_HELP_STRING([--enable-profile],
 176                              [build profiled library @<:@default=no@:>@]),
 177               [profile=$enableval],
 178               [profile=no])
 179 AC_ARG_ENABLE([timezone-tools],
 180               AC_HELP_STRING([--disable-timezone-tools],
 181                              [do not install timezone tools @<:@default=install@:>@]),
 182               [enable_timezone_tools=$enableval],
 183               [enable_timezone_tools=yes])
 184 AC_SUBST(enable_timezone_tools)
 185
 186 AC_ARG_ENABLE([hardcoded-path-in-tests],
 187               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 188                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 189               [hardcoded_path_in_tests=$enableval],
 190               [hardcoded_path_in_tests=no])
 191 AC_SUBST(hardcoded_path_in_tests)
 192
 193 AC_ARG_ENABLE([stackguard-randomization],
 194               AC_HELP_STRING([--enable-stackguard-randomization],
 195                              [initialize __stack_chk_guard canary with a random number at program start]),
 196               [enable_stackguard_randomize=$enableval],
 197               [enable_stackguard_randomize=no])
 198 if test "$enable_stackguard_randomize" = yes; then
 199   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 200 fi
 201
 202 AC_ARG_ENABLE([lock-elision],
 203               AC_HELP_STRING([--enable-lock-elision[=yes/no]],
 204                              [Enable lock elision for pthread mutexes by default]),
 205               [enable_lock_elision=$enableval],
 206               [enable_lock_elision=no])
 207 AC_SUBST(enable_lock_elision)
 208 if test "$enable_lock_elision" = yes ; then
 209   AC_DEFINE(ENABLE_LOCK_ELISION)
 210 fi
 211
 212 AC_ARG_ENABLE([hidden-plt],
 213               AC_HELP_STRING([--disable-hidden-plt],
 214                              [do not hide internal function calls to avoid PLT]),
 215               [hidden=$enableval],
 216               [hidden=yes])
 217 if test "x$hidden" = xno; then
 218   AC_DEFINE(NO_HIDDEN)
 219 fi
 220
 221 AC_ARG_ENABLE([bind-now],
 222               AC_HELP_STRING([--enable-bind-now],
 223                              [disable lazy relocations in DSOs]),
 224               [bindnow=$enableval],
 225               [bindnow=no])
 226 AC_SUBST(bindnow)
 227 if test "x$bindnow" = xyes; then
 228   AC_DEFINE(BIND_NOW)
 229 fi
 230
 231 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
 232 dnl -fstack-protector-strong.
 233 AC_ARG_ENABLE([stack-protector],
 234               AC_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
 235                              [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
 236               [enable_stack_protector=$enableval],
 237               [enable_stack_protector=no])
 238 case "$enable_stack_protector" in
 239 all|yes|no|strong) ;;
 240 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
 241 esac
 242
 243 dnl On some platforms we cannot use dynamic loading.  We must provide
 244 dnl static NSS modules.
 245 AC_ARG_ENABLE([static-nss],
 246               AC_HELP_STRING([--enable-static-nss],
 247                              [build static NSS modules @<:@default=no@:>@]),
 248               [static_nss=$enableval],
 249               [static_nss=no])
 250 dnl Enable static NSS also if we build no shared objects.
 251 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 252   static_nss=yes
 253   AC_DEFINE(DO_STATIC_NSS)
 254 fi
 255
 256 AC_ARG_ENABLE([force-install],
 257               AC_HELP_STRING([--disable-force-install],
 258                              [don't force installation of files from this package, even if they are older than the installed files]),
 259               [force_install=$enableval],
 260               [force_install=yes])
 261 AC_SUBST(force_install)
 262
 263 AC_ARG_ENABLE([maintainer-mode],
 264               AC_HELP_STRING([--enable-maintainer-mode],
 265                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 266               [maintainer=$enableval],
 267               [maintainer=no])
 268
 269 dnl On some platforms we allow dropping compatibility with all kernel
 270 dnl versions.
 271 AC_ARG_ENABLE([kernel],
 272               AC_HELP_STRING([--enable-kernel=VERSION],
 273                              [compile for compatibility with kernel not older than VERSION]),
 274               [minimum_kernel=$enableval],
 275               [])
 276 dnl Prevent unreasonable values.
 277 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 278   # Better nothing than this.
 279   minimum_kernel=""
 280 else
 281   if test "$minimum_kernel" = current; then
 282     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 283   fi
 284 fi
 285
 286 dnl For the development we sometimes want gcc to issue even more warnings.
 287 dnl This is not the default since many of the extra warnings are not
 288 dnl appropriate.
 289 AC_ARG_ENABLE([all-warnings],
 290               AC_HELP_STRING([--enable-all-warnings],
 291                              [enable all useful warnings gcc can issue]),
 292               [all_warnings=$enableval],
 293               [])
 294 AC_SUBST(all_warnings)
 295
 296 AC_ARG_ENABLE([werror],
 297               AC_HELP_STRING([--disable-werror],
 298                              [do not build with -Werror]),
 299               [enable_werror=$enableval],
 300               [enable_werror=yes])
 301 AC_SUBST(enable_werror)
 302
 303 AC_ARG_ENABLE([multi-arch],
 304               AC_HELP_STRING([--enable-multi-arch],
 305                              [enable single DSO with optimizations for multiple architectures]),
 306               [multi_arch=$enableval],
 307               [multi_arch=default])
 308
 309 AC_ARG_ENABLE([experimental-malloc],
 310               AC_HELP_STRING([--disable-experimental-malloc],
 311                              [disable experimental malloc features]),
 312               [experimental_malloc=$enableval],
 313               [experimental_malloc=yes])
 314 AC_SUBST(experimental_malloc)
 315
 316 AC_ARG_ENABLE([nss-crypt],
 317               AC_HELP_STRING([--enable-nss-crypt],
 318                              [enable libcrypt to use nss]),
 319               [nss_crypt=$enableval],
 320               [nss_crypt=no])
 321 if test x$nss_crypt = xyes; then
 322   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 323   if test $? -ne 0; then
 324     AC_MSG_ERROR([cannot find include directory with nss-config])
 325   fi
 326   nspr_includes=-I$(nspr-config --includedir 2>/dev/null)
 327   if test $? -ne 0; then
 328     AC_MSG_ERROR([cannot find include directory with nspr-config])
 329   fi
 330   old_CFLAGS="$CFLAGS"
 331   CFLAGS="$CFLAGS $nss_includes $nspr_includes"
 332   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 333 #include <hasht.h>
 334 #include <nsslowhash.h>
 335 void f (void) { NSSLOW_Init (); }])],
 336              libc_cv_nss_crypt=yes,
 337              AC_MSG_ERROR([
 338 cannot find NSS headers with lowlevel hash function interfaces]))
 339   old_LIBS="$LIBS"
 340   old_LDFLAGS="$LDFLAGS"
 341   LIBS="$LIBS -lfreebl3"
 342   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 343 #include <hasht.h>
 344 #include <nsslowhash.h>],
 345                                   [NSSLOW_Init();])],
 346                  libc_cv_nss_crypt=yes,
 347                  AC_MSG_ERROR([
 348 cannot link program using lowlevel NSS hash functions]))
 349   # Check to see if there is a static NSS cryptographic library.
 350   # If there isn't then we can't link anything with libcrypt.a,
 351   # and that might mean disabling some static tests.
 352   LDFLAGS="$LDFLAGS -static"
 353   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 354 #include <hasht.h>
 355 #include <nsslowhash.h>],
 356                                   [NSSLOW_Init();])],
 357                  libc_cv_static_nss_crypt=yes,
 358                  libc_cv_static_nss_crypt=no)
 359   LDFLAGS="$old_LDFLAGS"
 360   CFLAGS="$old_CFLAGS"
 361   LIBS="$old_LIBS"
 362 else
 363   libc_cv_nss_crypt=no
 364   libc_cv_static_nss_crypt=no
 365 fi
 366 AC_SUBST(libc_cv_nss_crypt)
 367 AC_SUBST(libc_cv_static_nss_crypt)
 368
 369
 370 AC_ARG_ENABLE([obsolete-rpc],
 371               AC_HELP_STRING([--enable-obsolete-rpc],
 372                              [build and install the obsolete RPC code for link-time usage]),
 373               [link_obsolete_rpc=$enableval],
 374               [link_obsolete_rpc=no])
 375 AC_SUBST(link_obsolete_rpc)
 376
 377 if test "$link_obsolete_rpc" = yes; then
 378   AC_DEFINE(LINK_OBSOLETE_RPC)
 379 fi
 380
 381 AC_ARG_ENABLE([obsolete-nsl],
 382               AC_HELP_STRING([--enable-obsolete-nsl],
 383                              [build and install the obsolete libnsl library and depending NSS modules]),
 384               [build_obsolete_nsl=$enableval],
 385               [build_obsolete_nsl=no])
 386 AC_SUBST(build_obsolete_nsl)
 387
 388 if test "$build_obsolete_nsl" = yes; then
 389   AC_DEFINE(LINK_OBSOLETE_NSL)
 390 fi
 391
 392 AC_ARG_ENABLE([systemtap],
 393               [AS_HELP_STRING([--enable-systemtap],
 394                [enable systemtap static probe points @<:@default=no@:>@])],
 395               [systemtap=$enableval],
 396               [systemtap=no])
 397 if test "x$systemtap" != xno; then
 398   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 399   old_CFLAGS="$CFLAGS"
 400   CFLAGS="-std=gnu11 $CFLAGS"
 401   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 402 void foo (int i, void *p)
 403 {
 404   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 405        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 406 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 407   CFLAGS="$old_CFLAGS"])
 408   if test $libc_cv_sdt = yes; then
 409     AC_DEFINE([USE_STAP_PROBE])
 410   elif test "x$systemtap" != xauto; then
 411     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 412   fi
 413 fi
 414
 415 AC_ARG_ENABLE([build-nscd],
 416               [AS_HELP_STRING([--disable-build-nscd],
 417                [disable building and installing the nscd daemon])],
 418               [build_nscd=$enableval],
 419               [build_nscd=default])
 420 AC_SUBST(build_nscd)
 421
 422 # Note the use of $use_nscd is near the bottom of the file.
 423 AC_ARG_ENABLE([nscd],
 424               [AS_HELP_STRING([--disable-nscd],
 425                [library functions will not contact the nscd daemon])],
 426               [use_nscd=$enableval],
 427               [use_nscd=yes])
 428
 429 AC_ARG_ENABLE([pt_chown],
 430               [AS_HELP_STRING([--enable-pt_chown],
 431                [Enable building and installing pt_chown])],
 432               [build_pt_chown=$enableval],
 433               [build_pt_chown=no])
 434 AC_SUBST(build_pt_chown)
 435 if test "$build_pt_chown" = yes; then
 436   AC_DEFINE(HAVE_PT_CHOWN)
 437 fi
 438
 439 AC_ARG_ENABLE([tunables],
 440               [AS_HELP_STRING([--enable-tunables],
 441                [Enable tunables support. Known values are 'yes', 'no' and 'valstring'])],
 442               [have_tunables=$enableval],
 443               [have_tunables=yes])
 444 AC_SUBST(have_tunables)
 445 if test "$have_tunables" = yes; then
 446   AC_DEFINE(HAVE_TUNABLES)
 447 fi
 448
 449 # The abi-tags file uses a fairly simplistic model for name recognition that
 450 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 451 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 452 # This doesn't get used much beyond that, so it's fairly safe.
 453 case "$host_os" in
 454 linux*)
 455   ;;
 456 gnu*)
 457   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 458   ;;
 459 esac
 460
 461 AC_ARG_ENABLE([mathvec],
 462               [AS_HELP_STRING([--enable-mathvec],
 463               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 464               [build_mathvec=$enableval],
 465               [build_mathvec=notset])
 466
 467 # We keep the original values in `$config_*' and never modify them, so we
 468 # can write them unchanged into config.make.  Everything else uses
 469 # $machine, $vendor, and $os, and changes them whenever convenient.
 470 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 471
 472 # Don't allow vendor == "unknown"
 473 test "$config_vendor" = unknown && config_vendor=
 474 config_os="`echo $config_os | sed 's/^unknown-//'`"
 475
 476 # Some configurations imply other options.
 477 elf=yes
 478
 479 # The configure fragment of a port can modify these to supplement
 480 # or override the table in the case statement below.  No fragment should
 481 # ever change the config_* variables, however.
 482 machine=$config_machine
 483 vendor=$config_vendor
 484 os=$config_os
 485 base_os=''
 486
 487 submachine=
 488 AC_ARG_WITH([cpu],
 489             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 490             [dnl
 491   case "$withval" in
 492   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 493   no) ;;
 494   *) submachine="$withval" ;;
 495   esac
 496 ])
 497
 498 # An preconfigure script can set this when it wants to disable the sanity
 499 # check below.
 500 libc_config_ok=no
 501
 502 dnl Let sysdeps/*/preconfigure act here.
 503 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 504
 505
 506 ###
 507 ### By using the undocumented --enable-hacker-mode option for configure
 508 ### one can skip this test to make the configuration not fail for unsupported
 509 ### platforms.
 510 ###
 511 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 512   case "$machine-$host_os" in
 513   *-linux* | *-gnu*)
 514     ;;
 515   *)
 516     AC_MSG_ERROR([
 517 *** The GNU C library is currently unavailable for this platform.
 518 *** If you are interested in seeing glibc on this platform visit
 519 *** the "How to submit a new port" in the wiki:
 520 ***   https://sourceware.org/glibc/wiki/#Development
 521 *** and join the community!])
 522     ;;
 523   esac
 524 fi
 525
 526 # Set base_machine if not set by a preconfigure fragment.
 527 test -n "$base_machine" || base_machine=$machine
 528 AC_SUBST(base_machine)
 529
 530 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
 531 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
 532                    [libc_cv_ssp=yes],
 533                    [libc_cv_ssp=no])
 534 ])
 535
 536 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
 537 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
 538                    [libc_cv_ssp_strong=yes],
 539                    [libc_cv_ssp_strong=no])
 540 ])
 541
 542 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
 543 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
 544                    [libc_cv_ssp_all=yes],
 545                    [libc_cv_ssp_all=no])
 546 ])
 547
 548 stack_protector=
 549 no_stack_protector=
 550 if test "$libc_cv_ssp" = yes; then
 551   no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
 552   AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
 553 fi
 554
 555 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
 556   stack_protector="-fstack-protector"
 557   AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
 558 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
 559   stack_protector="-fstack-protector-all"
 560   AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
 561 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
 562   stack_protector="-fstack-protector-strong"
 563   AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
 564 else
 565   stack_protector="-fno-stack-protector"
 566   AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
 567 fi
 568 AC_SUBST(libc_cv_ssp)
 569 AC_SUBST(stack_protector)
 570 AC_SUBST(no_stack_protector)
 571
 572 if test -n "$stack_protector"; then
 573   dnl Don't run configure tests with stack-protection on, to avoid problems with
 574   dnl bootstrapping.
 575   no_ssp=-fno-stack-protector
 576 else
 577   no_ssp=
 578
 579   if test "$enable_stack_protector" != no; then
 580     AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
 581   fi
 582 fi
 583
 584 # For the multi-arch option we need support in the assembler & linker.
 585 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 586                libc_cv_ld_gnu_indirect_function, [dnl
 587 cat > conftest.S <<EOF
 588 .type foo,%gnu_indirect_function
 589 foo:
 590 .globl _start
 591 _start:
 592 .globl __start
 593 __start:
 594 .data
 595 #ifdef _LP64
 596 .quad foo
 597 #else
 598 .long foo
 599 #endif
 600 EOF
 601 libc_cv_ld_gnu_indirect_function=no
 602 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 603             -nostartfiles -nostdlib $no_ssp \
 604             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 605   # Do a link to see if the backend supports IFUNC relocs.
 606   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 607   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 608     libc_cv_ld_gnu_indirect_function=yes
 609   }
 610 fi
 611 rm -f conftest*])
 612
 613 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
 614 AC_CACHE_CHECK([for gcc attribute ifunc support],
 615                libc_cv_gcc_indirect_function, [dnl
 616 cat > conftest.c <<EOF
 617 extern int func (int);
 618 int used_func (int a)
 619 {
 620   return a;
 621 }
 622 static void *resolver ()
 623 {
 624   return &used_func;
 625 }
 626 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
 627 EOF
 628 libc_cv_gcc_indirect_function=no
 629 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
 630    2>&AS_MESSAGE_LOG_FD ; then
 631   if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
 632     libc_cv_gcc_indirect_function=yes
 633   fi
 634 fi
 635 rm -f conftest*])
 636
 637 # Check if gcc warns about alias for function with incompatible types.
 638 AC_CACHE_CHECK([if compiler warns about alias for function with incompatible types],
 639                libc_cv_gcc_incompatible_alias, [dnl
 640 cat > conftest.c <<EOF
 641 int __redirect_foo (const void *s, int c);
 642
 643 __typeof (__redirect_foo) *foo_impl (void) __asm__ ("foo");
 644 __typeof (__redirect_foo) *foo_impl (void)
 645 {
 646   return 0;
 647 }
 648
 649 extern __typeof (__redirect_foo) foo_alias __attribute__ ((alias ("foo")));
 650 EOF
 651 libc_cv_gcc_incompatible_alias=yes
 652 if ${CC-cc} -Werror -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 653   libc_cv_gcc_incompatible_alias=no
 654 fi
 655 rm -f conftest*])
 656
 657 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 658   if test x"$multi_arch" = xyes; then
 659     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 660   else
 661     multi_arch=no
 662   fi
 663 fi
 664 if test x"$libc_cv_gcc_indirect_function" != xyes; then
 665   # GCC 8+ emits a warning for alias with incompatible types and it might
 666   # fail to build ifunc resolvers aliases to either weak or internal
 667   # symbols.  Disables multiarch build in this case.
 668   if test x"$libc_cv_gcc_incompatible_alias" == xyes; then
 669     AC_MSG_WARN([gcc emits a warning for alias between functions of incompatible types])
 670     if test x"$multi_arch" = xyes; then
 671       AC_MSG_ERROR([--enable-multi-arch support requires a gcc with gnu-indirect-function support])
 672     fi
 673     AC_MSG_WARN([Multi-arch is disabled.])
 674     multi_arch=no
 675   elif test x"$multi_arch" = xyes; then
 676     AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
 677 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
 678   fi
 679 fi
 680 multi_arch_d=
 681 if test x"$multi_arch" != xno; then
 682   multi_arch_d=/multiarch
 683 fi
 684
 685 # Compute the list of sysdep directories for this configuration.
 686 # This can take a while to compute.
 687 sysdep_dir=$srcdir/sysdeps
 688 AC_MSG_CHECKING(sysdep dirs)
 689 dnl We need to use [ and ] for other purposes for a while now.
 690 changequote(,)dnl
 691 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 692 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 693
 694 test "x$base_os" != x || case "$os" in
 695 gnu*)
 696   base_os=mach/hurd ;;
 697 linux*)
 698   base_os=unix/sysv ;;
 699 esac
 700
 701 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 702 tail=$os
 703 ostry=$os
 704 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 705   ostry="$ostry /$o"
 706   tail=$o
 707 done
 708 o=`echo $tail | sed 's/[0-9]*$//'`
 709 if test $o != $tail; then
 710   ostry="$ostry /$o"
 711 fi
 712 # For linux-gnu, try linux-gnu, then linux.
 713 o=`echo $tail | sed 's/-.*$//'`
 714 if test $o != $tail; then
 715   ostry="$ostry /$o"
 716 fi
 717
 718 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 719 base=
 720 tail=$base_os
 721 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 722   set $b
 723   base="$base /$1"
 724   tail="$2"
 725 done
 726
 727 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 728 mach=
 729 tail=$machine${submachine:+/$submachine}
 730 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 731   set $m
 732   # Prepend the machine's FPU directory unless --without-fp.
 733   if test "$with_fp" = yes; then
 734     maybe_fpu=/fpu
 735   else
 736     maybe_fpu=/nofpu
 737   fi
 738   # For each machine term, try it with and then without /multiarch.
 739   for try_fpu in $maybe_fpu ''; do
 740     for try_multi in $multi_arch_d ''; do
 741       mach="$mach /$1$try_fpu$try_multi"
 742     done
 743   done
 744   tail="$2"
 745 done
 746
 747 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 748 changequote([,])dnl
 749
 750 # Find what sysdep directories exist.
 751 sysnames=
 752 for b in $base ''; do
 753   for m0 in $mach ''; do
 754     for v in /$vendor ''; do
 755       test "$v" = / && continue
 756       for o in /$ostry ''; do
 757         test "$o" = / && continue
 758         for m in $mach ''; do
 759           try_suffix="$m0$b$v$o$m"
 760           if test -n "$try_suffix"; then
 761             try_srcdir="${srcdir}/"
 762             try="sysdeps$try_suffix"
 763             test -n "$enable_debug_configure" &&
 764             echo "$0 [DEBUG]: try $try" >&2
 765             if test -d "$try_srcdir$try"; then
 766               sysnames="$sysnames $try"
 767               { test -n "$o" || test -n "$b"; } && os_used=t
 768               { test -n "$m" || test -n "$m0"; } && machine_used=t
 769               case x${m0:-$m} in
 770               x*/$submachine) submachine_used=t ;;
 771               esac
 772             fi
 773           fi
 774         done
 775       done
 776     done
 777   done
 778 done
 779
 780 # If the assembler supports gnu_indirect_function symbol type and the
 781 # architecture supports multi-arch, we enable multi-arch by default.
 782 case $sysnames in
 783 *"$multi_arch_d"*)
 784   ;;
 785 *)
 786   test x"$multi_arch" = xdefault && multi_arch=no
 787   ;;
 788 esac
 789 if test x"$multi_arch" != xno; then
 790   AC_DEFINE(USE_MULTIARCH)
 791 fi
 792 AC_SUBST(multi_arch)
 793
 794 if test -z "$os_used" && test "$os" != none; then
 795   AC_MSG_ERROR(Operating system $os is not supported.)
 796 fi
 797 if test -z "$machine_used" && test "$machine" != none; then
 798   AC_MSG_ERROR(The $machine is not supported.)
 799 fi
 800 if test -z "$submachine_used" && test -n "$submachine"; then
 801   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 802 fi
 803 AC_SUBST(submachine)
 804
 805 # We have now validated the configuration.
 806
 807 # Expand the list of system names into a full list of directories
 808 # from each element's parent name and Implies file (if present).
 809 set $sysnames
 810 names=
 811 while test $# -gt 0; do
 812   name=$1
 813   shift
 814
 815   case " $names " in *" $name "*)
 816     # Already in the list.
 817     continue
 818   esac
 819
 820   # Report each name as we discover it, so there is no long pause in output.
 821   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 822
 823   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 824
 825   case $name in
 826     /*) xsrcdir= ;;
 827     *)  xsrcdir=$srcdir/ ;;
 828   esac
 829   test -n "$enable_debug_configure" &&
 830   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 831
 832   for implies_file in Implies Implies-before Implies-after; do
 833     implies_type=`echo $implies_file | sed s/-/_/`
 834     eval ${implies_type}=
 835     if test -f $xsrcdir$name/$implies_file; then
 836       # Collect more names from the `Implies' file (removing comments).
 837       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 838       for x in $implied_candidate; do
 839         found=no
 840         if test -d $xsrcdir$name_base/$x; then
 841           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 842           found=yes
 843         fi
 844         try="sysdeps/$x"
 845         try_srcdir=$srcdir/
 846         test -n "$enable_debug_configure" &&
 847          echo "[DEBUG]: $name $implies_file $x try() {$try_srcdir}$try" >&2
 848         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 849         then
 850           eval "${implies_type}=\"\$${implies_type} \$try\""
 851           found=yes
 852         fi
 853         if test $found = no; then
 854           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 855         fi
 856       done
 857     fi
 858   done
 859
 860   # Add NAME to the list of names.
 861   names="$names $name"
 862
 863   # Find the parent of NAME, using the empty string if it has none.
 864 changequote(,)dnl
 865   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 866 changequote([,])dnl
 867
 868   test -n "$enable_debug_configure" &&
 869     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 870 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 871
 872   # Add the names implied by NAME, and NAME's parent (if it has one), to
 873   # the list of names to be processed (the argument list).  We prepend the
 874   # implied names to the list and append the parent.  We want implied
 875   # directories to come before further directories inferred from the
 876   # configuration components; this ensures that for sysv4, unix/common
 877   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 878   # after sysv4).
 879   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 880   test -n "$sysnames" && set $sysnames
 881 done
 882
 883 # Add the default directories.
 884 default_sysnames="sysdeps/generic"
 885 sysnames="$names $default_sysnames"
 886 AC_SUBST(sysnames)
 887 # The other names were emitted during the scan.
 888 AC_MSG_RESULT($default_sysnames)
 889
 890
 891 ### Locate tools.
 892
 893 AC_PROG_INSTALL
 894 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 895   # The makefiles need to use a different form to find it in $srcdir.
 896   INSTALL='\$(..)./scripts/install-sh -c'
 897 fi
 898 AC_PROG_LN_S
 899
 900 LIBC_PROG_BINUTILS
 901
 902 # Accept binutils 2.25 or newer.
 903 AC_CHECK_PROG_VER(AS, $AS, --version,
 904                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 905                   [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 906                   AS=: critic_missing="$critic_missing as")
 907
 908 if test -n "`$LD --version | sed -n 's/^GNU \(gold\).*$/\1/p'`"; then
 909   # Accept gold 1.14 or higher
 910   AC_CHECK_PROG_VER(LD, $LD, --version,
 911                     [GNU gold.* \([0-9][0-9]*\.[0-9.]*\)],
 912                     [1.1[4-9]*|1.[2-9][0-9]*|1.1[0-9][0-9]*|[2-9].*|[1-9][0-9]*],
 913                     LD=: critic_missing="$critic_missing GNU gold")
 914 else
 915   AC_CHECK_PROG_VER(LD, $LD, --version,
 916                     [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 917                     [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 918                     LD=: critic_missing="$critic_missing GNU ld")
 919 fi
 920
 921 # These programs are version sensitive.
 922 AC_CHECK_TOOL_PREFIX
 923 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 924   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 925   [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
 926
 927 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 928   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 929   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 930   MSGFMT=: aux_missing="$aux_missing msgfmt")
 931 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 932   [GNU texinfo.* \([0-9][0-9.]*\)],
 933   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
 934   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 935 AC_CHECK_PROG_VER(SED, sed, --version,
 936   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
 937   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 938   SED=: aux_missing="$aux_missing sed")
 939 AC_CHECK_PROG_VER(AWK, gawk, --version,
 940   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
 941   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
 942 AC_CHECK_PROG_VER(BISON, bison, --version,
 943   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
 944   [2.7*|[3-9].*|[1-9][0-9]*], critic_missing="$critic_missing bison")
 945
 946 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
 947 AC_TRY_COMPILE([], [
 948 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 9)
 949 #error insufficient compiler
 950 #endif],
 951                [libc_cv_compiler_ok=yes],
 952                [libc_cv_compiler_ok=no])])
 953 AS_IF([test $libc_cv_compiler_ok != yes],
 954       [critic_missing="$critic_missing compiler"])
 955
 956 AC_CHECK_TOOL(NM, nm, false)
 957
 958 if test "x$maintainer" = "xyes"; then
 959   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 960   case "x$AUTOCONF" in
 961   xno|x|x:) AUTOCONF=no ;;
 962   *)
 963     AC_CACHE_CHECK(dnl
 964   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 965     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
 966       libc_cv_autoconf_works=yes
 967     else
 968       libc_cv_autoconf_works=no
 969     fi])
 970     test $libc_cv_autoconf_works = yes || AUTOCONF=no
 971     ;;
 972   esac
 973   if test "x$AUTOCONF" = xno; then
 974     aux_missing="$aux_missing autoconf"
 975   fi
 976 else
 977   AUTOCONF=no
 978 fi
 979
 980 # Check for python3 if available, or else python.
 981 AC_CHECK_PROGS(PYTHON_PROG, python3 python,no)
 982 case "x$PYTHON_PROG" in
 983 xno|x|x:) PYTHON_PROG=no ;;
 984 *) ;;
 985 esac
 986
 987 if test "x$PYTHON_PROG" = xno; then
 988   aux_missing="$aux_missing python"
 989 else
 990   PYTHON="$PYTHON_PROG -B"
 991   AC_SUBST(PYTHON)
 992 fi
 993
 994 test -n "$critic_missing" && AC_MSG_ERROR([
 995 *** These critical programs are missing or too old:$critic_missing
 996 *** Check the INSTALL file for required versions.])
 997
 998 test -n "$aux_missing" && AC_MSG_WARN([
 999 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1000 *** some features or tests will be disabled.
1001 *** Check the INSTALL file for required versions.])
1002
1003 # if using special system headers, find out the compiler's sekrit
1004 # header directory and add that to the list.  NOTE: Only does the right
1005 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1006 if test -n "$sysheaders"; then
1007   SYSINCLUDES=-nostdinc
1008   for d in include include-fixed; do
1009     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1010     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1011   done
1012   SYSINCLUDES="$SYSINCLUDES \
1013 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1014   if test -n "$CXX"; then
1015     CXX_SYSINCLUDES=
1016     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1017     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1018       test "x$cxxheaders" != x &&
1019       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1020     done
1021   fi
1022 fi
1023 AC_SUBST(SYSINCLUDES)
1024 AC_SUBST(CXX_SYSINCLUDES)
1025
1026 # Obtain some C++ header file paths.  This is used to make a local
1027 # copy of those headers in Makerules.
1028 if test -n "$CXX"; then
1029   find_cxx_header () {
1030     echo "#include <$1>" | $CXX -M -MP -x c++ - 2>/dev/null \
1031          | sed -n "\,$1:,{s/:\$//;p}"
1032   }
1033   CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1034   CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1035   CXX_BITS_STD_ABS_H="$(find_cxx_header bits/std_abs.h)"
1036 fi
1037 AC_SUBST(CXX_CSTDLIB_HEADER)
1038 AC_SUBST(CXX_CMATH_HEADER)
1039 AC_SUBST(CXX_BITS_STD_ABS_H)
1040
1041 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1042 # since this would lead to problems installing/building glibc.
1043 # LD_LIBRARY_PATH contains the current directory if one of the following
1044 # is true:
1045 # - one of the terminals (":" and ";") is the first or last sign
1046 # - two terminals occur directly after each other
1047 # - the path contains an element with a dot in it
1048 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1049 changequote(,)dnl
1050 case ${LD_LIBRARY_PATH} in
1051   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1052     ld_library_path_setting="contains current directory"
1053     ;;
1054   *)
1055     ld_library_path_setting="ok"
1056     ;;
1057 esac
1058 changequote([,])dnl
1059 AC_MSG_RESULT($ld_library_path_setting)
1060 if test "$ld_library_path_setting" != "ok"; then
1061 AC_MSG_ERROR([
1062 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1063 *** building glibc. Please change the environment variable
1064 *** and run configure again.])
1065 fi
1066
1067 AC_PATH_PROG(BASH_SHELL, bash, no)
1068
1069 AC_PATH_PROG(PERL, perl, no)
1070 if test "$PERL" != no &&
1071    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1072   PERL=no
1073 fi
1074 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1075              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1076
1077 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1078 cat > conftest.s <<EOF
1079 .text
1080 foo:
1081 .set glibc_conftest_frobozz,foo
1082 .globl glibc_conftest_frobozz
1083 EOF
1084 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1085 # (but it doesn't work), so we must do a linking check to be sure.
1086 cat > conftest1.c <<\EOF
1087 extern int glibc_conftest_frobozz;
1088 void _start() { glibc_conftest_frobozz = 1; }
1089 EOF
1090 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1091             -nostartfiles -nostdlib $no_ssp \
1092             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1093   libc_cv_asm_set_directive=yes
1094 else
1095   libc_cv_asm_set_directive=no
1096 fi
1097 rm -f conftest*])
1098 if test $libc_cv_asm_set_directive = yes; then
1099   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1100 fi
1101
1102 AC_CACHE_CHECK(linker support for protected data symbol,
1103                libc_cv_protected_data,
1104                [cat > conftest.c <<EOF
1105                 int bar __attribute__ ((visibility ("protected"))) = 1;
1106 EOF
1107                 libc_cv_protected_data=no
1108                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1109                   cat > conftest.c <<EOF
1110                   extern int bar;
1111                   int main (void) { return bar; }
1112 EOF
1113                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1114                     libc_cv_protected_data=yes
1115                   fi
1116                 fi
1117                 rm -f conftest.*
1118                ])
1119 AC_SUBST(libc_cv_protected_data)
1120
1121 AC_CACHE_CHECK(linker support for INSERT in linker script,
1122                libc_cv_insert,
1123                [cat > conftest.c <<EOF
1124                 const int __attribute__ ((section(".bar"))) bar = 0x12345678;
1125                 int test (void) { return bar; }
1126 EOF
1127                 cat > conftest.t <<EOF
1128                 SECTIONS
1129                 {
1130                   .bar : { *(.bar) }
1131                 }
1132                 INSERT AFTER .rela.dyn;
1133 EOF
1134                 libc_cv_insert=no
1135                 if AC_TRY_COMMAND([${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -Wl,-T,conftest.t -o conftest.so]); then
1136                   libc_cv_insert=yes
1137                 fi
1138                 rm -f conftest.*
1139                ])
1140 AC_SUBST(libc_cv_insert)
1141
1142 AC_CACHE_CHECK(for broken __attribute__((alias())),
1143                libc_cv_broken_alias_attribute,
1144                [cat > conftest.c <<EOF
1145                extern int foo (int x) __asm ("xyzzy");
1146                int bar (int x) { return x; }
1147                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1148                extern int dfoo;
1149                extern __typeof (dfoo) dfoo __asm ("abccb");
1150                int dfoo = 1;
1151 EOF
1152                libc_cv_broken_alias_attribute=yes
1153                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1154                  if grep 'xyzzy' conftest.s >/dev/null &&
1155                     grep 'abccb' conftest.s >/dev/null; then
1156                    libc_cv_broken_alias_attribute=no
1157                  fi
1158                fi
1159                rm -f conftest.c conftest.s
1160                ])
1161 if test $libc_cv_broken_alias_attribute = yes; then
1162   AC_MSG_ERROR(working alias attribute support required)
1163 fi
1164
1165 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1166                libc_cv_have_sdata_section,
1167                [echo "int i;" > conftest.c
1168                 libc_cv_have_sdata_section=no
1169                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1170                    | grep '\.sdata' >/dev/null; then
1171                   libc_cv_have_sdata_section=yes
1172                 fi
1173                 rm -f conftest.c conftest.so
1174                ])
1175 if test $libc_cv_have_sdata_section = yes; then
1176   AC_DEFINE(HAVE_SDATA_SECTION)
1177 fi
1178
1179 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1180                libc_cv_ctors_header, [dnl
1181   libc_cv_ctors_header=yes
1182   LIBC_TRY_LINK_STATIC([
1183 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1184 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1185 ],
1186               [dnl
1187       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1188         { gsub(/\@<:@ */, "@<:@") }
1189         $2 == ".ctors" || $2 == ".dtors" {
1190           size = strtonum("0x" $6)
1191           align = strtonum("0x" $NF)
1192           seen@<:@$2@:>@ = 1
1193           stub@<:@$2@:>@ = size == align * 2
1194         }
1195         END {
1196           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1197           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1198           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1199         }
1200       '], [libc_cv_ctors_header=no])
1201     ], [dnl
1202       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1203     ])
1204 ])
1205 if test $libc_cv_ctors_header = no; then
1206   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1207 fi
1208
1209 AC_CACHE_CHECK(for libunwind-support in compiler,
1210                libc_cv_cc_with_libunwind, [
1211   cat > conftest.c <<EOF
1212 int main (void) { return 0; }
1213 EOF
1214   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1215      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1216     libc_cv_cc_with_libunwind=yes
1217   else
1218     libc_cv_cc_with_libunwind=no
1219   fi
1220   rm -f conftest*])
1221 AC_SUBST(libc_cv_cc_with_libunwind)
1222 if test $libc_cv_cc_with_libunwind = yes; then
1223   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1224 fi
1225
1226 ASFLAGS_config=
1227 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1228                libc_cv_as_noexecstack, [dnl
1229 cat > conftest.c <<EOF
1230 void foo (void) { }
1231 EOF
1232 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1233                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1234    && grep .note.GNU-stack conftest.s >/dev/null \
1235    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1236                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1237 then
1238   libc_cv_as_noexecstack=yes
1239 else
1240   libc_cv_as_noexecstack=no
1241 fi
1242 rm -f conftest*])
1243 if test $libc_cv_as_noexecstack = yes; then
1244   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1245 fi
1246 AC_SUBST(ASFLAGS_config)
1247
1248 AC_CACHE_CHECK(for -z combreloc,
1249                libc_cv_z_combreloc, [dnl
1250 cat > conftest.c <<EOF
1251 extern int bar (int);
1252 extern int mumble;
1253 int foo (void) { return bar (mumble); }
1254 EOF
1255 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1256                         -fPIC -shared $no_ssp -o conftest.so conftest.c
1257                         -nostdlib -nostartfiles
1258                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1259 then
1260 dnl The following test is a bit weak.  We must use a tool which can test
1261 dnl cross-platform since the gcc used can be a cross compiler.  Without
1262 dnl introducing new options this is not easily doable.  Instead use a tool
1263 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1264 dnl look for a section named .rel.dyn or .rela.dyn.
1265   if $READELF -S conftest.so | grep -E '.rela?.dyn' > /dev/null; then
1266     libc_cv_z_combreloc=yes
1267   else
1268     libc_cv_z_combreloc=no
1269   fi
1270 else
1271   libc_cv_z_combreloc=no
1272 fi
1273 rm -f conftest*])
1274 if test "$libc_cv_z_combreloc" = yes; then
1275   AC_DEFINE(HAVE_Z_COMBRELOC)
1276 fi
1277 AC_SUBST(libc_cv_z_combreloc)
1278
1279 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1280                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1281 AC_SUBST(libc_cv_z_execstack)
1282
1283 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1284 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1285 ])
1286
1287 AC_SUBST(libc_cv_fpie)
1288
1289 AC_CACHE_CHECK(for --hash-style option,
1290                libc_cv_hashstyle, [dnl
1291 cat > conftest.c <<EOF
1292 int _start (void) { return 42; }
1293 EOF
1294 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1295                             -fPIC -shared -o conftest.so conftest.c
1296                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1297 then
1298   libc_cv_hashstyle=yes
1299 else
1300   libc_cv_hashstyle=no
1301 fi
1302 rm -f conftest*])
1303 AC_SUBST(libc_cv_hashstyle)
1304
1305 # The linker's default -shared behavior is good enough if it
1306 # does these things that our custom linker scripts ensure that
1307 # all allocated NOTE sections come first.
1308 if test "$use_default_link" = default; then
1309   AC_CACHE_CHECK([for sufficient default -shared layout],
1310                   libc_cv_use_default_link, [dnl
1311   libc_cv_use_default_link=no
1312   cat > conftest.s <<\EOF
1313           .section .note.a,"a",%note
1314           .balign 4
1315           .long 4,4,9
1316           .string "GNU"
1317           .string "foo"
1318           .section .note.b,"a",%note
1319           .balign 4
1320           .long 4,4,9
1321           .string "GNU"
1322           .string "bar"
1323 EOF
1324   if AC_TRY_COMMAND([dnl
1325   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1326        ac_try=`$READELF -S conftest.so | sed -n \
1327          ['${x;p;}
1328           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1329           t a
1330           b
1331           : a
1332           H']`
1333   then
1334     libc_seen_a=no libc_seen_b=no
1335     set -- $ac_try
1336     while test $# -ge 2 -a "$1" = NOTE; do
1337       case "$2" in
1338       .note.a) libc_seen_a=yes ;;
1339       .note.b) libc_seen_b=yes ;;
1340       esac
1341       shift 2
1342     done
1343     case "$libc_seen_a$libc_seen_b" in
1344     yesyes)
1345       libc_cv_use_default_link=yes
1346       ;;
1347     *)
1348       echo >&AS_MESSAGE_LOG_FD "\
1349 $libc_seen_a$libc_seen_b from:
1350 $ac_try"
1351       ;;
1352     esac
1353   fi
1354   rm -f conftest*])
1355   use_default_link=$libc_cv_use_default_link
1356 fi
1357
1358 AC_CACHE_CHECK(for GLOB_DAT reloc,
1359                libc_cv_has_glob_dat, [dnl
1360 cat > conftest.c <<EOF
1361 extern int mumble;
1362 int foo (void) { return mumble; }
1363 EOF
1364 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1365                         -fPIC -shared -o conftest.so conftest.c
1366                         -nostdlib -nostartfiles $no_ssp
1367                         1>&AS_MESSAGE_LOG_FD])
1368 then
1369 dnl look for GLOB_DAT relocation.
1370   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1371     libc_cv_has_glob_dat=yes
1372   else
1373     libc_cv_has_glob_dat=no
1374   fi
1375 else
1376   libc_cv_has_glob_dat=no
1377 fi
1378 rm -f conftest*])
1379 AC_SUBST(libc_cv_has_glob_dat)
1380
1381 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1382 if libc_cv_output_format=`
1383 ${CC-cc} -nostartfiles -nostdlib $no_ssp -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1384 then
1385   :
1386 else
1387   libc_cv_output_format=
1388 fi
1389 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1390 AC_SUBST(libc_cv_output_format)
1391
1392 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1393 cat > conftest.c <<EOF
1394 int foo;
1395 EOF
1396 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1397                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1398 then
1399   libc_cv_fno_toplevel_reorder=yes
1400 else
1401   libc_cv_fno_toplevel_reorder=no
1402 fi
1403 rm -f conftest*])
1404 if test $libc_cv_fno_toplevel_reorder = yes; then
1405   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1406 else
1407   fno_unit_at_a_time=-fno-unit-at-a-time
1408 fi
1409 AC_SUBST(fno_unit_at_a_time)
1410
1411 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1412 [dnl
1413 cat > conftest.c <<EOF
1414 __thread int i;
1415 void foo (void)
1416 {
1417   i = 10;
1418 }
1419 EOF
1420 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1421                    conftest.c 1>&AS_MESSAGE_LOG_FD])
1422 then
1423   libc_cv_mtls_dialect_gnu2=yes
1424 else
1425   libc_cv_mtls_dialect_gnu2=no
1426 fi
1427 rm -f conftest*])
1428 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1429 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1430
1431 AC_CACHE_CHECK(whether cc puts quotes around section names,
1432                libc_cv_have_section_quotes,
1433                [cat > conftest.c <<EOF
1434                 static const int foo
1435                 __attribute__ ((section ("bar"))) = 1;
1436 EOF
1437                 if ${CC-cc} -S conftest.c -o conftest.s; then
1438                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1439                     libc_cv_have_section_quotes=yes
1440                   else
1441                     libc_cv_have_section_quotes=no
1442                   fi
1443                 else
1444                   libc_cv_have_section_quotes=unknown
1445                 fi
1446                 rm -f conftest.{c,s}
1447                 ])
1448 if test $libc_cv_have_section_quotes = yes; then
1449   AC_DEFINE(HAVE_SECTION_QUOTES)
1450 fi
1451
1452 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1453 cat > conftest.c <<\EOF
1454 void zero (void *x)
1455 {
1456   __builtin_memset (x, 0, 1000);
1457 }
1458 EOF
1459 dnl
1460 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "memset" > /dev/null]);
1461 then
1462   libc_cv_gcc_builtin_memset=no
1463 else
1464   libc_cv_gcc_builtin_memset=yes
1465 fi
1466 rm -f conftest* ])
1467 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1468   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1469 fi
1470
1471 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1472 cat > conftest.c <<\EOF
1473 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1474 char *foo (const char *a, const char *b)
1475 {
1476   return __builtin_strstr (a, b);
1477 }
1478 EOF
1479 dnl
1480 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "my_strstr" > /dev/null]);
1481 then
1482   libc_cv_gcc_builtin_redirection=yes
1483 else
1484   libc_cv_gcc_builtin_redirection=no
1485 fi
1486 rm -f conftest* ])
1487 if test "$libc_cv_gcc_builtin_redirection" = no; then
1488   AC_MSG_ERROR([support for the symbol redirection needed])
1489 fi
1490
1491 dnl Determine how to disable generation of FMA instructions.
1492 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1493                libc_cv_cc_nofma, [dnl
1494 libc_cv_cc_nofma=
1495 for opt in -ffp-contract=off -mno-fused-madd; do
1496   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1497 done])
1498 AC_SUBST(libc_cv_cc_nofma)
1499
1500 if test -n "$submachine"; then
1501   AC_CACHE_CHECK([for compiler option for CPU variant],
1502                  libc_cv_cc_submachine, [dnl
1503   libc_cv_cc_submachine=no
1504   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1505     LIBC_TRY_CC_OPTION([$opt], [
1506       libc_cv_cc_submachine="$opt"
1507       break], [])
1508   done])
1509   if test "x$libc_cv_cc_submachine" = xno; then
1510     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1511   fi
1512 fi
1513 AC_SUBST(libc_cv_cc_submachine)
1514
1515 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1516 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1517 cat > conftest.c <<EOF
1518 void
1519 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1520 foo (void) {}
1521 EOF
1522 libc_cv_cc_loop_to_function=no
1523 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1524 then
1525   libc_cv_cc_loop_to_function=yes
1526 fi
1527 rm -f conftest*])
1528 if test $libc_cv_cc_loop_to_function = yes; then
1529   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1530 fi
1531 AC_SUBST(libc_cv_cc_loop_to_function)
1532
1533 dnl Check whether we have the gd library available.
1534 AC_MSG_CHECKING(for libgd)
1535 if test "$with_gd" != "no"; then
1536   old_CFLAGS="$CFLAGS"
1537   CFLAGS="$CFLAGS $libgd_include"
1538   old_LDFLAGS="$LDFLAGS"
1539   LDFLAGS="$LDFLAGS $libgd_ldflags"
1540   old_LIBS="$LIBS"
1541   LIBS="$LIBS -lgd -lpng -lz -lm"
1542   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1543   CFLAGS="$old_CFLAGS"
1544   LDFLAGS="$old_LDFLAGS"
1545   LIBS="$old_LIBS"
1546 else
1547   LIBGD=no
1548 fi
1549 AC_MSG_RESULT($LIBGD)
1550 AC_SUBST(LIBGD)
1551
1552 # SELinux detection
1553 if test x$with_selinux = xno ; then
1554   have_selinux=no;
1555 else
1556   # See if we have the SELinux library
1557   AC_CHECK_LIB(selinux, is_selinux_enabled,
1558                have_selinux=yes, have_selinux=no)
1559   if test x$with_selinux = xyes ; then
1560     if test x$have_selinux = xno ; then
1561       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1562     fi
1563   fi
1564 fi
1565 # Check if we're building with SELinux support.
1566 if test "x$have_selinux" = xyes; then
1567   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1568
1569   # See if we have the libaudit library
1570   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1571                have_libaudit=yes, have_libaudit=no)
1572   if test "x$have_libaudit" = xyes; then
1573     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1574   fi
1575   AC_SUBST(have_libaudit)
1576
1577   # See if we have the libcap library
1578   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1579   if test "x$have_libcap" = xyes; then
1580     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1581   fi
1582   AC_SUBST(have_libcap)
1583 fi
1584 AC_SUBST(have_selinux)
1585
1586 CPPUNDEFS=
1587 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1588 dnl Since we are building the implementations of the fortified functions here,
1589 dnl having the macro defined interacts very badly.
1590 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1591 [AC_TRY_COMPILE([], [
1592 #ifdef _FORTIFY_SOURCE
1593 # error bogon
1594 #endif],
1595                 [libc_cv_predef_fortify_source=no],
1596                 [libc_cv_predef_fortify_source=yes])])
1597 if test $libc_cv_predef_fortify_source = yes; then
1598   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1599 fi
1600 AC_SUBST(CPPUNDEFS)
1601
1602 # Some linkers on some architectures support __ehdr_start but with
1603 # bugs.  Make sure usage of it does not create relocations in the
1604 # output (as the linker should resolve them all for us).
1605 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1606                libc_cv_ehdr_start, [
1607 old_CFLAGS="$CFLAGS"
1608 old_LDFLAGS="$LDFLAGS"
1609 old_LIBS="$LIBS"
1610 CFLAGS="$CFLAGS -fPIC"
1611 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared $no_ssp"
1612 LIBS=
1613 AC_LINK_IFELSE([AC_LANG_SOURCE([
1614 typedef struct {
1615   char foo;
1616   long val;
1617 } Ehdr;
1618 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1619 long ehdr (void) { return __ehdr_start.val; }
1620 ])],
1621                [if $READELF -r conftest | grep -F __ehdr_start >/dev/null; then
1622                   libc_cv_ehdr_start=broken
1623                 else
1624                   libc_cv_ehdr_start=yes
1625                 fi], [libc_cv_ehdr_start=no])
1626 CFLAGS="$old_CFLAGS"
1627 LDFLAGS="$old_LDFLAGS"
1628 LIBS="$old_LIBS"
1629 ])
1630 if test "$libc_cv_ehdr_start" = yes; then
1631   AC_DEFINE([HAVE_EHDR_START])
1632 elif test "$libc_cv_ehdr_start" = broken; then
1633   AC_MSG_WARN([linker is broken -- you should upgrade])
1634 fi
1635
1636 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1637                libc_cv_builtin_trap, [dnl
1638 libc_cv_builtin_trap=no
1639 AC_TRY_COMPILE([], [__builtin_trap ()], [
1640 libc_undefs=`$NM -u conftest.o |
1641   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1642     2>&AS_MESSAGE_LOG_FD` || {
1643   AC_MSG_ERROR([confusing output from $NM -u])
1644 }
1645 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1646 if test -z "$libc_undefs"; then
1647   libc_cv_builtin_trap=yes
1648 fi])])
1649 if test $libc_cv_builtin_trap = yes; then
1650   AC_DEFINE([HAVE_BUILTIN_TRAP])
1651 fi
1652
1653 dnl C++ feature tests.
1654 AC_LANG_PUSH([C++])
1655
1656 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1657                libc_cv_cxx_thread_local, [
1658 old_CXXFLAGS="$CXXFLAGS"
1659 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1660 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1661 #include <thread>
1662
1663 // Compiler support.
1664 struct S
1665 {
1666   S ();
1667   ~S ();
1668 };
1669 thread_local S s;
1670 S * get () { return &s; }
1671
1672 // libstdc++ support.
1673 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1674 #error __cxa_thread_atexit_impl not supported
1675 #endif
1676 ])],
1677                [libc_cv_cxx_thread_local=yes],
1678                [libc_cv_cxx_thread_local=no])
1679 CXXFLAGS="$old_CXXFLAGS"
1680 ])
1681 AC_SUBST(libc_cv_cxx_thread_local)
1682
1683 AC_LANG_POP([C++])
1684 dnl End of C++ feature tests.
1685
1686 ### End of automated tests.
1687 ### Now run sysdeps configure fragments.
1688
1689 # They also can set these variables.
1690 use_ldconfig=no
1691 ldd_rewrite_script=no
1692 libc_cv_sysconfdir=$sysconfdir
1693 libc_cv_localstatedir=$localstatedir
1694 libc_cv_gcc_unwind_find_fde=no
1695 libc_cv_idn=no
1696
1697 # Iterate over all the sysdep directories we will use, running their
1698 # configure fragments.
1699 for dir in $sysnames; do
1700   case $dir in
1701     /*) dest=$dir ;;
1702     *)  dest=$srcdir/$dir ;;
1703   esac
1704   if test -r $dest/configure; then
1705     AC_MSG_RESULT(running configure fragment for $dir)
1706     . $dest/configure
1707   fi
1708 done
1709
1710 if test x"$build_mathvec" = xnotset; then
1711   build_mathvec=no
1712 fi
1713 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1714
1715 AC_SUBST(libc_extra_cflags)
1716 AC_SUBST(libc_extra_cppflags)
1717
1718 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1719   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1720 fi
1721 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1722
1723 # A sysdeps configure fragment can reset this if IFUNC is not actually
1724 # usable even though the assembler knows how to generate the symbol type.
1725 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1726   AC_DEFINE(HAVE_IFUNC)
1727 fi
1728
1729 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1730   AC_DEFINE(HAVE_GCC_IFUNC)
1731 fi
1732
1733 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1734 # configure fragment can override the value to prevent this AC_DEFINE.
1735 AC_SUBST(use_nscd)
1736 if test "x$use_nscd" != xno; then
1737   AC_DEFINE([USE_NSCD])
1738 fi
1739 if test "x$build_nscd" = xdefault; then
1740   build_nscd=$use_nscd
1741 fi
1742
1743 AC_SUBST(libc_cv_slibdir)
1744 AC_SUBST(libc_cv_rtlddir)
1745 AC_SUBST(libc_cv_complocaledir)
1746 AC_SUBST(libc_cv_sysconfdir)
1747 AC_SUBST(libc_cv_localstatedir)
1748 AC_SUBST(libc_cv_rootsbindir)
1749
1750 if test x$use_ldconfig = xyes; then
1751   AC_DEFINE(USE_LDCONFIG)
1752 fi
1753 AC_SUBST(use_ldconfig)
1754 AC_SUBST(ldd_rewrite_script)
1755
1756 AC_SUBST(static)
1757 AC_SUBST(shared)
1758
1759 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1760 [libc_cv_pic_default=yes
1761 cat > conftest.c <<EOF
1762 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1763 # error PIC is default.
1764 #endif
1765 EOF
1766 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1767   libc_cv_pic_default=no
1768 fi
1769 rm -f conftest.*])
1770 AC_SUBST(libc_cv_pic_default)
1771
1772 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_pie_default,
1773 [libc_cv_pie_default=yes
1774 cat > conftest.c <<EOF
1775 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1776 # error PIE is default.
1777 #endif
1778 EOF
1779 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1780   libc_cv_pie_default=no
1781 fi
1782 rm -f conftest.*])
1783 AC_SUBST(libc_cv_pie_default)
1784
1785 # Set the `multidir' variable by grabbing the variable from the compiler.
1786 # We do it once and save the result in a generated makefile.
1787 libc_cv_multidir=`${CC-cc} $CFLAGS $CPPFLAGS -print-multi-directory`
1788 AC_SUBST(libc_cv_multidir)
1789
1790 AC_SUBST(profile)
1791 AC_SUBST(static_nss)
1792
1793 AC_SUBST(DEFINES)
1794
1795 dnl See sysdeps/mach/configure.ac for this variable.
1796 AC_SUBST(mach_interface_list)
1797
1798 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1799 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1800 AC_SUBST(VERSION)
1801 AC_SUBST(RELEASE)
1802
1803 AC_CONFIG_FILES([config.make Makefile])
1804 AC_CONFIG_COMMANDS([default],[[
1805 case $CONFIG_FILES in *config.make*)
1806 echo "$config_vars" >> config.make;;
1807 esac
1808 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1809 AC_OUTPUT