configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 # We need the C++ compiler only for testing.
  54 AC_PROG_CXX
  55 AC_CHECK_TOOL(READELF, readelf, false)
  56
  57 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
  58   AC_MSG_ERROR([you must configure in a separate build directory])
  59 fi
  60
  61 # This will get text that should go into config.make.
  62 config_vars=
  63
  64 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  65 AC_ARG_WITH([gd],
  66             AC_HELP_STRING([--with-gd=DIR],
  67                            [find libgd include dir and library with prefix DIR]),
  68             [dnl
  69 case "$with_gd" in
  70 yes|''|no) ;;
  71 *) libgd_include="-I$withval/include"
  72    libgd_ldflags="-L$withval/lib" ;;
  73 esac
  74 ])
  75 AC_ARG_WITH([gd-include],
  76             AC_HELP_STRING([--with-gd-include=DIR],
  77                            [find libgd include files in DIR]),
  78             [dnl
  79 case "$with_gd_include" in
  80 ''|no) ;;
  81 *) libgd_include="-I$withval" ;;
  82 esac
  83 ])
  84 AC_ARG_WITH([gd-lib],
  85             AC_HELP_STRING([--with-gd-lib=DIR],
  86                            [find libgd library files in DIR]),
  87             [dnl
  88 case "$with_gd_lib" in
  89 ''|no) ;;
  90 *) libgd_ldflags="-L$withval" ;;
  91 esac
  92 ])
  93
  94 if test -n "$libgd_include"; then
  95   config_vars="$config_vars
  96 CFLAGS-memusagestat.c = $libgd_include"
  97 fi
  98 if test -n "$libgd_ldflags"; then
  99   config_vars="$config_vars
 100 libgd-LDFLAGS = $libgd_ldflags"
 101 fi
 102
 103 dnl Arguments to specify presence of other packages/features.
 104 AC_ARG_WITH([fp],
 105             AC_HELP_STRING([--with-fp],
 106                            [if using floating-point hardware @<:@default=yes@:>@]),
 107             [with_fp=$withval],
 108             [with_fp=yes])
 109 AC_SUBST(with_fp)
 110 AC_ARG_WITH([binutils],
 111             AC_HELP_STRING([--with-binutils=PATH],
 112                            [specify location of binutils (as and ld)]),
 113             [path_binutils=$withval],
 114             [path_binutils=''])
 115 AC_ARG_WITH([selinux],
 116             AC_HELP_STRING([--with-selinux],
 117                            [if building with SELinux support]),
 118             [with_selinux=$withval],
 119             [with_selinux=auto])
 120
 121 AC_ARG_WITH([headers],
 122             AC_HELP_STRING([--with-headers=PATH],
 123                            [location of system headers to use
 124                             (for example /usr/src/linux/include)
 125                             @<:@default=compiler default@:>@]),
 126             [sysheaders=$withval],
 127             [sysheaders=''])
 128 AC_SUBST(sysheaders)
 129
 130 AC_SUBST(use_default_link)
 131 AC_ARG_WITH([default-link],
 132             AC_HELP_STRING([--with-default-link],
 133                            [do not use explicit linker scripts]),
 134             [use_default_link=$withval],
 135             [use_default_link=default])
 136
 137 AC_ARG_ENABLE([sanity-checks],
 138               AC_HELP_STRING([--disable-sanity-checks],
 139                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 140               [enable_sanity=$enableval],
 141               [enable_sanity=yes])
 142
 143 AC_ARG_ENABLE([shared],
 144               AC_HELP_STRING([--enable-shared],
 145                              [build shared library @<:@default=yes if GNU ld@:>@]),
 146               [shared=$enableval],
 147               [shared=yes])
 148 AC_ARG_ENABLE([profile],
 149               AC_HELP_STRING([--enable-profile],
 150                              [build profiled library @<:@default=no@:>@]),
 151               [profile=$enableval],
 152               [profile=no])
 153 AC_ARG_ENABLE([versioning],
 154               AC_HELP_STRING([--disable-versioning],
 155                              [do not include versioning information in the library objects @<:@default=yes if supported@:>@]),
 156               [enable_versioning=$enableval],
 157               [enable_versioning=yes])
 158
 159 AC_ARG_ENABLE([oldest-abi],
 160               AC_HELP_STRING([--enable-oldest-abi=ABI],
 161                              [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
 162               [oldest_abi=$enableval],
 163               [oldest_abi=no])
 164 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
 165   oldest_abi=default
 166 else
 167   AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
 168 fi
 169 AC_SUBST(oldest_abi)
 170
 171 AC_ARG_ENABLE([hardcoded-path-in-tests],
 172               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 173                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 174               [hardcoded_path_in_tests=$enableval],
 175               [hardcoded_path_in_tests=no])
 176 AC_SUBST(hardcoded_path_in_tests)
 177
 178 AC_ARG_ENABLE([stackguard-randomization],
 179               AC_HELP_STRING([--enable-stackguard-randomization],
 180                              [initialize __stack_chk_guard canary with a random number at program start]),
 181               [enable_stackguard_randomize=$enableval],
 182               [enable_stackguard_randomize=no])
 183 if test "$enable_stackguard_randomize" = yes; then
 184   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 185 fi
 186
 187 dnl Generic infrastructure for drop-in additions to libc.
 188 AC_ARG_ENABLE([add-ons],
 189               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 190                              [configure and build add-ons in DIR1,DIR2,...
 191                               search for add-ons if no parameter given]),
 192                              , [enable_add_ons=yes])
 193
 194 AC_ARG_ENABLE([hidden-plt],
 195               AC_HELP_STRING([--disable-hidden-plt],
 196                              [do not hide internal function calls to avoid PLT]),
 197               [hidden=$enableval],
 198               [hidden=yes])
 199 if test "x$hidden" = xno; then
 200   AC_DEFINE(NO_HIDDEN)
 201 fi
 202
 203 AC_ARG_ENABLE([bind-now],
 204               AC_HELP_STRING([--enable-bind-now],
 205                              [disable lazy relocations in DSOs]),
 206               [bindnow=$enableval],
 207               [bindnow=no])
 208 AC_SUBST(bindnow)
 209
 210 dnl On some platforms we cannot use dynamic loading.  We must provide
 211 dnl static NSS modules.
 212 AC_ARG_ENABLE([static-nss],
 213               AC_HELP_STRING([--enable-static-nss],
 214                              [build static NSS modules @<:@default=no@:>@]),
 215               [static_nss=$enableval],
 216               [static_nss=no])
 217 dnl Enable static NSS also if we build no shared objects.
 218 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 219   static_nss=yes
 220   AC_DEFINE(DO_STATIC_NSS)
 221 fi
 222
 223 AC_ARG_ENABLE([force-install],
 224               AC_HELP_STRING([--disable-force-install],
 225                              [don't force installation of files from this package, even if they are older than the installed files]),
 226               [force_install=$enableval],
 227               [force_install=yes])
 228 AC_SUBST(force_install)
 229
 230 dnl On some platforms we allow dropping compatibility with all kernel
 231 dnl versions.
 232 AC_ARG_ENABLE([kernel],
 233               AC_HELP_STRING([--enable-kernel=VERSION],
 234                              [compile for compatibility with kernel not older than VERSION]),
 235               [minimum_kernel=$enableval],
 236               [])
 237 dnl Prevent unreasonable values.
 238 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 239   # Better nothing than this.
 240   minimum_kernel=""
 241 else
 242   if test "$minimum_kernel" = current; then
 243     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 244   fi
 245 fi
 246
 247 dnl For the development we sometimes want gcc to issue even more warnings.
 248 dnl This is not the default since many of the extra warnings are not
 249 dnl appropriate.
 250 AC_ARG_ENABLE([all-warnings],
 251               AC_HELP_STRING([--enable-all-warnings],
 252                              [enable all useful warnings gcc can issue]),
 253               [all_warnings=$enableval],
 254               [])
 255 AC_SUBST(all_warnings)
 256
 257 AC_ARG_ENABLE([multi-arch],
 258               AC_HELP_STRING([--enable-multi-arch],
 259                              [enable single DSO with optimizations for multiple architectures]),
 260               [multi_arch=$enableval],
 261               [multi_arch=default])
 262
 263 AC_ARG_ENABLE([nss-crypt],
 264               AC_HELP_STRING([--enable-nss-crypt],
 265                              [enable libcrypt to use nss]),
 266               [nss_crypt=$enableval],
 267               [nss_crypt=no])
 268 if test x$nss_crypt = xyes; then
 269   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 270   if test $? -ne 0; then
 271     AC_MSG_ERROR([cannot find include directory with nss-config])
 272   fi
 273   old_CFLAGS="$CFLAGS"
 274   CFLAGS="$CFLAGS $nss_includes"
 275   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 276 #include <hasht.h>
 277 #include <nsslowhash.h>
 278 void f (void) { NSSLOW_Init (); }])],
 279              libc_cv_nss_crypt=yes,
 280              AC_MSG_ERROR([
 281 cannot find NSS headers with lowlevel hash function interfaces]))
 282   old_LIBS="$LIBS"
 283   LIBS="$LIBS -lfreebl3"
 284   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 285 #include <hasht.h>
 286 #include <nsslowhash.h>],
 287                                   [NSSLOW_Init();])],
 288                  libc_cv_nss_crypt=yes,
 289                  AC_MSG_ERROR([
 290 cannot link program using lowlevel NSS hash functions]))
 291   CFLAGS="$old_CFLAGS"
 292   LIBS="$old_LIBS"
 293 else
 294   libc_cv_nss_crypt=no
 295 fi
 296 AC_SUBST(libc_cv_nss_crypt)
 297
 298
 299 AC_ARG_ENABLE([obsolete-rpc],
 300               AC_HELP_STRING([--enable-obsolete-rpc],
 301                              [build and install the obsolete RPC code for link-time usage]),
 302               [link_obsolete_rpc=$enableval],
 303               [link_obsolete_rpc=no])
 304 AC_SUBST(link_obsolete_rpc)
 305
 306 if test "$link_obsolete_rpc" = yes; then
 307   AC_DEFINE(LINK_OBSOLETE_RPC)
 308 fi
 309
 310 AC_ARG_ENABLE([systemtap],
 311               [AS_HELP_STRING([--enable-systemtap],
 312                [enable systemtap static probe points @<:@default=no@:>@])],
 313               [systemtap=$enableval],
 314               [systemtap=no])
 315 if test "x$systemtap" != xno; then
 316   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 317   old_CFLAGS="$CFLAGS"
 318   CFLAGS="-std=gnu99 $CFLAGS"
 319   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 320 void foo (int i, void *p)
 321 {
 322   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 323        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 324 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 325   CFLAGS="$old_CFLAGS"])
 326   if test $libc_cv_sdt = yes; then
 327     AC_DEFINE([USE_STAP_PROBE])
 328   elif test "x$systemtap" != xauto; then
 329     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 330   fi
 331 fi
 332
 333 AC_ARG_ENABLE([build-nscd],
 334               [AS_HELP_STRING([--disable-build-nscd],
 335                [disable building and installing the nscd daemon])],
 336               [build_nscd=$enableval],
 337               [build_nscd=default])
 338 AC_SUBST(build_nscd)
 339
 340 # Note the use of $use_nscd is near the bottom of the file.
 341 AC_ARG_ENABLE([nscd],
 342               [AS_HELP_STRING([--disable-nscd],
 343                [library functions will not contact the nscd daemon])],
 344               [use_nscd=$enableval],
 345               [use_nscd=yes])
 346
 347 # The way shlib-versions is used to generate soversions.mk uses a
 348 # fairly simplistic model for name recognition that can't distinguish
 349 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 350 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 351 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 352 case "$host_os" in
 353 linux*)
 354   ;;
 355 gnu*)
 356   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 357   ;;
 358 esac
 359
 360 # We keep the original values in `$config_*' and never modify them, so we
 361 # can write them unchanged into config.make.  Everything else uses
 362 # $machine, $vendor, and $os, and changes them whenever convenient.
 363 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 364
 365 # Don't allow vendor == "unknown"
 366 test "$config_vendor" = unknown && config_vendor=
 367 config_os="`echo $config_os | sed 's/^unknown-//'`"
 368
 369 # Some configurations imply other options.
 370 elf=yes
 371
 372 # The configure fragment of an add-on port can modify these to supplement
 373 # or override the table in the case statement below.  No fragment should
 374 # ever change the config_* variables, however.
 375 machine=$config_machine
 376 vendor=$config_vendor
 377 os=$config_os
 378 base_os=''
 379
 380 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 381 # Unify this here.
 382 if test "$machine" = rs6000; then
 383   machine="powerpc"
 384 fi
 385
 386 # Braindead PowerPC box with absolutely no FPU.
 387 case "$machine-$host_os" in
 388   powerpc*-*soft)
 389     with_fp=no
 390     ;;
 391 esac
 392
 393 submachine=
 394 AC_ARG_WITH([cpu],
 395             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 396             [dnl
 397   case "$withval" in
 398   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 399   no) ;;
 400   *) submachine="$withval" ;;
 401   esac
 402 ])
 403
 404 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
 405 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 406
 407 # An add-on can set this when it wants to disable the sanity check below.
 408 libc_config_ok=no
 409
 410 dnl Having this here, though empty, makes sure that if add-ons' fragments
 411 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 412 dnl our AC_OUTPUT will actually use it.
 413 AC_CONFIG_SUBDIRS()
 414
 415 case "$enable_add_ons" in
 416 ''|no) add_ons= ;;
 417 yes|'*')
 418  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 419           sed 's@/[[^/]]*$@@' | sort | uniq`
 420          add_ons_automatic=yes
 421          ;;
 422 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 423        add_ons_automatic=no ;;
 424 esac
 425
 426 configured_add_ons=
 427 add_ons_sfx=
 428 add_ons_pfx=
 429 if test x"$add_ons" != x; then
 430   for f in $add_ons; do
 431     # Some sanity checks
 432     case "$f" in
 433     crypt)
 434       AC_MSG_ERROR([
 435 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 436 *** part of glibc and using the old add-on will not work with this
 437 *** release.  Start again with fresh sources and without the old
 438 *** \`crypt' add-on.])
 439     ;;
 440     localedata)
 441       AC_MSG_ERROR([
 442 *** It seems that you're using an old \`localedata' add-on.  localedata
 443 *** is now part of glibc and using the old add-on will not work with
 444 *** this release.  Start again with fresh sources and without the old
 445 *** \`localedata' add-on.])
 446     ;;
 447     esac
 448   done
 449
 450   # Now source each add-on's configure fragment.
 451   # The fragments can use $srcdir/$libc_add_on to find themselves,
 452   # and test $add_ons_automatic to see if they were explicitly requested.
 453   # A fragment can clear (or even change) $libc_add_on to affect
 454   # whether it goes into the list to be actually used in the build.
 455   use_add_ons=
 456   for libc_add_on in $add_ons; do
 457     # Test whether such a directory really exists.
 458     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 459     case "$libc_add_on" in
 460     /*)
 461       libc_add_on_srcdir=$libc_add_on
 462       ;;
 463     *)
 464       test -d "$srcdir/$libc_add_on" || {
 465         if test -d "$libc_add_on"; then
 466           libc_add_on="`pwd`/$libc_add_on"
 467         else
 468           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 469         fi
 470       }
 471       libc_add_on_srcdir=$srcdir/$libc_add_on
 472       ;;
 473     esac
 474
 475     libc_add_on_frag=$libc_add_on_srcdir/configure
 476     libc_add_on_canonical=
 477     libc_add_on_config_subdirs=
 478     if test -r "$libc_add_on_frag"; then
 479       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 480       libc_add_on_canonical=unknown
 481       libc_add_on_subdirs=
 482       . "$libc_add_on_frag"
 483       test -z "$libc_add_on" || {
 484         configured_add_ons="$configured_add_ons $libc_add_on"
 485         if test "x$libc_add_on_canonical" = xunknown; then
 486           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 487         fi
 488         for d in $libc_add_on_subdirs; do
 489           case "$libc_add_on" in
 490           /*) subdir_srcdir="$libc_add_on" ;;
 491           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 492           esac
 493           case "$d" in
 494           .)
 495             d="${libc_add_on_canonical:-$libc_add_on}"
 496             ;;
 497           /*)
 498             subdir_srcdir="$d"
 499             ;;
 500           *)
 501             subdir_srcdir="$subdir_srcdir/$d"
 502             ;;
 503           esac
 504           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 505           add_on_subdirs="$add_on_subdirs $d"
 506           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 507 $d-srcdir = $subdir_srcdir"
 508         done
 509         for d in $libc_add_on_config_subdirs; do
 510           case "$d" in
 511           /*) AC_MSG_ERROR(dnl
 512 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 513           esac
 514           if test ! -d "$libc_add_on_srcdir/$d"; then
 515             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 516           fi
 517           case "$libc_add_on" in
 518           /*) AC_MSG_ERROR(dnl
 519 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 520           esac
 521           subdirs="$subdirs $libc_add_on/$d"
 522         done
 523       }
 524     fi
 525     if test -n "$libc_add_on"; then
 526       LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
 527       use_add_ons="$use_add_ons $libc_add_on"
 528       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 529       test -z "$libc_add_on_canonical" ||
 530       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 531     fi
 532   done
 533   # Use echo to strip excess whitespace.
 534   add_ons="`echo $use_add_ons`"
 535 fi
 536 AC_SUBST(add_ons)
 537 AC_SUBST(add_on_subdirs)
 538
 539
 540 ###
 541 ### I put this here to prevent those annoying emails from people who cannot
 542 ### read and try to compile glibc on unsupported platforms.  --drepper
 543 ###
 544 ### By using the undocumented --enable-hacker-mode option for configure
 545 ### one can skip this test to make the configuration not fail for unsupported
 546 ### platforms.
 547 ###
 548 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 549   case "$machine-$host_os" in
 550   *-linux* | *-gnu*)
 551     ;;
 552   *)
 553     echo "*** The GNU C library is currently not available for this platform."
 554     echo "*** So far nobody cared to port it and if there is no volunteer it"
 555     echo "*** might never happen.  So, if you have interest to see glibc on"
 556     echo "*** this platform visit"
 557     echo "***   http://www.gnu.org/software/libc/porting.html"
 558     echo "*** and join the group of porters"
 559     exit 1
 560     ;;
 561   esac
 562 fi
 563
 564 dnl We need to use [ and ] for other purposes for a while now.
 565 changequote(,)dnl
 566 # Expand the configuration machine name into a subdirectory by architecture
 567 # type and particular chip.  If an add-on configure fragment already set
 568 # base_machine, we don't change it.
 569 test -n "$base_machine" || case "$machine" in
 570 i[34567]86)     base_machine=i386 machine=i386/$machine ;;
 571 powerpc)        base_machine=powerpc machine=powerpc/powerpc32 ;;
 572 powerpc64)      base_machine=powerpc machine=powerpc/powerpc64 ;;
 573 s390)           base_machine=s390 machine=s390/s390-32 ;;
 574 s390x)          base_machine=s390 machine=s390/s390-64 ;;
 575 sh3*)           base_machine=sh machine=sh/sh3 ;;
 576 sh4*)           base_machine=sh machine=sh/sh4 ;;
 577 sparc | sparcv[67])
 578                 base_machine=sparc machine=sparc/sparc32 ;;
 579 sparcv8 | supersparc | hypersparc)
 580                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 581 sparcv8plus | sparcv8plusa | sparcv9)
 582                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 583 sparcv8plusb | sparcv9b)
 584                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
 585 sparcv9v)
 586                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
 587 sparcv9v2)
 588                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
 589 sparc64)
 590                 base_machine=sparc machine=sparc/sparc64 ;;
 591 sparc64b)
 592                 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
 593 sparc64v)
 594                 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
 595 sparc64v2)
 596                 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
 597 *)              base_machine=$machine ;;
 598 esac
 599 changequote([,])dnl
 600 AC_SUBST(base_machine)
 601
 602 if test "$base_machine" = "i386"; then
 603   AC_DEFINE(USE_REGPARMS)
 604 fi
 605
 606 # For the multi-arch option we need support in the assembler & linker.
 607 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 608                libc_cv_ld_gnu_indirect_function, [dnl
 609 cat > conftest.S <<EOF
 610 .type foo,%gnu_indirect_function
 611 foo:
 612 .globl _start
 613 _start:
 614 .globl __start
 615 __start:
 616 .data
 617 #ifdef _LP64
 618 .quad foo
 619 #else
 620 .long foo
 621 #endif
 622 EOF
 623 libc_cv_ld_gnu_indirect_function=no
 624 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 625             -nostartfiles -nostdlib \
 626             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 627   # Do a link to see if the backend supports IFUNC relocs.
 628   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 629   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 630     libc_cv_ld_gnu_indirect_function=yes
 631   }
 632 fi
 633 rm -f conftest*])
 634
 635 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 636 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 637 cat > conftest.s <<EOF
 638 .text
 639 EOF
 640 libc_cv_dot_text=
 641 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 642   libc_cv_dot_text=.text
 643 fi
 644 rm -f conftest*])
 645 if test -z "$libc_cv_dot_text"; then
 646   AC_MSG_RESULT(no)
 647 else
 648   AC_MSG_RESULT(yes)
 649 fi
 650
 651 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 652   if test x"$multi_arch" = xyes; then
 653     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 654   else
 655     multi_arch=no
 656   fi
 657 fi
 658 multi_arch_d=
 659 if test x"$multi_arch" != xno; then
 660   multi_arch_d=/multiarch
 661 fi
 662
 663 # Compute the list of sysdep directories for this configuration.
 664 # This can take a while to compute.
 665 sysdep_dir=$srcdir/sysdeps
 666 AC_MSG_CHECKING(sysdep dirs)
 667 dnl We need to use [ and ] for other purposes for a while now.
 668 changequote(,)dnl
 669 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 670 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 671
 672 test "x$base_os" != x || case "$os" in
 673 gnu*)
 674   base_os=mach/hurd ;;
 675 linux*)
 676   base_os=unix/sysv ;;
 677 esac
 678
 679 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 680 tail=$os
 681 ostry=$os
 682 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 683   ostry="$ostry /$o"
 684   tail=$o
 685 done
 686 o=`echo $tail | sed 's/[0-9]*$//'`
 687 if test $o != $tail; then
 688   ostry="$ostry /$o"
 689 fi
 690 # For linux-gnu, try linux-gnu, then linux.
 691 o=`echo $tail | sed 's/-.*$//'`
 692 if test $o != $tail; then
 693   ostry="$ostry /$o"
 694 fi
 695
 696 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 697 base=
 698 tail=$base_os
 699 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 700   set $b
 701   base="$base /$1"
 702   tail="$2"
 703 done
 704
 705 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 706 mach=
 707 tail=$machine${submachine:+/$submachine}
 708 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 709   set $m
 710   # Prepend the machine's FPU directory unless --without-fp.
 711   if test "$with_fp" = yes; then
 712     maybe_fpu=/fpu
 713   else
 714     maybe_fpu=/nofpu
 715   fi
 716   # For each machine term, try it with and then without /multiarch.
 717   for try_fpu in $maybe_fpu ''; do
 718     for try_multi in $multi_arch_d ''; do
 719       mach="$mach /$1$try_fpu$try_multi"
 720     done
 721   done
 722   tail="$2"
 723 done
 724
 725 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 726 changequote([,])dnl
 727
 728 # Find what sysdep directories exist.
 729 sysnames_add_ons=
 730 sysnames=
 731 for b in $base ''; do
 732   for m0 in $mach ''; do
 733     for v in /$vendor ''; do
 734       test "$v" = / && continue
 735       for o in /$ostry ''; do
 736         test "$o" = / && continue
 737         for m in $mach ''; do
 738           for d in $add_ons_pfx ''; do
 739             for a in $add_ons_sfx ''; do
 740               try_suffix="$m0$b$v$o$m"
 741               if test -n "$try_suffix"; then
 742                 try_srcdir="${srcdir}/"
 743                 case "$d" in
 744                 /*) try_srcdir= ;;
 745                 esac
 746                 try="${d}sysdeps$try_suffix$a"
 747                 test -n "$enable_debug_configure" &&
 748                 echo "$0 [DEBUG]: try $try" >&2
 749                 if test -d "$try_srcdir$try"; then
 750                   sysnames="$sysnames $try"
 751                   { test -n "$o" || test -n "$b"; } && os_used=t
 752                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 753                   case x${m0:-$m} in
 754                   x*/$submachine) submachine_used=t ;;
 755                   esac
 756                   if test -n "$d"; then
 757                     case "$sysnames_add_ons" in
 758                     *" $d "*) ;;
 759                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 760                     esac
 761                   fi
 762                 fi
 763               fi
 764             done
 765           done
 766         done
 767       done
 768     done
 769   done
 770 done
 771
 772 # If the assembler supports gnu_indirect_function symbol type and the
 773 # architecture supports multi-arch, we enable multi-arch by default.
 774 case $sysnames_add_ons$sysnames in
 775 *"$multi_arch_d"*)
 776   ;;
 777 *)
 778   test x"$multi_arch" = xdefault && multi_arch=no
 779   ;;
 780 esac
 781 if test x"$multi_arch" != xno; then
 782   AC_DEFINE(USE_MULTIARCH)
 783 fi
 784 AC_SUBST(multi_arch)
 785
 786 if test -z "$os_used" && test "$os" != none; then
 787   AC_MSG_ERROR(Operating system $os is not supported.)
 788 fi
 789 if test -z "$machine_used" && test "$machine" != none; then
 790   AC_MSG_ERROR(The $machine is not supported.)
 791 fi
 792 if test -z "$submachine_used" && test -n "$submachine"; then
 793   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 794 fi
 795 AC_SUBST(submachine)
 796
 797 # We have now validated the configuration.
 798
 799 # Expand the list of system names into a full list of directories
 800 # from each element's parent name and Implies file (if present).
 801 set $sysnames
 802 names=
 803 while test $# -gt 0; do
 804   name=$1
 805   shift
 806
 807   case " $names " in *" $name "*)
 808     # Already in the list.
 809     continue
 810   esac
 811
 812   # Report each name as we discover it, so there is no long pause in output.
 813   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 814
 815   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 816
 817   case $name in
 818     /*) xsrcdir= ;;
 819     *)  xsrcdir=$srcdir/ ;;
 820   esac
 821   test -n "$enable_debug_configure" &&
 822   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 823
 824   for implies_file in Implies Implies-before Implies-after; do
 825     implies_type=`echo $implies_file | sed s/-/_/`
 826     eval ${implies_type}=
 827     if test -f $xsrcdir$name/$implies_file; then
 828       # Collect more names from the `Implies' file (removing comments).
 829       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 830       for x in $implied_candidate; do
 831         found=no
 832         if test -d $xsrcdir$name_base/$x; then
 833           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 834           found=yes
 835         fi
 836         for d in $add_ons_pfx ''; do
 837           try="${d}sysdeps/$x"
 838           case $d in
 839            /*) try_srcdir= ;;
 840            *) try_srcdir=$srcdir/ ;;
 841           esac
 842           test -n "$enable_debug_configure" &&
 843            echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
 844           if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 845           then
 846             eval "${implies_type}=\"\$${implies_type} \$try\""
 847             found=yes
 848             case "$sysnames_add_ons" in
 849             *" $d "*) ;;
 850             *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 851             esac
 852           fi
 853         done
 854         if test $found = no; then
 855           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 856         fi
 857       done
 858     fi
 859   done
 860
 861   # Add NAME to the list of names.
 862   names="$names $name"
 863
 864   # Find the parent of NAME, using the empty string if it has none.
 865 changequote(,)dnl
 866   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 867 changequote([,])dnl
 868
 869   test -n "$enable_debug_configure" &&
 870     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 871 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 872
 873   # Add the names implied by NAME, and NAME's parent (if it has one), to
 874   # the list of names to be processed (the argument list).  We prepend the
 875   # implied names to the list and append the parent.  We want implied
 876   # directories to come before further directories inferred from the
 877   # configuration components; this ensures that for sysv4, unix/common
 878   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 879   # after sysv4).
 880   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 881   test -n "$sysnames" && set $sysnames
 882 done
 883
 884 # Add the default directories.
 885 default_sysnames="sysdeps/generic"
 886 sysnames="$names $default_sysnames"
 887 AC_SUBST(sysnames)
 888 # The other names were emitted during the scan.
 889 AC_MSG_RESULT($default_sysnames)
 890
 891 # Collect the list of add-ons that supply partial sysdeps trees.
 892 sysdeps_add_ons=
 893 for add_on in $add_ons; do
 894   case "$add_on" in
 895   /*) xsrcdir= ;;
 896   *) xsrcdir="$srcdir/" ;;
 897   esac
 898
 899   test -d "$xsrcdir$add_on/sysdeps" || {
 900     case "$configured_add_ons " in
 901     *" $add_on "*) ;;
 902     *|'')
 903       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
 904       ;;
 905     esac
 906     continue
 907   }
 908
 909   sysdeps_add_ons="$sysdeps_add_ons $add_on"
 910   case "$sysnames_add_ons" in
 911   *" $add_on/ "*) ;;
 912   *|'')
 913     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
 914     continue ;;
 915   esac
 916
 917   found=no
 918   for d in $sysnames; do
 919     case "$d" in
 920     $add_on/sysdeps/*) ;;
 921     *) continue ;;
 922     esac
 923     (cd "$xsrcdir$d" && for f in *[[!~]]; do
 924        case "$f" in
 925        sys|bits)
 926          for ff in $f/*.h; do
 927            test -d "$ff" || { test -e "$ff" && exit 88; }
 928          done
 929          ;;
 930        *)
 931          test -d "$f" || { test -e "$f" && exit 88; }
 932          ;;
 933        esac
 934      done)
 935     if test $? -eq 88; then
 936       found=yes
 937       break
 938     fi
 939   done
 940   if test $found = no; then
 941     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
 942   fi
 943 done
 944 AC_SUBST(sysdeps_add_ons)
 945
 946
 947 ### Locate tools.
 948
 949 AC_PROG_INSTALL
 950 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 951   # The makefiles need to use a different form to find it in $srcdir.
 952   INSTALL='\$(..)./scripts/install-sh -c'
 953 fi
 954 AC_PROG_LN_S
 955
 956 LIBC_PROG_BINUTILS
 957
 958 # Accept binutils 2.20 or newer.
 959 AC_CHECK_PROG_VER(AS, $AS, --version,
 960                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 961                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
 962 AC_CHECK_PROG_VER(LD, $LD, --version,
 963                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 964                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
 965
 966 # These programs are version sensitive.
 967 AC_CHECK_TOOL_PREFIX
 968 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 969   [version \([egcygnustpi-]*[0-9.]*\)], [4.[3-9].* | 4.[1-9][0-9].* | [5-9].* ],
 970   critic_missing="$critic_missing gcc")
 971 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 972   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 973   [3.79* | 3.[89]*], critic_missing="$critic_missing make")
 974
 975 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 976   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 977   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 978   MSGFMT=: aux_missing="$aux_missing msgfmt")
 979 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 980   [GNU texinfo.* \([0-9][0-9.]*\)],
 981   [4.[5-9]*|4.[1-9][0-9]*|[5-9].*],
 982   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 983 AC_CHECK_PROG_VER(SED, sed, --version,
 984   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
 985   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 986   SED=: aux_missing="$aux_missing sed")
 987 AC_CHECK_PROG_VER(AWK, gawk, --version,
 988   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
 989   [[3-9].*], critic_missing="$critic_missing gawk")
 990
 991 AC_CHECK_TOOL(NM, nm, false)
 992
 993 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 994 case "x$AUTOCONF" in
 995 xno|x|x:) AUTOCONF=no ;;
 996 *)
 997   AC_CACHE_CHECK(dnl
 998 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 999   if (cd $srcdir; $AUTOCONF $ACFLAGS configure.in > /dev/null 2>&1); then
1000     libc_cv_autoconf_works=yes
1001   else
1002     libc_cv_autoconf_works=no
1003   fi])
1004   test $libc_cv_autoconf_works = yes || AUTOCONF=no
1005   ;;
1006 esac
1007 if test "x$AUTOCONF" = xno; then
1008   aux_missing="$aux_missing autoconf"
1009 fi
1010
1011 test -n "$critic_missing" && AC_MSG_ERROR([
1012 *** These critical programs are missing or too old:$critic_missing
1013 *** Check the INSTALL file for required versions.])
1014
1015 test -n "$aux_missing" && AC_MSG_WARN([
1016 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1017 *** some features will be disabled.
1018 *** Check the INSTALL file for required versions.])
1019
1020 # if using special system headers, find out the compiler's sekrit
1021 # header directory and add that to the list.  NOTE: Only does the right
1022 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1023 if test -n "$sysheaders"; then
1024   SYSINCLUDES=-nostdinc
1025   for d in include include-fixed; do
1026     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1027     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1028   done
1029   SYSINCLUDES="$SYSINCLUDES \
1030 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1031   if test -n "$CXX"; then
1032     CXX_SYSINCLUDES=
1033     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1034     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1035       test "x$cxxheaders" != x &&
1036       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1037     done
1038   fi
1039 fi
1040 AC_SUBST(SYSINCLUDES)
1041 AC_SUBST(CXX_SYSINCLUDES)
1042
1043 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1044 # since this would lead to problems installing/building glibc.
1045 # LD_LIBRARY_PATH contains the current directory if one of the following
1046 # is true:
1047 # - one of the terminals (":" and ";") is the first or last sign
1048 # - two terminals occur directly after each other
1049 # - the path contains an element with a dot in it
1050 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1051 changequote(,)dnl
1052 case ${LD_LIBRARY_PATH} in
1053   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1054     ld_library_path_setting="contains current directory"
1055     ;;
1056   *)
1057     ld_library_path_setting="ok"
1058     ;;
1059 esac
1060 changequote([,])dnl
1061 AC_MSG_RESULT($ld_library_path_setting)
1062 if test "$ld_library_path_setting" != "ok"; then
1063 AC_MSG_ERROR([
1064 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1065 *** building glibc. Please change the environment variable
1066 *** and run configure again.])
1067 fi
1068
1069 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1070 if $CC -v -static-libgcc 2>&1 | grep 'unrecognized option.*static-libgcc' >/dev/null; then
1071   libc_cv_gcc_static_libgcc=
1072 else
1073   libc_cv_gcc_static_libgcc=-static-libgcc
1074 fi])
1075 AC_SUBST(libc_cv_gcc_static_libgcc)
1076
1077 AC_PATH_PROG(BASH_SHELL, bash, no)
1078 if test "$BASH_SHELL" != no &&
1079    $BASH_SHELL -c 'test "$BASH_VERSINFO" \
1080              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
1081   libc_cv_have_bash2=yes
1082 else
1083   libc_cv_have_bash2=no
1084 fi
1085 AC_SUBST(libc_cv_have_bash2)
1086
1087 dnl We need a ksh compatible shell for tzselect.
1088 if test "$BASH_SHELL" = no; then
1089   AC_PATH_PROG(KSH, ksh, no)
1090   if test "$KSH" = no; then
1091     libc_cv_have_ksh=no
1092   else
1093     libc_cv_have_ksh=yes
1094   fi
1095 else
1096   KSH="$BASH_SHELL"
1097   AC_SUBST(KSH)
1098   libc_cv_have_ksh=yes
1099 fi
1100 AC_SUBST(libc_cv_have_ksh)
1101
1102 AC_PATH_PROG(PERL, perl, no)
1103 if test "$PERL" != no &&
1104    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1105   PERL=no
1106 fi
1107 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1108              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1109 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1110
1111 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1112 AC_TRY_COMPILE(dnl
1113 [#define __need_size_t
1114 #define __need_wchar_t
1115 #include <stddef.h>
1116 #define __need_NULL
1117 #include <stddef.h>], [size_t size; wchar_t wchar;
1118 #ifdef offsetof
1119 #error stddef.h ignored __need_*
1120 #endif
1121 if (&size == NULL || &wchar == NULL) abort ();],
1122                libc_cv_friendly_stddef=yes,
1123                libc_cv_friendly_stddef=no)])
1124 if test $libc_cv_friendly_stddef = yes; then
1125   config_vars="$config_vars
1126 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1127 fi
1128
1129 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1130                libc_cv_need_minus_P, [dnl
1131 cat > conftest.S <<EOF
1132 #include "confdefs.h"
1133 /* Nothing whatsoever.  */
1134 EOF
1135 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1136   libc_cv_need_minus_P=no
1137 else
1138   libc_cv_need_minus_P=yes
1139 fi
1140 rm -f conftest*])
1141 if test $libc_cv_need_minus_P = yes; then
1142   config_vars="$config_vars
1143 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1144 fi
1145
1146 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1147 cat > conftest.s <<EOF
1148 ${libc_cv_dot_text}
1149 foo:
1150 .set glibc_conftest_frobozz,foo
1151 .globl glibc_conftest_frobozz
1152 EOF
1153 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1154 # (but it doesn't work), so we must do a linking check to be sure.
1155 cat > conftest1.c <<\EOF
1156 extern int glibc_conftest_frobozz;
1157 void _start() { glibc_conftest_frobozz = 1; }
1158 EOF
1159 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1160             -nostartfiles -nostdlib \
1161             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1162   libc_cv_asm_set_directive=yes
1163 else
1164   libc_cv_asm_set_directive=no
1165 fi
1166 rm -f conftest*])
1167 if test $libc_cv_asm_set_directive = yes; then
1168   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1169 fi
1170
1171 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1172                libc_cv_asm_unique_object, [dnl
1173 cat > conftest.s <<EOF
1174 ${libc_cv_dot_text}
1175 _sym:
1176 .type _sym, %gnu_unique_object
1177 EOF
1178 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1179   libc_cv_asm_unique_object=yes
1180 else
1181   libc_cv_asm_unique_object=no
1182 fi
1183 rm -f conftest*])
1184 if test $libc_cv_asm_unique_object = yes; then
1185   AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1186 fi
1187
1188 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
1189 [cat > conftest.s <<EOF
1190 ${libc_cv_dot_text}
1191 _sym:
1192 .symver _sym,sym@VERS
1193 EOF
1194 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1195   libc_cv_asm_symver_directive=yes
1196 else
1197   libc_cv_asm_symver_directive=no
1198 fi
1199 rm -f conftest*])
1200 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
1201 if test $libc_cv_asm_symver_directive = yes; then
1202   cat > conftest.s <<EOF
1203 ${libc_cv_dot_text}
1204 _sym:
1205 .symver _sym,sym@VERS
1206 EOF
1207   cat > conftest.map <<EOF
1208 VERS_1 {
1209         global: sym;
1210 };
1211
1212 VERS_2 {
1213         global: sym;
1214 } VERS_1;
1215 EOF
1216   if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1217     if AC_TRY_COMMAND([${CC-cc} $CFLAGS $LDFLAGS -shared
1218                                 -o conftest.so conftest.o
1219                                 -nostartfiles -nostdlib
1220                                 -Wl,--version-script,conftest.map
1221                        1>&AS_MESSAGE_LOG_FD]);
1222     then
1223       libc_cv_ld_version_script_option=yes
1224     else
1225       libc_cv_ld_version_script_option=no
1226     fi
1227   else
1228     libc_cv_ld_version_script_option=no
1229   fi
1230 else
1231   libc_cv_ld_version_script_option=no
1232 fi
1233 rm -f conftest*])
1234 if test $shared != no &&
1235    test $libc_cv_asm_symver_directive = yes &&
1236    test $libc_cv_ld_version_script_option = yes &&
1237    test $enable_versioning = yes; then
1238   VERSIONING=yes
1239   AC_DEFINE(DO_VERSIONING)
1240 else
1241   VERSIONING=no
1242 fi
1243 AC_SUBST(VERSIONING)
1244
1245 if test $shared != no && test $VERSIONING = no; then
1246   echo "\
1247 *** WARNING: You should not compile GNU libc without versioning. Not using
1248 *** versioning will introduce incompatibilities so that old binaries
1249 *** will not run anymore.
1250 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
1251 fi
1252 AC_CACHE_CHECK(for .previous assembler directive,
1253                libc_cv_asm_previous_directive, [dnl
1254 cat > conftest.s <<EOF
1255 .section foo_section
1256 .previous
1257 EOF
1258 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1259   libc_cv_asm_previous_directive=yes
1260 else
1261   libc_cv_asm_previous_directive=no
1262 fi
1263 rm -f conftest*])
1264 if test $libc_cv_asm_previous_directive = yes; then
1265   AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1266 else
1267   AC_CACHE_CHECK(for .popsection assembler directive,
1268                  libc_cv_asm_popsection_directive, [dnl
1269   cat > conftest.s <<EOF
1270 .pushsection foo_section
1271 .popsection
1272 EOF
1273   if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1274     libc_cv_asm_popsection_directive=yes
1275   else
1276     libc_cv_asm_popsection_directive=no
1277   fi
1278   rm -f conftest*])
1279   if test $libc_cv_asm_popsection_directive = yes; then
1280     AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1281   fi
1282 fi
1283 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1284                libc_cv_asm_protected_directive, [dnl
1285 cat > conftest.s <<EOF
1286 .protected foo
1287 foo:
1288 .hidden bar
1289 bar:
1290 EOF
1291 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1292   libc_cv_asm_protected_directive=yes
1293 else
1294   AC_MSG_ERROR(assembler support for symbol visibility is required)
1295 fi
1296 rm -f conftest*])
1297
1298 if test $libc_cv_asm_protected_directive = yes; then
1299   AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1300                  libc_cv_visibility_attribute,
1301                  [cat > conftest.c <<EOF
1302                   int foo __attribute__ ((visibility ("hidden"))) = 1;
1303                   int bar __attribute__ ((visibility ("protected"))) = 1;
1304 EOF
1305                   libc_cv_visibility_attribute=no
1306                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1307                     if grep '\.hidden.*foo' conftest.s >/dev/null; then
1308                       if grep '\.protected.*bar' conftest.s >/dev/null; then
1309                         libc_cv_visibility_attribute=yes
1310                       fi
1311                     fi
1312                   fi
1313                   rm -f conftest.{c,s}
1314                  ])
1315   if test $libc_cv_visibility_attribute != yes; then
1316     AC_MSG_ERROR(compiler support for visibility attribute is required)
1317   fi
1318 fi
1319
1320 if test $libc_cv_visibility_attribute = yes; then
1321   AC_CACHE_CHECK(for broken __attribute__((visibility())),
1322                  libc_cv_broken_visibility_attribute,
1323                  [cat > conftest.c <<EOF
1324                   int foo (int x);
1325                   int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1326                   int bar (int x) { return x; }
1327 EOF
1328                   libc_cv_broken_visibility_attribute=yes
1329                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1330 changequote(,)dnl
1331                     if grep '\.hidden[  _]foo' conftest.s >/dev/null; then
1332 changequote([,])dnl
1333                       libc_cv_broken_visibility_attribute=no
1334                     fi
1335                   fi
1336                   rm -f conftest.c conftest.s
1337                  ])
1338   if test $libc_cv_broken_visibility_attribute = yes; then
1339     AC_MSG_ERROR(working compiler support for visibility attribute is required)
1340   fi
1341 fi
1342
1343 AC_CACHE_CHECK(for broken __attribute__((alias())),
1344                libc_cv_broken_alias_attribute,
1345                [cat > conftest.c <<EOF
1346                extern int foo (int x) __asm ("xyzzy");
1347                int bar (int x) { return x; }
1348                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1349                extern int dfoo;
1350                extern __typeof (dfoo) dfoo __asm ("abccb");
1351                int dfoo = 1;
1352 EOF
1353                libc_cv_broken_alias_attribute=yes
1354                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1355                  if grep 'xyzzy' conftest.s >/dev/null &&
1356                     grep 'abccb' conftest.s >/dev/null; then
1357                    libc_cv_broken_alias_attribute=no
1358                  fi
1359                fi
1360                rm -f conftest.c conftest.s
1361                ])
1362 if test $libc_cv_broken_alias_attribute = yes; then
1363   AC_MSG_ERROR(working alias attribute support required)
1364 fi
1365
1366 if test $libc_cv_visibility_attribute = yes; then
1367   AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1368                  libc_cv_have_sdata_section,
1369                  [echo "int i;" > conftest.c
1370                   libc_cv_have_sdata_section=no
1371                   if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1372                      | grep '\.sdata' >/dev/null; then
1373                     libc_cv_have_sdata_section=yes
1374                   fi
1375                   rm -f conftest.c conftest.so
1376                  ])
1377   if test $libc_cv_have_sdata_section = yes; then
1378     AC_DEFINE(HAVE_SDATA_SECTION)
1379   fi
1380 fi
1381
1382 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1383                libc_cv_initfini_array, [dnl
1384 LIBC_TRY_LINK_STATIC([
1385 int foo (void) { return 1; }
1386 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1387 ],
1388   [if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1389     libc_cv_initfini_array=yes
1390   else
1391     libc_cv_initfini_array=no
1392   fi],
1393   [libc_cv_initfini_array=no])
1394 ])
1395 if test $libc_cv_initfini_array != yes; then
1396   AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1397 fi
1398
1399 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1400                libc_cv_ctors_header, [dnl
1401   libc_cv_ctors_header=yes
1402   LIBC_TRY_LINK_STATIC([
1403 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1404 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1405 ],
1406               [dnl
1407       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1408         { gsub(/\@<:@ */, "@<:@") }
1409         $2 == ".ctors" || $2 == ".dtors" {
1410           size = strtonum("0x" $6)
1411           align = strtonum("0x" $NF)
1412           seen@<:@$2@:>@ = 1
1413           stub@<:@$2@:>@ = size == align * 2
1414         }
1415         END {
1416           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1417           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1418           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1419         }
1420       '], [libc_cv_ctors_header=no])
1421     ], [dnl
1422       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1423     ])
1424 ])
1425 if test $libc_cv_ctors_header = no; then
1426   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1427 fi
1428
1429 AC_CACHE_CHECK(for libunwind-support in compiler,
1430                libc_cv_cc_with_libunwind, [
1431   cat > conftest.c <<EOF
1432 int main (void) { return 0; }
1433 EOF
1434   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1435      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1436     libc_cv_cc_with_libunwind=yes
1437   else
1438     libc_cv_cc_with_libunwind=no
1439   fi
1440   rm -f conftest*])
1441 AC_SUBST(libc_cv_cc_with_libunwind)
1442 if test $libc_cv_cc_with_libunwind = yes; then
1443   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1444 fi
1445
1446 LIBC_LINKER_FEATURE([-z nodelete], [-Wl,--enable-new-dtags,-z,nodelete],
1447                     [libc_cv_z_nodelete=yes],
1448                     [AC_MSG_ERROR(linker with -z nodelete support required)])
1449
1450 LIBC_LINKER_FEATURE([-z nodlopen], [-Wl,--enable-new-dtags,-z,nodlopen],
1451                     [libc_cv_z_nodlopen=yes],
1452                     [AC_MSG_ERROR(linker with -z nodlopen support required)])
1453
1454 LIBC_LINKER_FEATURE([-z initfirst], [-Wl,--enable-new-dtags,-z,initfirst],
1455                     [libc_cv_z_initfirst=yes],
1456                     [AC_MSG_ERROR(linker with -z initfirst support required)])
1457
1458 # Add-on fragments can set these for other machines.
1459 libc_commonpagesize=${libc_commonpagesize:-no}
1460 libc_relro_required=${libc_relro_required:-no}
1461 case "$base_machine" in
1462   i[[34567]]86 | x86_64 | powerpc* | s390*)
1463     libc_commonpagesize=0x1000
1464     libc_relro_required=yes
1465     ;;
1466   sparc*)
1467     libc_commonpagesize=0x2000
1468     libc_relro_required=yes
1469     ;;
1470 esac
1471
1472 if test $libc_commonpagesize != no; then
1473   AC_CACHE_CHECK(for -z relro option,
1474                  libc_cv_z_relro, [dnl
1475   libc_cv_z_relro=no
1476   AC_LANG_CONFTEST([AC_LANG_SOURCE([[
1477 int _start (void) { return 42; }
1478 extern void _exit (int);
1479 /* Since these pointers are const, they should go in rodata.
1480    Since they refer to functions that have to be resolved by
1481    dynamic linking, they should instead go in RELRO data.  */
1482 const void *const relro[] = { &_start, &_exit, 0 };
1483 /* GNU ld fails to produce RELRO data when it's very small and there is no
1484    normal writable data following it, or if only uninitialized (.bss) data
1485    follows it, or only very small writable data.  */
1486 int data[0x10000] = { 1, };
1487 ]])])
1488   cat > conftest.awk <<\EOF
1489 BEGIN {
1490   result = "no"
1491   commonpagesize = strtonum(commonpagesize)
1492 }
1493 { print "LINE:", $0 > "/dev/stderr" }
1494 $1 == "GNU_RELRO" {
1495   vaddr = strtonum($3)
1496   memsz = strtonum($6)
1497   end = vaddr + memsz
1498   printf "vaddr %#x memsz %#x end %#x commonpagesize %#x\n", \
1499     vaddr, memsz, end, commonpagesize > "/dev/stderr"
1500   result = (end % commonpagesize == 0) ? "yes" : "broken"
1501 }
1502 END { print result }
1503 EOF
1504   AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1505                     -fPIC -shared -o conftest.so conftest.c
1506                     -nostartfiles -nostdlib
1507                     -Wl,-z,relro 1>&AS_MESSAGE_LOG_FD]) &&
1508   AC_TRY_COMMAND([$READELF -Wl conftest.so > conftest.ph]) &&
1509   AC_TRY_COMMAND([
1510       $AWK -v commonpagesize=$libc_commonpagesize -f conftest.awk
1511            conftest.ph > conftest.cps
1512     ]) &&
1513   libc_cv_z_relro=`cat conftest.cps 2>&AS_MESSAGE_LOG_FD`
1514   rm -f conftest*])
1515   if { test "x$libc_relro_required" = xyes &&
1516        test "x$libc_cv_z_relro" != xyes
1517      }
1518   then
1519     AC_MSG_ERROR(linker with -z relro support required)
1520   fi
1521 else
1522   AC_MSG_WARN([missing architecture parameter to check for working -z relro])
1523 fi
1524
1525 AC_CACHE_CHECK(for -Bgroup option,
1526                libc_cv_Bgroup, [dnl
1527 cat > conftest.c <<EOF
1528 int _start (void) { return 42; }
1529 EOF
1530 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1531                             -fPIC -shared -o conftest.so conftest.c
1532                             -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1533 then
1534   libc_cv_Bgroup=yes
1535 else
1536   libc_cv_Bgroup=no
1537 fi
1538 rm -f conftest*])
1539 AC_SUBST(libc_cv_Bgroup)
1540
1541 ASFLAGS_config=
1542 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1543                libc_cv_as_noexecstack, [dnl
1544 cat > conftest.c <<EOF
1545 void foo (void) { }
1546 EOF
1547 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1548                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1549    && grep .note.GNU-stack conftest.s >/dev/null \
1550    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1551                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1552 then
1553   libc_cv_as_noexecstack=yes
1554 else
1555   libc_cv_as_noexecstack=no
1556 fi
1557 rm -f conftest*])
1558 if test $libc_cv_as_noexecstack = yes; then
1559   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1560 fi
1561 AC_SUBST(ASFLAGS_config)
1562
1563 AC_CACHE_CHECK(for -z combreloc,
1564                libc_cv_z_combreloc, [dnl
1565 cat > conftest.c <<EOF
1566 extern int bar (int);
1567 extern int mumble;
1568 int foo (void) { return bar (mumble); }
1569 EOF
1570 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1571                         -fPIC -shared -o conftest.so conftest.c
1572                         -nostdlib -nostartfiles
1573                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1574 then
1575 dnl The following test is a bit weak.  We must use a tool which can test
1576 dnl cross-platform since the gcc used can be a cross compiler.  Without
1577 dnl introducing new options this is not easily doable.  Instead use a tool
1578 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1579 dnl look for a section named .rel.dyn.
1580   if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1581     libc_cv_z_combreloc=yes
1582   else
1583     libc_cv_z_combreloc=no
1584   fi
1585 else
1586   libc_cv_z_combreloc=no
1587 fi
1588 rm -f conftest*])
1589 if test "$libc_cv_z_combreloc" = yes; then
1590   AC_DEFINE(HAVE_Z_COMBRELOC)
1591 fi
1592 AC_SUBST(libc_cv_z_combreloc)
1593
1594 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1595                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1596 AC_SUBST(libc_cv_z_execstack)
1597
1598 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1599 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1600 ])
1601
1602 AC_SUBST(libc_cv_fpie)
1603
1604 AC_CACHE_CHECK(for --hash-style option,
1605                libc_cv_hashstyle, [dnl
1606 cat > conftest.c <<EOF
1607 int _start (void) { return 42; }
1608 EOF
1609 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1610                             -fPIC -shared -o conftest.so conftest.c
1611                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1612 then
1613   libc_cv_hashstyle=yes
1614 else
1615   libc_cv_hashstyle=no
1616 fi
1617 rm -f conftest*])
1618 AC_SUBST(libc_cv_hashstyle)
1619
1620 # The linker's default -shared behavior is good enough if it
1621 # does these things that our custom linker scripts ensure that
1622 # all allocated NOTE sections come first.
1623 if test "$use_default_link" = default; then
1624   AC_CACHE_CHECK([for sufficient default -shared layout],
1625                   libc_cv_use_default_link, [dnl
1626   libc_cv_use_default_link=no
1627   cat > conftest.s <<\EOF
1628           .section .note.a,"a",%note
1629           .balign 4
1630           .long 4,4,9
1631           .string "GNU"
1632           .string "foo"
1633           .section .note.b,"a",%note
1634           .balign 4
1635           .long 4,4,9
1636           .string "GNU"
1637           .string "bar"
1638 EOF
1639   if AC_TRY_COMMAND([dnl
1640   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1641        ac_try=`$READELF -S conftest.so | sed -n \
1642          ['${x;p;}
1643           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1644           t a
1645           b
1646           : a
1647           H']`
1648   then
1649     libc_seen_a=no libc_seen_b=no
1650     set -- $ac_try
1651     while test $# -ge 2 -a "$1" = NOTE; do
1652       case "$2" in
1653       .note.a) libc_seen_a=yes ;;
1654       .note.b) libc_seen_b=yes ;;
1655       esac
1656       shift 2
1657     done
1658     case "$libc_seen_a$libc_seen_b" in
1659     yesyes)
1660       libc_cv_use_default_link=yes
1661       ;;
1662     *)
1663       echo >&AS_MESSAGE_LOG_FD "\
1664 $libc_seen_a$libc_seen_b from:
1665 $ac_try"
1666       ;;
1667     esac
1668   fi
1669   rm -f conftest*])
1670   use_default_link=$libc_cv_use_default_link
1671 fi
1672
1673 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1674 if libc_cv_output_format=`
1675 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1676 then
1677   :
1678 else
1679   libc_cv_output_format=
1680 fi
1681 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1682 AC_SUBST(libc_cv_output_format)
1683
1684 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1685 cat > conftest.c <<EOF
1686 int foo;
1687 EOF
1688 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1689                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1690 then
1691   libc_cv_fno_toplevel_reorder=yes
1692 else
1693   libc_cv_fno_toplevel_reorder=no
1694 fi
1695 rm -f conftest*])
1696 if test $libc_cv_fno_toplevel_reorder = yes; then
1697   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1698 else
1699   fno_unit_at_a_time=-fno-unit-at-a-time
1700 fi
1701 AC_SUBST(fno_unit_at_a_time)
1702
1703 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1704 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1705                    [libc_cv_ssp=yes],
1706                    [libc_cv_ssp=no])
1707 ])
1708 AC_SUBST(libc_cv_ssp)
1709
1710 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1711 cat > conftest.c <<EOF
1712 int foo;
1713 #ifdef __GNUC_GNU_INLINE__
1714 main () { return 0;}
1715 #else
1716 #error
1717 #endif
1718 EOF
1719 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1720                             -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1721 then
1722   libc_cv_gnu89_inline=yes
1723 else
1724   libc_cv_gnu89_inline=no
1725 fi
1726 rm -f conftest*])
1727 if test $libc_cv_gnu89_inline = yes; then
1728   gnu89_inline=-fgnu89-inline
1729 else
1730   gnu89_inline=
1731 fi
1732 AC_SUBST(gnu89_inline)
1733
1734 AC_CACHE_CHECK(whether cc puts quotes around section names,
1735                libc_cv_have_section_quotes,
1736                [cat > conftest.c <<EOF
1737                 static const int foo
1738                 __attribute__ ((section ("bar"))) = 1;
1739 EOF
1740                 if ${CC-cc} -S conftest.c -o conftest.s; then
1741                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1742                     libc_cv_have_section_quotes=yes
1743                   else
1744                     libc_cv_have_section_quotes=no
1745                   fi
1746                 else
1747                   libc_cv_have_section_quotes=unknown
1748                 fi
1749                 rm -f conftest.{c,s}
1750                 ])
1751 if test $libc_cv_have_section_quotes = yes; then
1752   AC_DEFINE(HAVE_SECTION_QUOTES)
1753 fi
1754
1755 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1756                [dnl
1757 cat > conftest.s <<EOF
1758 ${libc_cv_dot_text}
1759 .globl foo
1760 foo:
1761 .weak foo
1762 .weak bar; bar = foo
1763 EOF
1764 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1765   libc_cv_asm_weak_directive=yes
1766 else
1767   libc_cv_asm_weak_directive=no
1768 fi
1769 rm -f conftest*])
1770
1771 if test $libc_cv_asm_weak_directive = no; then
1772   AC_CACHE_CHECK(for assembler .weakext directive,
1773                  libc_cv_asm_weakext_directive,
1774                  [dnl
1775 cat > conftest.s <<EOF
1776 ${libc_cv_dot_text}
1777 .globl foo
1778 foo:
1779 .weakext bar foo
1780 .weakext baz
1781 .globl baz
1782 baz:
1783 EOF
1784   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1785     libc_cv_asm_weakext_directive=yes
1786   else
1787     libc_cv_asm_weakext_directive=no
1788   fi
1789   rm -f conftest*])
1790
1791 fi # no .weak
1792
1793 if test $libc_cv_asm_weak_directive = yes; then
1794   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1795 elif test $libc_cv_asm_weakext_directive = yes; then
1796   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1797 fi
1798
1799 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1800 case $machine in
1801   sparc/sparc64*) cfi_offset=2047;;
1802   *) cfi_offset=0;;
1803 esac
1804 cat > conftest.s <<EOF
1805         .text
1806         .type   func,%function
1807 func:
1808         .cfi_startproc
1809         .cfi_remember_state
1810         .cfi_rel_offset 1, $cfi_offset
1811         .cfi_endproc
1812 EOF
1813 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1814   libc_cv_asm_cfi_directives=yes
1815 else
1816   libc_cv_asm_cfi_directives=no
1817 fi
1818 rm -f conftest*])
1819 if test $libc_cv_asm_cfi_directives = yes; then
1820   AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1821 fi
1822
1823 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1824 cat > conftest.c <<\EOF
1825 _start () {}
1826 int __eh_pc;
1827 __throw () {}
1828 EOF
1829 dnl No \ in command here because it ends up inside ''.
1830 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1831                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1832                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1833   libc_cv_ld_no_whole_archive=yes
1834 else
1835   libc_cv_ld_no_whole_archive=no
1836 fi
1837 rm -f conftest*])
1838 if test $libc_cv_ld_no_whole_archive = no; then
1839   AC_MSG_ERROR([support for --no-whole-archive is needed])
1840 fi
1841
1842 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1843 cat > conftest.c <<\EOF
1844 _start () {}
1845 int __eh_pc;
1846 __throw () {}
1847 EOF
1848 dnl No \ in command here because it ends up inside ''.
1849 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1850                             -nostdlib -nostartfiles -fexceptions
1851                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1852   libc_cv_gcc_exceptions=yes
1853 else
1854   libc_cv_gcc_exceptions=no
1855 fi
1856 rm -f conftest*])
1857 if test $libc_cv_gcc_exceptions = yes; then
1858   exceptions=-fexceptions
1859 fi
1860 AC_SUBST(exceptions)dnl
1861
1862 if test "$host_cpu" = powerpc ; then
1863 # Check for a bug present in at least versions 2.8.x of GCC
1864 # and versions 1.0.x of EGCS.
1865 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1866 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1867                libc_cv_c_asmcr0_bug='no',
1868                libc_cv_c_asmcr0_bug='yes')])
1869 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1870   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1871 fi
1872 fi
1873
1874 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1875 cat > conftest.c <<\EOF
1876 void zero (void *x)
1877 {
1878   __builtin_memset (x, 0, 1000);
1879 }
1880 EOF
1881 dnl
1882 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1883 then
1884   libc_cv_gcc_builtin_memset=no
1885 else
1886   libc_cv_gcc_builtin_memset=yes
1887 fi
1888 rm -f conftest* ])
1889 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1890   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1891 fi
1892
1893 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1894 cat > conftest.c <<\EOF
1895 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1896 char *foo (const char *a, const char *b)
1897 {
1898   return __builtin_strstr (a, b);
1899 }
1900 EOF
1901 dnl
1902 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1903 then
1904   libc_cv_gcc_builtin_redirection=yes
1905 else
1906   libc_cv_gcc_builtin_redirection=no
1907 fi
1908 rm -f conftest* ])
1909 if test "$libc_cv_gcc_builtin_redirection" = no; then
1910   AC_MSG_ERROR([support for the symbol redirection needed])
1911 fi
1912
1913 dnl Check whether the compiler supports the __thread keyword.
1914 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1915 [cat > conftest.c <<\EOF
1916 __thread int a = 42;
1917 EOF
1918 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1919   libc_cv_gcc___thread=yes
1920 else
1921   libc_cv_gcc___thread=no
1922 fi
1923 rm -f conftest*])
1924 if test "$libc_cv_gcc___thread" = no; then
1925   AC_MSG_ERROR([support for the __thread keyword is required])
1926 fi
1927
1928 dnl Check whether the compiler supports the tls_model attribute.
1929 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1930 cat > conftest.c <<\EOF
1931 extern __thread int a __attribute__((tls_model ("initial-exec")));
1932 EOF
1933 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
1934   libc_cv_gcc_tls_model_attr=yes
1935 else
1936   libc_cv_gcc_tls_model_attr=no
1937 fi
1938 rm -f conftest*])
1939 if test "$libc_cv_gcc_tls_model_attr" = no; then
1940   AC_MSG_ERROR([support for the tls_model attribute is required])
1941 fi
1942
1943 dnl Determine how to disable generation of FMA instructions.
1944 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1945                libc_cv_cc_nofma, [dnl
1946 libc_cv_cc_nofma=
1947 for opt in -ffp-contract=off -mno-fused-madd; do
1948   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1949 done])
1950 AC_SUBST(libc_cv_cc_nofma)
1951
1952 if test -n "$submachine"; then
1953   AC_CACHE_CHECK([for compiler option for CPU variant],
1954                  libc_cv_cc_submachine, [dnl
1955   libc_cv_cc_submachine=no
1956   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1957     LIBC_TRY_CC_OPTION([$opt], [
1958       libc_cv_cc_submachine="$opt"
1959       break], [])
1960   done])
1961   if test "x$libc_cv_cc_submachine" = xno; then
1962     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1963   fi
1964 fi
1965 AC_SUBST(libc_cv_cc_submachine)
1966
1967 dnl Check whether we have the gd library available.
1968 AC_MSG_CHECKING(for libgd)
1969 if test "$with_gd" != "no"; then
1970   old_CFLAGS="$CFLAGS"
1971   CFLAGS="$CFLAGS $libgd_include"
1972   old_LDFLAGS="$LDFLAGS"
1973   LDFLAGS="$LDFLAGS $libgd_ldflags"
1974   old_LIBS="$LIBS"
1975   LIBS="$LIBS -lgd -lpng -lz -lm"
1976   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1977   CFLAGS="$old_CFLAGS"
1978   LDFLAGS="$old_LDFLAGS"
1979   LIBS="$old_LIBS"
1980 else
1981   LIBGD=no
1982 fi
1983 AC_MSG_RESULT($LIBGD)
1984 AC_SUBST(LIBGD)
1985
1986 # SELinux detection
1987 if test x$with_selinux = xno ; then
1988   have_selinux=no;
1989 else
1990   # See if we have the SELinux library
1991   AC_CHECK_LIB(selinux, is_selinux_enabled,
1992                have_selinux=yes, have_selinux=no)
1993   # See if we have the SELinux header with the NSCD permissions in it.
1994   if test x$have_selinux = xyes ; then
1995     AC_MSG_CHECKING([for NSCD Flask permissions in selinux/av_permissions.h])
1996     AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
1997                     [#ifdef NSCD__SHMEMHOST
1998                      return 0;
1999                      #else
2000                      #error NSCD__SHMEMHOST not defined
2001                      #endif],
2002                     have_selinux=yes, have_selinux=no)
2003     AC_MSG_RESULT($have_selinux)
2004   fi
2005
2006   if test x$with_selinux = xyes ; then
2007     if test x$have_selinux = xno ; then
2008       AC_MSG_ERROR([SELinux explicitly required, but sufficiently recent SELinux library not found])
2009     fi
2010   fi
2011 fi
2012 # Check if we're building with SELinux support.
2013 if test "x$have_selinux" = xyes; then
2014   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
2015
2016   # See if we have the libaudit library
2017   AC_CHECK_LIB(audit, audit_log_user_avc_message,
2018                have_libaudit=yes, have_libaudit=no)
2019   if test "x$have_libaudit" = xyes; then
2020     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
2021   fi
2022   AC_SUBST(have_libaudit)
2023
2024   # See if we have the libcap library
2025   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
2026   if test "x$have_libcap" = xyes; then
2027     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
2028   fi
2029   AC_SUBST(have_libcap)
2030 fi
2031 AC_SUBST(have_selinux)
2032
2033 dnl check for the size of 'long double'.
2034 AC_CHECK_SIZEOF(long double, 0)
2035 sizeof_long_double=$ac_cv_sizeof_long_double
2036 AC_SUBST(sizeof_long_double)
2037
2038 CPPUNDEFS=
2039 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
2040 dnl Since we are building the implementations of the fortified functions here,
2041 dnl having the macro defined interacts very badly.
2042 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
2043 [AC_TRY_COMPILE([], [
2044 #ifdef _FORTIFY_SOURCE
2045 # error bogon
2046 #endif],
2047                 [libc_cv_predef_fortify_source=no],
2048                 [libc_cv_predef_fortify_source=yes])])
2049 if test $libc_cv_predef_fortify_source = yes; then
2050   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
2051 fi
2052 AC_SUBST(CPPUNDEFS)
2053
2054 dnl Check for silly hacked compilers inserting -fstack-protector.
2055 dnl This breaks badly for the early startup code we compile, since
2056 dnl the compiled code can refer to a magic machine-dependent location
2057 dnl for the canary value before we have sufficient setup for that to
2058 dnl work.  It's also questionable to build all of libc with this flag
2059 dnl even when you're doing that for most applications you build, since
2060 dnl libc's code is so heavily-used and performance-sensitive.  If we
2061 dnl ever really want to make that work, it should be enabled explicitly
2062 dnl in the libc build, not inherited from implicit compiler settings.
2063 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
2064                libc_cv_predef_stack_protector, [
2065 AC_TRY_COMPILE([extern void foobar (char *);],
2066                [char large_array[2048]; foobar (large_array);], [
2067 libc_undefs=`$NM -u conftest.o |
2068   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
2069     2>&AS_MESSAGE_LOG_FD` || {
2070   AC_MSG_ERROR([confusing output from $NM -u])
2071 }
2072 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
2073 # On some architectures, there are architecture-specific undefined
2074 # symbols (resolved by the linker), so filter out unknown symbols.
2075 # This will fail to produce the correct result if the compiler
2076 # defaults to -fstack-protector but this produces an undefined symbol
2077 # other than __stack_chk_fail.  However, compilers like that have not
2078 # been encountered in practice.
2079 libc_undefs=`echo "$libc_undefs" | egrep '^(foobar|__stack_chk_fail)$'`
2080 case "$libc_undefs" in
2081 foobar) libc_cv_predef_stack_protector=no ;;
2082 '__stack_chk_fail
2083 foobar') libc_cv_predef_stack_protector=yes ;;
2084 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
2085 esac],
2086                [AC_MSG_ERROR([test compilation failed])])
2087 ])
2088 libc_extra_cflags=
2089 if test $libc_cv_predef_stack_protector = yes; then
2090   libc_extra_cflags=-fno-stack-protector
2091 fi
2092 AC_SUBST(libc_extra_cflags)
2093
2094 ### End of automated tests.
2095 ### Now run sysdeps configure fragments.
2096
2097 # They also can set these variables.
2098 use_ldconfig=no
2099 ldd_rewrite_script=no
2100 libc_cv_sysconfdir=$sysconfdir
2101 libc_cv_localstatedir=$localstatedir
2102 libc_cv_gcc_unwind_find_fde=no
2103 libc_cv_idn=no
2104
2105 # Iterate over all the sysdep directories we will use, running their
2106 # configure fragments.
2107 for dir in $sysnames; do
2108   case $dir in
2109     /*) dest=$dir ;;
2110     *)  dest=$srcdir/$dir ;;
2111   esac
2112   if test -r $dest/configure; then
2113     AC_MSG_RESULT(running configure fragment for $dir)
2114     . $dest/configure
2115   fi
2116 done
2117
2118 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2119   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2120 fi
2121 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2122
2123 # A sysdeps configure fragment can reset this if IFUNC is not actually
2124 # usable even though the assembler knows how to generate the symbol type.
2125 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
2126   AC_DEFINE(HAVE_IFUNC)
2127 fi
2128
2129 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
2130 # configure fragment can override the value to prevent this AC_DEFINE.
2131 AC_SUBST(use_nscd)
2132 if test "x$use_nscd" != xno; then
2133   AC_DEFINE([USE_NSCD])
2134 fi
2135 if test "x$build_nscd" = xdefault; then
2136   build_nscd=$use_nscd
2137 fi
2138
2139 # Test for old glibc 2.0.x headers so that they can be removed properly
2140 # Search only in includedir.
2141 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2142 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2143 then
2144   old_glibc_headers=yes
2145 else
2146   old_glibc_headers=no
2147 fi
2148 AC_MSG_RESULT($old_glibc_headers)
2149 if test ${old_glibc_headers} = yes; then
2150   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2151   AC_MSG_WARN(*** be removed.)
2152 fi
2153 AC_SUBST(old_glibc_headers)
2154
2155 AC_SUBST(libc_cv_slibdir)
2156 AC_SUBST(libc_cv_rtlddir)
2157 AC_SUBST(libc_cv_localedir)
2158 AC_SUBST(libc_cv_sysconfdir)
2159 AC_SUBST(libc_cv_localstatedir)
2160 AC_SUBST(libc_cv_rootsbindir)
2161 AC_SUBST(libc_cv_forced_unwind)
2162
2163 if test x$use_ldconfig = xyes; then
2164   AC_DEFINE(USE_LDCONFIG)
2165 fi
2166 AC_SUBST(use_ldconfig)
2167 AC_SUBST(ldd_rewrite_script)
2168
2169 AC_SUBST(static)
2170 AC_SUBST(shared)
2171
2172 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2173 [libc_cv_pic_default=yes
2174 cat > conftest.c <<EOF
2175 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2176 # error PIC is default.
2177 #endif
2178 EOF
2179 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2180   libc_cv_pic_default=no
2181 fi
2182 rm -f conftest.*])
2183 AC_SUBST(libc_cv_pic_default)
2184
2185 AC_SUBST(profile)
2186 AC_SUBST(static_nss)
2187
2188 AC_SUBST(DEFINES)
2189
2190 dnl See sysdeps/mach/configure.in for this variable.
2191 AC_SUBST(mach_interface_list)
2192
2193 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2194 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2195 AC_SUBST(VERSION)
2196 AC_SUBST(RELEASE)
2197
2198 AC_CONFIG_FILES([config.make Makefile])
2199 AC_CONFIG_COMMANDS([default],[[
2200 case $CONFIG_FILES in *config.make*)
2201 echo "$config_vars" >> config.make;;
2202 esac
2203 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2204 AC_OUTPUT