sysdeps/i386/__longjmp.S

   1 /* longjmp for i386.
   2    Copyright (C) 1995-1998,2000,2002,2005 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #define _ASM
  22 #define _SETJMP_H
  23 #include <bits/setjmp.h>
  24 #include <asm-syntax.h>
  25 #include <bp-sym.h>
  26 #include <bp-asm.h>
  27
  28 #define PARMS   LINKAGE         /* no space for saved regs */
  29 #define JBUF    PARMS
  30 #define VAL     JBUF+PTR_SIZE
  31
  32 ENTRY (BP_SYM (__longjmp))
  33         ENTER
  34
  35 #ifdef PTR_DEMANGLE
  36         movl JBUF(%esp), %eax   /* User's jmp_buf in %eax.  */
  37         CHECK_BOUNDS_BOTH_WIDE (%eax, JBUF(%esp), $JB_SIZE)
  38
  39         /* Save the return address now.  */
  40         movl (JB_PC*4)(%eax), %edx
  41         /* Get the stack pointer.  */
  42         movl (JB_SP*4)(%eax), %ecx
  43         PTR_DEMANGLE (%edx)
  44         PTR_DEMANGLE (%ecx)
  45         cfi_def_cfa(%eax, 0)
  46         cfi_register(%eip, %edx)
  47         cfi_register(%esp, %ecx)
  48         cfi_offset(%ebx, JB_BX*4)
  49         cfi_offset(%esi, JB_SI*4)
  50         cfi_offset(%edi, JB_DI*4)
  51         cfi_offset(%ebp, JB_BP*4)
  52         /* Restore registers.  */
  53         movl (JB_BX*4)(%eax), %ebx
  54         movl (JB_SI*4)(%eax), %esi
  55         movl (JB_DI*4)(%eax), %edi
  56         movl (JB_BP*4)(%eax), %ebp
  57         cfi_restore(%ebx)
  58         cfi_restore(%esi)
  59         cfi_restore(%edi)
  60         cfi_restore(%ebp)
  61
  62         movl VAL(%esp), %eax    /* Second argument is return value.  */
  63         movl %ecx, %esp
  64 #else
  65         movl JBUF(%esp), %ecx   /* User's jmp_buf in %ecx.  */
  66         CHECK_BOUNDS_BOTH_WIDE (%ecx, JBUF(%esp), $JB_SIZE)
  67
  68         movl VAL(%esp), %eax    /* Second argument is return value.  */
  69         /* Save the return address now.  */
  70         movl (JB_PC*4)(%ecx), %edx
  71         /* Restore registers.  */
  72         movl (JB_BX*4)(%ecx), %ebx
  73         movl (JB_SI*4)(%ecx), %esi
  74         movl (JB_DI*4)(%ecx), %edi
  75         movl (JB_BP*4)(%ecx), %ebp
  76         movl (JB_SP*4)(%ecx), %esp
  77 #endif
  78         /* Jump to saved PC.  */
  79         jmp *%edx
  80 END (BP_SYM (__longjmp))