Update build-many-glibcs.py for binutils ia64 obsoletion.
[glibc.git] / sysdeps / i386 / start.S
blobc57b25f055b0b21d84fa192f7063d0d201494fe0
1 /* Startup code compliant to the ELF i386 ABI.
2    Copyright (C) 1995-2020 Free Software Foundation, Inc.
3    This file is part of the GNU C Library.
5    The GNU C Library is free software; you can redistribute it and/or
6    modify it under the terms of the GNU Lesser General Public
7    License as published by the Free Software Foundation; either
8    version 2.1 of the License, or (at your option) any later version.
10    In addition to the permissions in the GNU Lesser General Public
11    License, the Free Software Foundation gives you unlimited
12    permission to link the compiled version of this file with other
13    programs, and to distribute those programs without any restriction
14    coming from the use of this file. (The GNU Lesser General Public
15    License restrictions do apply in other respects; for example, they
16    cover modification of the file, and distribution when not linked
17    into another program.)
19    Note that people who make modified versions of this file are not
20    obligated to grant this special exception for their modified
21    versions; it is their choice whether to do so. The GNU Lesser
22    General Public License gives permission to release a modified
23    version without this exception; this exception also makes it
24    possible to release a modified version which carries forward this
25    exception.
27    The GNU C Library is distributed in the hope that it will be useful,
28    but WITHOUT ANY WARRANTY; without even the implied warranty of
29    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
30    Lesser General Public License for more details.
32    You should have received a copy of the GNU Lesser General Public
33    License along with the GNU C Library; if not, see
34    <https://www.gnu.org/licenses/>.  */
36 /* This is the canonical entry point, usually the first thing in the text
37    segment.  The SVR4/i386 ABI (pages 3-31, 3-32) says that when the entry
38    point runs, most registers' values are unspecified, except for:
40    %edx         Contains a function pointer to be registered with `atexit'.
41                 This is how the dynamic linker arranges to have DT_FINI
42                 functions called for shared libraries that have been loaded
43                 before this code runs.
45    %esp         The stack contains the arguments and environment:
46                 0(%esp)                 argc
47                 4(%esp)                 argv[0]
48                 ...
49                 (4*argc)(%esp)          NULL
50                 (4*(argc+1))(%esp)      envp[0]
51                 ...
52                                         NULL
55 #include <sysdep.h>
57 ENTRY (_start)
58         /* Clearing frame pointer is insufficient, use CFI.  */
59         cfi_undefined (eip)
60         /* Clear the frame pointer.  The ABI suggests this be done, to mark
61            the outermost frame obviously.  */
62         xorl %ebp, %ebp
64         /* Extract the arguments as encoded on the stack and set up
65            the arguments for `main': argc, argv.  envp will be determined
66            later in __libc_start_main.  */
67         popl %esi               /* Pop the argument count.  */
68         movl %esp, %ecx         /* argv starts just at the current stack top.*/
70         /* Before pushing the arguments align the stack to a 16-byte
71         (SSE needs 16-byte alignment) boundary to avoid penalties from
72         misaligned accesses.  Thanks to Edward Seidl <seidl@janed.com>
73         for pointing this out.  */
74         andl $0xfffffff0, %esp
75         pushl %eax              /* Push garbage because we allocate
76                                    28 more bytes.  */
78         /* Provide the highest stack address to the user code (for stacks
79            which grow downwards).  */
80         pushl %esp
82         pushl %edx              /* Push address of the shared library
83                                    termination function.  */
85 #ifdef PIC
86         /* Load PIC register.  */
87         call 1f
88         addl $_GLOBAL_OFFSET_TABLE_, %ebx
90         /* Push address of our own entry points to .fini and .init.  */
91         leal __libc_csu_fini@GOTOFF(%ebx), %eax
92         pushl %eax
93         leal __libc_csu_init@GOTOFF(%ebx), %eax
94         pushl %eax
96         pushl %ecx              /* Push second argument: argv.  */
97         pushl %esi              /* Push first argument: argc.  */
99 # ifdef SHARED
100         pushl main@GOT(%ebx)
101 # else
102         /* Avoid relocation in static PIE since _start is called before
103            it is relocated.  Don't use "leal main@GOTOFF(%ebx), %eax"
104            since main may be in a shared object.  Linker will convert
105            "movl main@GOT(%ebx), %eax" to "leal main@GOTOFF(%ebx), %eax"
106            if main is defined locally.  */
107         movl main@GOT(%ebx), %eax
108         pushl %eax
109 # endif
111         /* Call the user's main function, and exit with its value.
112            But let the libc call main.    */
113         call __libc_start_main@PLT
114 #else
115         /* Push address of our own entry points to .fini and .init.  */
116         pushl $__libc_csu_fini
117         pushl $__libc_csu_init
119         pushl %ecx              /* Push second argument: argv.  */
120         pushl %esi              /* Push first argument: argc.  */
122         pushl $main
124         /* Call the user's main function, and exit with its value.
125            But let the libc call main.    */
126         call __libc_start_main
127 #endif
129         hlt                     /* Crash if somehow `exit' does return.  */
131 #ifdef PIC
132 1:      movl    (%esp), %ebx
133         ret
134 #endif
135 END (_start)
137 /* To fulfill the System V/i386 ABI we need this symbol.  Yuck, it's so
138    meaningless since we don't support machines < 80386.  */
139         .section .rodata
140         .globl _fp_hw
141 _fp_hw: .long 3
142         .size _fp_hw, 4
143         .type _fp_hw,@object
145 /* Define a symbol for the first piece of initialized data.  */
146         .data
147         .globl __data_start
148 __data_start:
149         .long 0
150         .weak data_start
151         data_start = __data_start