configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.13)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  23 AC_ARG_WITH(gettext, dnl
  24   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  25             [dnl
  26 case "$with_gettext" in
  27 yes)
  28   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  29 ''|no) ;;
  30 *)
  31   config_vars="$config_vars
  32 gettext-srcdir = $withval" ;;
  33 esac
  34 ])
  35 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  36 AC_ARG_WITH(gd, dnl
  37   --with-gd=DIR           find libgd include dir and library with prefix DIR,
  38             [dnl
  39 case "$with_gd" in
  40 yes|''|no) ;;
  41 *) libgd_include="-I$withval/include"
  42    libgd_ldflags="-L$withval/lib" ;;
  43 esac
  44 ])
  45 AC_ARG_WITH(gd-include, dnl
  46   --with-gd-include=DIR   find libgd include files in DIR,
  47             [dnl
  48 case "$with_gd_include" in
  49 ''|no) ;;
  50 *) libgd_include="-I$withval" ;;
  51 esac
  52 ])
  53 AC_ARG_WITH(gd-lib, dnl
  54   --with-gd-lib=DIR       find libgd library files in DIR,
  55             [dnl
  56 case "$with_gd_lib" in
  57 ''|no) ;;
  58 *) libgd_ldflags="-L$withval" ;;
  59 esac
  60 ])
  61
  62 if test -n "$libgd_include"; then
  63   config_vars="$config_vars
  64 CFLAGS-memprofstat.c = $libgd_include"
  65 fi
  66 if test -n "$libgd_ldflags"; then
  67   config_vars="$config_vars
  68 libgd-LDFLAGS = $libgd_ldflags"
  69 fi
  70
  71 dnl Arguments to specify presence of other packages/features.
  72 AC_ARG_WITH(fp, dnl
  73 [  --with-fp              if using floating-point hardware [default=yes]],
  74             with_fp=$withval, with_fp=yes)
  75 AC_ARG_WITH(binutils, dnl
  76   --with-binutils=PATH    specify location of binutils (as and ld),
  77             path_binutils=$withval, path_binutils='')
  78 AC_ARG_WITH(elf, dnl
  79   --with-elf              if using the ELF object format,
  80             elf=$withval, elf=no)
  81 AC_ARG_WITH(cvs, dnl
  82 [  --without-cvs          if CVS should not be used],
  83             with_cvs=$withval, with_cvs=yes)
  84 AC_SUBST(with_cvs)
  85
  86 AC_ARG_WITH(headers, dnl
  87 [  --with-headers=PATH     location of system headers to use
  88                           [e.g. /usr/src/linux/include]
  89                           [default=compiler default]],
  90             sysheaders=$withval, sysheaders='')
  91
  92 AC_ARG_ENABLE(libio, dnl
  93 [  --enable-libio          build in GNU libio instead of GNU stdio],
  94               [if test $enableval = yes; then
  95                  stdio=libio
  96                else
  97                  stdio=stdio
  98                fi],
  99               stdio=default)
 100
 101 AC_ARG_ENABLE(sanity-checks, dnl
 102 [  --disable-sanity-checks really do not use threads (should not be used
 103                           except in special situations) [default=yes]],
 104               enable_sanity=$enableval, enable_sanity=yes)
 105
 106 dnl Arguments to enable or disable building the static, shared, profiled,
 107 dnl and -fomit-frame-pointer libraries.
 108 dnl I've disabled this for now since we cannot build glibc without static
 109 dnl libraries built in the moment.
 110 dnl AC_ARG_ENABLE(static, dnl
 111 dnl [  --enable-static         build static library [default=yes]],
 112 dnl           static=$enableval, static=yes)
 113 static=yes
 114 AC_ARG_ENABLE(shared, dnl
 115 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
 116               shared=$enableval, shared=default)
 117 AC_ARG_ENABLE(profile, dnl
 118 [  --enable-profile        build profiled library [default=yes]],
 119               profile=$enableval, profile=yes)
 120 AC_ARG_ENABLE(omitfp, dnl
 121 [  --enable-omitfp         build undebuggable optimized library [default=no]],
 122               omitfp=$enableval, omitfp=no)
 123 AC_ARG_ENABLE(bounded, dnl
 124 [  --enable-bounded        build with runtime bounds checking [default=no]],
 125               bounded=$enableval, bounded=no)
 126 AC_ARG_ENABLE(versioning, dnl
 127 [  --disable-versioning    do not include versioning information in the
 128                           library objects [default=yes if supported]],
 129              enable_versioning=$enableval, enable_versioning=yes)
 130
 131 dnl Generic infrastructure for drop-in additions to libc.
 132 AC_ARG_ENABLE(add-ons, dnl
 133 [  --enable-add-ons[=DIR1,DIR2]...
 134                           configure and build add-ons in DIR1,DIR2,...
 135                           search for add-ons if no parameter given],
 136   [case "$enableval" in
 137     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 138          test "$add_ons" = "*" && add_ons= ;;
 139     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 140    esac],
 141   [add_ons=])
 142
 143 AC_CONFIG_SUBDIRS($add_ons)
 144 add_ons_pfx=
 145 if test x"$add_ons" != x; then
 146   for f in $add_ons; do
 147     # Test whether such a subdir really exists.
 148     if test -d $srcdir/$f; then
 149       add_ons_pfx="$add_ons_pfx $f/"
 150     else
 151       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 152     fi
 153   done
 154 fi
 155
 156 dnl On some platforms we cannot use dynamic loading.  We must provide
 157 dnl static NSS modules.
 158 AC_ARG_ENABLE(static-nss, dnl
 159 [  --enable-static-nss     build static NSS modules [default=no]],
 160               static_nss=$enableval, static_nss=no)
 161 if test x"$static_nss" = xyes; then
 162   AC_DEFINE(DO_STATIC_NSS)
 163 fi
 164
 165 AC_ARG_ENABLE(force-install,
 166 [  --disable-force-install don't force installation of files from this package,
 167                           even if they are older than the installed files],
 168               force_install=$enableval, force_install=yes)
 169 AC_SUBST(force_install)
 170
 171 dnl On some platforms we allow dropping compatibility with all kernel
 172 dnl versions.
 173 AC_ARG_ENABLE(kernel,
 174 [  --enable-kernel=VERSION compile for compatibility with kernel not older
 175                            than VERSION],
 176               minimum_kernel=$enableval)
 177 dnl Prevent unreasonable values.
 178 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 179   # Better nothing than this.
 180   minimum_kernel=""
 181 fi
 182
 183 AC_CANONICAL_HOST
 184
 185 # The way shlib-versions is used to generate soversions.mk uses a
 186 # fairly simplistic model for name recognition that can't distinguish
 187 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 188 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 189 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 190 case "$host_os" in
 191 linux*)
 192   ;;
 193 gnu*)
 194   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 195   ;;
 196 esac
 197
 198 # We keep the original values in `$config_*' and never modify them, so we
 199 # can write them unchanged into config.make.  Everything else uses
 200 # $machine, $vendor, and $os, and changes them whenever convenient.
 201 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 202
 203 # Some configurations imply other options.
 204 case "$host_os" in
 205 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 206   # These systems always use GNU tools.
 207   gnu_ld=yes gnu_as=yes ;;
 208 esac
 209 case "$host_os" in
 210 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 211 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 212   ;;
 213 gnu* | linux* | sysv4* | solaris2* | irix6*)
 214   # These systems (almost) always use the ELF format.
 215   elf=yes
 216   ;;
 217 esac
 218
 219 machine=$config_machine
 220 vendor=$config_vendor
 221 os=$config_os
 222
 223 ###
 224 ### I put this here to prevent those annoying emails from people who cannot
 225 ### read and try to compile glibc on unsupported platforms.  --drepper
 226 ###
 227 ### By using the undocumented --enable-hacker-mode option for configure
 228 ### one can skip this test to make the configuration not fail for unsupported
 229 ### platforms.
 230 ###
 231 if test -z "$enable_hacker_mode"; then
 232   case "$machine-$host_os" in
 233   *-linux* | *-gnu* | arm*-none*)
 234     ;;
 235   *)
 236     echo "*** The GNU C library is currently not available for this platform."
 237     echo "*** So far nobody cared to port it and if there is no volunteer it"
 238     echo "*** might never happen.  So, if you have interest to see glibc on"
 239     echo "*** this platform visit"
 240     echo "***   http://www.gnu.org/software/libc/porting.html"
 241     echo "*** and join the group of porters"
 242     exit 1
 243     ;;
 244   esac
 245 fi
 246
 247 dnl We need to use [ and ] for other purposes for a while now.
 248 changequote(,)dnl
 249 # Expand the configuration machine name into a subdirectory by architecture
 250 # type and particular chip.
 251 case "$machine" in
 252 a29k | am29000) base_machine=a29k machine=a29k ;;
 253 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 254 arm*)           base_machine=arm machine=arm/$machine ;;
 255 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 256 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 257 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 258 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 259 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 260 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 261 m88???)         base_machine=m88k machine=m88k/$machine ;;
 262 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 263 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 264 mips*)          base_machine=mips
 265                 case "`uname -m`" in
 266                 IP22) machine=mips/mips3 ;;
 267                 *)    machine=mips/$machine ;;
 268                 esac ;;
 269 sparc | sparcv[67])
 270                 base_machine=sparc machine=sparc/sparc32 ;;
 271 sparcv8 | supersparc | hypersparc)
 272                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 273 sparcv8plus | sparcv8plusa | sparcv9)
 274                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 275 sparc64 | ultrasparc)
 276                 base_machine=sparc machine=sparc/sparc64 ;;
 277 esac
 278 changequote([,])dnl
 279 AC_SUBST(base_machine)
 280
 281 if test "$base_machine" = "i386"; then
 282   AC_DEFINE(USE_REGPARMS)
 283 fi
 284
 285 # Compute the list of sysdep directories for this configuration.
 286 # This can take a while to compute.
 287 sysdep_dir=$srcdir/sysdeps
 288 AC_MSG_CHECKING(sysdep dirs)
 289 dnl We need to use [ and ] for other purposes for a while now.
 290 changequote(,)dnl
 291 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 292 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 293
 294 case "$os" in
 295 gnu*)
 296   base_os=mach/hurd ;;
 297 netbsd* | 386bsd* | freebsd* | bsdi*)
 298   base_os=unix/bsd/bsd4.4 ;;
 299 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 300   base_os=unix/bsd ;;
 301 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 302   base_os=unix/sysv ;;
 303 irix6*)
 304   base_os=unix/sysv/irix6/$os ;;
 305 solaris[2-9]*)
 306   base_os=unix/sysv/sysv4 ;;
 307 hpux*)
 308   base_os=unix/sysv/hpux/$os ;;
 309 none)
 310   base_os=standalone ;;
 311 *)
 312   base_os='' ;;
 313 esac
 314
 315 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 316 tail=$os
 317 ostry=$os
 318 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 319   ostry="$ostry /$o"
 320   tail=$o
 321 done
 322 o=`echo $tail | sed 's/[0-9]*$//'`
 323 if test $o != $tail; then
 324   ostry="$ostry /$o"
 325 fi
 326 # For linux-gnu, try linux-gnu, then linux.
 327 o=`echo $tail | sed 's/-.*$//'`
 328 if test $o != $tail; then
 329   ostry="$ostry /$o"
 330 fi
 331
 332 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 333 base=
 334 tail=$base_os
 335 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 336   set $b
 337   base="$base /$1"
 338   tail="$2"
 339 done
 340
 341 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 342 mach=
 343 tail=$machine
 344 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 345   set $m
 346   # Prepend the machine's FPU directory unless --without-fp.
 347   if test "$with_fp" = yes; then
 348     mach="$mach /$1/fpu"
 349   fi
 350   mach="$mach /$1"
 351   tail="$2"
 352 done
 353
 354 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 355 changequote([,])dnl
 356
 357 # Find what sysdep directories exist.
 358 sysnames=
 359 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 360 for d in $add_ons_pfx ''; do
 361   for b in $base ''; do
 362     for m0 in $mach ''; do
 363       for v in /$vendor ''; do
 364         test "$v" = / && continue
 365         for o in /$ostry ''; do
 366           test "$o" = / && continue
 367           for m in $mach ''; do
 368             if test "$m0$b$v$o$m"; then
 369               try="${d}sysdeps$m0$b$v$o$m"
 370               test -n "$enable_debug_configure" &&
 371               echo "$0 [DEBUG]: try $try" >&2
 372               if test -d $srcdir/$try; then
 373                 sysnames="$sysnames $try"
 374                 { test -n "$o" || test -n "$b"; } && os_used=t
 375                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 376               fi
 377             fi
 378           done
 379         done
 380       done
 381     done
 382   done
 383 done
 384 IFS="$ac_save_ifs"
 385
 386 if test -z "$os_used" && test "$os" != none; then
 387   AC_MSG_ERROR(Operating system $os is not supported.)
 388 fi
 389 if test -z "$machine_used" && test "$machine" != none; then
 390   AC_MSG_ERROR(The $machine is not supported.)
 391 fi
 392
 393 # We have now validated the configuration.
 394
 395
 396 # If using ELF, look for an `elf' subdirectory of each machine directory.
 397 # We prepend these rather than inserting them whereever the machine appears
 398 # because things specified by the machine's ELF ABI should override
 399 # OS-specific things, and should always be the same for any OS on the
 400 # machine (otherwise what's the point of an ABI?).
 401 if test "$elf" = yes; then
 402   elf_dirs=
 403   for d in $add_ons_pfx ''; do
 404     for m in $mach; do
 405       if test -d $srcdir/${d}sysdeps$m/elf; then
 406         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 407       fi
 408     done
 409   done
 410   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 411 fi
 412
 413
 414 # Expand the list of system names into a full list of directories
 415 # from each element's parent name and Implies file (if present).
 416 set $sysnames
 417 names=
 418 while test $# -gt 0; do
 419   name=$1
 420   shift
 421
 422   case " $names " in *" $name "*)
 423     # Already in the list.
 424     continue
 425   esac
 426
 427   # Report each name as we discover it, so there is no long pause in output.
 428   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 429
 430   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 431
 432   case $name in
 433     /*) xsrcdir= ;;
 434     *)  xsrcdir=$srcdir/ ;;
 435   esac
 436   test -n "$enable_debug_configure" &&
 437   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 438
 439   if test -f $xsrcdir$name/Implies; then
 440     # Collect more names from the `Implies' file (removing comments).
 441     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 442     implied=
 443     for x in $implied_candidate; do
 444       if test -d $xsrcdir$name_base/$x; then
 445         implied="$implied $name_base/$x";
 446       else
 447         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 448       fi
 449     done
 450   else
 451     implied=
 452   fi
 453
 454   # Add NAME to the list of names.
 455   names="$names $name"
 456
 457   # Find the parent of NAME, using the empty string if it has none.
 458 changequote(,)dnl
 459   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 460 changequote([,])dnl
 461
 462   # Add the names implied by NAME, and NAME's parent (if it has one), to
 463   # the list of names to be processed (the argument list).  We prepend the
 464   # implied names to the list and append the parent.  We want implied
 465   # directories to come before further directories inferred from the
 466   # configuration components; this ensures that for sysv4, unix/common
 467   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 468   # after sysv4).
 469   sysnames="`echo $implied $* $parent`"
 470   test -n "$sysnames" && set $sysnames
 471 done
 472
 473 # Add the default directories.
 474 default_sysnames=sysdeps/generic
 475 if test "$elf" = yes; then
 476   default_sysnames="sysdeps/generic/elf $default_sysnames"
 477 fi
 478 sysnames="$names $default_sysnames"
 479 AC_SUBST(sysnames)
 480 # The other names were emitted during the scan.
 481 AC_MSG_RESULT($default_sysnames)
 482
 483
 484 ### Locate tools.
 485
 486 AC_PROG_INSTALL
 487 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 488   # The makefiles need to use a different form to find it in $srcdir.
 489   INSTALL='\$(..)./scripts/install-sh -c'
 490 fi
 491 AC_PROG_LN_S
 492
 493 # These programs are version sensitive.
 494 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 495 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 496   [version \([egcygnustp-]*[0-9.]*\)],
 497   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|*gcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|2.9[5-9]*|cygnus-2.9[1-9]*|gcc-2.9[5-9]|gcc-2.1[0-9][0-9]],
 498   critic_missing=t)
 499 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 500   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 501   [3.75 | 3.76.[1-9]* | 3.7[789]* | 3.[89]*], critic_missing=t)
 502
 503 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 504   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 505   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 506 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 507   [GNU texinfo.* \([0-9][0-9.]*\)],
 508   [3.1[1-9] | 3.[2-9][0-9] | 4.* | 1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t)
 509
 510 if test -n "$critic_missing"; then
 511 AC_MSG_ERROR([
 512 *** Some critical program is missing or too old.
 513 *** Check the INSTALL file for required versions.])
 514 fi
 515
 516 test -n "$aux_missing" && AC_MSG_WARN([
 517 *** An auxiliary program is missing or too old;
 518 *** some features will be disabled.
 519 *** Check the INSTALL file for required versions.])
 520
 521 # glibcbug.in wants to know the compiler version.
 522 CCVERSION=`$CC -v 2>&1 | sed -n 's/gcc version //p'`
 523 AC_SUBST(CCVERSION)
 524
 525 AC_PROG_CC_LOCAL
 526 AC_CANONICAL_BUILD
 527 if test $host != $build; then
 528   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 529 fi
 530 AC_SUBST(cross_compiling)
 531 AC_PROG_CPP
 532 LIBC_PROG_BINUTILS
 533 AC_CHECK_TOOL(MIG, mig)
 534
 535 # if using special system headers, find out the compiler's sekrit
 536 # header directory and add that to the list.  NOTE: Only does the right
 537 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 538 if test -n "$sysheaders"; then
 539   ccheaders=`$CC -print-file-name=include`
 540   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 541 fi
 542 AC_SUBST(SYSINCLUDES)
 543
 544 # check if ranlib is necessary
 545 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 546 cat > conftest.c <<EOF
 547 int a;
 548 char b;
 549 void c(void) {}
 550 EOF
 551 $CC $CFLAGS -c conftest.c
 552 $AR cr conftest.a conftest.c
 553 cp conftest.a conftest2.a
 554 $RANLIB conftest.a
 555 if cmp -s conftest.a conftest2.a; then
 556   libc_cv_ranlib_necessary=no
 557 else
 558   libc_cv_ranlib_necessary=yes
 559 fi
 560 rm -rf conftest*])
 561 if test "$libc_cv_ranlib_necessary" = no; then
 562  RANLIB=:
 563 fi
 564
 565 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 566 # since this would lead to problems installing/building glibc.
 567 # LD_LIBRARY_PATH contains the current directory if one of the following
 568 # is true:
 569 # - one of the terminals (":" and ";") is the first or last sign
 570 # - two terminals occur directly after each other
 571 # - the path contains an element with a dot in it
 572 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 573 changequote(,)dnl
 574 case ${LD_LIBRARY_PATH} in
 575   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 576     ld_library_path_setting="contains current directory"
 577     ;;
 578   *)
 579     ld_library_path_setting="ok"
 580     ;;
 581 esac
 582 changequote([,])dnl
 583 AC_MSG_RESULT($ld_library_path_setting)
 584 if test "$ld_library_path_setting" != "ok"; then
 585 AC_MSG_ERROR([
 586 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 587 *** building glibc. Please change the environment variable
 588 *** and run configure again.])
 589 fi
 590
 591 AC_PATH_PROG(BASH, bash, no)
 592 if test "$BASH" != no &&
 593    $BASH -c 'test "$BASH_VERSINFO" \
 594              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 595   libc_cv_have_bash2=yes
 596 else
 597   libc_cv_have_bash2=no
 598 fi
 599 AC_SUBST(libc_cv_have_bash2)
 600
 601 dnl We need a ksh compatible shell for tzselect.
 602 if test "$BASH" = no; then
 603   AC_PATH_PROG(KSH, ksh, no)
 604   if test "$KSH" = no; then
 605     libc_cv_have_ksh=no
 606   else
 607     libc_cv_have_ksh=yes
 608   fi
 609 else
 610   KSH="$BASH"
 611   AC_SUBST(KSH)
 612   libc_cv_have_ksh=yes
 613 fi
 614 AC_SUBST(libc_cv_have_ksh)
 615
 616 AC_PROG_AWK
 617 AC_PATH_PROG(PERL, perl, no)
 618 AC_SUBST(PERL)
 619 AC_PATH_PROG(INSTALL_INFO, install-info, no,
 620              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
 621 AC_SUBST(INSTALL_INFO)
 622 if test "$INSTALL_INFO" != "no"; then
 623 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 624  [mkdir conftest.d
 625   # There is a hard ^_ on the next line.  I am open to better ideas.
 626   (echo '\x1f'
 627   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 628   echo '* Menu:') >conftest.d/dir
 629   (echo 'INFO-DIR-SECTION i-d-s works'
 630   echo 'START-INFO-DIR-ENTRY'
 631   echo '* Prog: (prog).   Program.'
 632   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 633   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 634   then
 635     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 636     then libc_cv_old_debian_install_info=no
 637     else libc_cv_old_debian_install_info=yes
 638     fi
 639   else libc_cv_old_debian_install_info=no testfailed=t
 640   fi
 641   rm -fr conftest.d])
 642 if test -n "$testfailed"
 643 then AC_MSG_WARN([install-info errored out, check config.log])
 644 fi
 645 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 646 fi
 647 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 648
 649 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 650 echo '#include <stddef.h>
 651 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 652 if eval "$ac_cpp conftest.c 2>/dev/null" \
 653 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 654   libc_cv_signed_size_t=no
 655 else
 656   libc_cv_signed_size_t=yes
 657 fi
 658 rm -f conftest*])
 659 if test $libc_cv_signed_size_t = yes; then
 660   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 661   cat >> confdefs.h <<\EOF
 662 #undef __SIZE_TYPE__
 663 #define __SIZE_TYPE__ unsigned
 664 EOF
 665 fi
 666
 667 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 668 AC_TRY_COMPILE(dnl
 669 [#define __need_size_t
 670 #define __need_wchar_t
 671 #include <stddef.h>
 672 #define __need_NULL
 673 #include <stddef.h>], [size_t size; wchar_t wchar;
 674 #ifdef offsetof
 675 #error stddef.h ignored __need_*
 676 #endif
 677 if (&size == NULL || &wchar == NULL) abort ();],
 678                libc_cv_friendly_stddef=yes,
 679                libc_cv_friendly_stddef=no)])
 680 if test $libc_cv_friendly_stddef = yes; then
 681   config_vars="$config_vars
 682 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 683 fi
 684
 685 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 686                libc_cv_need_minus_P, [dnl
 687 cat > conftest.S <<EOF
 688 #include "confdefs.h"
 689 /* Nothing whatsoever.  */
 690 EOF
 691 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 692   libc_cv_need_minus_P=no
 693 else
 694   libc_cv_need_minus_P=yes
 695 fi
 696 rm -f conftest*])
 697 if test $libc_cv_need_minus_P = yes; then
 698   config_vars="$config_vars
 699 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 700 fi
 701
 702 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 703 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 704 cat > conftest.s <<EOF
 705 .text
 706 EOF
 707 libc_cv_dot_text=
 708 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 709   libc_cv_dot_text=.text
 710 fi
 711 rm -f conftest*])
 712 if test -z "$libc_cv_dot_text"; then
 713   AC_MSG_RESULT(no)
 714 else
 715   AC_MSG_RESULT(yes)
 716 fi
 717
 718 AC_CACHE_CHECK(for assembler global-symbol directive,
 719                libc_cv_asm_global_directive, [dnl
 720 libc_cv_asm_global_directive=UNKNOWN
 721 for ac_globl in .globl .global .EXPORT; do
 722   cat > conftest.s <<EOF
 723         ${libc_cv_dot_text}
 724         ${ac_globl} foo
 725 foo:
 726 EOF
 727   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 728     libc_cv_asm_global_directive=${ac_globl}
 729   fi
 730   rm -f conftest*
 731   test $libc_cv_asm_global_directive != UNKNOWN && break
 732 done])
 733 if test $libc_cv_asm_global_directive = UNKNOWN; then
 734   AC_MSG_ERROR(cannot determine asm global directive)
 735 else
 736   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 737 fi
 738
 739 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 740 cat > conftest.s <<EOF
 741 ${libc_cv_dot_text}
 742 foo:
 743 .set glibc_conftest_frobozz,foo
 744 $libc_cv_asm_global_directive glibc_conftest_frobozz
 745 EOF
 746 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 747 # (but it doesn't work), so we must do a linking check to be sure.
 748 cat > conftest1.c <<\EOF
 749 extern int glibc_conftest_frobozz;
 750 main () { printf ("%d\n", glibc_conftest_frobozz); }
 751 EOF
 752 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 753             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 754   libc_cv_asm_set_directive=yes
 755 else
 756   libc_cv_asm_set_directive=no
 757 fi
 758 rm -f conftest*])
 759 if test $libc_cv_asm_set_directive = yes; then
 760   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 761 fi
 762
 763 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 764 [cat > conftest.s <<EOF
 765 ${libc_cv_dot_text}
 766 _sym:
 767 .symver _sym,sym@VERS
 768 EOF
 769 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 770   libc_cv_asm_symver_directive=yes
 771 else
 772   libc_cv_asm_symver_directive=no
 773 fi
 774 rm -f conftest*])
 775 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 776 if test $libc_cv_asm_symver_directive = yes; then
 777   cat > conftest.s <<EOF
 778 ${libc_cv_dot_text}
 779 _sym:
 780 .symver _sym,sym@VERS
 781 EOF
 782   cat > conftest.map <<EOF
 783 VERS_1 {
 784         global: sym;
 785 };
 786
 787 VERS_2 {
 788         global: sym;
 789 } VERS_1;
 790 EOF
 791   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 792     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 793                                         -nostartfiles -nostdlib
 794                                         -Wl,--version-script,conftest.map
 795                        1>&AC_FD_CC]);
 796     then
 797       libc_cv_ld_version_script_option=yes
 798     else
 799       libc_cv_ld_version_script_option=no
 800     fi
 801   else
 802     libc_cv_ld_version_script_option=no
 803   fi
 804 else
 805   libc_cv_ld_version_script_option=no
 806 fi
 807 rm -f conftest*])
 808 if test $libc_cv_asm_symver_directive = yes &&
 809    test $libc_cv_ld_version_script_option = yes &&
 810    test $enable_versioning = yes; then
 811   VERSIONING=yes
 812   AC_DEFINE(DO_VERSIONING)
 813 else
 814   VERSIONING=no
 815 fi
 816 AC_SUBST(VERSIONING)
 817
 818 if test $VERSIONING = no; then
 819   echo "\
 820 *** WARNING: You should not compile GNU libc without versioning. Not using
 821 *** versioning will introduce incompatibilities so that old binaries
 822 *** will not run anymore.
 823 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 824 fi
 825 if test $elf = yes; then
 826   AC_CACHE_CHECK(for .previous assembler directive,
 827                  libc_cv_asm_previous_directive, [dnl
 828   cat > conftest.s <<EOF
 829 .section foo_section
 830 .previous
 831 EOF
 832   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 833     libc_cv_asm_previous_directive=yes
 834   else
 835     libc_cv_asm_previous_directive=no
 836   fi
 837   rm -f conftest*])
 838   if test $libc_cv_asm_previous_directive = yes; then
 839     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 840   else
 841     AC_CACHE_CHECK(for .popsection assembler directive,
 842                    libc_cv_asm_popsection_directive, [dnl
 843     cat > conftest.s <<EOF
 844 .pushsection foo_section
 845 .popsection
 846 EOF
 847     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 848       libc_cv_asm_popsection_directive=yes
 849     else
 850       libc_cv_asm_popsection_directive=no
 851     fi
 852     rm -f conftest*])
 853     if test $libc_cv_asm_popsection_directive = yes; then
 854       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 855     fi
 856   fi
 857 fi
 858
 859 if test $elf != yes; then
 860   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 861                  [AC_TRY_COMPILE(, [asm (".section .init");
 862                                     asm (".section .fini");
 863                                     asm ("${libc_cv_dot_text}");],
 864                                  libc_cv_have_initfini=yes,
 865                                  libc_cv_have_initfini=no)])
 866   AC_SUBST(libc_cv_have_initfini)dnl
 867   if test $libc_cv_have_initfini = yes; then
 868     AC_DEFINE(HAVE_INITFINI)
 869   fi
 870 fi
 871
 872 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 873 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 874 [cat > conftest.$ac_ext <<EOF
 875 dnl This sometimes fails to find confdefs.h, for some reason.
 876 dnl [#]line __oline__ "[$]0"
 877 [#]line __oline__ "configure"
 878 #include "confdefs.h"
 879 void underscore_test(void) {
 880 return; }
 881 EOF
 882 if AC_TRY_EVAL(ac_compile); then
 883   if grep _underscore_test conftest* >/dev/null; then
 884     ifelse([$1], , :, [rm -f conftest*
 885     $1])
 886   else
 887     ifelse([$2], , , [rm -f conftest*
 888     $2])
 889   fi
 890 else
 891   echo "configure: failed program was:" >&AC_FD_CC
 892   cat conftest.$ac_ext >&AC_FD_CC
 893   ifelse([$2], , , [rm -f conftest*
 894   $2])
 895 fi
 896 rm -f conftest*])
 897
 898 if test $elf = yes; then
 899   libc_cv_asm_underscores=no
 900 else
 901   if test $ac_cv_prog_cc_works = yes; then
 902     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 903                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 904                                 libc_cv_asm_underscores=yes,
 905                                 libc_cv_asm_underscores=no)])
 906   else
 907     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 908                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 909                                             libc_cv_asm_underscores=no)])
 910   fi
 911 fi
 912 if test $libc_cv_asm_underscores = no; then
 913   AC_DEFINE(NO_UNDERSCORES)
 914 fi
 915
 916 if test $elf = yes; then
 917   libc_cv_weak_symbols=yes
 918 fi
 919
 920 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 921                  [dnl
 922 cat > conftest.s <<EOF
 923 ${libc_cv_dot_text}
 924 ${libc_cv_asm_global_directive} foo
 925 foo:
 926 .weak foo
 927 .weak bar; bar = foo
 928 EOF
 929 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 930   libc_cv_asm_weak_directive=yes
 931 else
 932   libc_cv_asm_weak_directive=no
 933 fi
 934 rm -f conftest*])
 935
 936 if test $libc_cv_asm_weak_directive = no; then
 937   AC_CACHE_CHECK(for assembler .weakext directive,
 938                  libc_cv_asm_weakext_directive,
 939                  [dnl
 940 cat > conftest.s <<EOF
 941 ${libc_cv_dot_text}
 942 ${libc_cv_asm_global_directive} foo
 943 foo:
 944 .weakext bar foo
 945 .weakext baz
 946 ${libc_cv_asm_global_directive} baz
 947 baz:
 948 EOF
 949   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 950     libc_cv_asm_weakext_directive=yes
 951   else
 952     libc_cv_asm_weakext_directive=no
 953   fi
 954   rm -f conftest*])
 955
 956 fi # no .weak
 957
 958 if test $libc_cv_asm_weak_directive = yes; then
 959   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 960 elif test $libc_cv_asm_weakext_directive = yes; then
 961   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 962 fi
 963
 964 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 965 cat > conftest.c <<\EOF
 966 _start () {}
 967 int __eh_pc;
 968 __throw () {}
 969 EOF
 970 dnl No \ in command here because it ends up inside ''.
 971 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 972                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 973                             -o conftest conftest.c 1>&AC_FD_CC]); then
 974   libc_cv_ld_no_whole_archive=yes
 975 else
 976   libc_cv_ld_no_whole_archive=no
 977 fi
 978 rm -f conftest*])
 979 if test $libc_cv_ld_no_whole_archive = yes; then
 980   no_whole_archive=-Wl,--no-whole-archive
 981 fi
 982 AC_SUBST(no_whole_archive)dnl
 983
 984 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
 985 cat > conftest.c <<\EOF
 986 _start () {}
 987 int __eh_pc;
 988 __throw () {}
 989 EOF
 990 dnl No \ in command here because it ends up inside ''.
 991 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 992                             -nostdlib -nostartfiles -fexceptions
 993                             -o conftest conftest.c 1>&AC_FD_CC]); then
 994   libc_cv_gcc_exceptions=yes
 995 else
 996   libc_cv_gcc_exceptions=no
 997 fi
 998 rm -f conftest*])
 999 if test $libc_cv_gcc_exceptions = yes; then
1000   exceptions=-fexceptions
1001 fi
1002 AC_SUBST(exceptions)dnl
1003
1004 if test "$base_machine" = alpha ; then
1005 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
1006 cat > conftest.c <<\EOF
1007 foo () { }
1008 EOF
1009 dnl
1010 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
1011 then
1012   libc_cv_gcc_alpha_ng_prefix=yes
1013 else
1014   libc_cv_gcc_alpha_ng_prefix=no
1015 fi
1016 rm -f conftest* ])
1017 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
1018   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
1019 else
1020   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
1021 fi
1022 fi
1023
1024 if test "$host_cpu" = powerpc ; then
1025 # Check for a bug present in at least versions 2.8.x of GCC
1026 # and versions 1.0.x of EGCS.
1027 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1028 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1029                libc_cv_c_asmcr0_bug='no',
1030                libc_cv_c_asmcr0_bug='yes')])
1031 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1032   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1033 fi
1034 fi
1035
1036 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
1037 [cat > conftest.c <<EOF
1038 #line __oline__ "configure"
1039 static char __EH_FRAME_BEGIN__[];
1040 _start ()
1041 {
1042 #ifdef CHECK__register_frame
1043   __register_frame (__EH_FRAME_BEGIN__);
1044   __deregister_frame (__EH_FRAME_BEGIN__);
1045 #endif
1046 #ifdef CHECK__register_frame_info
1047   __register_frame_info (__EH_FRAME_BEGIN__);
1048   __deregister_frame_info (__EH_FRAME_BEGIN__);
1049 #endif
1050 }
1051 int __eh_pc;
1052 __throw () {}
1053 /* FIXME: this is fragile.  */
1054 malloc () {}
1055 strcmp () {}
1056 strlen () {}
1057 memcpy () {}
1058 memset () {}
1059 free () {}
1060 abort () {}
1061 __bzero () {}
1062 EOF
1063 dnl No \ in command here because it ends up inside ''.
1064 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1065                             -nostdlib -nostartfiles
1066                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1067   libc_cv_gcc_dwarf2_unwind_info=static
1068 else
1069   libc_cv_gcc_dwarf2_unwind_info=no
1070 fi
1071 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1072   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1073                               -nostdlib -nostartfiles
1074                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1075     libc_cv_gcc_dwarf2_unwind_info=yes
1076   else
1077     libc_cv_gcc_dwarf2_unwind_info=no
1078   fi
1079 fi
1080 rm -f conftest*])
1081 case $libc_cv_gcc_dwarf2_unwind_info in
1082 yes)
1083   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1084   ;;
1085 static)
1086   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1087   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1088   ;;
1089 esac
1090
1091 dnl Check whether compiler understands __builtin_expect.
1092 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1093 [cat > conftest.c <<EOF
1094 #line __oline__ "configure"
1095 int foo (int a)
1096 {
1097   a = __builtin_expect (a, 10);
1098   return a == 10 ? 0 : 1;
1099 }
1100 EOF
1101 dnl No \ in command here because it ends up inside ''.
1102 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1103                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1104   libc_cv_gcc_builtin_expect=yes
1105 else
1106   libc_cv_gcc_builtin_expect=no
1107 fi
1108 rm -f conftest*])
1109 if test "$libc_cv_gcc_builtin_expect" = yes; then
1110   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1111 fi
1112
1113 dnl Check whether the compiler supports subtraction of local labels.
1114 AC_CACHE_CHECK(for local label subtraction, libc_cv_gcc_subtract_local_labels,
1115 [cat > conftest.c <<EOF
1116 changequote(,)dnl
1117 #line __oline__ "configure"
1118 int foo (int a)
1119 {
1120   static const int ar[] = { &&l1 - &&l1, &&l2 - &&l1 };
1121   void *p = &&l1 + ar[a];
1122   goto *p;
1123  l1:
1124   return 1;
1125  l2:
1126   return 2;
1127 }
1128 changequote([,])dnl
1129 EOF
1130 dnl No \ in command here because it ends up inside ''.
1131 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1132                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1133   libc_cv_gcc_subtract_local_labels=yes
1134 else
1135   libc_cv_gcc_subtract_local_labels=no
1136 fi
1137 rm -f conftest*])
1138 if test "$libc_cv_gcc_subtract_local_labels" = yes; then
1139   AC_DEFINE(HAVE_SUBTRACT_LOCAL_LABELS)
1140 fi
1141
1142 dnl Check whether we have the gd library available.
1143 AC_MSG_CHECKING(for libgd)
1144 old_CFLAGS="$CFLAGS"
1145 CFLAGS="$CFLAGS $libgd_include"
1146 old_LDFLAGS="$LDFLAGS"
1147 LDFLAGS="$LDFLAGS $libgd_ldflags"
1148 old_LIBS="$LIBS"
1149 LIBS="$LIBS -lgd -lpng -lz"
1150 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1151 CFLAGS="$old_CFLAGS"
1152 LDFLAGS="$old_LDFLAGS"
1153 LIBS="$old_LIBS"
1154 AC_MSG_RESULT($LIBGD)
1155 AC_SUBST(LIBGD)
1156
1157 ### End of automated tests.
1158 ### Now run sysdeps configure fragments.
1159
1160 # sysdeps configure fragments may set these with files to be linked below.
1161 libc_link_dests=
1162 libc_link_sources=
1163
1164 # They also can set these variables.
1165 ldd_rewrite_script=no
1166
1167 # Iterate over all the sysdep directories we will use, running their
1168 # configure fragments, and looking for a uname implementation.
1169 uname=
1170 for dir in $sysnames; do
1171   case $dir in
1172     /*) dest=$dir ;;
1173     *)  dest=$srcdir/$dir ;;
1174   esac
1175   if test -r $dest/configure; then
1176     AC_MSG_RESULT(running configure fragment for $dest)
1177     . $dest/configure
1178   fi
1179 [
1180   if test -z "$uname"; then
1181     if test -r $dest/uname.c ||
1182        test -r $dest/uname.S ||
1183        { test -r $dest/syscalls.list &&
1184          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1185       uname=$dir
1186     fi
1187   fi
1188 ]dnl
1189 done
1190
1191 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1192
1193 # If we will use the generic uname implementation, we must figure out what
1194 # it will say by examining the system, and write the results in config-name.h.
1195 if test "$uname" = "sysdeps/generic"; then
1196
1197 changequote(,)dnl
1198   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1199 changequote([,])dnl
1200   if test $uname_sysname != $config_os; then
1201     config_release=`echo $config_os | sed s/$uname_sysname//`
1202   fi
1203 dnl
1204 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1205     if test -r /vmunix; then
1206       kernel_id=`strings /vmunix | grep UNIX`
1207     elif test -r /dynix; then
1208       kernel_id=`strings /dynix | grep DYNIX`
1209     else
1210       kernel_id=
1211     fi
1212 ])dnl
1213
1214   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1215 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1216 changequote(,)dnl
1217   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1218 changequote([,])dnl
1219   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1220          != x$config_release; then
1221     # The configuration release is a substring of the kernel release.
1222     libc_cv_uname_release=$kernel_release
1223   elif test x$config_release != x; then
1224     libc_cv_uname_release=$config_release
1225   elif test x$kernel_release != x; then
1226     libc_cv_uname_release=$kernel_release
1227   else
1228     libc_cv_uname_release=unknown
1229   fi])
1230   uname_release="$libc_cv_uname_release"
1231
1232   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1233 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1234 changequote(,)dnl
1235   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1236 changequote([,])dnl
1237   if test -n "$kernel_version"; then
1238     libc_cv_uname_version="$kernel_version"
1239   else
1240     libc_cv_uname_version=unknown
1241   fi])
1242   uname_version="$libc_cv_uname_version"
1243
1244 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1245   config_uname=config-name.h:config-name.in
1246 else
1247   # For non-generic uname, we don't need to create config-name.h at all.
1248   config_uname=
1249 fi
1250
1251 AC_MSG_CHECKING(stdio selection)
1252 AC_SUBST(stdio)
1253 case $stdio in
1254 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1255 default) stdio=stdio ;;
1256 esac
1257 AC_MSG_RESULT($stdio)
1258
1259 # Test for old glibc 2.0.x headers so that they can be removed properly
1260 # Search only in includedir.
1261 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1262 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1263 then
1264   old_glibc_headers=yes
1265 else
1266   old_glibc_headers=no
1267 fi
1268 AC_MSG_RESULT($old_glibc_headers)
1269 if test ${old_glibc_headers} = yes; then
1270   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1271   AC_MSG_WARN(*** be removed.)
1272 fi
1273 AC_SUBST(old_glibc_headers)
1274
1275 AC_SUBST(libc_cv_slibdir)
1276 AC_SUBST(libc_cv_sysconfdir)
1277 AC_SUBST(libc_cv_rootsbindir)
1278
1279 AC_SUBST(has_ldconfig)
1280 AC_SUBST(ldd_rewrite_script)
1281
1282 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1283 if test $gnu_ld = yes; then
1284   AC_DEFINE(HAVE_GNU_LD)
1285 fi
1286 if test $gnu_as = yes; then
1287   AC_DEFINE(HAVE_GNU_AS)
1288 fi
1289 if test $elf = yes; then
1290   AC_DEFINE(HAVE_ELF)
1291 fi
1292
1293 AC_SUBST(static)
1294 AC_SUBST(shared)
1295 if test $shared = default; then
1296   if test $gnu_ld = yes; then
1297     shared=$elf
1298   else
1299     # For now we do not assume shared libs are available.  In future more
1300     # tests might become available.
1301     shared=no
1302   fi
1303 fi
1304
1305 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1306 [pic_default=yes
1307 cat > conftest.c <<EOF
1308 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1309 # error PIC is default.
1310 #endif
1311 EOF
1312 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1313   pic_default=no
1314 fi
1315 rm -f conftest.*])
1316 AC_SUBST(pic_default)
1317
1318 AC_SUBST(profile)
1319 AC_SUBST(omitfp)
1320 AC_SUBST(bounded)
1321 AC_SUBST(static_nss)
1322 AC_SUBST(nopic_initfini)
1323
1324 AC_SUBST(DEFINES)
1325
1326 case "$add_ons" in
1327   *door*) linux_doors=yes ;;
1328   *) linux_doors=no ;;
1329 esac
1330 AC_SUBST(linux_doors)
1331
1332 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1333   config_makefile=
1334 else
1335   config_makefile=Makefile
1336 fi
1337
1338 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1339 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1340 AC_SUBST(VERSION)
1341 AC_SUBST(RELEASE)
1342
1343 echo '*** Do NOT install this release on any production system!'
1344 echo '*** It is known to be broken and will be so for quite some time.'
1345 echo '*** Use the latest released version instead.'
1346
1347 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1348 case $CONFIG_FILES in *config.make*)
1349 echo "$config_vars" >> config.make;;
1350 esac
1351 test -d bits || mkdir bits], [config_vars='$config_vars'])