sysdeps/alpha/strncat.S

   1 /* Copyright (C) 1996 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Richard Henderson <rth@tamu.edu>, 1996.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Library General Public License as
   7    published by the Free Software Foundation; either version 2 of the
   8    License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Library General Public License for more details.
  14
  15    You should have received a copy of the GNU Library General Public
  16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  18    Boston, MA 02111-1307, USA.  */
  19
  20 /* Append no more than COUNT characters from the null-terminated string SRC
  21    to the null-terminated string DST.  Always null-terminate the new DST.  */
  22
  23 #include <sysdep.h>
  24
  25         .text
  26
  27 ENTRY(strncat)
  28         ldgp    gp, 0(pv)
  29 #ifdef PROF
  30         .set noat
  31         lda     AT, _mcount
  32         jsr     AT, (AT), _mcount
  33         .set at
  34 #endif
  35         .prologue 1
  36
  37         mov     a0, v0          # set up return value
  38         beq     a2, $zerocount
  39
  40         /* Find the end of the string.  */
  41
  42         ldq_u   t0, 0(a0)       # load first quadword (a0 may be misaligned)
  43         lda     t1, -1(zero)
  44         insqh   t1, a0, t1
  45         andnot  a0, 7, a0
  46         or      t1, t0, t0
  47         cmpbge  zero, t0, t1    # t1 <- bitmask: bit i == 1 <==> i-th byte == 0
  48         bne     t1, $found
  49
  50 $loop:  ldq     t0, 8(a0)
  51         addq    a0, 8, a0       # addr += 8
  52         cmpbge  zero, t0, t1
  53         beq     t1, $loop
  54
  55 $found: negq    t1, t2          # clear all but least set bit
  56         and     t1, t2, t1
  57
  58         and     t1, 0xf0, t2    # binary search for that set bit
  59         and     t1, 0xcc, t3
  60         and     t1, 0xaa, t4
  61         cmovne  t2, 4, t2
  62         cmovne  t3, 2, t3
  63         cmovne  t4, 1, t4
  64         addq    t2, t3, t2
  65         addq    a0, t4, a0
  66         addq    a0, t2, a0
  67
  68         /* Now do the append.  */
  69
  70         jsr     t9, __stxncpy
  71
  72         /* Worry about the null termination.  */
  73
  74         zapnot  t0, t8, t1      # was last byte a null?
  75         bne     t1, 0f
  76         ret
  77
  78 0:      and     t10, 0x80, t1
  79         bne     t1, 1f
  80
  81         /* Here there are bytes left in the current word.  Clear one.  */
  82         addq    t10, t10, t10   # end-of-count bit <<= 1
  83         zap     t0, t10, t0
  84         stq_u   t0, 0(a0)
  85         ret
  86
  87 1:      /* Here we must read the next DST word and clear the first byte.  */
  88         ldq_u   t0, 8(a0)
  89         zap     t0, 1, t0
  90         stq_u   t0, 8(a0)
  91
  92 $zerocount:
  93         ret
  94
  95         END(strncat)