sysdeps/i386/setjmp.S

   1 /* setjmp for i386.
   2    Copyright (C) 1995-2024 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <https://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <pointer_guard.h>
  21 #include <jmpbuf-offsets.h>
  22 #include <asm-syntax.h>
  23 #include <stap-probe.h>
  24
  25 #define PARMS   4               /* no space for saved regs */
  26 #define JMPBUF  PARMS
  27 #define SIGMSK  JMPBUF+4
  28
  29 ENTRY (__sigsetjmp)
  30
  31         movl JMPBUF(%esp), %eax
  32
  33         /* Save registers.  */
  34         movl %ebx, (JB_BX*4)(%eax)
  35         movl %esi, (JB_SI*4)(%eax)
  36         movl %edi, (JB_DI*4)(%eax)
  37         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
  38 #ifdef PTR_MANGLE
  39         PTR_MANGLE (%ecx)
  40 #endif
  41         movl %ecx, (JB_SP*4)(%eax)
  42         movl 0(%esp), %ecx      /* Save PC we are returning to now.  */
  43         LIBC_PROBE (setjmp, 3, 4@%eax, -4@SIGMSK(%esp), 4@%ecx)
  44 #ifdef PTR_MANGLE
  45         PTR_MANGLE (%ecx)
  46 #endif
  47         movl %ecx, (JB_PC*4)(%eax)
  48         movl %ebp, (JB_BP*4)(%eax) /* Save caller's frame pointer.  */
  49
  50 #if IS_IN (rtld)
  51         /* In ld.so we never save the signal mask.  */
  52         xorl %eax, %eax
  53         ret
  54 #else
  55         /* Make a tail call to __sigjmp_save; it takes the same args.  */
  56         jmp __sigjmp_save
  57 #endif
  58 END (__sigsetjmp)
  59 hidden_def (__sigsetjmp)