configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 AC_CHECK_TOOL(READELF, readelf, false)
  54
  55 # We need the C++ compiler only for testing.
  56 AC_PROG_CXX
  57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  59 AC_LANG_PUSH([C++])
  60 # Default, dynamic case.
  61 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  62                [libc_cv_cxx_link_ok=yes],
  63                [libc_cv_cxx_link_ok=no])
  64 # Static case.
  65 old_LDFLAGS="$LDFLAGS"
  66 LDFLAGS="$LDFLAGS -static"
  67 AC_LINK_IFELSE([AC_LANG_SOURCE([
  68 #include <iostream>
  69
  70 int
  71 main()
  72 {
  73   std::cout << "Hello, world!";
  74   return 0;
  75 }
  76 ])],
  77                [],
  78                [libc_cv_cxx_link_ok=no])
  79 LDFLAGS="$old_LDFLAGS"
  80 AC_LANG_POP([C++])])
  81 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  82
  83 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  84   AC_MSG_ERROR([you must configure in a separate build directory])
  85 fi
  86
  87 # This will get text that should go into config.make.
  88 config_vars=
  89
  90 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  91 AC_ARG_WITH([gd],
  92             AC_HELP_STRING([--with-gd=DIR],
  93                            [find libgd include dir and library with prefix DIR]),
  94             [dnl
  95 case "$with_gd" in
  96 yes|''|no) ;;
  97 *) libgd_include="-I$withval/include"
  98    libgd_ldflags="-L$withval/lib" ;;
  99 esac
 100 ])
 101 AC_ARG_WITH([gd-include],
 102             AC_HELP_STRING([--with-gd-include=DIR],
 103                            [find libgd include files in DIR]),
 104             [dnl
 105 case "$with_gd_include" in
 106 ''|no) ;;
 107 *) libgd_include="-I$withval" ;;
 108 esac
 109 ])
 110 AC_ARG_WITH([gd-lib],
 111             AC_HELP_STRING([--with-gd-lib=DIR],
 112                            [find libgd library files in DIR]),
 113             [dnl
 114 case "$with_gd_lib" in
 115 ''|no) ;;
 116 *) libgd_ldflags="-L$withval" ;;
 117 esac
 118 ])
 119
 120 if test -n "$libgd_include"; then
 121   config_vars="$config_vars
 122 CFLAGS-memusagestat.c = $libgd_include"
 123 fi
 124 if test -n "$libgd_ldflags"; then
 125   config_vars="$config_vars
 126 libgd-LDFLAGS = $libgd_ldflags"
 127 fi
 128
 129 dnl Arguments to specify presence of other packages/features.
 130 AC_ARG_WITH([fp],
 131             AC_HELP_STRING([--with-fp],
 132                            [if using floating-point hardware @<:@default=yes@:>@]),
 133             [with_fp=$withval],
 134             [with_fp=yes])
 135 AC_SUBST(with_fp)
 136 AC_ARG_WITH([binutils],
 137             AC_HELP_STRING([--with-binutils=PATH],
 138                            [specify location of binutils (as and ld)]),
 139             [path_binutils=$withval],
 140             [path_binutils=''])
 141 AC_ARG_WITH([selinux],
 142             AC_HELP_STRING([--with-selinux],
 143                            [if building with SELinux support]),
 144             [with_selinux=$withval],
 145             [with_selinux=auto])
 146
 147 AC_ARG_WITH([headers],
 148             AC_HELP_STRING([--with-headers=PATH],
 149                            [location of system headers to use
 150                             (for example /usr/src/linux/include)
 151                             @<:@default=compiler default@:>@]),
 152             [sysheaders=$withval],
 153             [sysheaders=''])
 154 AC_SUBST(sysheaders)
 155
 156 AC_SUBST(use_default_link)
 157 AC_ARG_WITH([default-link],
 158             AC_HELP_STRING([--with-default-link],
 159                            [do not use explicit linker scripts]),
 160             [use_default_link=$withval],
 161             [use_default_link=default])
 162
 163 AC_ARG_ENABLE([sanity-checks],
 164               AC_HELP_STRING([--disable-sanity-checks],
 165                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 166               [enable_sanity=$enableval],
 167               [enable_sanity=yes])
 168
 169 AC_ARG_ENABLE([shared],
 170               AC_HELP_STRING([--enable-shared],
 171                              [build shared library @<:@default=yes if GNU ld@:>@]),
 172               [shared=$enableval],
 173               [shared=yes])
 174 AC_ARG_ENABLE([profile],
 175               AC_HELP_STRING([--enable-profile],
 176                              [build profiled library @<:@default=no@:>@]),
 177               [profile=$enableval],
 178               [profile=no])
 179 AC_ARG_ENABLE([timezone-tools],
 180               AC_HELP_STRING([--disable-timezone-tools],
 181                              [do not install timezone tools @<:@default=install@:>@]),
 182               [enable_timezone_tools=$enableval],
 183               [enable_timezone_tools=yes])
 184 AC_SUBST(enable_timezone_tools)
 185
 186 AC_ARG_ENABLE([hardcoded-path-in-tests],
 187               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 188                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 189               [hardcoded_path_in_tests=$enableval],
 190               [hardcoded_path_in_tests=no])
 191 AC_SUBST(hardcoded_path_in_tests)
 192
 193 AC_ARG_ENABLE([stackguard-randomization],
 194               AC_HELP_STRING([--enable-stackguard-randomization],
 195                              [initialize __stack_chk_guard canary with a random number at program start]),
 196               [enable_stackguard_randomize=$enableval],
 197               [enable_stackguard_randomize=no])
 198 if test "$enable_stackguard_randomize" = yes; then
 199   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 200 fi
 201
 202 AC_ARG_ENABLE([lock-elision],
 203               AC_HELP_STRING([--enable-lock-elision[=yes/no]],
 204                              [Enable lock elision for pthread mutexes by default]),
 205               [enable_lock_elision=$enableval],
 206               [enable_lock_elision=no])
 207 AC_SUBST(enable_lock_elision)
 208 if test "$enable_lock_elision" = yes ; then
 209   AC_DEFINE(ENABLE_LOCK_ELISION)
 210 fi
 211
 212 dnl Generic infrastructure for drop-in additions to libc.
 213 AC_ARG_ENABLE([add-ons],
 214               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 215                              [configure and build add-ons in DIR1,DIR2,...
 216                               search for add-ons if no parameter given]),
 217                              , [enable_add_ons=yes])
 218
 219 AC_ARG_ENABLE([hidden-plt],
 220               AC_HELP_STRING([--disable-hidden-plt],
 221                              [do not hide internal function calls to avoid PLT]),
 222               [hidden=$enableval],
 223               [hidden=yes])
 224 if test "x$hidden" = xno; then
 225   AC_DEFINE(NO_HIDDEN)
 226 fi
 227
 228 AC_ARG_ENABLE([bind-now],
 229               AC_HELP_STRING([--enable-bind-now],
 230                              [disable lazy relocations in DSOs]),
 231               [bindnow=$enableval],
 232               [bindnow=no])
 233 AC_SUBST(bindnow)
 234 if test "x$bindnow" = xyes; then
 235   AC_DEFINE(BIND_NOW)
 236 fi
 237
 238 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
 239 dnl -fstack-protector-strong.
 240 AC_ARG_ENABLE([stack-protector],
 241               AC_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
 242                              [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
 243               [enable_stack_protector=$enableval],
 244               [enable_stack_protector=no])
 245 case "$enable_stack_protector" in
 246 all|yes|no|strong) ;;
 247 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
 248 esac
 249
 250 dnl On some platforms we cannot use dynamic loading.  We must provide
 251 dnl static NSS modules.
 252 AC_ARG_ENABLE([static-nss],
 253               AC_HELP_STRING([--enable-static-nss],
 254                              [build static NSS modules @<:@default=no@:>@]),
 255               [static_nss=$enableval],
 256               [static_nss=no])
 257 dnl Enable static NSS also if we build no shared objects.
 258 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 259   static_nss=yes
 260   AC_DEFINE(DO_STATIC_NSS)
 261 fi
 262
 263 AC_ARG_ENABLE([force-install],
 264               AC_HELP_STRING([--disable-force-install],
 265                              [don't force installation of files from this package, even if they are older than the installed files]),
 266               [force_install=$enableval],
 267               [force_install=yes])
 268 AC_SUBST(force_install)
 269
 270 AC_ARG_ENABLE([maintainer-mode],
 271               AC_HELP_STRING([--enable-maintainer-mode],
 272                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 273               [maintainer=$enableval],
 274               [maintainer=no])
 275
 276 dnl On some platforms we allow dropping compatibility with all kernel
 277 dnl versions.
 278 AC_ARG_ENABLE([kernel],
 279               AC_HELP_STRING([--enable-kernel=VERSION],
 280                              [compile for compatibility with kernel not older than VERSION]),
 281               [minimum_kernel=$enableval],
 282               [])
 283 dnl Prevent unreasonable values.
 284 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 285   # Better nothing than this.
 286   minimum_kernel=""
 287 else
 288   if test "$minimum_kernel" = current; then
 289     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 290   fi
 291 fi
 292
 293 dnl For the development we sometimes want gcc to issue even more warnings.
 294 dnl This is not the default since many of the extra warnings are not
 295 dnl appropriate.
 296 AC_ARG_ENABLE([all-warnings],
 297               AC_HELP_STRING([--enable-all-warnings],
 298                              [enable all useful warnings gcc can issue]),
 299               [all_warnings=$enableval],
 300               [])
 301 AC_SUBST(all_warnings)
 302
 303 AC_ARG_ENABLE([werror],
 304               AC_HELP_STRING([--disable-werror],
 305                              [do not build with -Werror]),
 306               [enable_werror=$enableval],
 307               [enable_werror=yes])
 308 AC_SUBST(enable_werror)
 309
 310 AC_ARG_ENABLE([multi-arch],
 311               AC_HELP_STRING([--enable-multi-arch],
 312                              [enable single DSO with optimizations for multiple architectures]),
 313               [multi_arch=$enableval],
 314               [multi_arch=default])
 315
 316 AC_ARG_ENABLE([nss-crypt],
 317               AC_HELP_STRING([--enable-nss-crypt],
 318                              [enable libcrypt to use nss]),
 319               [nss_crypt=$enableval],
 320               [nss_crypt=no])
 321 if test x$nss_crypt = xyes; then
 322   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 323   if test $? -ne 0; then
 324     AC_MSG_ERROR([cannot find include directory with nss-config])
 325   fi
 326   old_CFLAGS="$CFLAGS"
 327   CFLAGS="$CFLAGS $nss_includes"
 328   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 329 #include <hasht.h>
 330 #include <nsslowhash.h>
 331 void f (void) { NSSLOW_Init (); }])],
 332              libc_cv_nss_crypt=yes,
 333              AC_MSG_ERROR([
 334 cannot find NSS headers with lowlevel hash function interfaces]))
 335   old_LIBS="$LIBS"
 336   old_LDFLAGS="$LDFLAGS"
 337   LIBS="$LIBS -lfreebl3"
 338   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 339 #include <hasht.h>
 340 #include <nsslowhash.h>],
 341                                   [NSSLOW_Init();])],
 342                  libc_cv_nss_crypt=yes,
 343                  AC_MSG_ERROR([
 344 cannot link program using lowlevel NSS hash functions]))
 345   # Check to see if there is a static NSS cryptographic library.
 346   # If there isn't then we can't link anything with libcrypt.a,
 347   # and that might mean disabling some static tests.
 348   LDFLAGS="$LDFLAGS -static"
 349   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 350 #include <hasht.h>
 351 #include <nsslowhash.h>],
 352                                   [NSSLOW_Init();])],
 353                  libc_cv_static_nss_crypt=yes,
 354                  libc_cv_static_nss_crypt=no)
 355   LDFLAGS="$old_LDFLAGS"
 356   CFLAGS="$old_CFLAGS"
 357   LIBS="$old_LIBS"
 358 else
 359   libc_cv_nss_crypt=no
 360   libc_cv_static_nss_crypt=no
 361 fi
 362 AC_SUBST(libc_cv_nss_crypt)
 363 AC_SUBST(libc_cv_static_nss_crypt)
 364
 365
 366 AC_ARG_ENABLE([obsolete-rpc],
 367               AC_HELP_STRING([--enable-obsolete-rpc],
 368                              [build and install the obsolete RPC code for link-time usage]),
 369               [link_obsolete_rpc=$enableval],
 370               [link_obsolete_rpc=no])
 371 AC_SUBST(link_obsolete_rpc)
 372
 373 if test "$link_obsolete_rpc" = yes; then
 374   AC_DEFINE(LINK_OBSOLETE_RPC)
 375 fi
 376
 377 AC_ARG_ENABLE([systemtap],
 378               [AS_HELP_STRING([--enable-systemtap],
 379                [enable systemtap static probe points @<:@default=no@:>@])],
 380               [systemtap=$enableval],
 381               [systemtap=no])
 382 if test "x$systemtap" != xno; then
 383   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 384   old_CFLAGS="$CFLAGS"
 385   CFLAGS="-std=gnu11 $CFLAGS"
 386   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 387 void foo (int i, void *p)
 388 {
 389   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 390        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 391 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 392   CFLAGS="$old_CFLAGS"])
 393   if test $libc_cv_sdt = yes; then
 394     AC_DEFINE([USE_STAP_PROBE])
 395   elif test "x$systemtap" != xauto; then
 396     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 397   fi
 398 fi
 399
 400 AC_ARG_ENABLE([build-nscd],
 401               [AS_HELP_STRING([--disable-build-nscd],
 402                [disable building and installing the nscd daemon])],
 403               [build_nscd=$enableval],
 404               [build_nscd=default])
 405 AC_SUBST(build_nscd)
 406
 407 # Note the use of $use_nscd is near the bottom of the file.
 408 AC_ARG_ENABLE([nscd],
 409               [AS_HELP_STRING([--disable-nscd],
 410                [library functions will not contact the nscd daemon])],
 411               [use_nscd=$enableval],
 412               [use_nscd=yes])
 413
 414 AC_ARG_ENABLE([pt_chown],
 415               [AS_HELP_STRING([--enable-pt_chown],
 416                [Enable building and installing pt_chown])],
 417               [build_pt_chown=$enableval],
 418               [build_pt_chown=no])
 419 AC_SUBST(build_pt_chown)
 420 if test "$build_pt_chown" = yes; then
 421   AC_DEFINE(HAVE_PT_CHOWN)
 422 fi
 423
 424 # The abi-tags file uses a fairly simplistic model for name recognition that
 425 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 426 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 427 # This doesn't get used much beyond that, so it's fairly safe.
 428 case "$host_os" in
 429 linux*)
 430   ;;
 431 gnu*)
 432   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 433   ;;
 434 esac
 435
 436 AC_ARG_ENABLE([mathvec],
 437               [AS_HELP_STRING([--enable-mathvec],
 438               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 439               [build_mathvec=$enableval],
 440               [build_mathvec=notset])
 441
 442 # We keep the original values in `$config_*' and never modify them, so we
 443 # can write them unchanged into config.make.  Everything else uses
 444 # $machine, $vendor, and $os, and changes them whenever convenient.
 445 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 446
 447 # Don't allow vendor == "unknown"
 448 test "$config_vendor" = unknown && config_vendor=
 449 config_os="`echo $config_os | sed 's/^unknown-//'`"
 450
 451 # Some configurations imply other options.
 452 elf=yes
 453
 454 # The configure fragment of an add-on port can modify these to supplement
 455 # or override the table in the case statement below.  No fragment should
 456 # ever change the config_* variables, however.
 457 machine=$config_machine
 458 vendor=$config_vendor
 459 os=$config_os
 460 base_os=''
 461
 462 submachine=
 463 AC_ARG_WITH([cpu],
 464             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 465             [dnl
 466   case "$withval" in
 467   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 468   no) ;;
 469   *) submachine="$withval" ;;
 470   esac
 471 ])
 472
 473 # An preconfigure script can set this when it wants to disable the sanity
 474 # check below.
 475 libc_config_ok=no
 476
 477 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
 478 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 479
 480 dnl Having this here, though empty, makes sure that if add-ons' fragments
 481 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 482 dnl our AC_OUTPUT will actually use it.
 483 AC_CONFIG_SUBDIRS()
 484
 485 case "$enable_add_ons" in
 486 ''|no) add_ons= ;;
 487 yes|'*')
 488  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 489           sed 's@/[[^/]]*$@@' | sort | uniq`
 490          add_ons_automatic=yes
 491          ;;
 492 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 493        add_ons_automatic=no ;;
 494 esac
 495
 496 configured_add_ons=
 497 add_ons_sfx=
 498 add_ons_pfx=
 499 if test x"$add_ons" != x; then
 500   for f in $add_ons; do
 501     # Some sanity checks
 502     case "$f" in
 503     crypt)
 504       AC_MSG_ERROR([
 505 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 506 *** part of glibc and using the old add-on will not work with this
 507 *** release.  Start again with fresh sources and without the old
 508 *** \`crypt' add-on.])
 509     ;;
 510     localedata)
 511       AC_MSG_ERROR([
 512 *** It seems that you're using an old \`localedata' add-on.  localedata
 513 *** is now part of glibc and using the old add-on will not work with
 514 *** this release.  Start again with fresh sources and without the old
 515 *** \`localedata' add-on.])
 516     ;;
 517     esac
 518   done
 519
 520   # Now source each add-on's configure fragment.
 521   # The fragments can use $srcdir/$libc_add_on to find themselves,
 522   # and test $add_ons_automatic to see if they were explicitly requested.
 523   # A fragment can clear (or even change) $libc_add_on to affect
 524   # whether it goes into the list to be actually used in the build.
 525   use_add_ons=
 526   for libc_add_on in $add_ons; do
 527     # Test whether such a directory really exists.
 528     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 529     case "$libc_add_on" in
 530     /*)
 531       libc_add_on_srcdir=$libc_add_on
 532       ;;
 533     *)
 534       test -d "$srcdir/$libc_add_on" || {
 535         if test -d "$libc_add_on"; then
 536           libc_add_on="`pwd`/$libc_add_on"
 537         else
 538           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 539         fi
 540       }
 541       libc_add_on_srcdir=$srcdir/$libc_add_on
 542       ;;
 543     esac
 544
 545     libc_add_on_frag=$libc_add_on_srcdir/configure
 546     libc_add_on_canonical=
 547     libc_add_on_config_subdirs=
 548     if test -r "$libc_add_on_frag"; then
 549       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 550       libc_add_on_canonical=unknown
 551       libc_add_on_subdirs=
 552       . "$libc_add_on_frag"
 553       test -z "$libc_add_on" || {
 554         configured_add_ons="$configured_add_ons $libc_add_on"
 555         if test "x$libc_add_on_canonical" = xunknown; then
 556           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 557         fi
 558         for d in $libc_add_on_subdirs; do
 559           case "$libc_add_on" in
 560           /*) subdir_srcdir="$libc_add_on" ;;
 561           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 562           esac
 563           case "$d" in
 564           .)
 565             d="${libc_add_on_canonical:-$libc_add_on}"
 566             ;;
 567           /*)
 568             subdir_srcdir="$d"
 569             ;;
 570           *)
 571             subdir_srcdir="$subdir_srcdir/$d"
 572             ;;
 573           esac
 574           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 575           add_on_subdirs="$add_on_subdirs $d"
 576           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 577 $d-srcdir = $subdir_srcdir"
 578         done
 579         for d in $libc_add_on_config_subdirs; do
 580           case "$d" in
 581           /*) AC_MSG_ERROR(dnl
 582 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 583           esac
 584           if test ! -d "$libc_add_on_srcdir/$d"; then
 585             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 586           fi
 587           case "$libc_add_on" in
 588           /*) AC_MSG_ERROR(dnl
 589 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 590           esac
 591           subdirs="$subdirs $libc_add_on/$d"
 592         done
 593       }
 594     fi
 595     if test -n "$libc_add_on"; then
 596       LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
 597       use_add_ons="$use_add_ons $libc_add_on"
 598       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 599       test -z "$libc_add_on_canonical" ||
 600       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 601     fi
 602   done
 603   # Use echo to strip excess whitespace.
 604   add_ons="`echo $use_add_ons`"
 605 fi
 606 AC_SUBST(add_ons)
 607 AC_SUBST(add_on_subdirs)
 608
 609
 610 ###
 611 ### By using the undocumented --enable-hacker-mode option for configure
 612 ### one can skip this test to make the configuration not fail for unsupported
 613 ### platforms.
 614 ###
 615 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 616   case "$machine-$host_os" in
 617   *-linux* | *-gnu*)
 618     ;;
 619   *)
 620     AC_MSG_ERROR([
 621 *** The GNU C library is currently unavailable for this platform.
 622 *** If you are interested in seeing glibc on this platform visit
 623 *** the "How to submit a new port" in the wiki:
 624 ***   https://sourceware.org/glibc/wiki/#Development
 625 *** and join the community!])
 626     ;;
 627   esac
 628 fi
 629
 630 # Set base_machine if not set by a preconfigure fragment.
 631 test -n "$base_machine" || base_machine=$machine
 632 AC_SUBST(base_machine)
 633
 634 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
 635 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
 636                    [libc_cv_ssp=yes],
 637                    [libc_cv_ssp=no])
 638 ])
 639
 640 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
 641 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
 642                    [libc_cv_ssp_strong=yes],
 643                    [libc_cv_ssp_strong=no])
 644 ])
 645
 646 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
 647 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
 648                    [libc_cv_ssp_all=yes],
 649                    [libc_cv_ssp_all=no])
 650 ])
 651
 652 stack_protector=
 653 no_stack_protector=
 654 if test "$libc_cv_ssp" = yes; then
 655   no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
 656   AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
 657 fi
 658
 659 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
 660   stack_protector="-fstack-protector"
 661   AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
 662 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
 663   stack_protector="-fstack-protector-all"
 664   AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
 665 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
 666   stack_protector="-fstack-protector-strong"
 667   AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
 668 else
 669   stack_protector="-fno-stack-protector"
 670   AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
 671 fi
 672 AC_SUBST(libc_cv_ssp)
 673 AC_SUBST(stack_protector)
 674 AC_SUBST(no_stack_protector)
 675
 676 if test -n "$stack_protector"; then
 677   dnl Don't run configure tests with stack-protection on, to avoid problems with
 678   dnl bootstrapping.
 679   no_ssp=-fno-stack-protector
 680 else
 681   no_ssp=
 682
 683   if test "$enable_stack_protector" != no; then
 684     AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
 685   fi
 686 fi
 687
 688 # For the multi-arch option we need support in the assembler & linker.
 689 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 690                libc_cv_ld_gnu_indirect_function, [dnl
 691 cat > conftest.S <<EOF
 692 .type foo,%gnu_indirect_function
 693 foo:
 694 .globl _start
 695 _start:
 696 .globl __start
 697 __start:
 698 .data
 699 #ifdef _LP64
 700 .quad foo
 701 #else
 702 .long foo
 703 #endif
 704 EOF
 705 libc_cv_ld_gnu_indirect_function=no
 706 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 707             -nostartfiles -nostdlib $no_ssp \
 708             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 709   # Do a link to see if the backend supports IFUNC relocs.
 710   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 711   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 712     libc_cv_ld_gnu_indirect_function=yes
 713   }
 714 fi
 715 rm -f conftest*])
 716
 717 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
 718 AC_CACHE_CHECK([for gcc attribute ifunc support],
 719                libc_cv_gcc_indirect_function, [dnl
 720 cat > conftest.c <<EOF
 721 extern int func (int);
 722 int used_func (int a)
 723 {
 724   return a;
 725 }
 726 static void *resolver ()
 727 {
 728   return &used_func;
 729 }
 730 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
 731 EOF
 732 libc_cv_gcc_indirect_function=no
 733 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
 734    2>&AS_MESSAGE_LOG_FD ; then
 735   if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
 736     libc_cv_gcc_indirect_function=yes
 737   fi
 738 fi
 739 rm -f conftest*])
 740
 741 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 742   if test x"$multi_arch" = xyes; then
 743     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 744   else
 745     multi_arch=no
 746   fi
 747 fi
 748 if test x"$libc_cv_gcc_indirect_function" != xyes &&
 749    test x"$multi_arch" = xyes; then
 750   AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
 751 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
 752 fi
 753 multi_arch_d=
 754 if test x"$multi_arch" != xno; then
 755   multi_arch_d=/multiarch
 756 fi
 757
 758 # Compute the list of sysdep directories for this configuration.
 759 # This can take a while to compute.
 760 sysdep_dir=$srcdir/sysdeps
 761 AC_MSG_CHECKING(sysdep dirs)
 762 dnl We need to use [ and ] for other purposes for a while now.
 763 changequote(,)dnl
 764 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 765 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 766
 767 test "x$base_os" != x || case "$os" in
 768 gnu*)
 769   base_os=mach/hurd ;;
 770 linux*)
 771   base_os=unix/sysv ;;
 772 esac
 773
 774 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 775 tail=$os
 776 ostry=$os
 777 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 778   ostry="$ostry /$o"
 779   tail=$o
 780 done
 781 o=`echo $tail | sed 's/[0-9]*$//'`
 782 if test $o != $tail; then
 783   ostry="$ostry /$o"
 784 fi
 785 # For linux-gnu, try linux-gnu, then linux.
 786 o=`echo $tail | sed 's/-.*$//'`
 787 if test $o != $tail; then
 788   ostry="$ostry /$o"
 789 fi
 790
 791 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 792 base=
 793 tail=$base_os
 794 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 795   set $b
 796   base="$base /$1"
 797   tail="$2"
 798 done
 799
 800 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 801 mach=
 802 tail=$machine${submachine:+/$submachine}
 803 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 804   set $m
 805   # Prepend the machine's FPU directory unless --without-fp.
 806   if test "$with_fp" = yes; then
 807     maybe_fpu=/fpu
 808   else
 809     maybe_fpu=/nofpu
 810   fi
 811   # For each machine term, try it with and then without /multiarch.
 812   for try_fpu in $maybe_fpu ''; do
 813     for try_multi in $multi_arch_d ''; do
 814       mach="$mach /$1$try_fpu$try_multi"
 815     done
 816   done
 817   tail="$2"
 818 done
 819
 820 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 821 changequote([,])dnl
 822
 823 # Find what sysdep directories exist.
 824 sysnames_add_ons=
 825 sysnames=
 826 for b in $base ''; do
 827   for m0 in $mach ''; do
 828     for v in /$vendor ''; do
 829       test "$v" = / && continue
 830       for o in /$ostry ''; do
 831         test "$o" = / && continue
 832         for m in $mach ''; do
 833           for d in $add_ons_pfx ''; do
 834             for a in $add_ons_sfx ''; do
 835               try_suffix="$m0$b$v$o$m"
 836               if test -n "$try_suffix"; then
 837                 try_srcdir="${srcdir}/"
 838                 case "$d" in
 839                 /*) try_srcdir= ;;
 840                 esac
 841                 try="${d}sysdeps$try_suffix$a"
 842                 test -n "$enable_debug_configure" &&
 843                 echo "$0 [DEBUG]: try $try" >&2
 844                 if test -d "$try_srcdir$try"; then
 845                   sysnames="$sysnames $try"
 846                   { test -n "$o" || test -n "$b"; } && os_used=t
 847                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 848                   case x${m0:-$m} in
 849                   x*/$submachine) submachine_used=t ;;
 850                   esac
 851                   if test -n "$d"; then
 852                     case "$sysnames_add_ons" in
 853                     *" $d "*) ;;
 854                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 855                     esac
 856                   fi
 857                 fi
 858               fi
 859             done
 860           done
 861         done
 862       done
 863     done
 864   done
 865 done
 866
 867 # If the assembler supports gnu_indirect_function symbol type and the
 868 # architecture supports multi-arch, we enable multi-arch by default.
 869 case $sysnames_add_ons$sysnames in
 870 *"$multi_arch_d"*)
 871   ;;
 872 *)
 873   test x"$multi_arch" = xdefault && multi_arch=no
 874   ;;
 875 esac
 876 if test x"$multi_arch" != xno; then
 877   AC_DEFINE(USE_MULTIARCH)
 878 fi
 879 AC_SUBST(multi_arch)
 880
 881 if test -z "$os_used" && test "$os" != none; then
 882   AC_MSG_ERROR(Operating system $os is not supported.)
 883 fi
 884 if test -z "$machine_used" && test "$machine" != none; then
 885   AC_MSG_ERROR(The $machine is not supported.)
 886 fi
 887 if test -z "$submachine_used" && test -n "$submachine"; then
 888   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 889 fi
 890 AC_SUBST(submachine)
 891
 892 # We have now validated the configuration.
 893
 894 # Expand the list of system names into a full list of directories
 895 # from each element's parent name and Implies file (if present).
 896 set $sysnames
 897 names=
 898 while test $# -gt 0; do
 899   name=$1
 900   shift
 901
 902   case " $names " in *" $name "*)
 903     # Already in the list.
 904     continue
 905   esac
 906
 907   # Report each name as we discover it, so there is no long pause in output.
 908   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 909
 910   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 911
 912   case $name in
 913     /*) xsrcdir= ;;
 914     *)  xsrcdir=$srcdir/ ;;
 915   esac
 916   test -n "$enable_debug_configure" &&
 917   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 918
 919   for implies_file in Implies Implies-before Implies-after; do
 920     implies_type=`echo $implies_file | sed s/-/_/`
 921     eval ${implies_type}=
 922     if test -f $xsrcdir$name/$implies_file; then
 923       # Collect more names from the `Implies' file (removing comments).
 924       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 925       for x in $implied_candidate; do
 926         found=no
 927         if test -d $xsrcdir$name_base/$x; then
 928           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 929           found=yes
 930         fi
 931         for d in $add_ons_pfx ''; do
 932           try="${d}sysdeps/$x"
 933           case $d in
 934            /*) try_srcdir= ;;
 935            *) try_srcdir=$srcdir/ ;;
 936           esac
 937           test -n "$enable_debug_configure" &&
 938            echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
 939           if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 940           then
 941             eval "${implies_type}=\"\$${implies_type} \$try\""
 942             found=yes
 943             case "$sysnames_add_ons" in
 944             *" $d "*) ;;
 945             *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 946             esac
 947           fi
 948         done
 949         if test $found = no; then
 950           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 951         fi
 952       done
 953     fi
 954   done
 955
 956   # Add NAME to the list of names.
 957   names="$names $name"
 958
 959   # Find the parent of NAME, using the empty string if it has none.
 960 changequote(,)dnl
 961   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 962 changequote([,])dnl
 963
 964   test -n "$enable_debug_configure" &&
 965     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 966 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 967
 968   # Add the names implied by NAME, and NAME's parent (if it has one), to
 969   # the list of names to be processed (the argument list).  We prepend the
 970   # implied names to the list and append the parent.  We want implied
 971   # directories to come before further directories inferred from the
 972   # configuration components; this ensures that for sysv4, unix/common
 973   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 974   # after sysv4).
 975   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 976   test -n "$sysnames" && set $sysnames
 977 done
 978
 979 # Add the default directories.
 980 default_sysnames="sysdeps/generic"
 981 sysnames="$names $default_sysnames"
 982 AC_SUBST(sysnames)
 983 # The other names were emitted during the scan.
 984 AC_MSG_RESULT($default_sysnames)
 985
 986 # Collect the list of add-ons that supply partial sysdeps trees.
 987 sysdeps_add_ons=
 988 for add_on in $add_ons; do
 989   case "$add_on" in
 990   /*) xsrcdir= ;;
 991   *) xsrcdir="$srcdir/" ;;
 992   esac
 993
 994   test -d "$xsrcdir$add_on/sysdeps" || {
 995     case "$configured_add_ons " in
 996     *" $add_on "*) ;;
 997     *|'')
 998       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
 999       ;;
1000     esac
1001     continue
1002   }
1003
1004   sysdeps_add_ons="$sysdeps_add_ons $add_on"
1005   case "$sysnames_add_ons" in
1006   *" $add_on/ "*) ;;
1007   *|'')
1008     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
1009     continue ;;
1010   esac
1011
1012   found=no
1013   for d in $sysnames; do
1014     case "$d" in
1015     $add_on/sysdeps/*) ;;
1016     *) continue ;;
1017     esac
1018     (cd "$xsrcdir$d" && for f in *[[!~]]; do
1019        case "$f" in
1020        sys|bits)
1021          for ff in $f/*.h; do
1022            test -d "$ff" || { test -e "$ff" && exit 88; }
1023          done
1024          ;;
1025        *)
1026          test -d "$f" || { test -e "$f" && exit 88; }
1027          ;;
1028        esac
1029      done)
1030     if test $? -eq 88; then
1031       found=yes
1032       break
1033     fi
1034   done
1035   if test $found = no; then
1036     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
1037   fi
1038 done
1039 AC_SUBST(sysdeps_add_ons)
1040
1041
1042 ### Locate tools.
1043
1044 AC_PROG_INSTALL
1045 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
1046   # The makefiles need to use a different form to find it in $srcdir.
1047   INSTALL='\$(..)./scripts/install-sh -c'
1048 fi
1049 AC_PROG_LN_S
1050
1051 LIBC_PROG_BINUTILS
1052
1053 # Accept binutils 2.22 or newer.
1054 AC_CHECK_PROG_VER(AS, $AS, --version,
1055                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
1056                   [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
1057                   AS=: critic_missing="$critic_missing as")
1058 AC_CHECK_PROG_VER(LD, $LD, --version,
1059                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
1060                   [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
1061                   LD=: critic_missing="$critic_missing ld")
1062
1063 # These programs are version sensitive.
1064 AC_CHECK_TOOL_PREFIX
1065 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
1066   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
1067   [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
1068
1069 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
1070   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
1071   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
1072   MSGFMT=: aux_missing="$aux_missing msgfmt")
1073 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1074   [GNU texinfo.* \([0-9][0-9.]*\)],
1075   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
1076   MAKEINFO=: aux_missing="$aux_missing makeinfo")
1077 AC_CHECK_PROG_VER(SED, sed, --version,
1078   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
1079   [3.0[2-9]*|3.[1-9]*|[4-9]*],
1080   SED=: aux_missing="$aux_missing sed")
1081 AC_CHECK_PROG_VER(AWK, gawk, --version,
1082   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
1083   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
1084
1085 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
1086 AC_TRY_COMPILE([], [
1087 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
1088 #error insufficient compiler
1089 #endif],
1090                [libc_cv_compiler_ok=yes],
1091                [libc_cv_compiler_ok=no])])
1092 AS_IF([test $libc_cv_compiler_ok != yes],
1093       [critic_missing="$critic_missing compiler"])
1094
1095 AC_CHECK_TOOL(NM, nm, false)
1096
1097 if test "x$maintainer" = "xyes"; then
1098   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1099   case "x$AUTOCONF" in
1100   xno|x|x:) AUTOCONF=no ;;
1101   *)
1102     AC_CACHE_CHECK(dnl
1103   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1104     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
1105       libc_cv_autoconf_works=yes
1106     else
1107       libc_cv_autoconf_works=no
1108     fi])
1109     test $libc_cv_autoconf_works = yes || AUTOCONF=no
1110     ;;
1111   esac
1112   if test "x$AUTOCONF" = xno; then
1113     aux_missing="$aux_missing autoconf"
1114   fi
1115 else
1116   AUTOCONF=no
1117 fi
1118
1119 # Check for python3 if available, or else python.
1120 AC_CHECK_PROGS(PYTHON_PROG, python3 python,no)
1121 case "x$PYTHON_PROG" in
1122 xno|x|x:) PYTHON_PROG=no ;;
1123 *) ;;
1124 esac
1125
1126 if test "x$PYTHON_PROG" = xno; then
1127   aux_missing="$aux_missing python"
1128 else
1129   PYTHON="$PYTHON_PROG -B"
1130   AC_SUBST(PYTHON)
1131 fi
1132
1133 test -n "$critic_missing" && AC_MSG_ERROR([
1134 *** These critical programs are missing or too old:$critic_missing
1135 *** Check the INSTALL file for required versions.])
1136
1137 test -n "$aux_missing" && AC_MSG_WARN([
1138 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1139 *** some features or tests will be disabled.
1140 *** Check the INSTALL file for required versions.])
1141
1142 # if using special system headers, find out the compiler's sekrit
1143 # header directory and add that to the list.  NOTE: Only does the right
1144 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1145 if test -n "$sysheaders"; then
1146   SYSINCLUDES=-nostdinc
1147   for d in include include-fixed; do
1148     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1149     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1150   done
1151   SYSINCLUDES="$SYSINCLUDES \
1152 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1153   if test -n "$CXX"; then
1154     CXX_SYSINCLUDES=
1155     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1156     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1157       test "x$cxxheaders" != x &&
1158       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1159     done
1160   fi
1161 fi
1162 AC_SUBST(SYSINCLUDES)
1163 AC_SUBST(CXX_SYSINCLUDES)
1164
1165 # Obtain some C++ header file paths.  This is used to make a local
1166 # copy of those headers in Makerules.
1167 if test -n "$CXX"; then
1168   find_cxx_header () {
1169     echo "#include <$1>" | $CXX -M -MP -x c++ - | sed -n "/$1:/{s/:\$//;p}"
1170   }
1171   CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1172   CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1173 fi
1174 AC_SUBST(CXX_CSTDLIB_HEADER)
1175 AC_SUBST(CXX_CMATH_HEADER)
1176
1177 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1178 # since this would lead to problems installing/building glibc.
1179 # LD_LIBRARY_PATH contains the current directory if one of the following
1180 # is true:
1181 # - one of the terminals (":" and ";") is the first or last sign
1182 # - two terminals occur directly after each other
1183 # - the path contains an element with a dot in it
1184 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1185 changequote(,)dnl
1186 case ${LD_LIBRARY_PATH} in
1187   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1188     ld_library_path_setting="contains current directory"
1189     ;;
1190   *)
1191     ld_library_path_setting="ok"
1192     ;;
1193 esac
1194 changequote([,])dnl
1195 AC_MSG_RESULT($ld_library_path_setting)
1196 if test "$ld_library_path_setting" != "ok"; then
1197 AC_MSG_ERROR([
1198 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1199 *** building glibc. Please change the environment variable
1200 *** and run configure again.])
1201 fi
1202
1203 AC_PATH_PROG(BASH_SHELL, bash, no)
1204
1205 AC_PATH_PROG(PERL, perl, no)
1206 if test "$PERL" != no &&
1207    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1208   PERL=no
1209 fi
1210 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1211              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1212 AC_CHECK_PROG_VER(BISON, bison, --version,
1213                   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1214                   [2.7*|[3-9].*|[1-9][0-9]*],
1215                   BISON=no)
1216
1217 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1218 cat > conftest.s <<EOF
1219 .text
1220 foo:
1221 .set glibc_conftest_frobozz,foo
1222 .globl glibc_conftest_frobozz
1223 EOF
1224 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1225 # (but it doesn't work), so we must do a linking check to be sure.
1226 cat > conftest1.c <<\EOF
1227 extern int glibc_conftest_frobozz;
1228 void _start() { glibc_conftest_frobozz = 1; }
1229 EOF
1230 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1231             -nostartfiles -nostdlib $no_ssp \
1232             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1233   libc_cv_asm_set_directive=yes
1234 else
1235   libc_cv_asm_set_directive=no
1236 fi
1237 rm -f conftest*])
1238 if test $libc_cv_asm_set_directive = yes; then
1239   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1240 fi
1241
1242 AC_CACHE_CHECK(linker support for protected data symbol,
1243                libc_cv_protected_data,
1244                [cat > conftest.c <<EOF
1245                 int bar __attribute__ ((visibility ("protected"))) = 1;
1246 EOF
1247                 libc_cv_protected_data=no
1248                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1249                   cat > conftest.c <<EOF
1250                   extern int bar;
1251                   int main (void) { return bar; }
1252 EOF
1253                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1254                     libc_cv_protected_data=yes
1255                   fi
1256                 fi
1257                 rm -f conftest.*
1258                ])
1259 AC_SUBST(libc_cv_protected_data)
1260
1261 AC_CACHE_CHECK(for broken __attribute__((alias())),
1262                libc_cv_broken_alias_attribute,
1263                [cat > conftest.c <<EOF
1264                extern int foo (int x) __asm ("xyzzy");
1265                int bar (int x) { return x; }
1266                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1267                extern int dfoo;
1268                extern __typeof (dfoo) dfoo __asm ("abccb");
1269                int dfoo = 1;
1270 EOF
1271                libc_cv_broken_alias_attribute=yes
1272                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1273                  if grep 'xyzzy' conftest.s >/dev/null &&
1274                     grep 'abccb' conftest.s >/dev/null; then
1275                    libc_cv_broken_alias_attribute=no
1276                  fi
1277                fi
1278                rm -f conftest.c conftest.s
1279                ])
1280 if test $libc_cv_broken_alias_attribute = yes; then
1281   AC_MSG_ERROR(working alias attribute support required)
1282 fi
1283
1284 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1285                libc_cv_have_sdata_section,
1286                [echo "int i;" > conftest.c
1287                 libc_cv_have_sdata_section=no
1288                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1289                    | grep '\.sdata' >/dev/null; then
1290                   libc_cv_have_sdata_section=yes
1291                 fi
1292                 rm -f conftest.c conftest.so
1293                ])
1294 if test $libc_cv_have_sdata_section = yes; then
1295   AC_DEFINE(HAVE_SDATA_SECTION)
1296 fi
1297
1298 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1299                libc_cv_ctors_header, [dnl
1300   libc_cv_ctors_header=yes
1301   LIBC_TRY_LINK_STATIC([
1302 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1303 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1304 ],
1305               [dnl
1306       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1307         { gsub(/\@<:@ */, "@<:@") }
1308         $2 == ".ctors" || $2 == ".dtors" {
1309           size = strtonum("0x" $6)
1310           align = strtonum("0x" $NF)
1311           seen@<:@$2@:>@ = 1
1312           stub@<:@$2@:>@ = size == align * 2
1313         }
1314         END {
1315           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1316           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1317           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1318         }
1319       '], [libc_cv_ctors_header=no])
1320     ], [dnl
1321       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1322     ])
1323 ])
1324 if test $libc_cv_ctors_header = no; then
1325   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1326 fi
1327
1328 AC_CACHE_CHECK(for libunwind-support in compiler,
1329                libc_cv_cc_with_libunwind, [
1330   cat > conftest.c <<EOF
1331 int main (void) { return 0; }
1332 EOF
1333   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1334      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1335     libc_cv_cc_with_libunwind=yes
1336   else
1337     libc_cv_cc_with_libunwind=no
1338   fi
1339   rm -f conftest*])
1340 AC_SUBST(libc_cv_cc_with_libunwind)
1341 if test $libc_cv_cc_with_libunwind = yes; then
1342   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1343 fi
1344
1345 ASFLAGS_config=
1346 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1347                libc_cv_as_noexecstack, [dnl
1348 cat > conftest.c <<EOF
1349 void foo (void) { }
1350 EOF
1351 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1352                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1353    && grep .note.GNU-stack conftest.s >/dev/null \
1354    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1355                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1356 then
1357   libc_cv_as_noexecstack=yes
1358 else
1359   libc_cv_as_noexecstack=no
1360 fi
1361 rm -f conftest*])
1362 if test $libc_cv_as_noexecstack = yes; then
1363   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1364 fi
1365 AC_SUBST(ASFLAGS_config)
1366
1367 AC_CACHE_CHECK(for -z combreloc,
1368                libc_cv_z_combreloc, [dnl
1369 cat > conftest.c <<EOF
1370 extern int bar (int);
1371 extern int mumble;
1372 int foo (void) { return bar (mumble); }
1373 EOF
1374 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1375                         -fPIC -shared $no_ssp -o conftest.so conftest.c
1376                         -nostdlib -nostartfiles
1377                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1378 then
1379 dnl The following test is a bit weak.  We must use a tool which can test
1380 dnl cross-platform since the gcc used can be a cross compiler.  Without
1381 dnl introducing new options this is not easily doable.  Instead use a tool
1382 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1383 dnl look for a section named .rel.dyn.
1384   if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1385     libc_cv_z_combreloc=yes
1386   else
1387     libc_cv_z_combreloc=no
1388   fi
1389 else
1390   libc_cv_z_combreloc=no
1391 fi
1392 rm -f conftest*])
1393 if test "$libc_cv_z_combreloc" = yes; then
1394   AC_DEFINE(HAVE_Z_COMBRELOC)
1395 fi
1396 AC_SUBST(libc_cv_z_combreloc)
1397
1398 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1399                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1400 AC_SUBST(libc_cv_z_execstack)
1401
1402 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1403 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1404 ])
1405
1406 AC_SUBST(libc_cv_fpie)
1407
1408 AC_CACHE_CHECK(for --hash-style option,
1409                libc_cv_hashstyle, [dnl
1410 cat > conftest.c <<EOF
1411 int _start (void) { return 42; }
1412 EOF
1413 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1414                             -fPIC -shared -o conftest.so conftest.c
1415                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1416 then
1417   libc_cv_hashstyle=yes
1418 else
1419   libc_cv_hashstyle=no
1420 fi
1421 rm -f conftest*])
1422 AC_SUBST(libc_cv_hashstyle)
1423
1424 # The linker's default -shared behavior is good enough if it
1425 # does these things that our custom linker scripts ensure that
1426 # all allocated NOTE sections come first.
1427 if test "$use_default_link" = default; then
1428   AC_CACHE_CHECK([for sufficient default -shared layout],
1429                   libc_cv_use_default_link, [dnl
1430   libc_cv_use_default_link=no
1431   cat > conftest.s <<\EOF
1432           .section .note.a,"a",%note
1433           .balign 4
1434           .long 4,4,9
1435           .string "GNU"
1436           .string "foo"
1437           .section .note.b,"a",%note
1438           .balign 4
1439           .long 4,4,9
1440           .string "GNU"
1441           .string "bar"
1442 EOF
1443   if AC_TRY_COMMAND([dnl
1444   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1445        ac_try=`$READELF -S conftest.so | sed -n \
1446          ['${x;p;}
1447           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1448           t a
1449           b
1450           : a
1451           H']`
1452   then
1453     libc_seen_a=no libc_seen_b=no
1454     set -- $ac_try
1455     while test $# -ge 2 -a "$1" = NOTE; do
1456       case "$2" in
1457       .note.a) libc_seen_a=yes ;;
1458       .note.b) libc_seen_b=yes ;;
1459       esac
1460       shift 2
1461     done
1462     case "$libc_seen_a$libc_seen_b" in
1463     yesyes)
1464       libc_cv_use_default_link=yes
1465       ;;
1466     *)
1467       echo >&AS_MESSAGE_LOG_FD "\
1468 $libc_seen_a$libc_seen_b from:
1469 $ac_try"
1470       ;;
1471     esac
1472   fi
1473   rm -f conftest*])
1474   use_default_link=$libc_cv_use_default_link
1475 fi
1476
1477 AC_CACHE_CHECK(for GLOB_DAT reloc,
1478                libc_cv_has_glob_dat, [dnl
1479 cat > conftest.c <<EOF
1480 extern int mumble;
1481 int foo (void) { return mumble; }
1482 EOF
1483 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1484                         -fPIC -shared -o conftest.so conftest.c
1485                         -nostdlib -nostartfiles $no_ssp
1486                         1>&AS_MESSAGE_LOG_FD])
1487 then
1488 dnl look for GLOB_DAT relocation.
1489   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1490     libc_cv_has_glob_dat=yes
1491   else
1492     libc_cv_has_glob_dat=no
1493   fi
1494 else
1495   libc_cv_has_glob_dat=no
1496 fi
1497 rm -f conftest*])
1498 AC_SUBST(libc_cv_has_glob_dat)
1499
1500 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1501 if libc_cv_output_format=`
1502 ${CC-cc} -nostartfiles -nostdlib $no_ssp -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1503 then
1504   :
1505 else
1506   libc_cv_output_format=
1507 fi
1508 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1509 AC_SUBST(libc_cv_output_format)
1510
1511 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1512 cat > conftest.c <<EOF
1513 int foo;
1514 EOF
1515 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1516                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1517 then
1518   libc_cv_fno_toplevel_reorder=yes
1519 else
1520   libc_cv_fno_toplevel_reorder=no
1521 fi
1522 rm -f conftest*])
1523 if test $libc_cv_fno_toplevel_reorder = yes; then
1524   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1525 else
1526   fno_unit_at_a_time=-fno-unit-at-a-time
1527 fi
1528 AC_SUBST(fno_unit_at_a_time)
1529
1530 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1531 [dnl
1532 cat > conftest.c <<EOF
1533 __thread int i;
1534 void foo (void)
1535 {
1536   i = 10;
1537 }
1538 EOF
1539 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1540                    conftest.c 1>&AS_MESSAGE_LOG_FD])
1541 then
1542   libc_cv_mtls_dialect_gnu2=yes
1543 else
1544   libc_cv_mtls_dialect_gnu2=no
1545 fi
1546 rm -f conftest*])
1547 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1548 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1549
1550 AC_CACHE_CHECK(whether cc puts quotes around section names,
1551                libc_cv_have_section_quotes,
1552                [cat > conftest.c <<EOF
1553                 static const int foo
1554                 __attribute__ ((section ("bar"))) = 1;
1555 EOF
1556                 if ${CC-cc} -S conftest.c -o conftest.s; then
1557                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1558                     libc_cv_have_section_quotes=yes
1559                   else
1560                     libc_cv_have_section_quotes=no
1561                   fi
1562                 else
1563                   libc_cv_have_section_quotes=unknown
1564                 fi
1565                 rm -f conftest.{c,s}
1566                 ])
1567 if test $libc_cv_have_section_quotes = yes; then
1568   AC_DEFINE(HAVE_SECTION_QUOTES)
1569 fi
1570
1571 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1572 cat > conftest.c <<\EOF
1573 void zero (void *x)
1574 {
1575   __builtin_memset (x, 0, 1000);
1576 }
1577 EOF
1578 dnl
1579 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1580 then
1581   libc_cv_gcc_builtin_memset=no
1582 else
1583   libc_cv_gcc_builtin_memset=yes
1584 fi
1585 rm -f conftest* ])
1586 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1587   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1588 fi
1589
1590 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1591 cat > conftest.c <<\EOF
1592 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1593 char *foo (const char *a, const char *b)
1594 {
1595   return __builtin_strstr (a, b);
1596 }
1597 EOF
1598 dnl
1599 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1600 then
1601   libc_cv_gcc_builtin_redirection=yes
1602 else
1603   libc_cv_gcc_builtin_redirection=no
1604 fi
1605 rm -f conftest* ])
1606 if test "$libc_cv_gcc_builtin_redirection" = no; then
1607   AC_MSG_ERROR([support for the symbol redirection needed])
1608 fi
1609
1610 dnl Determine how to disable generation of FMA instructions.
1611 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1612                libc_cv_cc_nofma, [dnl
1613 libc_cv_cc_nofma=
1614 for opt in -ffp-contract=off -mno-fused-madd; do
1615   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1616 done])
1617 AC_SUBST(libc_cv_cc_nofma)
1618
1619 if test -n "$submachine"; then
1620   AC_CACHE_CHECK([for compiler option for CPU variant],
1621                  libc_cv_cc_submachine, [dnl
1622   libc_cv_cc_submachine=no
1623   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1624     LIBC_TRY_CC_OPTION([$opt], [
1625       libc_cv_cc_submachine="$opt"
1626       break], [])
1627   done])
1628   if test "x$libc_cv_cc_submachine" = xno; then
1629     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1630   fi
1631 fi
1632 AC_SUBST(libc_cv_cc_submachine)
1633
1634 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1635 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1636 cat > conftest.c <<EOF
1637 void
1638 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1639 foo (void) {}
1640 EOF
1641 libc_cv_cc_loop_to_function=no
1642 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1643 then
1644   libc_cv_cc_loop_to_function=yes
1645 fi
1646 rm -f conftest*])
1647 if test $libc_cv_cc_loop_to_function = yes; then
1648   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1649 fi
1650 AC_SUBST(libc_cv_cc_loop_to_function)
1651
1652 dnl Check whether we have the gd library available.
1653 AC_MSG_CHECKING(for libgd)
1654 if test "$with_gd" != "no"; then
1655   old_CFLAGS="$CFLAGS"
1656   CFLAGS="$CFLAGS $libgd_include"
1657   old_LDFLAGS="$LDFLAGS"
1658   LDFLAGS="$LDFLAGS $libgd_ldflags"
1659   old_LIBS="$LIBS"
1660   LIBS="$LIBS -lgd -lpng -lz -lm"
1661   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1662   CFLAGS="$old_CFLAGS"
1663   LDFLAGS="$old_LDFLAGS"
1664   LIBS="$old_LIBS"
1665 else
1666   LIBGD=no
1667 fi
1668 AC_MSG_RESULT($LIBGD)
1669 AC_SUBST(LIBGD)
1670
1671 # SELinux detection
1672 if test x$with_selinux = xno ; then
1673   have_selinux=no;
1674 else
1675   # See if we have the SELinux library
1676   AC_CHECK_LIB(selinux, is_selinux_enabled,
1677                have_selinux=yes, have_selinux=no)
1678   if test x$with_selinux = xyes ; then
1679     if test x$have_selinux = xno ; then
1680       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1681     fi
1682   fi
1683 fi
1684 # Check if we're building with SELinux support.
1685 if test "x$have_selinux" = xyes; then
1686   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1687
1688   # See if we have the libaudit library
1689   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1690                have_libaudit=yes, have_libaudit=no)
1691   if test "x$have_libaudit" = xyes; then
1692     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1693   fi
1694   AC_SUBST(have_libaudit)
1695
1696   # See if we have the libcap library
1697   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1698   if test "x$have_libcap" = xyes; then
1699     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1700   fi
1701   AC_SUBST(have_libcap)
1702 fi
1703 AC_SUBST(have_selinux)
1704
1705 CPPUNDEFS=
1706 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1707 dnl Since we are building the implementations of the fortified functions here,
1708 dnl having the macro defined interacts very badly.
1709 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1710 [AC_TRY_COMPILE([], [
1711 #ifdef _FORTIFY_SOURCE
1712 # error bogon
1713 #endif],
1714                 [libc_cv_predef_fortify_source=no],
1715                 [libc_cv_predef_fortify_source=yes])])
1716 if test $libc_cv_predef_fortify_source = yes; then
1717   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1718 fi
1719 AC_SUBST(CPPUNDEFS)
1720
1721 # Some linkers on some architectures support __ehdr_start but with
1722 # bugs.  Make sure usage of it does not create relocations in the
1723 # output (as the linker should resolve them all for us).
1724 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1725                libc_cv_ehdr_start, [
1726 old_CFLAGS="$CFLAGS"
1727 old_LDFLAGS="$LDFLAGS"
1728 old_LIBS="$LIBS"
1729 CFLAGS="$CFLAGS -fPIC"
1730 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared $no_ssp"
1731 LIBS=
1732 AC_LINK_IFELSE([AC_LANG_SOURCE([
1733 typedef struct {
1734   char foo;
1735   long val;
1736 } Ehdr;
1737 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1738 long ehdr (void) { return __ehdr_start.val; }
1739 ])],
1740                [if $READELF -r conftest | fgrep __ehdr_start >/dev/null; then
1741                   libc_cv_ehdr_start=broken
1742                 else
1743                   libc_cv_ehdr_start=yes
1744                 fi], [libc_cv_ehdr_start=no])
1745 CFLAGS="$old_CFLAGS"
1746 LDFLAGS="$old_LDFLAGS"
1747 LIBS="$old_LIBS"
1748 ])
1749 if test "$libc_cv_ehdr_start" = yes; then
1750   AC_DEFINE([HAVE_EHDR_START])
1751 elif test "$libc_cv_ehdr_start" = broken; then
1752   AC_MSG_WARN([linker is broken -- you should upgrade])
1753 fi
1754
1755 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1756                libc_cv_builtin_trap, [dnl
1757 libc_cv_builtin_trap=no
1758 AC_TRY_COMPILE([], [__builtin_trap ()], [
1759 libc_undefs=`$NM -u conftest.o |
1760   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1761     2>&AS_MESSAGE_LOG_FD` || {
1762   AC_MSG_ERROR([confusing output from $NM -u])
1763 }
1764 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1765 if test -z "$libc_undefs"; then
1766   libc_cv_builtin_trap=yes
1767 fi])])
1768 if test $libc_cv_builtin_trap = yes; then
1769   AC_DEFINE([HAVE_BUILTIN_TRAP])
1770 fi
1771
1772 dnl C++ feature tests.
1773 AC_LANG_PUSH([C++])
1774
1775 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1776                libc_cv_cxx_thread_local, [
1777 old_CXXFLAGS="$CXXFLAGS"
1778 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1779 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1780 #include <thread>
1781
1782 // Compiler support.
1783 struct S
1784 {
1785   S ();
1786   ~S ();
1787 };
1788 thread_local S s;
1789 S * get () { return &s; }
1790
1791 // libstdc++ support.
1792 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1793 #error __cxa_thread_atexit_impl not supported
1794 #endif
1795 ])],
1796                [libc_cv_cxx_thread_local=yes],
1797                [libc_cv_cxx_thread_local=no])
1798 CXXFLAGS="$old_CXXFLAGS"
1799 ])
1800 AC_SUBST(libc_cv_cxx_thread_local)
1801
1802 AC_LANG_POP([C++])
1803 dnl End of C++ feature tests.
1804
1805 ### End of automated tests.
1806 ### Now run sysdeps configure fragments.
1807
1808 # They also can set these variables.
1809 use_ldconfig=no
1810 ldd_rewrite_script=no
1811 libc_cv_sysconfdir=$sysconfdir
1812 libc_cv_localstatedir=$localstatedir
1813 libc_cv_gcc_unwind_find_fde=no
1814 libc_cv_idn=no
1815
1816 # Iterate over all the sysdep directories we will use, running their
1817 # configure fragments.
1818 for dir in $sysnames; do
1819   case $dir in
1820     /*) dest=$dir ;;
1821     *)  dest=$srcdir/$dir ;;
1822   esac
1823   if test -r $dest/configure; then
1824     AC_MSG_RESULT(running configure fragment for $dir)
1825     . $dest/configure
1826   fi
1827 done
1828
1829 if test x"$build_mathvec" = xnotset; then
1830   build_mathvec=no
1831 fi
1832 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1833
1834 AC_SUBST(libc_extra_cflags)
1835 AC_SUBST(libc_extra_cppflags)
1836
1837 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1838   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1839 fi
1840 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1841
1842 # A sysdeps configure fragment can reset this if IFUNC is not actually
1843 # usable even though the assembler knows how to generate the symbol type.
1844 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1845   AC_DEFINE(HAVE_IFUNC)
1846 fi
1847
1848 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1849   AC_DEFINE(HAVE_GCC_IFUNC)
1850 fi
1851
1852 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1853 # configure fragment can override the value to prevent this AC_DEFINE.
1854 AC_SUBST(use_nscd)
1855 if test "x$use_nscd" != xno; then
1856   AC_DEFINE([USE_NSCD])
1857 fi
1858 if test "x$build_nscd" = xdefault; then
1859   build_nscd=$use_nscd
1860 fi
1861
1862 AC_SUBST(libc_cv_slibdir)
1863 AC_SUBST(libc_cv_rtlddir)
1864 AC_SUBST(libc_cv_complocaledir)
1865 AC_SUBST(libc_cv_sysconfdir)
1866 AC_SUBST(libc_cv_localstatedir)
1867 AC_SUBST(libc_cv_rootsbindir)
1868
1869 if test x$use_ldconfig = xyes; then
1870   AC_DEFINE(USE_LDCONFIG)
1871 fi
1872 AC_SUBST(use_ldconfig)
1873 AC_SUBST(ldd_rewrite_script)
1874
1875 AC_SUBST(static)
1876 AC_SUBST(shared)
1877
1878 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1879 [libc_cv_pic_default=yes
1880 cat > conftest.c <<EOF
1881 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1882 # error PIC is default.
1883 #endif
1884 EOF
1885 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1886   libc_cv_pic_default=no
1887 fi
1888 rm -f conftest.*])
1889 AC_SUBST(libc_cv_pic_default)
1890
1891 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_pie_default,
1892 [libc_cv_pie_default=yes
1893 cat > conftest.c <<EOF
1894 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1895 # error PIE is default.
1896 #endif
1897 EOF
1898 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1899   libc_cv_pie_default=no
1900 fi
1901 rm -f conftest.*])
1902 AC_SUBST(libc_cv_pie_default)
1903
1904 AC_SUBST(profile)
1905 AC_SUBST(static_nss)
1906
1907 AC_SUBST(DEFINES)
1908
1909 dnl See sysdeps/mach/configure.ac for this variable.
1910 AC_SUBST(mach_interface_list)
1911
1912 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1913 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1914 AC_SUBST(VERSION)
1915 AC_SUBST(RELEASE)
1916
1917 AC_CONFIG_FILES([config.make Makefile])
1918 AC_CONFIG_COMMANDS([default],[[
1919 case $CONFIG_FILES in *config.make*)
1920 echo "$config_vars" >> config.make;;
1921 esac
1922 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1923 AC_OUTPUT