configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 # We need the C++ compiler only for testing.
  54 AC_PROG_CXX
  55 AC_CHECK_TOOL(READELF, readelf, false)
  56
  57 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
  58   AC_MSG_ERROR([you must configure in a separate build directory])
  59 fi
  60
  61 # This will get text that should go into config.make.
  62 config_vars=
  63
  64 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  65 AC_ARG_WITH([gd],
  66             AC_HELP_STRING([--with-gd=DIR],
  67                            [find libgd include dir and library with prefix DIR]),
  68             [dnl
  69 case "$with_gd" in
  70 yes|''|no) ;;
  71 *) libgd_include="-I$withval/include"
  72    libgd_ldflags="-L$withval/lib" ;;
  73 esac
  74 ])
  75 AC_ARG_WITH([gd-include],
  76             AC_HELP_STRING([--with-gd-include=DIR],
  77                            [find libgd include files in DIR]),
  78             [dnl
  79 case "$with_gd_include" in
  80 ''|no) ;;
  81 *) libgd_include="-I$withval" ;;
  82 esac
  83 ])
  84 AC_ARG_WITH([gd-lib],
  85             AC_HELP_STRING([--with-gd-lib=DIR],
  86                            [find libgd library files in DIR]),
  87             [dnl
  88 case "$with_gd_lib" in
  89 ''|no) ;;
  90 *) libgd_ldflags="-L$withval" ;;
  91 esac
  92 ])
  93
  94 if test -n "$libgd_include"; then
  95   config_vars="$config_vars
  96 CFLAGS-memusagestat.c = $libgd_include"
  97 fi
  98 if test -n "$libgd_ldflags"; then
  99   config_vars="$config_vars
 100 libgd-LDFLAGS = $libgd_ldflags"
 101 fi
 102
 103 dnl Arguments to specify presence of other packages/features.
 104 AC_ARG_WITH([fp],
 105             AC_HELP_STRING([--with-fp],
 106                            [if using floating-point hardware @<:@default=yes@:>@]),
 107             [with_fp=$withval],
 108             [with_fp=yes])
 109 AC_SUBST(with_fp)
 110 AC_ARG_WITH([binutils],
 111             AC_HELP_STRING([--with-binutils=PATH],
 112                            [specify location of binutils (as and ld)]),
 113             [path_binutils=$withval],
 114             [path_binutils=''])
 115 AC_ARG_WITH([selinux],
 116             AC_HELP_STRING([--with-selinux],
 117                            [if building with SELinux support]),
 118             [with_selinux=$withval],
 119             [with_selinux=auto])
 120
 121 AC_ARG_WITH([headers],
 122             AC_HELP_STRING([--with-headers=PATH],
 123                            [location of system headers to use
 124                             (for example /usr/src/linux/include)
 125                             @<:@default=compiler default@:>@]),
 126             [sysheaders=$withval],
 127             [sysheaders=''])
 128 AC_SUBST(sysheaders)
 129
 130 AC_SUBST(use_default_link)
 131 AC_ARG_WITH([default-link],
 132             AC_HELP_STRING([--with-default-link],
 133                            [do not use explicit linker scripts]),
 134             [use_default_link=$withval],
 135             [use_default_link=default])
 136
 137 AC_ARG_ENABLE([sanity-checks],
 138               AC_HELP_STRING([--disable-sanity-checks],
 139                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 140               [enable_sanity=$enableval],
 141               [enable_sanity=yes])
 142
 143 AC_ARG_ENABLE([shared],
 144               AC_HELP_STRING([--enable-shared],
 145                              [build shared library @<:@default=yes if GNU ld@:>@]),
 146               [shared=$enableval],
 147               [shared=yes])
 148 AC_ARG_ENABLE([profile],
 149               AC_HELP_STRING([--enable-profile],
 150                              [build profiled library @<:@default=no@:>@]),
 151               [profile=$enableval],
 152               [profile=no])
 153
 154 AC_ARG_ENABLE([oldest-abi],
 155               AC_HELP_STRING([--enable-oldest-abi=ABI],
 156                              [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
 157               [oldest_abi=$enableval],
 158               [oldest_abi=no])
 159 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
 160   oldest_abi=default
 161 else
 162   AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
 163 fi
 164 AC_SUBST(oldest_abi)
 165
 166 AC_ARG_ENABLE([hardcoded-path-in-tests],
 167               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 168                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 169               [hardcoded_path_in_tests=$enableval],
 170               [hardcoded_path_in_tests=no])
 171 AC_SUBST(hardcoded_path_in_tests)
 172
 173 AC_ARG_ENABLE([stackguard-randomization],
 174               AC_HELP_STRING([--enable-stackguard-randomization],
 175                              [initialize __stack_chk_guard canary with a random number at program start]),
 176               [enable_stackguard_randomize=$enableval],
 177               [enable_stackguard_randomize=no])
 178 if test "$enable_stackguard_randomize" = yes; then
 179   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 180 fi
 181
 182 AC_ARG_ENABLE([lock-elision],
 183               AC_HELP_STRING([--enable-lock-elision[=yes/no]],
 184                              [Enable lock elision for pthread mutexes by default]),
 185               [enable_lock_elision=$enableval],
 186               [enable_lock_elision=no])
 187 AC_SUBST(enable_lock_elision)
 188 if test "$enable_lock_elision" = yes ; then
 189   AC_DEFINE(ENABLE_LOCK_ELISION)
 190 fi
 191
 192 dnl Generic infrastructure for drop-in additions to libc.
 193 AC_ARG_ENABLE([add-ons],
 194               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 195                              [configure and build add-ons in DIR1,DIR2,...
 196                               search for add-ons if no parameter given]),
 197                              , [enable_add_ons=yes])
 198
 199 AC_ARG_ENABLE([hidden-plt],
 200               AC_HELP_STRING([--disable-hidden-plt],
 201                              [do not hide internal function calls to avoid PLT]),
 202               [hidden=$enableval],
 203               [hidden=yes])
 204 if test "x$hidden" = xno; then
 205   AC_DEFINE(NO_HIDDEN)
 206 fi
 207
 208 AC_ARG_ENABLE([bind-now],
 209               AC_HELP_STRING([--enable-bind-now],
 210                              [disable lazy relocations in DSOs]),
 211               [bindnow=$enableval],
 212               [bindnow=no])
 213 AC_SUBST(bindnow)
 214
 215 dnl On some platforms we cannot use dynamic loading.  We must provide
 216 dnl static NSS modules.
 217 AC_ARG_ENABLE([static-nss],
 218               AC_HELP_STRING([--enable-static-nss],
 219                              [build static NSS modules @<:@default=no@:>@]),
 220               [static_nss=$enableval],
 221               [static_nss=no])
 222 dnl Enable static NSS also if we build no shared objects.
 223 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 224   static_nss=yes
 225   AC_DEFINE(DO_STATIC_NSS)
 226 fi
 227
 228 AC_ARG_ENABLE([force-install],
 229               AC_HELP_STRING([--disable-force-install],
 230                              [don't force installation of files from this package, even if they are older than the installed files]),
 231               [force_install=$enableval],
 232               [force_install=yes])
 233 AC_SUBST(force_install)
 234
 235 AC_ARG_ENABLE([maintainer-mode],
 236               AC_HELP_STRING([--enable-maintainer-mode],
 237                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 238               [maintainer=$enableval],
 239               [maintainer=no])
 240
 241 dnl On some platforms we allow dropping compatibility with all kernel
 242 dnl versions.
 243 AC_ARG_ENABLE([kernel],
 244               AC_HELP_STRING([--enable-kernel=VERSION],
 245                              [compile for compatibility with kernel not older than VERSION]),
 246               [minimum_kernel=$enableval],
 247               [])
 248 dnl Prevent unreasonable values.
 249 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 250   # Better nothing than this.
 251   minimum_kernel=""
 252 else
 253   if test "$minimum_kernel" = current; then
 254     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 255   fi
 256 fi
 257
 258 dnl For the development we sometimes want gcc to issue even more warnings.
 259 dnl This is not the default since many of the extra warnings are not
 260 dnl appropriate.
 261 AC_ARG_ENABLE([all-warnings],
 262               AC_HELP_STRING([--enable-all-warnings],
 263                              [enable all useful warnings gcc can issue]),
 264               [all_warnings=$enableval],
 265               [])
 266 AC_SUBST(all_warnings)
 267
 268 AC_ARG_ENABLE([multi-arch],
 269               AC_HELP_STRING([--enable-multi-arch],
 270                              [enable single DSO with optimizations for multiple architectures]),
 271               [multi_arch=$enableval],
 272               [multi_arch=default])
 273
 274 AC_ARG_ENABLE([nss-crypt],
 275               AC_HELP_STRING([--enable-nss-crypt],
 276                              [enable libcrypt to use nss]),
 277               [nss_crypt=$enableval],
 278               [nss_crypt=no])
 279 if test x$nss_crypt = xyes; then
 280   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 281   if test $? -ne 0; then
 282     AC_MSG_ERROR([cannot find include directory with nss-config])
 283   fi
 284   old_CFLAGS="$CFLAGS"
 285   CFLAGS="$CFLAGS $nss_includes"
 286   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 287 #include <hasht.h>
 288 #include <nsslowhash.h>
 289 void f (void) { NSSLOW_Init (); }])],
 290              libc_cv_nss_crypt=yes,
 291              AC_MSG_ERROR([
 292 cannot find NSS headers with lowlevel hash function interfaces]))
 293   old_LIBS="$LIBS"
 294   LIBS="$LIBS -lfreebl3"
 295   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 296 #include <hasht.h>
 297 #include <nsslowhash.h>],
 298                                   [NSSLOW_Init();])],
 299                  libc_cv_nss_crypt=yes,
 300                  AC_MSG_ERROR([
 301 cannot link program using lowlevel NSS hash functions]))
 302   CFLAGS="$old_CFLAGS"
 303   LIBS="$old_LIBS"
 304 else
 305   libc_cv_nss_crypt=no
 306 fi
 307 AC_SUBST(libc_cv_nss_crypt)
 308
 309
 310 AC_ARG_ENABLE([obsolete-rpc],
 311               AC_HELP_STRING([--enable-obsolete-rpc],
 312                              [build and install the obsolete RPC code for link-time usage]),
 313               [link_obsolete_rpc=$enableval],
 314               [link_obsolete_rpc=no])
 315 AC_SUBST(link_obsolete_rpc)
 316
 317 if test "$link_obsolete_rpc" = yes; then
 318   AC_DEFINE(LINK_OBSOLETE_RPC)
 319 fi
 320
 321 AC_ARG_ENABLE([systemtap],
 322               [AS_HELP_STRING([--enable-systemtap],
 323                [enable systemtap static probe points @<:@default=no@:>@])],
 324               [systemtap=$enableval],
 325               [systemtap=no])
 326 if test "x$systemtap" != xno; then
 327   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 328   old_CFLAGS="$CFLAGS"
 329   CFLAGS="-std=gnu99 $CFLAGS"
 330   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 331 void foo (int i, void *p)
 332 {
 333   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 334        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 335 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 336   CFLAGS="$old_CFLAGS"])
 337   if test $libc_cv_sdt = yes; then
 338     AC_DEFINE([USE_STAP_PROBE])
 339   elif test "x$systemtap" != xauto; then
 340     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 341   fi
 342 fi
 343
 344 AC_ARG_ENABLE([build-nscd],
 345               [AS_HELP_STRING([--disable-build-nscd],
 346                [disable building and installing the nscd daemon])],
 347               [build_nscd=$enableval],
 348               [build_nscd=default])
 349 AC_SUBST(build_nscd)
 350
 351 # Note the use of $use_nscd is near the bottom of the file.
 352 AC_ARG_ENABLE([nscd],
 353               [AS_HELP_STRING([--disable-nscd],
 354                [library functions will not contact the nscd daemon])],
 355               [use_nscd=$enableval],
 356               [use_nscd=yes])
 357
 358 AC_ARG_ENABLE([pt_chown],
 359               [AS_HELP_STRING([--enable-pt_chown],
 360                [Enable building and installing pt_chown])],
 361               [build_pt_chown=$enableval],
 362               [build_pt_chown=no])
 363 AC_SUBST(build_pt_chown)
 364 if test "$build_pt_chown" = yes; then
 365   AC_DEFINE(HAVE_PT_CHOWN)
 366 fi
 367
 368 # The way shlib-versions is used to generate soversions.mk uses a
 369 # fairly simplistic model for name recognition that can't distinguish
 370 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 371 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 372 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 373 case "$host_os" in
 374 linux*)
 375   ;;
 376 gnu*)
 377   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 378   ;;
 379 esac
 380
 381 # We keep the original values in `$config_*' and never modify them, so we
 382 # can write them unchanged into config.make.  Everything else uses
 383 # $machine, $vendor, and $os, and changes them whenever convenient.
 384 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 385
 386 # Don't allow vendor == "unknown"
 387 test "$config_vendor" = unknown && config_vendor=
 388 config_os="`echo $config_os | sed 's/^unknown-//'`"
 389
 390 # Some configurations imply other options.
 391 elf=yes
 392
 393 # The configure fragment of an add-on port can modify these to supplement
 394 # or override the table in the case statement below.  No fragment should
 395 # ever change the config_* variables, however.
 396 machine=$config_machine
 397 vendor=$config_vendor
 398 os=$config_os
 399 base_os=''
 400
 401 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 402 # Unify this here.
 403 if test "$machine" = rs6000; then
 404   machine="powerpc"
 405 fi
 406
 407 # Braindead PowerPC box with absolutely no FPU.
 408 case "$machine-$host_os" in
 409   powerpc*-*soft)
 410     with_fp=no
 411     ;;
 412 esac
 413
 414 submachine=
 415 AC_ARG_WITH([cpu],
 416             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 417             [dnl
 418   case "$withval" in
 419   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 420   no) ;;
 421   *) submachine="$withval" ;;
 422   esac
 423 ])
 424
 425 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
 426 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 427
 428 # An add-on can set this when it wants to disable the sanity check below.
 429 libc_config_ok=no
 430
 431 dnl Having this here, though empty, makes sure that if add-ons' fragments
 432 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 433 dnl our AC_OUTPUT will actually use it.
 434 AC_CONFIG_SUBDIRS()
 435
 436 case "$enable_add_ons" in
 437 ''|no) add_ons= ;;
 438 yes|'*')
 439  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 440           sed 's@/[[^/]]*$@@' | sort | uniq`
 441          add_ons_automatic=yes
 442          ;;
 443 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 444        add_ons_automatic=no ;;
 445 esac
 446
 447 configured_add_ons=
 448 add_ons_sfx=
 449 add_ons_pfx=
 450 if test x"$add_ons" != x; then
 451   for f in $add_ons; do
 452     # Some sanity checks
 453     case "$f" in
 454     crypt)
 455       AC_MSG_ERROR([
 456 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 457 *** part of glibc and using the old add-on will not work with this
 458 *** release.  Start again with fresh sources and without the old
 459 *** \`crypt' add-on.])
 460     ;;
 461     localedata)
 462       AC_MSG_ERROR([
 463 *** It seems that you're using an old \`localedata' add-on.  localedata
 464 *** is now part of glibc and using the old add-on will not work with
 465 *** this release.  Start again with fresh sources and without the old
 466 *** \`localedata' add-on.])
 467     ;;
 468     esac
 469   done
 470
 471   # Now source each add-on's configure fragment.
 472   # The fragments can use $srcdir/$libc_add_on to find themselves,
 473   # and test $add_ons_automatic to see if they were explicitly requested.
 474   # A fragment can clear (or even change) $libc_add_on to affect
 475   # whether it goes into the list to be actually used in the build.
 476   use_add_ons=
 477   for libc_add_on in $add_ons; do
 478     # Test whether such a directory really exists.
 479     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 480     case "$libc_add_on" in
 481     /*)
 482       libc_add_on_srcdir=$libc_add_on
 483       ;;
 484     *)
 485       test -d "$srcdir/$libc_add_on" || {
 486         if test -d "$libc_add_on"; then
 487           libc_add_on="`pwd`/$libc_add_on"
 488         else
 489           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 490         fi
 491       }
 492       libc_add_on_srcdir=$srcdir/$libc_add_on
 493       ;;
 494     esac
 495
 496     libc_add_on_frag=$libc_add_on_srcdir/configure
 497     libc_add_on_canonical=
 498     libc_add_on_config_subdirs=
 499     if test -r "$libc_add_on_frag"; then
 500       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 501       libc_add_on_canonical=unknown
 502       libc_add_on_subdirs=
 503       . "$libc_add_on_frag"
 504       test -z "$libc_add_on" || {
 505         configured_add_ons="$configured_add_ons $libc_add_on"
 506         if test "x$libc_add_on_canonical" = xunknown; then
 507           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 508         fi
 509         for d in $libc_add_on_subdirs; do
 510           case "$libc_add_on" in
 511           /*) subdir_srcdir="$libc_add_on" ;;
 512           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 513           esac
 514           case "$d" in
 515           .)
 516             d="${libc_add_on_canonical:-$libc_add_on}"
 517             ;;
 518           /*)
 519             subdir_srcdir="$d"
 520             ;;
 521           *)
 522             subdir_srcdir="$subdir_srcdir/$d"
 523             ;;
 524           esac
 525           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 526           add_on_subdirs="$add_on_subdirs $d"
 527           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 528 $d-srcdir = $subdir_srcdir"
 529         done
 530         for d in $libc_add_on_config_subdirs; do
 531           case "$d" in
 532           /*) AC_MSG_ERROR(dnl
 533 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 534           esac
 535           if test ! -d "$libc_add_on_srcdir/$d"; then
 536             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 537           fi
 538           case "$libc_add_on" in
 539           /*) AC_MSG_ERROR(dnl
 540 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 541           esac
 542           subdirs="$subdirs $libc_add_on/$d"
 543         done
 544       }
 545     fi
 546     if test -n "$libc_add_on"; then
 547       LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
 548       use_add_ons="$use_add_ons $libc_add_on"
 549       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 550       test -z "$libc_add_on_canonical" ||
 551       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 552     fi
 553   done
 554   # Use echo to strip excess whitespace.
 555   add_ons="`echo $use_add_ons`"
 556 fi
 557 AC_SUBST(add_ons)
 558 AC_SUBST(add_on_subdirs)
 559
 560
 561 ###
 562 ### I put this here to prevent those annoying emails from people who cannot
 563 ### read and try to compile glibc on unsupported platforms.  --drepper
 564 ###
 565 ### By using the undocumented --enable-hacker-mode option for configure
 566 ### one can skip this test to make the configuration not fail for unsupported
 567 ### platforms.
 568 ###
 569 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 570   case "$machine-$host_os" in
 571   *-linux* | *-gnu*)
 572     ;;
 573   *)
 574     echo "*** The GNU C library is currently not available for this platform."
 575     echo "*** So far nobody cared to port it and if there is no volunteer it"
 576     echo "*** might never happen.  So, if you have interest to see glibc on"
 577     echo "*** this platform visit"
 578     echo "***   http://www.gnu.org/software/libc/porting.html"
 579     echo "*** and join the group of porters"
 580     exit 1
 581     ;;
 582   esac
 583 fi
 584
 585 dnl We need to use [ and ] for other purposes for a while now.
 586 changequote(,)dnl
 587 # Expand the configuration machine name into a subdirectory by architecture
 588 # type and particular chip.  If an add-on configure fragment already set
 589 # base_machine, we don't change it.
 590 test -n "$base_machine" || case "$machine" in
 591 i[4567]86)      base_machine=i386 machine=i386/$machine ;;
 592 powerpc64*)     base_machine=powerpc machine=powerpc/powerpc64 ;;
 593 powerpc*)       base_machine=powerpc machine=powerpc/powerpc32 ;;
 594 s390)           base_machine=s390 machine=s390/s390-32 ;;
 595 s390x)          base_machine=s390 machine=s390/s390-64 ;;
 596 sh3*)           base_machine=sh machine=sh/sh3 ;;
 597 sh4*)           base_machine=sh machine=sh/sh4 ;;
 598 sparc | sparcv[67])
 599                 base_machine=sparc machine=sparc/sparc32 ;;
 600 sparcv8 | supersparc | hypersparc)
 601                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 602 sparcv8plus | sparcv8plusa | sparcv9)
 603                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 604 sparcv8plusb | sparcv9b)
 605                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
 606 sparcv9v)
 607                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
 608 sparcv9v2)
 609                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
 610 sparc64)
 611                 base_machine=sparc machine=sparc/sparc64 ;;
 612 sparc64b)
 613                 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
 614 sparc64v)
 615                 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
 616 sparc64v2)
 617                 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
 618 *)              base_machine=$machine ;;
 619 esac
 620 changequote([,])dnl
 621 AC_SUBST(base_machine)
 622
 623 if test "$base_machine" = "i386"; then
 624   AC_DEFINE(USE_REGPARMS)
 625 fi
 626
 627 # For the multi-arch option we need support in the assembler & linker.
 628 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 629                libc_cv_ld_gnu_indirect_function, [dnl
 630 cat > conftest.S <<EOF
 631 .type foo,%gnu_indirect_function
 632 foo:
 633 .globl _start
 634 _start:
 635 .globl __start
 636 __start:
 637 .data
 638 #ifdef _LP64
 639 .quad foo
 640 #else
 641 .long foo
 642 #endif
 643 EOF
 644 libc_cv_ld_gnu_indirect_function=no
 645 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 646             -nostartfiles -nostdlib \
 647             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 648   # Do a link to see if the backend supports IFUNC relocs.
 649   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 650   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 651     libc_cv_ld_gnu_indirect_function=yes
 652   }
 653 fi
 654 rm -f conftest*])
 655
 656 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 657 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 658 cat > conftest.s <<EOF
 659 .text
 660 EOF
 661 libc_cv_dot_text=
 662 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 663   libc_cv_dot_text=.text
 664 fi
 665 rm -f conftest*])
 666 if test -z "$libc_cv_dot_text"; then
 667   AC_MSG_RESULT(no)
 668 else
 669   AC_MSG_RESULT(yes)
 670 fi
 671
 672 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 673   if test x"$multi_arch" = xyes; then
 674     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 675   else
 676     multi_arch=no
 677   fi
 678 fi
 679 multi_arch_d=
 680 if test x"$multi_arch" != xno; then
 681   multi_arch_d=/multiarch
 682 fi
 683
 684 # Compute the list of sysdep directories for this configuration.
 685 # This can take a while to compute.
 686 sysdep_dir=$srcdir/sysdeps
 687 AC_MSG_CHECKING(sysdep dirs)
 688 dnl We need to use [ and ] for other purposes for a while now.
 689 changequote(,)dnl
 690 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 691 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 692
 693 test "x$base_os" != x || case "$os" in
 694 gnu*)
 695   base_os=mach/hurd ;;
 696 linux*)
 697   base_os=unix/sysv ;;
 698 esac
 699
 700 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 701 tail=$os
 702 ostry=$os
 703 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 704   ostry="$ostry /$o"
 705   tail=$o
 706 done
 707 o=`echo $tail | sed 's/[0-9]*$//'`
 708 if test $o != $tail; then
 709   ostry="$ostry /$o"
 710 fi
 711 # For linux-gnu, try linux-gnu, then linux.
 712 o=`echo $tail | sed 's/-.*$//'`
 713 if test $o != $tail; then
 714   ostry="$ostry /$o"
 715 fi
 716
 717 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 718 base=
 719 tail=$base_os
 720 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 721   set $b
 722   base="$base /$1"
 723   tail="$2"
 724 done
 725
 726 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 727 mach=
 728 tail=$machine${submachine:+/$submachine}
 729 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 730   set $m
 731   # Prepend the machine's FPU directory unless --without-fp.
 732   if test "$with_fp" = yes; then
 733     maybe_fpu=/fpu
 734   else
 735     maybe_fpu=/nofpu
 736   fi
 737   # For each machine term, try it with and then without /multiarch.
 738   for try_fpu in $maybe_fpu ''; do
 739     for try_multi in $multi_arch_d ''; do
 740       mach="$mach /$1$try_fpu$try_multi"
 741     done
 742   done
 743   tail="$2"
 744 done
 745
 746 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 747 changequote([,])dnl
 748
 749 # Find what sysdep directories exist.
 750 sysnames_add_ons=
 751 sysnames=
 752 for b in $base ''; do
 753   for m0 in $mach ''; do
 754     for v in /$vendor ''; do
 755       test "$v" = / && continue
 756       for o in /$ostry ''; do
 757         test "$o" = / && continue
 758         for m in $mach ''; do
 759           for d in $add_ons_pfx ''; do
 760             for a in $add_ons_sfx ''; do
 761               try_suffix="$m0$b$v$o$m"
 762               if test -n "$try_suffix"; then
 763                 try_srcdir="${srcdir}/"
 764                 case "$d" in
 765                 /*) try_srcdir= ;;
 766                 esac
 767                 try="${d}sysdeps$try_suffix$a"
 768                 test -n "$enable_debug_configure" &&
 769                 echo "$0 [DEBUG]: try $try" >&2
 770                 if test -d "$try_srcdir$try"; then
 771                   sysnames="$sysnames $try"
 772                   { test -n "$o" || test -n "$b"; } && os_used=t
 773                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 774                   case x${m0:-$m} in
 775                   x*/$submachine) submachine_used=t ;;
 776                   esac
 777                   if test -n "$d"; then
 778                     case "$sysnames_add_ons" in
 779                     *" $d "*) ;;
 780                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 781                     esac
 782                   fi
 783                 fi
 784               fi
 785             done
 786           done
 787         done
 788       done
 789     done
 790   done
 791 done
 792
 793 # If the assembler supports gnu_indirect_function symbol type and the
 794 # architecture supports multi-arch, we enable multi-arch by default.
 795 case $sysnames_add_ons$sysnames in
 796 *"$multi_arch_d"*)
 797   ;;
 798 *)
 799   test x"$multi_arch" = xdefault && multi_arch=no
 800   ;;
 801 esac
 802 if test x"$multi_arch" != xno; then
 803   AC_DEFINE(USE_MULTIARCH)
 804 fi
 805 AC_SUBST(multi_arch)
 806
 807 if test -z "$os_used" && test "$os" != none; then
 808   AC_MSG_ERROR(Operating system $os is not supported.)
 809 fi
 810 if test -z "$machine_used" && test "$machine" != none; then
 811   AC_MSG_ERROR(The $machine is not supported.)
 812 fi
 813 if test -z "$submachine_used" && test -n "$submachine"; then
 814   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 815 fi
 816 AC_SUBST(submachine)
 817
 818 # We have now validated the configuration.
 819
 820 # Expand the list of system names into a full list of directories
 821 # from each element's parent name and Implies file (if present).
 822 set $sysnames
 823 names=
 824 while test $# -gt 0; do
 825   name=$1
 826   shift
 827
 828   case " $names " in *" $name "*)
 829     # Already in the list.
 830     continue
 831   esac
 832
 833   # Report each name as we discover it, so there is no long pause in output.
 834   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 835
 836   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 837
 838   case $name in
 839     /*) xsrcdir= ;;
 840     *)  xsrcdir=$srcdir/ ;;
 841   esac
 842   test -n "$enable_debug_configure" &&
 843   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 844
 845   for implies_file in Implies Implies-before Implies-after; do
 846     implies_type=`echo $implies_file | sed s/-/_/`
 847     eval ${implies_type}=
 848     if test -f $xsrcdir$name/$implies_file; then
 849       # Collect more names from the `Implies' file (removing comments).
 850       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 851       for x in $implied_candidate; do
 852         found=no
 853         if test -d $xsrcdir$name_base/$x; then
 854           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 855           found=yes
 856         fi
 857         for d in $add_ons_pfx ''; do
 858           try="${d}sysdeps/$x"
 859           case $d in
 860            /*) try_srcdir= ;;
 861            *) try_srcdir=$srcdir/ ;;
 862           esac
 863           test -n "$enable_debug_configure" &&
 864            echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
 865           if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 866           then
 867             eval "${implies_type}=\"\$${implies_type} \$try\""
 868             found=yes
 869             case "$sysnames_add_ons" in
 870             *" $d "*) ;;
 871             *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 872             esac
 873           fi
 874         done
 875         if test $found = no; then
 876           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 877         fi
 878       done
 879     fi
 880   done
 881
 882   # Add NAME to the list of names.
 883   names="$names $name"
 884
 885   # Find the parent of NAME, using the empty string if it has none.
 886 changequote(,)dnl
 887   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 888 changequote([,])dnl
 889
 890   test -n "$enable_debug_configure" &&
 891     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 892 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 893
 894   # Add the names implied by NAME, and NAME's parent (if it has one), to
 895   # the list of names to be processed (the argument list).  We prepend the
 896   # implied names to the list and append the parent.  We want implied
 897   # directories to come before further directories inferred from the
 898   # configuration components; this ensures that for sysv4, unix/common
 899   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 900   # after sysv4).
 901   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 902   test -n "$sysnames" && set $sysnames
 903 done
 904
 905 # Add the default directories.
 906 default_sysnames="sysdeps/generic"
 907 sysnames="$names $default_sysnames"
 908 AC_SUBST(sysnames)
 909 # The other names were emitted during the scan.
 910 AC_MSG_RESULT($default_sysnames)
 911
 912 # Collect the list of add-ons that supply partial sysdeps trees.
 913 sysdeps_add_ons=
 914 for add_on in $add_ons; do
 915   case "$add_on" in
 916   /*) xsrcdir= ;;
 917   *) xsrcdir="$srcdir/" ;;
 918   esac
 919
 920   test -d "$xsrcdir$add_on/sysdeps" || {
 921     case "$configured_add_ons " in
 922     *" $add_on "*) ;;
 923     *|'')
 924       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
 925       ;;
 926     esac
 927     continue
 928   }
 929
 930   sysdeps_add_ons="$sysdeps_add_ons $add_on"
 931   case "$sysnames_add_ons" in
 932   *" $add_on/ "*) ;;
 933   *|'')
 934     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
 935     continue ;;
 936   esac
 937
 938   found=no
 939   for d in $sysnames; do
 940     case "$d" in
 941     $add_on/sysdeps/*) ;;
 942     *) continue ;;
 943     esac
 944     (cd "$xsrcdir$d" && for f in *[[!~]]; do
 945        case "$f" in
 946        sys|bits)
 947          for ff in $f/*.h; do
 948            test -d "$ff" || { test -e "$ff" && exit 88; }
 949          done
 950          ;;
 951        *)
 952          test -d "$f" || { test -e "$f" && exit 88; }
 953          ;;
 954        esac
 955      done)
 956     if test $? -eq 88; then
 957       found=yes
 958       break
 959     fi
 960   done
 961   if test $found = no; then
 962     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
 963   fi
 964 done
 965 AC_SUBST(sysdeps_add_ons)
 966
 967
 968 ### Locate tools.
 969
 970 AC_PROG_INSTALL
 971 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 972   # The makefiles need to use a different form to find it in $srcdir.
 973   INSTALL='\$(..)./scripts/install-sh -c'
 974 fi
 975 AC_PROG_LN_S
 976
 977 LIBC_PROG_BINUTILS
 978
 979 # Accept binutils 2.20 or newer.
 980 AC_CHECK_PROG_VER(AS, $AS, --version,
 981                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 982                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
 983 AC_CHECK_PROG_VER(LD, $LD, --version,
 984                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 985                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
 986
 987 # These programs are version sensitive.
 988 AC_CHECK_TOOL_PREFIX
 989 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 990   [version \([egcygnustpi-]*[0-9.]*\)], [4.[4-9].* | 4.[1-9][0-9].* | [5-9].* ],
 991   critic_missing="$critic_missing gcc")
 992 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 993   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 994   [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
 995
 996 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 997   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 998   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 999   MSGFMT=: aux_missing="$aux_missing msgfmt")
1000 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1001   [GNU texinfo.* \([0-9][0-9.]*\)],
1002   [4.[5-9]*|4.[1-9][0-9]*|[5-9].*],
1003   MAKEINFO=: aux_missing="$aux_missing makeinfo")
1004 AC_CHECK_PROG_VER(SED, sed, --version,
1005   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
1006   [3.0[2-9]*|3.[1-9]*|[4-9]*],
1007   SED=: aux_missing="$aux_missing sed")
1008 AC_CHECK_PROG_VER(AWK, gawk, --version,
1009   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
1010   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
1011
1012 AC_CHECK_TOOL(NM, nm, false)
1013
1014 if test "x$maintainer" = "xyes"; then
1015   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1016   case "x$AUTOCONF" in
1017   xno|x|x:) AUTOCONF=no ;;
1018   *)
1019     AC_CACHE_CHECK(dnl
1020   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1021     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
1022       libc_cv_autoconf_works=yes
1023     else
1024       libc_cv_autoconf_works=no
1025     fi])
1026     test $libc_cv_autoconf_works = yes || AUTOCONF=no
1027     ;;
1028   esac
1029   if test "x$AUTOCONF" = xno; then
1030     aux_missing="$aux_missing autoconf"
1031   fi
1032 else
1033   AUTOCONF=no
1034 fi
1035
1036 test -n "$critic_missing" && AC_MSG_ERROR([
1037 *** These critical programs are missing or too old:$critic_missing
1038 *** Check the INSTALL file for required versions.])
1039
1040 test -n "$aux_missing" && AC_MSG_WARN([
1041 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1042 *** some features will be disabled.
1043 *** Check the INSTALL file for required versions.])
1044
1045 # if using special system headers, find out the compiler's sekrit
1046 # header directory and add that to the list.  NOTE: Only does the right
1047 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1048 if test -n "$sysheaders"; then
1049   SYSINCLUDES=-nostdinc
1050   for d in include include-fixed; do
1051     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1052     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1053   done
1054   SYSINCLUDES="$SYSINCLUDES \
1055 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1056   if test -n "$CXX"; then
1057     CXX_SYSINCLUDES=
1058     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1059     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1060       test "x$cxxheaders" != x &&
1061       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1062     done
1063   fi
1064 fi
1065 AC_SUBST(SYSINCLUDES)
1066 AC_SUBST(CXX_SYSINCLUDES)
1067
1068 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1069 # since this would lead to problems installing/building glibc.
1070 # LD_LIBRARY_PATH contains the current directory if one of the following
1071 # is true:
1072 # - one of the terminals (":" and ";") is the first or last sign
1073 # - two terminals occur directly after each other
1074 # - the path contains an element with a dot in it
1075 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1076 changequote(,)dnl
1077 case ${LD_LIBRARY_PATH} in
1078   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1079     ld_library_path_setting="contains current directory"
1080     ;;
1081   *)
1082     ld_library_path_setting="ok"
1083     ;;
1084 esac
1085 changequote([,])dnl
1086 AC_MSG_RESULT($ld_library_path_setting)
1087 if test "$ld_library_path_setting" != "ok"; then
1088 AC_MSG_ERROR([
1089 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1090 *** building glibc. Please change the environment variable
1091 *** and run configure again.])
1092 fi
1093
1094 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1095 if $CC -v -static-libgcc 2>&1 | grep 'unrecognized option.*static-libgcc' >/dev/null; then
1096   libc_cv_gcc_static_libgcc=
1097 else
1098   libc_cv_gcc_static_libgcc=-static-libgcc
1099 fi])
1100 AC_SUBST(libc_cv_gcc_static_libgcc)
1101
1102 AC_PATH_PROG(BASH_SHELL, bash, no)
1103
1104 AC_PATH_PROG(PERL, perl, no)
1105 if test "$PERL" != no &&
1106    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1107   PERL=no
1108 fi
1109 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1110              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1111 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1112
1113 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1114 AC_TRY_COMPILE(dnl
1115 [#define __need_size_t
1116 #define __need_wchar_t
1117 #include <stddef.h>
1118 #define __need_NULL
1119 #include <stddef.h>], [size_t size; wchar_t wchar;
1120 #ifdef offsetof
1121 #error stddef.h ignored __need_*
1122 #endif
1123 if (&size == NULL || &wchar == NULL) abort ();],
1124                libc_cv_friendly_stddef=yes,
1125                libc_cv_friendly_stddef=no)])
1126 if test $libc_cv_friendly_stddef = yes; then
1127   config_vars="$config_vars
1128 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1129 fi
1130
1131 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1132                libc_cv_need_minus_P, [dnl
1133 cat > conftest.S <<EOF
1134 #include "confdefs.h"
1135 /* Nothing whatsoever.  */
1136 EOF
1137 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1138   libc_cv_need_minus_P=no
1139 else
1140   libc_cv_need_minus_P=yes
1141 fi
1142 rm -f conftest*])
1143 if test $libc_cv_need_minus_P = yes; then
1144   config_vars="$config_vars
1145 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1146 fi
1147
1148 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1149 cat > conftest.s <<EOF
1150 ${libc_cv_dot_text}
1151 foo:
1152 .set glibc_conftest_frobozz,foo
1153 .globl glibc_conftest_frobozz
1154 EOF
1155 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1156 # (but it doesn't work), so we must do a linking check to be sure.
1157 cat > conftest1.c <<\EOF
1158 extern int glibc_conftest_frobozz;
1159 void _start() { glibc_conftest_frobozz = 1; }
1160 EOF
1161 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1162             -nostartfiles -nostdlib \
1163             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1164   libc_cv_asm_set_directive=yes
1165 else
1166   libc_cv_asm_set_directive=no
1167 fi
1168 rm -f conftest*])
1169 if test $libc_cv_asm_set_directive = yes; then
1170   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1171 fi
1172
1173 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1174                libc_cv_asm_unique_object, [dnl
1175 cat > conftest.s <<EOF
1176 ${libc_cv_dot_text}
1177 _sym:
1178 .type _sym, %gnu_unique_object
1179 EOF
1180 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1181   libc_cv_asm_unique_object=yes
1182 else
1183   libc_cv_asm_unique_object=no
1184 fi
1185 rm -f conftest*])
1186 if test $libc_cv_asm_unique_object = yes; then
1187   AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1188 fi
1189
1190 AC_CACHE_CHECK(for .previous assembler directive,
1191                libc_cv_asm_previous_directive, [dnl
1192 cat > conftest.s <<EOF
1193 .section foo_section
1194 .previous
1195 EOF
1196 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1197   libc_cv_asm_previous_directive=yes
1198 else
1199   libc_cv_asm_previous_directive=no
1200 fi
1201 rm -f conftest*])
1202 if test $libc_cv_asm_previous_directive = yes; then
1203   AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1204 else
1205   AC_CACHE_CHECK(for .popsection assembler directive,
1206                  libc_cv_asm_popsection_directive, [dnl
1207   cat > conftest.s <<EOF
1208 .pushsection foo_section
1209 .popsection
1210 EOF
1211   if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1212     libc_cv_asm_popsection_directive=yes
1213   else
1214     libc_cv_asm_popsection_directive=no
1215   fi
1216   rm -f conftest*])
1217   if test $libc_cv_asm_popsection_directive = yes; then
1218     AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1219   fi
1220 fi
1221 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1222                libc_cv_asm_protected_directive, [dnl
1223 cat > conftest.s <<EOF
1224 .protected foo
1225 foo:
1226 .hidden bar
1227 bar:
1228 EOF
1229 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1230   libc_cv_asm_protected_directive=yes
1231 else
1232   AC_MSG_ERROR(assembler support for symbol visibility is required)
1233 fi
1234 rm -f conftest*])
1235
1236 if test $libc_cv_asm_protected_directive = yes; then
1237   AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1238                  libc_cv_visibility_attribute,
1239                  [cat > conftest.c <<EOF
1240                   int foo __attribute__ ((visibility ("hidden"))) = 1;
1241                   int bar __attribute__ ((visibility ("protected"))) = 1;
1242 EOF
1243                   libc_cv_visibility_attribute=no
1244                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1245                     if grep '\.hidden.*foo' conftest.s >/dev/null; then
1246                       if grep '\.protected.*bar' conftest.s >/dev/null; then
1247                         libc_cv_visibility_attribute=yes
1248                       fi
1249                     fi
1250                   fi
1251                   rm -f conftest.{c,s}
1252                  ])
1253   if test $libc_cv_visibility_attribute != yes; then
1254     AC_MSG_ERROR(compiler support for visibility attribute is required)
1255   fi
1256 fi
1257
1258 if test $libc_cv_visibility_attribute = yes; then
1259   AC_CACHE_CHECK(for broken __attribute__((visibility())),
1260                  libc_cv_broken_visibility_attribute,
1261                  [cat > conftest.c <<EOF
1262                   int foo (int x);
1263                   int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1264                   int bar (int x) { return x; }
1265 EOF
1266                   libc_cv_broken_visibility_attribute=yes
1267                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1268 changequote(,)dnl
1269                     if grep '\.hidden[  _]foo' conftest.s >/dev/null; then
1270 changequote([,])dnl
1271                       libc_cv_broken_visibility_attribute=no
1272                     fi
1273                   fi
1274                   rm -f conftest.c conftest.s
1275                  ])
1276   if test $libc_cv_broken_visibility_attribute = yes; then
1277     AC_MSG_ERROR(working compiler support for visibility attribute is required)
1278   fi
1279 fi
1280
1281 AC_CACHE_CHECK(for broken __attribute__((alias())),
1282                libc_cv_broken_alias_attribute,
1283                [cat > conftest.c <<EOF
1284                extern int foo (int x) __asm ("xyzzy");
1285                int bar (int x) { return x; }
1286                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1287                extern int dfoo;
1288                extern __typeof (dfoo) dfoo __asm ("abccb");
1289                int dfoo = 1;
1290 EOF
1291                libc_cv_broken_alias_attribute=yes
1292                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1293                  if grep 'xyzzy' conftest.s >/dev/null &&
1294                     grep 'abccb' conftest.s >/dev/null; then
1295                    libc_cv_broken_alias_attribute=no
1296                  fi
1297                fi
1298                rm -f conftest.c conftest.s
1299                ])
1300 if test $libc_cv_broken_alias_attribute = yes; then
1301   AC_MSG_ERROR(working alias attribute support required)
1302 fi
1303
1304 if test $libc_cv_visibility_attribute = yes; then
1305   AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1306                  libc_cv_have_sdata_section,
1307                  [echo "int i;" > conftest.c
1308                   libc_cv_have_sdata_section=no
1309                   if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1310                      | grep '\.sdata' >/dev/null; then
1311                     libc_cv_have_sdata_section=yes
1312                   fi
1313                   rm -f conftest.c conftest.so
1314                  ])
1315   if test $libc_cv_have_sdata_section = yes; then
1316     AC_DEFINE(HAVE_SDATA_SECTION)
1317   fi
1318 fi
1319
1320 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1321                libc_cv_initfini_array, [dnl
1322 LIBC_TRY_LINK_STATIC([
1323 int foo (void) { return 1; }
1324 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1325 ],
1326   [if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1327     libc_cv_initfini_array=yes
1328   else
1329     libc_cv_initfini_array=no
1330   fi],
1331   [libc_cv_initfini_array=no])
1332 ])
1333 if test $libc_cv_initfini_array != yes; then
1334   AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1335 fi
1336
1337 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1338                libc_cv_ctors_header, [dnl
1339   libc_cv_ctors_header=yes
1340   LIBC_TRY_LINK_STATIC([
1341 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1342 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1343 ],
1344               [dnl
1345       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1346         { gsub(/\@<:@ */, "@<:@") }
1347         $2 == ".ctors" || $2 == ".dtors" {
1348           size = strtonum("0x" $6)
1349           align = strtonum("0x" $NF)
1350           seen@<:@$2@:>@ = 1
1351           stub@<:@$2@:>@ = size == align * 2
1352         }
1353         END {
1354           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1355           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1356           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1357         }
1358       '], [libc_cv_ctors_header=no])
1359     ], [dnl
1360       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1361     ])
1362 ])
1363 if test $libc_cv_ctors_header = no; then
1364   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1365 fi
1366
1367 AC_CACHE_CHECK(for libunwind-support in compiler,
1368                libc_cv_cc_with_libunwind, [
1369   cat > conftest.c <<EOF
1370 int main (void) { return 0; }
1371 EOF
1372   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1373      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1374     libc_cv_cc_with_libunwind=yes
1375   else
1376     libc_cv_cc_with_libunwind=no
1377   fi
1378   rm -f conftest*])
1379 AC_SUBST(libc_cv_cc_with_libunwind)
1380 if test $libc_cv_cc_with_libunwind = yes; then
1381   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1382 fi
1383
1384 LIBC_LINKER_FEATURE([-z nodelete], [-Wl,--enable-new-dtags,-z,nodelete],
1385                     [libc_cv_z_nodelete=yes],
1386                     [AC_MSG_ERROR(linker with -z nodelete support required)])
1387
1388 LIBC_LINKER_FEATURE([-z nodlopen], [-Wl,--enable-new-dtags,-z,nodlopen],
1389                     [libc_cv_z_nodlopen=yes],
1390                     [AC_MSG_ERROR(linker with -z nodlopen support required)])
1391
1392 LIBC_LINKER_FEATURE([-z initfirst], [-Wl,--enable-new-dtags,-z,initfirst],
1393                     [libc_cv_z_initfirst=yes],
1394                     [AC_MSG_ERROR(linker with -z initfirst support required)])
1395
1396 # Add-on fragments can set these for other machines.
1397 libc_commonpagesize=${libc_commonpagesize:-no}
1398 libc_relro_required=${libc_relro_required:-no}
1399 case "$base_machine" in
1400   i[[34567]]86 | x86_64 | powerpc* | s390*)
1401     libc_commonpagesize=0x1000
1402     libc_relro_required=yes
1403     ;;
1404   sparc*)
1405     libc_commonpagesize=0x2000
1406     libc_relro_required=yes
1407     ;;
1408 esac
1409
1410 if test $libc_commonpagesize != no; then
1411   AC_CACHE_CHECK(for -z relro option,
1412                  libc_cv_z_relro, [dnl
1413   libc_cv_z_relro=no
1414   AC_LANG_CONFTEST([AC_LANG_SOURCE([[
1415 int _start (void) { return 42; }
1416 extern void _exit (int);
1417 /* Since these pointers are const, they should go in rodata.
1418    Since they refer to functions that have to be resolved by
1419    dynamic linking, they should instead go in RELRO data.  */
1420 const void *const relro[] = { &_start, &_exit, 0 };
1421 /* GNU ld fails to produce RELRO data when it's very small and there is no
1422    normal writable data following it, or if only uninitialized (.bss) data
1423    follows it, or only very small writable data.  */
1424 int data[0x10000] = { 1, };
1425 ]])])
1426   cat > conftest.awk <<\EOF
1427 BEGIN {
1428   result = "no"
1429   commonpagesize = strtonum(commonpagesize)
1430 }
1431 { print "LINE:", $0 > "/dev/stderr" }
1432 $1 == "GNU_RELRO" {
1433   vaddr = strtonum($3)
1434   memsz = strtonum($6)
1435   end = vaddr + memsz
1436   printf "vaddr %#x memsz %#x end %#x commonpagesize %#x\n", \
1437     vaddr, memsz, end, commonpagesize > "/dev/stderr"
1438   result = (end % commonpagesize == 0) ? "yes" : "broken"
1439 }
1440 END { print result }
1441 EOF
1442   AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1443                     -fPIC -shared -o conftest.so conftest.c
1444                     -nostartfiles -nostdlib
1445                     -Wl,-z,relro 1>&AS_MESSAGE_LOG_FD]) &&
1446   AC_TRY_COMMAND([$READELF -Wl conftest.so > conftest.ph]) &&
1447   AC_TRY_COMMAND([
1448       $AWK -v commonpagesize=$libc_commonpagesize -f conftest.awk
1449            conftest.ph > conftest.cps
1450     ]) &&
1451   libc_cv_z_relro=`cat conftest.cps 2>&AS_MESSAGE_LOG_FD`
1452   rm -f conftest*])
1453   if { test "x$libc_relro_required" = xyes &&
1454        test "x$libc_cv_z_relro" != xyes
1455      }
1456   then
1457     AC_MSG_ERROR(linker with -z relro support required)
1458   fi
1459 else
1460   AC_MSG_WARN([missing architecture parameter to check for working -z relro])
1461 fi
1462
1463 AC_CACHE_CHECK(for -Bgroup option,
1464                libc_cv_Bgroup, [dnl
1465 cat > conftest.c <<EOF
1466 int _start (void) { return 42; }
1467 EOF
1468 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1469                             -fPIC -shared -o conftest.so conftest.c
1470                             -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1471 then
1472   libc_cv_Bgroup=yes
1473 else
1474   libc_cv_Bgroup=no
1475 fi
1476 rm -f conftest*])
1477 AC_SUBST(libc_cv_Bgroup)
1478
1479 ASFLAGS_config=
1480 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1481                libc_cv_as_noexecstack, [dnl
1482 cat > conftest.c <<EOF
1483 void foo (void) { }
1484 EOF
1485 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1486                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1487    && grep .note.GNU-stack conftest.s >/dev/null \
1488    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1489                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1490 then
1491   libc_cv_as_noexecstack=yes
1492 else
1493   libc_cv_as_noexecstack=no
1494 fi
1495 rm -f conftest*])
1496 if test $libc_cv_as_noexecstack = yes; then
1497   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1498 fi
1499 AC_SUBST(ASFLAGS_config)
1500
1501 AC_CACHE_CHECK(for -z combreloc,
1502                libc_cv_z_combreloc, [dnl
1503 cat > conftest.c <<EOF
1504 extern int bar (int);
1505 extern int mumble;
1506 int foo (void) { return bar (mumble); }
1507 EOF
1508 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1509                         -fPIC -shared -o conftest.so conftest.c
1510                         -nostdlib -nostartfiles
1511                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1512 then
1513 dnl The following test is a bit weak.  We must use a tool which can test
1514 dnl cross-platform since the gcc used can be a cross compiler.  Without
1515 dnl introducing new options this is not easily doable.  Instead use a tool
1516 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1517 dnl look for a section named .rel.dyn.
1518   if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1519     libc_cv_z_combreloc=yes
1520   else
1521     libc_cv_z_combreloc=no
1522   fi
1523 else
1524   libc_cv_z_combreloc=no
1525 fi
1526 rm -f conftest*])
1527 if test "$libc_cv_z_combreloc" = yes; then
1528   AC_DEFINE(HAVE_Z_COMBRELOC)
1529 fi
1530 AC_SUBST(libc_cv_z_combreloc)
1531
1532 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1533                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1534 AC_SUBST(libc_cv_z_execstack)
1535
1536 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1537 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1538 ])
1539
1540 AC_SUBST(libc_cv_fpie)
1541
1542 AC_CACHE_CHECK(for --hash-style option,
1543                libc_cv_hashstyle, [dnl
1544 cat > conftest.c <<EOF
1545 int _start (void) { return 42; }
1546 EOF
1547 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1548                             -fPIC -shared -o conftest.so conftest.c
1549                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1550 then
1551   libc_cv_hashstyle=yes
1552 else
1553   libc_cv_hashstyle=no
1554 fi
1555 rm -f conftest*])
1556 AC_SUBST(libc_cv_hashstyle)
1557
1558 # The linker's default -shared behavior is good enough if it
1559 # does these things that our custom linker scripts ensure that
1560 # all allocated NOTE sections come first.
1561 if test "$use_default_link" = default; then
1562   AC_CACHE_CHECK([for sufficient default -shared layout],
1563                   libc_cv_use_default_link, [dnl
1564   libc_cv_use_default_link=no
1565   cat > conftest.s <<\EOF
1566           .section .note.a,"a",%note
1567           .balign 4
1568           .long 4,4,9
1569           .string "GNU"
1570           .string "foo"
1571           .section .note.b,"a",%note
1572           .balign 4
1573           .long 4,4,9
1574           .string "GNU"
1575           .string "bar"
1576 EOF
1577   if AC_TRY_COMMAND([dnl
1578   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1579        ac_try=`$READELF -S conftest.so | sed -n \
1580          ['${x;p;}
1581           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1582           t a
1583           b
1584           : a
1585           H']`
1586   then
1587     libc_seen_a=no libc_seen_b=no
1588     set -- $ac_try
1589     while test $# -ge 2 -a "$1" = NOTE; do
1590       case "$2" in
1591       .note.a) libc_seen_a=yes ;;
1592       .note.b) libc_seen_b=yes ;;
1593       esac
1594       shift 2
1595     done
1596     case "$libc_seen_a$libc_seen_b" in
1597     yesyes)
1598       libc_cv_use_default_link=yes
1599       ;;
1600     *)
1601       echo >&AS_MESSAGE_LOG_FD "\
1602 $libc_seen_a$libc_seen_b from:
1603 $ac_try"
1604       ;;
1605     esac
1606   fi
1607   rm -f conftest*])
1608   use_default_link=$libc_cv_use_default_link
1609 fi
1610
1611 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1612 if libc_cv_output_format=`
1613 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1614 then
1615   :
1616 else
1617   libc_cv_output_format=
1618 fi
1619 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1620 AC_SUBST(libc_cv_output_format)
1621
1622 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1623 cat > conftest.c <<EOF
1624 int foo;
1625 EOF
1626 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1627                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1628 then
1629   libc_cv_fno_toplevel_reorder=yes
1630 else
1631   libc_cv_fno_toplevel_reorder=no
1632 fi
1633 rm -f conftest*])
1634 if test $libc_cv_fno_toplevel_reorder = yes; then
1635   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1636 else
1637   fno_unit_at_a_time=-fno-unit-at-a-time
1638 fi
1639 AC_SUBST(fno_unit_at_a_time)
1640
1641 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1642 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1643                    [libc_cv_ssp=yes],
1644                    [libc_cv_ssp=no])
1645 ])
1646 AC_SUBST(libc_cv_ssp)
1647
1648 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1649 cat > conftest.c <<EOF
1650 int foo;
1651 #ifdef __GNUC_GNU_INLINE__
1652 main () { return 0;}
1653 #else
1654 #error
1655 #endif
1656 EOF
1657 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1658                             -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1659 then
1660   libc_cv_gnu89_inline=yes
1661 else
1662   libc_cv_gnu89_inline=no
1663 fi
1664 rm -f conftest*])
1665 if test $libc_cv_gnu89_inline = yes; then
1666   gnu89_inline=-fgnu89-inline
1667 else
1668   gnu89_inline=
1669 fi
1670 AC_SUBST(gnu89_inline)
1671
1672 AC_CACHE_CHECK(whether cc puts quotes around section names,
1673                libc_cv_have_section_quotes,
1674                [cat > conftest.c <<EOF
1675                 static const int foo
1676                 __attribute__ ((section ("bar"))) = 1;
1677 EOF
1678                 if ${CC-cc} -S conftest.c -o conftest.s; then
1679                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1680                     libc_cv_have_section_quotes=yes
1681                   else
1682                     libc_cv_have_section_quotes=no
1683                   fi
1684                 else
1685                   libc_cv_have_section_quotes=unknown
1686                 fi
1687                 rm -f conftest.{c,s}
1688                 ])
1689 if test $libc_cv_have_section_quotes = yes; then
1690   AC_DEFINE(HAVE_SECTION_QUOTES)
1691 fi
1692
1693 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1694                [dnl
1695 cat > conftest.s <<EOF
1696 ${libc_cv_dot_text}
1697 .globl foo
1698 foo:
1699 .weak foo
1700 .weak bar; bar = foo
1701 EOF
1702 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1703   libc_cv_asm_weak_directive=yes
1704 else
1705   libc_cv_asm_weak_directive=no
1706 fi
1707 rm -f conftest*])
1708
1709 if test $libc_cv_asm_weak_directive = no; then
1710   AC_CACHE_CHECK(for assembler .weakext directive,
1711                  libc_cv_asm_weakext_directive,
1712                  [dnl
1713 cat > conftest.s <<EOF
1714 ${libc_cv_dot_text}
1715 .globl foo
1716 foo:
1717 .weakext bar foo
1718 .weakext baz
1719 .globl baz
1720 baz:
1721 EOF
1722   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1723     libc_cv_asm_weakext_directive=yes
1724   else
1725     libc_cv_asm_weakext_directive=no
1726   fi
1727   rm -f conftest*])
1728
1729 fi # no .weak
1730
1731 if test $libc_cv_asm_weak_directive = yes; then
1732   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1733 elif test $libc_cv_asm_weakext_directive = yes; then
1734   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1735 fi
1736
1737 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1738 case $machine in
1739   sparc/sparc64*) cfi_offset=2047;;
1740   *) cfi_offset=0;;
1741 esac
1742 cat > conftest.s <<EOF
1743         .text
1744         .type   func,%function
1745 func:
1746         .cfi_startproc
1747         .cfi_remember_state
1748         .cfi_rel_offset 1, $cfi_offset
1749         .cfi_endproc
1750 EOF
1751 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1752   libc_cv_asm_cfi_directives=yes
1753 else
1754   libc_cv_asm_cfi_directives=no
1755 fi
1756 rm -f conftest*])
1757 if test $libc_cv_asm_cfi_directives = yes; then
1758   AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1759 fi
1760
1761 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1762 cat > conftest.c <<\EOF
1763 _start () {}
1764 int __eh_pc;
1765 __throw () {}
1766 EOF
1767 dnl No \ in command here because it ends up inside ''.
1768 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1769                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1770                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1771   libc_cv_ld_no_whole_archive=yes
1772 else
1773   libc_cv_ld_no_whole_archive=no
1774 fi
1775 rm -f conftest*])
1776 if test $libc_cv_ld_no_whole_archive = no; then
1777   AC_MSG_ERROR([support for --no-whole-archive is needed])
1778 fi
1779
1780 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1781 cat > conftest.c <<\EOF
1782 _start () {}
1783 int __eh_pc;
1784 __throw () {}
1785 EOF
1786 dnl No \ in command here because it ends up inside ''.
1787 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1788                             -nostdlib -nostartfiles -fexceptions
1789                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1790   libc_cv_gcc_exceptions=yes
1791 else
1792   libc_cv_gcc_exceptions=no
1793 fi
1794 rm -f conftest*])
1795 if test $libc_cv_gcc_exceptions = yes; then
1796   exceptions=-fexceptions
1797 fi
1798 AC_SUBST(exceptions)dnl
1799
1800 if test "$host_cpu" = powerpc ; then
1801 # Check for a bug present in at least versions 2.8.x of GCC
1802 # and versions 1.0.x of EGCS.
1803 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1804 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1805                libc_cv_c_asmcr0_bug='no',
1806                libc_cv_c_asmcr0_bug='yes')])
1807 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1808   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1809 fi
1810 fi
1811
1812 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1813 cat > conftest.c <<\EOF
1814 void zero (void *x)
1815 {
1816   __builtin_memset (x, 0, 1000);
1817 }
1818 EOF
1819 dnl
1820 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1821 then
1822   libc_cv_gcc_builtin_memset=no
1823 else
1824   libc_cv_gcc_builtin_memset=yes
1825 fi
1826 rm -f conftest* ])
1827 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1828   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1829 fi
1830
1831 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1832 cat > conftest.c <<\EOF
1833 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1834 char *foo (const char *a, const char *b)
1835 {
1836   return __builtin_strstr (a, b);
1837 }
1838 EOF
1839 dnl
1840 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1841 then
1842   libc_cv_gcc_builtin_redirection=yes
1843 else
1844   libc_cv_gcc_builtin_redirection=no
1845 fi
1846 rm -f conftest* ])
1847 if test "$libc_cv_gcc_builtin_redirection" = no; then
1848   AC_MSG_ERROR([support for the symbol redirection needed])
1849 fi
1850
1851 dnl Check whether the compiler supports the __thread keyword.
1852 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1853 [cat > conftest.c <<\EOF
1854 __thread int a = 42;
1855 EOF
1856 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1857   libc_cv_gcc___thread=yes
1858 else
1859   libc_cv_gcc___thread=no
1860 fi
1861 rm -f conftest*])
1862 if test "$libc_cv_gcc___thread" = no; then
1863   AC_MSG_ERROR([support for the __thread keyword is required])
1864 fi
1865
1866 dnl Check whether the compiler supports the tls_model attribute.
1867 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1868 cat > conftest.c <<\EOF
1869 extern __thread int a __attribute__((tls_model ("initial-exec")));
1870 EOF
1871 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
1872   libc_cv_gcc_tls_model_attr=yes
1873 else
1874   libc_cv_gcc_tls_model_attr=no
1875 fi
1876 rm -f conftest*])
1877 if test "$libc_cv_gcc_tls_model_attr" = no; then
1878   AC_MSG_ERROR([support for the tls_model attribute is required])
1879 fi
1880
1881 dnl Determine how to disable generation of FMA instructions.
1882 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1883                libc_cv_cc_nofma, [dnl
1884 libc_cv_cc_nofma=
1885 for opt in -ffp-contract=off -mno-fused-madd; do
1886   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1887 done])
1888 AC_SUBST(libc_cv_cc_nofma)
1889
1890 if test -n "$submachine"; then
1891   AC_CACHE_CHECK([for compiler option for CPU variant],
1892                  libc_cv_cc_submachine, [dnl
1893   libc_cv_cc_submachine=no
1894   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1895     LIBC_TRY_CC_OPTION([$opt], [
1896       libc_cv_cc_submachine="$opt"
1897       break], [])
1898   done])
1899   if test "x$libc_cv_cc_submachine" = xno; then
1900     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1901   fi
1902 fi
1903 AC_SUBST(libc_cv_cc_submachine)
1904
1905 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1906 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1907 cat > conftest.c <<EOF
1908 void
1909 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1910 foo (void) {}
1911 EOF
1912 libc_cv_cc_loop_to_function=no
1913 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1914 then
1915   libc_cv_cc_loop_to_function=yes
1916 fi
1917 rm -f conftest*])
1918 if test $libc_cv_cc_loop_to_function = yes; then
1919   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1920 fi
1921 AC_SUBST(libc_cv_cc_loop_to_function)
1922
1923 dnl Check whether we have the gd library available.
1924 AC_MSG_CHECKING(for libgd)
1925 if test "$with_gd" != "no"; then
1926   old_CFLAGS="$CFLAGS"
1927   CFLAGS="$CFLAGS $libgd_include"
1928   old_LDFLAGS="$LDFLAGS"
1929   LDFLAGS="$LDFLAGS $libgd_ldflags"
1930   old_LIBS="$LIBS"
1931   LIBS="$LIBS -lgd -lpng -lz -lm"
1932   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1933   CFLAGS="$old_CFLAGS"
1934   LDFLAGS="$old_LDFLAGS"
1935   LIBS="$old_LIBS"
1936 else
1937   LIBGD=no
1938 fi
1939 AC_MSG_RESULT($LIBGD)
1940 AC_SUBST(LIBGD)
1941
1942 # SELinux detection
1943 if test x$with_selinux = xno ; then
1944   have_selinux=no;
1945 else
1946   # See if we have the SELinux library
1947   AC_CHECK_LIB(selinux, is_selinux_enabled,
1948                have_selinux=yes, have_selinux=no)
1949   if test x$with_selinux = xyes ; then
1950     if test x$have_selinux = xno ; then
1951       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1952     fi
1953   fi
1954 fi
1955 # Check if we're building with SELinux support.
1956 if test "x$have_selinux" = xyes; then
1957   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1958
1959   # See if we have the libaudit library
1960   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1961                have_libaudit=yes, have_libaudit=no)
1962   if test "x$have_libaudit" = xyes; then
1963     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1964   fi
1965   AC_SUBST(have_libaudit)
1966
1967   # See if we have the libcap library
1968   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1969   if test "x$have_libcap" = xyes; then
1970     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1971   fi
1972   AC_SUBST(have_libcap)
1973 fi
1974 AC_SUBST(have_selinux)
1975
1976 dnl check for the size of 'long double'.
1977 AC_CHECK_SIZEOF(long double, 0)
1978 sizeof_long_double=$ac_cv_sizeof_long_double
1979 AC_SUBST(sizeof_long_double)
1980
1981 CPPUNDEFS=
1982 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1983 dnl Since we are building the implementations of the fortified functions here,
1984 dnl having the macro defined interacts very badly.
1985 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1986 [AC_TRY_COMPILE([], [
1987 #ifdef _FORTIFY_SOURCE
1988 # error bogon
1989 #endif],
1990                 [libc_cv_predef_fortify_source=no],
1991                 [libc_cv_predef_fortify_source=yes])])
1992 if test $libc_cv_predef_fortify_source = yes; then
1993   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1994 fi
1995 AC_SUBST(CPPUNDEFS)
1996
1997 dnl Check for silly hacked compilers inserting -fstack-protector.
1998 dnl This breaks badly for the early startup code we compile, since
1999 dnl the compiled code can refer to a magic machine-dependent location
2000 dnl for the canary value before we have sufficient setup for that to
2001 dnl work.  It's also questionable to build all of libc with this flag
2002 dnl even when you're doing that for most applications you build, since
2003 dnl libc's code is so heavily-used and performance-sensitive.  If we
2004 dnl ever really want to make that work, it should be enabled explicitly
2005 dnl in the libc build, not inherited from implicit compiler settings.
2006 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
2007                libc_cv_predef_stack_protector, [
2008 AC_TRY_COMPILE([extern void foobar (char *);],
2009                [char large_array[2048]; foobar (large_array);], [
2010 libc_undefs=`$NM -u conftest.o |
2011   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
2012     2>&AS_MESSAGE_LOG_FD` || {
2013   AC_MSG_ERROR([confusing output from $NM -u])
2014 }
2015 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
2016 # On some architectures, there are architecture-specific undefined
2017 # symbols (resolved by the linker), so filter out unknown symbols.
2018 # This will fail to produce the correct result if the compiler
2019 # defaults to -fstack-protector but this produces an undefined symbol
2020 # other than __stack_chk_fail.  However, compilers like that have not
2021 # been encountered in practice.
2022 libc_undefs=`echo "$libc_undefs" | egrep '^(foobar|__stack_chk_fail)$'`
2023 case "$libc_undefs" in
2024 foobar) libc_cv_predef_stack_protector=no ;;
2025 '__stack_chk_fail
2026 foobar') libc_cv_predef_stack_protector=yes ;;
2027 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
2028 esac],
2029                [AC_MSG_ERROR([test compilation failed])])
2030 ])
2031 libc_extra_cflags=
2032 if test $libc_cv_predef_stack_protector = yes; then
2033   libc_extra_cflags="$libc_extra_cflags -fno-stack-protector"
2034 fi
2035 libc_extra_cppflags=
2036
2037 AC_CACHE_CHECK([whether the linker provides __ehdr_start],
2038                libc_cv_ehdr_start, [
2039 old_CFLAGS="$CFLAGS"
2040 old_LDFLAGS="$LDFLAGS"
2041 old_LIBS="$LIBS"
2042 CFLAGS="$CFLAGS -fPIC"
2043 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared"
2044 LIBS=
2045 AC_LINK_IFELSE([AC_LANG_SOURCE([
2046 extern const char __ehdr_start __attribute__ ((visibility ("hidden")));
2047 const char *ehdr (void) { return &__ehdr_start; }
2048 ])],
2049                [libc_cv_ehdr_start=yes], [libc_cv_ehdr_start=no])
2050 CFLAGS="$old_CFLAGS"
2051 LDFLAGS="$old_LDFLAGS"
2052 LIBS="$old_LIBS"
2053 ])
2054 if test $libc_cv_ehdr_start = yes; then
2055   AC_DEFINE([HAVE_EHDR_START])
2056 fi
2057
2058 ### End of automated tests.
2059 ### Now run sysdeps configure fragments.
2060
2061 # They also can set these variables.
2062 use_ldconfig=no
2063 ldd_rewrite_script=no
2064 libc_cv_sysconfdir=$sysconfdir
2065 libc_cv_localstatedir=$localstatedir
2066 libc_cv_gcc_unwind_find_fde=no
2067 libc_cv_idn=no
2068
2069 # Iterate over all the sysdep directories we will use, running their
2070 # configure fragments.
2071 for dir in $sysnames; do
2072   case $dir in
2073     /*) dest=$dir ;;
2074     *)  dest=$srcdir/$dir ;;
2075   esac
2076   if test -r $dest/configure; then
2077     AC_MSG_RESULT(running configure fragment for $dir)
2078     . $dest/configure
2079   fi
2080 done
2081
2082 AC_SUBST(libc_extra_cflags)
2083 AC_SUBST(libc_extra_cppflags)
2084
2085 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2086   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2087 fi
2088 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2089
2090 # A sysdeps configure fragment can reset this if IFUNC is not actually
2091 # usable even though the assembler knows how to generate the symbol type.
2092 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
2093   AC_DEFINE(HAVE_IFUNC)
2094 fi
2095
2096 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
2097 # configure fragment can override the value to prevent this AC_DEFINE.
2098 AC_SUBST(use_nscd)
2099 if test "x$use_nscd" != xno; then
2100   AC_DEFINE([USE_NSCD])
2101 fi
2102 if test "x$build_nscd" = xdefault; then
2103   build_nscd=$use_nscd
2104 fi
2105
2106 # Test for old glibc 2.0.x headers so that they can be removed properly
2107 # Search only in includedir.
2108 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2109 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2110 then
2111   old_glibc_headers=yes
2112 else
2113   old_glibc_headers=no
2114 fi
2115 AC_MSG_RESULT($old_glibc_headers)
2116 if test ${old_glibc_headers} = yes; then
2117   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2118   AC_MSG_WARN(*** be removed.)
2119 fi
2120 AC_SUBST(old_glibc_headers)
2121
2122 AC_SUBST(libc_cv_slibdir)
2123 AC_SUBST(libc_cv_rtlddir)
2124 AC_SUBST(libc_cv_localedir)
2125 AC_SUBST(libc_cv_sysconfdir)
2126 AC_SUBST(libc_cv_localstatedir)
2127 AC_SUBST(libc_cv_rootsbindir)
2128 AC_SUBST(libc_cv_forced_unwind)
2129
2130 if test x$use_ldconfig = xyes; then
2131   AC_DEFINE(USE_LDCONFIG)
2132 fi
2133 AC_SUBST(use_ldconfig)
2134 AC_SUBST(ldd_rewrite_script)
2135
2136 AC_SUBST(static)
2137 AC_SUBST(shared)
2138
2139 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2140 [libc_cv_pic_default=yes
2141 cat > conftest.c <<EOF
2142 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2143 # error PIC is default.
2144 #endif
2145 EOF
2146 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2147   libc_cv_pic_default=no
2148 fi
2149 rm -f conftest.*])
2150 AC_SUBST(libc_cv_pic_default)
2151
2152 AC_SUBST(profile)
2153 AC_SUBST(static_nss)
2154
2155 AC_SUBST(DEFINES)
2156
2157 dnl See sysdeps/mach/configure.ac for this variable.
2158 AC_SUBST(mach_interface_list)
2159
2160 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2161 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2162 AC_SUBST(VERSION)
2163 AC_SUBST(RELEASE)
2164
2165 AC_CONFIG_FILES([config.make Makefile])
2166 AC_CONFIG_COMMANDS([default],[[
2167 case $CONFIG_FILES in *config.make*)
2168 echo "$config_vars" >> config.make;;
2169 esac
2170 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2171 AC_OUTPUT