sysdeps/mach/configure.in

   1 sinclude(./aclocal.m4)dnl Autoconf lossage.
   2 GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
   3
   4 dnl Autoconf weirdness requires that AC_CHECK_TOOL be in the main configure.in,
   5 dnl but only on Mach-based configurations is the tool needed.
   6 if test "x$MIG" = xMISSING; then
   7   AC_MSG_ERROR([cannot find required build tool mig])
   8 fi
   9
  10 ### Sanity checks for Mach header installation
  11 AC_CHECK_HEADER(mach/mach_types.h,, [AC_MSG_ERROR([cannot find Mach headers])])
  12 AC_CHECK_HEADER(mach/mach_types.defs,, [dnl
  13 AC_MSG_ERROR([cannot find Mach .defs files])])
  14
  15 dnl
  16 dnl mach_TYPE_CHECK(foo_t, bar_t)
  17 dnl
  18 dnl Check if foo_t is defined by <mach/mach_types.h>.
  19 dnl If not, compile with -Dfoo_t=bar_t.
  20 dnl
  21 AC_DEFUN([mach_TYPE_CHECK], [dnl
  22 AC_CACHE_CHECK(for $1 in mach/mach_types.h, libc_cv_mach_$1,
  23 AC_TRY_COMPILE([#include <mach/mach_types.h>], [extern $1 foo;],
  24 libc_cv_mach_$1=$1, libc_cv_mach_$1=$2))
  25 if test [$]libc_cv_mach_$1 != $1; then
  26   DEFINES="$DEFINES -D$1=$2"
  27 fi])
  28
  29 dnl
  30 dnl OSF Mach has renamed these typedefs for some reason.
  31 dnl
  32 mach_TYPE_CHECK(task_t, task_port_t)
  33 mach_TYPE_CHECK(thread_t, thread_port_t)
  34
  35 dnl
  36 dnl The creation_time field is a GNU Mach addition the other variants lack.
  37 dnl
  38 AC_CACHE_CHECK(for creation_time in task_basic_info,
  39                libc_cv_mach_task_creation_time, [dnl
  40 AC_TRY_COMPILE([#include <mach/task_info.h>], [
  41 extern struct task_basic_info *i;
  42 long s = i->creation_time.seconds;
  43 ], libc_cv_mach_task_creation_time=yes, libc_cv_mach_task_creation_time=no)])
  44 if test $libc_cv_mach_task_creation_time = no; then
  45   DEFINES="$DEFINES -DNO_CREATION_TIME=1"
  46 fi
  47
  48 dnl
  49 dnl The Darwin variant no longer has <mach/mach.defs>
  50 dnl but instead has several constituent .defs files.
  51 dnl In this scenario we will presume there is a <mach/mach_interface.h>
  52 dnl that contains an #include for each constituent header file,
  53 dnl but we don't do a check for that here because in a bare
  54 dnl environment the compile against those headers will fail.
  55 dnl
  56 mach_interface_list=
  57 for ifc in mach mach4 \
  58            clock clock_priv host_priv host_security ledger lock_set \
  59            processor processor_set task thread_act vm_map \
  60            memory_object memory_object_default default_pager \
  61            i386/mach_i386 \
  62            ; do
  63   AC_CHECK_HEADER(mach/${ifc}.defs, [dnl
  64   mach_interface_list="$mach_interface_list $ifc"])
  65 done
  66 if test "x$mach_interface_list" = x; then
  67   AC_MSG_ERROR([what manner of Mach is this?])
  68 fi
  69
  70 AC_CACHE_CHECK(for host_page_size in mach_host.defs,
  71                libc_cv_mach_host_page_size, [dnl
  72 AC_EGREP_HEADER(host_page_size, mach/mach_host.defs,
  73                 libc_cv_mach_host_page_size=yes,
  74                 libc_cv_mach_host_page_size=no)])
  75 if test $libc_cv_mach_host_page_size = yes; then
  76   AC_DEFINE([HAVE_HOST_PAGE_SIZE])
  77 fi
  78
  79 AC_CHECK_HEADER(mach/machine/ndr_def.h, [dnl
  80   DEFINES="$DEFINES -DNDR_DEF_HEADER='<mach/machine/ndr_def.h>'"], [dnl
  81 AC_CHECK_HEADER(machine/ndr_def.h, [dnl
  82   DEFINES="$DEFINES -DNDR_DEF_HEADER='<machine/ndr_def.h>'"])])
  83
  84 AC_CACHE_CHECK(for i386_io_perm_modify in mach_i386.defs,
  85                libc_cv_mach_i386_ioports, [dnl
  86 AC_EGREP_HEADER(i386_io_perm_modify, mach/i386/mach_i386.defs,
  87                 libc_cv_mach_i386_ioports=yes,
  88                 libc_cv_mach_i386_ioports=no)])
  89 if test $libc_cv_mach_i386_ioports = yes; then
  90   AC_DEFINE([HAVE_I386_IO_PERM_MODIFY])
  91 fi