sysdeps/s390/multiarch/strchrnul-vx.S

   1 /* Vector optimized 32/64 bit S/390 version of strchrnul.
   2    Copyright (C) 2015-2017 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #if defined HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc)
  20
  21 # include "sysdep.h"
  22 # include "asm-syntax.h"
  23
  24         .text
  25
  26 /* char *strchrnul (const char *s, int c)
  27    Returns pointer to first c or to \0 if c not found.
  28
  29    Register usage:
  30    -r1=tmp
  31    -r2=s and return pointer
  32    -r3=c
  33    -r4=tmp
  34    -r5=current_len
  35    -v16=part of s
  36    -v18=vector with c replicated in every byte
  37 */
  38 ENTRY(__strchrnul_vx)
  39         .machine "z13"
  40         .machinemode "zarch_nohighgprs"
  41
  42         vlbb    %v16,0(%r2),6   /* Load s until next 4k-byte boundary.  */
  43         lcbb    %r1,0(%r2),6    /* Get bytes to 4k-byte boundary or 16.  */
  44
  45         lghi    %r5,0           /* current_len = 0.  */
  46
  47         vlvgb   %v18,%r3,0      /* Generate vector which elements are all c.
  48                                    If c > 255, c will be truncated.  */
  49         vrepb   %v18,%v18,0
  50
  51         vfeezbs %v16,%v16,%v18  /* Find element equal with zero search.  */
  52         vlgvb   %r4,%v16,7      /* Load byte index of character or zero.  */
  53         clrjl   %r4,%r1,.Lfound /* Return if c/zero is in loaded bytes.  */
  54
  55         /* Align s to 16 byte.  */
  56         risbgn  %r4,%r2,60,128+63,0 /* %r3 = bits 60-63 of %r2 'and' 15.  */
  57         lghi    %r5,16          /* current_len = 16.  */
  58         slr     %r5,%r4         /* Compute bytes to 16bytes boundary.  */
  59
  60         /* Find c/zero in 16byte aligned loop */
  61 .Lloop:
  62         vl      %v16,0(%r5,%r2) /* Load s */
  63         vfeezbs %v16,%v16,%v18  /* Find element equal with zero search.  */
  64         jno     .Lfound         /* Found c/zero (cc=0|1|2).  */
  65         vl      %v16,16(%r5,%r2)
  66         vfeezbs %v16,%v16,%v18
  67         jno     .Lfound16
  68         vl      %v16,32(%r5,%r2)
  69         vfeezbs %v16,%v16,%v18
  70         jno     .Lfound32
  71         vl      %v16,48(%r5,%r2)
  72         vfeezbs %v16,%v16,%v18
  73         jno     .Lfound48
  74
  75         aghi    %r5,64
  76         j       .Lloop          /* No character and no zero -> loop.  */
  77
  78         /* Found character or zero */
  79 .Lfound48:
  80         aghi    %r5,16
  81 .Lfound32:
  82         aghi    %r5,16
  83 .Lfound16:
  84         aghi    %r5,16
  85 .Lfound:
  86         vlgvb   %r1,%v16,7      /* Load byte index of character.  */
  87         algr    %r5,%r1
  88         la      %r2,0(%r5,%r2)  /* Return pointer to character.  */
  89
  90 .Lend:
  91         br      %r14
  92 END(__strchrnul_vx)
  93 #endif /* HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc) */