| blob | 9dd2c686a7b3c06d4ab35d251a82e742b4c8928c |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Note we do not use AC_PREREQ here! See aclocal.m4 for what we use instead.
3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
4 AC_CONFIG_SRCDIR([include/features.h])
5 AC_CONFIG_HEADERS([config.h])
6 AC_CONFIG_AUX_DIR([scripts])
8 ACX_PKGVERSION([GNU libc])
9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
11 [Package description])
12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
13 [Bug reporting address])
15 # Glibc should not depend on any header files
16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
17 [m4_divert_text([DEFAULTS],
18 [ac_includes_default='/* none */'])])
20 # We require GCC, and by default use its preprocessor. Override AC_PROG_CPP
21 # here to work around the Autoconf issue discussed in
22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
23 AC_DEFUN([AC_PROG_CPP],
24 [AC_REQUIRE([AC_PROG_CC])dnl
25 AC_ARG_VAR([CPP], [C preprocessor])dnl
26 _AC_ARG_VAR_CPPFLAGS()dnl
27 # On Suns, sometimes $CPP names a directory.
28 if test -n "$CPP" && test -d "$CPP"; then
29 CPP=
30 fi
31 if test -z "$CPP"; then
32 CPP="$CC -E"
33 fi
34 AC_SUBST(CPP)dnl
35 ])# AC_PROG_CPP
37 # We require GCC. Override _AC_PROG_CC_C89 here to work around the Autoconf
38 # issue discussed in
39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
42 dnl This is here so we can set $subdirs directly based on configure fragments.
43 AC_CONFIG_SUBDIRS()
45 AC_CANONICAL_HOST
47 AC_PROG_CC
48 if test $host != $build; then
49 AC_CHECK_PROGS(BUILD_CC, gcc cc)
50 fi
51 AC_SUBST(cross_compiling)
52 AC_PROG_CPP
53 # We need the C++ compiler only for testing.
54 AC_PROG_CXX
55 AC_CHECK_TOOL(READELF, readelf, false)
57 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
58 AC_MSG_ERROR([you must configure in a separate build directory])
59 fi
61 # This will get text that should go into config.make.
62 config_vars=
64 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
65 AC_ARG_WITH([gd],
66 AC_HELP_STRING([--with-gd=DIR],
67 [find libgd include dir and library with prefix DIR]),
68 [dnl
69 case "$with_gd" in
70 yes|''|no) ;;
71 *) libgd_include="-I$withval/include"
72 libgd_ldflags="-L$withval/lib" ;;
73 esac
74 ])
75 AC_ARG_WITH([gd-include],
76 AC_HELP_STRING([--with-gd-include=DIR],
77 [find libgd include files in DIR]),
78 [dnl
79 case "$with_gd_include" in
80 ''|no) ;;
81 *) libgd_include="-I$withval" ;;
82 esac
83 ])
84 AC_ARG_WITH([gd-lib],
85 AC_HELP_STRING([--with-gd-lib=DIR],
86 [find libgd library files in DIR]),
87 [dnl
88 case "$with_gd_lib" in
89 ''|no) ;;
90 *) libgd_ldflags="-L$withval" ;;
91 esac
92 ])
94 if test -n "$libgd_include"; then
95 config_vars="$config_vars
96 CFLAGS-memusagestat.c = $libgd_include"
97 fi
98 if test -n "$libgd_ldflags"; then
99 config_vars="$config_vars
100 libgd-LDFLAGS = $libgd_ldflags"
101 fi
103 dnl Arguments to specify presence of other packages/features.
104 AC_ARG_WITH([fp],
105 AC_HELP_STRING([--with-fp],
106 [if using floating-point hardware @<:@default=yes@:>@]),
107 [with_fp=$withval],
108 [with_fp=yes])
109 AC_SUBST(with_fp)
110 AC_ARG_WITH([binutils],
111 AC_HELP_STRING([--with-binutils=PATH],
112 [specify location of binutils (as and ld)]),
113 [path_binutils=$withval],
114 [path_binutils=''])
115 AC_ARG_WITH([selinux],
116 AC_HELP_STRING([--with-selinux],
117 [if building with SELinux support]),
118 [with_selinux=$withval],
119 [with_selinux=auto])
121 AC_ARG_WITH([headers],
122 AC_HELP_STRING([--with-headers=PATH],
123 [location of system headers to use
124 (for example /usr/src/linux/include)
125 @<:@default=compiler default@:>@]),
126 [sysheaders=$withval],
127 [sysheaders=''])
128 AC_SUBST(sysheaders)
130 AC_SUBST(use_default_link)
131 AC_ARG_WITH([default-link],
132 AC_HELP_STRING([--with-default-link],
133 [do not use explicit linker scripts]),
134 [use_default_link=$withval],
135 [use_default_link=default])
137 AC_ARG_ENABLE([sanity-checks],
138 AC_HELP_STRING([--disable-sanity-checks],
139 [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
140 [enable_sanity=$enableval],
141 [enable_sanity=yes])
143 AC_ARG_ENABLE([shared],
144 AC_HELP_STRING([--enable-shared],
145 [build shared library @<:@default=yes if GNU ld@:>@]),
146 [shared=$enableval],
147 [shared=yes])
148 AC_ARG_ENABLE([profile],
149 AC_HELP_STRING([--enable-profile],
150 [build profiled library @<:@default=no@:>@]),
151 [profile=$enableval],
152 [profile=no])
154 AC_ARG_ENABLE([hardcoded-path-in-tests],
155 AC_HELP_STRING([--enable-hardcoded-path-in-tests],
156 [hardcode newly built glibc path in tests @<:@default=no@:>@]),
157 [hardcoded_path_in_tests=$enableval],
158 [hardcoded_path_in_tests=no])
159 AC_SUBST(hardcoded_path_in_tests)
161 AC_ARG_ENABLE([stackguard-randomization],
162 AC_HELP_STRING([--enable-stackguard-randomization],
163 [initialize __stack_chk_guard canary with a random number at program start]),
164 [enable_stackguard_randomize=$enableval],
165 [enable_stackguard_randomize=no])
166 if test "$enable_stackguard_randomize" = yes; then
167 AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
168 fi
170 AC_ARG_ENABLE([lock-elision],
171 AC_HELP_STRING([--enable-lock-elision[=yes/no]],
172 [Enable lock elision for pthread mutexes by default]),
173 [enable_lock_elision=$enableval],
174 [enable_lock_elision=no])
175 AC_SUBST(enable_lock_elision)
176 if test "$enable_lock_elision" = yes ; then
177 AC_DEFINE(ENABLE_LOCK_ELISION)
178 fi
180 dnl Generic infrastructure for drop-in additions to libc.
181 AC_ARG_ENABLE([add-ons],
182 AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
183 [configure and build add-ons in DIR1,DIR2,...
184 search for add-ons if no parameter given]),
185 , [enable_add_ons=yes])
187 AC_ARG_ENABLE([hidden-plt],
188 AC_HELP_STRING([--disable-hidden-plt],
189 [do not hide internal function calls to avoid PLT]),
190 [hidden=$enableval],
191 [hidden=yes])
192 if test "x$hidden" = xno; then
193 AC_DEFINE(NO_HIDDEN)
194 fi
196 AC_ARG_ENABLE([bind-now],
197 AC_HELP_STRING([--enable-bind-now],
198 [disable lazy relocations in DSOs]),
199 [bindnow=$enableval],
200 [bindnow=no])
201 AC_SUBST(bindnow)
203 dnl On some platforms we cannot use dynamic loading. We must provide
204 dnl static NSS modules.
205 AC_ARG_ENABLE([static-nss],
206 AC_HELP_STRING([--enable-static-nss],
207 [build static NSS modules @<:@default=no@:>@]),
208 [static_nss=$enableval],
209 [static_nss=no])
210 dnl Enable static NSS also if we build no shared objects.
211 if test x"$static_nss" = xyes || test x"$shared" = xno; then
212 static_nss=yes
213 AC_DEFINE(DO_STATIC_NSS)
214 fi
216 AC_ARG_ENABLE([force-install],
217 AC_HELP_STRING([--disable-force-install],
218 [don't force installation of files from this package, even if they are older than the installed files]),
219 [force_install=$enableval],
220 [force_install=yes])
221 AC_SUBST(force_install)
223 AC_ARG_ENABLE([maintainer-mode],
224 AC_HELP_STRING([--enable-maintainer-mode],
225 [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
226 [maintainer=$enableval],
227 [maintainer=no])
229 dnl On some platforms we allow dropping compatibility with all kernel
230 dnl versions.
231 AC_ARG_ENABLE([kernel],
232 AC_HELP_STRING([--enable-kernel=VERSION],
233 [compile for compatibility with kernel not older than VERSION]),
234 [minimum_kernel=$enableval],
235 [])
236 dnl Prevent unreasonable values.
237 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
238 # Better nothing than this.
239 minimum_kernel=""
240 else
241 if test "$minimum_kernel" = current; then
242 minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
243 fi
244 fi
246 dnl For the development we sometimes want gcc to issue even more warnings.
247 dnl This is not the default since many of the extra warnings are not
248 dnl appropriate.
249 AC_ARG_ENABLE([all-warnings],
250 AC_HELP_STRING([--enable-all-warnings],
251 [enable all useful warnings gcc can issue]),
252 [all_warnings=$enableval],
253 [])
254 AC_SUBST(all_warnings)
256 AC_ARG_ENABLE([multi-arch],
257 AC_HELP_STRING([--enable-multi-arch],
258 [enable single DSO with optimizations for multiple architectures]),
259 [multi_arch=$enableval],
260 [multi_arch=default])
262 AC_ARG_ENABLE([nss-crypt],
263 AC_HELP_STRING([--enable-nss-crypt],
264 [enable libcrypt to use nss]),
265 [nss_crypt=$enableval],
266 [nss_crypt=no])
267 if test x$nss_crypt = xyes; then
268 nss_includes=-I$(nss-config --includedir 2>/dev/null)
269 if test $? -ne 0; then
270 AC_MSG_ERROR([cannot find include directory with nss-config])
271 fi
272 old_CFLAGS="$CFLAGS"
273 CFLAGS="$CFLAGS $nss_includes"
274 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
275 #include <hasht.h>
276 #include <nsslowhash.h>
277 void f (void) { NSSLOW_Init (); }])],
278 libc_cv_nss_crypt=yes,
279 AC_MSG_ERROR([
280 cannot find NSS headers with lowlevel hash function interfaces]))
281 old_LIBS="$LIBS"
282 LIBS="$LIBS -lfreebl3"
283 AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
284 #include <hasht.h>
285 #include <nsslowhash.h>],
286 [NSSLOW_Init();])],
287 libc_cv_nss_crypt=yes,
288 AC_MSG_ERROR([
289 cannot link program using lowlevel NSS hash functions]))
290 CFLAGS="$old_CFLAGS"
291 LIBS="$old_LIBS"
292 else
293 libc_cv_nss_crypt=no
294 fi
295 AC_SUBST(libc_cv_nss_crypt)
298 AC_ARG_ENABLE([obsolete-rpc],
299 AC_HELP_STRING([--enable-obsolete-rpc],
300 [build and install the obsolete RPC code for link-time usage]),
301 [link_obsolete_rpc=$enableval],
302 [link_obsolete_rpc=no])
303 AC_SUBST(link_obsolete_rpc)
305 if test "$link_obsolete_rpc" = yes; then
306 AC_DEFINE(LINK_OBSOLETE_RPC)
307 fi
309 AC_ARG_ENABLE([systemtap],
310 [AS_HELP_STRING([--enable-systemtap],
311 [enable systemtap static probe points @<:@default=no@:>@])],
312 [systemtap=$enableval],
313 [systemtap=no])
314 if test "x$systemtap" != xno; then
315 AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
316 old_CFLAGS="$CFLAGS"
317 CFLAGS="-std=gnu99 $CFLAGS"
318 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
319 void foo (int i, void *p)
320 {
321 asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
322 :: STAP_PROBE_ASM_OPERANDS (2, i, p));
323 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
324 CFLAGS="$old_CFLAGS"])
325 if test $libc_cv_sdt = yes; then
326 AC_DEFINE([USE_STAP_PROBE])
327 elif test "x$systemtap" != xauto; then
328 AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
329 fi
330 fi
332 AC_ARG_ENABLE([build-nscd],
333 [AS_HELP_STRING([--disable-build-nscd],
334 [disable building and installing the nscd daemon])],
335 [build_nscd=$enableval],
336 [build_nscd=default])
337 AC_SUBST(build_nscd)
339 # Note the use of $use_nscd is near the bottom of the file.
340 AC_ARG_ENABLE([nscd],
341 [AS_HELP_STRING([--disable-nscd],
342 [library functions will not contact the nscd daemon])],
343 [use_nscd=$enableval],
344 [use_nscd=yes])
346 AC_ARG_ENABLE([pt_chown],
347 [AS_HELP_STRING([--enable-pt_chown],
348 [Enable building and installing pt_chown])],
349 [build_pt_chown=$enableval],
350 [build_pt_chown=no])
351 AC_SUBST(build_pt_chown)
352 if test "$build_pt_chown" = yes; then
353 AC_DEFINE(HAVE_PT_CHOWN)
354 fi
356 # We keep the original values in `$config_*' and never modify them, so we
357 # can write them unchanged into config.make. Everything else uses
358 # $machine, $vendor, and $os, and changes them whenever convenient.
359 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
361 # Don't allow vendor == "unknown"
362 test "$config_vendor" = unknown && config_vendor=
363 config_os="`echo $config_os | sed 's/^unknown-//'`"
365 # Some configurations imply other options.
366 elf=yes
368 # The configure fragment of an add-on port can modify these to supplement
369 # or override the table in the case statement below. No fragment should
370 # ever change the config_* variables, however.
371 machine=$config_machine
372 vendor=$config_vendor
373 os=$config_os
374 base_os=''
376 submachine=
377 AC_ARG_WITH([cpu],
378 AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
379 [dnl
380 case "$withval" in
381 yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
382 no) ;;
383 *) submachine="$withval" ;;
384 esac
385 ])
387 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
388 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
390 # An add-on can set this when it wants to disable the sanity check below.
391 libc_config_ok=no
393 dnl Having this here, though empty, makes sure that if add-ons' fragments
394 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
395 dnl our AC_OUTPUT will actually use it.
396 AC_CONFIG_SUBDIRS()
398 case "$enable_add_ons" in
399 ''|no) add_ons= ;;
400 yes|'*')
401 add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
402 sed 's@/[[^/]]*$@@' | sort | uniq`
403 add_ons_automatic=yes
404 ;;
405 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
406 add_ons_automatic=no ;;
407 esac
409 configured_add_ons=
410 add_ons_sfx=
411 add_ons_pfx=
412 if test x"$add_ons" != x; then
413 for f in $add_ons; do
414 # Some sanity checks
415 case "$f" in
416 crypt)
417 AC_MSG_ERROR([
418 *** It seems that you're using an old \`crypt' add-on. crypt is now
419 *** part of glibc and using the old add-on will not work with this
420 *** release. Start again with fresh sources and without the old
421 *** \`crypt' add-on.])
422 ;;
423 localedata)
424 AC_MSG_ERROR([
425 *** It seems that you're using an old \`localedata' add-on. localedata
426 *** is now part of glibc and using the old add-on will not work with
427 *** this release. Start again with fresh sources and without the old
428 *** \`localedata' add-on.])
429 ;;
430 esac
431 done
433 # Now source each add-on's configure fragment.
434 # The fragments can use $srcdir/$libc_add_on to find themselves,
435 # and test $add_ons_automatic to see if they were explicitly requested.
436 # A fragment can clear (or even change) $libc_add_on to affect
437 # whether it goes into the list to be actually used in the build.
438 use_add_ons=
439 for libc_add_on in $add_ons; do
440 # Test whether such a directory really exists.
441 # It can be absolute, or relative to $srcdir, or relative to the build dir.
442 case "$libc_add_on" in
443 /*)
444 libc_add_on_srcdir=$libc_add_on
445 ;;
446 *)
447 test -d "$srcdir/$libc_add_on" || {
448 if test -d "$libc_add_on"; then
449 libc_add_on="`pwd`/$libc_add_on"
450 else
451 AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
452 fi
453 }
454 libc_add_on_srcdir=$srcdir/$libc_add_on
455 ;;
456 esac
458 libc_add_on_frag=$libc_add_on_srcdir/configure
459 libc_add_on_canonical=
460 libc_add_on_config_subdirs=
461 if test -r "$libc_add_on_frag"; then
462 AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
463 libc_add_on_canonical=unknown
464 libc_add_on_subdirs=
465 . "$libc_add_on_frag"
466 test -z "$libc_add_on" || {
467 configured_add_ons="$configured_add_ons $libc_add_on"
468 if test "x$libc_add_on_canonical" = xunknown; then
469 AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
470 fi
471 for d in $libc_add_on_subdirs; do
472 case "$libc_add_on" in
473 /*) subdir_srcdir="$libc_add_on" ;;
474 *) subdir_srcdir="\$(..)$libc_add_on" ;;
475 esac
476 case "$d" in
477 .)
478 d="${libc_add_on_canonical:-$libc_add_on}"
479 ;;
480 /*)
481 subdir_srcdir="$d"
482 ;;
483 *)
484 subdir_srcdir="$subdir_srcdir/$d"
485 ;;
486 esac
487 d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
488 add_on_subdirs="$add_on_subdirs $d"
489 test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
490 $d-srcdir = $subdir_srcdir"
491 done
492 for d in $libc_add_on_config_subdirs; do
493 case "$d" in
494 /*) AC_MSG_ERROR(dnl
495 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
496 esac
497 if test ! -d "$libc_add_on_srcdir/$d"; then
498 AC_MSG_ERROR(fragment wants to configure missing directory $d)
499 fi
500 case "$libc_add_on" in
501 /*) AC_MSG_ERROR(dnl
502 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
503 esac
504 subdirs="$subdirs $libc_add_on/$d"
505 done
506 }
507 fi
508 if test -n "$libc_add_on"; then
509 LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
510 use_add_ons="$use_add_ons $libc_add_on"
511 add_ons_pfx="$add_ons_pfx $libc_add_on/"
512 test -z "$libc_add_on_canonical" ||
513 add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
514 fi
515 done
516 # Use echo to strip excess whitespace.
517 add_ons="`echo $use_add_ons`"
518 fi
519 AC_SUBST(add_ons)
520 AC_SUBST(add_on_subdirs)
523 ###
524 ### I put this here to prevent those annoying emails from people who cannot
525 ### read and try to compile glibc on unsupported platforms. --drepper
526 ###
527 ### By using the undocumented --enable-hacker-mode option for configure
528 ### one can skip this test to make the configuration not fail for unsupported
529 ### platforms.
530 ###
531 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
532 case "$machine-$host_os" in
533 *-linux* | *-gnu*)
534 ;;
535 *)
536 echo "*** The GNU C library is currently not available for this platform."
537 echo "*** So far nobody cared to port it and if there is no volunteer it"
538 echo "*** might never happen. So, if you have interest to see glibc on"
539 echo "*** this platform visit"
540 echo "*** http://www.gnu.org/software/libc/porting.html"
541 echo "*** and join the group of porters"
542 exit 1
543 ;;
544 esac
545 fi
547 # Set base_machine if not set by a preconfigure fragment.
548 test -n "$base_machine" || base_machine=$machine
549 AC_SUBST(base_machine)
551 # For the multi-arch option we need support in the assembler & linker.
552 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
553 libc_cv_ld_gnu_indirect_function, [dnl
554 cat > conftest.S <<EOF
555 .type foo,%gnu_indirect_function
556 foo:
557 .globl _start
558 _start:
559 .globl __start
560 __start:
561 .data
562 #ifdef _LP64
563 .quad foo
564 #else
565 .long foo
566 #endif
567 EOF
568 libc_cv_ld_gnu_indirect_function=no
569 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
570 -nostartfiles -nostdlib \
571 -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
572 # Do a link to see if the backend supports IFUNC relocs.
573 $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
574 LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
575 libc_cv_ld_gnu_indirect_function=yes
576 }
577 fi
578 rm -f conftest*])
580 AC_MSG_CHECKING(whether .text pseudo-op must be used)
581 AC_CACHE_VAL(libc_cv_dot_text, [dnl
582 cat > conftest.s <<EOF
583 .text
584 EOF
585 libc_cv_dot_text=
586 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
587 libc_cv_dot_text=.text
588 fi
589 rm -f conftest*])
590 if test -z "$libc_cv_dot_text"; then
591 AC_MSG_RESULT(no)
592 else
593 AC_MSG_RESULT(yes)
594 fi
596 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
597 if test x"$multi_arch" = xyes; then
598 AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
599 else
600 multi_arch=no
601 fi
602 fi
603 multi_arch_d=
604 if test x"$multi_arch" != xno; then
605 multi_arch_d=/multiarch
606 fi
608 # Compute the list of sysdep directories for this configuration.
609 # This can take a while to compute.
610 sysdep_dir=$srcdir/sysdeps
611 AC_MSG_CHECKING(sysdep dirs)
612 dnl We need to use [ and ] for other purposes for a while now.
613 changequote(,)dnl
614 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
615 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
617 test "x$base_os" != x || case "$os" in
618 gnu*)
619 base_os=mach/hurd ;;
620 linux*)
621 base_os=unix/sysv ;;
622 esac
624 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
625 tail=$os
626 ostry=$os
627 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
628 ostry="$ostry /$o"
629 tail=$o
630 done
631 o=`echo $tail | sed 's/[0-9]*$//'`
632 if test $o != $tail; then
633 ostry="$ostry /$o"
634 fi
635 # For linux-gnu, try linux-gnu, then linux.
636 o=`echo $tail | sed 's/-.*$//'`
637 if test $o != $tail; then
638 ostry="$ostry /$o"
639 fi
641 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
642 base=
643 tail=$base_os
644 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
645 set $b
646 base="$base /$1"
647 tail="$2"
648 done
650 # For sparc/sparc32, try sparc/sparc32 and then sparc.
651 mach=
652 tail=$machine${submachine:+/$submachine}
653 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
654 set $m
655 # Prepend the machine's FPU directory unless --without-fp.
656 if test "$with_fp" = yes; then
657 maybe_fpu=/fpu
658 else
659 maybe_fpu=/nofpu
660 fi
661 # For each machine term, try it with and then without /multiarch.
662 for try_fpu in $maybe_fpu ''; do
663 for try_multi in $multi_arch_d ''; do
664 mach="$mach /$1$try_fpu$try_multi"
665 done
666 done
667 tail="$2"
668 done
670 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
671 changequote([,])dnl
673 # Find what sysdep directories exist.
674 sysnames_add_ons=
675 sysnames=
676 for b in $base ''; do
677 for m0 in $mach ''; do
678 for v in /$vendor ''; do
679 test "$v" = / && continue
680 for o in /$ostry ''; do
681 test "$o" = / && continue
682 for m in $mach ''; do
683 for d in $add_ons_pfx ''; do
684 for a in $add_ons_sfx ''; do
685 try_suffix="$m0$b$v$o$m"
686 if test -n "$try_suffix"; then
687 try_srcdir="${srcdir}/"
688 case "$d" in
689 /*) try_srcdir= ;;
690 esac
691 try="${d}sysdeps$try_suffix$a"
692 test -n "$enable_debug_configure" &&
693 echo "$0 [DEBUG]: try $try" >&2
694 if test -d "$try_srcdir$try"; then
695 sysnames="$sysnames $try"
696 { test -n "$o" || test -n "$b"; } && os_used=t
697 { test -n "$m" || test -n "$m0"; } && machine_used=t
698 case x${m0:-$m} in
699 x*/$submachine) submachine_used=t ;;
700 esac
701 if test -n "$d"; then
702 case "$sysnames_add_ons" in
703 *" $d "*) ;;
704 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
705 esac
706 fi
707 fi
708 fi
709 done
710 done
711 done
712 done
713 done
714 done
715 done
717 # If the assembler supports gnu_indirect_function symbol type and the
718 # architecture supports multi-arch, we enable multi-arch by default.
719 case $sysnames_add_ons$sysnames in
720 *"$multi_arch_d"*)
721 ;;
722 *)
723 test x"$multi_arch" = xdefault && multi_arch=no
724 ;;
725 esac
726 if test x"$multi_arch" != xno; then
727 AC_DEFINE(USE_MULTIARCH)
728 fi
729 AC_SUBST(multi_arch)
731 if test -z "$os_used" && test "$os" != none; then
732 AC_MSG_ERROR(Operating system $os is not supported.)
733 fi
734 if test -z "$machine_used" && test "$machine" != none; then
735 AC_MSG_ERROR(The $machine is not supported.)
736 fi
737 if test -z "$submachine_used" && test -n "$submachine"; then
738 AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
739 fi
740 AC_SUBST(submachine)
742 # We have now validated the configuration.
744 # Expand the list of system names into a full list of directories
745 # from each element's parent name and Implies file (if present).
746 set $sysnames
747 names=
748 while test $# -gt 0; do
749 name=$1
750 shift
752 case " $names " in *" $name "*)
753 # Already in the list.
754 continue
755 esac
757 # Report each name as we discover it, so there is no long pause in output.
758 echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
760 name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
762 case $name in
763 /*) xsrcdir= ;;
764 *) xsrcdir=$srcdir/ ;;
765 esac
766 test -n "$enable_debug_configure" &&
767 echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
769 for implies_file in Implies Implies-before Implies-after; do
770 implies_type=`echo $implies_file | sed s/-/_/`
771 eval ${implies_type}=
772 if test -f $xsrcdir$name/$implies_file; then
773 # Collect more names from the `Implies' file (removing comments).
774 implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
775 for x in $implied_candidate; do
776 found=no
777 if test -d $xsrcdir$name_base/$x; then
778 eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
779 found=yes
780 fi
781 for d in $add_ons_pfx ''; do
782 try="${d}sysdeps/$x"
783 case $d in
784 /*) try_srcdir= ;;
785 *) try_srcdir=$srcdir/ ;;
786 esac
787 test -n "$enable_debug_configure" &&
788 echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
789 if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
790 then
791 eval "${implies_type}=\"\$${implies_type} \$try\""
792 found=yes
793 case "$sysnames_add_ons" in
794 *" $d "*) ;;
795 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
796 esac
797 fi
798 done
799 if test $found = no; then
800 AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
801 fi
802 done
803 fi
804 done
806 # Add NAME to the list of names.
807 names="$names $name"
809 # Find the parent of NAME, using the empty string if it has none.
810 changequote(,)dnl
811 parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
812 changequote([,])dnl
814 test -n "$enable_debug_configure" &&
815 echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
816 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
818 # Add the names implied by NAME, and NAME's parent (if it has one), to
819 # the list of names to be processed (the argument list). We prepend the
820 # implied names to the list and append the parent. We want implied
821 # directories to come before further directories inferred from the
822 # configuration components; this ensures that for sysv4, unix/common
823 # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
824 # after sysv4).
825 sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
826 test -n "$sysnames" && set $sysnames
827 done
829 # Add the default directories.
830 default_sysnames="sysdeps/generic"
831 sysnames="$names $default_sysnames"
832 AC_SUBST(sysnames)
833 # The other names were emitted during the scan.
834 AC_MSG_RESULT($default_sysnames)
836 # Collect the list of add-ons that supply partial sysdeps trees.
837 sysdeps_add_ons=
838 for add_on in $add_ons; do
839 case "$add_on" in
840 /*) xsrcdir= ;;
841 *) xsrcdir="$srcdir/" ;;
842 esac
844 test -d "$xsrcdir$add_on/sysdeps" || {
845 case "$configured_add_ons " in
846 *" $add_on "*) ;;
847 *|'')
848 AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
849 ;;
850 esac
851 continue
852 }
854 sysdeps_add_ons="$sysdeps_add_ons $add_on"
855 case "$sysnames_add_ons" in
856 *" $add_on/ "*) ;;
857 *|'')
858 AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
859 continue ;;
860 esac
862 found=no
863 for d in $sysnames; do
864 case "$d" in
865 $add_on/sysdeps/*) ;;
866 *) continue ;;
867 esac
868 (cd "$xsrcdir$d" && for f in *[[!~]]; do
869 case "$f" in
870 sys|bits)
871 for ff in $f/*.h; do
872 test -d "$ff" || { test -e "$ff" && exit 88; }
873 done
874 ;;
875 *)
876 test -d "$f" || { test -e "$f" && exit 88; }
877 ;;
878 esac
879 done)
880 if test $? -eq 88; then
881 found=yes
882 break
883 fi
884 done
885 if test $found = no; then
886 AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
887 fi
888 done
889 AC_SUBST(sysdeps_add_ons)
892 ### Locate tools.
894 AC_PROG_INSTALL
895 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
896 # The makefiles need to use a different form to find it in $srcdir.
897 INSTALL='\$(..)./scripts/install-sh -c'
898 fi
899 AC_PROG_LN_S
901 LIBC_PROG_BINUTILS
903 # Accept binutils 2.20 or newer.
904 AC_CHECK_PROG_VER(AS, $AS, --version,
905 [GNU assembler.* \([0-9]*\.[0-9.]*\)],
906 [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
907 AC_CHECK_PROG_VER(LD, $LD, --version,
908 [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
909 [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
911 # These programs are version sensitive.
912 AC_CHECK_TOOL_PREFIX
913 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
914 [GNU Make[^0-9]*\([0-9][0-9.]*\)],
915 [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
917 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
918 [GNU gettext.* \([0-9]*\.[0-9.]*\)],
919 [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
920 MSGFMT=: aux_missing="$aux_missing msgfmt")
921 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
922 [GNU texinfo.* \([0-9][0-9.]*\)],
923 [4.[5-9]*|4.[1-9][0-9]*|[5-9].*],
924 MAKEINFO=: aux_missing="$aux_missing makeinfo")
925 AC_CHECK_PROG_VER(SED, sed, --version,
926 [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
927 [3.0[2-9]*|3.[1-9]*|[4-9]*],
928 SED=: aux_missing="$aux_missing sed")
929 AC_CHECK_PROG_VER(AWK, gawk, --version,
930 [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
931 [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
933 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
934 AC_TRY_COMPILE([], [
935 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 4)
936 #error insufficient compiler
937 #endif],
938 [libc_cv_compiler_ok=yes],
939 [libc_cv_compiler_ok=no])])
940 AS_IF([test $libc_cv_compiler_ok != yes],
941 [critic_missing="$critic_missing compiler"])
943 AC_CHECK_TOOL(NM, nm, false)
945 if test "x$maintainer" = "xyes"; then
946 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
947 case "x$AUTOCONF" in
948 xno|x|x:) AUTOCONF=no ;;
949 *)
950 AC_CACHE_CHECK(dnl
951 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
952 if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
953 libc_cv_autoconf_works=yes
954 else
955 libc_cv_autoconf_works=no
956 fi])
957 test $libc_cv_autoconf_works = yes || AUTOCONF=no
958 ;;
959 esac
960 if test "x$AUTOCONF" = xno; then
961 aux_missing="$aux_missing autoconf"
962 fi
963 else
964 AUTOCONF=no
965 fi
967 test -n "$critic_missing" && AC_MSG_ERROR([
968 *** These critical programs are missing or too old:$critic_missing
969 *** Check the INSTALL file for required versions.])
971 test -n "$aux_missing" && AC_MSG_WARN([
972 *** These auxiliary programs are missing or incompatible versions:$aux_missing
973 *** some features will be disabled.
974 *** Check the INSTALL file for required versions.])
976 # if using special system headers, find out the compiler's sekrit
977 # header directory and add that to the list. NOTE: Only does the right
978 # thing on a system that doesn't need fixincludes. (Not presently a problem.)
979 if test -n "$sysheaders"; then
980 SYSINCLUDES=-nostdinc
981 for d in include include-fixed; do
982 i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
983 SYSINCLUDES="$SYSINCLUDES -isystem $i"
984 done
985 SYSINCLUDES="$SYSINCLUDES \
986 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
987 if test -n "$CXX"; then
988 CXX_SYSINCLUDES=
989 for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
990 | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
991 test "x$cxxheaders" != x &&
992 CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
993 done
994 fi
995 fi
996 AC_SUBST(SYSINCLUDES)
997 AC_SUBST(CXX_SYSINCLUDES)
999 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1000 # since this would lead to problems installing/building glibc.
1001 # LD_LIBRARY_PATH contains the current directory if one of the following
1002 # is true:
1003 # - one of the terminals (":" and ";") is the first or last sign
1004 # - two terminals occur directly after each other
1005 # - the path contains an element with a dot in it
1006 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1007 changequote(,)dnl
1008 case ${LD_LIBRARY_PATH} in
1009 [:\;]* | *[:\;] | *[:\;][:\;]* | *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1010 ld_library_path_setting="contains current directory"
1011 ;;
1012 *)
1013 ld_library_path_setting="ok"
1014 ;;
1015 esac
1016 changequote([,])dnl
1017 AC_MSG_RESULT($ld_library_path_setting)
1018 if test "$ld_library_path_setting" != "ok"; then
1019 AC_MSG_ERROR([
1020 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1021 *** building glibc. Please change the environment variable
1022 *** and run configure again.])
1023 fi
1025 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1026 if $CC -v -static-libgcc 2>&1 | grep 'unrecognized option.*static-libgcc' >/dev/null; then
1027 libc_cv_gcc_static_libgcc=
1028 else
1029 libc_cv_gcc_static_libgcc=-static-libgcc
1030 fi])
1031 AC_SUBST(libc_cv_gcc_static_libgcc)
1033 AC_PATH_PROG(BASH_SHELL, bash, no)
1035 AC_PATH_PROG(PERL, perl, no)
1036 if test "$PERL" != no &&
1037 (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1038 PERL=no
1039 fi
1040 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1041 $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1042 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1044 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1045 AC_TRY_COMPILE(dnl
1046 [#define __need_size_t
1047 #define __need_wchar_t
1048 #include <stddef.h>
1049 #define __need_NULL
1050 #include <stddef.h>], [size_t size; wchar_t wchar;
1051 #ifdef offsetof
1052 #error stddef.h ignored __need_*
1053 #endif
1054 if (&size == NULL || &wchar == NULL) abort ();],
1055 libc_cv_friendly_stddef=yes,
1056 libc_cv_friendly_stddef=no)])
1057 if test $libc_cv_friendly_stddef = yes; then
1058 config_vars="$config_vars
1059 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1060 fi
1062 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1063 libc_cv_need_minus_P, [dnl
1064 cat > conftest.S <<EOF
1065 #include "confdefs.h"
1066 /* Nothing whatsoever. */
1067 EOF
1068 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1069 libc_cv_need_minus_P=no
1070 else
1071 libc_cv_need_minus_P=yes
1072 fi
1073 rm -f conftest*])
1074 if test $libc_cv_need_minus_P = yes; then
1075 config_vars="$config_vars
1076 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1077 fi
1079 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1080 cat > conftest.s <<EOF
1081 ${libc_cv_dot_text}
1082 foo:
1083 .set glibc_conftest_frobozz,foo
1084 .globl glibc_conftest_frobozz
1085 EOF
1086 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1087 # (but it doesn't work), so we must do a linking check to be sure.
1088 cat > conftest1.c <<\EOF
1089 extern int glibc_conftest_frobozz;
1090 void _start() { glibc_conftest_frobozz = 1; }
1091 EOF
1092 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1093 -nostartfiles -nostdlib \
1094 -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1095 libc_cv_asm_set_directive=yes
1096 else
1097 libc_cv_asm_set_directive=no
1098 fi
1099 rm -f conftest*])
1100 if test $libc_cv_asm_set_directive = yes; then
1101 AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1102 fi
1104 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1105 libc_cv_asm_unique_object, [dnl
1106 cat > conftest.s <<EOF
1107 ${libc_cv_dot_text}
1108 _sym:
1109 .type _sym, %gnu_unique_object
1110 EOF
1111 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1112 libc_cv_asm_unique_object=yes
1113 else
1114 libc_cv_asm_unique_object=no
1115 fi
1116 rm -f conftest*])
1117 if test $libc_cv_asm_unique_object = yes; then
1118 AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1119 fi
1121 AC_CACHE_CHECK(for .previous assembler directive,
1122 libc_cv_asm_previous_directive, [dnl
1123 cat > conftest.s <<EOF
1124 .section foo_section
1125 .previous
1126 EOF
1127 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1128 libc_cv_asm_previous_directive=yes
1129 else
1130 libc_cv_asm_previous_directive=no
1131 fi
1132 rm -f conftest*])
1133 if test $libc_cv_asm_previous_directive = yes; then
1134 AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1135 else
1136 AC_CACHE_CHECK(for .popsection assembler directive,
1137 libc_cv_asm_popsection_directive, [dnl
1138 cat > conftest.s <<EOF
1139 .pushsection foo_section
1140 .popsection
1141 EOF
1142 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1143 libc_cv_asm_popsection_directive=yes
1144 else
1145 libc_cv_asm_popsection_directive=no
1146 fi
1147 rm -f conftest*])
1148 if test $libc_cv_asm_popsection_directive = yes; then
1149 AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1150 fi
1151 fi
1152 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1153 libc_cv_asm_protected_directive, [dnl
1154 cat > conftest.s <<EOF
1155 .protected foo
1156 foo:
1157 .hidden bar
1158 bar:
1159 EOF
1160 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1161 libc_cv_asm_protected_directive=yes
1162 else
1163 AC_MSG_ERROR(assembler support for symbol visibility is required)
1164 fi
1165 rm -f conftest*])
1167 if test $libc_cv_asm_protected_directive = yes; then
1168 AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1169 libc_cv_visibility_attribute,
1170 [cat > conftest.c <<EOF
1171 int foo __attribute__ ((visibility ("hidden"))) = 1;
1172 int bar __attribute__ ((visibility ("protected"))) = 1;
1173 EOF
1174 libc_cv_visibility_attribute=no
1175 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1176 if grep '\.hidden.*foo' conftest.s >/dev/null; then
1177 if grep '\.protected.*bar' conftest.s >/dev/null; then
1178 libc_cv_visibility_attribute=yes
1179 fi
1180 fi
1181 fi
1182 rm -f conftest.{c,s}
1183 ])
1184 if test $libc_cv_visibility_attribute != yes; then
1185 AC_MSG_ERROR(compiler support for visibility attribute is required)
1186 fi
1187 fi
1189 if test $libc_cv_visibility_attribute = yes; then
1190 AC_CACHE_CHECK(for broken __attribute__((visibility())),
1191 libc_cv_broken_visibility_attribute,
1192 [cat > conftest.c <<EOF
1193 int foo (int x);
1194 int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1195 int bar (int x) { return x; }
1196 EOF
1197 libc_cv_broken_visibility_attribute=yes
1198 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1199 changequote(,)dnl
1200 if grep '\.hidden[ _]foo' conftest.s >/dev/null; then
1201 changequote([,])dnl
1202 libc_cv_broken_visibility_attribute=no
1203 fi
1204 fi
1205 rm -f conftest.c conftest.s
1206 ])
1207 if test $libc_cv_broken_visibility_attribute = yes; then
1208 AC_MSG_ERROR(working compiler support for visibility attribute is required)
1209 fi
1210 fi
1212 AC_CACHE_CHECK(for broken __attribute__((alias())),
1213 libc_cv_broken_alias_attribute,
1214 [cat > conftest.c <<EOF
1215 extern int foo (int x) __asm ("xyzzy");
1216 int bar (int x) { return x; }
1217 extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1218 extern int dfoo;
1219 extern __typeof (dfoo) dfoo __asm ("abccb");
1220 int dfoo = 1;
1221 EOF
1222 libc_cv_broken_alias_attribute=yes
1223 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1224 if grep 'xyzzy' conftest.s >/dev/null &&
1225 grep 'abccb' conftest.s >/dev/null; then
1226 libc_cv_broken_alias_attribute=no
1227 fi
1228 fi
1229 rm -f conftest.c conftest.s
1230 ])
1231 if test $libc_cv_broken_alias_attribute = yes; then
1232 AC_MSG_ERROR(working alias attribute support required)
1233 fi
1235 if test $libc_cv_visibility_attribute = yes; then
1236 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1237 libc_cv_have_sdata_section,
1238 [echo "int i;" > conftest.c
1239 libc_cv_have_sdata_section=no
1240 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1241 | grep '\.sdata' >/dev/null; then
1242 libc_cv_have_sdata_section=yes
1243 fi
1244 rm -f conftest.c conftest.so
1245 ])
1246 if test $libc_cv_have_sdata_section = yes; then
1247 AC_DEFINE(HAVE_SDATA_SECTION)
1248 fi
1249 fi
1251 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1252 libc_cv_initfini_array, [dnl
1253 LIBC_TRY_LINK_STATIC([
1254 int foo (void) { return 1; }
1255 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1256 ],
1257 [if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1258 libc_cv_initfini_array=yes
1259 else
1260 libc_cv_initfini_array=no
1261 fi],
1262 [libc_cv_initfini_array=no])
1263 ])
1264 if test $libc_cv_initfini_array != yes; then
1265 AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1266 fi
1268 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1269 libc_cv_ctors_header, [dnl
1270 libc_cv_ctors_header=yes
1271 LIBC_TRY_LINK_STATIC([
1272 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1273 __attribute__ ((destructor)) void dtor (void) { asm (""); }
1274 ],
1275 [dnl
1276 AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1277 { gsub(/\@<:@ */, "@<:@") }
1278 $2 == ".ctors" || $2 == ".dtors" {
1279 size = strtonum("0x" $6)
1280 align = strtonum("0x" $NF)
1281 seen@<:@$2@:>@ = 1
1282 stub@<:@$2@:>@ = size == align * 2
1283 }
1284 END {
1285 ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1286 dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1287 exit ((ctors_ok && dtors_ok) ? 0 : 1)
1288 }
1289 '], [libc_cv_ctors_header=no])
1290 ], [dnl
1291 AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1292 ])
1293 ])
1294 if test $libc_cv_ctors_header = no; then
1295 AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1296 fi
1298 AC_CACHE_CHECK(for libunwind-support in compiler,
1299 libc_cv_cc_with_libunwind, [
1300 cat > conftest.c <<EOF
1301 int main (void) { return 0; }
1302 EOF
1303 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1304 conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1305 libc_cv_cc_with_libunwind=yes
1306 else
1307 libc_cv_cc_with_libunwind=no
1308 fi
1309 rm -f conftest*])
1310 AC_SUBST(libc_cv_cc_with_libunwind)
1311 if test $libc_cv_cc_with_libunwind = yes; then
1312 AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1313 fi
1315 LIBC_LINKER_FEATURE([-z nodelete], [-Wl,--enable-new-dtags,-z,nodelete],
1316 [libc_cv_z_nodelete=yes],
1317 [AC_MSG_ERROR(linker with -z nodelete support required)])
1319 LIBC_LINKER_FEATURE([-z nodlopen], [-Wl,--enable-new-dtags,-z,nodlopen],
1320 [libc_cv_z_nodlopen=yes],
1321 [AC_MSG_ERROR(linker with -z nodlopen support required)])
1323 LIBC_LINKER_FEATURE([-z initfirst], [-Wl,--enable-new-dtags,-z,initfirst],
1324 [libc_cv_z_initfirst=yes],
1325 [AC_MSG_ERROR(linker with -z initfirst support required)])
1327 AC_CACHE_CHECK(for -Bgroup option,
1328 libc_cv_Bgroup, [dnl
1329 cat > conftest.c <<EOF
1330 int _start (void) { return 42; }
1331 EOF
1332 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1333 -fPIC -shared -o conftest.so conftest.c
1334 -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1335 then
1336 libc_cv_Bgroup=yes
1337 else
1338 libc_cv_Bgroup=no
1339 fi
1340 rm -f conftest*])
1341 AC_SUBST(libc_cv_Bgroup)
1343 ASFLAGS_config=
1344 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1345 libc_cv_as_noexecstack, [dnl
1346 cat > conftest.c <<EOF
1347 void foo (void) { }
1348 EOF
1349 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1350 -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1351 && grep .note.GNU-stack conftest.s >/dev/null \
1352 && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1353 -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1354 then
1355 libc_cv_as_noexecstack=yes
1356 else
1357 libc_cv_as_noexecstack=no
1358 fi
1359 rm -f conftest*])
1360 if test $libc_cv_as_noexecstack = yes; then
1361 ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1362 fi
1363 AC_SUBST(ASFLAGS_config)
1365 AC_CACHE_CHECK(for -z combreloc,
1366 libc_cv_z_combreloc, [dnl
1367 cat > conftest.c <<EOF
1368 extern int bar (int);
1369 extern int mumble;
1370 int foo (void) { return bar (mumble); }
1371 EOF
1372 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1373 -fPIC -shared -o conftest.so conftest.c
1374 -nostdlib -nostartfiles
1375 -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1376 then
1377 dnl The following test is a bit weak. We must use a tool which can test
1378 dnl cross-platform since the gcc used can be a cross compiler. Without
1379 dnl introducing new options this is not easily doable. Instead use a tool
1380 dnl which always is cross-platform: readelf. To detect whether -z combreloc
1381 dnl look for a section named .rel.dyn.
1382 if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1383 libc_cv_z_combreloc=yes
1384 else
1385 libc_cv_z_combreloc=no
1386 fi
1387 else
1388 libc_cv_z_combreloc=no
1389 fi
1390 rm -f conftest*])
1391 if test "$libc_cv_z_combreloc" = yes; then
1392 AC_DEFINE(HAVE_Z_COMBRELOC)
1393 fi
1394 AC_SUBST(libc_cv_z_combreloc)
1396 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1397 [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1398 AC_SUBST(libc_cv_z_execstack)
1400 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1401 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1402 ])
1404 AC_SUBST(libc_cv_fpie)
1406 AC_CACHE_CHECK(for --hash-style option,
1407 libc_cv_hashstyle, [dnl
1408 cat > conftest.c <<EOF
1409 int _start (void) { return 42; }
1410 EOF
1411 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1412 -fPIC -shared -o conftest.so conftest.c
1413 -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1414 then
1415 libc_cv_hashstyle=yes
1416 else
1417 libc_cv_hashstyle=no
1418 fi
1419 rm -f conftest*])
1420 AC_SUBST(libc_cv_hashstyle)
1422 # The linker's default -shared behavior is good enough if it
1423 # does these things that our custom linker scripts ensure that
1424 # all allocated NOTE sections come first.
1425 if test "$use_default_link" = default; then
1426 AC_CACHE_CHECK([for sufficient default -shared layout],
1427 libc_cv_use_default_link, [dnl
1428 libc_cv_use_default_link=no
1429 cat > conftest.s <<\EOF
1430 .section .note.a,"a",%note
1431 .balign 4
1432 .long 4,4,9
1433 .string "GNU"
1434 .string "foo"
1435 .section .note.b,"a",%note
1436 .balign 4
1437 .long 4,4,9
1438 .string "GNU"
1439 .string "bar"
1440 EOF
1441 if AC_TRY_COMMAND([dnl
1442 ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1443 ac_try=`$READELF -S conftest.so | sed -n \
1444 ['${x;p;}
1445 s/^ *\[ *[1-9][0-9]*\] *\([^ ][^ ]*\) *\([^ ][^ ]*\) .*$/\2 \1/
1446 t a
1447 b
1448 : a
1449 H']`
1450 then
1451 libc_seen_a=no libc_seen_b=no
1452 set -- $ac_try
1453 while test $# -ge 2 -a "$1" = NOTE; do
1454 case "$2" in
1455 .note.a) libc_seen_a=yes ;;
1456 .note.b) libc_seen_b=yes ;;
1457 esac
1458 shift 2
1459 done
1460 case "$libc_seen_a$libc_seen_b" in
1461 yesyes)
1462 libc_cv_use_default_link=yes
1463 ;;
1464 *)
1465 echo >&AS_MESSAGE_LOG_FD "\
1466 $libc_seen_a$libc_seen_b from:
1467 $ac_try"
1468 ;;
1469 esac
1470 fi
1471 rm -f conftest*])
1472 use_default_link=$libc_cv_use_default_link
1473 fi
1475 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1476 if libc_cv_output_format=`
1477 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1478 then
1479 :
1480 else
1481 libc_cv_output_format=
1482 fi
1483 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1484 AC_SUBST(libc_cv_output_format)
1486 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1487 cat > conftest.c <<EOF
1488 int foo;
1489 EOF
1490 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1491 conftest.c 1>&AS_MESSAGE_LOG_FD])
1492 then
1493 libc_cv_fno_toplevel_reorder=yes
1494 else
1495 libc_cv_fno_toplevel_reorder=no
1496 fi
1497 rm -f conftest*])
1498 if test $libc_cv_fno_toplevel_reorder = yes; then
1499 fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1500 else
1501 fno_unit_at_a_time=-fno-unit-at-a-time
1502 fi
1503 AC_SUBST(fno_unit_at_a_time)
1505 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1506 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1507 [libc_cv_ssp=yes],
1508 [libc_cv_ssp=no])
1509 ])
1510 AC_SUBST(libc_cv_ssp)
1512 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1513 cat > conftest.c <<EOF
1514 int foo;
1515 #ifdef __GNUC_GNU_INLINE__
1516 main () { return 0;}
1517 #else
1518 #error
1519 #endif
1520 EOF
1521 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1522 -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1523 then
1524 libc_cv_gnu89_inline=yes
1525 else
1526 libc_cv_gnu89_inline=no
1527 fi
1528 rm -f conftest*])
1529 if test $libc_cv_gnu89_inline = yes; then
1530 gnu89_inline=-fgnu89-inline
1531 else
1532 gnu89_inline=
1533 fi
1534 AC_SUBST(gnu89_inline)
1536 AC_CACHE_CHECK(whether cc puts quotes around section names,
1537 libc_cv_have_section_quotes,
1538 [cat > conftest.c <<EOF
1539 static const int foo
1540 __attribute__ ((section ("bar"))) = 1;
1541 EOF
1542 if ${CC-cc} -S conftest.c -o conftest.s; then
1543 if grep '\.section.*"bar"' conftest.s >/dev/null; then
1544 libc_cv_have_section_quotes=yes
1545 else
1546 libc_cv_have_section_quotes=no
1547 fi
1548 else
1549 libc_cv_have_section_quotes=unknown
1550 fi
1551 rm -f conftest.{c,s}
1552 ])
1553 if test $libc_cv_have_section_quotes = yes; then
1554 AC_DEFINE(HAVE_SECTION_QUOTES)
1555 fi
1557 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1558 [dnl
1559 cat > conftest.s <<EOF
1560 ${libc_cv_dot_text}
1561 .globl foo
1562 foo:
1563 .weak foo
1564 .weak bar; bar = foo
1565 EOF
1566 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1567 libc_cv_asm_weak_directive=yes
1568 else
1569 libc_cv_asm_weak_directive=no
1570 fi
1571 rm -f conftest*])
1573 if test $libc_cv_asm_weak_directive = no; then
1574 AC_CACHE_CHECK(for assembler .weakext directive,
1575 libc_cv_asm_weakext_directive,
1576 [dnl
1577 cat > conftest.s <<EOF
1578 ${libc_cv_dot_text}
1579 .globl foo
1580 foo:
1581 .weakext bar foo
1582 .weakext baz
1583 .globl baz
1584 baz:
1585 EOF
1586 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1587 libc_cv_asm_weakext_directive=yes
1588 else
1589 libc_cv_asm_weakext_directive=no
1590 fi
1591 rm -f conftest*])
1593 fi # no .weak
1595 if test $libc_cv_asm_weak_directive = yes; then
1596 AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1597 elif test $libc_cv_asm_weakext_directive = yes; then
1598 AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1599 fi
1601 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1602 cat > conftest.c <<\EOF
1603 _start () {}
1604 int __eh_pc;
1605 __throw () {}
1606 EOF
1607 dnl No \ in command here because it ends up inside ''.
1608 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1609 -nostdlib -nostartfiles -Wl,--no-whole-archive
1610 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1611 libc_cv_ld_no_whole_archive=yes
1612 else
1613 libc_cv_ld_no_whole_archive=no
1614 fi
1615 rm -f conftest*])
1616 if test $libc_cv_ld_no_whole_archive = no; then
1617 AC_MSG_ERROR([support for --no-whole-archive is needed])
1618 fi
1620 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1621 cat > conftest.c <<\EOF
1622 _start () {}
1623 int __eh_pc;
1624 __throw () {}
1625 EOF
1626 dnl No \ in command here because it ends up inside ''.
1627 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1628 -nostdlib -nostartfiles -fexceptions
1629 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1630 libc_cv_gcc_exceptions=yes
1631 else
1632 libc_cv_gcc_exceptions=no
1633 fi
1634 rm -f conftest*])
1635 if test $libc_cv_gcc_exceptions = yes; then
1636 exceptions=-fexceptions
1637 fi
1638 AC_SUBST(exceptions)dnl
1640 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1641 cat > conftest.c <<\EOF
1642 void zero (void *x)
1643 {
1644 __builtin_memset (x, 0, 1000);
1645 }
1646 EOF
1647 dnl
1648 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1649 then
1650 libc_cv_gcc_builtin_memset=no
1651 else
1652 libc_cv_gcc_builtin_memset=yes
1653 fi
1654 rm -f conftest* ])
1655 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1656 AC_DEFINE(HAVE_BUILTIN_MEMSET)
1657 fi
1659 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1660 cat > conftest.c <<\EOF
1661 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1662 char *foo (const char *a, const char *b)
1663 {
1664 return __builtin_strstr (a, b);
1665 }
1666 EOF
1667 dnl
1668 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1669 then
1670 libc_cv_gcc_builtin_redirection=yes
1671 else
1672 libc_cv_gcc_builtin_redirection=no
1673 fi
1674 rm -f conftest* ])
1675 if test "$libc_cv_gcc_builtin_redirection" = no; then
1676 AC_MSG_ERROR([support for the symbol redirection needed])
1677 fi
1679 dnl Check whether the compiler supports the __thread keyword.
1680 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1681 [cat > conftest.c <<\EOF
1682 __thread int a = 42;
1683 EOF
1684 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1685 libc_cv_gcc___thread=yes
1686 else
1687 libc_cv_gcc___thread=no
1688 fi
1689 rm -f conftest*])
1690 if test "$libc_cv_gcc___thread" = no; then
1691 AC_MSG_ERROR([support for the __thread keyword is required])
1692 fi
1694 dnl Check whether the compiler supports the tls_model attribute.
1695 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1696 cat > conftest.c <<\EOF
1697 extern __thread int a __attribute__((tls_model ("initial-exec")));
1698 EOF
1699 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
1700 libc_cv_gcc_tls_model_attr=yes
1701 else
1702 libc_cv_gcc_tls_model_attr=no
1703 fi
1704 rm -f conftest*])
1705 if test "$libc_cv_gcc_tls_model_attr" = no; then
1706 AC_MSG_ERROR([support for the tls_model attribute is required])
1707 fi
1709 dnl Determine how to disable generation of FMA instructions.
1710 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1711 libc_cv_cc_nofma, [dnl
1712 libc_cv_cc_nofma=
1713 for opt in -ffp-contract=off -mno-fused-madd; do
1714 LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1715 done])
1716 AC_SUBST(libc_cv_cc_nofma)
1718 if test -n "$submachine"; then
1719 AC_CACHE_CHECK([for compiler option for CPU variant],
1720 libc_cv_cc_submachine, [dnl
1721 libc_cv_cc_submachine=no
1722 for opt in "-march=$submachine" "-mcpu=$submachine"; do
1723 LIBC_TRY_CC_OPTION([$opt], [
1724 libc_cv_cc_submachine="$opt"
1725 break], [])
1726 done])
1727 if test "x$libc_cv_cc_submachine" = xno; then
1728 AC_MSG_ERROR([${CC-cc} does not support $submachine])
1729 fi
1730 fi
1731 AC_SUBST(libc_cv_cc_submachine)
1733 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1734 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1735 cat > conftest.c <<EOF
1736 void
1737 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1738 foo (void) {}
1739 EOF
1740 libc_cv_cc_loop_to_function=no
1741 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1742 then
1743 libc_cv_cc_loop_to_function=yes
1744 fi
1745 rm -f conftest*])
1746 if test $libc_cv_cc_loop_to_function = yes; then
1747 AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1748 fi
1749 AC_SUBST(libc_cv_cc_loop_to_function)
1751 dnl Check whether we have the gd library available.
1752 AC_MSG_CHECKING(for libgd)
1753 if test "$with_gd" != "no"; then
1754 old_CFLAGS="$CFLAGS"
1755 CFLAGS="$CFLAGS $libgd_include"
1756 old_LDFLAGS="$LDFLAGS"
1757 LDFLAGS="$LDFLAGS $libgd_ldflags"
1758 old_LIBS="$LIBS"
1759 LIBS="$LIBS -lgd -lpng -lz -lm"
1760 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1761 CFLAGS="$old_CFLAGS"
1762 LDFLAGS="$old_LDFLAGS"
1763 LIBS="$old_LIBS"
1764 else
1765 LIBGD=no
1766 fi
1767 AC_MSG_RESULT($LIBGD)
1768 AC_SUBST(LIBGD)
1770 # SELinux detection
1771 if test x$with_selinux = xno ; then
1772 have_selinux=no;
1773 else
1774 # See if we have the SELinux library
1775 AC_CHECK_LIB(selinux, is_selinux_enabled,
1776 have_selinux=yes, have_selinux=no)
1777 if test x$with_selinux = xyes ; then
1778 if test x$have_selinux = xno ; then
1779 AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1780 fi
1781 fi
1782 fi
1783 # Check if we're building with SELinux support.
1784 if test "x$have_selinux" = xyes; then
1785 AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1787 # See if we have the libaudit library
1788 AC_CHECK_LIB(audit, audit_log_user_avc_message,
1789 have_libaudit=yes, have_libaudit=no)
1790 if test "x$have_libaudit" = xyes; then
1791 AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1792 fi
1793 AC_SUBST(have_libaudit)
1795 # See if we have the libcap library
1796 AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1797 if test "x$have_libcap" = xyes; then
1798 AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1799 fi
1800 AC_SUBST(have_libcap)
1801 fi
1802 AC_SUBST(have_selinux)
1804 dnl check for the size of 'long double'.
1805 AC_CHECK_SIZEOF(long double, 0)
1806 sizeof_long_double=$ac_cv_sizeof_long_double
1807 AC_SUBST(sizeof_long_double)
1809 CPPUNDEFS=
1810 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1811 dnl Since we are building the implementations of the fortified functions here,
1812 dnl having the macro defined interacts very badly.
1813 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1814 [AC_TRY_COMPILE([], [
1815 #ifdef _FORTIFY_SOURCE
1816 # error bogon
1817 #endif],
1818 [libc_cv_predef_fortify_source=no],
1819 [libc_cv_predef_fortify_source=yes])])
1820 if test $libc_cv_predef_fortify_source = yes; then
1821 CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1822 fi
1823 AC_SUBST(CPPUNDEFS)
1825 dnl Check for silly hacked compilers inserting -fstack-protector.
1826 dnl This breaks badly for the early startup code we compile, since
1827 dnl the compiled code can refer to a magic machine-dependent location
1828 dnl for the canary value before we have sufficient setup for that to
1829 dnl work. It's also questionable to build all of libc with this flag
1830 dnl even when you're doing that for most applications you build, since
1831 dnl libc's code is so heavily-used and performance-sensitive. If we
1832 dnl ever really want to make that work, it should be enabled explicitly
1833 dnl in the libc build, not inherited from implicit compiler settings.
1834 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
1835 libc_cv_predef_stack_protector, [
1836 AC_TRY_COMPILE([extern void foobar (char *);],
1837 [char large_array[2048]; foobar (large_array);], [
1838 libc_undefs=`$NM -u conftest.o |
1839 LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1840 2>&AS_MESSAGE_LOG_FD` || {
1841 AC_MSG_ERROR([confusing output from $NM -u])
1842 }
1843 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1844 # On some architectures, there are architecture-specific undefined
1845 # symbols (resolved by the linker), so filter out unknown symbols.
1846 # This will fail to produce the correct result if the compiler
1847 # defaults to -fstack-protector but this produces an undefined symbol
1848 # other than __stack_chk_fail. However, compilers like that have not
1849 # been encountered in practice.
1850 libc_undefs=`echo "$libc_undefs" | egrep '^(foobar|__stack_chk_fail)$'`
1851 case "$libc_undefs" in
1852 foobar) libc_cv_predef_stack_protector=no ;;
1853 '__stack_chk_fail
1854 foobar') libc_cv_predef_stack_protector=yes ;;
1855 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
1856 esac],
1857 [AC_MSG_ERROR([test compilation failed])])
1858 ])
1859 libc_extra_cflags=
1860 if test $libc_cv_predef_stack_protector = yes; then
1861 libc_extra_cflags="$libc_extra_cflags -fno-stack-protector"
1862 fi
1863 libc_extra_cppflags=
1865 # Some linkers on some architectures support __ehdr_start but with
1866 # bugs. Make sure usage of it does not create relocations in the
1867 # output (as the linker should resolve them all for us).
1868 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1869 libc_cv_ehdr_start, [
1870 old_CFLAGS="$CFLAGS"
1871 old_LDFLAGS="$LDFLAGS"
1872 old_LIBS="$LIBS"
1873 CFLAGS="$CFLAGS -fPIC"
1874 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared"
1875 LIBS=
1876 AC_LINK_IFELSE([AC_LANG_SOURCE([
1877 typedef struct {
1878 char foo;
1879 long val;
1880 } Ehdr;
1881 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1882 long ehdr (void) { return __ehdr_start.val; }
1883 ])],
1884 [if $READELF -r conftest | fgrep __ehdr_start >/dev/null; then
1885 libc_cv_ehdr_start=broken
1886 else
1887 libc_cv_ehdr_start=yes
1888 fi], [libc_cv_ehdr_start=no])
1889 CFLAGS="$old_CFLAGS"
1890 LDFLAGS="$old_LDFLAGS"
1891 LIBS="$old_LIBS"
1892 ])
1893 if test "$libc_cv_ehdr_start" = yes; then
1894 AC_DEFINE([HAVE_EHDR_START])
1895 elif test "$libc_cv_ehdr_start" = broken; then
1896 AC_MSG_WARN([linker is broken -- you should upgrade])
1897 fi
1899 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1900 libc_cv_builtin_trap, [dnl
1901 libc_cv_builtin_trap=no
1902 AC_TRY_COMPILE([], [__builtin_trap ()], [
1903 libc_undefs=`$NM -u conftest.o |
1904 LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1905 2>&AS_MESSAGE_LOG_FD` || {
1906 AC_MSG_ERROR([confusing output from $NM -u])
1907 }
1908 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1909 if test -z "$libc_undefs"; then
1910 libc_cv_builtin_trap=yes
1911 fi])])
1912 if test $libc_cv_builtin_trap = yes; then
1913 AC_DEFINE([HAVE_BUILTIN_TRAP])
1914 fi
1916 ### End of automated tests.
1917 ### Now run sysdeps configure fragments.
1919 # They also can set these variables.
1920 use_ldconfig=no
1921 ldd_rewrite_script=no
1922 libc_cv_sysconfdir=$sysconfdir
1923 libc_cv_localstatedir=$localstatedir
1924 libc_cv_gcc_unwind_find_fde=no
1925 libc_cv_idn=no
1927 # Iterate over all the sysdep directories we will use, running their
1928 # configure fragments.
1929 for dir in $sysnames; do
1930 case $dir in
1931 /*) dest=$dir ;;
1932 *) dest=$srcdir/$dir ;;
1933 esac
1934 if test -r $dest/configure; then
1935 AC_MSG_RESULT(running configure fragment for $dir)
1936 . $dest/configure
1937 fi
1938 done
1940 AC_SUBST(libc_extra_cflags)
1941 AC_SUBST(libc_extra_cppflags)
1943 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1944 AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1945 fi
1946 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1948 # A sysdeps configure fragment can reset this if IFUNC is not actually
1949 # usable even though the assembler knows how to generate the symbol type.
1950 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1951 AC_DEFINE(HAVE_IFUNC)
1952 fi
1954 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1955 # configure fragment can override the value to prevent this AC_DEFINE.
1956 AC_SUBST(use_nscd)
1957 if test "x$use_nscd" != xno; then
1958 AC_DEFINE([USE_NSCD])
1959 fi
1960 if test "x$build_nscd" = xdefault; then
1961 build_nscd=$use_nscd
1962 fi
1964 # Test for old glibc 2.0.x headers so that they can be removed properly
1965 # Search only in includedir.
1966 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1967 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1968 then
1969 old_glibc_headers=yes
1970 else
1971 old_glibc_headers=no
1972 fi
1973 AC_MSG_RESULT($old_glibc_headers)
1974 if test ${old_glibc_headers} = yes; then
1975 AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1976 AC_MSG_WARN(*** be removed.)
1977 fi
1978 AC_SUBST(old_glibc_headers)
1980 AC_SUBST(libc_cv_slibdir)
1981 AC_SUBST(libc_cv_rtlddir)
1982 AC_SUBST(libc_cv_localedir)
1983 AC_SUBST(libc_cv_sysconfdir)
1984 AC_SUBST(libc_cv_localstatedir)
1985 AC_SUBST(libc_cv_rootsbindir)
1986 AC_SUBST(libc_cv_forced_unwind)
1988 if test x$use_ldconfig = xyes; then
1989 AC_DEFINE(USE_LDCONFIG)
1990 fi
1991 AC_SUBST(use_ldconfig)
1992 AC_SUBST(ldd_rewrite_script)
1994 AC_SUBST(static)
1995 AC_SUBST(shared)
1997 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1998 [libc_cv_pic_default=yes
1999 cat > conftest.c <<EOF
2000 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2001 # error PIC is default.
2002 #endif
2003 EOF
2004 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2005 libc_cv_pic_default=no
2006 fi
2007 rm -f conftest.*])
2008 AC_SUBST(libc_cv_pic_default)
2010 AC_SUBST(profile)
2011 AC_SUBST(static_nss)
2013 AC_SUBST(DEFINES)
2015 dnl See sysdeps/mach/configure.ac for this variable.
2016 AC_SUBST(mach_interface_list)
2018 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2019 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2020 AC_SUBST(VERSION)
2021 AC_SUBST(RELEASE)
2023 AC_CONFIG_FILES([config.make Makefile])
2024 AC_CONFIG_COMMANDS([default],[[
2025 case $CONFIG_FILES in *config.make*)
2026 echo "$config_vars" >> config.make;;
2027 esac
2028 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2029 AC_OUTPUT