sysdeps/i386/fpu/e_expl.S

   1 /*
   2  * Written by J.T. Conklin <jtc@netbsd.org>.
   3  * Public domain.
   4  *
   5  * Adapted for `long double' by Ulrich Drepper <drepper@cygnus.com>.
   6  */
   7
   8 /*
   9  * The 8087 method for the exponential function is to calculate
  10  *   exp(x) = 2^(x log2(e))
  11  * after separating integer and fractional parts
  12  *   x log2(e) = i + f, |f| <= .5
  13  * 2^i is immediate but f needs to be precise for long double accuracy.
  14  * Suppress range reduction error in computing f by the following.
  15  * Separate x into integer and fractional parts
  16  *   x = xi + xf, |xf| <= .5
  17  * Separate log2(e) into the sum of an exact number c0 and small part c1.
  18  *   c0 + c1 = log2(e) to extra precision
  19  * Then
  20  *   f = (c0 xi - i) + c0 xf + c1 x
  21  * where c0 xi is exact and so also is (c0 xi - i).
  22  * -- moshier@na-net.ornl.gov
  23  */
  24
  25 #include <machine/asm.h>
  26
  27 #ifdef USE_AS_EXP10L
  28 # define IEEE754_EXPL __ieee754_exp10l
  29 # define EXPL_FINITE __exp10l_finite
  30 # define FLDLOG fldl2t
  31 #elif defined USE_AS_EXPM1L
  32 # define IEEE754_EXPL __expm1l
  33 # undef EXPL_FINITE
  34 # define FLDLOG fldl2e
  35 #else
  36 # define IEEE754_EXPL __ieee754_expl
  37 # define EXPL_FINITE __expl_finite
  38 # define FLDLOG fldl2e
  39 #endif
  40
  41         .section .rodata.cst16,"aM",@progbits,16
  42
  43         .p2align 4
  44 #ifdef USE_AS_EXP10L
  45         .type c0,@object
  46 c0:     .byte 0, 0, 0, 0, 0, 0, 0x9a, 0xd4, 0x00, 0x40
  47         .byte 0, 0, 0, 0, 0, 0
  48         ASM_SIZE_DIRECTIVE(c0)
  49         .type c1,@object
  50 c1:     .byte 0x58, 0x92, 0xfc, 0x15, 0x37, 0x9a, 0x97, 0xf0, 0xef, 0x3f
  51         .byte 0, 0, 0, 0, 0, 0
  52         ASM_SIZE_DIRECTIVE(c1)
  53 #else
  54         .type c0,@object
  55 c0:     .byte 0, 0, 0, 0, 0, 0, 0xaa, 0xb8, 0xff, 0x3f
  56         .byte 0, 0, 0, 0, 0, 0
  57         ASM_SIZE_DIRECTIVE(c0)
  58         .type c1,@object
  59 c1:     .byte 0x20, 0xfa, 0xee, 0xc2, 0x5f, 0x70, 0xa5, 0xec, 0xed, 0x3f
  60         .byte 0, 0, 0, 0, 0, 0
  61         ASM_SIZE_DIRECTIVE(c1)
  62 #endif
  63 #ifndef USE_AS_EXPM1L
  64         .type csat,@object
  65 csat:   .byte 0, 0, 0, 0, 0, 0, 0, 0x80, 0x0e, 0x40
  66         .byte 0, 0, 0, 0, 0, 0
  67         ASM_SIZE_DIRECTIVE(csat)
  68 #endif
  69
  70 #ifdef PIC
  71 # define MO(op) op##@GOTOFF(%ecx)
  72 #else
  73 # define MO(op) op
  74 #endif
  75
  76         .text
  77 ENTRY(IEEE754_EXPL)
  78 #ifdef USE_AS_EXPM1L
  79         movzwl  4+8(%esp), %eax
  80         xorb    $0x80, %ah      // invert sign bit (now 1 is "positive")
  81         cmpl    $0xc006, %eax   // is num positive and exp >= 6 (number is >= 128.0)?
  82         jae     HIDDEN_JUMPTARGET (__expl) // (if num is denormal, it is at least >= 64.0)
  83 #endif
  84         fldt    4(%esp)
  85 /* I added the following ugly construct because expl(+-Inf) resulted
  86    in NaN.  The ugliness results from the bright minds at Intel.
  87    For the i686 the code can be written better.
  88    -- drepper@cygnus.com.  */
  89         fxam                    /* Is NaN or +-Inf?  */
  90 #ifdef PIC
  91         LOAD_PIC_REG (cx)
  92 #endif
  93 #ifdef USE_AS_EXPM1L
  94         xorb    $0x80, %ah
  95         cmpl    $0xc006, %eax
  96         fstsw   %ax
  97         movb    $0x45, %dh
  98         jb      4f
  99
 100         /* Below -64.0 (may be -NaN or -Inf). */
 101         andb    %ah, %dh
 102         cmpb    $0x01, %dh
 103         je      2f              /* Is +-NaN, jump.  */
 104         jmp     1f              /* -large, possibly -Inf.  */
 105
 106 4:      /* In range -64.0 to 64.0 (may be +-0 but not NaN or +-Inf).  */
 107         /* Test for +-0 as argument.  */
 108         andb    %ah, %dh
 109         cmpb    $0x40, %dh
 110         je      2f
 111
 112         /* Test for arguments that are small but not subnormal.  */
 113         movzwl  4+8(%esp), %eax
 114         andl    $0x7fff, %eax
 115         cmpl    $0x3fbf, %eax
 116         jge     3f
 117         /* Argument's exponent below -64; avoid spurious underflow if
 118            normal.  */
 119         cmpl    $0x0001, %eax
 120         jge     2f
 121 #else
 122         movzwl  4+8(%esp), %eax
 123         andl    $0x7fff, %eax
 124         cmpl    $0x400d, %eax
 125         jg      5f
 126         cmpl    $0x3fbc, %eax
 127         jge     3f
 128         /* Argument's exponent below -67, result rounds to 1.  */
 129         fld1
 130         faddp
 131         jmp     2f
 132 5:      /* Overflow, underflow or infinity or NaN as argument.  */
 133         fstsw   %ax
 134         movb    $0x45, %dh
 135         andb    %ah, %dh
 136         cmpb    $0x05, %dh
 137         je      1f              /* Is +-Inf, jump.    */
 138         cmpb    $0x01, %dh
 139         je      2f              /* Is +-NaN, jump.    */
 140         /* Overflow or underflow; saturate.  */
 141         fstp    %st
 142         fldt    MO(csat)
 143         andb    $2, %ah
 144         jz      3f
 145         fchs
 146 #endif
 147 3:      FLDLOG                  /* 1  log2(base)      */
 148         fmul    %st(1), %st     /* 1  x log2(base)    */
 149         /* Set round-to-nearest temporarily.  */
 150         subl    $8, %esp
 151         cfi_adjust_cfa_offset (8)
 152         fstcw   4(%esp)
 153         movl    $0xf3ff, %edx
 154         andl    4(%esp), %edx
 155         movl    %edx, (%esp)
 156         fldcw   (%esp)
 157         frndint                 /* 1  i               */
 158         fld     %st(1)          /* 2  x               */
 159         frndint                 /* 2  xi              */
 160         fldcw   4(%esp)
 161         addl    $8, %esp
 162         cfi_adjust_cfa_offset (-8)
 163         fld     %st(1)          /* 3  i               */
 164         fldt    MO(c0)          /* 4  c0              */
 165         fld     %st(2)          /* 5  xi              */
 166         fmul    %st(1), %st     /* 5  c0 xi           */
 167         fsubp   %st, %st(2)     /* 4  f = c0 xi  - i  */
 168         fld     %st(4)          /* 5  x               */
 169         fsub    %st(3), %st     /* 5  xf = x - xi     */
 170         fmulp   %st, %st(1)     /* 4  c0 xf           */
 171         faddp   %st, %st(1)     /* 3  f = f + c0 xf   */
 172         fldt    MO(c1)          /* 4                  */
 173         fmul    %st(4), %st     /* 4  c1 * x          */
 174         faddp   %st, %st(1)     /* 3  f = f + c1 * x  */
 175         f2xm1                   /* 3 2^(fract(x * log2(base))) - 1 */
 176 #ifdef USE_AS_EXPM1L
 177         fstp    %st(1)          /* 2                  */
 178         fscale                  /* 2 scale factor is st(1); base^x - 2^i */
 179         fxch                    /* 2 i                */
 180         fld1                    /* 3 1.0              */
 181         fscale                  /* 3 2^i              */
 182         fld1                    /* 4 1.0              */
 183         fsubrp  %st, %st(1)     /* 3 2^i - 1.0        */
 184         fstp    %st(1)          /* 2                  */
 185         faddp   %st, %st(1)     /* 1 base^x - 1.0     */
 186 #else
 187         fld1                    /* 4 1.0              */
 188         faddp                   /* 3 2^(fract(x * log2(base))) */
 189         fstp    %st(1)          /* 2  */
 190         fscale                  /* 2 scale factor is st(1); base^x */
 191         fstp    %st(1)          /* 1  */
 192 #endif
 193         fstp    %st(1)          /* 0  */
 194         jmp     2f
 195 1:
 196 #ifdef USE_AS_EXPM1L
 197         /* For expm1l, only negative sign gets here.  */
 198         fstp    %st
 199         fld1
 200         fchs
 201 #else
 202         testl   $0x200, %eax    /* Test sign.  */
 203         jz      2f              /* If positive, jump.  */
 204         fstp    %st
 205         fldz                    /* Set result to 0.  */
 206 #endif
 207 2:      ret
 208 END(IEEE754_EXPL)
 209 #ifdef USE_AS_EXPM1L
 210 libm_hidden_def (__expm1l)
 211 weak_alias (__expm1l, expm1l)
 212 #else
 213 strong_alias (IEEE754_EXPL, EXPL_FINITE)
 214 #endif