sysdeps/gnu/errlist.awk

   1 # Copyright (C) 1991, 92, 93, 94, 95, 96 Free Software Foundation, Inc.
   2 # This file is part of the GNU C Library.
   3
   4 # The GNU C Library is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU Library General Public License
   6 # as published by the Free Software Foundation; either version 2 of
   7 # the License, or (at your option) any later version.
   8
   9 # The GNU C Library is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Library General Public License for more details.
  13
  14 # You should have received a copy of the GNU Library General Public
  15 # License along with the GNU C Library; see the file COPYING.LIB.  If
  16 # not, write to the Free Software Foundation, Inc., 675 Mass Ave,
  17 # Cambridge, MA 02139, USA.
  18
  19 # errno.texi contains lines like:
  20 # @comment errno.h
  21 # @comment POSIX.1: Function not implemented
  22 # @deftypevr Macro int ENOSYS
  23 # @comment errno 78
  24 # Descriptive paragraph...
  25 # @end deftypevr
  26
  27 BEGIN {
  28     alias["EWOULDBLOCK"] = "EAGAIN";
  29     alias["EDEADLOCK"] = "EDEADLK";
  30
  31     print "/* This file is generated from errno.texi by errlist.awk.  */"
  32     print "";
  33     print "#include <errno.h>";
  34     print "";
  35     print "const char *const _sys_errlist[] =";
  36     print "  {";
  37     print "    [0] = N_(\"Success\"),"
  38   }
  39 $1 == "@comment" && $2 == "errno.h" { errnoh=1; next }
  40 errnoh == 1 && $1 == "@comment" \
  41   {
  42     ++errnoh;
  43     etext = $3;
  44     for (i = 4; i <= NF; ++i)
  45       etext = etext " " $i;
  46     next;
  47   }
  48 errnoh == 2 && $1 == "@deftypevr" && $2 == "Macro" && $3 == "int" \
  49   {
  50     e = $4; errnoh++; next;
  51   }
  52 errnoh == 3 && $1 == "@comment" && $2 == "errno" \
  53   {
  54     errno = $3 + 0;
  55     if (alias[e])
  56       printf "#if defined (%s) && %s != %s\n", e, e, alias[e];
  57     else
  58       printf "#ifdef %s\n", e;
  59     errnoh = 4;
  60     desc="";
  61     next;
  62   }
  63 errnoh == 4 && $1 == "@end" && $2 == "deftypevr" \
  64   {
  65     printf "/*%s */\n", desc;
  66     printf "    [%s] = N_(\"%s\"),\n", e, etext;
  67     print "#endif";
  68     errnoh = 0;
  69     next;
  70   }
  71 errnoh == 4 \
  72   {
  73     # This magic tag in C comments gets them copied into libc.pot.
  74     desc = desc "\nTRANS " $0; next
  75   }
  76 { errnoh=0 }
  77 END {
  78   print "  };";
  79   print "";
  80   print "const int _sys_nerr = sizeof _sys_errlist / sizeof _sys_errlist[0];";
  81   print "weak_alias (_sys_errlist, sys_errlist)";
  82   print "weak_alias (_sys_nerr, sys_nerr)";
  83   }