sysdeps/i386/fpu/s_asinhl.S

   1 /* ix87 specific implementation of arcsinh.
   2    Copyright (C) 1996, 1997, 2005 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 #include <machine/asm.h>
  22
  23 #ifdef __ELF__
  24         .section .rodata
  25 #else
  26         .text
  27 #endif
  28
  29         .align ALIGNARG(4)
  30         ASM_TYPE_DIRECTIVE(huge,@object)
  31 huge:   .tfloat 1e+4930
  32         ASM_SIZE_DIRECTIVE(huge)
  33         .align ALIGNARG(4)
  34         /* Please note that we use double value for 1.0.  This number
  35            has an exact representation and so we don't get accuracy
  36            problems.  The advantage is that the code is simpler.  */
  37         ASM_TYPE_DIRECTIVE(one,@object)
  38 one:    .double 1.0
  39         ASM_SIZE_DIRECTIVE(one)
  40         /* It is not important that this constant is precise.  It is only
  41            a value which is known to be on the safe side for using the
  42            fyl2xp1 instruction.  */
  43         ASM_TYPE_DIRECTIVE(limit,@object)
  44 limit:  .double 0.29
  45         ASM_SIZE_DIRECTIVE(limit)
  46
  47 #ifdef PIC
  48 #define MO(op) op##@GOTOFF(%edx)
  49 #else
  50 #define MO(op) op
  51 #endif
  52
  53         .text
  54 ENTRY(__asinhl)
  55         movl    12(%esp), %ecx
  56         movl    $0x7fff, %eax
  57         andl    %ecx, %eax
  58         andl    $0x8000, %ecx
  59         movl    %eax, %edx
  60         orl     $0xffff8000, %edx
  61         incl    %edx
  62         jz      7f                      // x in ±Inf or NaN
  63         xorl    %ecx, 12(%esp)
  64         fldt    4(%esp)                 // |x|
  65         cmpl    $0x3fde, %eax
  66         jb      2f                      // |x| < 2^-34
  67         fldln2                          // log(2) : |x|
  68         cmpl    $0x4020, %eax
  69         fxch                            // |x| : log(2)
  70         ja      3f                      // |x| > 2^34
  71 #ifdef  PIC
  72         LOAD_PIC_REG (dx)
  73 #endif
  74         cmpl    $0x4000, %eax
  75         ja      5f                      // |x| > 2
  76
  77         // 2^-34 <= |x| <= 2 => y = sign(x)*log1p(|x|+|x|^2/(1+sqrt(1+|x|^2)))
  78         fld     %st                     // |x| : |x| : log(2)
  79         fmul    %st(1)                  // |x|^2 : |x| : log(2)
  80         fld     %st                     // |x|^2 : |x|^2 : |x| : log(2)
  81         faddl   MO(one)                 // 1+|x|^2 : |x|^2 : |x| : log(2)
  82         fsqrt                           // sqrt(1+|x|^2) : |x|^2 : |x| : log(2)
  83         faddl   MO(one)                 // 1+sqrt(1+|x|^2) : |x|^2 : |x| : log(2)
  84         fdivrp                          // |x|^2/(1+sqrt(1+|x|^2)) : |x| : log(2)
  85         faddp                           // |x|+|x|^2/(1+sqrt(1+|x|^2)) : log(2)
  86         fcoml   MO(limit)
  87         fnstsw
  88         sahf
  89         ja      6f
  90         fyl2xp1
  91         jecxz   4f
  92         fchs
  93 4:      ret
  94
  95 7:      fldt    4(%esp)
  96         ret
  97
  98 6:      faddl   MO(one)
  99         fyl2x
 100         jecxz   4f
 101         fchs
 102 4:      ret
 103
 104         // |x| < 2^-34 => y = x (inexact iff |x| != 0.0)
 105         .align ALIGNARG(4)
 106 2:
 107 #ifdef  PIC
 108         LOAD_PIC_REG (dx)
 109 #endif
 110         jecxz   4f
 111         fchs                            // x
 112 4:      fld     %st                     // x : x
 113         fldt    MO(huge)                // huge : x : x
 114         faddp                           // huge+x : x
 115         fstp    %st(0)                  // x
 116         ret
 117
 118         // |x| > 2^34 => y = sign(x) * (log(|x|) + log(2))
 119         .align ALIGNARG(4)
 120 3:      fyl2x                           // log(|x|)
 121         fldln2                          // log(2) : log(|x|)
 122         faddp                           // log(|x|)+log(2)
 123         jecxz   4f
 124         fchs
 125 4:      ret
 126
 127         // |x| > 2 => y = sign(x) * log(2*|x| + 1/(|x|+sqrt(x*x+1)))
 128         .align ALIGNARG(4)
 129 5:      fld     %st                     // |x| : |x| : log(2)
 130         fadd    %st, %st(1)             // |x| : 2*|x| : log(2)
 131         fld     %st                     // |x| : |x| : 2*|x| : log(2)
 132         fmul    %st(1)                  // |x|^2 : |x| : 2*|x| : log(2)
 133         faddl   MO(one)                 // 1+|x|^2 : |x| : 2*|x| : log(2)
 134         fsqrt                           // sqrt(1+|x|^2) : |x| : 2*|x| : log(2)
 135         faddp                           // |x|+sqrt(1+|x|^2) : 2*|x| : log(2)
 136         fdivrl  MO(one)                 // 1/(|x|+sqrt(1+|x|^2)) : 2*|x| : log(2)
 137         faddp                           // 2*|x|+1/(|x|+sqrt(1+|x|^2)) : log(2)
 138         fyl2x                           // log(2*|x|+1/(|x|+sqrt(1+|x|^2)))
 139         jecxz   4f
 140         fchs
 141 4:      ret
 142 END(__asinhl)
 143 weak_alias (__asinhl, asinhl)