configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.10)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37   --with-fp               if using floating-point hardware [default=yes],
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(gnu-binutils, dnl
  40   --with-gnu-binutils     if using GNU binutils (as and ld),
  41             gnu_binutils=$withval, gnu_binutils=no)
  42 AC_ARG_WITH(gnu-ld, dnl
  43   --with-gnu-ld           if using GNU ld (in the binutils package),
  44             gnu_ld=$withval, gnu_ld=no)
  45 AC_ARG_WITH(gnu-as, dnl
  46   --with-gnu-as           if using GNU as (in the binutils package),
  47             gnu_as=$withval, gnu_as=no)
  48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  49 AC_ARG_WITH(elf, dnl
  50   --with-elf              if using the ELF object format,
  51             elf=$withval, elf=no)
  52
  53 AC_ARG_ENABLE(libio, dnl
  54 [  --enable-libio          build in GNU libio instead of GNU stdio],
  55               [if test $enableval = yes; then
  56                  stdio=libio
  57                else
  58                  stdio=stdio
  59                fi],
  60               stdio=default)
  61
  62 dnl Arguments to enable or disable building the shared, profiled, and
  63 dnl -fomit-frame-pointer libraries.
  64 AC_ARG_ENABLE(shared, dnl
  65 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  66               shared=$enableval, shared=default)
  67 AC_ARG_ENABLE(profile, dnl
  68 [  --enable-profile        build profiled library [default=yes]],
  69               profile=$enableval, profile=yes)
  70 AC_ARG_ENABLE(omitfp, dnl
  71 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  72               omitfp=$enableval, omitfp=no)
  73
  74 dnl Generic infrastructure for drop-in additions to libc.
  75 AC_ARG_ENABLE(add-ons, dnl
  76 [  --enable-add-ons=DIR... configure and build named extra directories],
  77               [add_ons=`echo "$enableval" | sed 's/,/ /g'`],
  78               [add_ons=])
  79 AC_CONFIG_SUBDIRS($add_ons)
  80 add_ons_pfx=
  81 if test x"$add_ons" != x; then
  82   for f in $add_ons; do
  83     add_ons_pfx="$add_ons_pfx $f/"
  84   done
  85 fi
  86
  87 AC_CANONICAL_HOST
  88 # We keep the original values in `$config_*' and never modify them, so we
  89 # can write them unchanged into config.make.  Everything else uses
  90 # $machine, $vendor, and $os, and changes them whenever convenient.
  91 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
  92
  93 # Some configurations imply other options.
  94 case "$host_os" in
  95 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
  96   # These systems always use GNU tools.
  97   gnu_ld=yes gnu_as=yes ;;
  98 esac
  99 case "$host_os" in
 100 linux*ecoff*)
 101   ;;
 102 gnu* | linux* | sysv4* | solaris2*)
 103   # These systems (almost) always use the ELF format.
 104   elf=yes
 105   ;;
 106 esac
 107
 108 machine=$config_machine
 109 vendor=$config_vendor
 110 os=$config_os
 111
 112 dnl We need to use [ and ] for other purposes for a while now.
 113 changequote(,)dnl
 114 # Expand the configuration machine name into a subdirectory by architecture
 115 # type and particular chip.
 116 case "$machine" in
 117 a29k | am29000) base_machine=a29k machine=a29k ;;
 118 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 119 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 120 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 121 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 122 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 123 m88???)         base_machine=m88k machine=m88k/$machine ;;
 124 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 125 mips*)          base_machine=mips machine=mips/$machine ;;
 126 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 127 sparc[6789])    base_machine=sparc machine=sparc/$machine ;;
 128 supersparc)     base_machine=sparc machine=sparc/sparc8 ;;
 129 esac
 130 changequote([,])dnl
 131 AC_SUBST(base_machine)
 132
 133 # Compute the list of sysdep directories for this configuration.
 134 # This can take a while to compute.
 135 sysdep_dir=$srcdir/sysdeps
 136 AC_MSG_CHECKING(sysdep dirs)
 137 dnl We need to use [ and ] for other purposes for a while now.
 138 changequote(,)dnl
 139 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 140 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 141
 142 case "$os" in
 143 gnu*)
 144   base_os=mach/hurd ;;
 145 netbsd* | 386bsd* | freebsd* | bsdi*)
 146   base_os=unix/bsd/bsd4.4 ;;
 147 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 148   base_os=unix/bsd ;;
 149 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 150   base_os=unix/sysv ;;
 151 solaris[2-9]*)
 152   base_os=unix/sysv/sysv4 ;;
 153 none)
 154   base_os=standalone ;;
 155 *)
 156   base_os='' ;;
 157 esac
 158
 159 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 160 tail=$os
 161 ostry=$os
 162 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 163   ostry="$ostry /$o"
 164   tail=$o
 165 done
 166 o=`echo $tail | sed 's/[0-9]*$//'`
 167 if test $o != $tail; then
 168   ostry="$ostry /$o"
 169 fi
 170 # For linux-gnu, try linux-gnu, then linux.
 171 o=`echo $tail | sed 's/-.*$//'`
 172 if test $o != $tail; then
 173   ostry="$ostry /$o"
 174 fi
 175
 176 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 177 base=
 178 tail=$base_os
 179 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 180   set $b
 181   base="$base /$1"
 182   tail="$2"
 183 done
 184
 185 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 186 mach=
 187 tail=$machine
 188 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 189   set $m
 190   # Prepend the machine's FPU directory unless --without-fp.
 191   if test "$with_fp" = yes; then
 192     mach="$mach /$1/fpu"
 193   fi
 194   mach="$mach /$1"
 195   tail="$2"
 196 done
 197
 198 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 199 changequote([,])dnl
 200
 201 # Find what sysdep directories exist.
 202 sysnames=
 203 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 204 for d in $add_ons_pfx ''; do
 205   for b in $base ''; do
 206     for m0 in $mach ''; do
 207       for v in /$vendor ''; do
 208         for o in /$ostry ''; do
 209           for m in $mach ''; do
 210             if test "$m0$b$v$o$m"; then
 211               try="${d}sysdeps$m0$b$v$o$m"
 212               test -n "$enable_debug_configure" &&
 213               echo "$0 [DEBUG]: try $try" >&2
 214               case $try in
 215                 /*) dest=$try ;;
 216                 *)  dest=$srcdir/$try ;;
 217               esac
 218               if test -d $dest; then
 219                 sysnames="$sysnames $try"
 220                 { test -n "$o" || test -n "$b"; } && os_used=t
 221                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 222               fi
 223             fi
 224           done
 225         done
 226       done
 227     done
 228   done
 229 done
 230 IFS="$ac_save_ifs"
 231
 232 if test -z "$os_used" && test "$os" != none; then
 233   AC_MSG_ERROR(Operating system $os is not supported.)
 234 fi
 235 if test -z "$machine_used" && test "$machine" != none; then
 236   AC_MSG_ERROR(The $machine is not supported.)
 237 fi
 238
 239 # We have now validated the configuration.
 240
 241
 242 # If using ELF, look for an `elf' subdirectory of each machine directory.
 243 # We prepend these rather than inserting them whereever the machine appears
 244 # because things specified by the machine's ELF ABI should override
 245 # OS-specific things, and should always be the same for any OS on the
 246 # machine (otherwise what's the point of an ABI?).
 247 if test "$elf" = yes; then
 248   elf_dirs=
 249   for d in $add_ons_pfx ''; do
 250     case $d in
 251       /*) xsrcdir= ;;
 252       *)  xsrcdir=$srcdir/ ;;
 253     esac
 254     for m in $mach; do
 255       if test -d $xsrcdir${d}sysdeps$m/elf; then
 256         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 257       fi
 258     done
 259   done
 260   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 261 fi
 262
 263
 264 # Expand the list of system names into a full list of directories
 265 # from each element's parent name and Implies file (if present).
 266 set $sysnames
 267 names=
 268 while test $# -gt 0; do
 269   name=$1
 270   shift
 271
 272   case " $names " in *" $name "*)
 273     # Already in the list.
 274     continue
 275   esac
 276
 277   # Report each name as we discover it, so there is no long pause in output.
 278   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 279
 280   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 281
 282   case $name in
 283     /*) xsrcdir= ;;
 284     *)  xsrcdir=$srcdir/ ;;
 285   esac
 286   test -n "$enable_debug_configure" &&
 287   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 288
 289   if test -f $xsrcdir$name/Implies; then
 290     # Collect more names from the `Implies' file (removing comments).
 291     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 292     implied=
 293     for x in $implied_candidate; do
 294       if test -d $xsrcdir$name_base/$x; then
 295         implied="$implied $name_base/$x";
 296       else
 297         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 298       fi
 299     done
 300   else
 301     implied=
 302   fi
 303
 304   # Add NAME to the list of names.
 305   names="$names $name"
 306
 307   # Find the parent of NAME, using the empty string if it has none.
 308 changequote(,)dnl
 309   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 310 changequote([,])dnl
 311
 312   # Add the names implied by NAME, and NAME's parent (if it has one), to
 313   # the list of names to be processed (the argument list).  We prepend the
 314   # implied names to the list and append the parent.  We want implied
 315   # directories to come before further directories inferred from the
 316   # configuration components; this ensures that for sysv4, unix/common
 317   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 318   # after sysv4).
 319   sysnames="`echo $implied $* $parent`"
 320   test -n "$sysnames" && set $sysnames
 321 done
 322
 323 # Add the default directories.
 324 sysnames="$names sysdeps/generic sysdeps/stub"
 325 AC_SUBST(sysnames)
 326 # The other names were emitted during the scan.
 327 AC_MSG_RESULT(sysdeps/generic sysdeps/stub)
 328
 329
 330 ### Locate tools.
 331
 332 AC_PROG_INSTALL
 333 if test "$INSTALL" = "${srcdir}/install-sh"; then
 334   # The makefiles need to use a different form to find it in $srcdir.
 335   INSTALL='$(..)./install-sh'
 336 fi
 337 AC_PROG_LN_S
 338 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 339
 340 AC_CHECK_TOOL(CC, gcc)
 341 if test $host != $build; then
 342   AC_CHECK_PROG(BUILD_CC, gcc cc)
 343 fi
 344 AC_PROG_CPP
 345 AC_CHECK_TOOL(AR, ar)
 346 AC_CHECK_TOOL(RANLIB, ranlib, :)
 347
 348 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 349 echo '#include <stddef.h>
 350 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 351 if eval "$ac_cpp conftest.c 2>/dev/null" \
 352 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 353   libc_cv_signed_size_t=no
 354 else
 355   libc_cv_signed_size_t=yes
 356 fi
 357 rm -f conftest*])
 358 if test $libc_cv_signed_size_t = yes; then
 359   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 360   cat >> confdefs.h <<\EOF
 361 #undef __SIZE_TYPE__
 362 #define __SIZE_TYPE__ unsigned
 363 EOF
 364 fi
 365
 366 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 367 AC_TRY_COMPILE(dnl
 368 [#define __need_size_t
 369 #define __need_wchar_t
 370 #include <stddef.h>
 371 #define __need_NULL
 372 #include <stddef.h>], [size_t size; wchar_t wchar;
 373 #ifdef offsetof
 374 #error stddef.h ignored __need_*
 375 #endif
 376 if (&size == NULL || &wchar == NULL) abort ();],
 377                libc_cv_friendly_stddef=yes,
 378                libc_cv_friendly_stddef=no)])
 379 if test $libc_cv_friendly_stddef = yes; then
 380   config_vars="$config_vars
 381 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 382 fi
 383
 384 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 385                libc_cv_need_minus_P, [dnl
 386 cat > conftest.S <<EOF
 387 #include "confdefs.h"
 388 /* Nothing whatsoever.  */
 389 EOF
 390 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 391   libc_cv_need_minus_P=no
 392 else
 393   libc_cv_need_minus_P=yes
 394 fi
 395 rm -f conftest*])
 396 if test $libc_cv_need_minus_P = yes; then
 397   config_vars="$config_vars
 398 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 399 fi
 400
 401 AC_CACHE_CHECK(for assembler global-symbol directive,
 402                libc_cv_asm_global_directive, [dnl
 403 libc_cv_asm_global_directive=UNKNOWN
 404 for ac_globl in .globl .global; do
 405   cat > conftest.s <<EOF
 406 .text
 407 ${ac_globl} foo
 408 foo: .long 0
 409 EOF
 410   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 411     libc_cv_asm_global_directive=${ac_globl}
 412   fi
 413   rm -f conftest*
 414   test $libc_cv_asm_global_directive != UNKNOWN && break
 415 done])
 416 if test $libc_cv_asm_global_directive = UNKNOWN; then
 417   AC_MSG_ERROR(cannot determine asm global directive)
 418 else
 419   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 420 fi
 421
 422 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 423 cat > conftest.s <<EOF
 424 .text
 425 foo: .long 0
 426 .set glibc_conftest_frobozz,foo
 427 $libc_cv_asm_global_directive glibc_conftest_frobozz
 428 EOF
 429 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 430 # (but it doesn't work), so we must do a linking check to be sure.
 431 cat > conftest1.c <<\EOF
 432 extern int glibc_conftest_frobozz;
 433 main () { printf ("%d\n", glibc_conftest_frobozz); }
 434 EOF
 435 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 436             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 437   libc_cv_asm_set_directive=yes
 438 else
 439   libc_cv_asm_set_directive=no
 440 fi
 441 rm -f conftest*])
 442 if test $libc_cv_asm_set_directive = yes; then
 443   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 444 fi
 445
 446 if test $elf != yes; then
 447   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 448                  [AC_TRY_COMPILE(, [asm (".section .init");
 449                                     asm (".section .fini");
 450                                     asm (".text");],
 451                                  libc_cv_have_initfini=yes,
 452                                  libc_cv_have_initfini=no)])
 453   AC_SUBST(libc_cv_have_initfini)dnl
 454   if test $libc_cv_have_initfini = yes; then
 455     AC_DEFINE(HAVE_INITFINI)
 456   fi
 457 fi
 458
 459 if test $elf = yes; then
 460   libc_cv_asm_underscores=no
 461 else
 462   AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 463                  [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 464                               libc_cv_asm_underscores=yes,
 465                               libc_cv_asm_underscores=no)])
 466 fi
 467 if test $libc_cv_asm_underscores = no; then
 468   AC_DEFINE(NO_UNDERSCORES)
 469 fi
 470
 471 if test $elf = yes; then
 472   libc_cv_weak_symbols=yes
 473   libc_cv_asm_weak_directive=yes
 474   libc_cv_asm_weakext_directive=no
 475 else
 476   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 477                  [dnl
 478 cat > conftest.s <<EOF
 479 .text
 480 ${libc_cv_asm_global_directive} foo
 481 foo: .long 0
 482 .weak foo
 483 .weak bar; bar = foo
 484 EOF
 485   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 486     libc_cv_asm_weak_directive=yes
 487   else
 488     libc_cv_asm_weak_directive=no
 489   fi
 490   rm -f conftest*])
 491
 492 if test $libc_cv_asm_weak_directive = no; then
 493   AC_CACHE_CHECK(for assembler .weakext directive,
 494                  libc_cv_asm_weakext_directive,
 495                  [dnl
 496 cat > conftest.s <<EOF
 497 .text
 498 ${libc_cv_asm_global_directive} foo
 499 foo: .long 0
 500 .weakext foo
 501 .weakext foo, bar
 502 EOF
 503   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 504     libc_cv_asm_weakext_directive=yes
 505   else
 506     libc_cv_asm_weakext_directive=no
 507   fi
 508   rm -f conftest*])
 509
 510   fi # no .weak
 511 fi # not ELF
 512
 513 if test $libc_cv_asm_weak_directive = yes; then
 514   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 515 elif test $libc_cv_asm_weakext_directive = yes; then
 516   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 517 fi
 518
 519 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 520 cat > conftest.c <<\EOF
 521 _start () {}
 522 int __eh_pc;
 523 __throw () {}
 524 EOF
 525 dnl No \ in command here because it ends up inside ''.
 526 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 527                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 528                             -o conftest conftest.c]); then
 529   libc_cv_ld_no_whole_archive=yes
 530 else
 531   libc_cv_ld_no_whole_archive=no
 532 fi
 533 rm -f conftest*])
 534 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 535
 536 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
 537 cat > conftest.c <<\EOF
 538 _start () {}
 539 int __eh_pc;
 540 __throw () {}
 541 EOF
 542 dnl No \ in command here because it ends up inside ''.
 543 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 544                             -nostdlib -nostartfiles -fno-exceptions
 545                             -o conftest conftest.c]); then
 546   libc_cv_gcc_no_exceptions=yes
 547 else
 548   libc_cv_gcc_no_exceptions=no
 549 fi
 550 rm -f conftest*])
 551 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
 552
 553 ### End of automated tests.
 554 ### Now run sysdeps configure fragments.
 555
 556 # sysdeps configure fragments may set these with files to be linked below.
 557 libc_link_dests=
 558 libc_link_sources=
 559
 560 # Iterate over all the sysdep directories we will use, running their
 561 # configure fragments, and looking for a uname implementation.
 562 uname=
 563 for dir in $sysnames; do
 564   case $dir in
 565     /*) dest=$dir ;;
 566     *)  dest=$srcdir/$dir ;;
 567   esac
 568   if test -r $dest/configure; then
 569     AC_MSG_RESULT(running configure fragment for $dest)
 570     . $dest/configure
 571   fi
 572 [
 573   if test -z "$uname"; then
 574     if test -r $sysdep_dir/$dir/uname.c ||
 575        test -r $sysdep_dir/$dir/uname.S ||
 576        { test -r $sysdep_dir/$dir/syscalls.list &&
 577          grep '^uname[  ]' $sysdep_dir/$dir/syscalls.list >/dev/null; }; then
 578       uname=$dir
 579     fi
 580   fi
 581 ]dnl
 582 done
 583
 584 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 585
 586 # If we will use the generic uname implementation, we must figure out what
 587 # it will say by examining the system, and write the results in config-name.h.
 588 if test "$uname" = generic; then
 589
 590 changequote(,)dnl
 591   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 592 changequote([,])dnl
 593   if test $uname_sysname != $config_os; then
 594     config_release=`echo $config_os | sed s/$uname_sysname//`
 595   fi
 596 dnl
 597 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 598     if test -r /vmunix; then
 599       kernel_id=`strings /vmunix | grep UNIX`
 600     elif test -r /dynix; then
 601       kernel_id=`strings /dynix | grep DYNIX`
 602     else
 603       kernel_id=
 604     fi
 605 ])dnl
 606
 607   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 608 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 609 changequote(,)dnl
 610   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 611 changequote([,])dnl
 612   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 613          != x$config_release; then
 614     # The configuration release is a substring of the kernel release.
 615     libc_cv_uname_release=$kernel_release
 616   elif test x$config_release != x; then
 617     libc_cv_uname_release=$config_release
 618   elif test x$kernel_release != x; then
 619     libc_cv_uname_release=$kernel_release
 620   else
 621     libc_cv_uname_release=unknown
 622   fi])
 623   uname_release="$libc_cv_uname_release"
 624
 625   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 626 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 627 changequote(,)dnl
 628   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 629 changequote([,])dnl
 630   if test -n "$kernel_version"; then
 631     libc_cv_uname_version="$kernel_version"
 632   else
 633     libc_cv_uname_version=unknown
 634   fi])
 635   uname_version="$libc_cv_uname_version"
 636
 637 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 638   config_uname=config-name.h:config-name.in
 639 else
 640   # For non-generic uname, we don't need to create config-name.h at all.
 641   config_uname=
 642 fi
 643
 644 AC_MSG_CHECKING(stdio selection)
 645 AC_SUBST(stdio)
 646 case $stdio in
 647 libio) AC_DEFINE(USE_IN_LIBIO) ;;
 648 default) stdio=stdio ;;
 649 esac
 650 AC_MSG_RESULT($stdio)
 651
 652 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
 653 if test $gnu_ld = yes; then
 654   AC_DEFINE(HAVE_GNU_LD)
 655 fi
 656 if test $gnu_as = yes; then
 657   AC_DEFINE(HAVE_GNU_AS)
 658 fi
 659 if test $elf = yes; then
 660   AC_DEFINE(HAVE_ELF)
 661 fi
 662
 663 AC_SUBST(shared)
 664 if test $shared = default; then
 665   if test $gnu_ld = yes; then
 666     shared=$elf
 667   fi
 668 fi
 669 AC_SUBST(profile)
 670 AC_SUBST(omitfp)
 671
 672 AC_SUBST(DEFINES)
 673
 674 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 675   config_makefile=
 676 else
 677   config_makefile=Makefile
 678 fi
 679
 680 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
 681           [echo '$config_vars' >> config.make])