sysdeps/i386/setjmp.S

   1 /* setjmp for i386.
   2    Copyright (C) 1995-2023 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <https://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <pointer_guard.h>
  21 #include <jmpbuf-offsets.h>
  22 #include <jmp_buf-ssp.h>
  23 #include <asm-syntax.h>
  24 #include <stap-probe.h>
  25
  26 #define PARMS   4               /* no space for saved regs */
  27 #define JMPBUF  PARMS
  28 #define SIGMSK  JMPBUF+4
  29
  30 /* Don't save shadow stack register if shadow stack isn't enabled.  */
  31 #if !SHSTK_ENABLED
  32 # undef SHADOW_STACK_POINTER_OFFSET
  33 #endif
  34
  35 ENTRY (__sigsetjmp)
  36
  37         movl JMPBUF(%esp), %eax
  38
  39         /* Save registers.  */
  40         movl %ebx, (JB_BX*4)(%eax)
  41         movl %esi, (JB_SI*4)(%eax)
  42         movl %edi, (JB_DI*4)(%eax)
  43         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
  44 #ifdef PTR_MANGLE
  45         PTR_MANGLE (%ecx)
  46 #endif
  47         movl %ecx, (JB_SP*4)(%eax)
  48         movl 0(%esp), %ecx      /* Save PC we are returning to now.  */
  49         LIBC_PROBE (setjmp, 3, 4@%eax, -4@SIGMSK(%esp), 4@%ecx)
  50 #ifdef PTR_MANGLE
  51         PTR_MANGLE (%ecx)
  52 #endif
  53         movl %ecx, (JB_PC*4)(%eax)
  54         movl %ebp, (JB_BP*4)(%eax) /* Save caller's frame pointer.  */
  55
  56 #ifdef SHADOW_STACK_POINTER_OFFSET
  57 # if IS_IN (libc) && defined SHARED && defined FEATURE_1_OFFSET
  58         /* Check if Shadow Stack is enabled.  */
  59         testl $X86_FEATURE_1_SHSTK, %gs:FEATURE_1_OFFSET
  60         jz L(skip_ssp)
  61 # else
  62         xorl %ecx, %ecx
  63 # endif
  64         /* Get the current Shadow-Stack-Pointer and save it.  */
  65         rdsspd %ecx
  66         movl %ecx, SHADOW_STACK_POINTER_OFFSET(%eax)
  67 # if IS_IN (libc) && defined SHARED && defined FEATURE_1_OFFSET
  68 L(skip_ssp):
  69 # endif
  70 #endif
  71 #if IS_IN (rtld)
  72         /* In ld.so we never save the signal mask.  */
  73         xorl %eax, %eax
  74         ret
  75 #else
  76         /* Make a tail call to __sigjmp_save; it takes the same args.  */
  77         jmp __sigjmp_save
  78 #endif
  79 END (__sigsetjmp)
  80 hidden_def (__sigsetjmp)