sysdeps/csky/preconfigure.ac

   1 GLIBC_PROVIDES[]dnl See aclocal.m4 in the top level source directory.
   2 # Local preconfigure fragment for sysdeps/csky
   3
   4 case "$machine" in
   5 csky*)
   6     abi=`$CC $CFLAGS $CPPFLAGS -E -dM -xc /dev/null |
   7       sed -n 's/^#define __CSKYABI__ \(.*\)/\1/p'`
   8     soft_float=`$CC $CFLAGS $CPPFLAGS -E -dM -xc /dev/null |
   9       sed -n 's/^#define __CSKY_SOFT_FLOAT__ \(.*\)/\1/p'`
  10     hard_float_abi=`$CC $CFLAGS $CPPFLAGS -E -dM -xc /dev/null |
  11       sed -n 's/^#define __CSKY_HARD_FLOAT_ABI__ \(.*\)/\1/p'`
  12
  13     case "$abi" in
  14     1)
  15         AC_MSG_ERROR([glibc does not support abiv1 yet], [1])
  16         ;;
  17     2)
  18         machine=abiv2
  19         ;;
  20     *)
  21         AC_MSG_ERROR([Unknown abi], [1])
  22         ;;
  23     esac
  24
  25     # This check is for compatibility with GCC versions earlier than 11.
  26     # The older versions of C-SKY GCC do not support the '-mfloat-abi=softfp' option
  27     # and never define the '__CSKY_HARD_FLOAT_ABI__'.
  28     # Therefore, if a check for '-mfloat-abi=softfp' is added as the expression
  29     #     'defined(__CSKY_HARD_FLOAT__) && !defined(__CSKY_HARD_FLOAT_ABI__)'
  30     # which is correct for newer versions of GCC will not work for those older versions.
  31     # Since no expression compatible with all versions of GCC exists,
  32     # a check for the '-mfloat-abi=softfp' option is added.
  33     if AC_TRY_COMMAND(${CC-cc} -S -mfloat-abi=softfp /dev/null 1>&AS_MESSAGE_LOG_FD); then
  34       soft_float_abi_support=1
  35     else
  36       soft_float_abi_support=0
  37     fi
  38
  39     if test -n "$soft_float"; then
  40         with_fp_cond=0
  41         with_hard_float_abi=0
  42     else
  43         with_fp_cond=1
  44         if test -n "$soft_float_abi_support"; then
  45             if test -n "$hard_float_abi"; then
  46                 with_hard_float_abi=1
  47             else
  48                 with_hard_float_abi=0
  49             fi
  50         else
  51             with_hard_float_abi=1
  52         fi
  53     fi
  54
  55     base_machine=csky
  56     machine=csky/$machine
  57
  58     AC_DEFINE_UNQUOTED([CSKYABI], [$abi])
  59     AC_DEFINE_UNQUOTED([CSKY_HARD_FLOAT], [$with_fp_cond])
  60     AC_DEFINE_UNQUOTED([CSKY_HARD_FLOAT_ABI], [$with_hard_float_abi])
  61     ;;
  62 esac