sysdeps/alpha/strncat.S

   1 /* Copyright (C) 1996-2018 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Richard Henderson <rth@tamu.edu>, 1996.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* Append no more than COUNT characters from the null-terminated string SRC
  20    to the null-terminated string DST.  Always null-terminate the new DST.  */
  21
  22 #include <sysdep.h>
  23
  24         .text
  25
  26 ENTRY(strncat)
  27         ldgp    gp, 0(pv)
  28 #ifdef PROF
  29         .set noat
  30         lda     AT, _mcount
  31         jsr     AT, (AT), _mcount
  32         .set at
  33 #endif
  34         .prologue 1
  35
  36         mov     a0, v0          # set up return value
  37         beq     a2, $zerocount
  38
  39         /* Find the end of the string.  */
  40
  41         ldq_u   t0, 0(a0)       # load first quadword (a0 may be misaligned)
  42         lda     t1, -1(zero)
  43         insqh   t1, a0, t1
  44         andnot  a0, 7, a0
  45         or      t1, t0, t0
  46         cmpbge  zero, t0, t1    # t1 <- bitmask: bit i == 1 <==> i-th byte == 0
  47         bne     t1, $found
  48
  49 $loop:  ldq     t0, 8(a0)
  50         addq    a0, 8, a0       # addr += 8
  51         cmpbge  zero, t0, t1
  52         beq     t1, $loop
  53
  54 $found: negq    t1, t2          # clear all but least set bit
  55         and     t1, t2, t1
  56
  57         and     t1, 0xf0, t2    # binary search for that set bit
  58         and     t1, 0xcc, t3
  59         and     t1, 0xaa, t4
  60         cmovne  t2, 4, t2
  61         cmovne  t3, 2, t3
  62         cmovne  t4, 1, t4
  63         addq    t2, t3, t2
  64         addq    a0, t4, a0
  65         addq    a0, t2, a0
  66
  67         /* Now do the append.  */
  68
  69         jsr     t9, __stxncpy
  70
  71         /* Worry about the null termination.  */
  72
  73         zapnot  t0, t8, t1      # was last byte a null?
  74         bne     t1, 0f
  75         ret
  76
  77 0:      and     t10, 0x80, t1
  78         bne     t1, 1f
  79
  80         /* Here there are bytes left in the current word.  Clear one.  */
  81         addq    t10, t10, t10   # end-of-count bit <<= 1
  82         zap     t0, t10, t0
  83         stq_u   t0, 0(a0)
  84         ret
  85
  86 1:      /* Here we must read the next DST word and clear the first byte.  */
  87         ldq_u   t0, 8(a0)
  88         zap     t0, 1, t0
  89         stq_u   t0, 8(a0)
  90
  91 $zerocount:
  92         ret
  93
  94         END(strncat)