sysdeps/powerpc/powerpc64/power7/fpu/s_isinf.S

   1 /* isinf().  PowerPC64/POWER7 version.
   2    Copyright (C) 2010 Free Software Foundation, Inc.
   3    Contributed by Luis Machado <luisgpm@br.ibm.com>.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 #include <sysdep.h>
  22 #include <math_ldbl_opt.h>
  23
  24 /* int __isinf(x)  */
  25         .section    ".toc","aw"
  26 .LC0:   /* 1.0 */
  27         .tc         FD_ONE[TC],0x3ff0000000000000
  28         .section    ".text"
  29         .type       __isinf, @function
  30         .machine    power7
  31 EALIGN (__isinf, 4, 0)
  32         CALL_MCOUNT 0
  33         lfd     fp0,.LC0@toc(r2)
  34         ftdiv   cr7,fp1,fp0
  35         li      r3,0
  36         bflr    29            /* If not INF, return.  */
  37
  38         /* Either we have -INF/+INF or a denormal.  */
  39
  40         stfd    fp1,-16(r1)   /* Transfer FP to GPR's.  */
  41         ori     2,2,0         /* Force a new dispatch group.  */
  42         lhz     r4,-16(r1)    /* Fetch the upper portion of the high word of
  43                               the FP value (where the exponent and sign bits
  44                               are).  */
  45         cmpwi   cr7,r4,0x7ff0 /* r4 == 0x7ff0?  */
  46         li      r3,1
  47         beqlr   cr7           /* EQ means INF, otherwise -INF.  */
  48         li      r3,-1
  49         blr
  50         END (__isinf)
  51
  52 hidden_def (__isinf)
  53 weak_alias (__isinf, isinf)
  54
  55 /* It turns out that the 'double' version will also always work for
  56    single-precision.  */
  57 strong_alias (__isinf, __isinff)
  58 hidden_def (__isinff)
  59 weak_alias (__isinff, isinff)
  60
  61 #ifdef NO_LONG_DOUBLE
  62 strong_alias (__isinf, __isinfl)
  63 weak_alias (__isinf, isinfl)
  64 #endif
  65
  66 #ifndef IS_IN_libm
  67 # if LONG_DOUBLE_COMPAT(libc, GLIBC_2_0)
  68 compat_symbol (libc, __isinf, __isinfl, GLIBC_2_0);
  69 compat_symbol (libc, isinf, isinfl, GLIBC_2_0);
  70 # endif
  71 #endif
  72