sysdeps/powerpc/powerpc64/power7/fpu/s_finite.S

   1 /* finite().  PowerPC64/POWER7 version.
   2    Copyright (C) 2010 Free Software Foundation, Inc.
   3    Contributed by Luis Machado <luisgpm@br.ibm.com>.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 #include <sysdep.h>
  22 #include <math_ldbl_opt.h>
  23
  24 /* int __finite(x)  */
  25         .section    ".toc","aw"
  26 .LC0:   /* 1.0 */
  27         .tc         FD_ONE[TC],0x3ff0000000000000
  28         .section    ".text"
  29         .type       __finite, @function
  30         .machine    power7
  31 EALIGN (__finite, 4, 0)
  32         CALL_MCOUNT 0
  33         lfd     fp0,.LC0@toc(r2)
  34         ftdiv   cr7,fp1,fp0
  35         li      r3,1
  36         bflr    30
  37
  38         /* If we are here, we either have +/-INF,
  39         NaN or denormal.  */
  40
  41         stfd    fp1,-16(r1)   /* Transfer FP to GPR's.  */
  42         ori     2,2,0         /* Force a new dispatch group.  */
  43
  44         lhz     r4,-16(r1)    /* Fetch the upper portion of the high word of
  45                               the FP value (where the exponent and sign bits
  46                               are).  */
  47         clrlwi  r4,r4,17      /* r4 = abs(r4).  */
  48         cmpwi   cr7,r4,0x7ff0 /* r4 == 0x7ff0?  */
  49         bltlr   cr7           /* LT means finite, other non-finite.  */
  50         li      r3,0
  51         blr
  52         END (__finite)
  53
  54 hidden_def (__finite)
  55 weak_alias (__finite, finite)
  56
  57 /* It turns out that the 'double' version will also always work for
  58    single-precision.  */
  59 strong_alias (__finite, __finitef)
  60 hidden_def (__finitef)
  61 weak_alias (__finitef, finitef)
  62
  63 #ifndef IS_IN_libm
  64 # if LONG_DOUBLE_COMPAT(libc, GLIBC_2_0)
  65 compat_symbol (libc, __finite, __finitel, GLIBC_2_0);
  66 compat_symbol (libc, finite, finitel, GLIBC_2_0);
  67 # endif
  68 #endif
  69