| blob | 1cc5bef40637c9a50ca3e8a4b624ee907a59b214 |
1 .file "exp10.s"
4 // Copyright (c) 2000 - 2003, Intel Corporation
5 // All rights reserved.
6 //
7 // Contributed 2000 by the Intel Numerics Group, Intel Corporation
8 //
9 // Redistribution and use in source and binary forms, with or without
10 // modification, are permitted provided that the following conditions are
11 // met:
12 //
13 // * Redistributions of source code must retain the above copyright
14 // notice, this list of conditions and the following disclaimer.
15 //
16 // * Redistributions in binary form must reproduce the above copyright
17 // notice, this list of conditions and the following disclaimer in the
18 // documentation and/or other materials provided with the distribution.
19 //
20 // * The name of Intel Corporation may not be used to endorse or promote
21 // products derived from this software without specific prior written
22 // permission.
24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
35 //
36 // Intel Corporation is the author of this code, and requests that all
37 // problem reports or change requests be submitted to it directly at
38 // http: //www.intel.com/software/products/opensource/libraries/num.htm.
39 //
40 // History
41 //==============================================================
42 // 08/25/00 Initial version
43 // 05/20/02 Cleaned up namespace and sf0 syntax
44 // 09/06/02 Improved performance; no inexact flags on exact cases
45 // 01/29/03 Added missing } to bundle templates
46 //
47 // API
48 //==============================================================
49 // double exp10(double)
50 //
51 // Overview of operation
52 //==============================================================
53 // Background
54 //
55 // Implementation
56 //
57 // Let x= (K + fh + fl + r)/log2(10), where
58 // K is an integer, fh= 0.b1 b2 b3 b4 b5,
59 // fl= 2^{-5}* 0.b6 b7 b8 b8 b10 (fh, fl >= 0),
60 // and |r|<2^{-11}
61 // Th is a table that stores 2^fh (32 entries) rounded to
62 // double extended precision (only mantissa is stored)
63 // Tl is a table that stores 2^fl (32 entries) rounded to
64 // double extended precision (only mantissa is stored)
65 //
66 // 10^x is approximated as
67 // 2^K * Th [ f ] * Tl [ f ] * (1+c1*e+c1*r+c2*r^2+c3*r^3+c4*r^4),
68 // where e= (x*log2(10)_hi-RN(x*log2(10)_hi))+log2(10)_lo*x
70 // Note there are only 22 non-zero values that produce an exact result:
71 // 1.0, 2.0, ... 22.0.
72 // We test for these cases and use s1 to avoid setting the inexact flag.
74 // Special values
75 //==============================================================
76 // exp10(0)= 1
77 // exp10(+inf)= inf
78 // exp10(-inf)= 0
79 //
81 // Registers used
82 //==============================================================
83 // r2-r3, r14-r40
84 // f6-f15, f32-f51
85 // p6-p9, p12
86 //
89 GR_TBL_START = r2
90 GR_LOG_TBL = r3
92 GR_OF_LIMIT = r14
93 GR_UF_LIMIT = r15
94 GR_EXP_CORR = r16
95 GR_F_low = r17
96 GR_F_high = r18
97 GR_K = r19
98 GR_Flow_ADDR = r20
100 GR_BIAS = r21
101 GR_Fh = r22
102 GR_Fh_ADDR = r23
103 GR_EXPMAX = r24
104 GR_BIAS53 = r25
106 GR_ROUNDVAL = r26
107 GR_MASK = r27
108 GR_KF0 = r28
109 GR_MASK_low = r29
110 GR_COEFF_START = r30
111 GR_exact_limit = r31
113 GR_SAVE_B0 = r33
114 GR_SAVE_PFS = r34
115 GR_SAVE_GP = r35
116 GR_SAVE_SP = r36
118 GR_Parameter_X = r37
119 GR_Parameter_Y = r38
120 GR_Parameter_RESULT = r39
121 GR_Parameter_TAG = r40
124 FR_X = f10
125 FR_Y = f1
126 FR_RESULT = f8
129 FR_COEFF1 = f6
130 FR_COEFF2 = f7
131 FR_R = f9
132 FR_LOG2_10 = f10
134 FR_2P53 = f11
135 FR_KF0 = f12
136 FR_COEFF3 = f13
137 FR_COEFF4 = f14
138 FR_UF_LIMIT = f15
140 FR_OF_LIMIT = f32
141 FR_DX_L210 = f33
142 FR_ROUNDVAL = f34
143 FR_KF = f35
145 FR_2_TO_K = f36
146 FR_T_low = f37
147 FR_T_high = f38
148 FR_P34 = f39
149 FR_R2 = f40
151 FR_P12 = f41
152 FR_T_low_K = f42
153 FR_P14 = f43
154 FR_T = f44
155 FR_P = f45
157 FR_L2_10_low = f46
158 FR_L2_10_high = f47
159 FR_E0 = f48
160 FR_E = f49
161 FR_exact_limit = f50
163 FR_int_x = f51
166 // Data tables
167 //==============================================================
169 RODATA
171 .align 16
173 LOCAL_OBJECT_START(poly_coeffs)
175 data8 0xd49a784bcd1b8afe, 0x00003fcb // log2(10)*2^(10-63)
176 data8 0x9257edfe9b5fb698, 0x3fbf // log2(10)_low (bits 64...127)
177 data8 0x3fac6b08d704a0c0, 0x3f83b2ab6fba4e77 // C_3 and C_4
178 data8 0xb17217f7d1cf79ab, 0x00003ffe // C_1
179 data8 0xf5fdeffc162c7541, 0x00003ffc // C_2
180 LOCAL_OBJECT_END(poly_coeffs)
183 LOCAL_OBJECT_START(T_table)
185 // 2^{0.00000 b6 b7 b8 b9 b10}
186 data8 0x8000000000000000, 0x8016302f17467628
187 data8 0x802c6436d0e04f50, 0x80429c17d77c18ed
188 data8 0x8058d7d2d5e5f6b0, 0x806f17687707a7af
189 data8 0x80855ad965e88b83, 0x809ba2264dada76a
190 data8 0x80b1ed4fd999ab6c, 0x80c83c56b50cf77f
191 data8 0x80de8f3b8b85a0af, 0x80f4e5ff089f763e
192 data8 0x810b40a1d81406d4, 0x81219f24a5baa59d
193 data8 0x813801881d886f7b, 0x814e67cceb90502c
194 data8 0x8164d1f3bc030773, 0x817b3ffd3b2f2e47
195 data8 0x8191b1ea15813bfd, 0x81a827baf7838b78
196 data8 0x81bea1708dde6055, 0x81d51f0b8557ec1c
197 data8 0x81eba08c8ad4536f, 0x820225f44b55b33b
198 data8 0x8218af4373fc25eb, 0x822f3c7ab205c89a
199 data8 0x8245cd9ab2cec048, 0x825c62a423d13f0c
200 data8 0x8272fb97b2a5894c, 0x828998760d01faf3
201 data8 0x82a0393fe0bb0ca8, 0x82b6ddf5dbc35906
202 //
203 //
204 // 2^{0.b1 b2 b3 b4 b5}
205 data8 0x8000000000000000, 0x82cd8698ac2ba1d7
206 data8 0x85aac367cc487b14, 0x88980e8092da8527
207 data8 0x8b95c1e3ea8bd6e6, 0x8ea4398b45cd53c0
208 data8 0x91c3d373ab11c336, 0x94f4efa8fef70961
209 data8 0x9837f0518db8a96f, 0x9b8d39b9d54e5538
210 data8 0x9ef5326091a111ad, 0xa27043030c496818
211 data8 0xa5fed6a9b15138ea, 0xa9a15ab4ea7c0ef8
212 data8 0xad583eea42a14ac6, 0xb123f581d2ac258f
213 data8 0xb504f333f9de6484, 0xb8fbaf4762fb9ee9
214 data8 0xbd08a39f580c36be, 0xc12c4cca66709456
215 data8 0xc5672a115506dadd, 0xc9b9bd866e2f27a2
216 data8 0xce248c151f8480e3, 0xd2a81d91f12ae45a
217 data8 0xd744fccad69d6af4, 0xdbfbb797daf23755
218 data8 0xe0ccdeec2a94e111, 0xe5b906e77c8348a8
219 data8 0xeac0c6e7dd24392e, 0xefe4b99bdcdaf5cb
220 data8 0xf5257d152486cc2c, 0xfa83b2db722a033a
221 LOCAL_OBJECT_END(T_table)
225 .section .text
226 GLOBAL_IEEE754_ENTRY(exp10)
229 {.mfi
230 alloc r32= ar.pfs, 1, 4, 4, 0
231 // will continue only for non-zero normal/denormal numbers
232 fclass.nm.unc p12, p7= f8, 0x1b
233 mov GR_BIAS53= 0xffff+63-10
234 }
235 {.mlx
236 // GR_TBL_START= pointer to log2(10), C_1...C_4 followed by T_table
237 addl GR_TBL_START= @ltoff(poly_coeffs), gp
238 movl GR_ROUNDVAL= 0x3fc00000 // 1.5 (SP)
239 }
240 ;;
242 {.mfi
243 ld8 GR_COEFF_START= [ GR_TBL_START ] // Load pointer to coeff table
244 fcmp.lt.s1 p6, p8= f8, f0 // X<0 ?
245 nop.i 0
246 }
247 ;;
249 {.mlx
250 setf.exp FR_2P53= GR_BIAS53 // 2^{63-10}
251 movl GR_UF_LIMIT= 0xc07439b746e36b52 // (-2^10-51) / log2(10)
252 }
253 {.mlx
254 setf.s FR_ROUNDVAL= GR_ROUNDVAL
255 movl GR_OF_LIMIT= 0x40734413509f79fe // Overflow threshold
256 }
257 ;;
259 {.mib
260 ldfe FR_LOG2_10= [ GR_COEFF_START ], 16 // load log2(10)*2^(10-63)
261 nop.i 0
262 (p12) br.cond.spnt SPECIAL_exp10 // Branch if nan, inf, zero
263 }
264 ;;
266 {.mmf
267 ldfe FR_L2_10_low= [ GR_COEFF_START ], 16 // load log2(10)_low
268 setf.d FR_OF_LIMIT= GR_OF_LIMIT // Set overflow limit
269 fma.s0 f8= f8, f1, f0 // normalize x
270 }
271 ;;
273 {.mfi
274 ldfpd FR_COEFF3, FR_COEFF4= [ GR_COEFF_START ], 16 // load C_3, C_4
275 (p8) fcvt.fx.s1 FR_int_x = f8 // Convert x to integer
276 nop.i 0
277 }
278 {.mfi
279 setf.d FR_UF_LIMIT= GR_UF_LIMIT // Set underflow limit
280 fma.s1 FR_KF0= f8, FR_LOG2_10, FR_ROUNDVAL // y= (x*log2(10)*2^10 +
281 // 1.5*2^63) * 2^(-63)
282 mov GR_EXP_CORR= 0xffff-126
283 }
284 ;;
286 {.mfi
287 nop.m 0
288 fma.s1 FR_L2_10_high= FR_LOG2_10, FR_2P53, f0 // FR_LOG2_10= log2(10)_hi
289 nop.i 0
290 }
291 ;;
293 {.mfi
294 ldfe FR_COEFF1= [ GR_COEFF_START ], 16 // load C_1
295 fms.s1 FR_KF= FR_KF0, f1, FR_ROUNDVAL // (K+f)*2^(10-63)
296 mov GR_MASK= 1023
297 }
298 ;;
300 {.mfi
301 ldfe FR_COEFF2= [ GR_COEFF_START ], 16 // load C_2
302 fma.s1 FR_LOG2_10= f8, FR_L2_10_high, f0 // y0= x*log2(10)_hi
303 mov GR_MASK_low= 31
304 }
305 ;;
307 {.mlx
308 getf.sig GR_KF0= FR_KF0 // (K+f)*2^10= round_to_int(y)
309 (p8) movl GR_exact_limit= 0x41b00000 // Largest x for exact result,
310 // +22.0
311 }
312 ;;
314 {.mfi
315 add GR_LOG_TBL= 256, GR_COEFF_START // Pointer to high T_table
316 fcmp.gt.s1 p12, p7= f8, FR_OF_LIMIT // x>overflow threshold ?
317 nop.i 0
318 }
319 ;;
321 {.mfi
322 (p8) setf.s FR_exact_limit = GR_exact_limit // Largest x for exact result
323 (p8) fcvt.xf FR_int_x = FR_int_x // Integral part of x
324 shr GR_K= GR_KF0, 10 // K
325 }
326 {.mfi
327 and GR_F_high= GR_MASK, GR_KF0 // f_high*32
328 fnma.s1 FR_R= FR_KF, FR_2P53, FR_LOG2_10 // r= x*log2(10)-2^{63-10}*
329 // [ (K+f)*2^{10-63} ]
330 and GR_F_low= GR_KF0, GR_MASK_low // f_low
331 }
332 ;;
334 {.mmi
335 shladd GR_Flow_ADDR= GR_F_low, 3, GR_COEFF_START // address of 2^{f_low}
336 add GR_BIAS= GR_K, GR_EXP_CORR // K= bias-2*63
337 shr GR_Fh= GR_F_high, 5 // f_high
338 }
339 ;;
341 {.mfi
342 setf.exp FR_2_TO_K= GR_BIAS // 2^{K-126}
343 (p7) fcmp.lt.s1 p12, p7= f8, FR_UF_LIMIT // x<underflow threshold ?
344 shladd GR_Fh_ADDR= GR_Fh, 3, GR_LOG_TBL // address of 2^{f_high}
345 }
346 {.mfi
347 ldf8 FR_T_low= [ GR_Flow_ADDR ] // load T_low= 2^{f_low}
348 fms.s1 FR_DX_L210= f8, FR_L2_10_high, FR_LOG2_10 // x*log2(10)_hi-
349 // RN(x*log2(10)_hi)
350 nop.i 0
351 }
352 ;;
354 {.mfi
355 ldf8 FR_T_high= [ GR_Fh_ADDR ] // load T_high= 2^{f_high}
356 fma.s1 FR_P34= FR_COEFF4, FR_R, FR_COEFF3 // P34= C_3+C_4*r
357 nop.i 0
358 }
359 {.mfb
360 nop.m 0
361 fma.s1 FR_R2= FR_R, FR_R, f0 // r*r
362 (p12) br.cond.spnt OUT_RANGE_exp10
363 }
364 ;;
366 {.mfi
367 nop.m 0
368 // e= (x*log2(10)_hi-RN(x*log2(10)_hi))+log2(10)_lo*x
369 fma.s1 FR_E0= f8, FR_L2_10_low, FR_DX_L210
370 cmp.eq p7,p9= r0,r0 // Assume inexact result
371 }
372 {.mfi
373 nop.m 0
374 fma.s1 FR_P12= FR_COEFF2, FR_R, FR_COEFF1 // P12= C_1+C_2*r
375 nop.i 0
376 }
377 ;;
379 {.mfi
380 nop.m 0
381 (p8) fcmp.eq.s1 p9,p7= FR_int_x, f8 // Test x positive integer
382 nop.i 0
383 }
384 {.mfi
385 nop.m 0
386 fma.s1 FR_T_low_K= FR_T_low, FR_2_TO_K, f0 // T= 2^{K-126}*T_low
387 nop.i 0
388 }
389 ;;
391 {.mfi
392 nop.m 0
393 fma.s1 FR_E= FR_E0, FR_COEFF1, f0 // E= C_1*e
394 nop.i 0
395 }
396 {.mfi
397 nop.m 0
398 fma.s1 FR_P14= FR_R2, FR_P34, FR_P12 // P14= P12+r2*P34
399 nop.i 0
400 }
401 ;;
403 // If x a positive integer, will it produce an exact result?
404 // p7 result will be inexact
405 // p9 result will be exact
406 {.mfi
407 nop.m 0
408 (p9) fcmp.le.s1 p9,p7= f8, FR_exact_limit // Test x gives exact result
409 nop.i 0
410 }
411 {.mfi
412 nop.m 0
413 fma.s1 FR_T= FR_T_low_K, FR_T_high, f0 // T= T*T_high
414 nop.i 0
415 }
416 ;;
418 {.mfi
419 nop.m 0
420 fma.s1 FR_P= FR_P14, FR_R, FR_E // P= P14*r+E
421 nop.i 0
422 }
423 ;;
425 .pred.rel "mutex",p7,p9
426 {.mfi
427 nop.m 0
428 (p7) fma.d.s0 f8= FR_P, FR_T, FR_T // result= T+T*P, inexact set
429 nop.i 0
430 }
431 {.mfb
432 nop.m 0
433 (p9) fma.d.s1 f8= FR_P, FR_T, FR_T // result= T+T*P, exact use s1
434 br.ret.sptk b0 // return
435 }
436 ;;
439 SPECIAL_exp10:
440 {.mfi
441 nop.m 0
442 fclass.m p6, p0= f8, 0x22 // x= -Infinity ?
443 nop.i 0
444 }
445 ;;
447 {.mfi
448 nop.m 0
449 fclass.m p7, p0= f8, 0x21 // x= +Infinity ?
450 nop.i 0
451 }
452 ;;
454 {.mfi
455 nop.m 0
456 fclass.m p8, p0= f8, 0x7 // x= +/-Zero ?
457 nop.i 0
458 }
459 {.mfb
460 nop.m 0
461 (p6) mov f8= f0 // exp10(-Infinity)= 0
462 (p6) br.ret.spnt b0
463 }
464 ;;
466 {.mfb
467 nop.m 0
468 nop.f 0
469 (p7) br.ret.spnt b0 // exp10(+Infinity)= +Infinity
470 }
471 ;;
473 {.mfb
474 nop.m 0
475 (p8) mov f8= f1 // exp10(+/-0)= 1
476 (p8) br.ret.spnt b0
477 }
478 ;;
480 {.mfb
481 nop.m 0
482 fma.d.s0 f8= f8, f1, f0 // Remaining cases: NaNs
483 br.ret.sptk b0
484 }
485 ;;
488 OUT_RANGE_exp10:
490 // overflow: p8= 1
492 {.mii
493 (p8) mov GR_EXPMAX= 0x1fffe
494 nop.i 0
495 nop.i 0
496 }
497 ;;
500 {.mmb
501 (p8) mov GR_Parameter_TAG= 166
502 (p8) setf.exp FR_R= GR_EXPMAX
503 nop.b 999
504 }
505 ;;
507 {.mfi
508 nop.m 999
509 (p8) fma.d.s0 f8= FR_R, FR_R, f0 // Create overflow
510 nop.i 999
511 }
512 // underflow: p6= 1
513 {.mii
514 nop.m 0
515 (p6) mov GR_EXPMAX= 1
516 nop.i 0
517 }
518 ;;
520 {.mmb
521 nop.m 0
522 (p6) setf.exp FR_R= GR_EXPMAX
523 nop.b 999
524 }
525 ;;
527 {.mfb
528 nop.m 999
529 (p6) fma.d.s0 f8= FR_R, FR_R, f0 // Create underflow
530 (p6) br.ret.sptk b0 // will not call libm_error for underflow
531 }
532 ;;
534 GLOBAL_IEEE754_END(exp10)
535 weak_alias (exp10, pow10)
537 LOCAL_LIBM_ENTRY(__libm_error_region)
539 .prologue
540 {.mfi
541 add GR_Parameter_Y= -32, sp // Parameter 2 value
542 nop.f 0
543 .save ar.pfs, GR_SAVE_PFS
544 mov GR_SAVE_PFS= ar.pfs // Save ar.pfs
545 }
547 {.mfi
548 .fframe 64
549 add sp= -64, sp // Create new stack
550 nop.f 0
551 mov GR_SAVE_GP= gp // Save gp
552 }
553 ;;
555 {.mmi
556 stfd [ GR_Parameter_Y ]= FR_Y, 16 // STORE Parameter 2 on stack
557 add GR_Parameter_X= 16, sp // Parameter 1 address
558 .save b0, GR_SAVE_B0
559 mov GR_SAVE_B0= b0 // Save b0
560 }
561 ;;
563 .body
564 {.mib
565 stfd [ GR_Parameter_X ]= FR_X // STORE Parameter 1 on stack
566 add GR_Parameter_RESULT= 0, GR_Parameter_Y // Parameter 3 address
567 nop.b 0
568 }
569 {.mib
570 stfd [ GR_Parameter_Y ]= FR_RESULT // STORE Parameter 3 on stack
571 add GR_Parameter_Y= -16, GR_Parameter_Y
572 br.call.sptk b0= __libm_error_support# // Call error handling function
573 }
574 ;;
576 {.mmi
577 add GR_Parameter_RESULT= 48, sp
578 nop.m 0
579 nop.i 0
580 }
581 ;;
583 {.mmi
584 ldfd f8= [ GR_Parameter_RESULT ] // Get return result off stack
585 .restore sp
586 add sp= 64, sp // Restore stack pointer
587 mov b0= GR_SAVE_B0 // Restore return address
588 }
589 ;;
591 {.mib
592 mov gp= GR_SAVE_GP // Restore gp
593 mov ar.pfs= GR_SAVE_PFS // Restore ar.pfs
594 br.ret.sptk b0 // Return
595 }
596 ;;
599 LOCAL_LIBM_END(__libm_error_region)
601 .type __libm_error_support#, @function
602 .global __libm_error_support#