sysdeps/x86_64/fpu/s_fmax.S

   1 /* Compute maximum of two numbers, regarding NaN as missing argument.
   2    Copyright (C) 2002-2016 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Andreas Jaeger <aj@suse.de>, 2002.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21
  22         .text
  23 ENTRY(__fmax)
  24         ucomisd %xmm0, %xmm1
  25         jp      1f              // jump if unordered
  26         maxsd   %xmm1, %xmm0
  27         jmp     2f
  28
  29 1:      ucomisd %xmm1, %xmm1    // Is xmm1 a NaN?
  30         jp      3f
  31         // xmm0 is a NaN; xmm1 is not.  Test if xmm0 is signaling.
  32         movsd   %xmm0, -8(%rsp)
  33         testb   $0x8, -2(%rsp)
  34         jz      4f
  35         movsd   %xmm1, %xmm0    // otherwise return xmm1
  36         ret
  37
  38 3:      // xmm1 is a NaN; xmm0 may or may not be.
  39         ucomisd %xmm0, %xmm0
  40         jp      4f
  41         // xmm1 is a NaN; xmm0 is not.  Test if xmm1 is signaling.
  42         movsd   %xmm1, -8(%rsp)
  43         testb   $0x8, -2(%rsp)
  44         jz      4f
  45         ret
  46
  47 4:      // Both arguments are NaNs, or one is a signaling NaN.
  48         addsd   %xmm1, %xmm0
  49
  50 2:      ret
  51 END(__fmax)
  52 weak_alias (__fmax, fmax)