configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.13)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  23 AC_ARG_WITH(gd, dnl
  24   --with-gd=DIR           find libgd include dir and library with prefix DIR,
  25             [dnl
  26 case "$with_gd" in
  27 yes|''|no) ;;
  28 *) libgd_include="-I$withval/include"
  29    libgd_ldflags="-L$withval/lib" ;;
  30 esac
  31 ])
  32 AC_ARG_WITH(gd-include, dnl
  33   --with-gd-include=DIR   find libgd include files in DIR,
  34             [dnl
  35 case "$with_gd_include" in
  36 ''|no) ;;
  37 *) libgd_include="-I$withval" ;;
  38 esac
  39 ])
  40 AC_ARG_WITH(gd-lib, dnl
  41   --with-gd-lib=DIR       find libgd library files in DIR,
  42             [dnl
  43 case "$with_gd_lib" in
  44 ''|no) ;;
  45 *) libgd_ldflags="-L$withval" ;;
  46 esac
  47 ])
  48
  49 if test -n "$libgd_include"; then
  50   config_vars="$config_vars
  51 CFLAGS-memusagestat.c = $libgd_include"
  52 fi
  53 if test -n "$libgd_ldflags"; then
  54   config_vars="$config_vars
  55 libgd-LDFLAGS = $libgd_ldflags"
  56 fi
  57
  58 dnl Arguments to specify presence of other packages/features.
  59 AC_ARG_WITH(fp, dnl
  60 [  --with-fp              if using floating-point hardware [default=yes]],
  61             with_fp=$withval, with_fp=yes)
  62 AC_ARG_WITH(binutils, dnl
  63   --with-binutils=PATH    specify location of binutils (as and ld),
  64             path_binutils=$withval, path_binutils='')
  65 AC_ARG_WITH(elf, dnl
  66   --with-elf              if using the ELF object format,
  67             elf=$withval, elf=no)
  68 AC_ARG_WITH(cvs, dnl
  69 [  --without-cvs           if CVS should not be used],
  70             with_cvs=$withval, with_cvs=yes)
  71 if test "$with_cvs" = yes; then
  72   if test -d $srcdir/CVS && grep :pserver: $srcdir/CVS/Root > /dev/null
  73   then
  74     with_cvs=no
  75   fi
  76 fi
  77 AC_SUBST(with_cvs)
  78
  79 AC_ARG_WITH(headers, dnl
  80 [  --with-headers=PATH     location of system headers to use
  81                           [e.g. /usr/src/linux/include]
  82                           [default=compiler default]],
  83             sysheaders=$withval, sysheaders='')
  84
  85 AC_ARG_ENABLE(libio, dnl
  86 [  --enable-libio          build in GNU libio instead of GNU stdio],
  87               [if test $enableval = yes; then
  88                  stdio=libio
  89                else
  90                  stdio=stdio
  91                fi],
  92               stdio=default)
  93
  94 AC_ARG_ENABLE(sanity-checks, dnl
  95 [  --disable-sanity-checks really do not use threads (should not be used
  96                           except in special situations) [default=yes]],
  97               enable_sanity=$enableval, enable_sanity=yes)
  98
  99 dnl Arguments to enable or disable building the static, shared, profiled,
 100 dnl and -fomit-frame-pointer libraries.
 101 dnl I've disabled this for now since we cannot build glibc without static
 102 dnl libraries built in the moment.
 103 dnl AC_ARG_ENABLE(static, dnl
 104 dnl [  --enable-static         build static library [default=yes]],
 105 dnl           static=$enableval, static=yes)
 106 static=yes
 107 AC_ARG_ENABLE(shared, dnl
 108 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
 109               shared=$enableval, shared=default)
 110 AC_ARG_ENABLE(profile, dnl
 111 [  --enable-profile        build profiled library [default=yes]],
 112               profile=$enableval, profile=yes)
 113 AC_ARG_ENABLE(omitfp, dnl
 114 [  --enable-omitfp         build undebuggable optimized library [default=no]],
 115               omitfp=$enableval, omitfp=no)
 116 AC_ARG_ENABLE(bounded, dnl
 117 [  --enable-bounded        build with runtime bounds checking [default=no]],
 118               bounded=$enableval, bounded=no)
 119 AC_ARG_ENABLE(versioning, dnl
 120 [  --disable-versioning    do not include versioning information in the
 121                           library objects [default=yes if supported]],
 122              enable_versioning=$enableval, enable_versioning=yes)
 123
 124 AC_ARG_ENABLE(oldest-abi, dnl
 125 [  --enable-oldest-abi=ABI configure the oldest ABI supported [e.g. 2.2]
 126                           [default=glibc default]],
 127             oldest_abi=$enableval, oldest_abi=no)
 128 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
 129   oldest_abi=default
 130 else
 131   AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
 132 fi
 133 AC_SUBST(oldest_abi)
 134
 135 dnl Generic infrastructure for drop-in additions to libc.
 136 AC_ARG_ENABLE(add-ons, dnl
 137 [  --enable-add-ons[=DIR1,DIR2]...
 138                           configure and build add-ons in DIR1,DIR2,...
 139                           search for add-ons if no parameter given],
 140   [case "$enableval" in
 141     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 142          test "$add_ons" = "*" && add_ons= ;;
 143     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 144    esac],
 145   [add_ons=])
 146
 147 AC_CONFIG_SUBDIRS($add_ons)
 148 add_ons_pfx=
 149 if test x"$add_ons" != x; then
 150   for f in $add_ons; do
 151     # Some sanity checks
 152     if test "$f" = "crypt"; then
 153       AC_MSG_ERROR([
 154 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 155 *** part of glibc and using the old add-on will not work with this
 156 *** release.  Start again with fresh sources and without the old
 157 *** \`crypt' add-on.])
 158     fi
 159     if test "$f" = "localedata"; then
 160       AC_MSG_ERROR([
 161 *** It seems that you're using an old \`localedata' add-on.  localedata
 162 *** is now part of glibc and using the old add-on will not work with
 163 *** this release.  Start again with fresh sources and without the old
 164 *** \`localedata' add-on.])
 165     fi
 166     # Test whether such a subdir really exists.
 167     if test -d $srcdir/$f; then
 168       add_ons_pfx="$add_ons_pfx $f/"
 169     else
 170       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 171     fi
 172   done
 173 fi
 174
 175 dnl On some platforms we cannot use dynamic loading.  We must provide
 176 dnl static NSS modules.
 177 AC_ARG_ENABLE(static-nss, dnl
 178 [  --enable-static-nss     build static NSS modules [default=no]],
 179               static_nss=$enableval, static_nss=no)
 180 if test x"$static_nss" = xyes; then
 181   AC_DEFINE(DO_STATIC_NSS)
 182 fi
 183
 184 AC_ARG_ENABLE(force-install,
 185 [  --disable-force-install don't force installation of files from this package,
 186                           even if they are older than the installed files],
 187               force_install=$enableval, force_install=yes)
 188 AC_SUBST(force_install)
 189
 190 dnl On some platforms we allow dropping compatibility with all kernel
 191 dnl versions.
 192 AC_ARG_ENABLE(kernel,
 193 [  --enable-kernel=VERSION compile for compatibility with kernel not older
 194                            than VERSION],
 195               minimum_kernel=$enableval)
 196 dnl Prevent unreasonable values.
 197 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 198   # Better nothing than this.
 199   minimum_kernel=""
 200 else
 201   if test "$minimum_kernel" = current; then
 202     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 203   fi
 204 fi
 205
 206 dnl For the development we sometimes want gcc to issue even more warnings.
 207 dnl This is not the default since many of the extra warnings are not
 208 dnl appropriate.
 209 AC_ARG_ENABLE(all-warnings,
 210 [  --enable-all-warnings   enable all useful warnings gcc can issue],
 211               all_warnings=$enableval)
 212 AC_SUBST(all_warnings)
 213
 214 AC_CANONICAL_HOST
 215
 216 # The way shlib-versions is used to generate soversions.mk uses a
 217 # fairly simplistic model for name recognition that can't distinguish
 218 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 219 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 220 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 221 case "$host_os" in
 222 linux*)
 223   ;;
 224 gnu*)
 225   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 226   ;;
 227 esac
 228
 229 # We keep the original values in `$config_*' and never modify them, so we
 230 # can write them unchanged into config.make.  Everything else uses
 231 # $machine, $vendor, and $os, and changes them whenever convenient.
 232 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 233
 234 # Don't allow vendor == "unknown"
 235 test "$config_vendor" = unknown && config_vendor=
 236 config_os="`echo $config_os | sed 's/^unknown-//'`"
 237
 238 # Some configurations imply other options.
 239 case "$host_os" in
 240 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 241   # These systems always use GNU tools.
 242   gnu_ld=yes gnu_as=yes ;;
 243 esac
 244 case "$host_os" in
 245 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 246 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 247   ;;
 248 gnu* | linux* | sysv4* | solaris2* | irix6*)
 249   # These systems (almost) always use the ELF format.
 250   elf=yes
 251   ;;
 252 esac
 253
 254 machine=$config_machine
 255 vendor=$config_vendor
 256 os=$config_os
 257
 258 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 259 # Unify this here.
 260 if test "$machine" = rs6000; then
 261   machine="powerpc"
 262 fi
 263
 264 ###
 265 ### I put this here to prevent those annoying emails from people who cannot
 266 ### read and try to compile glibc on unsupported platforms.  --drepper
 267 ###
 268 ### By using the undocumented --enable-hacker-mode option for configure
 269 ### one can skip this test to make the configuration not fail for unsupported
 270 ### platforms.
 271 ###
 272 if test -z "$enable_hacker_mode"; then
 273   case "$machine-$host_os" in
 274   *-linux* | *-gnu* | arm*-none* | powerpc-aix4.3.*)
 275     ;;
 276   *)
 277     echo "*** The GNU C library is currently not available for this platform."
 278     echo "*** So far nobody cared to port it and if there is no volunteer it"
 279     echo "*** might never happen.  So, if you have interest to see glibc on"
 280     echo "*** this platform visit"
 281     echo "***   http://www.gnu.org/software/libc/porting.html"
 282     echo "*** and join the group of porters"
 283     exit 1
 284     ;;
 285   esac
 286 fi
 287
 288 dnl We need to use [ and ] for other purposes for a while now.
 289 changequote(,)dnl
 290 # Expand the configuration machine name into a subdirectory by architecture
 291 # type and particular chip.
 292 case "$machine" in
 293 a29k | am29000) base_machine=a29k machine=a29k ;;
 294 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 295 arm*)           base_machine=arm machine=arm/arm32/$machine ;;
 296 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 297 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 298 hppa*64*)       base_machine=hppa machine=hppa/hppa64 ;;
 299 hppa*)          base_machine=hppa machine=hppa/hppa1.1 ;;
 300 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 301 ia64)           base_machine=ia64 machine=ia64 ;;
 302 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 303 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 304 m88???)         base_machine=m88k machine=m88k/$machine ;;
 305 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 306 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 307 mips*)          base_machine=mips
 308                 case "`uname -m`" in
 309                 IP22) machine=mips/mips3 ;;
 310                 *)    machine=mips/$machine ;;
 311                 esac ;;
 312 s390)           base_machine=s390 machine=s390/s390-32 ;;
 313 s390x)          base_machine=s390 machine=s390/s390-64 ;;
 314 sh3*)           base_machine=sh machine=sh/sh3 ;;
 315 sh4*)           base_machine=sh machine=sh/sh4 ;;
 316 sparc | sparcv[67])
 317                 base_machine=sparc machine=sparc/sparc32 ;;
 318 sparcv8 | supersparc | hypersparc)
 319                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 320 sparcv8plus | sparcv8plusa | sparcv9)
 321                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 322 sparcv8plusb | sparcv9b)
 323                 base_machine=sparc machine=sparc/sparc32/sparcv9b ;;
 324 sparc64 | ultrasparc)
 325                 base_machine=sparc machine=sparc/sparc64 ;;
 326 sparc64b | ultrasparc3)
 327                 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
 328 thumb*)         base_machine=thumb machine=arm/thumb/$machine ;;
 329 esac
 330 changequote([,])dnl
 331 AC_SUBST(base_machine)
 332
 333 if test "$base_machine" = "i386"; then
 334   AC_DEFINE(USE_REGPARMS)
 335 fi
 336
 337 # Compute the list of sysdep directories for this configuration.
 338 # This can take a while to compute.
 339 sysdep_dir=$srcdir/sysdeps
 340 AC_MSG_CHECKING(sysdep dirs)
 341 dnl We need to use [ and ] for other purposes for a while now.
 342 changequote(,)dnl
 343 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 344 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 345
 346 case "$os" in
 347 gnu*)
 348   base_os=mach/hurd ;;
 349 netbsd* | 386bsd* | freebsd* | bsdi*)
 350   base_os=unix/bsd/bsd4.4 ;;
 351 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 352   base_os=unix/bsd ;;
 353 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 354   base_os=unix/sysv ;;
 355 irix6*)
 356   base_os=unix/sysv/irix6/$os ;;
 357 solaris[2-9]*)
 358   base_os=unix/sysv/sysv4 ;;
 359 hpux*)
 360   base_os=unix/sysv/hpux/$os ;;
 361 aix4.3*)
 362   base_os=unix/sysv/aix/aix4.3 ;;
 363 none)
 364   base_os=standalone ;;
 365 *)
 366   base_os='' ;;
 367 esac
 368
 369 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 370 tail=$os
 371 ostry=$os
 372 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 373   ostry="$ostry /$o"
 374   tail=$o
 375 done
 376 o=`echo $tail | sed 's/[0-9]*$//'`
 377 if test $o != $tail; then
 378   ostry="$ostry /$o"
 379 fi
 380 # For linux-gnu, try linux-gnu, then linux.
 381 o=`echo $tail | sed 's/-.*$//'`
 382 if test $o != $tail; then
 383   ostry="$ostry /$o"
 384 fi
 385
 386 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 387 base=
 388 tail=$base_os
 389 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 390   set $b
 391   base="$base /$1"
 392   tail="$2"
 393 done
 394
 395 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 396 mach=
 397 tail=$machine
 398 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 399   set $m
 400   # Prepend the machine's FPU directory unless --without-fp.
 401   if test "$with_fp" = yes; then
 402     mach="$mach /$1/fpu"
 403   fi
 404   mach="$mach /$1"
 405   tail="$2"
 406 done
 407
 408 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 409 changequote([,])dnl
 410
 411 # Find what sysdep directories exist.
 412 sysnames=
 413 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 414 for d in $add_ons_pfx ''; do
 415   for b in $base ''; do
 416     for m0 in $mach ''; do
 417       for v in /$vendor ''; do
 418         test "$v" = / && continue
 419         for o in /$ostry ''; do
 420           test "$o" = / && continue
 421           for m in $mach ''; do
 422             if test "$m0$b$v$o$m"; then
 423               try="${d}sysdeps$m0$b$v$o$m"
 424               test -n "$enable_debug_configure" &&
 425               echo "$0 [DEBUG]: try $try" >&2
 426               if test -d $srcdir/$try; then
 427                 sysnames="$sysnames $try"
 428                 { test -n "$o" || test -n "$b"; } && os_used=t
 429                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 430               fi
 431             fi
 432           done
 433         done
 434       done
 435     done
 436   done
 437 done
 438 IFS="$ac_save_ifs"
 439
 440 if test -z "$os_used" && test "$os" != none; then
 441   AC_MSG_ERROR(Operating system $os is not supported.)
 442 fi
 443 if test -z "$machine_used" && test "$machine" != none; then
 444   AC_MSG_ERROR(The $machine is not supported.)
 445 fi
 446
 447 # We have now validated the configuration.
 448
 449
 450 # If using ELF, look for an `elf' subdirectory of each machine directory.
 451 # We prepend these rather than inserting them whereever the machine appears
 452 # because things specified by the machine's ELF ABI should override
 453 # OS-specific things, and should always be the same for any OS on the
 454 # machine (otherwise what's the point of an ABI?).
 455 if test "$elf" = yes; then
 456   elf_dirs=
 457   for d in $add_ons_pfx ''; do
 458     for m in $mach; do
 459       if test -d $srcdir/${d}sysdeps$m/elf; then
 460         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 461       fi
 462     done
 463   done
 464   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 465 fi
 466
 467
 468 # Expand the list of system names into a full list of directories
 469 # from each element's parent name and Implies file (if present).
 470 set $sysnames
 471 names=
 472 while test $# -gt 0; do
 473   name=$1
 474   shift
 475
 476   case " $names " in *" $name "*)
 477     # Already in the list.
 478     continue
 479   esac
 480
 481   # Report each name as we discover it, so there is no long pause in output.
 482   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 483
 484   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 485
 486   case $name in
 487     /*) xsrcdir= ;;
 488     *)  xsrcdir=$srcdir/ ;;
 489   esac
 490   test -n "$enable_debug_configure" &&
 491   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 492
 493   if test -f $xsrcdir$name/Implies; then
 494     # Collect more names from the `Implies' file (removing comments).
 495     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 496     implied=
 497     for x in $implied_candidate; do
 498       found=no
 499       if test -d $xsrcdir$name_base/$x; then
 500         implied="$implied $name_base/$x";
 501         found=yes
 502       fi
 503       for d in $add_ons_pfx ''; do
 504         try="${d}sysdeps/$x"
 505         case $d in
 506          /*) try_srcdir= ;;
 507          *) try_srcdir=$srcdir/ ;;
 508         esac
 509         test -n "$enable_debug_configure" &&
 510          echo "[DEBUG]: $name implied $x try($d) {$try_srcdir}$try" >&2
 511         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 512         then
 513           implied="$implied $try"
 514           found=yes
 515         fi
 516       done
 517       if test $found = no; then
 518         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 519       fi
 520     done
 521   else
 522     implied=
 523   fi
 524
 525   # Add NAME to the list of names.
 526   names="$names $name"
 527
 528   # Find the parent of NAME, using the empty string if it has none.
 529 changequote(,)dnl
 530   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 531 changequote([,])dnl
 532
 533   # Add the names implied by NAME, and NAME's parent (if it has one), to
 534   # the list of names to be processed (the argument list).  We prepend the
 535   # implied names to the list and append the parent.  We want implied
 536   # directories to come before further directories inferred from the
 537   # configuration components; this ensures that for sysv4, unix/common
 538   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 539   # after sysv4).
 540   sysnames="`echo $implied $* $parent`"
 541   test -n "$sysnames" && set $sysnames
 542 done
 543
 544 # Add the default directories.
 545 default_sysnames=sysdeps/generic
 546 if test "$elf" = yes; then
 547   default_sysnames="sysdeps/generic/elf $default_sysnames"
 548 fi
 549 sysnames="$names $default_sysnames"
 550 AC_SUBST(sysnames)
 551 # The other names were emitted during the scan.
 552 AC_MSG_RESULT($default_sysnames)
 553
 554
 555 ### Locate tools.
 556
 557 AC_PROG_INSTALL
 558 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 559   # The makefiles need to use a different form to find it in $srcdir.
 560   INSTALL='\$(..)./scripts/install-sh -c'
 561 fi
 562 AC_PROG_LN_S
 563
 564 # We need the physical current working directory.  We cannot use the
 565 # "pwd -P" shell builtin since that's not portable.  Instead we try to
 566 # find a pwd binary.  Note that assigning to the PWD environment
 567 # variable might have some interesting side effects, so we don't do
 568 # that.
 569 AC_PATH_PROG(PWD_P, pwd, no)
 570 if test "$PWD_P" = no; then
 571   AC_MSG_ERROR(*** A pwd binary could not be found.)
 572 fi
 573
 574 # These programs are version sensitive.
 575 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 576 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 577   [version \([egcygnustpi-]*[0-9.]*\)],
 578   [*gcc-2.9[5-9].*|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|2.9[5-9]*|3.[0-9]*|cygnus-2.9[1-9]*|gcc-2.9[5-9]|gcc-2.1[0-9][0-9]|sgicc-*],
 579   critic_missing=gcc)
 580 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 581   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 582   [3.79* | 3.[89]*], critic_missing="$critic_missing make")
 583
 584
 585 if test -n "$critic_missing"; then
 586 AC_MSG_ERROR([
 587 *** These critical programs are missing or too old:$critic_missing
 588 *** Check the INSTALL file for required versions.])
 589 fi
 590
 591
 592 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 593   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 594   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 595   MSGFMT=: aux_missing="$aux_missing msgfmt")
 596 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 597   [GNU texinfo.* \([0-9][0-9.]*\)],
 598   [4.*],
 599   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 600 AC_CHECK_PROG_VER(SED, gsed sed, --version,
 601   [GNU sed version \([0-9]*\.[0-9.]*\)],
 602   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 603   SED=: aux_missing="$aux_missing sed")
 604
 605 AC_PROG_CC_LOCAL
 606 AC_CANONICAL_BUILD
 607 if test $host != $build; then
 608   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 609 fi
 610 AC_SUBST(cross_compiling)
 611 AC_PROG_CPP
 612 LIBC_PROG_BINUTILS
 613 AC_CHECK_TOOL(MIG, mig)
 614
 615 # Accept binutils 2.10.1 or newer (and also any ia64 2.9 version)
 616 # XXX Commented out because it filters out too many good versions.
 617 # XXX --drepper
 618 # AC_CHECK_PROG_VER(AS, $AS, --version,
 619 #   [GNU assembler.* \([0-9]*\.[0-9.]*\(-ia64-[0-9]*\)*\)],
 620 #   [2.10.[1-9]* | 2.1[1-9]* | 2.9-ia64-*], AS=: critic_missing=t)
 621
 622 test -n "$aux_missing" && AC_MSG_WARN([
 623 *** These auxiliary programs are missing or too old:$aux_missing
 624 *** some features will be disabled.
 625 *** Check the INSTALL file for required versions.])
 626
 627 # glibcbug.in wants to know the compiler version.
 628 CCVERSION=`$CC -v 2>&1 | sed -n 's/gcc version //p'`
 629 AC_SUBST(CCVERSION)
 630
 631 # if using special system headers, find out the compiler's sekrit
 632 # header directory and add that to the list.  NOTE: Only does the right
 633 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 634 if test -n "$sysheaders"; then
 635   ccheaders=`$CC -print-file-name=include`
 636   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 637 fi
 638 AC_SUBST(SYSINCLUDES)
 639
 640 # check if ranlib is necessary
 641 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 642 cat > conftest.c <<EOF
 643 int a;
 644 char b;
 645 void c(void) {}
 646 EOF
 647 $CC $CFLAGS -c conftest.c
 648 $AR cr conftest.a conftest.c
 649 cp conftest.a conftest2.a
 650 $RANLIB conftest.a
 651 if cmp -s conftest.a conftest2.a; then
 652   libc_cv_ranlib_necessary=no
 653 else
 654   libc_cv_ranlib_necessary=yes
 655 fi
 656 rm -rf conftest*])
 657 if test "$libc_cv_ranlib_necessary" = no; then
 658  RANLIB=:
 659 fi
 660
 661 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 662 # since this would lead to problems installing/building glibc.
 663 # LD_LIBRARY_PATH contains the current directory if one of the following
 664 # is true:
 665 # - one of the terminals (":" and ";") is the first or last sign
 666 # - two terminals occur directly after each other
 667 # - the path contains an element with a dot in it
 668 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 669 changequote(,)dnl
 670 case ${LD_LIBRARY_PATH} in
 671   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 672     ld_library_path_setting="contains current directory"
 673     ;;
 674   *)
 675     ld_library_path_setting="ok"
 676     ;;
 677 esac
 678 changequote([,])dnl
 679 AC_MSG_RESULT($ld_library_path_setting)
 680 if test "$ld_library_path_setting" != "ok"; then
 681 AC_MSG_ERROR([
 682 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 683 *** building glibc. Please change the environment variable
 684 *** and run configure again.])
 685 fi
 686
 687 AC_PATH_PROG(BASH, bash, no)
 688 if test "$BASH" != no &&
 689    $BASH -c 'test "$BASH_VERSINFO" \
 690              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 691   libc_cv_have_bash2=yes
 692 else
 693   libc_cv_have_bash2=no
 694 fi
 695 AC_SUBST(libc_cv_have_bash2)
 696
 697 dnl We need a ksh compatible shell for tzselect.
 698 if test "$BASH" = no; then
 699   AC_PATH_PROG(KSH, ksh, no)
 700   if test "$KSH" = no; then
 701     libc_cv_have_ksh=no
 702   else
 703     libc_cv_have_ksh=yes
 704   fi
 705 else
 706   KSH="$BASH"
 707   AC_SUBST(KSH)
 708   libc_cv_have_ksh=yes
 709 fi
 710 AC_SUBST(libc_cv_have_ksh)
 711
 712 AC_PROG_AWK
 713 AC_PATH_PROG(PERL, perl, no)
 714 if test "$PERL" != no &&
 715    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
 716   PERL=no
 717 fi
 718 AC_PATH_PROG(INSTALL_INFO, install-info, no,
 719              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
 720 if test "$INSTALL_INFO" != "no"; then
 721 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 722  [mkdir conftest.d
 723   # There is a hard ^_ on the next line.  I am open to better ideas.
 724   (echo '\x1f'
 725   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 726   echo '* Menu:') >conftest.d/dir
 727   (echo 'INFO-DIR-SECTION i-d-s works'
 728   echo 'START-INFO-DIR-ENTRY'
 729   echo '* Prog: (prog).   Program.'
 730   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 731   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 732   then
 733     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 734     then libc_cv_old_debian_install_info=no
 735     else libc_cv_old_debian_install_info=yes
 736     fi
 737   else libc_cv_old_debian_install_info=no testfailed=t
 738   fi
 739   rm -fr conftest.d])
 740 if test -n "$testfailed"
 741 then AC_MSG_WARN([install-info errored out, check config.log])
 742 fi
 743 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 744 fi
 745 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 746
 747 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
 748
 749 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 750 echo '#include <stddef.h>
 751 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 752 if eval "$ac_cpp conftest.c 2>/dev/null" \
 753 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 754   libc_cv_signed_size_t=no
 755 else
 756   libc_cv_signed_size_t=yes
 757 fi
 758 rm -f conftest*])
 759 if test $libc_cv_signed_size_t = yes; then
 760   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 761   cat >> confdefs.h <<\EOF
 762 #undef __SIZE_TYPE__
 763 #define __SIZE_TYPE__ unsigned
 764 EOF
 765 fi
 766
 767 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 768 AC_TRY_COMPILE(dnl
 769 [#define __need_size_t
 770 #define __need_wchar_t
 771 #include <stddef.h>
 772 #define __need_NULL
 773 #include <stddef.h>], [size_t size; wchar_t wchar;
 774 #ifdef offsetof
 775 #error stddef.h ignored __need_*
 776 #endif
 777 if (&size == NULL || &wchar == NULL) abort ();],
 778                libc_cv_friendly_stddef=yes,
 779                libc_cv_friendly_stddef=no)])
 780 if test $libc_cv_friendly_stddef = yes; then
 781   config_vars="$config_vars
 782 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 783 fi
 784
 785 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 786                libc_cv_need_minus_P, [dnl
 787 cat > conftest.S <<EOF
 788 #include "confdefs.h"
 789 /* Nothing whatsoever.  */
 790 EOF
 791 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 792   libc_cv_need_minus_P=no
 793 else
 794   libc_cv_need_minus_P=yes
 795 fi
 796 rm -f conftest*])
 797 if test $libc_cv_need_minus_P = yes; then
 798   config_vars="$config_vars
 799 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 800 fi
 801
 802 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 803 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 804 cat > conftest.s <<EOF
 805 .text
 806 EOF
 807 libc_cv_dot_text=
 808 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 809   libc_cv_dot_text=.text
 810 fi
 811 rm -f conftest*])
 812 if test -z "$libc_cv_dot_text"; then
 813   AC_MSG_RESULT(no)
 814 else
 815   AC_MSG_RESULT(yes)
 816 fi
 817
 818 AC_CACHE_CHECK(for assembler global-symbol directive,
 819                libc_cv_asm_global_directive, [dnl
 820 libc_cv_asm_global_directive=UNKNOWN
 821 for ac_globl in .globl .global .EXPORT; do
 822   cat > conftest.s <<EOF
 823         ${libc_cv_dot_text}
 824         ${ac_globl} foo
 825 foo:
 826 EOF
 827   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 828     libc_cv_asm_global_directive=${ac_globl}
 829   fi
 830   rm -f conftest*
 831   test $libc_cv_asm_global_directive != UNKNOWN && break
 832 done])
 833 if test $libc_cv_asm_global_directive = UNKNOWN; then
 834   AC_MSG_ERROR(cannot determine asm global directive)
 835 else
 836   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 837 fi
 838
 839 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 840 cat > conftest.s <<EOF
 841 ${libc_cv_dot_text}
 842 foo:
 843 .set glibc_conftest_frobozz,foo
 844 $libc_cv_asm_global_directive glibc_conftest_frobozz
 845 EOF
 846 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 847 # (but it doesn't work), so we must do a linking check to be sure.
 848 cat > conftest1.c <<\EOF
 849 extern int glibc_conftest_frobozz;
 850 main () { printf ("%d\n", glibc_conftest_frobozz); }
 851 EOF
 852 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 853             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 854   libc_cv_asm_set_directive=yes
 855 else
 856   libc_cv_asm_set_directive=no
 857 fi
 858 rm -f conftest*])
 859 if test $libc_cv_asm_set_directive = yes; then
 860   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 861 fi
 862
 863 # The Aix ld uses global .symbol_names instead of symbol_names.
 864 case "$os" in
 865 aix4.3*)
 866   AC_DEFINE(HAVE_ASM_GLOBAL_DOT_NAME)
 867 esac
 868
 869 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 870 [cat > conftest.s <<EOF
 871 ${libc_cv_dot_text}
 872 _sym:
 873 .symver _sym,sym@VERS
 874 EOF
 875 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 876   libc_cv_asm_symver_directive=yes
 877 else
 878   libc_cv_asm_symver_directive=no
 879 fi
 880 rm -f conftest*])
 881 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 882 if test $libc_cv_asm_symver_directive = yes; then
 883   cat > conftest.s <<EOF
 884 ${libc_cv_dot_text}
 885 _sym:
 886 .symver _sym,sym@VERS
 887 EOF
 888   cat > conftest.map <<EOF
 889 VERS_1 {
 890         global: sym;
 891 };
 892
 893 VERS_2 {
 894         global: sym;
 895 } VERS_1;
 896 EOF
 897   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 898     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 899                                         -nostartfiles -nostdlib
 900                                         -Wl,--version-script,conftest.map
 901                        1>&AC_FD_CC]);
 902     then
 903       libc_cv_ld_version_script_option=yes
 904     else
 905       libc_cv_ld_version_script_option=no
 906     fi
 907   else
 908     libc_cv_ld_version_script_option=no
 909   fi
 910 else
 911   libc_cv_ld_version_script_option=no
 912 fi
 913 rm -f conftest*])
 914 if test $shared != no &&
 915    test $libc_cv_asm_symver_directive = yes &&
 916    test $libc_cv_ld_version_script_option = yes &&
 917    test $enable_versioning = yes; then
 918   VERSIONING=yes
 919   AC_DEFINE(DO_VERSIONING)
 920 else
 921   VERSIONING=no
 922 fi
 923 AC_SUBST(VERSIONING)
 924
 925 if test $elf = yes && test $shared != no && test $VERSIONING = no; then
 926   echo "\
 927 *** WARNING: You should not compile GNU libc without versioning. Not using
 928 *** versioning will introduce incompatibilities so that old binaries
 929 *** will not run anymore.
 930 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 931 fi
 932 if test $elf = yes; then
 933   AC_CACHE_CHECK(for .previous assembler directive,
 934                  libc_cv_asm_previous_directive, [dnl
 935   cat > conftest.s <<EOF
 936 .section foo_section
 937 .previous
 938 EOF
 939   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 940     libc_cv_asm_previous_directive=yes
 941   else
 942     libc_cv_asm_previous_directive=no
 943   fi
 944   rm -f conftest*])
 945   if test $libc_cv_asm_previous_directive = yes; then
 946     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 947   else
 948     AC_CACHE_CHECK(for .popsection assembler directive,
 949                    libc_cv_asm_popsection_directive, [dnl
 950     cat > conftest.s <<EOF
 951 .pushsection foo_section
 952 .popsection
 953 EOF
 954     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 955       libc_cv_asm_popsection_directive=yes
 956     else
 957       libc_cv_asm_popsection_directive=no
 958     fi
 959     rm -f conftest*])
 960     if test $libc_cv_asm_popsection_directive = yes; then
 961       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 962     fi
 963   fi
 964   AC_CACHE_CHECK(for .protected and .hidden assembler directive,
 965                  libc_cv_asm_protected_directive, [dnl
 966   cat > conftest.s <<EOF
 967 .protected foo
 968 foo:
 969 .hidden bar
 970 bar:
 971 EOF
 972   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 973     libc_cv_asm_protected_directive=yes
 974   else
 975     libc_cv_asm_protected_directive=no
 976   fi
 977   rm -f conftest*])
 978   AC_SUBST(libc_cv_asm_protected_directive)
 979
 980   AC_CACHE_CHECK(for -z nodelete option,
 981                  libc_cv_z_nodelete, [dnl
 982   cat > conftest.c <<EOF
 983 int _start (void) { return 42; }
 984 EOF
 985   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c -Wl,--enable-new-dtags,-z,nodelete 1>&AC_FD_CC])
 986   then
 987     libc_cv_z_nodelete=yes
 988   else
 989     libc_cv_z_nodelete=no
 990   fi
 991   rm -f conftest*])
 992   AC_SUBST(libc_cv_z_nodelete)
 993
 994   AC_CACHE_CHECK(for -z nodlopen option,
 995                  libc_cv_z_nodlopen, [dnl
 996   cat > conftest.c <<EOF
 997 int _start (void) { return 42; }
 998 EOF
 999   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c -Wl,--enable-new-dtags,-z,nodlopen 1>&AC_FD_CC])
1000   then
1001     libc_cv_z_nodlopen=yes
1002   else
1003     libc_cv_z_nodlopen=no
1004   fi
1005   rm -f conftest*])
1006   AC_SUBST(libc_cv_z_nodlopen)
1007
1008   AC_CACHE_CHECK(for -z initfirst option,
1009                  libc_cv_z_initfirst, [dnl
1010   cat > conftest.c <<EOF
1011 int _start (void) { return 42; }
1012 EOF
1013   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c -Wl,--enable-new-dtags,-z,initfirst 1>&AC_FD_CC])
1014   then
1015     libc_cv_z_initfirst=yes
1016   else
1017     libc_cv_z_initfirst=no
1018   fi
1019   rm -f conftest*])
1020   AC_SUBST(libc_cv_z_initfirst)
1021
1022   AC_CACHE_CHECK(for -Bgroup option,
1023                  libc_cv_Bgroup, [dnl
1024   cat > conftest.c <<EOF
1025 int _start (void) { return 42; }
1026 EOF
1027   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c -Wl,-Bgroup -nostdlib 1>&AC_FD_CC])
1028   then
1029     libc_cv_Bgroup=yes
1030   else
1031     libc_cv_Bgroup=no
1032   fi
1033   rm -f conftest*])
1034   AC_SUBST(libc_cv_Bgroup)
1035 fi
1036
1037 if test $elf != yes; then
1038   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
1039                  [AC_TRY_COMPILE(, [asm (".section .init");
1040                                     asm (".section .fini");
1041                                     asm ("${libc_cv_dot_text}");],
1042                                  libc_cv_have_initfini=yes,
1043                                  libc_cv_have_initfini=no)])
1044   AC_SUBST(libc_cv_have_initfini)dnl
1045   if test $libc_cv_have_initfini = yes; then
1046     AC_DEFINE(HAVE_INITFINI)
1047   fi
1048 fi
1049
1050 if test $elf = yes -a $gnu_ld = yes; then
1051   AC_CACHE_CHECK(whether cc puts quotes around section names,
1052                  libc_cv_have_section_quotes,
1053                  [cat > conftest.c <<EOF
1054                   static const int foo
1055                   __attribute__ ((section ("bar"))) = 1;
1056 EOF
1057                   if ${CC-cc} -S conftest.c -o conftest.s; then
1058                     if grep '\.section.*"bar"' conftest.s >/dev/null; then
1059                       libc_cv_have_section_quotes=yes
1060                     else
1061                       libc_cv_have_section_quotes=no
1062                     fi
1063                   else
1064                     libc_cv_have_section_quotes=unknown
1065                   fi
1066                   rm -f conftest.[cs]
1067                  ])
1068   if test $libc_cv_have_section_quotes = yes; then
1069     AC_DEFINE(HAVE_SECTION_QUOTES)
1070   fi
1071 fi
1072
1073 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
1074 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
1075 [cat > conftest.$ac_ext <<EOF
1076 dnl This sometimes fails to find confdefs.h, for some reason.
1077 dnl [#]line __oline__ "[$]0"
1078 [#]line __oline__ "configure"
1079 #include "confdefs.h"
1080 void underscore_test(void) {
1081 return; }
1082 EOF
1083 if AC_TRY_EVAL(ac_compile); then
1084   if grep _underscore_test conftest* >/dev/null; then
1085     ifelse([$1], , :, [rm -f conftest*
1086     $1])
1087   else
1088     ifelse([$2], , , [rm -f conftest*
1089     $2])
1090   fi
1091 else
1092   echo "configure: failed program was:" >&AC_FD_CC
1093   cat conftest.$ac_ext >&AC_FD_CC
1094   ifelse([$2], , , [rm -f conftest*
1095   $2])
1096 fi
1097 rm -f conftest*])
1098
1099 if test $elf = yes; then
1100   libc_cv_asm_underscores=no
1101 else
1102   if test $ac_cv_prog_cc_works = yes; then
1103     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
1104                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
1105                                 libc_cv_asm_underscores=yes,
1106                                 libc_cv_asm_underscores=no)])
1107   else
1108     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
1109                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
1110                                             libc_cv_asm_underscores=no)])
1111   fi
1112 fi
1113 if test $libc_cv_asm_underscores = no; then
1114   AC_DEFINE(NO_UNDERSCORES)
1115 fi
1116
1117 if test $elf = yes; then
1118   libc_cv_weak_symbols=yes
1119 fi
1120
1121 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1122                [dnl
1123 cat > conftest.s <<EOF
1124 ${libc_cv_dot_text}
1125 ${libc_cv_asm_global_directive} foo
1126 foo:
1127 .weak foo
1128 .weak bar; bar = foo
1129 EOF
1130 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
1131   libc_cv_asm_weak_directive=yes
1132 else
1133   libc_cv_asm_weak_directive=no
1134 fi
1135 rm -f conftest*])
1136
1137 if test $libc_cv_asm_weak_directive = no; then
1138   AC_CACHE_CHECK(for assembler .weakext directive,
1139                  libc_cv_asm_weakext_directive,
1140                  [dnl
1141 cat > conftest.s <<EOF
1142 ${libc_cv_dot_text}
1143 ${libc_cv_asm_global_directive} foo
1144 foo:
1145 .weakext bar foo
1146 .weakext baz
1147 ${libc_cv_asm_global_directive} baz
1148 baz:
1149 EOF
1150   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
1151     libc_cv_asm_weakext_directive=yes
1152   else
1153     libc_cv_asm_weakext_directive=no
1154   fi
1155   rm -f conftest*])
1156
1157 fi # no .weak
1158
1159 if test $libc_cv_asm_weak_directive = yes; then
1160   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1161 elif test $libc_cv_asm_weakext_directive = yes; then
1162   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1163 fi
1164
1165 dnl The standard hppa assembler uses `;' to start comments and `!'
1166 dnl as a line separator.  CRIS uses `;' to start comments and `@' for
1167 dnl line separator.
1168 case "${host_cpu}-${host_os}" in
1169   cris*)
1170     libc_cv_asm_line_sep='@'
1171     AC_DEFINE_UNQUOTED(ASM_LINE_SEP, $libc_cv_asm_line_sep)
1172     ;;
1173   hppa*linux*)
1174   AC_CACHE_CHECK(for assembler line separator,
1175                  libc_cv_asm_line_sep, [dnl
1176   cat > conftest.s <<EOF
1177  nop ; is_old_puffin
1178 EOF
1179   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
1180     libc_cv_asm_line_sep='!'
1181   else
1182     if test -z "$enable_hacker_mode"; then
1183       echo "*** You need a newer assembler to compile glibc"
1184       rm -f conftest*
1185       exit 1
1186     fi
1187     libc_cv_asm_line_sep=';'
1188   fi
1189   rm -f conftest*])
1190   AC_DEFINE_UNQUOTED(ASM_LINE_SEP, $libc_cv_asm_line_sep)
1191   ;;
1192 esac
1193
1194 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1195 cat > conftest.c <<\EOF
1196 _start () {}
1197 int __eh_pc;
1198 __throw () {}
1199 EOF
1200 dnl No \ in command here because it ends up inside ''.
1201 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1202                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1203                             -o conftest conftest.c 1>&AC_FD_CC]); then
1204   libc_cv_ld_no_whole_archive=yes
1205 else
1206   libc_cv_ld_no_whole_archive=no
1207 fi
1208 rm -f conftest*])
1209 if test $libc_cv_ld_no_whole_archive = yes; then
1210   no_whole_archive=-Wl,--no-whole-archive
1211 fi
1212 AC_SUBST(no_whole_archive)dnl
1213
1214 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1215 cat > conftest.c <<\EOF
1216 _start () {}
1217 int __eh_pc;
1218 __throw () {}
1219 EOF
1220 dnl No \ in command here because it ends up inside ''.
1221 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1222                             -nostdlib -nostartfiles -fexceptions
1223                             -o conftest conftest.c 1>&AC_FD_CC]); then
1224   libc_cv_gcc_exceptions=yes
1225 else
1226   libc_cv_gcc_exceptions=no
1227 fi
1228 rm -f conftest*])
1229 if test $libc_cv_gcc_exceptions = yes; then
1230   exceptions=-fexceptions
1231 fi
1232 AC_SUBST(exceptions)dnl
1233
1234 if test "$base_machine" = alpha ; then
1235 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
1236 cat > conftest.c <<\EOF
1237 foo () { }
1238 EOF
1239 dnl
1240 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
1241 then
1242   libc_cv_gcc_alpha_ng_prefix=yes
1243 else
1244   libc_cv_gcc_alpha_ng_prefix=no
1245 fi
1246 rm -f conftest* ])
1247 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
1248   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
1249 else
1250   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
1251 fi
1252 fi
1253
1254 if test "$host_cpu" = powerpc ; then
1255 # Check for a bug present in at least versions 2.8.x of GCC
1256 # and versions 1.0.x of EGCS.
1257 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1258 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1259                libc_cv_c_asmcr0_bug='no',
1260                libc_cv_c_asmcr0_bug='yes')])
1261 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1262   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1263 fi
1264 fi
1265
1266 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
1267 [cat > conftest.c <<EOF
1268 #line __oline__ "configure"
1269 static char __EH_FRAME_BEGIN__[];
1270 _start ()
1271 {
1272 #ifdef CHECK__register_frame
1273   __register_frame (__EH_FRAME_BEGIN__);
1274   __deregister_frame (__EH_FRAME_BEGIN__);
1275 #endif
1276 #ifdef CHECK__register_frame_info
1277   __register_frame_info (__EH_FRAME_BEGIN__);
1278   __deregister_frame_info (__EH_FRAME_BEGIN__);
1279 #endif
1280 }
1281 int __eh_pc;
1282 __throw () {}
1283 /* FIXME: this is fragile.  */
1284 malloc () {}
1285 strcmp () {}
1286 strlen () {}
1287 memcpy () {}
1288 memset () {}
1289 free () {}
1290 abort () {}
1291 __bzero () {}
1292 EOF
1293 dnl No \ in command here because it ends up inside ''.
1294 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1295                             -nostdlib -nostartfiles
1296                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1297   libc_cv_gcc_dwarf2_unwind_info=static
1298 else
1299   libc_cv_gcc_dwarf2_unwind_info=no
1300 fi
1301 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1302   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1303                               -nostdlib -nostartfiles
1304                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1305     libc_cv_gcc_dwarf2_unwind_info=yes
1306   else
1307     libc_cv_gcc_dwarf2_unwind_info=no
1308   fi
1309 fi
1310 rm -f conftest*])
1311 case $libc_cv_gcc_dwarf2_unwind_info in
1312 yes)
1313   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1314   ;;
1315 static)
1316   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1317   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1318   ;;
1319 esac
1320
1321 dnl Check whether compiler understands __builtin_expect.
1322 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1323 [cat > conftest.c <<EOF
1324 #line __oline__ "configure"
1325 int foo (int a)
1326 {
1327   a = __builtin_expect (a, 10);
1328   return a == 10 ? 0 : 1;
1329 }
1330 EOF
1331 dnl No \ in command here because it ends up inside ''.
1332 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1333                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1334   libc_cv_gcc_builtin_expect=yes
1335 else
1336   libc_cv_gcc_builtin_expect=no
1337 fi
1338 rm -f conftest*])
1339 if test "$libc_cv_gcc_builtin_expect" = yes; then
1340   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1341 fi
1342
1343 dnl Check whether the compiler supports subtraction of local labels.
1344 AC_CACHE_CHECK(for local label subtraction, libc_cv_gcc_subtract_local_labels,
1345 [cat > conftest.c <<EOF
1346 changequote(,)dnl
1347 #line __oline__ "configure"
1348 int foo (int a)
1349 {
1350   static const int ar[] = { &&l1 - &&l1, &&l2 - &&l1 };
1351   void *p = &&l1 + ar[a];
1352   goto *p;
1353  l1:
1354   return 1;
1355  l2:
1356   return 2;
1357 }
1358 changequote([,])dnl
1359 EOF
1360 dnl No \ in command here because it ends up inside ''.
1361 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1362                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1363   libc_cv_gcc_subtract_local_labels=yes
1364 else
1365   libc_cv_gcc_subtract_local_labels=no
1366 fi
1367 rm -f conftest*])
1368 if test "$libc_cv_gcc_subtract_local_labels" = yes; then
1369   AC_DEFINE(HAVE_SUBTRACT_LOCAL_LABELS)
1370 fi
1371
1372 dnl Check whether we have the gd library available.
1373 AC_MSG_CHECKING(for libgd)
1374 if test "$with_gd" != "no"; then
1375   old_CFLAGS="$CFLAGS"
1376   CFLAGS="$CFLAGS $libgd_include"
1377   old_LDFLAGS="$LDFLAGS"
1378   LDFLAGS="$LDFLAGS $libgd_ldflags"
1379   old_LIBS="$LIBS"
1380   LIBS="$LIBS -lgd -lpng -lz -lm"
1381   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1382   CFLAGS="$old_CFLAGS"
1383   LDFLAGS="$old_LDFLAGS"
1384   LIBS="$old_LIBS"
1385 else
1386   LIBGD=no
1387 fi
1388 AC_MSG_RESULT($LIBGD)
1389 AC_SUBST(LIBGD)
1390
1391 dnl check for the size of 'long double'.
1392 AC_CHECK_SIZEOF(long double, 0)
1393 sizeof_long_double=$ac_cv_sizeof_long_double
1394 AC_SUBST(sizeof_long_double)
1395
1396 ### End of automated tests.
1397 ### Now run sysdeps configure fragments.
1398
1399 # sysdeps configure fragments may set these with files to be linked below.
1400 libc_link_dests=
1401 libc_link_sources=
1402
1403 # They also can set these variables.
1404 use_ldconfig=no
1405 ldd_rewrite_script=no
1406 libc_cv_sysconfdir=$sysconfdir
1407
1408 # Iterate over all the sysdep directories we will use, running their
1409 # configure fragments, and looking for a uname implementation.
1410 uname=
1411 for dir in $sysnames; do
1412   case $dir in
1413     /*) dest=$dir ;;
1414     *)  dest=$srcdir/$dir ;;
1415   esac
1416   if test -r $dest/configure; then
1417     AC_MSG_RESULT(running configure fragment for $dest)
1418     . $dest/configure
1419   fi
1420 [
1421   if test -z "$uname"; then
1422     if test -r $dest/uname.c ||
1423        test -r $dest/uname.S ||
1424        { test -r $dest/syscalls.list &&
1425          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1426       uname=$dir
1427     fi
1428   fi
1429 ]dnl
1430 done
1431
1432 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1433
1434 # If we will use the generic uname implementation, we must figure out what
1435 # it will say by examining the system, and write the results in config-name.h.
1436 if test "$uname" = "sysdeps/generic"; then
1437
1438 changequote(,)dnl
1439   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1440 changequote([,])dnl
1441   if test $uname_sysname != $config_os; then
1442     config_release=`echo $config_os | sed s/$uname_sysname//`
1443   fi
1444 dnl
1445 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1446     if test -r /vmunix; then
1447       kernel_id=`strings /vmunix | grep UNIX`
1448     elif test -r /dynix; then
1449       kernel_id=`strings /dynix | grep DYNIX`
1450     else
1451       kernel_id=
1452     fi
1453 ])dnl
1454
1455   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1456 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1457 changequote(,)dnl
1458   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1459 changequote([,])dnl
1460   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1461          != x$config_release; then
1462     # The configuration release is a substring of the kernel release.
1463     libc_cv_uname_release=$kernel_release
1464   elif test x$config_release != x; then
1465     libc_cv_uname_release=$config_release
1466   elif test x$kernel_release != x; then
1467     libc_cv_uname_release=$kernel_release
1468   else
1469     libc_cv_uname_release=unknown
1470   fi])
1471   uname_release="$libc_cv_uname_release"
1472
1473   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1474 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1475 changequote(,)dnl
1476   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1477 changequote([,])dnl
1478   if test -n "$kernel_version"; then
1479     libc_cv_uname_version="$kernel_version"
1480   else
1481     libc_cv_uname_version=unknown
1482   fi])
1483   uname_version="$libc_cv_uname_version"
1484
1485 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1486   config_uname=config-name.h:config-name.in
1487 else
1488   # For non-generic uname, we don't need to create config-name.h at all.
1489   config_uname=
1490 fi
1491
1492 AC_MSG_CHECKING(stdio selection)
1493 AC_SUBST(stdio)
1494 case $stdio in
1495 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1496 default) stdio=stdio ;;
1497 esac
1498 AC_MSG_RESULT($stdio)
1499
1500 # Test for old glibc 2.0.x headers so that they can be removed properly
1501 # Search only in includedir.
1502 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1503 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1504 then
1505   old_glibc_headers=yes
1506 else
1507   old_glibc_headers=no
1508 fi
1509 AC_MSG_RESULT($old_glibc_headers)
1510 if test ${old_glibc_headers} = yes; then
1511   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1512   AC_MSG_WARN(*** be removed.)
1513 fi
1514 AC_SUBST(old_glibc_headers)
1515
1516 AC_SUBST(libc_cv_slibdir)
1517 AC_SUBST(libc_cv_localedir)
1518 AC_SUBST(libc_cv_sysconfdir)
1519 AC_SUBST(libc_cv_rootsbindir)
1520
1521 AC_SUBST(use_ldconfig)
1522 AC_SUBST(ldd_rewrite_script)
1523
1524 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1525 if test $gnu_ld = yes; then
1526   AC_DEFINE(HAVE_GNU_LD)
1527 fi
1528 if test $gnu_as = yes; then
1529   AC_DEFINE(HAVE_GNU_AS)
1530 fi
1531 if test $elf = yes; then
1532   AC_DEFINE(HAVE_ELF)
1533 fi
1534
1535 AC_SUBST(static)
1536 AC_SUBST(shared)
1537 if test $shared = default; then
1538   if test $gnu_ld = yes; then
1539     shared=$elf
1540   else
1541     # For now we do not assume shared libs are available.  In future more
1542     # tests might become available.
1543     shared=no
1544   fi
1545 fi
1546
1547 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1548 [pic_default=yes
1549 cat > conftest.c <<EOF
1550 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1551 # error PIC is default.
1552 #endif
1553 EOF
1554 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1555   pic_default=no
1556 fi
1557 rm -f conftest.*])
1558 AC_SUBST(pic_default)
1559
1560 AC_SUBST(profile)
1561 AC_SUBST(omitfp)
1562 AC_SUBST(bounded)
1563 AC_SUBST(static_nss)
1564 AC_SUBST(nopic_initfini)
1565
1566 AC_SUBST(DEFINES)
1567
1568 case "$add_ons" in
1569   *door*) linux_doors=yes ;;
1570   *) linux_doors=no ;;
1571 esac
1572 AC_SUBST(linux_doors)
1573
1574 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1575   config_makefile=
1576 else
1577   config_makefile=Makefile
1578 fi
1579
1580 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1581 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1582 AC_SUBST(VERSION)
1583 AC_SUBST(RELEASE)
1584
1585 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1586 case $CONFIG_FILES in *config.make*)
1587 echo "$config_vars" >> config.make;;
1588 esac
1589 test -d bits || mkdir bits], [config_vars='$config_vars'])