| blob | def655ab8b804b8882117d48b35a0ba69853442a |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Note we do not use AC_PREREQ here! See aclocal.m4 for what we use instead.
3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
4 AC_CONFIG_SRCDIR([include/features.h])
5 AC_CONFIG_HEADERS([config.h])
6 AC_CONFIG_AUX_DIR([scripts])
8 ACX_PKGVERSION([GNU libc])
9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
11 [Package description])
12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
13 [Bug reporting address])
15 # Glibc should not depend on any header files
16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
17 [m4_divert_text([DEFAULTS],
18 [ac_includes_default='/* none */'])])
20 # We require GCC, and by default use its preprocessor. Override AC_PROG_CPP
21 # here to work around the Autoconf issue discussed in
22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
23 AC_DEFUN([AC_PROG_CPP],
24 [AC_REQUIRE([AC_PROG_CC])dnl
25 AC_ARG_VAR([CPP], [C preprocessor])dnl
26 _AC_ARG_VAR_CPPFLAGS()dnl
27 # On Suns, sometimes $CPP names a directory.
28 if test -n "$CPP" && test -d "$CPP"; then
29 CPP=
30 fi
31 if test -z "$CPP"; then
32 CPP="$CC -E"
33 fi
34 AC_SUBST(CPP)dnl
35 ])# AC_PROG_CPP
37 # We require GCC. Override _AC_PROG_CC_C89 here to work around the Autoconf
38 # issue discussed in
39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
42 dnl This is here so we can set $subdirs directly based on configure fragments.
43 AC_CONFIG_SUBDIRS()
45 AC_CANONICAL_HOST
47 AC_PROG_CC
48 if test $host != $build; then
49 AC_CHECK_PROGS(BUILD_CC, gcc cc)
50 fi
51 AC_SUBST(cross_compiling)
52 AC_PROG_CPP
53 AC_CHECK_TOOL(READELF, readelf, false)
55 # We need the C++ compiler only for testing.
56 AC_PROG_CXX
57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
59 AC_LANG_PUSH([C++])
60 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
61 [libc_cv_cxx_link_ok=yes],
62 [libc_cv_cxx_link_ok=no])
63 AC_LANG_POP([C++])])
64 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
66 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
67 AC_MSG_ERROR([you must configure in a separate build directory])
68 fi
70 # This will get text that should go into config.make.
71 config_vars=
73 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
74 AC_ARG_WITH([gd],
75 AC_HELP_STRING([--with-gd=DIR],
76 [find libgd include dir and library with prefix DIR]),
77 [dnl
78 case "$with_gd" in
79 yes|''|no) ;;
80 *) libgd_include="-I$withval/include"
81 libgd_ldflags="-L$withval/lib" ;;
82 esac
83 ])
84 AC_ARG_WITH([gd-include],
85 AC_HELP_STRING([--with-gd-include=DIR],
86 [find libgd include files in DIR]),
87 [dnl
88 case "$with_gd_include" in
89 ''|no) ;;
90 *) libgd_include="-I$withval" ;;
91 esac
92 ])
93 AC_ARG_WITH([gd-lib],
94 AC_HELP_STRING([--with-gd-lib=DIR],
95 [find libgd library files in DIR]),
96 [dnl
97 case "$with_gd_lib" in
98 ''|no) ;;
99 *) libgd_ldflags="-L$withval" ;;
100 esac
101 ])
103 if test -n "$libgd_include"; then
104 config_vars="$config_vars
105 CFLAGS-memusagestat.c = $libgd_include"
106 fi
107 if test -n "$libgd_ldflags"; then
108 config_vars="$config_vars
109 libgd-LDFLAGS = $libgd_ldflags"
110 fi
112 dnl Arguments to specify presence of other packages/features.
113 AC_ARG_WITH([fp],
114 AC_HELP_STRING([--with-fp],
115 [if using floating-point hardware @<:@default=yes@:>@]),
116 [with_fp=$withval],
117 [with_fp=yes])
118 AC_SUBST(with_fp)
119 AC_ARG_WITH([binutils],
120 AC_HELP_STRING([--with-binutils=PATH],
121 [specify location of binutils (as and ld)]),
122 [path_binutils=$withval],
123 [path_binutils=''])
124 AC_ARG_WITH([selinux],
125 AC_HELP_STRING([--with-selinux],
126 [if building with SELinux support]),
127 [with_selinux=$withval],
128 [with_selinux=auto])
130 AC_ARG_WITH([headers],
131 AC_HELP_STRING([--with-headers=PATH],
132 [location of system headers to use
133 (for example /usr/src/linux/include)
134 @<:@default=compiler default@:>@]),
135 [sysheaders=$withval],
136 [sysheaders=''])
137 AC_SUBST(sysheaders)
139 AC_SUBST(use_default_link)
140 AC_ARG_WITH([default-link],
141 AC_HELP_STRING([--with-default-link],
142 [do not use explicit linker scripts]),
143 [use_default_link=$withval],
144 [use_default_link=default])
146 AC_ARG_ENABLE([sanity-checks],
147 AC_HELP_STRING([--disable-sanity-checks],
148 [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
149 [enable_sanity=$enableval],
150 [enable_sanity=yes])
152 AC_ARG_ENABLE([shared],
153 AC_HELP_STRING([--enable-shared],
154 [build shared library @<:@default=yes if GNU ld@:>@]),
155 [shared=$enableval],
156 [shared=yes])
157 AC_ARG_ENABLE([profile],
158 AC_HELP_STRING([--enable-profile],
159 [build profiled library @<:@default=no@:>@]),
160 [profile=$enableval],
161 [profile=no])
163 AC_ARG_ENABLE([hardcoded-path-in-tests],
164 AC_HELP_STRING([--enable-hardcoded-path-in-tests],
165 [hardcode newly built glibc path in tests @<:@default=no@:>@]),
166 [hardcoded_path_in_tests=$enableval],
167 [hardcoded_path_in_tests=no])
168 AC_SUBST(hardcoded_path_in_tests)
170 AC_ARG_ENABLE([stackguard-randomization],
171 AC_HELP_STRING([--enable-stackguard-randomization],
172 [initialize __stack_chk_guard canary with a random number at program start]),
173 [enable_stackguard_randomize=$enableval],
174 [enable_stackguard_randomize=no])
175 if test "$enable_stackguard_randomize" = yes; then
176 AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
177 fi
179 AC_ARG_ENABLE([lock-elision],
180 AC_HELP_STRING([--enable-lock-elision[=yes/no]],
181 [Enable lock elision for pthread mutexes by default]),
182 [enable_lock_elision=$enableval],
183 [enable_lock_elision=no])
184 AC_SUBST(enable_lock_elision)
185 if test "$enable_lock_elision" = yes ; then
186 AC_DEFINE(ENABLE_LOCK_ELISION)
187 fi
189 dnl Generic infrastructure for drop-in additions to libc.
190 AC_ARG_ENABLE([add-ons],
191 AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
192 [configure and build add-ons in DIR1,DIR2,...
193 search for add-ons if no parameter given]),
194 , [enable_add_ons=yes])
196 AC_ARG_ENABLE([hidden-plt],
197 AC_HELP_STRING([--disable-hidden-plt],
198 [do not hide internal function calls to avoid PLT]),
199 [hidden=$enableval],
200 [hidden=yes])
201 if test "x$hidden" = xno; then
202 AC_DEFINE(NO_HIDDEN)
203 fi
205 AC_ARG_ENABLE([bind-now],
206 AC_HELP_STRING([--enable-bind-now],
207 [disable lazy relocations in DSOs]),
208 [bindnow=$enableval],
209 [bindnow=no])
210 AC_SUBST(bindnow)
212 dnl On some platforms we cannot use dynamic loading. We must provide
213 dnl static NSS modules.
214 AC_ARG_ENABLE([static-nss],
215 AC_HELP_STRING([--enable-static-nss],
216 [build static NSS modules @<:@default=no@:>@]),
217 [static_nss=$enableval],
218 [static_nss=no])
219 dnl Enable static NSS also if we build no shared objects.
220 if test x"$static_nss" = xyes || test x"$shared" = xno; then
221 static_nss=yes
222 AC_DEFINE(DO_STATIC_NSS)
223 fi
225 AC_ARG_ENABLE([force-install],
226 AC_HELP_STRING([--disable-force-install],
227 [don't force installation of files from this package, even if they are older than the installed files]),
228 [force_install=$enableval],
229 [force_install=yes])
230 AC_SUBST(force_install)
232 AC_ARG_ENABLE([maintainer-mode],
233 AC_HELP_STRING([--enable-maintainer-mode],
234 [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
235 [maintainer=$enableval],
236 [maintainer=no])
238 dnl On some platforms we allow dropping compatibility with all kernel
239 dnl versions.
240 AC_ARG_ENABLE([kernel],
241 AC_HELP_STRING([--enable-kernel=VERSION],
242 [compile for compatibility with kernel not older than VERSION]),
243 [minimum_kernel=$enableval],
244 [])
245 dnl Prevent unreasonable values.
246 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
247 # Better nothing than this.
248 minimum_kernel=""
249 else
250 if test "$minimum_kernel" = current; then
251 minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
252 fi
253 fi
255 dnl For the development we sometimes want gcc to issue even more warnings.
256 dnl This is not the default since many of the extra warnings are not
257 dnl appropriate.
258 AC_ARG_ENABLE([all-warnings],
259 AC_HELP_STRING([--enable-all-warnings],
260 [enable all useful warnings gcc can issue]),
261 [all_warnings=$enableval],
262 [])
263 AC_SUBST(all_warnings)
265 AC_ARG_ENABLE([werror],
266 AC_HELP_STRING([--disable-werror],
267 [do not build with -Werror]),
268 [enable_werror=$enableval],
269 [enable_werror=yes])
270 AC_SUBST(enable_werror)
272 AC_ARG_ENABLE([multi-arch],
273 AC_HELP_STRING([--enable-multi-arch],
274 [enable single DSO with optimizations for multiple architectures]),
275 [multi_arch=$enableval],
276 [multi_arch=default])
278 AC_ARG_ENABLE([nss-crypt],
279 AC_HELP_STRING([--enable-nss-crypt],
280 [enable libcrypt to use nss]),
281 [nss_crypt=$enableval],
282 [nss_crypt=no])
283 if test x$nss_crypt = xyes; then
284 nss_includes=-I$(nss-config --includedir 2>/dev/null)
285 if test $? -ne 0; then
286 AC_MSG_ERROR([cannot find include directory with nss-config])
287 fi
288 old_CFLAGS="$CFLAGS"
289 CFLAGS="$CFLAGS $nss_includes"
290 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
291 #include <hasht.h>
292 #include <nsslowhash.h>
293 void f (void) { NSSLOW_Init (); }])],
294 libc_cv_nss_crypt=yes,
295 AC_MSG_ERROR([
296 cannot find NSS headers with lowlevel hash function interfaces]))
297 old_LIBS="$LIBS"
298 LIBS="$LIBS -lfreebl3"
299 AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
300 #include <hasht.h>
301 #include <nsslowhash.h>],
302 [NSSLOW_Init();])],
303 libc_cv_nss_crypt=yes,
304 AC_MSG_ERROR([
305 cannot link program using lowlevel NSS hash functions]))
306 CFLAGS="$old_CFLAGS"
307 LIBS="$old_LIBS"
308 else
309 libc_cv_nss_crypt=no
310 fi
311 AC_SUBST(libc_cv_nss_crypt)
314 AC_ARG_ENABLE([obsolete-rpc],
315 AC_HELP_STRING([--enable-obsolete-rpc],
316 [build and install the obsolete RPC code for link-time usage]),
317 [link_obsolete_rpc=$enableval],
318 [link_obsolete_rpc=no])
319 AC_SUBST(link_obsolete_rpc)
321 if test "$link_obsolete_rpc" = yes; then
322 AC_DEFINE(LINK_OBSOLETE_RPC)
323 fi
325 AC_ARG_ENABLE([systemtap],
326 [AS_HELP_STRING([--enable-systemtap],
327 [enable systemtap static probe points @<:@default=no@:>@])],
328 [systemtap=$enableval],
329 [systemtap=no])
330 if test "x$systemtap" != xno; then
331 AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
332 old_CFLAGS="$CFLAGS"
333 CFLAGS="-std=gnu99 $CFLAGS"
334 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
335 void foo (int i, void *p)
336 {
337 asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
338 :: STAP_PROBE_ASM_OPERANDS (2, i, p));
339 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
340 CFLAGS="$old_CFLAGS"])
341 if test $libc_cv_sdt = yes; then
342 AC_DEFINE([USE_STAP_PROBE])
343 elif test "x$systemtap" != xauto; then
344 AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
345 fi
346 fi
348 AC_ARG_ENABLE([build-nscd],
349 [AS_HELP_STRING([--disable-build-nscd],
350 [disable building and installing the nscd daemon])],
351 [build_nscd=$enableval],
352 [build_nscd=default])
353 AC_SUBST(build_nscd)
355 # Note the use of $use_nscd is near the bottom of the file.
356 AC_ARG_ENABLE([nscd],
357 [AS_HELP_STRING([--disable-nscd],
358 [library functions will not contact the nscd daemon])],
359 [use_nscd=$enableval],
360 [use_nscd=yes])
362 AC_ARG_ENABLE([pt_chown],
363 [AS_HELP_STRING([--enable-pt_chown],
364 [Enable building and installing pt_chown])],
365 [build_pt_chown=$enableval],
366 [build_pt_chown=no])
367 AC_SUBST(build_pt_chown)
368 if test "$build_pt_chown" = yes; then
369 AC_DEFINE(HAVE_PT_CHOWN)
370 fi
372 # The abi-tags file uses a fairly simplistic model for name recognition that
373 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu. So we mutate a
374 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
375 # This doesn't get used much beyond that, so it's fairly safe.
376 case "$host_os" in
377 linux*)
378 ;;
379 gnu*)
380 host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
381 ;;
382 esac
384 # We keep the original values in `$config_*' and never modify them, so we
385 # can write them unchanged into config.make. Everything else uses
386 # $machine, $vendor, and $os, and changes them whenever convenient.
387 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
389 # Don't allow vendor == "unknown"
390 test "$config_vendor" = unknown && config_vendor=
391 config_os="`echo $config_os | sed 's/^unknown-//'`"
393 # Some configurations imply other options.
394 elf=yes
396 # The configure fragment of an add-on port can modify these to supplement
397 # or override the table in the case statement below. No fragment should
398 # ever change the config_* variables, however.
399 machine=$config_machine
400 vendor=$config_vendor
401 os=$config_os
402 base_os=''
404 submachine=
405 AC_ARG_WITH([cpu],
406 AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
407 [dnl
408 case "$withval" in
409 yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
410 no) ;;
411 *) submachine="$withval" ;;
412 esac
413 ])
415 # An preconfigure script can set this when it wants to disable the sanity
416 # check below.
417 libc_config_ok=no
419 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
420 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
422 dnl Having this here, though empty, makes sure that if add-ons' fragments
423 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
424 dnl our AC_OUTPUT will actually use it.
425 AC_CONFIG_SUBDIRS()
427 case "$enable_add_ons" in
428 ''|no) add_ons= ;;
429 yes|'*')
430 add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
431 sed 's@/[[^/]]*$@@' | sort | uniq`
432 add_ons_automatic=yes
433 ;;
434 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
435 add_ons_automatic=no ;;
436 esac
438 configured_add_ons=
439 add_ons_sfx=
440 add_ons_pfx=
441 if test x"$add_ons" != x; then
442 for f in $add_ons; do
443 # Some sanity checks
444 case "$f" in
445 crypt)
446 AC_MSG_ERROR([
447 *** It seems that you're using an old \`crypt' add-on. crypt is now
448 *** part of glibc and using the old add-on will not work with this
449 *** release. Start again with fresh sources and without the old
450 *** \`crypt' add-on.])
451 ;;
452 localedata)
453 AC_MSG_ERROR([
454 *** It seems that you're using an old \`localedata' add-on. localedata
455 *** is now part of glibc and using the old add-on will not work with
456 *** this release. Start again with fresh sources and without the old
457 *** \`localedata' add-on.])
458 ;;
459 esac
460 done
462 # Now source each add-on's configure fragment.
463 # The fragments can use $srcdir/$libc_add_on to find themselves,
464 # and test $add_ons_automatic to see if they were explicitly requested.
465 # A fragment can clear (or even change) $libc_add_on to affect
466 # whether it goes into the list to be actually used in the build.
467 use_add_ons=
468 for libc_add_on in $add_ons; do
469 # Test whether such a directory really exists.
470 # It can be absolute, or relative to $srcdir, or relative to the build dir.
471 case "$libc_add_on" in
472 /*)
473 libc_add_on_srcdir=$libc_add_on
474 ;;
475 *)
476 test -d "$srcdir/$libc_add_on" || {
477 if test -d "$libc_add_on"; then
478 libc_add_on="`pwd`/$libc_add_on"
479 else
480 AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
481 fi
482 }
483 libc_add_on_srcdir=$srcdir/$libc_add_on
484 ;;
485 esac
487 libc_add_on_frag=$libc_add_on_srcdir/configure
488 libc_add_on_canonical=
489 libc_add_on_config_subdirs=
490 if test -r "$libc_add_on_frag"; then
491 AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
492 libc_add_on_canonical=unknown
493 libc_add_on_subdirs=
494 . "$libc_add_on_frag"
495 test -z "$libc_add_on" || {
496 configured_add_ons="$configured_add_ons $libc_add_on"
497 if test "x$libc_add_on_canonical" = xunknown; then
498 AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
499 fi
500 for d in $libc_add_on_subdirs; do
501 case "$libc_add_on" in
502 /*) subdir_srcdir="$libc_add_on" ;;
503 *) subdir_srcdir="\$(..)$libc_add_on" ;;
504 esac
505 case "$d" in
506 .)
507 d="${libc_add_on_canonical:-$libc_add_on}"
508 ;;
509 /*)
510 subdir_srcdir="$d"
511 ;;
512 *)
513 subdir_srcdir="$subdir_srcdir/$d"
514 ;;
515 esac
516 d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
517 add_on_subdirs="$add_on_subdirs $d"
518 test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
519 $d-srcdir = $subdir_srcdir"
520 done
521 for d in $libc_add_on_config_subdirs; do
522 case "$d" in
523 /*) AC_MSG_ERROR(dnl
524 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
525 esac
526 if test ! -d "$libc_add_on_srcdir/$d"; then
527 AC_MSG_ERROR(fragment wants to configure missing directory $d)
528 fi
529 case "$libc_add_on" in
530 /*) AC_MSG_ERROR(dnl
531 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
532 esac
533 subdirs="$subdirs $libc_add_on/$d"
534 done
535 }
536 fi
537 if test -n "$libc_add_on"; then
538 LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
539 use_add_ons="$use_add_ons $libc_add_on"
540 add_ons_pfx="$add_ons_pfx $libc_add_on/"
541 test -z "$libc_add_on_canonical" ||
542 add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
543 fi
544 done
545 # Use echo to strip excess whitespace.
546 add_ons="`echo $use_add_ons`"
547 fi
548 AC_SUBST(add_ons)
549 AC_SUBST(add_on_subdirs)
552 ###
553 ### I put this here to prevent those annoying emails from people who cannot
554 ### read and try to compile glibc on unsupported platforms. --drepper
555 ###
556 ### By using the undocumented --enable-hacker-mode option for configure
557 ### one can skip this test to make the configuration not fail for unsupported
558 ### platforms.
559 ###
560 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
561 case "$machine-$host_os" in
562 *-linux* | *-gnu*)
563 ;;
564 *)
565 echo "*** The GNU C library is currently not available for this platform."
566 echo "*** So far nobody cared to port it and if there is no volunteer it"
567 echo "*** might never happen. So, if you have interest to see glibc on"
568 echo "*** this platform visit"
569 echo "*** http://www.gnu.org/software/libc/porting.html"
570 echo "*** and join the group of porters"
571 exit 1
572 ;;
573 esac
574 fi
576 # Set base_machine if not set by a preconfigure fragment.
577 test -n "$base_machine" || base_machine=$machine
578 AC_SUBST(base_machine)
580 # For the multi-arch option we need support in the assembler & linker.
581 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
582 libc_cv_ld_gnu_indirect_function, [dnl
583 cat > conftest.S <<EOF
584 .type foo,%gnu_indirect_function
585 foo:
586 .globl _start
587 _start:
588 .globl __start
589 __start:
590 .data
591 #ifdef _LP64
592 .quad foo
593 #else
594 .long foo
595 #endif
596 EOF
597 libc_cv_ld_gnu_indirect_function=no
598 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
599 -nostartfiles -nostdlib \
600 -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
601 # Do a link to see if the backend supports IFUNC relocs.
602 $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
603 LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
604 libc_cv_ld_gnu_indirect_function=yes
605 }
606 fi
607 rm -f conftest*])
609 AC_MSG_CHECKING(whether .text pseudo-op must be used)
610 AC_CACHE_VAL(libc_cv_dot_text, [dnl
611 cat > conftest.s <<EOF
612 .text
613 EOF
614 libc_cv_dot_text=
615 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
616 libc_cv_dot_text=.text
617 fi
618 rm -f conftest*])
619 if test -z "$libc_cv_dot_text"; then
620 AC_MSG_RESULT(no)
621 else
622 AC_MSG_RESULT(yes)
623 fi
625 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
626 if test x"$multi_arch" = xyes; then
627 AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
628 else
629 multi_arch=no
630 fi
631 fi
632 multi_arch_d=
633 if test x"$multi_arch" != xno; then
634 multi_arch_d=/multiarch
635 fi
637 # Compute the list of sysdep directories for this configuration.
638 # This can take a while to compute.
639 sysdep_dir=$srcdir/sysdeps
640 AC_MSG_CHECKING(sysdep dirs)
641 dnl We need to use [ and ] for other purposes for a while now.
642 changequote(,)dnl
643 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
644 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
646 test "x$base_os" != x || case "$os" in
647 gnu*)
648 base_os=mach/hurd ;;
649 linux*)
650 base_os=unix/sysv ;;
651 esac
653 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
654 tail=$os
655 ostry=$os
656 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
657 ostry="$ostry /$o"
658 tail=$o
659 done
660 o=`echo $tail | sed 's/[0-9]*$//'`
661 if test $o != $tail; then
662 ostry="$ostry /$o"
663 fi
664 # For linux-gnu, try linux-gnu, then linux.
665 o=`echo $tail | sed 's/-.*$//'`
666 if test $o != $tail; then
667 ostry="$ostry /$o"
668 fi
670 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
671 base=
672 tail=$base_os
673 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
674 set $b
675 base="$base /$1"
676 tail="$2"
677 done
679 # For sparc/sparc32, try sparc/sparc32 and then sparc.
680 mach=
681 tail=$machine${submachine:+/$submachine}
682 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
683 set $m
684 # Prepend the machine's FPU directory unless --without-fp.
685 if test "$with_fp" = yes; then
686 maybe_fpu=/fpu
687 else
688 maybe_fpu=/nofpu
689 fi
690 # For each machine term, try it with and then without /multiarch.
691 for try_fpu in $maybe_fpu ''; do
692 for try_multi in $multi_arch_d ''; do
693 mach="$mach /$1$try_fpu$try_multi"
694 done
695 done
696 tail="$2"
697 done
699 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
700 changequote([,])dnl
702 # Find what sysdep directories exist.
703 sysnames_add_ons=
704 sysnames=
705 for b in $base ''; do
706 for m0 in $mach ''; do
707 for v in /$vendor ''; do
708 test "$v" = / && continue
709 for o in /$ostry ''; do
710 test "$o" = / && continue
711 for m in $mach ''; do
712 for d in $add_ons_pfx ''; do
713 for a in $add_ons_sfx ''; do
714 try_suffix="$m0$b$v$o$m"
715 if test -n "$try_suffix"; then
716 try_srcdir="${srcdir}/"
717 case "$d" in
718 /*) try_srcdir= ;;
719 esac
720 try="${d}sysdeps$try_suffix$a"
721 test -n "$enable_debug_configure" &&
722 echo "$0 [DEBUG]: try $try" >&2
723 if test -d "$try_srcdir$try"; then
724 sysnames="$sysnames $try"
725 { test -n "$o" || test -n "$b"; } && os_used=t
726 { test -n "$m" || test -n "$m0"; } && machine_used=t
727 case x${m0:-$m} in
728 x*/$submachine) submachine_used=t ;;
729 esac
730 if test -n "$d"; then
731 case "$sysnames_add_ons" in
732 *" $d "*) ;;
733 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
734 esac
735 fi
736 fi
737 fi
738 done
739 done
740 done
741 done
742 done
743 done
744 done
746 # If the assembler supports gnu_indirect_function symbol type and the
747 # architecture supports multi-arch, we enable multi-arch by default.
748 case $sysnames_add_ons$sysnames in
749 *"$multi_arch_d"*)
750 ;;
751 *)
752 test x"$multi_arch" = xdefault && multi_arch=no
753 ;;
754 esac
755 if test x"$multi_arch" != xno; then
756 AC_DEFINE(USE_MULTIARCH)
757 fi
758 AC_SUBST(multi_arch)
760 if test -z "$os_used" && test "$os" != none; then
761 AC_MSG_ERROR(Operating system $os is not supported.)
762 fi
763 if test -z "$machine_used" && test "$machine" != none; then
764 AC_MSG_ERROR(The $machine is not supported.)
765 fi
766 if test -z "$submachine_used" && test -n "$submachine"; then
767 AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
768 fi
769 AC_SUBST(submachine)
771 # We have now validated the configuration.
773 # Expand the list of system names into a full list of directories
774 # from each element's parent name and Implies file (if present).
775 set $sysnames
776 names=
777 while test $# -gt 0; do
778 name=$1
779 shift
781 case " $names " in *" $name "*)
782 # Already in the list.
783 continue
784 esac
786 # Report each name as we discover it, so there is no long pause in output.
787 echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
789 name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
791 case $name in
792 /*) xsrcdir= ;;
793 *) xsrcdir=$srcdir/ ;;
794 esac
795 test -n "$enable_debug_configure" &&
796 echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
798 for implies_file in Implies Implies-before Implies-after; do
799 implies_type=`echo $implies_file | sed s/-/_/`
800 eval ${implies_type}=
801 if test -f $xsrcdir$name/$implies_file; then
802 # Collect more names from the `Implies' file (removing comments).
803 implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
804 for x in $implied_candidate; do
805 found=no
806 if test -d $xsrcdir$name_base/$x; then
807 eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
808 found=yes
809 fi
810 for d in $add_ons_pfx ''; do
811 try="${d}sysdeps/$x"
812 case $d in
813 /*) try_srcdir= ;;
814 *) try_srcdir=$srcdir/ ;;
815 esac
816 test -n "$enable_debug_configure" &&
817 echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
818 if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
819 then
820 eval "${implies_type}=\"\$${implies_type} \$try\""
821 found=yes
822 case "$sysnames_add_ons" in
823 *" $d "*) ;;
824 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
825 esac
826 fi
827 done
828 if test $found = no; then
829 AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
830 fi
831 done
832 fi
833 done
835 # Add NAME to the list of names.
836 names="$names $name"
838 # Find the parent of NAME, using the empty string if it has none.
839 changequote(,)dnl
840 parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
841 changequote([,])dnl
843 test -n "$enable_debug_configure" &&
844 echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
845 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
847 # Add the names implied by NAME, and NAME's parent (if it has one), to
848 # the list of names to be processed (the argument list). We prepend the
849 # implied names to the list and append the parent. We want implied
850 # directories to come before further directories inferred from the
851 # configuration components; this ensures that for sysv4, unix/common
852 # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
853 # after sysv4).
854 sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
855 test -n "$sysnames" && set $sysnames
856 done
858 # Add the default directories.
859 default_sysnames="sysdeps/generic"
860 sysnames="$names $default_sysnames"
861 AC_SUBST(sysnames)
862 # The other names were emitted during the scan.
863 AC_MSG_RESULT($default_sysnames)
865 # Collect the list of add-ons that supply partial sysdeps trees.
866 sysdeps_add_ons=
867 for add_on in $add_ons; do
868 case "$add_on" in
869 /*) xsrcdir= ;;
870 *) xsrcdir="$srcdir/" ;;
871 esac
873 test -d "$xsrcdir$add_on/sysdeps" || {
874 case "$configured_add_ons " in
875 *" $add_on "*) ;;
876 *|'')
877 AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
878 ;;
879 esac
880 continue
881 }
883 sysdeps_add_ons="$sysdeps_add_ons $add_on"
884 case "$sysnames_add_ons" in
885 *" $add_on/ "*) ;;
886 *|'')
887 AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
888 continue ;;
889 esac
891 found=no
892 for d in $sysnames; do
893 case "$d" in
894 $add_on/sysdeps/*) ;;
895 *) continue ;;
896 esac
897 (cd "$xsrcdir$d" && for f in *[[!~]]; do
898 case "$f" in
899 sys|bits)
900 for ff in $f/*.h; do
901 test -d "$ff" || { test -e "$ff" && exit 88; }
902 done
903 ;;
904 *)
905 test -d "$f" || { test -e "$f" && exit 88; }
906 ;;
907 esac
908 done)
909 if test $? -eq 88; then
910 found=yes
911 break
912 fi
913 done
914 if test $found = no; then
915 AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
916 fi
917 done
918 AC_SUBST(sysdeps_add_ons)
921 ### Locate tools.
923 AC_PROG_INSTALL
924 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
925 # The makefiles need to use a different form to find it in $srcdir.
926 INSTALL='\$(..)./scripts/install-sh -c'
927 fi
928 AC_PROG_LN_S
930 LIBC_PROG_BINUTILS
932 # Accept binutils 2.22 or newer.
933 AC_CHECK_PROG_VER(AS, $AS, --version,
934 [GNU assembler.* \([0-9]*\.[0-9.]*\)],
935 [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
936 AS=: critic_missing="$critic_missing as")
937 AC_CHECK_PROG_VER(LD, $LD, --version,
938 [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
939 [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
940 LD=: critic_missing="$critic_missing ld")
942 # These programs are version sensitive.
943 AC_CHECK_TOOL_PREFIX
944 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
945 [GNU Make[^0-9]*\([0-9][0-9.]*\)],
946 [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
948 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
949 [GNU gettext.* \([0-9]*\.[0-9.]*\)],
950 [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
951 MSGFMT=: aux_missing="$aux_missing msgfmt")
952 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
953 [GNU texinfo.* \([0-9][0-9.]*\)],
954 [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
955 MAKEINFO=: aux_missing="$aux_missing makeinfo")
956 AC_CHECK_PROG_VER(SED, sed, --version,
957 [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
958 [3.0[2-9]*|3.[1-9]*|[4-9]*],
959 SED=: aux_missing="$aux_missing sed")
960 AC_CHECK_PROG_VER(AWK, gawk, --version,
961 [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
962 [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
964 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
965 AC_TRY_COMPILE([], [
966 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6)
967 #error insufficient compiler
968 #endif],
969 [libc_cv_compiler_ok=yes],
970 [libc_cv_compiler_ok=no])])
971 AS_IF([test $libc_cv_compiler_ok != yes],
972 [critic_missing="$critic_missing compiler"])
974 AC_CHECK_TOOL(NM, nm, false)
976 if test "x$maintainer" = "xyes"; then
977 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
978 case "x$AUTOCONF" in
979 xno|x|x:) AUTOCONF=no ;;
980 *)
981 AC_CACHE_CHECK(dnl
982 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
983 if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
984 libc_cv_autoconf_works=yes
985 else
986 libc_cv_autoconf_works=no
987 fi])
988 test $libc_cv_autoconf_works = yes || AUTOCONF=no
989 ;;
990 esac
991 if test "x$AUTOCONF" = xno; then
992 aux_missing="$aux_missing autoconf"
993 fi
994 else
995 AUTOCONF=no
996 fi
998 test -n "$critic_missing" && AC_MSG_ERROR([
999 *** These critical programs are missing or too old:$critic_missing
1000 *** Check the INSTALL file for required versions.])
1002 test -n "$aux_missing" && AC_MSG_WARN([
1003 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1004 *** some features will be disabled.
1005 *** Check the INSTALL file for required versions.])
1007 # if using special system headers, find out the compiler's sekrit
1008 # header directory and add that to the list. NOTE: Only does the right
1009 # thing on a system that doesn't need fixincludes. (Not presently a problem.)
1010 if test -n "$sysheaders"; then
1011 SYSINCLUDES=-nostdinc
1012 for d in include include-fixed; do
1013 i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1014 SYSINCLUDES="$SYSINCLUDES -isystem $i"
1015 done
1016 SYSINCLUDES="$SYSINCLUDES \
1017 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1018 if test -n "$CXX"; then
1019 CXX_SYSINCLUDES=
1020 for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1021 | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1022 test "x$cxxheaders" != x &&
1023 CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1024 done
1025 fi
1026 fi
1027 AC_SUBST(SYSINCLUDES)
1028 AC_SUBST(CXX_SYSINCLUDES)
1030 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1031 # since this would lead to problems installing/building glibc.
1032 # LD_LIBRARY_PATH contains the current directory if one of the following
1033 # is true:
1034 # - one of the terminals (":" and ";") is the first or last sign
1035 # - two terminals occur directly after each other
1036 # - the path contains an element with a dot in it
1037 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1038 changequote(,)dnl
1039 case ${LD_LIBRARY_PATH} in
1040 [:\;]* | *[:\;] | *[:\;][:\;]* | *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1041 ld_library_path_setting="contains current directory"
1042 ;;
1043 *)
1044 ld_library_path_setting="ok"
1045 ;;
1046 esac
1047 changequote([,])dnl
1048 AC_MSG_RESULT($ld_library_path_setting)
1049 if test "$ld_library_path_setting" != "ok"; then
1050 AC_MSG_ERROR([
1051 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1052 *** building glibc. Please change the environment variable
1053 *** and run configure again.])
1054 fi
1056 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1057 if $CC -v -static-libgcc 2>&1 | grep 'unrecognized option.*static-libgcc' >/dev/null; then
1058 libc_cv_gcc_static_libgcc=
1059 else
1060 libc_cv_gcc_static_libgcc=-static-libgcc
1061 fi])
1062 AC_SUBST(libc_cv_gcc_static_libgcc)
1064 AC_PATH_PROG(BASH_SHELL, bash, no)
1066 AC_PATH_PROG(PERL, perl, no)
1067 if test "$PERL" != no &&
1068 (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1069 PERL=no
1070 fi
1071 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1072 $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1073 AC_CHECK_PROG_VER(BISON, bison, --version,
1074 [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1075 [2.7*|[3-9].*|[1-9][0-9]*],
1076 BISON=no)
1078 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1079 AC_TRY_COMPILE(dnl
1080 [#define __need_size_t
1081 #define __need_wchar_t
1082 #include <stddef.h>
1083 #define __need_NULL
1084 #include <stddef.h>], [size_t size; wchar_t wchar;
1085 #ifdef offsetof
1086 #error stddef.h ignored __need_*
1087 #endif
1088 if (&size == NULL || &wchar == NULL) abort ();],
1089 libc_cv_friendly_stddef=yes,
1090 libc_cv_friendly_stddef=no)])
1091 if test $libc_cv_friendly_stddef = yes; then
1092 config_vars="$config_vars
1093 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1094 fi
1096 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1097 libc_cv_need_minus_P, [dnl
1098 cat > conftest.S <<EOF
1099 #include "confdefs.h"
1100 /* Nothing whatsoever. */
1101 EOF
1102 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1103 libc_cv_need_minus_P=no
1104 else
1105 libc_cv_need_minus_P=yes
1106 fi
1107 rm -f conftest*])
1108 if test $libc_cv_need_minus_P = yes; then
1109 config_vars="$config_vars
1110 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1111 fi
1113 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1114 cat > conftest.s <<EOF
1115 ${libc_cv_dot_text}
1116 foo:
1117 .set glibc_conftest_frobozz,foo
1118 .globl glibc_conftest_frobozz
1119 EOF
1120 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1121 # (but it doesn't work), so we must do a linking check to be sure.
1122 cat > conftest1.c <<\EOF
1123 extern int glibc_conftest_frobozz;
1124 void _start() { glibc_conftest_frobozz = 1; }
1125 EOF
1126 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1127 -nostartfiles -nostdlib \
1128 -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1129 libc_cv_asm_set_directive=yes
1130 else
1131 libc_cv_asm_set_directive=no
1132 fi
1133 rm -f conftest*])
1134 if test $libc_cv_asm_set_directive = yes; then
1135 AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1136 fi
1138 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1139 libc_cv_asm_unique_object, [dnl
1140 cat > conftest.s <<EOF
1141 ${libc_cv_dot_text}
1142 _sym:
1143 .type _sym, %gnu_unique_object
1144 EOF
1145 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1146 libc_cv_asm_unique_object=yes
1147 else
1148 libc_cv_asm_unique_object=no
1149 fi
1150 rm -f conftest*])
1151 if test $libc_cv_asm_unique_object = yes; then
1152 AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1153 fi
1155 AC_CACHE_CHECK(for .previous assembler directive,
1156 libc_cv_asm_previous_directive, [dnl
1157 cat > conftest.s <<EOF
1158 .section foo_section
1159 .previous
1160 EOF
1161 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1162 libc_cv_asm_previous_directive=yes
1163 else
1164 libc_cv_asm_previous_directive=no
1165 fi
1166 rm -f conftest*])
1167 if test $libc_cv_asm_previous_directive = yes; then
1168 AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1169 else
1170 AC_CACHE_CHECK(for .popsection assembler directive,
1171 libc_cv_asm_popsection_directive, [dnl
1172 cat > conftest.s <<EOF
1173 .pushsection foo_section
1174 .popsection
1175 EOF
1176 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1177 libc_cv_asm_popsection_directive=yes
1178 else
1179 libc_cv_asm_popsection_directive=no
1180 fi
1181 rm -f conftest*])
1182 if test $libc_cv_asm_popsection_directive = yes; then
1183 AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1184 fi
1185 fi
1186 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1187 libc_cv_asm_protected_directive, [dnl
1188 cat > conftest.s <<EOF
1189 .protected foo
1190 foo:
1191 .hidden bar
1192 bar:
1193 EOF
1194 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1195 libc_cv_asm_protected_directive=yes
1196 else
1197 AC_MSG_ERROR(assembler support for symbol visibility is required)
1198 fi
1199 rm -f conftest*])
1201 if test $libc_cv_asm_protected_directive = yes; then
1202 AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1203 libc_cv_visibility_attribute,
1204 [cat > conftest.c <<EOF
1205 int foo __attribute__ ((visibility ("hidden"))) = 1;
1206 int bar __attribute__ ((visibility ("protected"))) = 1;
1207 EOF
1208 libc_cv_visibility_attribute=no
1209 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1210 if grep '\.hidden.*foo' conftest.s >/dev/null; then
1211 if grep '\.protected.*bar' conftest.s >/dev/null; then
1212 libc_cv_visibility_attribute=yes
1213 fi
1214 fi
1215 fi
1216 rm -f conftest.{c,s}
1217 ])
1218 if test $libc_cv_visibility_attribute != yes; then
1219 AC_MSG_ERROR(compiler support for visibility attribute is required)
1220 fi
1221 fi
1223 if test $libc_cv_visibility_attribute = yes; then
1224 AC_CACHE_CHECK(linker support for protected data symbol,
1225 libc_cv_protected_data,
1226 [cat > conftest.c <<EOF
1227 int bar __attribute__ ((visibility ("protected"))) = 1;
1228 EOF
1229 libc_cv_protected_data=no
1230 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles -fPIC -shared conftest.c -o conftest.so); then
1231 cat > conftest.c <<EOF
1232 extern int bar;
1233 int main (void) { return bar; }
1234 EOF
1235 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles conftest.c -o conftest conftest.so); then
1236 libc_cv_protected_data=yes
1237 fi
1238 fi
1239 rm -f conftest.*
1240 ])
1241 else
1242 libc_cv_protected_data=no
1243 fi
1244 AC_SUBST(libc_cv_protected_data)
1246 if test $libc_cv_visibility_attribute = yes; then
1247 AC_CACHE_CHECK(for broken __attribute__((visibility())),
1248 libc_cv_broken_visibility_attribute,
1249 [cat > conftest.c <<EOF
1250 int foo (int x);
1251 int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1252 int bar (int x) { return x; }
1253 EOF
1254 libc_cv_broken_visibility_attribute=yes
1255 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1256 changequote(,)dnl
1257 if grep '\.hidden[ _]foo' conftest.s >/dev/null; then
1258 changequote([,])dnl
1259 libc_cv_broken_visibility_attribute=no
1260 fi
1261 fi
1262 rm -f conftest.c conftest.s
1263 ])
1264 if test $libc_cv_broken_visibility_attribute = yes; then
1265 AC_MSG_ERROR(working compiler support for visibility attribute is required)
1266 fi
1267 fi
1269 AC_CACHE_CHECK(for broken __attribute__((alias())),
1270 libc_cv_broken_alias_attribute,
1271 [cat > conftest.c <<EOF
1272 extern int foo (int x) __asm ("xyzzy");
1273 int bar (int x) { return x; }
1274 extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1275 extern int dfoo;
1276 extern __typeof (dfoo) dfoo __asm ("abccb");
1277 int dfoo = 1;
1278 EOF
1279 libc_cv_broken_alias_attribute=yes
1280 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1281 if grep 'xyzzy' conftest.s >/dev/null &&
1282 grep 'abccb' conftest.s >/dev/null; then
1283 libc_cv_broken_alias_attribute=no
1284 fi
1285 fi
1286 rm -f conftest.c conftest.s
1287 ])
1288 if test $libc_cv_broken_alias_attribute = yes; then
1289 AC_MSG_ERROR(working alias attribute support required)
1290 fi
1292 if test $libc_cv_visibility_attribute = yes; then
1293 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1294 libc_cv_have_sdata_section,
1295 [echo "int i;" > conftest.c
1296 libc_cv_have_sdata_section=no
1297 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1298 | grep '\.sdata' >/dev/null; then
1299 libc_cv_have_sdata_section=yes
1300 fi
1301 rm -f conftest.c conftest.so
1302 ])
1303 if test $libc_cv_have_sdata_section = yes; then
1304 AC_DEFINE(HAVE_SDATA_SECTION)
1305 fi
1306 fi
1308 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1309 libc_cv_initfini_array, [dnl
1310 LIBC_TRY_LINK_STATIC([
1311 int foo (void) { return 1; }
1312 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1313 ],
1314 [if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1315 libc_cv_initfini_array=yes
1316 else
1317 libc_cv_initfini_array=no
1318 fi],
1319 [libc_cv_initfini_array=no])
1320 ])
1321 if test $libc_cv_initfini_array != yes; then
1322 AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1323 fi
1325 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1326 libc_cv_ctors_header, [dnl
1327 libc_cv_ctors_header=yes
1328 LIBC_TRY_LINK_STATIC([
1329 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1330 __attribute__ ((destructor)) void dtor (void) { asm (""); }
1331 ],
1332 [dnl
1333 AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1334 { gsub(/\@<:@ */, "@<:@") }
1335 $2 == ".ctors" || $2 == ".dtors" {
1336 size = strtonum("0x" $6)
1337 align = strtonum("0x" $NF)
1338 seen@<:@$2@:>@ = 1
1339 stub@<:@$2@:>@ = size == align * 2
1340 }
1341 END {
1342 ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1343 dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1344 exit ((ctors_ok && dtors_ok) ? 0 : 1)
1345 }
1346 '], [libc_cv_ctors_header=no])
1347 ], [dnl
1348 AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1349 ])
1350 ])
1351 if test $libc_cv_ctors_header = no; then
1352 AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1353 fi
1355 AC_CACHE_CHECK(for libunwind-support in compiler,
1356 libc_cv_cc_with_libunwind, [
1357 cat > conftest.c <<EOF
1358 int main (void) { return 0; }
1359 EOF
1360 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1361 conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1362 libc_cv_cc_with_libunwind=yes
1363 else
1364 libc_cv_cc_with_libunwind=no
1365 fi
1366 rm -f conftest*])
1367 AC_SUBST(libc_cv_cc_with_libunwind)
1368 if test $libc_cv_cc_with_libunwind = yes; then
1369 AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1370 fi
1372 LIBC_LINKER_FEATURE([-z nodelete], [-Wl,--enable-new-dtags,-z,nodelete],
1373 [libc_cv_z_nodelete=yes],
1374 [AC_MSG_ERROR(linker with -z nodelete support required)])
1376 LIBC_LINKER_FEATURE([-z nodlopen], [-Wl,--enable-new-dtags,-z,nodlopen],
1377 [libc_cv_z_nodlopen=yes],
1378 [AC_MSG_ERROR(linker with -z nodlopen support required)])
1380 LIBC_LINKER_FEATURE([-z initfirst], [-Wl,--enable-new-dtags,-z,initfirst],
1381 [libc_cv_z_initfirst=yes],
1382 [AC_MSG_ERROR(linker with -z initfirst support required)])
1384 AC_CACHE_CHECK(for -Bgroup option,
1385 libc_cv_Bgroup, [dnl
1386 cat > conftest.c <<EOF
1387 int _start (void) { return 42; }
1388 EOF
1389 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1390 -fPIC -shared -o conftest.so conftest.c
1391 -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1392 then
1393 libc_cv_Bgroup=yes
1394 else
1395 libc_cv_Bgroup=no
1396 fi
1397 rm -f conftest*])
1398 AC_SUBST(libc_cv_Bgroup)
1400 ASFLAGS_config=
1401 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1402 libc_cv_as_noexecstack, [dnl
1403 cat > conftest.c <<EOF
1404 void foo (void) { }
1405 EOF
1406 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1407 -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1408 && grep .note.GNU-stack conftest.s >/dev/null \
1409 && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1410 -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1411 then
1412 libc_cv_as_noexecstack=yes
1413 else
1414 libc_cv_as_noexecstack=no
1415 fi
1416 rm -f conftest*])
1417 if test $libc_cv_as_noexecstack = yes; then
1418 ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1419 fi
1420 AC_SUBST(ASFLAGS_config)
1422 AC_CACHE_CHECK(for -z combreloc,
1423 libc_cv_z_combreloc, [dnl
1424 cat > conftest.c <<EOF
1425 extern int bar (int);
1426 extern int mumble;
1427 int foo (void) { return bar (mumble); }
1428 EOF
1429 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1430 -fPIC -shared -o conftest.so conftest.c
1431 -nostdlib -nostartfiles
1432 -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1433 then
1434 dnl The following test is a bit weak. We must use a tool which can test
1435 dnl cross-platform since the gcc used can be a cross compiler. Without
1436 dnl introducing new options this is not easily doable. Instead use a tool
1437 dnl which always is cross-platform: readelf. To detect whether -z combreloc
1438 dnl look for a section named .rel.dyn.
1439 if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1440 libc_cv_z_combreloc=yes
1441 else
1442 libc_cv_z_combreloc=no
1443 fi
1444 else
1445 libc_cv_z_combreloc=no
1446 fi
1447 rm -f conftest*])
1448 if test "$libc_cv_z_combreloc" = yes; then
1449 AC_DEFINE(HAVE_Z_COMBRELOC)
1450 fi
1451 AC_SUBST(libc_cv_z_combreloc)
1453 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1454 [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1455 AC_SUBST(libc_cv_z_execstack)
1457 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1458 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1459 ])
1461 AC_SUBST(libc_cv_fpie)
1463 AC_CACHE_CHECK(for --hash-style option,
1464 libc_cv_hashstyle, [dnl
1465 cat > conftest.c <<EOF
1466 int _start (void) { return 42; }
1467 EOF
1468 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1469 -fPIC -shared -o conftest.so conftest.c
1470 -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1471 then
1472 libc_cv_hashstyle=yes
1473 else
1474 libc_cv_hashstyle=no
1475 fi
1476 rm -f conftest*])
1477 AC_SUBST(libc_cv_hashstyle)
1479 # The linker's default -shared behavior is good enough if it
1480 # does these things that our custom linker scripts ensure that
1481 # all allocated NOTE sections come first.
1482 if test "$use_default_link" = default; then
1483 AC_CACHE_CHECK([for sufficient default -shared layout],
1484 libc_cv_use_default_link, [dnl
1485 libc_cv_use_default_link=no
1486 cat > conftest.s <<\EOF
1487 .section .note.a,"a",%note
1488 .balign 4
1489 .long 4,4,9
1490 .string "GNU"
1491 .string "foo"
1492 .section .note.b,"a",%note
1493 .balign 4
1494 .long 4,4,9
1495 .string "GNU"
1496 .string "bar"
1497 EOF
1498 if AC_TRY_COMMAND([dnl
1499 ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1500 ac_try=`$READELF -S conftest.so | sed -n \
1501 ['${x;p;}
1502 s/^ *\[ *[1-9][0-9]*\] *\([^ ][^ ]*\) *\([^ ][^ ]*\) .*$/\2 \1/
1503 t a
1504 b
1505 : a
1506 H']`
1507 then
1508 libc_seen_a=no libc_seen_b=no
1509 set -- $ac_try
1510 while test $# -ge 2 -a "$1" = NOTE; do
1511 case "$2" in
1512 .note.a) libc_seen_a=yes ;;
1513 .note.b) libc_seen_b=yes ;;
1514 esac
1515 shift 2
1516 done
1517 case "$libc_seen_a$libc_seen_b" in
1518 yesyes)
1519 libc_cv_use_default_link=yes
1520 ;;
1521 *)
1522 echo >&AS_MESSAGE_LOG_FD "\
1523 $libc_seen_a$libc_seen_b from:
1524 $ac_try"
1525 ;;
1526 esac
1527 fi
1528 rm -f conftest*])
1529 use_default_link=$libc_cv_use_default_link
1530 fi
1532 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1533 if libc_cv_output_format=`
1534 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1535 then
1536 :
1537 else
1538 libc_cv_output_format=
1539 fi
1540 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1541 AC_SUBST(libc_cv_output_format)
1543 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1544 cat > conftest.c <<EOF
1545 int foo;
1546 EOF
1547 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1548 conftest.c 1>&AS_MESSAGE_LOG_FD])
1549 then
1550 libc_cv_fno_toplevel_reorder=yes
1551 else
1552 libc_cv_fno_toplevel_reorder=no
1553 fi
1554 rm -f conftest*])
1555 if test $libc_cv_fno_toplevel_reorder = yes; then
1556 fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1557 else
1558 fno_unit_at_a_time=-fno-unit-at-a-time
1559 fi
1560 AC_SUBST(fno_unit_at_a_time)
1562 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1563 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1564 [libc_cv_ssp=yes],
1565 [libc_cv_ssp=no])
1566 ])
1567 AC_SUBST(libc_cv_ssp)
1569 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1570 cat > conftest.c <<EOF
1571 int foo;
1572 #ifdef __GNUC_GNU_INLINE__
1573 main () { return 0;}
1574 #else
1575 #error
1576 #endif
1577 EOF
1578 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1579 -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1580 then
1581 libc_cv_gnu89_inline=yes
1582 else
1583 libc_cv_gnu89_inline=no
1584 fi
1585 rm -f conftest*])
1586 if test $libc_cv_gnu89_inline = yes; then
1587 gnu89_inline=-fgnu89-inline
1588 else
1589 gnu89_inline=
1590 fi
1591 AC_SUBST(gnu89_inline)
1593 AC_CACHE_CHECK(whether cc puts quotes around section names,
1594 libc_cv_have_section_quotes,
1595 [cat > conftest.c <<EOF
1596 static const int foo
1597 __attribute__ ((section ("bar"))) = 1;
1598 EOF
1599 if ${CC-cc} -S conftest.c -o conftest.s; then
1600 if grep '\.section.*"bar"' conftest.s >/dev/null; then
1601 libc_cv_have_section_quotes=yes
1602 else
1603 libc_cv_have_section_quotes=no
1604 fi
1605 else
1606 libc_cv_have_section_quotes=unknown
1607 fi
1608 rm -f conftest.{c,s}
1609 ])
1610 if test $libc_cv_have_section_quotes = yes; then
1611 AC_DEFINE(HAVE_SECTION_QUOTES)
1612 fi
1614 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1615 [dnl
1616 cat > conftest.s <<EOF
1617 ${libc_cv_dot_text}
1618 .globl foo
1619 foo:
1620 .weak foo
1621 .weak bar; bar = foo
1622 EOF
1623 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1624 libc_cv_asm_weak_directive=yes
1625 else
1626 libc_cv_asm_weak_directive=no
1627 fi
1628 rm -f conftest*])
1630 if test $libc_cv_asm_weak_directive = no; then
1631 AC_CACHE_CHECK(for assembler .weakext directive,
1632 libc_cv_asm_weakext_directive,
1633 [dnl
1634 cat > conftest.s <<EOF
1635 ${libc_cv_dot_text}
1636 .globl foo
1637 foo:
1638 .weakext bar foo
1639 .weakext baz
1640 .globl baz
1641 baz:
1642 EOF
1643 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1644 libc_cv_asm_weakext_directive=yes
1645 else
1646 libc_cv_asm_weakext_directive=no
1647 fi
1648 rm -f conftest*])
1650 fi # no .weak
1652 if test $libc_cv_asm_weak_directive = yes; then
1653 AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1654 elif test $libc_cv_asm_weakext_directive = yes; then
1655 AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1656 fi
1658 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1659 cat > conftest.c <<\EOF
1660 _start () {}
1661 int __eh_pc;
1662 __throw () {}
1663 EOF
1664 dnl No \ in command here because it ends up inside ''.
1665 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1666 -nostdlib -nostartfiles -Wl,--no-whole-archive
1667 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1668 libc_cv_ld_no_whole_archive=yes
1669 else
1670 libc_cv_ld_no_whole_archive=no
1671 fi
1672 rm -f conftest*])
1673 if test $libc_cv_ld_no_whole_archive = no; then
1674 AC_MSG_ERROR([support for --no-whole-archive is needed])
1675 fi
1677 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1678 cat > conftest.c <<\EOF
1679 _start () {}
1680 int __eh_pc;
1681 __throw () {}
1682 EOF
1683 dnl No \ in command here because it ends up inside ''.
1684 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1685 -nostdlib -nostartfiles -fexceptions
1686 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1687 libc_cv_gcc_exceptions=yes
1688 else
1689 libc_cv_gcc_exceptions=no
1690 fi
1691 rm -f conftest*])
1692 if test $libc_cv_gcc_exceptions = yes; then
1693 exceptions=-fexceptions
1694 fi
1695 AC_SUBST(exceptions)dnl
1697 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1698 cat > conftest.c <<\EOF
1699 void zero (void *x)
1700 {
1701 __builtin_memset (x, 0, 1000);
1702 }
1703 EOF
1704 dnl
1705 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1706 then
1707 libc_cv_gcc_builtin_memset=no
1708 else
1709 libc_cv_gcc_builtin_memset=yes
1710 fi
1711 rm -f conftest* ])
1712 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1713 AC_DEFINE(HAVE_BUILTIN_MEMSET)
1714 fi
1716 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1717 cat > conftest.c <<\EOF
1718 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1719 char *foo (const char *a, const char *b)
1720 {
1721 return __builtin_strstr (a, b);
1722 }
1723 EOF
1724 dnl
1725 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1726 then
1727 libc_cv_gcc_builtin_redirection=yes
1728 else
1729 libc_cv_gcc_builtin_redirection=no
1730 fi
1731 rm -f conftest* ])
1732 if test "$libc_cv_gcc_builtin_redirection" = no; then
1733 AC_MSG_ERROR([support for the symbol redirection needed])
1734 fi
1736 dnl Check whether the compiler supports the __thread keyword.
1737 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1738 [cat > conftest.c <<\EOF
1739 __thread int a = 42;
1740 EOF
1741 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1742 libc_cv_gcc___thread=yes
1743 else
1744 libc_cv_gcc___thread=no
1745 fi
1746 rm -f conftest*])
1747 if test "$libc_cv_gcc___thread" = no; then
1748 AC_MSG_ERROR([support for the __thread keyword is required])
1749 fi
1751 dnl Check whether the compiler supports the tls_model attribute.
1752 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1753 cat > conftest.c <<\EOF
1754 extern __thread int a __attribute__((tls_model ("initial-exec")));
1755 EOF
1756 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
1757 libc_cv_gcc_tls_model_attr=yes
1758 else
1759 libc_cv_gcc_tls_model_attr=no
1760 fi
1761 rm -f conftest*])
1762 if test "$libc_cv_gcc_tls_model_attr" = no; then
1763 AC_MSG_ERROR([support for the tls_model attribute is required])
1764 fi
1766 dnl Determine how to disable generation of FMA instructions.
1767 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1768 libc_cv_cc_nofma, [dnl
1769 libc_cv_cc_nofma=
1770 for opt in -ffp-contract=off -mno-fused-madd; do
1771 LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1772 done])
1773 AC_SUBST(libc_cv_cc_nofma)
1775 if test -n "$submachine"; then
1776 AC_CACHE_CHECK([for compiler option for CPU variant],
1777 libc_cv_cc_submachine, [dnl
1778 libc_cv_cc_submachine=no
1779 for opt in "-march=$submachine" "-mcpu=$submachine"; do
1780 LIBC_TRY_CC_OPTION([$opt], [
1781 libc_cv_cc_submachine="$opt"
1782 break], [])
1783 done])
1784 if test "x$libc_cv_cc_submachine" = xno; then
1785 AC_MSG_ERROR([${CC-cc} does not support $submachine])
1786 fi
1787 fi
1788 AC_SUBST(libc_cv_cc_submachine)
1790 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1791 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1792 cat > conftest.c <<EOF
1793 void
1794 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1795 foo (void) {}
1796 EOF
1797 libc_cv_cc_loop_to_function=no
1798 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1799 then
1800 libc_cv_cc_loop_to_function=yes
1801 fi
1802 rm -f conftest*])
1803 if test $libc_cv_cc_loop_to_function = yes; then
1804 AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1805 fi
1806 AC_SUBST(libc_cv_cc_loop_to_function)
1808 dnl Check whether we have the gd library available.
1809 AC_MSG_CHECKING(for libgd)
1810 if test "$with_gd" != "no"; then
1811 old_CFLAGS="$CFLAGS"
1812 CFLAGS="$CFLAGS $libgd_include"
1813 old_LDFLAGS="$LDFLAGS"
1814 LDFLAGS="$LDFLAGS $libgd_ldflags"
1815 old_LIBS="$LIBS"
1816 LIBS="$LIBS -lgd -lpng -lz -lm"
1817 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1818 CFLAGS="$old_CFLAGS"
1819 LDFLAGS="$old_LDFLAGS"
1820 LIBS="$old_LIBS"
1821 else
1822 LIBGD=no
1823 fi
1824 AC_MSG_RESULT($LIBGD)
1825 AC_SUBST(LIBGD)
1827 # SELinux detection
1828 if test x$with_selinux = xno ; then
1829 have_selinux=no;
1830 else
1831 # See if we have the SELinux library
1832 AC_CHECK_LIB(selinux, is_selinux_enabled,
1833 have_selinux=yes, have_selinux=no)
1834 if test x$with_selinux = xyes ; then
1835 if test x$have_selinux = xno ; then
1836 AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1837 fi
1838 fi
1839 fi
1840 # Check if we're building with SELinux support.
1841 if test "x$have_selinux" = xyes; then
1842 AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1844 # See if we have the libaudit library
1845 AC_CHECK_LIB(audit, audit_log_user_avc_message,
1846 have_libaudit=yes, have_libaudit=no)
1847 if test "x$have_libaudit" = xyes; then
1848 AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1849 fi
1850 AC_SUBST(have_libaudit)
1852 # See if we have the libcap library
1853 AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1854 if test "x$have_libcap" = xyes; then
1855 AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1856 fi
1857 AC_SUBST(have_libcap)
1858 fi
1859 AC_SUBST(have_selinux)
1861 dnl check for the size of 'long double'.
1862 AC_CHECK_SIZEOF(long double, 0)
1863 sizeof_long_double=$ac_cv_sizeof_long_double
1864 AC_SUBST(sizeof_long_double)
1866 CPPUNDEFS=
1867 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1868 dnl Since we are building the implementations of the fortified functions here,
1869 dnl having the macro defined interacts very badly.
1870 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1871 [AC_TRY_COMPILE([], [
1872 #ifdef _FORTIFY_SOURCE
1873 # error bogon
1874 #endif],
1875 [libc_cv_predef_fortify_source=no],
1876 [libc_cv_predef_fortify_source=yes])])
1877 if test $libc_cv_predef_fortify_source = yes; then
1878 CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1879 fi
1880 AC_SUBST(CPPUNDEFS)
1882 dnl Check for silly hacked compilers inserting -fstack-protector.
1883 dnl This breaks badly for the early startup code we compile, since
1884 dnl the compiled code can refer to a magic machine-dependent location
1885 dnl for the canary value before we have sufficient setup for that to
1886 dnl work. It's also questionable to build all of libc with this flag
1887 dnl even when you're doing that for most applications you build, since
1888 dnl libc's code is so heavily-used and performance-sensitive. If we
1889 dnl ever really want to make that work, it should be enabled explicitly
1890 dnl in the libc build, not inherited from implicit compiler settings.
1891 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
1892 libc_cv_predef_stack_protector, [
1893 AC_TRY_COMPILE([extern void foobar (char *);],
1894 [char large_array[2048]; foobar (large_array);], [
1895 libc_undefs=`$NM -u conftest.o |
1896 LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1897 2>&AS_MESSAGE_LOG_FD` || {
1898 AC_MSG_ERROR([confusing output from $NM -u])
1899 }
1900 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1901 # On some architectures, there are architecture-specific undefined
1902 # symbols (resolved by the linker), so filter out unknown symbols.
1903 # This will fail to produce the correct result if the compiler
1904 # defaults to -fstack-protector but this produces an undefined symbol
1905 # other than __stack_chk_fail. However, compilers like that have not
1906 # been encountered in practice.
1907 libc_undefs=`echo "$libc_undefs" | egrep '^(foobar|__stack_chk_fail)$'`
1908 case "$libc_undefs" in
1909 foobar) libc_cv_predef_stack_protector=no ;;
1910 '__stack_chk_fail
1911 foobar') libc_cv_predef_stack_protector=yes ;;
1912 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
1913 esac],
1914 [AC_MSG_ERROR([test compilation failed])])
1915 ])
1916 libc_extra_cflags=
1917 if test $libc_cv_predef_stack_protector = yes; then
1918 libc_extra_cflags="$libc_extra_cflags -fno-stack-protector"
1919 fi
1920 libc_extra_cppflags=
1922 # Some linkers on some architectures support __ehdr_start but with
1923 # bugs. Make sure usage of it does not create relocations in the
1924 # output (as the linker should resolve them all for us).
1925 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1926 libc_cv_ehdr_start, [
1927 old_CFLAGS="$CFLAGS"
1928 old_LDFLAGS="$LDFLAGS"
1929 old_LIBS="$LIBS"
1930 CFLAGS="$CFLAGS -fPIC"
1931 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared"
1932 LIBS=
1933 AC_LINK_IFELSE([AC_LANG_SOURCE([
1934 typedef struct {
1935 char foo;
1936 long val;
1937 } Ehdr;
1938 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1939 long ehdr (void) { return __ehdr_start.val; }
1940 ])],
1941 [if $READELF -r conftest | fgrep __ehdr_start >/dev/null; then
1942 libc_cv_ehdr_start=broken
1943 else
1944 libc_cv_ehdr_start=yes
1945 fi], [libc_cv_ehdr_start=no])
1946 CFLAGS="$old_CFLAGS"
1947 LDFLAGS="$old_LDFLAGS"
1948 LIBS="$old_LIBS"
1949 ])
1950 if test "$libc_cv_ehdr_start" = yes; then
1951 AC_DEFINE([HAVE_EHDR_START])
1952 elif test "$libc_cv_ehdr_start" = broken; then
1953 AC_MSG_WARN([linker is broken -- you should upgrade])
1954 fi
1956 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1957 libc_cv_builtin_trap, [dnl
1958 libc_cv_builtin_trap=no
1959 AC_TRY_COMPILE([], [__builtin_trap ()], [
1960 libc_undefs=`$NM -u conftest.o |
1961 LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1962 2>&AS_MESSAGE_LOG_FD` || {
1963 AC_MSG_ERROR([confusing output from $NM -u])
1964 }
1965 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1966 if test -z "$libc_undefs"; then
1967 libc_cv_builtin_trap=yes
1968 fi])])
1969 if test $libc_cv_builtin_trap = yes; then
1970 AC_DEFINE([HAVE_BUILTIN_TRAP])
1971 fi
1973 ### End of automated tests.
1974 ### Now run sysdeps configure fragments.
1976 # They also can set these variables.
1977 use_ldconfig=no
1978 ldd_rewrite_script=no
1979 libc_cv_sysconfdir=$sysconfdir
1980 libc_cv_localstatedir=$localstatedir
1981 libc_cv_gcc_unwind_find_fde=no
1982 libc_cv_idn=no
1984 # Iterate over all the sysdep directories we will use, running their
1985 # configure fragments.
1986 for dir in $sysnames; do
1987 case $dir in
1988 /*) dest=$dir ;;
1989 *) dest=$srcdir/$dir ;;
1990 esac
1991 if test -r $dest/configure; then
1992 AC_MSG_RESULT(running configure fragment for $dir)
1993 . $dest/configure
1994 fi
1995 done
1997 AC_SUBST(libc_extra_cflags)
1998 AC_SUBST(libc_extra_cppflags)
2000 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2001 AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2002 fi
2003 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2005 # A sysdeps configure fragment can reset this if IFUNC is not actually
2006 # usable even though the assembler knows how to generate the symbol type.
2007 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
2008 AC_DEFINE(HAVE_IFUNC)
2009 fi
2011 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
2012 # configure fragment can override the value to prevent this AC_DEFINE.
2013 AC_SUBST(use_nscd)
2014 if test "x$use_nscd" != xno; then
2015 AC_DEFINE([USE_NSCD])
2016 fi
2017 if test "x$build_nscd" = xdefault; then
2018 build_nscd=$use_nscd
2019 fi
2021 # Test for old glibc 2.0.x headers so that they can be removed properly
2022 # Search only in includedir.
2023 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2024 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2025 then
2026 old_glibc_headers=yes
2027 else
2028 old_glibc_headers=no
2029 fi
2030 AC_MSG_RESULT($old_glibc_headers)
2031 if test ${old_glibc_headers} = yes; then
2032 AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2033 AC_MSG_WARN(*** be removed.)
2034 fi
2035 AC_SUBST(old_glibc_headers)
2037 AC_SUBST(libc_cv_slibdir)
2038 AC_SUBST(libc_cv_rtlddir)
2039 AC_SUBST(libc_cv_localedir)
2040 AC_SUBST(libc_cv_sysconfdir)
2041 AC_SUBST(libc_cv_localstatedir)
2042 AC_SUBST(libc_cv_rootsbindir)
2043 AC_SUBST(libc_cv_forced_unwind)
2045 if test x$use_ldconfig = xyes; then
2046 AC_DEFINE(USE_LDCONFIG)
2047 fi
2048 AC_SUBST(use_ldconfig)
2049 AC_SUBST(ldd_rewrite_script)
2051 AC_SUBST(static)
2052 AC_SUBST(shared)
2054 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2055 [libc_cv_pic_default=yes
2056 cat > conftest.c <<EOF
2057 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2058 # error PIC is default.
2059 #endif
2060 EOF
2061 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2062 libc_cv_pic_default=no
2063 fi
2064 rm -f conftest.*])
2065 AC_SUBST(libc_cv_pic_default)
2067 AC_SUBST(profile)
2068 AC_SUBST(static_nss)
2070 AC_SUBST(DEFINES)
2072 dnl See sysdeps/mach/configure.ac for this variable.
2073 AC_SUBST(mach_interface_list)
2075 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2076 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2077 AC_SUBST(VERSION)
2078 AC_SUBST(RELEASE)
2080 AC_CONFIG_FILES([config.make Makefile])
2081 AC_CONFIG_COMMANDS([default],[[
2082 case $CONFIG_FILES in *config.make*)
2083 echo "$config_vars" >> config.make;;
2084 esac
2085 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2086 AC_OUTPUT