sysdeps/m68k/add_n.S

   1 /* mc68020 __mpn_add_n -- Add two limb vectors of the same length > 0 and store
   2    sum in a third limb vector.
   3
   4 Copyright (C) 1992, 1994, 1996 Free Software Foundation, Inc.
   5
   6 This file is part of the GNU MP Library.
   7
   8 The GNU MP Library is free software; you can redistribute it and/or modify
   9 it under the terms of the GNU Library General Public License as published by
  10 the Free Software Foundation; either version 2 of the License, or (at your
  11 option) any later version.
  12
  13 The GNU MP Library is distributed in the hope that it will be useful, but
  14 WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
  16 License for more details.
  17
  18 You should have received a copy of the GNU Library General Public License
  19 along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  20 the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  21 MA 02111-1307, USA. */
  22
  23 /*
  24   INPUT PARAMETERS
  25   res_ptr       (sp + 4)
  26   s1_ptr        (sp + 8)
  27   s2_ptr        (sp + 16)
  28   size          (sp + 12)
  29 */
  30
  31 #include "sysdep.h"
  32 #include "asm-syntax.h"
  33
  34         TEXT
  35         ALIGN
  36         GLOBL   C_SYMBOL_NAME(__mpn_add_n)
  37
  38 C_SYMBOL_NAME(__mpn_add_n:)
  39 PROLOG(__mpn_add_n)
  40 /* Save used registers on the stack.  */
  41         movel   R(d2),MEM_PREDEC(sp)
  42         movel   R(a2),MEM_PREDEC(sp)
  43
  44 /* Copy the arguments to registers.  Better use movem?  */
  45         movel   MEM_DISP(sp,12),R(a2)
  46         movel   MEM_DISP(sp,16),R(a0)
  47         movel   MEM_DISP(sp,20),R(a1)
  48         movel   MEM_DISP(sp,24),R(d2)
  49
  50         eorw    #1,R(d2)
  51         lsrl    #1,R(d2)
  52         bcc     L(L1)
  53         subql   #1,R(d2)        /* clears cy as side effect */
  54
  55 L(Loop:)
  56         movel   MEM_POSTINC(a0),R(d0)
  57         movel   MEM_POSTINC(a1),R(d1)
  58         addxl   R(d1),R(d0)
  59         movel   R(d0),MEM_POSTINC(a2)
  60 L(L1:)  movel   MEM_POSTINC(a0),R(d0)
  61         movel   MEM_POSTINC(a1),R(d1)
  62         addxl   R(d1),R(d0)
  63         movel   R(d0),MEM_POSTINC(a2)
  64
  65         dbf     R(d2),L(Loop)           /* loop until 16 lsb of %4 == -1 */
  66         subxl   R(d0),R(d0)     /* d0 <= -cy; save cy as 0 or -1 in d0 */
  67         subl    #0x10000,R(d2)
  68         bcs     L(L2)
  69         addl    R(d0),R(d0)     /* restore cy */
  70         bra     L(Loop)
  71
  72 L(L2:)
  73         negl    R(d0)
  74
  75 /* Restore used registers from stack frame.  */
  76         movel   MEM_POSTINC(sp),R(a2)
  77         movel   MEM_POSTINC(sp),R(d2)
  78
  79         rts
  80 EPILOG(__mpn_add_n)