| blob | 7c059039a69956866dcc3a4127c681c8e5c75f06 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Note we do not use AC_PREREQ here! See aclocal.m4 for what we use instead.
3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
4 AC_CONFIG_SRCDIR([include/features.h])
5 AC_CONFIG_HEADERS([config.h])
6 AC_CONFIG_AUX_DIR([scripts])
8 ACX_PKGVERSION([GNU libc])
9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
11 [Package description])
12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
13 [Bug reporting address])
15 # Glibc should not depend on any header files
16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
17 [m4_divert_text([DEFAULTS],
18 [ac_includes_default='/* none */'])])
20 dnl This is here so we can set $subdirs directly based on configure fragments.
21 AC_CONFIG_SUBDIRS()
23 AC_CANONICAL_HOST
25 AC_PROG_CC
26 if test $host != $build; then
27 AC_CHECK_PROGS(BUILD_CC, gcc cc)
28 fi
29 AC_SUBST(cross_compiling)
30 AC_PROG_CPP
31 # We need the C++ compiler only for testing.
32 AC_PROG_CXX
33 AC_CHECK_TOOL(READELF, readelf, false)
35 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
36 AC_MSG_ERROR([you must configure in a separate build directory])
37 fi
39 # This will get text that should go into config.make.
40 config_vars=
42 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
43 AC_ARG_WITH([gd],
44 AC_HELP_STRING([--with-gd=DIR],
45 [find libgd include dir and library with prefix DIR]),
46 [dnl
47 case "$with_gd" in
48 yes|''|no) ;;
49 *) libgd_include="-I$withval/include"
50 libgd_ldflags="-L$withval/lib" ;;
51 esac
52 ])
53 AC_ARG_WITH([gd-include],
54 AC_HELP_STRING([--with-gd-include=DIR],
55 [find libgd include files in DIR]),
56 [dnl
57 case "$with_gd_include" in
58 ''|no) ;;
59 *) libgd_include="-I$withval" ;;
60 esac
61 ])
62 AC_ARG_WITH([gd-lib],
63 AC_HELP_STRING([--with-gd-lib=DIR],
64 [find libgd library files in DIR]),
65 [dnl
66 case "$with_gd_lib" in
67 ''|no) ;;
68 *) libgd_ldflags="-L$withval" ;;
69 esac
70 ])
72 if test -n "$libgd_include"; then
73 config_vars="$config_vars
74 CFLAGS-memusagestat.c = $libgd_include"
75 fi
76 if test -n "$libgd_ldflags"; then
77 config_vars="$config_vars
78 libgd-LDFLAGS = $libgd_ldflags"
79 fi
81 dnl Arguments to specify presence of other packages/features.
82 AC_ARG_WITH([fp],
83 AC_HELP_STRING([--with-fp],
84 [if using floating-point hardware @<:@default=yes@:>@]),
85 [with_fp=$withval],
86 [with_fp=yes])
87 AC_SUBST(with_fp)
88 AC_ARG_WITH([binutils],
89 AC_HELP_STRING([--with-binutils=PATH],
90 [specify location of binutils (as and ld)]),
91 [path_binutils=$withval],
92 [path_binutils=''])
93 AC_ARG_WITH([selinux],
94 AC_HELP_STRING([--with-selinux],
95 [if building with SELinux support]),
96 [with_selinux=$withval],
97 [with_selinux=auto])
99 AC_ARG_WITH([headers],
100 AC_HELP_STRING([--with-headers=PATH],
101 [location of system headers to use
102 (for example /usr/src/linux/include)
103 @<:@default=compiler default@:>@]),
104 [sysheaders=$withval],
105 [sysheaders=''])
106 AC_SUBST(sysheaders)
108 AC_SUBST(use_default_link)
109 AC_ARG_WITH([default-link],
110 AC_HELP_STRING([--with-default-link],
111 [do not use explicit linker scripts]),
112 [use_default_link=$withval],
113 [use_default_link=default])
115 AC_ARG_ENABLE([sanity-checks],
116 AC_HELP_STRING([--disable-sanity-checks],
117 [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
118 [enable_sanity=$enableval],
119 [enable_sanity=yes])
121 AC_ARG_ENABLE([shared],
122 AC_HELP_STRING([--enable-shared],
123 [build shared library @<:@default=yes if GNU ld@:>@]),
124 [shared=$enableval],
125 [shared=yes])
126 AC_ARG_ENABLE([profile],
127 AC_HELP_STRING([--enable-profile],
128 [build profiled library @<:@default=no@:>@]),
129 [profile=$enableval],
130 [profile=no])
131 AC_ARG_ENABLE([versioning],
132 AC_HELP_STRING([--disable-versioning],
133 [do not include versioning information in the library objects @<:@default=yes if supported@:>@]),
134 [enable_versioning=$enableval],
135 [enable_versioning=yes])
137 AC_ARG_ENABLE([oldest-abi],
138 AC_HELP_STRING([--enable-oldest-abi=ABI],
139 [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
140 [oldest_abi=$enableval],
141 [oldest_abi=no])
142 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
143 oldest_abi=default
144 else
145 AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
146 fi
147 AC_SUBST(oldest_abi)
149 AC_ARG_ENABLE([stackguard-randomization],
150 AC_HELP_STRING([--enable-stackguard-randomization],
151 [initialize __stack_chk_guard canary with a random number at program start]),
152 [enable_stackguard_randomize=$enableval],
153 [enable_stackguard_randomize=no])
154 if test "$enable_stackguard_randomize" = yes; then
155 AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
156 fi
158 dnl Generic infrastructure for drop-in additions to libc.
159 AC_ARG_ENABLE([add-ons],
160 AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
161 [configure and build add-ons in DIR1,DIR2,...
162 search for add-ons if no parameter given]),
163 , [enable_add_ons=yes])
165 AC_ARG_ENABLE([hidden-plt],
166 AC_HELP_STRING([--disable-hidden-plt],
167 [do not hide internal function calls to avoid PLT]),
168 [hidden=$enableval],
169 [hidden=yes])
170 if test "x$hidden" = xno; then
171 AC_DEFINE(NO_HIDDEN)
172 fi
174 AC_ARG_ENABLE([bind-now],
175 AC_HELP_STRING([--enable-bind-now],
176 [disable lazy relocations in DSOs]),
177 [bindnow=$enableval],
178 [bindnow=no])
179 AC_SUBST(bindnow)
181 dnl On some platforms we cannot use dynamic loading. We must provide
182 dnl static NSS modules.
183 AC_ARG_ENABLE([static-nss],
184 AC_HELP_STRING([--enable-static-nss],
185 [build static NSS modules @<:@default=no@:>@]),
186 [static_nss=$enableval],
187 [static_nss=no])
188 dnl Enable static NSS also if we build no shared objects.
189 if test x"$static_nss" = xyes || test x"$shared" = xno; then
190 static_nss=yes
191 AC_DEFINE(DO_STATIC_NSS)
192 fi
194 AC_ARG_ENABLE([force-install],
195 AC_HELP_STRING([--disable-force-install],
196 [don't force installation of files from this package, even if they are older than the installed files]),
197 [force_install=$enableval],
198 [force_install=yes])
199 AC_SUBST(force_install)
201 dnl On some platforms we allow dropping compatibility with all kernel
202 dnl versions.
203 AC_ARG_ENABLE([kernel],
204 AC_HELP_STRING([--enable-kernel=VERSION],
205 [compile for compatibility with kernel not older than VERSION]),
206 [minimum_kernel=$enableval],
207 [])
208 dnl Prevent unreasonable values.
209 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
210 # Better nothing than this.
211 minimum_kernel=""
212 else
213 if test "$minimum_kernel" = current; then
214 minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
215 fi
216 fi
218 dnl For the development we sometimes want gcc to issue even more warnings.
219 dnl This is not the default since many of the extra warnings are not
220 dnl appropriate.
221 AC_ARG_ENABLE([all-warnings],
222 AC_HELP_STRING([--enable-all-warnings],
223 [enable all useful warnings gcc can issue]),
224 [all_warnings=$enableval],
225 [])
226 AC_SUBST(all_warnings)
228 AC_ARG_ENABLE([multi-arch],
229 AC_HELP_STRING([--enable-multi-arch],
230 [enable single DSO with optimizations for multiple architectures]),
231 [multi_arch=$enableval],
232 [multi_arch=default])
234 AC_ARG_ENABLE([nss-crypt],
235 AC_HELP_STRING([--enable-nss-crypt],
236 [enable libcrypt to use nss]),
237 [nss_crypt=$enableval],
238 [nss_crypt=no])
239 if test x$nss_crypt = xyes; then
240 nss_includes=-I$(nss-config --includedir 2>/dev/null)
241 if test $? -ne 0; then
242 AC_MSG_ERROR([cannot find include directory with nss-config])
243 fi
244 old_CFLAGS="$CFLAGS"
245 CFLAGS="$CFLAGS $nss_includes"
246 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
247 #include <hasht.h>
248 #include <nsslowhash.h>
249 void f (void) { NSSLOW_Init (); }])],
250 libc_cv_nss_crypt=yes,
251 AC_MSG_ERROR([
252 cannot find NSS headers with lowlevel hash function interfaces]))
253 old_LIBS="$LIBS"
254 LIBS="$LIBS -lfreebl3"
255 AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
256 #include <hasht.h>
257 #include <nsslowhash.h>],
258 [NSSLOW_Init();])],
259 libc_cv_nss_crypt=yes,
260 AC_MSG_ERROR([
261 cannot link program using lowlevel NSS hash functions]))
262 CFLAGS="$old_CFLAGS"
263 LIBS="$old_LIBS"
264 else
265 libc_cv_nss_crypt=no
266 fi
267 AC_SUBST(libc_cv_nss_crypt)
270 AC_ARG_ENABLE([obsolete-rpc],
271 AC_HELP_STRING([--enable-obsolete-rpc],
272 [build and install the obsolete RPC code for link-time usage]),
273 [link_obsolete_rpc=$enableval],
274 [link_obsolete_rpc=no])
275 AC_SUBST(link_obsolete_rpc)
277 if test "$link_obsolete_rpc" = yes; then
278 AC_DEFINE(LINK_OBSOLETE_RPC)
279 fi
281 AC_ARG_ENABLE([systemtap],
282 [AS_HELP_STRING([--enable-systemtap],
283 [enable systemtap static probe points @<:@default=no@:>@])],
284 [systemtap=$enableval],
285 [systemtap=no])
286 if test "x$systemtap" != xno; then
287 AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
288 old_CFLAGS="$CFLAGS"
289 CFLAGS="-std=gnu99 $CFLAGS"
290 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
291 void foo (int i, void *p)
292 {
293 asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
294 :: STAP_PROBE_ASM_OPERANDS (2, i, p));
295 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
296 CFLAGS="$old_CFLAGS"])
297 if test $libc_cv_sdt = yes; then
298 AC_DEFINE([USE_STAP_PROBE])
299 elif test "x$systemtap" != xauto; then
300 AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
301 fi
302 fi
304 AC_ARG_ENABLE([build-nscd],
305 [AS_HELP_STRING([--disable-build-nscd],
306 [disable building and installing the nscd daemon])],
307 [build_nscd=$enableval],
308 [build_nscd=default])
309 AC_SUBST(build_nscd)
311 # Note the use of $use_nscd is near the bottom of the file.
312 AC_ARG_ENABLE([nscd],
313 [AS_HELP_STRING([--disable-nscd],
314 [library functions will not contact the nscd daemon])],
315 [use_nscd=$enableval],
316 [use_nscd=yes])
318 # The way shlib-versions is used to generate soversions.mk uses a
319 # fairly simplistic model for name recognition that can't distinguish
320 # i486-pc-linux-gnu fully from i486-pc-gnu. So we mutate a $host_os
321 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
322 # tell. This doesn't get used much beyond that, so it's fairly safe.
323 case "$host_os" in
324 linux*)
325 ;;
326 gnu*)
327 host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
328 ;;
329 esac
331 # We keep the original values in `$config_*' and never modify them, so we
332 # can write them unchanged into config.make. Everything else uses
333 # $machine, $vendor, and $os, and changes them whenever convenient.
334 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
336 # Don't allow vendor == "unknown"
337 test "$config_vendor" = unknown && config_vendor=
338 config_os="`echo $config_os | sed 's/^unknown-//'`"
340 # Some configurations imply other options.
341 elf=yes
343 # The configure fragment of an add-on port can modify these to supplement
344 # or override the table in the case statement below. No fragment should
345 # ever change the config_* variables, however.
346 machine=$config_machine
347 vendor=$config_vendor
348 os=$config_os
349 base_os=''
351 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
352 # Unify this here.
353 if test "$machine" = rs6000; then
354 machine="powerpc"
355 fi
357 # Braindead PowerPC box with absolutely no FPU.
358 case "$machine-$host_os" in
359 powerpc*-*soft)
360 with_fp=no
361 ;;
362 esac
364 submachine=
365 AC_ARG_WITH([cpu],
366 AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
367 [dnl
368 case "$withval" in
369 yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
370 no) ;;
371 *) submachine="$withval" ;;
372 esac
373 ])
375 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
376 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
378 # An add-on can set this when it wants to disable the sanity check below.
379 libc_config_ok=no
381 dnl Having this here, though empty, makes sure that if add-ons' fragments
382 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
383 dnl our AC_OUTPUT will actually use it.
384 AC_CONFIG_SUBDIRS()
386 case "$enable_add_ons" in
387 ''|no) add_ons= ;;
388 yes|'*')
389 add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
390 sed 's@/[[^/]]*$@@' | sort | uniq`
391 add_ons_automatic=yes
392 ;;
393 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
394 add_ons_automatic=no ;;
395 esac
397 configured_add_ons=
398 add_ons_sfx=
399 add_ons_pfx=
400 if test x"$add_ons" != x; then
401 for f in $add_ons; do
402 # Some sanity checks
403 case "$f" in
404 crypt)
405 AC_MSG_ERROR([
406 *** It seems that you're using an old \`crypt' add-on. crypt is now
407 *** part of glibc and using the old add-on will not work with this
408 *** release. Start again with fresh sources and without the old
409 *** \`crypt' add-on.])
410 ;;
411 localedata)
412 AC_MSG_ERROR([
413 *** It seems that you're using an old \`localedata' add-on. localedata
414 *** is now part of glibc and using the old add-on will not work with
415 *** this release. Start again with fresh sources and without the old
416 *** \`localedata' add-on.])
417 ;;
418 esac
419 done
421 # Now source each add-on's configure fragment.
422 # The fragments can use $srcdir/$libc_add_on to find themselves,
423 # and test $add_ons_automatic to see if they were explicitly requested.
424 # A fragment can clear (or even change) $libc_add_on to affect
425 # whether it goes into the list to be actually used in the build.
426 use_add_ons=
427 for libc_add_on in $add_ons; do
428 # Test whether such a directory really exists.
429 # It can be absolute, or relative to $srcdir, or relative to the build dir.
430 case "$libc_add_on" in
431 /*)
432 libc_add_on_srcdir=$libc_add_on
433 ;;
434 *)
435 test -d "$srcdir/$libc_add_on" || {
436 if test -d "$libc_add_on"; then
437 libc_add_on="`pwd`/$libc_add_on"
438 else
439 AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
440 fi
441 }
442 libc_add_on_srcdir=$srcdir/$libc_add_on
443 ;;
444 esac
446 libc_add_on_frag=$libc_add_on_srcdir/configure
447 libc_add_on_canonical=
448 libc_add_on_config_subdirs=
449 if test -r "$libc_add_on_frag"; then
450 AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
451 libc_add_on_canonical=unknown
452 libc_add_on_subdirs=
453 . "$libc_add_on_frag"
454 test -z "$libc_add_on" || {
455 configured_add_ons="$configured_add_ons $libc_add_on"
456 if test "x$libc_add_on_canonical" = xunknown; then
457 AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
458 fi
459 for d in $libc_add_on_subdirs; do
460 case "$libc_add_on" in
461 /*) subdir_srcdir="$libc_add_on" ;;
462 *) subdir_srcdir="\$(..)$libc_add_on" ;;
463 esac
464 case "$d" in
465 .)
466 d="${libc_add_on_canonical:-$libc_add_on}"
467 ;;
468 /*)
469 subdir_srcdir="$d"
470 ;;
471 *)
472 subdir_srcdir="$subdir_srcdir/$d"
473 ;;
474 esac
475 d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
476 add_on_subdirs="$add_on_subdirs $d"
477 test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
478 $d-srcdir = $subdir_srcdir"
479 done
480 for d in $libc_add_on_config_subdirs; do
481 case "$d" in
482 /*) AC_MSG_ERROR(dnl
483 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
484 esac
485 if test ! -d "$libc_add_on_srcdir/$d"; then
486 AC_MSG_ERROR(fragment wants to configure missing directory $d)
487 fi
488 case "$libc_add_on" in
489 /*) AC_MSG_ERROR(dnl
490 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
491 esac
492 subdirs="$subdirs $libc_add_on/$d"
493 done
494 }
495 fi
496 if test -n "$libc_add_on"; then
497 LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
498 use_add_ons="$use_add_ons $libc_add_on"
499 add_ons_pfx="$add_ons_pfx $libc_add_on/"
500 test -z "$libc_add_on_canonical" ||
501 add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
502 fi
503 done
504 # Use echo to strip excess whitespace.
505 add_ons="`echo $use_add_ons`"
506 fi
507 AC_SUBST(add_ons)
508 AC_SUBST(add_on_subdirs)
511 ###
512 ### I put this here to prevent those annoying emails from people who cannot
513 ### read and try to compile glibc on unsupported platforms. --drepper
514 ###
515 ### By using the undocumented --enable-hacker-mode option for configure
516 ### one can skip this test to make the configuration not fail for unsupported
517 ### platforms.
518 ###
519 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
520 case "$machine-$host_os" in
521 *-linux* | *-gnu*)
522 ;;
523 *)
524 echo "*** The GNU C library is currently not available for this platform."
525 echo "*** So far nobody cared to port it and if there is no volunteer it"
526 echo "*** might never happen. So, if you have interest to see glibc on"
527 echo "*** this platform visit"
528 echo "*** http://www.gnu.org/software/libc/porting.html"
529 echo "*** and join the group of porters"
530 exit 1
531 ;;
532 esac
533 fi
535 dnl We need to use [ and ] for other purposes for a while now.
536 changequote(,)dnl
537 # Expand the configuration machine name into a subdirectory by architecture
538 # type and particular chip. If an add-on configure fragment already set
539 # base_machine, we don't change it.
540 test -n "$base_machine" || case "$machine" in
541 i[34567]86) base_machine=i386 machine=i386/$machine ;;
542 powerpc) base_machine=powerpc machine=powerpc/powerpc32 ;;
543 powerpc64) base_machine=powerpc machine=powerpc/powerpc64 ;;
544 s390) base_machine=s390 machine=s390/s390-32 ;;
545 s390x) base_machine=s390 machine=s390/s390-64 ;;
546 sh3*) base_machine=sh machine=sh/sh3 ;;
547 sh4*) base_machine=sh machine=sh/sh4 ;;
548 sparc | sparcv[67])
549 base_machine=sparc machine=sparc/sparc32 ;;
550 sparcv8 | supersparc | hypersparc)
551 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
552 sparcv8plus | sparcv8plusa | sparcv9)
553 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
554 sparcv8plusb | sparcv9b)
555 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
556 sparcv9v)
557 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
558 sparcv9v2)
559 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
560 sparc64)
561 base_machine=sparc machine=sparc/sparc64 ;;
562 sparc64b)
563 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
564 sparc64v)
565 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
566 sparc64v2)
567 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
568 *) base_machine=$machine ;;
569 esac
570 changequote([,])dnl
571 AC_SUBST(base_machine)
573 if test "$base_machine" = "i386"; then
574 AC_DEFINE(USE_REGPARMS)
575 fi
577 # For the multi-arch option we need support in the assembler & linker.
578 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
579 libc_cv_ld_gnu_indirect_function, [dnl
580 cat > conftest.s <<EOF
581 .type foo,%gnu_indirect_function
582 foo:
583 .globl _start
584 _start:
585 .globl __start
586 __start:
587 .data
588 .long foo
589 EOF
590 libc_cv_ld_gnu_indirect_function=no
591 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
592 -nostartfiles -nostdlib \
593 -o conftest conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
594 # Do a link to see if the backend supports IFUNC relocs.
595 $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
596 LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
597 libc_cv_ld_gnu_indirect_function=yes
598 }
599 fi
600 rm -f conftest*])
602 AC_MSG_CHECKING(whether .text pseudo-op must be used)
603 AC_CACHE_VAL(libc_cv_dot_text, [dnl
604 cat > conftest.s <<EOF
605 .text
606 EOF
607 libc_cv_dot_text=
608 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
609 libc_cv_dot_text=.text
610 fi
611 rm -f conftest*])
612 if test -z "$libc_cv_dot_text"; then
613 AC_MSG_RESULT(no)
614 else
615 AC_MSG_RESULT(yes)
616 fi
618 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
619 if test x"$multi_arch" = xyes; then
620 AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
621 else
622 multi_arch=no
623 fi
624 fi
625 if test x"$multi_arch" != xno; then
626 multi_arch_d=/multiarch
627 fi
629 # Compute the list of sysdep directories for this configuration.
630 # This can take a while to compute.
631 sysdep_dir=$srcdir/sysdeps
632 AC_MSG_CHECKING(sysdep dirs)
633 dnl We need to use [ and ] for other purposes for a while now.
634 changequote(,)dnl
635 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
636 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
638 test "x$base_os" != x || case "$os" in
639 gnu*)
640 base_os=mach/hurd ;;
641 linux*)
642 base_os=unix/sysv ;;
643 esac
645 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
646 tail=$os
647 ostry=$os
648 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
649 ostry="$ostry /$o"
650 tail=$o
651 done
652 o=`echo $tail | sed 's/[0-9]*$//'`
653 if test $o != $tail; then
654 ostry="$ostry /$o"
655 fi
656 # For linux-gnu, try linux-gnu, then linux.
657 o=`echo $tail | sed 's/-.*$//'`
658 if test $o != $tail; then
659 ostry="$ostry /$o"
660 fi
662 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
663 base=
664 tail=$base_os
665 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
666 set $b
667 base="$base /$1"
668 tail="$2"
669 done
671 # For sparc/sparc32, try sparc/sparc32 and then sparc.
672 mach=
673 tail=$machine${submachine:+/$submachine}
674 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
675 set $m
676 # Prepend the machine's FPU directory unless --without-fp.
677 if test "$with_fp" = yes; then
678 mach="$mach /$1/fpu"
679 else
680 mach="$mach /$1/nofpu"
681 fi
682 mach="$mach /$1"
683 tail="$2"
684 done
686 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
687 changequote([,])dnl
689 # Find what sysdep directories exist.
690 sysnames_add_ons=
691 sysnames=
692 for b in $base ''; do
693 for m0 in $mach ''; do
694 for v in /$vendor ''; do
695 test "$v" = / && continue
696 for o in /$ostry ''; do
697 test "$o" = / && continue
698 for m in $multi_arch_d $mach ''; do
699 for d in $add_ons_pfx ''; do
700 for a in $add_ons_sfx ''; do
701 if test -n "$m0$m0sub$b$v$o$m$msub"; then
702 try_srcdir="${srcdir}/"
703 case "$d" in
704 /*) try_srcdir= ;;
705 esac
706 try="${d}sysdeps$m0$m0sub$b$v$o$m$msub$a"
707 test -n "$enable_debug_configure" &&
708 echo "$0 [DEBUG]: try $try" >&2
709 if test -d "$try_srcdir$try"; then
710 sysnames="$sysnames $try"
711 { test -n "$o" || test -n "$b"; } && os_used=t
712 { test -n "$m" || test -n "$m0"; } && machine_used=t
713 case x${m0:-$m} in
714 x*/$submachine) submachine_used=t ;;
715 esac
716 if test -n "$d"; then
717 case "$sysnames_add_ons" in
718 *" $d "*) ;;
719 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
720 esac
721 fi
722 fi
723 fi
724 done
725 done
726 done
727 done
728 done
729 done
730 done
732 # If the assembler supports gnu_indirect_function symbol type and the
733 # architecture supports multi-arch, we enable multi-arch by default.
734 case $sysnames_add_ons$sysnames in
735 *"$multi_arch_d"*)
736 ;;
737 *)
738 test x"$multi_arch" = xdefault && multi_arch=no
739 ;;
740 esac
741 if test x"$multi_arch" != xno; then
742 AC_DEFINE(USE_MULTIARCH)
743 fi
744 AC_SUBST(multi_arch)
746 if test -z "$os_used" && test "$os" != none; then
747 AC_MSG_ERROR(Operating system $os is not supported.)
748 fi
749 if test -z "$machine_used" && test "$machine" != none; then
750 AC_MSG_ERROR(The $machine is not supported.)
751 fi
752 if test -z "$submachine_used" && test -n "$submachine"; then
753 AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
754 fi
755 AC_SUBST(submachine)
757 # We have now validated the configuration.
759 # Expand the list of system names into a full list of directories
760 # from each element's parent name and Implies file (if present).
761 set $sysnames
762 names=
763 while test $# -gt 0; do
764 name=$1
765 shift
767 case " $names " in *" $name "*)
768 # Already in the list.
769 continue
770 esac
772 # Report each name as we discover it, so there is no long pause in output.
773 echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
775 name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
777 case $name in
778 /*) xsrcdir= ;;
779 *) xsrcdir=$srcdir/ ;;
780 esac
781 test -n "$enable_debug_configure" &&
782 echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
784 for implies_file in Implies Implies-before Implies-after; do
785 implies_type=`echo $implies_file | sed s/-/_/`
786 eval ${implies_type}=
787 if test -f $xsrcdir$name/$implies_file; then
788 # Collect more names from the `Implies' file (removing comments).
789 implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
790 for x in $implied_candidate; do
791 found=no
792 if test -d $xsrcdir$name_base/$x; then
793 eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
794 found=yes
795 fi
796 for d in $add_ons_pfx ''; do
797 try="${d}sysdeps/$x"
798 case $d in
799 /*) try_srcdir= ;;
800 *) try_srcdir=$srcdir/ ;;
801 esac
802 test -n "$enable_debug_configure" &&
803 echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
804 if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
805 then
806 eval "${implies_type}=\"\$${implies_type} \$try\""
807 found=yes
808 case "$sysnames_add_ons" in
809 *" $d "*) ;;
810 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
811 esac
812 fi
813 done
814 if test $found = no; then
815 AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
816 fi
817 done
818 fi
819 done
821 # Add NAME to the list of names.
822 names="$names $name"
824 # Find the parent of NAME, using the empty string if it has none.
825 changequote(,)dnl
826 parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
827 changequote([,])dnl
829 test -n "$enable_debug_configure" &&
830 echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
831 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
833 # Add the names implied by NAME, and NAME's parent (if it has one), to
834 # the list of names to be processed (the argument list). We prepend the
835 # implied names to the list and append the parent. We want implied
836 # directories to come before further directories inferred from the
837 # configuration components; this ensures that for sysv4, unix/common
838 # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
839 # after sysv4).
840 sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
841 test -n "$sysnames" && set $sysnames
842 done
844 # Add the default directories.
845 default_sysnames="sysdeps/generic"
846 sysnames="$names $default_sysnames"
847 AC_SUBST(sysnames)
848 # The other names were emitted during the scan.
849 AC_MSG_RESULT($default_sysnames)
851 # Collect the list of add-ons that supply partial sysdeps trees.
852 sysdeps_add_ons=
853 for add_on in $add_ons; do
854 case "$add_on" in
855 /*) xsrcdir= ;;
856 *) xsrcdir="$srcdir/" ;;
857 esac
859 test -d "$xsrcdir$add_on/sysdeps" || {
860 case "$configured_add_ons " in
861 *" $add_on "*) ;;
862 *|'')
863 AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
864 ;;
865 esac
866 continue
867 }
869 sysdeps_add_ons="$sysdeps_add_ons $add_on"
870 case "$sysnames_add_ons" in
871 *" $add_on/ "*) ;;
872 *|'')
873 AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
874 continue ;;
875 esac
877 found=no
878 for d in $sysnames; do
879 case "$d" in
880 $add_on/sysdeps/*) ;;
881 *) continue ;;
882 esac
883 (cd "$xsrcdir$d" && for f in *[[!~]]; do
884 case "$f" in
885 sys|bits)
886 for ff in $f/*.h; do
887 test -d "$ff" || { test -e "$ff" && exit 88; }
888 done
889 ;;
890 *)
891 test -d "$f" || { test -e "$f" && exit 88; }
892 ;;
893 esac
894 done)
895 if test $? -eq 88; then
896 found=yes
897 break
898 fi
899 done
900 if test $found = no; then
901 AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
902 fi
903 done
904 AC_SUBST(sysdeps_add_ons)
907 ### Locate tools.
909 AC_PROG_INSTALL
910 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
911 # The makefiles need to use a different form to find it in $srcdir.
912 INSTALL='\$(..)./scripts/install-sh -c'
913 fi
914 AC_PROG_LN_S
916 LIBC_PROG_BINUTILS
917 AC_SUBST(MIG)dnl Needed by sysdeps/mach/configure.in
919 # Accept binutils 2.20 or newer.
920 AC_CHECK_PROG_VER(AS, $AS, --version,
921 [GNU assembler.* \([0-9]*\.[0-9.]*\)],
922 [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
923 AC_CHECK_PROG_VER(LD, $LD, --version,
924 [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
925 [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
927 # These programs are version sensitive.
928 AC_CHECK_TOOL_PREFIX
929 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
930 [version \([egcygnustpi-]*[0-9.]*\)], [4.[3-9].* | 4.[1-9][0-9].* | [5-9].* ],
931 critic_missing="$critic_missing gcc")
932 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
933 [GNU Make[^0-9]*\([0-9][0-9.]*\)],
934 [3.79* | 3.[89]*], critic_missing="$critic_missing make")
936 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
937 [GNU gettext.* \([0-9]*\.[0-9.]*\)],
938 [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
939 MSGFMT=: aux_missing="$aux_missing msgfmt")
940 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
941 [GNU texinfo.* \([0-9][0-9.]*\)],
942 [4.[5-9]*|4.[1-9][0-9]*|[5-9].*],
943 MAKEINFO=: aux_missing="$aux_missing makeinfo")
944 AC_CHECK_PROG_VER(SED, sed, --version,
945 [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
946 [3.0[2-9]*|3.[1-9]*|[4-9]*],
947 SED=: aux_missing="$aux_missing sed")
948 AC_CHECK_PROG_VER(AWK, gawk, --version,
949 [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
950 [[3-9].*], critic_missing="$critic_missing gawk")
952 AC_CHECK_TOOL(NM, nm, false)
954 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
955 case "x$AUTOCONF" in
956 xno|x|x:) AUTOCONF=no ;;
957 *)
958 AC_CACHE_CHECK(dnl
959 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
960 if (cd $srcdir; $AUTOCONF $ACFLAGS configure.in > /dev/null 2>&1); then
961 libc_cv_autoconf_works=yes
962 else
963 libc_cv_autoconf_works=no
964 fi])
965 test $libc_cv_autoconf_works = yes || AUTOCONF=no
966 ;;
967 esac
968 if test "x$AUTOCONF" = xno; then
969 aux_missing="$aux_missing autoconf"
970 fi
972 test -n "$critic_missing" && AC_MSG_ERROR([
973 *** These critical programs are missing or too old:$critic_missing
974 *** Check the INSTALL file for required versions.])
976 test -n "$aux_missing" && AC_MSG_WARN([
977 *** These auxiliary programs are missing or incompatible versions:$aux_missing
978 *** some features will be disabled.
979 *** Check the INSTALL file for required versions.])
981 # if using special system headers, find out the compiler's sekrit
982 # header directory and add that to the list. NOTE: Only does the right
983 # thing on a system that doesn't need fixincludes. (Not presently a problem.)
984 if test -n "$sysheaders"; then
985 SYSINCLUDES=-nostdinc
986 for d in include include-fixed; do
987 i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
988 SYSINCLUDES="$SYSINCLUDES -isystem $i"
989 done
990 SYSINCLUDES="$SYSINCLUDES \
991 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
992 if test -n "$CXX"; then
993 CXX_SYSINCLUDES=
994 cxxmachine=`$CXX -dumpmachine 2>&AS_MESSAGE_LOG_FD` &&
995 cxxheaders=`$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
996 | sed -n -e '1,/#include/d' -e '/^ \//{p;q;}' | sed 's/ //'`
997 test "x$cxxheaders" != x && test "x$i" != "x$cxxheaders" &&
998 CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders \
999 -isystem $cxxheaders/$cxxmachine -isystem $cxxheaders/backward"
1000 fi
1001 fi
1002 AC_SUBST(SYSINCLUDES)
1003 AC_SUBST(CXX_SYSINCLUDES)
1005 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1006 # since this would lead to problems installing/building glibc.
1007 # LD_LIBRARY_PATH contains the current directory if one of the following
1008 # is true:
1009 # - one of the terminals (":" and ";") is the first or last sign
1010 # - two terminals occur directly after each other
1011 # - the path contains an element with a dot in it
1012 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1013 changequote(,)dnl
1014 case ${LD_LIBRARY_PATH} in
1015 [:\;]* | *[:\;] | *[:\;][:\;]* | *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1016 ld_library_path_setting="contains current directory"
1017 ;;
1018 *)
1019 ld_library_path_setting="ok"
1020 ;;
1021 esac
1022 changequote([,])dnl
1023 AC_MSG_RESULT($ld_library_path_setting)
1024 if test "$ld_library_path_setting" != "ok"; then
1025 AC_MSG_ERROR([
1026 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1027 *** building glibc. Please change the environment variable
1028 *** and run configure again.])
1029 fi
1031 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1032 if $CC -v -static-libgcc 2>&1 | grep 'unrecognized option.*static-libgcc' >/dev/null; then
1033 libc_cv_gcc_static_libgcc=
1034 else
1035 libc_cv_gcc_static_libgcc=-static-libgcc
1036 fi])
1037 AC_SUBST(libc_cv_gcc_static_libgcc)
1039 AC_PATH_PROG(BASH_SHELL, bash, no)
1040 if test "$BASH_SHELL" != no &&
1041 $BASH_SHELL -c 'test "$BASH_VERSINFO" \
1042 && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
1043 libc_cv_have_bash2=yes
1044 else
1045 libc_cv_have_bash2=no
1046 fi
1047 AC_SUBST(libc_cv_have_bash2)
1049 dnl We need a ksh compatible shell for tzselect.
1050 if test "$BASH_SHELL" = no; then
1051 AC_PATH_PROG(KSH, ksh, no)
1052 if test "$KSH" = no; then
1053 libc_cv_have_ksh=no
1054 else
1055 libc_cv_have_ksh=yes
1056 fi
1057 else
1058 KSH="$BASH_SHELL"
1059 AC_SUBST(KSH)
1060 libc_cv_have_ksh=yes
1061 fi
1062 AC_SUBST(libc_cv_have_ksh)
1064 AC_PATH_PROG(PERL, perl, no)
1065 if test "$PERL" != no &&
1066 (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1067 PERL=no
1068 fi
1069 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1070 $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1071 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1073 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1074 AC_TRY_COMPILE(dnl
1075 [#define __need_size_t
1076 #define __need_wchar_t
1077 #include <stddef.h>
1078 #define __need_NULL
1079 #include <stddef.h>], [size_t size; wchar_t wchar;
1080 #ifdef offsetof
1081 #error stddef.h ignored __need_*
1082 #endif
1083 if (&size == NULL || &wchar == NULL) abort ();],
1084 libc_cv_friendly_stddef=yes,
1085 libc_cv_friendly_stddef=no)])
1086 if test $libc_cv_friendly_stddef = yes; then
1087 config_vars="$config_vars
1088 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1089 fi
1091 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1092 libc_cv_need_minus_P, [dnl
1093 cat > conftest.S <<EOF
1094 #include "confdefs.h"
1095 /* Nothing whatsoever. */
1096 EOF
1097 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1098 libc_cv_need_minus_P=no
1099 else
1100 libc_cv_need_minus_P=yes
1101 fi
1102 rm -f conftest*])
1103 if test $libc_cv_need_minus_P = yes; then
1104 config_vars="$config_vars
1105 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1106 fi
1108 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1109 cat > conftest.s <<EOF
1110 ${libc_cv_dot_text}
1111 foo:
1112 .set glibc_conftest_frobozz,foo
1113 .globl glibc_conftest_frobozz
1114 EOF
1115 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1116 # (but it doesn't work), so we must do a linking check to be sure.
1117 cat > conftest1.c <<\EOF
1118 extern int glibc_conftest_frobozz;
1119 void _start() { glibc_conftest_frobozz = 1; }
1120 EOF
1121 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1122 -nostartfiles -nostdlib \
1123 -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1124 libc_cv_asm_set_directive=yes
1125 else
1126 libc_cv_asm_set_directive=no
1127 fi
1128 rm -f conftest*])
1129 if test $libc_cv_asm_set_directive = yes; then
1130 AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1131 fi
1133 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1134 libc_cv_asm_unique_object, [dnl
1135 cat > conftest.s <<EOF
1136 ${libc_cv_dot_text}
1137 _sym:
1138 .type _sym, %gnu_unique_object
1139 EOF
1140 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1141 libc_cv_asm_unique_object=yes
1142 else
1143 libc_cv_asm_unique_object=no
1144 fi
1145 rm -f conftest*])
1146 if test $libc_cv_asm_unique_object = yes; then
1147 AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1148 fi
1150 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
1151 [cat > conftest.s <<EOF
1152 ${libc_cv_dot_text}
1153 _sym:
1154 .symver _sym,sym@VERS
1155 EOF
1156 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1157 libc_cv_asm_symver_directive=yes
1158 else
1159 libc_cv_asm_symver_directive=no
1160 fi
1161 rm -f conftest*])
1162 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
1163 if test $libc_cv_asm_symver_directive = yes; then
1164 cat > conftest.s <<EOF
1165 ${libc_cv_dot_text}
1166 _sym:
1167 .symver _sym,sym@VERS
1168 EOF
1169 cat > conftest.map <<EOF
1170 VERS_1 {
1171 global: sym;
1172 };
1174 VERS_2 {
1175 global: sym;
1176 } VERS_1;
1177 EOF
1178 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1179 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $LDFLAGS -shared
1180 -o conftest.so conftest.o
1181 -nostartfiles -nostdlib
1182 -Wl,--version-script,conftest.map
1183 1>&AS_MESSAGE_LOG_FD]);
1184 then
1185 libc_cv_ld_version_script_option=yes
1186 else
1187 libc_cv_ld_version_script_option=no
1188 fi
1189 else
1190 libc_cv_ld_version_script_option=no
1191 fi
1192 else
1193 libc_cv_ld_version_script_option=no
1194 fi
1195 rm -f conftest*])
1196 if test $shared != no &&
1197 test $libc_cv_asm_symver_directive = yes &&
1198 test $libc_cv_ld_version_script_option = yes &&
1199 test $enable_versioning = yes; then
1200 VERSIONING=yes
1201 AC_DEFINE(DO_VERSIONING)
1202 else
1203 VERSIONING=no
1204 fi
1205 AC_SUBST(VERSIONING)
1207 if test $shared != no && test $VERSIONING = no; then
1208 echo "\
1209 *** WARNING: You should not compile GNU libc without versioning. Not using
1210 *** versioning will introduce incompatibilities so that old binaries
1211 *** will not run anymore.
1212 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
1213 fi
1214 AC_CACHE_CHECK(for .previous assembler directive,
1215 libc_cv_asm_previous_directive, [dnl
1216 cat > conftest.s <<EOF
1217 .section foo_section
1218 .previous
1219 EOF
1220 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1221 libc_cv_asm_previous_directive=yes
1222 else
1223 libc_cv_asm_previous_directive=no
1224 fi
1225 rm -f conftest*])
1226 if test $libc_cv_asm_previous_directive = yes; then
1227 AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1228 else
1229 AC_CACHE_CHECK(for .popsection assembler directive,
1230 libc_cv_asm_popsection_directive, [dnl
1231 cat > conftest.s <<EOF
1232 .pushsection foo_section
1233 .popsection
1234 EOF
1235 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1236 libc_cv_asm_popsection_directive=yes
1237 else
1238 libc_cv_asm_popsection_directive=no
1239 fi
1240 rm -f conftest*])
1241 if test $libc_cv_asm_popsection_directive = yes; then
1242 AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1243 fi
1244 fi
1245 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1246 libc_cv_asm_protected_directive, [dnl
1247 cat > conftest.s <<EOF
1248 .protected foo
1249 foo:
1250 .hidden bar
1251 bar:
1252 EOF
1253 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1254 libc_cv_asm_protected_directive=yes
1255 else
1256 AC_MSG_ERROR(assembler support for symbol visibility is required)
1257 fi
1258 rm -f conftest*])
1260 if test $libc_cv_asm_protected_directive = yes; then
1261 AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1262 libc_cv_visibility_attribute,
1263 [cat > conftest.c <<EOF
1264 int foo __attribute__ ((visibility ("hidden"))) = 1;
1265 int bar __attribute__ ((visibility ("protected"))) = 1;
1266 EOF
1267 libc_cv_visibility_attribute=no
1268 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1269 if grep '\.hidden.*foo' conftest.s >/dev/null; then
1270 if grep '\.protected.*bar' conftest.s >/dev/null; then
1271 libc_cv_visibility_attribute=yes
1272 fi
1273 fi
1274 fi
1275 rm -f conftest.{c,s}
1276 ])
1277 if test $libc_cv_visibility_attribute != yes; then
1278 AC_MSG_ERROR(compiler support for visibility attribute is required)
1279 fi
1280 fi
1282 if test $libc_cv_visibility_attribute = yes; then
1283 AC_CACHE_CHECK(for broken __attribute__((visibility())),
1284 libc_cv_broken_visibility_attribute,
1285 [cat > conftest.c <<EOF
1286 int foo (int x);
1287 int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1288 int bar (int x) { return x; }
1289 EOF
1290 libc_cv_broken_visibility_attribute=yes
1291 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1292 changequote(,)dnl
1293 if grep '\.hidden[ _]foo' conftest.s >/dev/null; then
1294 changequote([,])dnl
1295 libc_cv_broken_visibility_attribute=no
1296 fi
1297 fi
1298 rm -f conftest.c conftest.s
1299 ])
1300 if test $libc_cv_broken_visibility_attribute = yes; then
1301 AC_MSG_ERROR(working compiler support for visibility attribute is required)
1302 fi
1303 fi
1305 AC_CACHE_CHECK(for broken __attribute__((alias())),
1306 libc_cv_broken_alias_attribute,
1307 [cat > conftest.c <<EOF
1308 extern int foo (int x) __asm ("xyzzy");
1309 int bar (int x) { return x; }
1310 extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1311 extern int dfoo;
1312 extern __typeof (dfoo) dfoo __asm ("abccb");
1313 int dfoo = 1;
1314 EOF
1315 libc_cv_broken_alias_attribute=yes
1316 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1317 if grep 'xyzzy' conftest.s >/dev/null &&
1318 grep 'abccb' conftest.s >/dev/null; then
1319 libc_cv_broken_alias_attribute=no
1320 fi
1321 fi
1322 rm -f conftest.c conftest.s
1323 ])
1324 if test $libc_cv_broken_alias_attribute = yes; then
1325 AC_MSG_ERROR(working alias attribute support required)
1326 fi
1328 if test $libc_cv_visibility_attribute = yes; then
1329 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1330 libc_cv_have_sdata_section,
1331 [echo "int i;" > conftest.c
1332 libc_cv_have_sdata_section=no
1333 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1334 | grep '\.sdata' >/dev/null; then
1335 libc_cv_have_sdata_section=yes
1336 fi
1337 rm -f conftest.c conftest.so
1338 ])
1339 if test $libc_cv_have_sdata_section = yes; then
1340 AC_DEFINE(HAVE_SDATA_SECTION)
1341 fi
1342 fi
1344 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1345 libc_cv_initfini_array, [dnl
1346 LIBC_TRY_LINK_STATIC([
1347 int foo (void) { return 1; }
1348 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1349 ],
1350 [if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1351 libc_cv_initfini_array=yes
1352 else
1353 libc_cv_initfini_array=no
1354 fi],
1355 [libc_cv_initfini_array=no])
1356 ])
1357 if test $libc_cv_initfini_array != yes; then
1358 AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1359 fi
1361 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1362 libc_cv_ctors_header, [dnl
1363 libc_cv_ctors_header=yes
1364 LIBC_TRY_LINK_STATIC([
1365 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1366 __attribute__ ((destructor)) void dtor (void) { asm (""); }
1367 ],
1368 [dnl
1369 AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1370 { gsub(/\@<:@ */, "@<:@") }
1371 $2 == ".ctors" || $2 == ".dtors" {
1372 size = strtonum("0x" $6)
1373 align = strtonum("0x" $NF)
1374 seen@<:@$2@:>@ = 1
1375 stub@<:@$2@:>@ = size == align * 2
1376 }
1377 END {
1378 ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1379 dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1380 exit ((ctors_ok && dtors_ok) ? 0 : 1)
1381 }
1382 '], [libc_cv_ctors_header=no])
1383 ], [dnl
1384 AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1385 ])
1386 ])
1387 if test $libc_cv_ctors_header = no; then
1388 AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1389 fi
1391 AC_CACHE_CHECK(for libunwind-support in compiler,
1392 libc_cv_cc_with_libunwind, [
1393 cat > conftest.c <<EOF
1394 int main (void) { return 0; }
1395 EOF
1396 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1397 conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1398 libc_cv_cc_with_libunwind=yes
1399 else
1400 libc_cv_cc_with_libunwind=no
1401 fi
1402 rm -f conftest*])
1403 AC_SUBST(libc_cv_cc_with_libunwind)
1404 if test $libc_cv_cc_with_libunwind = yes; then
1405 AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1406 fi
1408 AC_CACHE_CHECK(for -z nodelete option,
1409 libc_cv_z_nodelete, [dnl
1410 cat > conftest.c <<EOF
1411 int _start (void) { return 42; }
1412 EOF
1413 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1414 -fPIC -shared -o conftest.so conftest.c
1415 -nostartfiles -nostdlib
1416 -Wl,--enable-new-dtags,-z,nodelete 1>&AS_MESSAGE_LOG_FD])
1417 then
1418 libc_cv_z_nodelete=yes
1419 else
1420 AC_MSG_ERROR(linker with -z nodelete support required)
1421 fi
1422 rm -f conftest*])
1424 AC_CACHE_CHECK(for -z nodlopen option,
1425 libc_cv_z_nodlopen, [dnl
1426 cat > conftest.c <<EOF
1427 int _start (void) { return 42; }
1428 EOF
1429 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1430 -fPIC -shared -o conftest.so conftest.c
1431 -nostartfiles -nostdlib
1432 -Wl,--enable-new-dtags,-z,nodlopen 1>&AS_MESSAGE_LOG_FD])
1433 then
1434 libc_cv_z_nodlopen=yes
1435 else
1436 AC_MSG_ERROR(linker with -z nodlopen support required)
1437 fi
1438 rm -f conftest*])
1440 AC_CACHE_CHECK(for -z initfirst option,
1441 libc_cv_z_initfirst, [dnl
1442 cat > conftest.c <<EOF
1443 int _start (void) { return 42; }
1444 EOF
1445 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1446 -fPIC -shared -o conftest.so conftest.c
1447 -nostartfiles -nostdlib
1448 -Wl,--enable-new-dtags,-z,initfirst 1>&AS_MESSAGE_LOG_FD])
1449 then
1450 libc_cv_z_initfirst=yes
1451 else
1452 AC_MSG_ERROR(linker with -z initfirst support required)
1453 fi
1454 rm -f conftest*])
1456 # Add-on fragments can set these for other machines.
1457 libc_commonpagesize=${libc_commonpagesize:-no}
1458 libc_relro_required=${libc_relro_required:-no}
1459 case "$base_machine" in
1460 i[[34567]]86 | x86_64 | powerpc* | s390*)
1461 libc_commonpagesize=0x1000
1462 libc_relro_required=yes
1463 ;;
1464 sparc*)
1465 libc_commonpagesize=0x2000
1466 libc_relro_required=yes
1467 ;;
1468 esac
1470 if test $libc_commonpagesize != no; then
1471 AC_CACHE_CHECK(for -z relro option,
1472 libc_cv_z_relro, [dnl
1473 libc_cv_z_relro=no
1474 AC_LANG_CONFTEST([AC_LANG_SOURCE([[
1475 int _start (void) { return 42; }
1476 extern void _exit (int);
1477 /* Since these pointers are const, they should go in rodata.
1478 Since they refer to functions that have to be resolved by
1479 dynamic linking, they should instead go in RELRO data. */
1480 const void *const relro[] = { &_start, &_exit, 0 };
1481 /* GNU ld fails to produce RELRO data when it's very small and there is no
1482 normal writable data following it, or if only uninitialized (.bss) data
1483 follows it, or only very small writable data. */
1484 int data[0x10000] = { 1, };
1485 ]])])
1486 cat > conftest.awk <<\EOF
1487 BEGIN {
1488 result = "no"
1489 commonpagesize = strtonum(commonpagesize)
1490 }
1491 { print "LINE:", $0 > "/dev/stderr" }
1492 $1 == "GNU_RELRO" {
1493 vaddr = strtonum($3)
1494 memsz = strtonum($6)
1495 end = vaddr + memsz
1496 printf "vaddr %#x memsz %#x end %#x commonpagesize %#x\n", \
1497 vaddr, memsz, end, commonpagesize > "/dev/stderr"
1498 result = (end % commonpagesize == 0) ? "yes" : "broken"
1499 }
1500 END { print result }
1501 EOF
1502 AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1503 -fPIC -shared -o conftest.so conftest.c
1504 -nostartfiles -nostdlib
1505 -Wl,-z,relro 1>&AS_MESSAGE_LOG_FD]) &&
1506 AC_TRY_COMMAND([$READELF -Wl conftest.so > conftest.ph]) &&
1507 AC_TRY_COMMAND([
1508 $AWK -v commonpagesize=$libc_commonpagesize -f conftest.awk
1509 conftest.ph > conftest.cps
1510 ]) &&
1511 libc_cv_z_relro=`cat conftest.cps 2>&AS_MESSAGE_LOG_FD`
1512 rm -f conftest*])
1513 if { test "x$libc_relro_required" = xyes &&
1514 test "x$libc_cv_z_relro" != xyes
1515 }
1516 then
1517 AC_MSG_ERROR(linker with -z relro support required)
1518 fi
1519 else
1520 AC_MSG_WARN([missing architecture parameter to check for working -z relro])
1521 fi
1523 AC_CACHE_CHECK(for -Bgroup option,
1524 libc_cv_Bgroup, [dnl
1525 cat > conftest.c <<EOF
1526 int _start (void) { return 42; }
1527 EOF
1528 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1529 -fPIC -shared -o conftest.so conftest.c
1530 -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1531 then
1532 libc_cv_Bgroup=yes
1533 else
1534 libc_cv_Bgroup=no
1535 fi
1536 rm -f conftest*])
1537 AC_SUBST(libc_cv_Bgroup)
1539 ASFLAGS_config=
1540 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1541 libc_cv_as_noexecstack, [dnl
1542 cat > conftest.c <<EOF
1543 void foo (void) { }
1544 EOF
1545 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1546 -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1547 && grep .note.GNU-stack conftest.s >/dev/null \
1548 && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1549 -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1550 then
1551 libc_cv_as_noexecstack=yes
1552 else
1553 libc_cv_as_noexecstack=no
1554 fi
1555 rm -f conftest*])
1556 if test $libc_cv_as_noexecstack = yes; then
1557 ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1558 fi
1559 AC_SUBST(ASFLAGS_config)
1561 AC_CACHE_CHECK(for -z combreloc,
1562 libc_cv_z_combreloc, [dnl
1563 cat > conftest.c <<EOF
1564 extern int bar (int);
1565 extern int mumble;
1566 int foo (void) { return bar (mumble); }
1567 EOF
1568 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1569 -fPIC -shared -o conftest.so conftest.c
1570 -nostdlib -nostartfiles
1571 -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1572 then
1573 dnl The following test is a bit weak. We must use a tool which can test
1574 dnl cross-platform since the gcc used can be a cross compiler. Without
1575 dnl introducing new options this is not easily doable. Instead use a tool
1576 dnl which always is cross-platform: readelf. To detect whether -z combreloc
1577 dnl look for a section named .rel.dyn.
1578 if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1579 libc_cv_z_combreloc=yes
1580 else
1581 libc_cv_z_combreloc=no
1582 fi
1583 else
1584 libc_cv_z_combreloc=no
1585 fi
1586 rm -f conftest*])
1587 if test "$libc_cv_z_combreloc" = yes; then
1588 AC_DEFINE(HAVE_Z_COMBRELOC)
1589 fi
1590 AC_SUBST(libc_cv_z_combreloc)
1592 AC_CACHE_CHECK(for -z execstack,
1593 libc_cv_z_execstack, [dnl
1594 cat > conftest.c <<EOF
1595 int _start (void) { return 42; }
1596 EOF
1597 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1598 -fPIC -shared -o conftest.so conftest.c
1599 -Wl,-z,execstack -nostdlib
1600 1>&AS_MESSAGE_LOG_FD])
1601 then
1602 libc_cv_z_execstack=yes
1603 else
1604 libc_cv_z_execstack=no
1605 fi
1606 rm -f conftest*])
1607 AC_SUBST(libc_cv_z_execstack)
1609 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1610 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1611 ])
1613 AC_SUBST(libc_cv_fpie)
1615 AC_CACHE_CHECK(for --hash-style option,
1616 libc_cv_hashstyle, [dnl
1617 cat > conftest.c <<EOF
1618 int _start (void) { return 42; }
1619 EOF
1620 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1621 -fPIC -shared -o conftest.so conftest.c
1622 -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1623 then
1624 libc_cv_hashstyle=yes
1625 else
1626 libc_cv_hashstyle=no
1627 fi
1628 rm -f conftest*])
1629 AC_SUBST(libc_cv_hashstyle)
1631 # The linker's default -shared behavior is good enough if it
1632 # does these things that our custom linker scripts ensure that
1633 # all allocated NOTE sections come first.
1634 if test "$use_default_link" = default; then
1635 AC_CACHE_CHECK([for sufficient default -shared layout],
1636 libc_cv_use_default_link, [dnl
1637 libc_cv_use_default_link=no
1638 cat > conftest.s <<\EOF
1639 .section .note.a,"a",%note
1640 .balign 4
1641 .long 4,4,9
1642 .string "GNU"
1643 .string "foo"
1644 .section .note.b,"a",%note
1645 .balign 4
1646 .long 4,4,9
1647 .string "GNU"
1648 .string "bar"
1649 EOF
1650 if AC_TRY_COMMAND([dnl
1651 ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1652 ac_try=`$READELF -S conftest.so | sed -n \
1653 ['${x;p;}
1654 s/^ *\[ *[1-9][0-9]*\] *\([^ ][^ ]*\) *\([^ ][^ ]*\) .*$/\2 \1/
1655 t a
1656 b
1657 : a
1658 H']`
1659 then
1660 libc_seen_a=no libc_seen_b=no
1661 set -- $ac_try
1662 while test $# -ge 2 -a "$1" = NOTE; do
1663 case "$2" in
1664 .note.a) libc_seen_a=yes ;;
1665 .note.b) libc_seen_b=yes ;;
1666 esac
1667 shift 2
1668 done
1669 case "$libc_seen_a$libc_seen_b" in
1670 yesyes)
1671 libc_cv_use_default_link=yes
1672 ;;
1673 *)
1674 echo >&AS_MESSAGE_LOG_FD "\
1675 $libc_seen_a$libc_seen_b from:
1676 $ac_try"
1677 ;;
1678 esac
1679 fi
1680 rm -f conftest*])
1681 use_default_link=$libc_cv_use_default_link
1682 fi
1684 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1685 if libc_cv_output_format=`
1686 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1687 then
1688 :
1689 else
1690 libc_cv_output_format=
1691 fi
1692 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1693 AC_SUBST(libc_cv_output_format)
1695 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1696 cat > conftest.c <<EOF
1697 int foo;
1698 EOF
1699 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1700 conftest.c 1>&AS_MESSAGE_LOG_FD])
1701 then
1702 libc_cv_fno_toplevel_reorder=yes
1703 else
1704 libc_cv_fno_toplevel_reorder=no
1705 fi
1706 rm -f conftest*])
1707 if test $libc_cv_fno_toplevel_reorder = yes; then
1708 fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1709 else
1710 fno_unit_at_a_time=-fno-unit-at-a-time
1711 fi
1712 AC_SUBST(fno_unit_at_a_time)
1714 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1715 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1716 [libc_cv_ssp=yes],
1717 [libc_cv_ssp=no])
1718 ])
1719 AC_SUBST(libc_cv_ssp)
1721 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1722 cat > conftest.c <<EOF
1723 int foo;
1724 #ifdef __GNUC_GNU_INLINE__
1725 main () { return 0;}
1726 #else
1727 #error
1728 #endif
1729 EOF
1730 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1731 -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1732 then
1733 libc_cv_gnu89_inline=yes
1734 else
1735 libc_cv_gnu89_inline=no
1736 fi
1737 rm -f conftest*])
1738 if test $libc_cv_gnu89_inline = yes; then
1739 gnu89_inline=-fgnu89-inline
1740 else
1741 gnu89_inline=
1742 fi
1743 AC_SUBST(gnu89_inline)
1745 AC_CACHE_CHECK(whether cc puts quotes around section names,
1746 libc_cv_have_section_quotes,
1747 [cat > conftest.c <<EOF
1748 static const int foo
1749 __attribute__ ((section ("bar"))) = 1;
1750 EOF
1751 if ${CC-cc} -S conftest.c -o conftest.s; then
1752 if grep '\.section.*"bar"' conftest.s >/dev/null; then
1753 libc_cv_have_section_quotes=yes
1754 else
1755 libc_cv_have_section_quotes=no
1756 fi
1757 else
1758 libc_cv_have_section_quotes=unknown
1759 fi
1760 rm -f conftest.{c,s}
1761 ])
1762 if test $libc_cv_have_section_quotes = yes; then
1763 AC_DEFINE(HAVE_SECTION_QUOTES)
1764 fi
1766 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1767 [dnl
1768 cat > conftest.s <<EOF
1769 ${libc_cv_dot_text}
1770 .globl foo
1771 foo:
1772 .weak foo
1773 .weak bar; bar = foo
1774 EOF
1775 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1776 libc_cv_asm_weak_directive=yes
1777 else
1778 libc_cv_asm_weak_directive=no
1779 fi
1780 rm -f conftest*])
1782 if test $libc_cv_asm_weak_directive = no; then
1783 AC_CACHE_CHECK(for assembler .weakext directive,
1784 libc_cv_asm_weakext_directive,
1785 [dnl
1786 cat > conftest.s <<EOF
1787 ${libc_cv_dot_text}
1788 .globl foo
1789 foo:
1790 .weakext bar foo
1791 .weakext baz
1792 .globl baz
1793 baz:
1794 EOF
1795 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1796 libc_cv_asm_weakext_directive=yes
1797 else
1798 libc_cv_asm_weakext_directive=no
1799 fi
1800 rm -f conftest*])
1802 fi # no .weak
1804 if test $libc_cv_asm_weak_directive = yes; then
1805 AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1806 elif test $libc_cv_asm_weakext_directive = yes; then
1807 AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1808 fi
1810 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1811 case $machine in
1812 sparc/sparc64*) cfi_offset=2047;;
1813 *) cfi_offset=0;;
1814 esac
1815 cat > conftest.s <<EOF
1816 .text
1817 .type func,%function
1818 func:
1819 .cfi_startproc
1820 .cfi_remember_state
1821 .cfi_rel_offset 1, $cfi_offset
1822 .cfi_endproc
1823 EOF
1824 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1825 libc_cv_asm_cfi_directives=yes
1826 else
1827 libc_cv_asm_cfi_directives=no
1828 fi
1829 rm -f conftest*])
1830 if test $libc_cv_asm_cfi_directives = yes; then
1831 AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1832 fi
1834 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1835 cat > conftest.c <<\EOF
1836 _start () {}
1837 int __eh_pc;
1838 __throw () {}
1839 EOF
1840 dnl No \ in command here because it ends up inside ''.
1841 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1842 -nostdlib -nostartfiles -Wl,--no-whole-archive
1843 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1844 libc_cv_ld_no_whole_archive=yes
1845 else
1846 libc_cv_ld_no_whole_archive=no
1847 fi
1848 rm -f conftest*])
1849 if test $libc_cv_ld_no_whole_archive = no; then
1850 AC_MSG_ERROR([support for --no-whole-archive is needed])
1851 fi
1853 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1854 cat > conftest.c <<\EOF
1855 _start () {}
1856 int __eh_pc;
1857 __throw () {}
1858 EOF
1859 dnl No \ in command here because it ends up inside ''.
1860 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1861 -nostdlib -nostartfiles -fexceptions
1862 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1863 libc_cv_gcc_exceptions=yes
1864 else
1865 libc_cv_gcc_exceptions=no
1866 fi
1867 rm -f conftest*])
1868 if test $libc_cv_gcc_exceptions = yes; then
1869 exceptions=-fexceptions
1870 fi
1871 AC_SUBST(exceptions)dnl
1873 if test "$host_cpu" = powerpc ; then
1874 # Check for a bug present in at least versions 2.8.x of GCC
1875 # and versions 1.0.x of EGCS.
1876 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1877 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1878 libc_cv_c_asmcr0_bug='no',
1879 libc_cv_c_asmcr0_bug='yes')])
1880 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1881 AC_DEFINE(BROKEN_PPC_ASM_CR0)
1882 fi
1883 fi
1885 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1886 cat > conftest.c <<\EOF
1887 void zero (void *x)
1888 {
1889 __builtin_memset (x, 0, 1000);
1890 }
1891 EOF
1892 dnl
1893 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1894 then
1895 libc_cv_gcc_builtin_memset=no
1896 else
1897 libc_cv_gcc_builtin_memset=yes
1898 fi
1899 rm -f conftest* ])
1900 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1901 AC_DEFINE(HAVE_BUILTIN_MEMSET)
1902 fi
1904 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1905 cat > conftest.c <<\EOF
1906 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1907 char *foo (const char *a, const char *b)
1908 {
1909 return __builtin_strstr (a, b);
1910 }
1911 EOF
1912 dnl
1913 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1914 then
1915 libc_cv_gcc_builtin_redirection=yes
1916 else
1917 libc_cv_gcc_builtin_redirection=no
1918 fi
1919 rm -f conftest* ])
1920 if test "$libc_cv_gcc_builtin_redirection" = no; then
1921 AC_MSG_ERROR([support for the symbol redirection needed])
1922 fi
1924 dnl Check whether the compiler supports the __thread keyword.
1925 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1926 [cat > conftest.c <<\EOF
1927 __thread int a = 42;
1928 EOF
1929 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1930 libc_cv_gcc___thread=yes
1931 else
1932 libc_cv_gcc___thread=no
1933 fi
1934 rm -f conftest*])
1935 if test "$libc_cv_gcc___thread" = no; then
1936 AC_MSG_ERROR([support for the __thread keyword is required])
1937 fi
1939 dnl Check whether the compiler supports the tls_model attribute.
1940 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1941 cat > conftest.c <<\EOF
1942 extern __thread int a __attribute__((tls_model ("initial-exec")));
1943 EOF
1944 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
1945 libc_cv_gcc_tls_model_attr=yes
1946 else
1947 libc_cv_gcc_tls_model_attr=no
1948 fi
1949 rm -f conftest*])
1950 if test "$libc_cv_gcc_tls_model_attr" = no; then
1951 AC_MSG_ERROR([support for the tls_model attribute is required])
1952 fi
1954 dnl Determine how to disable generation of FMA instructions.
1955 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1956 libc_cv_cc_nofma, [dnl
1957 libc_cv_cc_nofma=
1958 for opt in -ffp-contract=off -mno-fused-madd; do
1959 LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1960 done])
1962 if test -n "$submachine"; then
1963 AC_CACHE_CHECK([for compiler option for CPU variant],
1964 libc_cv_cc_submachine, [dnl
1965 libc_cv_cc_submachine=no
1966 for opt in "-march=$submachine" "-mcpu=$submachine"; do
1967 LIBC_TRY_CC_OPTION([$opt], [
1968 libc_cv_cc_submachine="$opt"
1969 break], [])
1970 done])
1971 if test "x$libc_cv_cc_submachine" = xno; then
1972 AC_MSG_ERROR([${CC-cc} does not support $submachine])
1973 fi
1974 fi
1975 AC_SUBST(libc_cv_cc_submachine)
1977 dnl Check whether we have the gd library available.
1978 AC_MSG_CHECKING(for libgd)
1979 if test "$with_gd" != "no"; then
1980 old_CFLAGS="$CFLAGS"
1981 CFLAGS="$CFLAGS $libgd_include"
1982 old_LDFLAGS="$LDFLAGS"
1983 LDFLAGS="$LDFLAGS $libgd_ldflags"
1984 old_LIBS="$LIBS"
1985 LIBS="$LIBS -lgd -lpng -lz -lm"
1986 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1987 CFLAGS="$old_CFLAGS"
1988 LDFLAGS="$old_LDFLAGS"
1989 LIBS="$old_LIBS"
1990 else
1991 LIBGD=no
1992 fi
1993 AC_MSG_RESULT($LIBGD)
1994 AC_SUBST(LIBGD)
1996 # SELinux detection
1997 if test x$with_selinux = xno ; then
1998 have_selinux=no;
1999 else
2000 # See if we have the SELinux library
2001 AC_CHECK_LIB(selinux, is_selinux_enabled,
2002 have_selinux=yes, have_selinux=no)
2003 # See if we have the SELinux header with the NSCD permissions in it.
2004 if test x$have_selinux = xyes ; then
2005 AC_MSG_CHECKING([for NSCD Flask permissions in selinux/av_permissions.h])
2006 AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
2007 [#ifdef NSCD__SHMEMHOST
2008 return 0;
2009 #else
2010 #error NSCD__SHMEMHOST not defined
2011 #endif],
2012 have_selinux=yes, have_selinux=no)
2013 AC_MSG_RESULT($have_selinux)
2014 fi
2016 if test x$with_selinux = xyes ; then
2017 if test x$have_selinux = xno ; then
2018 AC_MSG_ERROR([SELinux explicitly required, but sufficiently recent SELinux library not found])
2019 fi
2020 fi
2021 fi
2022 # Check if we're building with SELinux support.
2023 if test "x$have_selinux" = xyes; then
2024 AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
2026 # See if we have the libaudit library
2027 AC_CHECK_LIB(audit, audit_log_user_avc_message,
2028 have_libaudit=yes, have_libaudit=no)
2029 if test "x$have_libaudit" = xyes; then
2030 AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
2031 fi
2032 AC_SUBST(have_libaudit)
2034 # See if we have the libcap library
2035 AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
2036 if test "x$have_libcap" = xyes; then
2037 AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
2038 fi
2039 AC_SUBST(have_libcap)
2040 fi
2041 AC_SUBST(have_selinux)
2043 dnl check for the size of 'long double'.
2044 AC_CHECK_SIZEOF(long double, 0)
2045 sizeof_long_double=$ac_cv_sizeof_long_double
2046 AC_SUBST(sizeof_long_double)
2048 CPPUNDEFS=
2049 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
2050 dnl Since we are building the implementations of the fortified functions here,
2051 dnl having the macro defined interacts very badly.
2052 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
2053 [AC_TRY_COMPILE([], [
2054 #ifdef _FORTIFY_SOURCE
2055 # error bogon
2056 #endif],
2057 [libc_cv_predef_fortify_source=no],
2058 [libc_cv_predef_fortify_source=yes])])
2059 if test $libc_cv_predef_fortify_source = yes; then
2060 CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
2061 fi
2062 AC_SUBST(CPPUNDEFS)
2064 dnl Check for silly hacked compilers inserting -fstack-protector.
2065 dnl This breaks badly for the early startup code we compile, since
2066 dnl the compiled code can refer to a magic machine-dependent location
2067 dnl for the canary value before we have sufficient setup for that to
2068 dnl work. It's also questionable to build all of libc with this flag
2069 dnl even when you're doing that for most applications you build, since
2070 dnl libc's code is so heavily-used and performance-sensitive. If we
2071 dnl ever really want to make that work, it should be enabled explicitly
2072 dnl in the libc build, not inherited from implicit compiler settings.
2073 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
2074 libc_cv_predef_stack_protector, [
2075 AC_TRY_COMPILE([extern void foobar (char *);],
2076 [char large_array[2048]; foobar (large_array);], [
2077 libc_undefs=`$NM -u conftest.o |
2078 LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
2079 2>&AS_MESSAGE_LOG_FD` || {
2080 AC_MSG_ERROR([confusing output from $NM -u])
2081 }
2082 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
2083 # On some architectures, there are architecture-specific undefined
2084 # symbols (resolved by the linker), so filter out unknown symbols.
2085 # This will fail to produce the correct result if the compiler
2086 # defaults to -fstack-protector but this produces an undefined symbol
2087 # other than __stack_chk_fail. However, compilers like that have not
2088 # been encountered in practice.
2089 libc_undefs=`echo "$libc_undefs" | egrep '^(foobar|__stack_chk_fail)$'`
2090 case "$libc_undefs" in
2091 foobar) libc_cv_predef_stack_protector=no ;;
2092 '__stack_chk_fail
2093 foobar') libc_cv_predef_stack_protector=yes ;;
2094 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
2095 esac],
2096 [AC_MSG_ERROR([test compilation failed])])
2097 ])
2098 libc_extra_cflags=
2099 if test $libc_cv_predef_stack_protector = yes; then
2100 libc_extra_cflags=-fno-stack-protector
2101 fi
2102 AC_SUBST(libc_extra_cflags)
2104 ### End of automated tests.
2105 ### Now run sysdeps configure fragments.
2107 # They also can set these variables.
2108 use_ldconfig=no
2109 ldd_rewrite_script=no
2110 libc_cv_sysconfdir=$sysconfdir
2111 libc_cv_localstatedir=$localstatedir
2112 libc_cv_gcc_unwind_find_fde=no
2113 libc_cv_idn=no
2115 # Iterate over all the sysdep directories we will use, running their
2116 # configure fragments.
2117 for dir in $sysnames; do
2118 case $dir in
2119 /*) dest=$dir ;;
2120 *) dest=$srcdir/$dir ;;
2121 esac
2122 if test -r $dest/configure; then
2123 AC_MSG_RESULT(running configure fragment for $dir)
2124 . $dest/configure
2125 fi
2126 done
2128 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2129 AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2130 fi
2131 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2133 # A sysdeps configure fragment can reset this if IFUNC is not actually
2134 # usable even though the assembler knows how to generate the symbol type.
2135 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
2136 AC_DEFINE(HAVE_IFUNC)
2137 fi
2139 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
2140 # configure fragment can override the value to prevent this AC_DEFINE.
2141 AC_SUBST(use_nscd)
2142 if test "x$use_nscd" != xno; then
2143 AC_DEFINE([USE_NSCD])
2144 fi
2145 if test "x$build_nscd" = xdefault; then
2146 build_nscd=$use_nscd
2147 fi
2149 # Test for old glibc 2.0.x headers so that they can be removed properly
2150 # Search only in includedir.
2151 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2152 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2153 then
2154 old_glibc_headers=yes
2155 else
2156 old_glibc_headers=no
2157 fi
2158 AC_MSG_RESULT($old_glibc_headers)
2159 if test ${old_glibc_headers} = yes; then
2160 AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2161 AC_MSG_WARN(*** be removed.)
2162 fi
2163 AC_SUBST(old_glibc_headers)
2165 AC_SUBST(libc_cv_slibdir)
2166 AC_SUBST(libc_cv_localedir)
2167 AC_SUBST(libc_cv_sysconfdir)
2168 AC_SUBST(libc_cv_localstatedir)
2169 AC_SUBST(libc_cv_rootsbindir)
2170 AC_SUBST(libc_cv_forced_unwind)
2172 dnl sysdeps/CPU/configure.in checks set this via arch-specific asm tests
2173 AC_SUBST(libc_cv_cc_sse4)
2174 AC_SUBST(libc_cv_cc_avx)
2175 AC_SUBST(libc_cv_cc_sse2avx)
2176 AC_SUBST(libc_cv_cc_novzeroupper)
2177 AC_SUBST(libc_cv_cc_fma4)
2178 AC_SUBST(libc_cv_cc_nofma)
2179 AC_SUBST(libc_cv_as_i686)
2180 AC_SUBST(libc_cv_sparc_as_vis3)
2182 if test x$use_ldconfig = xyes; then
2183 AC_DEFINE(USE_LDCONFIG)
2184 fi
2185 AC_SUBST(use_ldconfig)
2186 AC_SUBST(ldd_rewrite_script)
2188 AC_SUBST(static)
2189 AC_SUBST(shared)
2191 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2192 [libc_cv_pic_default=yes
2193 cat > conftest.c <<EOF
2194 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2195 # error PIC is default.
2196 #endif
2197 EOF
2198 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2199 libc_cv_pic_default=no
2200 fi
2201 rm -f conftest.*])
2202 AC_SUBST(libc_cv_pic_default)
2204 AC_SUBST(profile)
2205 AC_SUBST(static_nss)
2207 AC_SUBST(DEFINES)
2209 dnl See sysdeps/mach/configure.in for this variable.
2210 AC_SUBST(mach_interface_list)
2212 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2213 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2214 AC_SUBST(VERSION)
2215 AC_SUBST(RELEASE)
2217 AC_CONFIG_FILES([config.make Makefile])
2218 AC_CONFIG_COMMANDS([default],[[
2219 case $CONFIG_FILES in *config.make*)
2220 echo "$config_vars" >> config.make;;
2221 esac
2222 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2223 AC_OUTPUT