configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.10)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37   --with-fp               if using floating-point hardware,
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(gnu-binutils, dnl
  40   --with-gnu-binutils     if using GNU binutils (as and ld),
  41             gnu_binutils=$withval, gnu_binutils=no)
  42 AC_ARG_WITH(gnu-ld, dnl
  43   --with-gnu-ld           if using GNU ld (in the binutils package),
  44             gnu_ld=$withval, gnu_ld=no)
  45 AC_ARG_WITH(gnu-as, dnl
  46   --with-gnu-as           if using GNU as (in the binutils package),
  47             gnu_as=$withval, gnu_as=no)
  48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  49 AC_ARG_WITH(elf, dnl
  50   --with-elf              if using the ELF object format,
  51             elf=$withval, elf=no)
  52
  53 AC_ARG_ENABLE(libio, dnl
  54 [  --enable-libio          build in GNU libio instead of GNU stdio],
  55               [if test $enableval = yes; then
  56                  stdio=libio
  57                else
  58                  stdio=stdio
  59                fi],
  60               stdio=default)
  61
  62 dnl Arguments to enable or disable building the shared, profiled, and
  63 dnl -fomit-frame-pointer libraries.
  64 AC_ARG_ENABLE(shared, dnl
  65 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  66             shared=$enableval, shared=default)
  67 AC_ARG_ENABLE(profile, dnl
  68 [  --enable-profile        build profiled library [default=yes]],
  69             profile=$enableval, profile=yes)
  70 AC_ARG_ENABLE(omitfp, dnl
  71 [  --enable-omitfp       build undebuggable optimized library [default=no]],
  72             omitfp=$enableval, omitfp=no)
  73
  74 AC_CANONICAL_HOST
  75 # We keep the original values in `$config_*' and never modify them, so we
  76 # can write them unchanged into config.make.  Everything else uses
  77 # $machine, $vendor, and $os, and changes them whenever convenient.
  78 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
  79
  80 # Some configurations imply other options.
  81 case "$host_os" in
  82 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
  83   # These systems always use GNU tools.
  84   gnu_ld=yes gnu_as=yes ;;
  85 esac
  86 case "$host_os" in
  87 gnu* | linux* | sysv4* | solaris2*)
  88   # These systems always use the ELF format.
  89   elf=yes ;;
  90 esac
  91
  92 # Linux/Alpha does not use ELF yet.
  93 case "$host_cpu-$host_os" in
  94 alpha*-linux*)
  95   gnu_ld=no elf=no ;;
  96 esac
  97
  98 machine=$config_machine
  99 vendor=$config_vendor
 100 os=$config_os
 101
 102 dnl We need to use [ and ] for other purposes for a while now.
 103 changequote(,)dnl
 104 # Expand the configuration machine name into a subdirectory by architecture
 105 # type and particular chip.
 106 case "$machine" in
 107 a29k | am29000) base_machine=a29k machine=a29k ;;
 108 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 109 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 110 i[345]86)       base_machine=i386 machine=i386/$machine ;;
 111 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 112 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 113 m88???)         base_machine=m88k machine=m88k/$machine ;;
 114 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 115 mips*)          base_machine=mips machine=mips/$machine ;;
 116 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 117 sparc[6789])    base_machine=sparc machine=sparc/$machine ;;
 118 supersparc)     base_machine=sparc machine=sparc/sparc8 ;;
 119 esac
 120 changequote([,])dnl
 121 AC_SUBST(base_machine)
 122
 123 # Compute the list of sysdep directories for this configuration.
 124 sysdep_dir=$srcdir/sysdeps
 125 AC_CACHE_CHECK(sysdep dirs, libc_cv_sysdirs, [dnl
 126 dnl We need to use [ and ] for other purposes for a while now.
 127 changequote(,)dnl
 128 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 129 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 130
 131 case "$os" in
 132 gnu*)
 133   base_os=mach/hurd ;;
 134 netbsd* | 386bsd* | freebsd* | bsdi*)
 135   base_os=unix/bsd/bsd4.4 ;;
 136 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 137   base_os=unix/bsd ;;
 138 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 139   base_os=unix/sysv ;;
 140 solaris[2-9]*)
 141   base_os=unix/sysv/sysv4 ;;
 142 none)
 143   base_os=standalone ;;
 144 *)
 145   base_os='' ;;
 146 esac
 147
 148 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 149 tail=$os
 150 ostry=$os
 151 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 152   ostry="$ostry /$o"
 153   tail=$o
 154 done
 155 o=`echo $tail | sed 's/[0-9]*$//'`
 156 if test $o != $tail; then
 157   ostry="$ostry /$o"
 158 fi
 159
 160 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 161 base=
 162 tail=$base_os
 163 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 164   set $b
 165   base="$base /$1"
 166   tail="$2"
 167 done
 168
 169 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 170 mach=
 171 tail=$machine
 172 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 173   set $m
 174   # Prepend the machine's FPU directory unless --without-fp.
 175   if test "$with_fp" = yes; then
 176     mach="$mach /$1/fpu"
 177   fi
 178   mach="$mach /$1"
 179   tail="$2"
 180 done
 181
 182 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 183 changequote([,])dnl
 184
 185 # Find what sysdep directories exist.
 186 sysnames=
 187 for b in $base ''; do
 188   for m0 in $mach ''; do
 189     for v in /$vendor ''; do
 190       for o in /$ostry ''; do
 191         for m in $mach ''; do
 192           try="$m0$b$v$o$m"
 193           test -n "$enable_debug_configure" && echo "$0 [DEBUG]: try $try" >&2
 194           if test -d $sysdep_dir$try; then
 195             sysnames="$sysnames $try"
 196             { test -n "$o" || test -n "$b"; } && os_used=t
 197             { test -n "$m" || test -n "$m0"; } && machine_used=t
 198           fi
 199         done
 200       done
 201     done
 202   done
 203 done
 204
 205 if test -z "$os_used" && test "$os" != none; then
 206   AC_MSG_ERROR(Operating system $os is not supported.)
 207 fi
 208 if test -z "$machine_used" && test "$machine" != none; then
 209   AC_MSG_ERROR(The $machine is not supported.)
 210 fi
 211
 212 # We have now validated the configuration.
 213
 214
 215 # If using ELF, look for an `elf' subdirectory of each machine directory.
 216 # We prepend these rather than inserting them whereever the machine appears
 217 # because things specified by the machine's ELF ABI should override
 218 # OS-specific things, and should always be the same for any OS on the
 219 # machine (otherwise what's the point of an ABI?).
 220 if test "$elf" = yes; then
 221   elf_dirs=
 222   for m in $mach; do
 223     if test -d $sysdep_dir$m/elf; then
 224       elf_dirs="$elf_dirs $m/elf"
 225     fi
 226   done
 227   sysnames="`echo $elf_dirs | sed -e 's,^/,,' -e 's, /,,g'` $sysnames"
 228 fi
 229
 230
 231 # Remove the leading slashes.
 232 sysnames="`echo $sysnames | sed -e 's@^/@@' -e 's@ /@ @g'`"
 233
 234
 235 # Expand the list of system names into a full list of directories
 236 # from each element's parent name and Implies file (if present).
 237 set $sysnames
 238 while test $# -gt 0; do
 239   name=$1
 240   shift
 241
 242   if test -f $sysdep_dir/$name/Implies; then
 243     # Collect more names from the `Implies' file (removing comments).
 244     implied="`sed 's/#.*$//' < $sysdep_dir/$name/Implies`"
 245     for x in $implied; do
 246       test -d $sysdep_dir/$x || echo "Warning: $name implies nonexistent $x">&2
 247     done
 248   else
 249     implied=
 250   fi
 251
 252   # Add NAME to the list of names.
 253   names="$names $name"
 254
 255   # Find the parent of NAME, using the empty string if it has none.
 256 changequote(,)dnl
 257   parent="`echo $name | sed -n -e '/\//!q' -e 's=/[^/]*$==p'`"
 258 changequote([,])dnl
 259
 260   # Add the names implied by NAME, and NAME's parent (if it has one), to
 261   # the list of names to be processed (the argument list).  We prepend the
 262   # implied names to the list and append the parent.  We want implied
 263   # directories to come before further directories inferred from the
 264   # configuration components; this ensures that for sysv4, unix/common
 265   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 266   # after sysv4).
 267   sysnames="`echo $implied $* $parent`"
 268   test -n "$sysnames" && set $sysnames
 269 done
 270
 271 # Add the default directories.
 272 names="$names generic stub"
 273
 274 # Now uniquize the list.
 275 seen=
 276 sysnames=
 277 for name in $names; do
 278   if echo "$seen" | fgrep -x $name >/dev/null; then
 279     # Already in the list.
 280     true;
 281   else
 282     # A new one.
 283     if test -z "$seen"; then
 284       seen="$name" sysnames="$name"
 285     else
 286       seen="$seen
 287 $name"
 288       sysnames="$sysnames $name"
 289     fi
 290   fi
 291 done
 292 libc_cv_sysdirs="$sysnames"])
 293 AC_SUBST(sysnames) sysnames="$libc_cv_sysdirs"
 294
 295 AC_PROG_INSTALL
 296 if test "$INSTALL" = "${srcdir}/install-sh"; then
 297   # The makefiles need to use a different form to find it in $srcdir.
 298   INSTALL='$(..)./install-sh'
 299 fi
 300 AC_PROG_LN_S
 301 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 302
 303 AC_CHECK_TOOL(CC, gcc)
 304 AC_PROG_CPP
 305 AC_CHECK_TOOL(AR, ar)
 306 AC_CHECK_TOOL(RANLIB, ranlib, :)
 307 AC_CHECK_TOOL(OBJDUMP, objdump)
 308 AC_CHECK_TOOL(OBJCOPY, objcopy)
 309 AC_PROG_AWK
 310
 311 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 312 echo '#include <stddef.h>
 313 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 314 if eval "$ac_cpp conftest.c 2>/dev/null" \
 315 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 316   libc_cv_signed_size_t=no
 317 else
 318   libc_cv_signed_size_t=yes
 319 fi
 320 rm -f conftest*])
 321 if test $libc_cv_signed_size_t = yes; then
 322   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 323   cat >> confdefs.h <<\EOF
 324 #undef __SIZE_TYPE__
 325 #define __SIZE_TYPE__ unsigned
 326 EOF
 327 fi
 328
 329 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 330 AC_TRY_COMPILE(dnl
 331 [#define __need_size_t
 332 #define __need_wchar_t
 333 #include <stddef.h>
 334 #define __need_NULL
 335 #include <stddef.h>], [size_t size; wchar_t wchar;
 336 #ifdef offsetof
 337 #error stddef.h ignored __need_*
 338 #endif
 339 if (&size == NULL || &wchar == NULL) abort ();],
 340                libc_cv_friendly_stddef=yes,
 341                libc_cv_friendly_stddef=no)])
 342 if test $libc_cv_friendly_stddef = yes; then
 343   config_vars="$config_vars
 344 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 345 fi
 346
 347 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 348                libc_cv_need_minus_P, [dnl
 349 cat > conftest.S <<EOF
 350 #include "confdefs.h"
 351 /* Nothing whatsoever.  */
 352 EOF
 353 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 354   libc_cv_need_minus_P=no
 355 else
 356   libc_cv_need_minus_P=yes
 357 fi
 358 rm -f conftest*])
 359 if test $libc_cv_need_minus_P = yes; then
 360   config_vars="$config_vars
 361 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 362 fi
 363
 364 AC_CACHE_CHECK(for assembler global-symbol directive,
 365                libc_cv_asm_global_directive, [dnl
 366 libc_cv_asm_global_directive=UNKNOWN
 367 for ac_globl in .globl .global; do
 368   cat > conftest.s <<EOF
 369 .text
 370 ${ac_globl} foo
 371 foo: .long 0
 372 EOF
 373   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 374     libc_cv_asm_global_directive=${ac_globl}
 375   fi
 376   rm -f conftest*
 377   test $libc_cv_asm_global_directive != UNKNOWN && break
 378 done])
 379 if test $libc_cv_asm_global_directive = UNKNOWN; then
 380   AC_MSG_ERROR(cannot determine asm global directive)
 381 else
 382   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 383 fi
 384
 385 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 386 cat > conftest.s <<EOF
 387 .text
 388 foo: .long 0
 389 .set glibc_conftest_frobozz,foo
 390 $libc_cv_asm_global_directive glibc_conftest_frobozz
 391 EOF
 392 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 393 # (but it doesn't work), so we must do a linking check to be sure.
 394 cat > conftest1.c <<\EOF
 395 extern int glibc_conftest_frobozz;
 396 main () { printf ("%d\n", glibc_conftest_frobozz); }
 397 EOF
 398 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 399             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 400   libc_cv_asm_set_directive=yes
 401 else
 402   libc_cv_asm_set_directive=no
 403 fi
 404 rm -f conftest*])
 405 if test $libc_cv_asm_set_directive = yes; then
 406   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 407 fi
 408
 409 if test $elf != yes; then
 410   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 411                  [AC_TRY_COMPILE(, [asm (".section .init");
 412                                     asm (".section .fini");],
 413                                  libc_cv_have_initfini=yes,
 414                                  libc_cv_have_initfini=no)])
 415   AC_SUBST(libc_cv_have_initfini)dnl
 416   if test $libc_cv_have_initfini = yes; then
 417     AC_DEFINE(HAVE_INITFINI)
 418   fi
 419 fi
 420
 421 if test $elf = yes; then
 422   libc_cv_asm_underscores=no
 423 else
 424   AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 425                  [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 426                               libc_cv_asm_underscores=yes,
 427                               libc_cv_asm_underscores=no)])
 428 fi
 429 if test $libc_cv_asm_underscores = no; then
 430   AC_DEFINE(NO_UNDERSCORES)
 431 fi
 432
 433 if test $elf = yes; then
 434   libc_cv_weak_symbols=yes
 435   libc_cv_asm_weak_directive=yes
 436   libc_cv_asm_weakext_directive=no
 437 else
 438   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 439                  [dnl
 440 cat > conftest.s <<EOF
 441 .text
 442 ${libc_cv_asm_global_directive} foo
 443 foo: .long 0
 444 .weak foo
 445 .weak bar; bar = foo
 446 EOF
 447   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 448     libc_cv_asm_weak_directive=yes
 449   else
 450     libc_cv_asm_weak_directive=no
 451   fi
 452   rm -f conftest*])
 453
 454 if test $libc_cv_asm_weak_directive = no; then
 455   AC_CACHE_CHECK(for assembler .weakext directive,
 456                  libc_cv_asm_weakext_directive,
 457                  [dnl
 458 cat > conftest.s <<EOF
 459 .text
 460 ${libc_cv_asm_global_directive} foo
 461 foo: .long 0
 462 .weakext foo
 463 .weakext bar, foo
 464 EOF
 465   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 466     libc_cv_asm_weakext_directive=yes
 467   else
 468     libc_cv_asm_weakext_directive=no
 469   fi
 470   rm -f conftest*])
 471
 472   fi # no .weak
 473 fi # not ELF
 474
 475 if test $libc_cv_asm_weak_directive = yes; then
 476   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 477 elif test $libc_cv_asm_weakext_directive = yes; then
 478   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 479 fi
 480
 481 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 482 cat > conftest.c <<\EOF
 483 main () { exit (0); }
 484 EOF
 485 if ${CC-cc} $CFLAGS -Wl,--no-whole-archive \
 486             -o conftest conftest.c 2>/dev/null; then
 487   libc_cv_ld_no_whole_archive=yes
 488 else
 489   libc_cv_ld_no_whole_archive=no
 490 fi
 491 rm -f conftest*])
 492 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 493
 494 ### End of automated tests.
 495 ### Now run sysdeps configure fragments.
 496
 497 # sysdeps configure fragments may set these with files to be linked below.
 498 libc_link_dests=
 499 libc_link_sources=
 500
 501 # Iterate over all the sysdep directories we will use, running their
 502 # configure fragments, and looking for a uname implementation.
 503 uname=
 504 for dir in $sysnames; do
 505   if test -r $sysdep_dir/$dir/configure; then
 506     AC_MSG_RESULT(running configure fragment for $dir)
 507     . $sysdep_dir/$dir/configure
 508   fi
 509 [
 510   if test -z "$uname"; then
 511     if test -r $sysdep_dir/$dir/uname.c ||
 512        test -r $sysdep_dir/$dir/uname.S ||
 513        { test -r $sysdep_dir/$dir/syscalls.list &&
 514          grep '^uname[  ]' $sysdep_dir/$dir/syscalls.list >/dev/null; }; then
 515       uname=$dir
 516     fi
 517   fi
 518 ]dnl
 519 done
 520
 521 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 522
 523 # If we will use the generic uname implementation, we must figure out what
 524 # it will say by examining the system, and write the results in config-name.h.
 525 if test "$uname" = generic; then
 526
 527 changequote(,)dnl
 528   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 529 changequote([,])dnl
 530   if test $uname_sysname != $config_os; then
 531     config_release=`echo $config_os | sed s/$uname_sysname//`
 532   fi
 533 dnl
 534 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 535     if test -r /vmunix; then
 536       kernel_id=`strings /vmunix | grep UNIX`
 537     elif test -r /dynix; then
 538       kernel_id=`strings /dynix | grep DYNIX`
 539     else
 540       kernel_id=
 541     fi
 542 ])dnl
 543
 544   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 545 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 546 changequote(,)dnl
 547   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 548 changequote([,])dnl
 549   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 550          != x$config_release; then
 551     # The configuration release is a substring of the kernel release.
 552     libc_cv_uname_release=$kernel_release
 553   elif test x$config_release != x; then
 554     libc_cv_uname_release=$config_release
 555   elif test x$kernel_release != x; then
 556     libc_cv_uname_release=$kernel_release
 557   else
 558     libc_cv_uname_release=unknown
 559   fi])
 560   uname_release="$libc_cv_uname_release"
 561
 562   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 563 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 564 changequote(,)dnl
 565   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 566 changequote([,])dnl
 567   if test -n "$kernel_version"; then
 568     libc_cv_uname_version="$kernel_version"
 569   else
 570     libc_cv_uname_version=unknown
 571   fi])
 572   uname_version="$libc_cv_uname_version"
 573
 574 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 575   config_uname=config-name.h:config-name.in
 576 else
 577   # For non-generic uname, we don't need to create config-name.h at all.
 578   config_uname=
 579 fi
 580
 581 AC_MSG_CHECKING(stdio selection)
 582 AC_SUBST(stdio)
 583 case $stdio in
 584 libio) AC_DEFINE(USE_IN_LIBIO) ;;
 585 default) stdio=stdio ;;
 586 esac
 587 AC_MSG_RESULT($stdio)
 588
 589 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
 590 if test $gnu_ld = yes; then
 591   AC_DEFINE(HAVE_GNU_LD)
 592 fi
 593 if test $gnu_as = yes; then
 594   AC_DEFINE(HAVE_GNU_AS)
 595 fi
 596 if test $elf = yes; then
 597   AC_DEFINE(HAVE_ELF)
 598 fi
 599
 600 AC_SUBST(shared)
 601 if test $shared = default; then
 602   if test $gnu_ld = yes; then
 603     shared=$elf
 604   fi
 605 fi
 606 AC_SUBST(profile)
 607 AC_SUBST(omitfp)
 608
 609 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 610   config_makefile=
 611 else
 612   config_makefile=Makefile
 613 fi
 614
 615 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
 616           [echo '$config_vars' >> config.make])