sysdeps/unix/sysv/linux/configure.in

   1 sinclude(./aclocal.m4)dnl Autoconf lossage
   2 GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
   3 # Local configure fragment for sysdeps/unix/sysv/linux.
   4
   5 # On Linux, the default is to use libio instead of stdio.
   6 test $stdio = default && stdio=libio
   7
   8 # Don't bother trying to generate any glue code to be compatible with the
   9 # existing system library, because we are the only system library.
  10 inhibit_glue=yes
  11
  12 define([LIBC_LINUX_VERSION],[2.0.10])dnl
  13 if test -n "$sysheaders"; then
  14   OLD_CPPFLAGS=$CPPFLAGS
  15   CPPFLAGS="$CPPFLAGS $SYSINCLUDES"
  16 fi
  17 define([libc_cv_linuxVER], [libc_cv_linux]patsubst(LIBC_LINUX_VERSION,[\.]))dnl
  18 AC_CACHE_CHECK(installed Linux kernel header files, libc_cv_linuxVER, [dnl
  19 AC_EGREP_CPP([eat flaming death], [#include <linux/version.h>
  20 #if !defined LINUX_VERSION_CODE || LINUX_VERSION_CODE < ]dnl
  21 patsubst(LIBC_LINUX_VERSION,[^\([^.]*\)\.\([^.]*\)\.\([^.]*\)$],dnl
  22 [ (\1 *65536+ \2 *256+ \3) /* \1.\2.\3 */])[
  23 eat flaming death
  24 #endif],
  25              libc_cv_linuxVER='TOO OLD!',
  26              libc_cv_linuxVER='LIBC_LINUX_VERSION or later')])
  27 if test "$libc_cv_linuxVER" != 'LIBC_LINUX_VERSION or later'; then
  28   AC_MSG_ERROR([GNU libc requires kernel header files from
  29 Linux LIBC_LINUX_VERSION or later to be installed before configuring.
  30 The kernel header files are found usually in /usr/include/asm and
  31 /usr/include/linux; make sure these directories use files from
  32 Linux LIBC_LINUX_VERSION or later.  This check uses <linux/version.h>, so
  33 make sure that file was built correctly when installing the kernel header
  34 files.  To use kernel headers not from /usr/include/linux, use the
  35 configure option --with-headers.])
  36 fi
  37
  38 # If the user gave a minimal version number test whether the available
  39 # kernel headers are young enough.  Additionally we have minimal
  40 # kernel versions for some architectures.
  41 case "$machine" in
  42   mips*)
  43     arch_minimum_kernel=2.2.15
  44     ;;
  45   sh*)
  46     arch_minimum_kernel=2.3.99
  47     ;;
  48   ia64*)
  49     arch_minimum_kernel=2.4.0
  50     ;;
  51   hppa*)
  52     arch_minimum_kernel=2.3.99
  53     ;;
  54   *)
  55     arch_minimum_kernel=2.0.10
  56     ;;
  57 esac
  58 if test -n "$minimum_kernel"; then
  59   changequote(,)
  60   user_version=$((`echo "$minimum_kernel.0.0.0" | sed 's/\([0-9]*\)\.\([0-9]*\)\.\([0-9]*\).*/\1 \* 65536 + \2 \* 256 + \3/'`))
  61   arch_version=$((`echo "$arch_minimum_kernel.0.0.0" | sed 's/\([0-9]*\)\.\([0-9]*\)\.\([0-9]*\).*/\1 \* 65536 + \2 \* 256 + \3/'`))
  62   changequote([,])
  63   if test $user_version -lt $arch_version; then
  64     AC_MSG_WARN([minimum kernel version reset to $arch_minimum_kernel])
  65     minimum_kernel=$arch_minimum_kernel
  66   fi
  67 else
  68   if test $arch_minimum_kernel != '2.0.10'; then
  69     minimum_kernel=$arch_minimum_kernel
  70   fi
  71 fi
  72
  73 if test -n "$minimum_kernel"; then
  74   AC_MSG_CHECKING(for kernel header at least $minimum_kernel)
  75 changequote(,)dnl
  76   decnum=`echo "$minimum_kernel.0.0.0" | sed 's/\([0-9]*\)\.\([0-9]*\)\.\([0-9]*\).*/(\1 * 65536 + \2 * 256 + \3)/'`;
  77   abinum=`echo "$minimum_kernel.0.0.0" | sed 's/\([0-9]*\)\.\([0-9]*\)\.\([0-9]*\).*/\1,\2,\3/'`;
  78 changequote([,])dnl
  79   AC_EGREP_CPP([eat flaming death], [#include <linux/version.h>
  80 #if LINUX_VERSION_CODE < $decnum
  81 eat flaming death
  82 #endif], libc_minimum_kernel='too old!', libc_minimum_kernel=ok)
  83   AC_MSG_RESULT($libc_minimum_kernel)
  84   if test "$libc_minimum_kernel" = ok; then
  85     AC_DEFINE_UNQUOTED(__LINUX_KERNEL_VERSION, $decnum)
  86     AC_DEFINE_UNQUOTED(__ABI_TAG_VERSION, $abinum)
  87   else
  88     AC_MSG_ERROR([*** The available kernel headers are older than the requested
  89 *** compatible kernel version])
  90   fi
  91 fi
  92
  93 if test -n "$sysheaders"; then
  94   CPPFLAGS=$OLD_CPPFLAGS
  95 fi
  96 # The Linux filesystem standard prescribes where to place "essential"
  97 # files.  I.e., when the installation prefix is "/usr" we have to place
  98 # shared library objects and the configuration files on the root partition
  99 # in /lib and /etc.
 100 if test "$prefix" = "/usr" -o "$prefix" = "/usr/"; then
 101   # 64bit libraries on sparc go to /lib64 and not /lib
 102   if test "$machine" = "sparc/sparc64"; then
 103     libc_cv_slibdir="/lib64"
 104     if test "$libdir" = '${exec_prefix}/lib'; then
 105       libdir='${exec_prefix}/lib64';
 106       # Locale data can be shared between 32bit and 64bit libraries
 107       libc_cv_localedir='${exec_prefix}/lib/locale'
 108     fi
 109   else
 110     libc_cv_slibdir="/lib"
 111   fi
 112   # Allow the user to override the path with --sysconfdir
 113   if test $sysconfdir = '${prefix}/etc'; then
 114     libc_cv_sysconfdir=/etc
 115   else
 116     libc_cv_sysconfdir=$sysconfdir
 117    fi
 118   libc_cv_rootsbindir="/sbin"
 119 fi
 120
 121 # Under Linux the LinuxThreads add-on should be available.
 122 case $add_ons in
 123   # It is available.  Good.
 124   *linuxthreads*)
 125     message=
 126     ;;
 127   *)
 128     message="\
 129 *** WARNING: Are you sure you do not want to use the \`linuxthreads'
 130 *** add-on?"
 131     ;;
 132 esac
 133
 134 if test "$message"; then
 135   if test $enable_sanity = yes; then
 136     echo "\
 137 *** You should not compile the GNU libc without the \`linuxthreads'
 138 *** add-on.  Not using them risks being incompatible with the
 139 *** libraries of other systems.  Consider getting the add-on and restarting
 140 *** the configuration.
 141 *** If you really mean to not use this add-on, run configure again
 142 *** using the extra parameter \`--disable-sanity-checks'."
 143     exit 1
 144   else
 145     echo "$message"
 146   fi
 147 fi
 148
 149 # One Linux we use ldconfig.
 150 use_ldconfig=yes
 151
 152 # We need some extensions to the `ldd' script.
 153 changequote(,)
 154 case "$machine" in
 155   i[3456]86* | m68*)
 156     ldd_rewrite_script=../sysdeps/unix/sysv/linux/ldd-rewrite.sed
 157     ;;
 158   sparc*)
 159     ldd_rewrite_script=../sysdeps/unix/sysv/linux/sparc/ldd-rewrite.sed
 160     ;;
 161   *)
 162     ;;
 163 esac
 164 changequote([,])
 165
 166 if test $host = $build; then
 167   # If $prefix/include/{net,scsi} are symlinks, make install will
 168   # clobber what they're linked to (probably a kernel tree).
 169   # test -L ought to work on all Linux boxes.
 170   if test "x$prefix" != xNONE; then
 171     ac_prefix=$prefix
 172   else
 173     ac_prefix=$ac_default_prefix
 174   fi
 175   AC_MSG_CHECKING([for symlinks in ${ac_prefix}/include])
 176   ac_message=
 177   if test -L ${ac_prefix}/include/net; then
 178     ac_message="$ac_message
 179    ${ac_prefix}/include/net is a symlink"
 180   fi
 181   if test -L ${ac_prefix}/include/scsi; then
 182     ac_message="$ac_message
 183    ${ac_prefix}/include/scsi is a symlink"
 184   fi
 185   if test -n "$ac_message"; then
 186     AC_MSG_ERROR([$ac_message
 187 \`make install' will destroy the target of the link(s).
 188 Delete the links and re-run configure, or better still, move the entire
 189 ${ac_prefix}/include directory out of the way.])
 190   else
 191     AC_MSG_RESULT(ok)
 192   fi
 193 fi