configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37 [  --with-fp              if using floating-point hardware [default=yes]],
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(binutils, dnl
  40   --with-binutils=PATH    specify location of binutils (as and ld),
  41             path_binutils=$withval, path_binutils='')
  42 AC_ARG_WITH(elf, dnl
  43   --with-elf              if using the ELF object format,
  44             elf=$withval, elf=no)
  45 AC_ARG_WITH(cvs, dnl
  46 [  --without-cvs          if CVS should not be used],
  47             with_cvs=$withval, with_cvs=yes)
  48 AC_SUBST(with_cvs)
  49
  50 AC_ARG_ENABLE(libio, dnl
  51 [  --enable-libio          build in GNU libio instead of GNU stdio],
  52               [if test $enableval = yes; then
  53                  stdio=libio
  54                else
  55                  stdio=stdio
  56                fi],
  57               stdio=default)
  58
  59 AC_ARG_ENABLE(sanity-checks, dnl
  60 [  --disable-sanity-checks really do not use threads (should not be used
  61                           except in special situations) [default=yes]],
  62               enable_sanity=$enableval, enable_sanity=yes)
  63
  64 dnl Arguments to enable or disable building the static, shared, profiled,
  65 dnl and -fomit-frame-pointer libraries.
  66 AC_ARG_ENABLE(static, dnl
  67 [  --enable-static         build static library [default=yes]],
  68               static=$enableval, static=yes)
  69 AC_ARG_ENABLE(shared, dnl
  70 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  71               shared=$enableval, shared=default)
  72 AC_ARG_ENABLE(profile, dnl
  73 [  --enable-profile        build profiled library [default=yes]],
  74               profile=$enableval, profile=yes)
  75 AC_ARG_ENABLE(omitfp, dnl
  76 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  77               omitfp=$enableval, omitfp=no)
  78 AC_ARG_ENABLE(bounded, dnl
  79 [  --enable-bounded        build with runtime bounds checking [default=no]],
  80               bounded=$enableval, bounded=no)
  81 AC_ARG_ENABLE(versioning, dnl
  82 [  --disable-versioning    do not include versioning information in the
  83                           library objects [default=yes if supported]],
  84              enable_versioning=$enableval, enable_versioning=yes)
  85
  86 dnl Generic infrastructure for drop-in additions to libc.
  87 AC_ARG_ENABLE(add-ons, dnl
  88 [  --enable-add-ons[=DIR1,DIR2]... configure and build add-ons in DIR1,DIR2,...
  89                                   search for add-ons if no parameter given],
  90   [case "$enableval" in
  91     yes) if test "$srcdir" = "."; then
  92            add_ons=`echo */configure | sed -e 's!/configure!!g'`
  93          else
  94            add_ons=`echo $srcdir/*/configure | \
  95                     sed -e 's!/configure!!g' -e "s!$srcdir/!!g"`
  96          fi;;
  97     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
  98    esac],
  99   [add_ons=])
 100
 101 AC_CONFIG_SUBDIRS($add_ons)
 102 add_ons_pfx=
 103 if test x"$add_ons" != x; then
 104   for f in $add_ons; do
 105     # Test whether such a subdir really exists.
 106     if test -d $srcdir/$f; then
 107       add_ons_pfx="$add_ons_pfx $f/"
 108     else
 109       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 110     fi
 111   done
 112 fi
 113
 114 dnl On some platforms we cannot use dynamic loading.  We must provide
 115 dnl static NSS modules.
 116 AC_ARG_ENABLE(static-nss, dnl
 117 [  --enable-static-nss     build static NSS modules [default=no]],
 118               static_nss=$enableval, static_nss=no)
 119 if test x"$static_nss" = xyes; then
 120   AC_DEFINE(DO_STATIC_NSS)
 121 fi
 122
 123 AC_CANONICAL_HOST
 124
 125 # The way shlib-versions is used to generate soversions.mk uses a
 126 # fairly simplistic model for name recognition that can't distinguish
 127 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 128 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 129 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 130 case "$host_os" in
 131 linux*)
 132   ;;
 133 gnu*)
 134   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 135   ;;
 136 esac
 137
 138 ###
 139 ### I put this here to prevent those annoying emails from people who cannot
 140 ### read and try to compile glibc on unsupported platforms.  --drepper
 141 ###
 142 ### By using the undocumented --enable-hacker-mode option for configure
 143 ### one can skip this test to make the configuration not fail for unsupported
 144 ### platforms.
 145 ###
 146 if test -z "$enable_hacker_mode"; then
 147   case "$machine-$host_os" in
 148   *-linux* | *-gnu* | arm*-none*)
 149     ;;
 150   *)
 151     echo "*** The GNU C library is currently not available for this platform."
 152     echo "*** So far nobody cared to port it and if there is no volunteer it"
 153     echo "*** might never happen.  So, if you have interest to see glibc on"
 154     echo "*** this platform visit"
 155     echo "***   http://www.gnu.org/software/libc/porting.html"
 156     echo "*** and join the group of porters"
 157     exit 1
 158     ;;
 159   esac
 160 fi
 161
 162 # We keep the original values in `$config_*' and never modify them, so we
 163 # can write them unchanged into config.make.  Everything else uses
 164 # $machine, $vendor, and $os, and changes them whenever convenient.
 165 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 166
 167 # Some configurations imply other options.
 168 case "$host_os" in
 169 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 170   # These systems always use GNU tools.
 171   gnu_ld=yes gnu_as=yes ;;
 172 esac
 173 case "$host_os" in
 174 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 175 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 176   ;;
 177 gnu* | linux* | sysv4* | solaris2* | irix6*)
 178   # These systems (almost) always use the ELF format.
 179   elf=yes
 180   ;;
 181 esac
 182
 183 machine=$config_machine
 184 vendor=$config_vendor
 185 os=$config_os
 186
 187 dnl We need to use [ and ] for other purposes for a while now.
 188 changequote(,)dnl
 189 # Expand the configuration machine name into a subdirectory by architecture
 190 # type and particular chip.
 191 case "$machine" in
 192 a29k | am29000) base_machine=a29k machine=a29k ;;
 193 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 194 arm*)           base_machine=arm machine=arm/$machine ;;
 195 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 196 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 197 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 198 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 199 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 200 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 201 m88???)         base_machine=m88k machine=m88k/$machine ;;
 202 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 203 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 204 mips*)          base_machine=mips
 205                 case "`uname -m`" in
 206                 IP22) machine=mips/mips3 ;;
 207                 *)    machine=mips/$machine ,,
 208                 esac ;;
 209 sparc | sparcv[67])
 210                 base_machine=sparc machine=sparc/sparc32 ;;
 211 sparcv8 | supersparc | hypersparc)
 212                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 213 sparc64 | ultrasparc)
 214                 base_machine=sparc machine=sparc/sparc64 ;;
 215 esac
 216 changequote([,])dnl
 217 AC_SUBST(base_machine)
 218
 219 if test "$base_machine" = "i386"; then
 220   AC_DEFINE(USE_REGPARMS)
 221 fi
 222
 223 # Compute the list of sysdep directories for this configuration.
 224 # This can take a while to compute.
 225 sysdep_dir=$srcdir/sysdeps
 226 AC_MSG_CHECKING(sysdep dirs)
 227 dnl We need to use [ and ] for other purposes for a while now.
 228 changequote(,)dnl
 229 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 230 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 231
 232 case "$os" in
 233 gnu*)
 234   base_os=mach/hurd ;;
 235 netbsd* | 386bsd* | freebsd* | bsdi*)
 236   base_os=unix/bsd/bsd4.4 ;;
 237 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 238   base_os=unix/bsd ;;
 239 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 240   base_os=unix/sysv ;;
 241 irix6*)
 242   base_os=unix/sysv/irix6/$os ;;
 243 solaris[2-9]*)
 244   base_os=unix/sysv/sysv4 ;;
 245 none)
 246   base_os=standalone ;;
 247 *)
 248   base_os='' ;;
 249 esac
 250
 251 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 252 tail=$os
 253 ostry=$os
 254 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 255   ostry="$ostry /$o"
 256   tail=$o
 257 done
 258 o=`echo $tail | sed 's/[0-9]*$//'`
 259 if test $o != $tail; then
 260   ostry="$ostry /$o"
 261 fi
 262 # For linux-gnu, try linux-gnu, then linux.
 263 o=`echo $tail | sed 's/-.*$//'`
 264 if test $o != $tail; then
 265   ostry="$ostry /$o"
 266 fi
 267
 268 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 269 base=
 270 tail=$base_os
 271 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 272   set $b
 273   base="$base /$1"
 274   tail="$2"
 275 done
 276
 277 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 278 mach=
 279 tail=$machine
 280 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 281   set $m
 282   # Prepend the machine's FPU directory unless --without-fp.
 283   if test "$with_fp" = yes; then
 284     mach="$mach /$1/fpu"
 285   fi
 286   mach="$mach /$1"
 287   tail="$2"
 288 done
 289
 290 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 291 changequote([,])dnl
 292
 293 # Find what sysdep directories exist.
 294 sysnames=
 295 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 296 for d in $add_ons_pfx ''; do
 297   for b in $base ''; do
 298     for m0 in $mach ''; do
 299       for v in /$vendor ''; do
 300         test "$v" = / && continue
 301         for o in /$ostry ''; do
 302           test "$o" = / && continue
 303           for m in $mach ''; do
 304             if test "$m0$b$v$o$m"; then
 305               try="${d}sysdeps$m0$b$v$o$m"
 306               test -n "$enable_debug_configure" &&
 307               echo "$0 [DEBUG]: try $try" >&2
 308               case $try in
 309                 /*) dest=$try ;;
 310                 *)  dest=$srcdir/$try ;;
 311               esac
 312               if test -d $dest; then
 313                 sysnames="$sysnames $try"
 314                 { test -n "$o" || test -n "$b"; } && os_used=t
 315                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 316               fi
 317             fi
 318           done
 319         done
 320       done
 321     done
 322   done
 323 done
 324 IFS="$ac_save_ifs"
 325
 326 if test -z "$os_used" && test "$os" != none; then
 327   AC_MSG_ERROR(Operating system $os is not supported.)
 328 fi
 329 if test -z "$machine_used" && test "$machine" != none; then
 330   AC_MSG_ERROR(The $machine is not supported.)
 331 fi
 332
 333 # We have now validated the configuration.
 334
 335
 336 # If using ELF, look for an `elf' subdirectory of each machine directory.
 337 # We prepend these rather than inserting them whereever the machine appears
 338 # because things specified by the machine's ELF ABI should override
 339 # OS-specific things, and should always be the same for any OS on the
 340 # machine (otherwise what's the point of an ABI?).
 341 if test "$elf" = yes; then
 342   elf_dirs=
 343   for d in $add_ons_pfx ''; do
 344     case $d in
 345       /*) xsrcdir= ;;
 346       *)  xsrcdir=$srcdir/ ;;
 347     esac
 348     for m in $mach; do
 349       if test -d $xsrcdir${d}sysdeps$m/elf; then
 350         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 351       fi
 352     done
 353   done
 354   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 355 fi
 356
 357
 358 # Expand the list of system names into a full list of directories
 359 # from each element's parent name and Implies file (if present).
 360 set $sysnames
 361 names=
 362 while test $# -gt 0; do
 363   name=$1
 364   shift
 365
 366   case " $names " in *" $name "*)
 367     # Already in the list.
 368     continue
 369   esac
 370
 371   # Report each name as we discover it, so there is no long pause in output.
 372   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 373
 374   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 375
 376   case $name in
 377     /*) xsrcdir= ;;
 378     *)  xsrcdir=$srcdir/ ;;
 379   esac
 380   test -n "$enable_debug_configure" &&
 381   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 382
 383   if test -f $xsrcdir$name/Implies; then
 384     # Collect more names from the `Implies' file (removing comments).
 385     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 386     implied=
 387     for x in $implied_candidate; do
 388       if test -d $xsrcdir$name_base/$x; then
 389         implied="$implied $name_base/$x";
 390       else
 391         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 392       fi
 393     done
 394   else
 395     implied=
 396   fi
 397
 398   # Add NAME to the list of names.
 399   names="$names $name"
 400
 401   # Find the parent of NAME, using the empty string if it has none.
 402 changequote(,)dnl
 403   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 404 changequote([,])dnl
 405
 406   # Add the names implied by NAME, and NAME's parent (if it has one), to
 407   # the list of names to be processed (the argument list).  We prepend the
 408   # implied names to the list and append the parent.  We want implied
 409   # directories to come before further directories inferred from the
 410   # configuration components; this ensures that for sysv4, unix/common
 411   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 412   # after sysv4).
 413   sysnames="`echo $implied $* $parent`"
 414   test -n "$sysnames" && set $sysnames
 415 done
 416
 417 # Add the default directories.
 418 sysnames="$names sysdeps/generic"
 419 AC_SUBST(sysnames)
 420 # The other names were emitted during the scan.
 421 AC_MSG_RESULT(sysdeps/generic)
 422
 423
 424 ### Locate tools.
 425
 426 AC_PROG_INSTALL
 427 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 428   # The makefiles need to use a different form to find it in $srcdir.
 429   INSTALL='\$(..)./install-sh -c'
 430 fi
 431 AC_PROG_LN_S
 432 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 433 if test "$MSGFMT" != ":"; then
 434 changequote(,)dnl Need [] for regexps.
 435   if $MSGFMT --version 2>&1 | grep 'GNU gettext.*0\.[1-9][0-9]' >/dev/null 2>&1
 436 changequote([,])dnl
 437   then : # msgfmt from gettext 0.10 or greater, works.
 438   else
 439     AC_MSG_WARN([
 440 *** (g)msgfmt is too old or wrong version (need gettext 0.10 or better).])
 441     MSGFMT=":"
 442   fi
 443 fi
 444
 445 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo)
 446 if test "$MAKEINFO"; then
 447 changequote(,)dnl Need [] for regexps.
 448   if $MAKEINFO --version | grep 'texinfo 3\.[1-9][1-9]' >/dev/null 2>&1
 449 changequote([,])dnl
 450   then : # Makeinfo 3.11 or greater, works.
 451   else
 452     AC_MSG_WARN([
 453 *** makeinfo is too old (need version 3.11 or better).
 454 *** You should install the needed version and re-configure since otherwise
 455 *** you won't get the info pages installed.])
 456     MAKEINFO=
 457   fi
 458 fi
 459
 460 AC_PROG_CC_LOCAL
 461 AC_CANONICAL_BUILD
 462 if test $host != $build; then
 463   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 464 fi
 465 AC_SUBST(cross_compiling)
 466 AC_PROG_CPP
 467 LIBC_PROG_BINUTILS
 468 AC_CHECK_TOOL(AR, ar)
 469 AC_CHECK_TOOL(RANLIB, ranlib, :)
 470
 471 # check for recent compiler
 472 AC_MSG_CHECKING(compiler version)
 473 changequote(,)dnl
 474 case `${CC-cc} -v 2>&1` in
 475   *egcs-2.91.* | *egcs-1.0.[2-9]* | *egcs-1.1* | *2.8.[1-9]* | *2.9.[0-9]*)
 476     cc_is_recent="ok"
 477     ;;
 478   *)
 479     cc_is_recent="too old"
 480     ;;
 481 esac
 482 changequote([,])dnl
 483 AC_MSG_RESULT($cc_is_recent)
 484 if test "$cc_is_recent" != "ok"; then
 485   AC_MSG_WARN([
 486 *** Your compiler is too old.
 487 *** You need at least egcs 1.0.2 or GNU CC 2.8.1 to compile glibc.
 488 ])
 489 fi
 490
 491 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 492 # since this would lead to problems installing/building glibc.
 493 # LD_LIBRARY_PATH contains the current directory if one of the following
 494 # is true:
 495 # - one of the terminals (":" and ";") is the first or last sign
 496 # - two terminals occur directly after each other
 497 # - the path contains an element with a dot in it
 498 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 499 changequote(,)dnl
 500 case ${LD_LIBRARY_PATH} in
 501   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 502     ld_library_path_setting="contains current directory"
 503     ;;
 504   *)
 505     ld_library_path_setting="ok"
 506     ;;
 507 esac
 508 changequote([,])dnl
 509 AC_MSG_RESULT($ld_library_path_setting)
 510 if test "$ld_library_path_setting" != "ok"; then
 511 AC_MSG_ERROR(
 512 *** LD_LIBRARY_PATH shouldn't contain the current path when building glibc.
 513 *** Please change the environment variable and run configure again.)
 514 fi
 515
 516 AC_PATH_PROG(BASH, bash, no)
 517 if test "$BASH" != no &&
 518    $BASH -c 'test "$BASH_VERSINFO" \
 519              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 520   libc_cv_have_bash2=yes
 521 else
 522   libc_cv_have_bash2=no
 523 fi
 524 AC_SUBST(libc_cv_have_bash2)
 525
 526 dnl We need a ksh compatible shell for tzselect.
 527 if test "$BASH" = no; then
 528   AC_PATH_PROG(KSH, ksh, no)
 529   if test "$KSH" = no; then
 530     libc_cv_have_ksh=no
 531   else
 532     libc_cv_have_ksh=yes
 533   fi
 534 else
 535   KSH="$BASH"
 536   AC_SUBST(KSH)
 537   libc_cv_have_ksh=yes
 538 fi
 539 AC_SUBST(libc_cv_have_ksh)
 540
 541 AC_PATH_PROGS(PERL, perl, no)
 542 AC_SUBST(PERL)
 543
 544 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 545 echo '#include <stddef.h>
 546 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 547 if eval "$ac_cpp conftest.c 2>/dev/null" \
 548 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 549   libc_cv_signed_size_t=no
 550 else
 551   libc_cv_signed_size_t=yes
 552 fi
 553 rm -f conftest*])
 554 if test $libc_cv_signed_size_t = yes; then
 555   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 556   cat >> confdefs.h <<\EOF
 557 #undef __SIZE_TYPE__
 558 #define __SIZE_TYPE__ unsigned
 559 EOF
 560 fi
 561
 562 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 563 AC_TRY_COMPILE(dnl
 564 [#define __need_size_t
 565 #define __need_wchar_t
 566 #include <stddef.h>
 567 #define __need_NULL
 568 #include <stddef.h>], [size_t size; wchar_t wchar;
 569 #ifdef offsetof
 570 #error stddef.h ignored __need_*
 571 #endif
 572 if (&size == NULL || &wchar == NULL) abort ();],
 573                libc_cv_friendly_stddef=yes,
 574                libc_cv_friendly_stddef=no)])
 575 if test $libc_cv_friendly_stddef = yes; then
 576   config_vars="$config_vars
 577 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 578 fi
 579
 580 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 581                libc_cv_need_minus_P, [dnl
 582 cat > conftest.S <<EOF
 583 #include "confdefs.h"
 584 /* Nothing whatsoever.  */
 585 EOF
 586 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 587   libc_cv_need_minus_P=no
 588 else
 589   libc_cv_need_minus_P=yes
 590 fi
 591 rm -f conftest*])
 592 if test $libc_cv_need_minus_P = yes; then
 593   config_vars="$config_vars
 594 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 595 fi
 596
 597 # gcc 2.7.x has a bug where if -pipe is set, the assembler will always
 598 # be told to read stdin.  This causes the compiler to hang when fed an
 599 # .s file.
 600 if test $ac_cv_prog_gcc = yes; then
 601  case `${CC-cc} -v 2>&1` in
 602   *2.7*)
 603   # We must check this even if -pipe is not given here, because the user
 604   # might do `make CFLAGS=-pipe'.
 605   AC_CACHE_CHECK(for gcc 2.7.x -pipe bug, libc_cv_gcc_pipe_bug, [dnl
 606    cp /dev/null conftest.s
 607    cat >conftest1.s <<EOF
 608 .nosuchdirective
 609 EOF
 610    if ${CC-cc} -pipe -c conftest.s <conftest1.s 2>/dev/null; then
 611     libc_cv_gcc_pipe_bug=no
 612    else
 613     libc_cv_gcc_pipe_bug=yes
 614    fi
 615    rm -f conftest*])
 616   if test $libc_cv_gcc_pipe_bug = yes; then
 617    makeCC="${CC-cc} -B\$(common-objpfx)"
 618    makeCFLAGS=$CFLAGS
 619    CFLAGS=`echo $CFLAGS |sed 's/-pipe//'`
 620   fi;;
 621  *) libc_cv_gcc_pipe_bug=no;;
 622  esac
 623 else
 624  libc_cv_gcc_pipe_bug=no
 625 fi
 626
 627 AC_CACHE_CHECK(for assembler global-symbol directive,
 628                libc_cv_asm_global_directive, [dnl
 629 libc_cv_asm_global_directive=UNKNOWN
 630 for ac_globl in .globl .global; do
 631   cat > conftest.s <<EOF
 632 .text
 633 ${ac_globl} foo
 634 foo:
 635 EOF
 636   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 637     libc_cv_asm_global_directive=${ac_globl}
 638   fi
 639   rm -f conftest*
 640   test $libc_cv_asm_global_directive != UNKNOWN && break
 641 done])
 642 if test $libc_cv_asm_global_directive = UNKNOWN; then
 643   AC_MSG_ERROR(cannot determine asm global directive)
 644 else
 645   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 646 fi
 647
 648 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 649 cat > conftest.s <<EOF
 650 .text
 651 foo:
 652 .set glibc_conftest_frobozz,foo
 653 $libc_cv_asm_global_directive glibc_conftest_frobozz
 654 EOF
 655 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 656 # (but it doesn't work), so we must do a linking check to be sure.
 657 cat > conftest1.c <<\EOF
 658 extern int glibc_conftest_frobozz;
 659 main () { printf ("%d\n", glibc_conftest_frobozz); }
 660 EOF
 661 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 662             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 663   libc_cv_asm_set_directive=yes
 664 else
 665   libc_cv_asm_set_directive=no
 666 fi
 667 rm -f conftest*])
 668 if test $libc_cv_asm_set_directive = yes; then
 669   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 670 fi
 671
 672 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 673 [cat > conftest.s <<EOF
 674 .text
 675 _sym:
 676 .symver _sym,sym@VERS
 677 EOF
 678 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 679   libc_cv_asm_symver_directive=yes
 680 else
 681   libc_cv_asm_symver_directive=no
 682 fi
 683 rm -f conftest*])
 684 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 685 if test $libc_cv_asm_symver_directive = yes; then
 686   cat > conftest.s <<EOF
 687 .text
 688 _sym:
 689 .symver _sym,sym@VERS
 690 EOF
 691   cat > conftest.map <<EOF
 692 VERS_1 {
 693         global: sym;
 694 };
 695
 696 VERS_2 {
 697         global: sym;
 698 } VERS_1;
 699 EOF
 700   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 701     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 702                                         -nostartfiles -nostdlib
 703                                         -Wl,--version-script,conftest.map
 704                        1>&AC_FD_CC]);
 705     then
 706       libc_cv_ld_version_script_option=yes
 707     else
 708       libc_cv_ld_version_script_option=no
 709     fi
 710   else
 711     libc_cv_ld_version_script_option=no
 712   fi
 713 else
 714   libc_cv_ld_version_script_option=no
 715 fi
 716 rm -f conftest*])
 717 if test $libc_cv_asm_symver_directive = yes &&
 718    test $libc_cv_ld_version_script_option = yes &&
 719    test $enable_versioning = yes; then
 720   VERSIONING=yes
 721   AC_DEFINE(DO_VERSIONING)
 722 else
 723   VERSIONING=no
 724 fi
 725 AC_SUBST(VERSIONING)
 726
 727 if test $VERSIONING = no; then
 728   echo "\
 729 *** WARNING: You should not compile GNU libc without versioning. Not using
 730 *** versioning will introduce incompatibilities so that old binaries
 731 *** will not run anymore.
 732 *** For versioning you need recent binutils (binutils-2.8.1.0.17 or newer)."
 733 fi
 734 if test $elf = yes; then
 735   AC_CACHE_CHECK(for .previous assembler directive,
 736                  libc_cv_asm_previous_directive, [dnl
 737   cat > conftest.s <<EOF
 738 .section foo_section
 739 .previous
 740 EOF
 741   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 742     libc_cv_asm_previous_directive=yes
 743   else
 744     libc_cv_asm_previous_directive=no
 745   fi
 746   rm -f conftest*])
 747   if test $libc_cv_asm_previous_directive = yes; then
 748     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 749   else
 750     AC_CACHE_CHECK(for .popsection assembler directive,
 751                    libc_cv_asm_popsection_directive, [dnl
 752     cat > conftest.s <<EOF
 753 .pushsection foo_section
 754 .popsection
 755 EOF
 756     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 757       libc_cv_asm_popsection_directive=yes
 758     else
 759       libc_cv_asm_popsection_directive=no
 760     fi
 761     rm -f conftest*])
 762     if test $libc_cv_asm_popsection_directive = yes; then
 763       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 764     fi
 765   fi
 766 fi
 767
 768 if test $elf != yes; then
 769   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 770                  [AC_TRY_COMPILE(, [asm (".section .init");
 771                                     asm (".section .fini");
 772                                     asm (".text");],
 773                                  libc_cv_have_initfini=yes,
 774                                  libc_cv_have_initfini=no)])
 775   AC_SUBST(libc_cv_have_initfini)dnl
 776   if test $libc_cv_have_initfini = yes; then
 777     AC_DEFINE(HAVE_INITFINI)
 778   fi
 779 fi
 780
 781 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 782 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 783 [cat > conftest.$ac_ext <<EOF
 784 dnl This sometimes fails to find confdefs.h, for some reason.
 785 dnl [#]line __oline__ "[$]0"
 786 [#]line __oline__ "configure"
 787 #include "confdefs.h"
 788 void underscore_test(void) {
 789 return; }
 790 EOF
 791 if AC_TRY_EVAL(ac_compile); then
 792   if grep _underscore_test conftest* >/dev/null; then
 793     ifelse([$1], , :, [rm -f conftest*
 794     $1])
 795   else
 796     ifelse([$2], , , [rm -f conftest*
 797     $2])
 798   fi
 799 else
 800   echo "configure: failed program was:" >&AC_FD_CC
 801   cat conftest.$ac_ext >&AC_FD_CC
 802   ifelse([$2], , , [rm -f conftest*
 803   $2])
 804 fi
 805 rm -f conftest*])
 806
 807 if test $elf = yes; then
 808   libc_cv_asm_underscores=no
 809 else
 810   if test $ac_cv_prog_cc_works = yes; then
 811     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 812                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 813                                 libc_cv_asm_underscores=yes,
 814                                 libc_cv_asm_underscores=no)])
 815   else
 816     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 817                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 818                                             libc_cv_asm_underscores=no)])
 819   fi
 820 fi
 821 if test $libc_cv_asm_underscores = no; then
 822   AC_DEFINE(NO_UNDERSCORES)
 823 fi
 824
 825 if test $elf = yes; then
 826   libc_cv_weak_symbols=yes
 827 fi
 828
 829 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 830                  [dnl
 831 cat > conftest.s <<EOF
 832 .text
 833 ${libc_cv_asm_global_directive} foo
 834 foo:
 835 .weak foo
 836 .weak bar; bar = foo
 837 EOF
 838 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 839   libc_cv_asm_weak_directive=yes
 840 else
 841   libc_cv_asm_weak_directive=no
 842 fi
 843 rm -f conftest*])
 844
 845 if test $libc_cv_asm_weak_directive = no; then
 846   AC_CACHE_CHECK(for assembler .weakext directive,
 847                  libc_cv_asm_weakext_directive,
 848                  [dnl
 849 cat > conftest.s <<EOF
 850 .text
 851 ${libc_cv_asm_global_directive} foo
 852 foo:
 853 .weakext bar foo
 854 .weakext baz
 855 ${libc_cv_asm_global_directive} baz
 856 baz:
 857 EOF
 858   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 859     libc_cv_asm_weakext_directive=yes
 860   else
 861     libc_cv_asm_weakext_directive=no
 862   fi
 863   rm -f conftest*])
 864
 865 fi # no .weak
 866
 867 if test $libc_cv_asm_weak_directive = yes; then
 868   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 869 elif test $libc_cv_asm_weakext_directive = yes; then
 870   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 871 fi
 872
 873 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 874 cat > conftest.c <<\EOF
 875 _start () {}
 876 int __eh_pc;
 877 __throw () {}
 878 EOF
 879 dnl No \ in command here because it ends up inside ''.
 880 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 881                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 882                             -o conftest conftest.c 1>&AC_FD_CC]); then
 883   libc_cv_ld_no_whole_archive=yes
 884 else
 885   libc_cv_ld_no_whole_archive=no
 886 fi
 887 rm -f conftest*])
 888 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 889
 890 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
 891 cat > conftest.c <<\EOF
 892 _start () {}
 893 int __eh_pc;
 894 __throw () {}
 895 EOF
 896 dnl No \ in command here because it ends up inside ''.
 897 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 898                             -nostdlib -nostartfiles -fno-exceptions
 899                             -o conftest conftest.c 1>&AC_FD_CC]); then
 900   libc_cv_gcc_no_exceptions=yes
 901 else
 902   libc_cv_gcc_no_exceptions=no
 903 fi
 904 rm -f conftest*])
 905 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
 906
 907 if test "$base_machine" = alpha ; then
 908 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
 909 cat > conftest.c <<\EOF
 910 foo () { }
 911 EOF
 912 dnl
 913 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
 914 then
 915   libc_cv_gcc_alpha_ng_prefix=yes
 916 else
 917   libc_cv_gcc_alpha_ng_prefix=no
 918 fi
 919 rm -f conftest* ])
 920 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
 921   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
 922 else
 923   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
 924 fi
 925 fi
 926
 927 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
 928 [cat > conftest.c <<EOF
 929 #line __oline__ "configure"
 930 static char __EH_FRAME_BEGIN__[];
 931 _start ()
 932 {
 933 #ifdef CHECK__register_frame
 934   __register_frame (__EH_FRAME_BEGIN__);
 935   __deregister_frame (__EH_FRAME_BEGIN__);
 936 #endif
 937 #ifdef CHECK__register_frame_info
 938   __register_frame_info (__EH_FRAME_BEGIN__);
 939   __deregister_frame_info (__EH_FRAME_BEGIN__);
 940 #endif
 941 }
 942 int __eh_pc;
 943 __throw () {}
 944 /* FIXME: this is fragile.  */
 945 malloc () {}
 946 strcmp () {}
 947 strlen () {}
 948 memcpy () {}
 949 memset () {}
 950 free () {}
 951 abort () {}
 952 __bzero () {}
 953 EOF
 954 dnl No \ in command here because it ends up inside ''.
 955 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
 956                             -nostdlib -nostartfiles
 957                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
 958   libc_cv_gcc_dwarf2_unwind_info=static
 959 else
 960   libc_cv_gcc_dwarf2_unwind_info=no
 961 fi
 962 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
 963   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
 964                               -nostdlib -nostartfiles
 965                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
 966     libc_cv_gcc_dwarf2_unwind_info=yes
 967   else
 968     libc_cv_gcc_dwarf2_unwind_info=no
 969   fi
 970 fi
 971 rm -f conftest*])
 972 case $libc_cv_gcc_dwarf2_unwind_info in
 973 yes)
 974   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
 975   ;;
 976 static)
 977   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
 978   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
 979   ;;
 980 esac
 981
 982 ### End of automated tests.
 983 ### Now run sysdeps configure fragments.
 984
 985 # sysdeps configure fragments may set these with files to be linked below.
 986 libc_link_dests=
 987 libc_link_sources=
 988
 989 # Iterate over all the sysdep directories we will use, running their
 990 # configure fragments, and looking for a uname implementation.
 991 uname=
 992 for dir in $sysnames; do
 993   case $dir in
 994     /*) dest=$dir ;;
 995     *)  dest=$srcdir/$dir ;;
 996   esac
 997   if test -r $dest/configure; then
 998     AC_MSG_RESULT(running configure fragment for $dest)
 999     . $dest/configure
1000   fi
1001 [
1002   if test -z "$uname"; then
1003     if test -r $dest/uname.c ||
1004        test -r $dest/uname.S ||
1005        { test -r $dest/syscalls.list &&
1006          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1007       uname=$dir
1008     fi
1009   fi
1010 ]dnl
1011 done
1012
1013 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1014
1015 # If we will use the generic uname implementation, we must figure out what
1016 # it will say by examining the system, and write the results in config-name.h.
1017 if test "$uname" = "sysdeps/generic"; then
1018
1019 changequote(,)dnl
1020   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1021 changequote([,])dnl
1022   if test $uname_sysname != $config_os; then
1023     config_release=`echo $config_os | sed s/$uname_sysname//`
1024   fi
1025 dnl
1026 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1027     if test -r /vmunix; then
1028       kernel_id=`strings /vmunix | grep UNIX`
1029     elif test -r /dynix; then
1030       kernel_id=`strings /dynix | grep DYNIX`
1031     else
1032       kernel_id=
1033     fi
1034 ])dnl
1035
1036   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1037 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1038 changequote(,)dnl
1039   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1040 changequote([,])dnl
1041   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1042          != x$config_release; then
1043     # The configuration release is a substring of the kernel release.
1044     libc_cv_uname_release=$kernel_release
1045   elif test x$config_release != x; then
1046     libc_cv_uname_release=$config_release
1047   elif test x$kernel_release != x; then
1048     libc_cv_uname_release=$kernel_release
1049   else
1050     libc_cv_uname_release=unknown
1051   fi])
1052   uname_release="$libc_cv_uname_release"
1053
1054   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1055 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1056 changequote(,)dnl
1057   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1058 changequote([,])dnl
1059   if test -n "$kernel_version"; then
1060     libc_cv_uname_version="$kernel_version"
1061   else
1062     libc_cv_uname_version=unknown
1063   fi])
1064   uname_version="$libc_cv_uname_version"
1065
1066 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1067   config_uname=config-name.h:config-name.in
1068 else
1069   # For non-generic uname, we don't need to create config-name.h at all.
1070   config_uname=
1071 fi
1072
1073 AC_MSG_CHECKING(stdio selection)
1074 AC_SUBST(stdio)
1075 case $stdio in
1076 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1077 default) stdio=stdio ;;
1078 esac
1079 AC_MSG_RESULT($stdio)
1080
1081 AC_MSG_CHECKING(ldap selection)
1082 AC_SUBST(LDAP)
1083 case $add_ons in
1084 *ldap*)
1085    ldap=yes
1086    LDAP=ldap ;;
1087 *) ldap=no
1088    LDAP= ;;
1089 esac
1090 AC_MSG_RESULT($ldap)
1091
1092 AC_SUBST(libc_cv_slibdir)
1093 AC_SUBST(libc_cv_sysconfdir)
1094 AC_SUBST(libc_cv_rootsbindir)
1095
1096 AC_SUBST(has_ldconfig)
1097
1098 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1099 if test $gnu_ld = yes; then
1100   AC_DEFINE(HAVE_GNU_LD)
1101 fi
1102 if test $gnu_as = yes; then
1103   AC_DEFINE(HAVE_GNU_AS)
1104 fi
1105 if test $elf = yes; then
1106   AC_DEFINE(HAVE_ELF)
1107 fi
1108
1109 AC_SUBST(static)
1110 AC_SUBST(shared)
1111 if test $shared = default; then
1112   if test $gnu_ld = yes; then
1113     shared=$elf
1114   else
1115     # For now we do not assume shared libs are available.  In future more
1116     # tests might become available.
1117     shared=no
1118   fi
1119 fi
1120
1121 dnl We must not allow compilation without static library on some platforms.
1122 if test $static = no && test $shared = yes; then
1123   case "$host_os" in
1124   linux* | gnu*)
1125     AC_MSG_ERROR([
1126 *** You must compile with support for the static library since the shared
1127 *** library uses it.  Restart configure without \`--disable-static'.])
1128     ;;
1129   *)
1130     ;;
1131   esac
1132 fi
1133
1134 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1135 [pic_default=yes
1136 cat > conftest.c <<EOF
1137 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1138 # error PIC is default.
1139 #endif
1140 EOF
1141 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1142   pic_default=no
1143 fi
1144 rm -f conftest.*])
1145 AC_SUBST(pic_default)
1146
1147 AC_SUBST(profile)
1148 AC_SUBST(omitfp)
1149 AC_SUBST(bounded)
1150 AC_SUBST(static_nss)
1151 AC_SUBST(nopic_initfini)
1152
1153 AC_SUBST(DEFINES)
1154
1155 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1156   config_makefile=
1157 else
1158   config_makefile=Makefile
1159 fi
1160
1161 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
1162 AC_SUBST(VERSION)
1163
1164 if test $libc_cv_gcc_pipe_bug = yes; then
1165  realCC=$CC
1166  CC=$makeCC
1167  CFLAGS=$makeCFLAGS
1168 fi
1169 AC_OUTPUT_COMMANDS([
1170 if test "$realCC"; then
1171  sed -e 's/%{pipe:-}/%|/g' `$realCC -print-file-name=specs` >specsT
1172  mv specsT specs
1173 fi], [realCC=$realCC])
1174
1175 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
1176           [echo '$config_vars' >> config.make; test -d bits || mkdir bits])