sysdeps/unix/sysv/linux/arm/eabi/mmap64.S

   1 /* Copyright (C) 2000, 2003, 2005, 2009 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.  */
  18
  19 #include <sysdep.h>
  20
  21 #define EINVAL          22
  22
  23 #ifdef __ARMEB__
  24 # define LOW_OFFSET      8 + 4
  25 /* The initial + 4 is for the stack postdecrement.  */
  26 # define HIGH_OFFSET 4 + 8 + 0
  27 #else
  28 # define LOW_OFFSET      8 + 0
  29 # define HIGH_OFFSET 4 + 8 + 4
  30 #endif
  31
  32         /* The mmap2 system call takes six arguments, all in registers.  */
  33         .text
  34 ENTRY (__mmap64)
  35         ldr     ip, [sp, $LOW_OFFSET]
  36         str     r5, [sp, #-4]!
  37         cfi_adjust_cfa_offset (4)
  38         cfi_rel_offset (r5, 0)
  39         ldr     r5, [sp, $HIGH_OFFSET]
  40         str     r4, [sp, #-4]!
  41         cfi_adjust_cfa_offset (4)
  42         cfi_rel_offset (r4, 0)
  43         cfi_remember_state
  44         movs    r4, ip, lsl $20         @ check that offset is page-aligned
  45         mov     ip, ip, lsr $12
  46         moveqs  r4, r5, lsr $12         @ check for overflow
  47         bne     .Linval
  48         ldr     r4, [sp, $8]            @ load fd
  49         orr     r5, ip, r5, lsl $20     @ compose page offset
  50         DO_CALL (mmap2, 0)
  51         cmn     r0, $4096
  52         ldmfd   sp!, {r4, r5}
  53         cfi_adjust_cfa_offset (-8)
  54         cfi_restore (r4)
  55         cfi_restore (r5)
  56         RETINSTR(cc, lr)
  57         b       PLTJMP(syscall_error)
  58
  59         cfi_restore_state
  60 .Linval:
  61         mov     r0, $-EINVAL
  62         ldmfd   sp!, {r4, r5}
  63         cfi_adjust_cfa_offset (-8)
  64         cfi_restore (r4)
  65         cfi_restore (r5)
  66         b       PLTJMP(syscall_error)
  67 PSEUDO_END (__mmap64)
  68
  69 weak_alias (__mmap64, mmap64)