| blob | be48c9a19c5b26e006548a6c47bb89a94eb7e210 |
1 # Process this file with autoconf to produce a configure script.
2 AC_PREREQ([2.62])
4 dnl ***********************************
5 dnl *** include special GLib macros ***
6 dnl ***********************************
8 m4_define(glib_configure_ac)
10 #
11 # The following version number definitions apply to GLib, GModule, GObject,
12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
13 # all treated with the same interface and binary age.
14 #
15 # Making releases:
16 # glib_micro_version += 1;
17 # glib_interface_age += 1;
18 # glib_binary_age += 1;
19 # if any functions have been added, set glib_interface_age to 0.
20 # if backwards compatibility has been broken,
21 # set glib_binary_age _and_ glib_interface_age to 0.
22 #
23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
25 # for that version - see gversion.h for further information.
26 #
27 # in easier to understand terms:
28 #
29 # <mclasen> on the stable branch, interface age == micro
30 # <mclasen> on the unstable (ie master), interface age = 0
32 m4_define([glib_major_version], [2])
33 m4_define([glib_minor_version], [57])
34 m4_define([glib_micro_version], [1])
35 m4_define([glib_interface_age], [0])
36 m4_define([glib_binary_age],
37 [m4_eval(100 * glib_minor_version + glib_micro_version)])
38 m4_define([glib_version],
39 [glib_major_version.glib_minor_version.glib_micro_version])
41 # libtool version related macros
42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
43 m4_define([glib_lt_current],
44 [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
45 m4_define([glib_lt_revision], [glib_interface_age])
46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
47 m4_define([glib_lt_current_minus_age],
48 [m4_eval(glib_lt_current - glib_lt_age)])
50 # if the minor version number is odd, then we want debugging. Otherwise
51 # we only want minimal debugging support.
52 m4_define([glib_debug_default],
53 [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
56 AC_INIT(glib, [glib_version],
57 [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
59 AC_CONFIG_HEADERS([config.h])
60 AC_CONFIG_SRCDIR([glib/glib.h])
61 AC_CONFIG_MACRO_DIR([m4macros])
63 # Save this value here, since automake will set cflags later
64 cflags_set=${CFLAGS:+set}
66 AM_INIT_AUTOMAKE([1.13.3 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar subdir-objects])
67 AM_MAINTAINER_MODE([enable])
69 # Support silent build rules. Disable
70 # by either passing --disable-silent-rules to configure or passing V=1
71 # to make
72 AM_SILENT_RULES([yes])
74 GLIB_MAJOR_VERSION=glib_major_version
75 GLIB_MINOR_VERSION=glib_minor_version
76 GLIB_MICRO_VERSION=glib_micro_version
77 GLIB_INTERFACE_AGE=glib_interface_age
78 GLIB_BINARY_AGE=glib_binary_age
79 GLIB_VERSION=glib_version
81 AC_SUBST(GLIB_MAJOR_VERSION)
82 AC_SUBST(GLIB_MINOR_VERSION)
83 AC_SUBST(GLIB_MICRO_VERSION)
84 AC_SUBST(GLIB_VERSION)
85 AC_SUBST(GLIB_INTERFACE_AGE)
86 AC_SUBST(GLIB_BINARY_AGE)
88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
89 [Define to the GLIB major version])
90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
91 [Define to the GLIB minor version])
92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
93 [Define to the GLIB micro version])
94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
95 [Define to the GLIB interface age])
96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
97 [Define to the GLIB binary age])
99 # libtool versioning
100 LT_RELEASE=glib_lt_release
101 LT_CURRENT=glib_lt_current
102 LT_REVISION=glib_lt_revision
103 LT_AGE=glib_lt_age
104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
105 AC_SUBST(LT_RELEASE)
106 AC_SUBST(LT_CURRENT)
107 AC_SUBST(LT_REVISION)
108 AC_SUBST(LT_AGE)
109 AC_SUBST(LT_CURRENT_MINUS_AGE)
111 dnl Checks for programs.
112 AC_PROG_CC
113 AC_PROG_CPP
114 AC_USE_SYSTEM_EXTENSIONS
116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
118 AC_CANONICAL_HOST
120 dnl
122 AC_MSG_CHECKING([for Win32])
123 LIB_EXE_MACHINE_FLAG=X86
124 case "$host" in
125 *-*-mingw*)
126 glib_native_win32=yes
127 glib_pid_type='void *'
128 glib_pid_format='p'
129 glib_pollfd_format='%#x'
130 glib_dir_separator='\\\\'
131 glib_searchpath_separator=';'
132 glib_cv_stack_grows=no
133 # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
134 # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
135 # (Sorry, I don't know exactly what is the problem, but it is related to
136 # floating point formatting and decimal point vs. comma.)
137 # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
138 # rigorous enough to notice, though.
139 # So preset the autoconf cache variables.
140 ac_cv_func_vsnprintf_c99=no
141 ac_cv_func_snprintf_c99=no
142 case "$host" in
143 x86_64-*-*)
144 LIB_EXE_MACHINE_FLAG=X64
145 glib_pollfd_format='%#I64x'
146 ;;
147 esac
149 AC_DEFINE([_WIN32_WINNT], [0x0601], [Target the Windows 7 API])
150 ;;
151 *)
152 glib_native_win32=no
153 glib_pid_type=int
154 glib_pid_format='i'
155 glib_pollfd_format='%d'
156 glib_dir_separator='/'
157 glib_searchpath_separator=':'
158 ;;
159 esac
160 case $host in
161 *-*-linux*)
162 glib_os_linux=yes
163 ;;
164 esac
166 AC_MSG_RESULT([$glib_native_win32])
168 AC_MSG_CHECKING([for the Android])
169 case $host in
170 *android*)
171 glib_native_android="yes"
172 ;;
173 *)
174 glib_native_android="no"
175 ;;
176 esac
177 AC_MSG_RESULT([$glib_native_android])
179 AC_SUBST(LIB_EXE_MACHINE_FLAG)
181 glib_have_carbon=no
182 AC_MSG_CHECKING([for Mac OS X Carbon support])
183 AC_TRY_CPP([
184 #include <Carbon/Carbon.h>
185 #include <CoreServices/CoreServices.h>
186 ], glib_have_carbon=yes)
188 AC_MSG_RESULT([$glib_have_carbon])
190 glib_have_cocoa=no
191 AC_MSG_CHECKING([for Mac OS X Cocoa support])
192 AC_TRY_CPP([
193 #include <Cocoa/Cocoa.h>
194 #ifdef GNUSTEP_BASE_VERSION
195 #error "Detected GNUstep, not Cocoa"
196 #endif
197 ], glib_have_cocoa=yes)
199 AC_MSG_RESULT([$glib_have_cocoa])
201 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
202 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
203 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
204 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
205 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
206 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
208 AS_IF([test "$glib_native_win32" = "yes"], [
209 AC_CHECK_TOOL(WINDRES, windres, no)
210 if test "$WINDRES" = no; then
211 AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
212 fi
213 AC_CHECK_TOOL(NM, nm, no)
214 if test "$NM" = no; then
215 AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
216 fi
217 AC_CHECK_TOOL(RANLIB, ranlib, :)
218 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
219 AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
220 ])
221 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
223 AS_IF([test "x$glib_have_carbon" = "xyes"], [
224 AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
225 CARBON_LIBS="-Wl,-framework,Carbon"
226 LDFLAGS="$LDFLAGS $CARBON_LIBS"
227 ], [CARBON_LIBS=""])
229 AC_SUBST([CARBON_LIBS])
230 ac_cv_have_os_x_9_or_later="no"
231 AS_IF([test "x$glib_have_cocoa" = "xyes"], [
232 AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
233 COCOA_LIBS="-Wl,-framework,Foundation -Wl,-framework,AppKit"
234 LDFLAGS="$LDFLAGS $COCOA_LIBS"
235 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
236 #include <AvailabilityMacros.h>
237 #if MAC_OS_X_VERSION_MIN_REQUIRED < 1090
238 #error Compiling for minimum OS X version before 10.9
239 #endif
240 ]])],[ac_cv_have_os_x_9_or_later="yes"])
241 ], [COCOA_LIBS=""])
242 AM_CONDITIONAL([MAC_OS_X_9], [test "x$ac_cv_have_os_x_9_or_later" = xyes])
243 AC_SUBST([COCOA_LIBS])
245 dnl declare --enable-* args and collect ac_help strings
246 AC_ARG_ENABLE(debug,
247 AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
248 [turn on debugging @<:@default=glib_debug_default@:>@]),,
249 enable_debug=glib_debug_default)
251 AC_ARG_ENABLE(gc_friendly,
252 [AS_HELP_STRING([--enable-gc-friendly],
253 [turn on garbage collector friendliness [default=no]])],,
254 [enable_gc_friendly=no])
255 AC_ARG_ENABLE(mem_pools,
256 [AS_HELP_STRING([--disable-mem-pools],
257 [disable all glib memory pools])],,
258 [disable_mem_pools=no])
260 GLIB_TESTS
262 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
263 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
264 AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
265 AC_MSG_RESULT([yes])
266 ], [ AC_MSG_RESULT([no]) ])
268 AC_MSG_CHECKING([whether to disable memory pools])
269 AS_IF([test "x$disable_mem_pools" = "xno"], [
270 AC_MSG_RESULT([no])
271 ], [
272 AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
273 AC_MSG_RESULT([yes])
274 ])
276 dnl location to install runtime libraries, e.g. ../../lib to install
277 dnl to /lib if libdir is /usr/lib
278 AC_ARG_WITH(runtime-libdir,
279 [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
280 [install runtime libraries relative to libdir])],
281 [],
282 [with_runtime_libdir=""])
283 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
284 AC_SUBST(GLIB_RUNTIME_LIBDIR)
285 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
287 dnl Check for a working C++ compiler, but do not bail out, if none is found.
288 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
289 AC_LANG_SAVE
290 AC_LANG_CPLUSPLUS
291 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
292 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
293 AC_LANG_RESTORE
295 AM_PROG_CC_C_O
296 AC_PROG_INSTALL
298 AC_SYS_LARGEFILE
300 PKG_PROG_PKG_CONFIG(0.16)
302 if test "x$enable_debug" = "xyes"; then
303 if test "x$cflags_set" != "x" ; then
304 case " $CFLAGS " in
305 *[[\ \ ]]-g[[\ \ ]]*) ;;
306 *) CFLAGS="$CFLAGS -g" ;;
307 esac
308 fi
309 GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
310 else
311 GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
313 if test "x$enable_debug" = "xno"; then
314 GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
315 fi
316 fi
318 # Ensure MSVC-compatible struct packing convention is used when
319 # compiling for Win32 with gcc.
320 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
321 # gcc2 uses "-fnative-struct".
322 if test x"$glib_native_win32" = xyes; then
323 if test x"$GCC" = xyes; then
324 msnative_struct=''
325 AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
326 if test -z "$ac_cv_prog_CC"; then
327 our_gcc="$CC"
328 else
329 our_gcc="$ac_cv_prog_CC"
330 fi
331 case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
332 2.)
333 if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
334 msnative_struct='-fnative-struct'
335 fi
336 ;;
337 *)
338 if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
339 msnative_struct='-mms-bitfields'
340 fi
341 ;;
342 esac
343 if test x"$msnative_struct" = x ; then
344 AC_MSG_RESULT([no way])
345 AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
346 else
347 CFLAGS="$CFLAGS $msnative_struct"
348 AC_MSG_RESULT([${msnative_struct}])
349 fi
350 fi
351 fi
352 GLIB_EXTRA_CFLAGS="${msnative_struct}"
353 AC_SUBST(GLIB_EXTRA_CFLAGS)
355 AC_EXEEXT
357 AC_PROG_AWK
358 AC_CHECK_PROGS(PERL, [perl5 perl])
360 # option to specify python interpreter to use; this just sets $PYTHON, so that
361 # we will fallback to reading $PYTHON if --with-python is not given, and
362 # python.m4 will get the expected input
363 AC_ARG_WITH(python,
364 AS_HELP_STRING([--with-python=PATH],
365 [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
366 [PYTHON="$withval"], [])
367 if test x"$PYTHON" = xyes; then
368 AC_MSG_ERROR([--with-python option requires a path or program argument])
369 fi
370 AM_PATH_PYTHON(2.7,,PYTHON="python2.7")
373 dnl ***********************
374 dnl *** Tests for iconv ***
375 dnl ***********************
376 dnl
377 dnl We do this before the gettext checks, to avoid distortion
379 dnl On Windows we use a native implementation
381 AS_IF([ test x"$glib_native_win32" = xyes], [
382 with_libiconv=native
383 ], [
384 AC_ARG_WITH(libiconv,
385 [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
386 [use the libiconv library])],,
387 [with_libiconv=maybe])
389 found_iconv=no
390 case $with_libiconv in
391 maybe)
392 # Check in the C library first
393 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
394 # Check if we have GNU libiconv
395 if test $found_iconv = "no"; then
396 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
397 fi
398 # Check if we have a iconv in -liconv, possibly from vendor
399 if test $found_iconv = "no"; then
400 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
401 fi
402 ;;
403 no)
404 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
405 ;;
406 gnu|yes)
407 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
408 ;;
409 native)
410 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
411 ;;
412 esac
414 if test "x$found_iconv" = "xno" ; then
415 AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
416 fi
417 ])
419 dnl
420 dnl zlib support
421 dnl
422 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
423 AS_IF([test "x$found_zlib" = "xno"], [
424 AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
425 if test "x$found_zlib" = "xno" ; then
426 AC_MSG_ERROR([*** Working zlib library and headers not found ***])
427 fi
428 ZLIB_LIBS='-lz'
429 AC_SUBST(ZLIB_LIBS)
430 ])
432 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
433 AC_SUBST(LIBFFI_CFLAGS)
434 AC_SUBST(LIBFFI_LIBS)
436 dnl
437 dnl gettext support
438 dnl
440 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
441 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
442 GLIB_GNU_GETTEXT
444 if test "$gt_cv_have_gettext" != "yes" ; then
445 AC_MSG_ERROR([
446 *** You must have either have gettext support in your C library, or use the
447 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html)
448 ])
449 fi
451 LIBS="$INTLLIBS $LIBS"
453 GETTEXT_PACKAGE=glib20
454 AC_SUBST(GETTEXT_PACKAGE)
455 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
456 [Define the gettext package to be used])
458 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
460 dnl
461 dnl Now we are done with gettext checks, figure out ICONV_LIBS
462 dnl
464 AS_IF([test x"$glib_native_win32" != xyes], [
465 if test x$with_libiconv != xno ; then
466 case " $INTLLIBS " in
467 *[[\ \ ]]-liconv[[\ \ ]]*) ;;
468 *) ICONV_LIBS="-liconv" ;;
469 esac
470 fi
471 ])
472 AC_SUBST(ICONV_LIBS)
474 case $with_libiconv in
475 gnu)
476 AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
477 ;;
478 native)
479 AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
480 ;;
481 esac
483 dnl Initialize libtool
484 LT_PREREQ([2.2])
485 LT_INIT([disable-static win32-dll])
486 dnl when using libtool 2.x create libtool early, because it's used in configure
487 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
490 AS_IF([test "$glib_native_win32" = "yes"], [
491 if test x$enable_static = xyes -a x$enable_shared = xyes; then
492 AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
493 fi
494 if test x$enable_static = xyes; then
495 glib_win32_static_compilation=yes
496 GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
497 #define GOBJECT_STATIC_COMPILATION 1"
498 AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
499 fi
500 ])
501 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
503 # Checks for library functions.
504 AC_FUNC_ALLOCA
505 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
506 AC_CHECK_FUNCS(timegm gmtime_r)
507 AC_FUNC_STRERROR_R()
509 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
510 [AC_TRY_LINK([#include <unistd.h>
511 extern int __libc_enable_secure;],
512 [return __libc_enable_secure;],
513 glib_cv_have_libc_enable_secure=yes,
514 glib_cv_have_libc_enable_secure=no)])
515 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
516 AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
517 [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
518 ])
520 AC_CHECK_SIZEOF(char)
521 AC_CHECK_SIZEOF(short)
522 AC_CHECK_SIZEOF(long)
523 AC_CHECK_SIZEOF(int)
524 AC_CHECK_SIZEOF(void *)
525 AC_CHECK_SIZEOF(long long)
526 AC_CHECK_SIZEOF(__int64)
528 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
529 [AC_TRY_LINK([#include <signal.h>
530 #include <sys/types.h>
531 sig_atomic_t val = 42;],
532 [return val == 42 ? 0 : 1],
533 ac_cv_type_sig_atomic_t=yes,
534 ac_cv_type_sig_atomic_t=no)])
535 if test x$ac_cv_type_sig_atomic_t = xyes; then
536 AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
537 [Define if you have the 'sig_atomic_t' type.])
538 fi
540 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
541 :
542 else
543 AC_MSG_ERROR([
544 *** GLib requires a 64 bit type. You might want to consider
545 *** using the GNU C compiler.
546 ])
547 fi
549 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
550 # long long is a 64 bit integer.
551 AC_MSG_CHECKING(for format to printf and scanf a guint64)
552 AC_CACHE_VAL(glib_cv_long_long_format,[
553 for format in ll q I64; do
554 AC_TRY_RUN([#include <stdio.h>
555 int main()
556 {
557 long long b, a = -0x3AFAFAFAFAFAFAFALL;
558 char buffer[1000];
559 sprintf (buffer, "%${format}u", a);
560 sscanf (buffer, "%${format}u", &b);
561 exit (b!=a);
562 }
563 ],
564 [glib_cv_long_long_format=${format}
565 break],
566 [],[:])
567 done])
568 AS_IF([ test -n "$glib_cv_long_long_format"], [
569 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
570 AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
571 if test x"$glib_cv_long_long_format" = xI64; then
572 AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
573 fi
574 ], [AC_MSG_RESULT(none)])
575 ],[ test x$ac_cv_sizeof___int64 = x8], [
576 # __int64 is a 64 bit integer.
577 AC_MSG_CHECKING(for format to printf and scanf a guint64)
578 # We know this is MSVCRT.DLL, and what the formats are
579 glib_cv_long_long_format=I64
580 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
581 AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
582 AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
583 ])
585 AC_C_CONST
587 dnl
588 dnl check in which direction the stack grows
589 dnl
590 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
591 AC_TRY_RUN([
592 volatile int *a = 0, *b = 0;
593 void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
594 int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
595 ],
596 glib_cv_stack_grows=yes
597 ,
598 glib_cv_stack_grows=no
599 ,)
600 ])
602 # check for flavours of varargs macros
603 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
604 AC_TRY_COMPILE([],[
605 int a(int p1, int p2, int p3);
606 #define call_a(...) a(1,__VA_ARGS__)
607 call_a(2,3);
608 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
609 AC_MSG_RESULT($g_have_iso_c_varargs)
611 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
612 AS_IF([test "$CXX" = ""], [
613 dnl No C++ compiler
614 g_have_iso_cxx_varargs=no
615 else
616 AC_LANG_CPLUSPLUS
617 AC_TRY_COMPILE([],[
618 int a(int p1, int p2, int p3);
619 #define call_a(...) a(1,__VA_ARGS__)
620 call_a(2,3);
621 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
622 AC_LANG_C
623 ])
624 AC_MSG_RESULT($g_have_iso_cxx_varargs)
626 AC_MSG_CHECKING(for GNUC varargs macros)
627 AC_TRY_COMPILE([],[
628 int a(int p1, int p2, int p3);
629 #define call_a(params...) a(1,params)
630 call_a(2,3);
631 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
632 AC_MSG_RESULT($g_have_gnuc_varargs)
634 # check for GNUC visibility support
635 AC_MSG_CHECKING(for GNUC visibility attribute)
636 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
637 void
638 __attribute__ ((visibility ("hidden")))
639 f_hidden (void)
640 {
641 }
642 void
643 __attribute__ ((visibility ("internal")))
644 f_internal (void)
645 {
646 }
647 void
648 __attribute__ ((visibility ("protected")))
649 f_protected (void)
650 {
651 }
652 void
653 __attribute__ ((visibility ("default")))
654 f_default (void)
655 {
656 }
657 int main (void)
658 {
659 f_hidden();
660 f_internal();
661 f_protected();
662 f_default();
663 return 0;
664 }
665 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
666 AC_MSG_RESULT($g_have_gnuc_visibility)
667 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
669 AC_MSG_CHECKING([whether using Sun Studio C compiler])
670 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
671 #else
672 # include "error: this is not Sun Studio."
673 #endif
674 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
675 AC_MSG_RESULT($g_have_sunstudio_visibility)
676 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
678 # check for bytesex stuff
679 AC_C_BIGENDIAN
680 if test x$ac_cv_c_bigendian = xuniversal ; then
681 AC_MSG_ERROR([Universal builds not supported: see https://bugzilla.gnome.org/show_bug.cgi?id=742548])
682 fi
685 # check for header files
686 AC_CHECK_HEADERS([sys/param.h sys/resource.h mach/mach_time.h])
687 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
688 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
689 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
690 AC_CHECK_HEADERS([linux/magic.h])
691 AC_CHECK_HEADERS([termios.h])
693 # Some versions of MSC lack these
694 AC_CHECK_HEADERS([dirent.h sys/time.h])
696 # We don't care about this, but we need to keep including it in
697 # glibconfig.h for backward compatibility
698 AC_CHECK_HEADERS([values.h])
700 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
701 [#if HAVE_SYS_PARAM_H
702 #include <sys/param.h>
703 #endif
704 ])
705 AC_CHECK_FUNCS(sysctlbyname)
707 AC_HEADER_MAJOR
708 AC_CHECK_HEADERS([xlocale.h])
710 # check for structure fields
711 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec, struct stat.st_birthtime, struct stat.st_birthtimensec, struct stat.st_birthtim, struct stat.st_birthtim.tv_nsec])
712 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
713 #include <sys/stat.h>
714 #ifdef G_OS_UNIX
715 #include <unistd.h>
716 #endif
717 #ifdef HAVE_SYS_STATFS_H
718 #include <sys/statfs.h>
719 #endif
720 #ifdef HAVE_SYS_PARAM_H
721 #include <sys/param.h>
722 #endif
723 #ifdef HAVE_SYS_MOUNT_H
724 #include <sys/mount.h>
725 #endif])
726 # struct statvfs.f_basetype is available on Solaris but not for Linux.
727 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
728 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
729 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
731 AC_STRUCT_DIRENT_D_TYPE
733 # Checks for libcharset
734 AM_LANGINFO_CODESET
735 gl_GLIBC21
736 AC_ARG_WITH(charsetalias-dir,
737 AS_HELP_STRING([--with-charsetalias-dir=DIR], [directory for charset.alias file [LIBDIR]]),
738 [],
739 [with_charsetalias_dir='${libdir}'])
740 GLIB_CHARSETALIAS_DIR=$with_charsetalias_dir
741 AC_SUBST(GLIB_CHARSETALIAS_DIR)
743 # check additional type sizes
744 AC_CHECK_SIZEOF(size_t)
746 dnl Try to figure out whether gsize should be long or int
747 AC_MSG_CHECKING([for the appropriate definition for size_t])
749 case $ac_cv_sizeof_size_t in
750 $ac_cv_sizeof_short)
751 glib_size_type=short
752 ;;
753 $ac_cv_sizeof_int)
754 glib_size_type=int
755 ;;
756 $ac_cv_sizeof_long)
757 glib_size_type=long
758 ;;
759 $ac_cv_sizeof_long_long)
760 glib_size_type='long long'
761 ;;
762 $ac_cv_sizeof__int64)
763 glib_size_type='__int64'
764 ;;
765 *) AC_MSG_ERROR([No type matching size_t in size])
766 ;;
767 esac
769 dnl If int/long are the same size, we see which one produces
770 dnl warnings when used in the location as size_t. (This matters
771 dnl on AIX with xlc)
772 dnl
773 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
774 test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
775 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
776 #if defined(_AIX) && !defined(__GNUC__)
777 #pragma options langlvl=stdc89
778 #endif
779 #include <stddef.h>
780 int main ()
781 {
782 size_t s = 1;
783 unsigned int *size_int = &s;
784 return (int)*size_int;
785 }
786 ]])],glib_size_type=int,
787 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
788 #if defined(_AIX) && !defined(__GNUC__)
789 #pragma options langlvl=stdc89
790 #endif
791 #include <stddef.h>
792 int main ()
793 {
794 size_t s = 1;
795 unsigned long *size_long = &s;
796 return (int)*size_long;
797 }
798 ]])],glib_size_type=long)])
799 ])
801 AC_MSG_RESULT(unsigned $glib_size_type)
803 AC_CHECK_SIZEOF(ssize_t)
805 dnl Try to figure out whether gssize should be long or int
806 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
808 case $ac_cv_sizeof_ssize_t in
809 $ac_cv_sizeof_short)
810 glib_ssize_type=short
811 ;;
812 $ac_cv_sizeof_int)
813 glib_ssize_type=int
814 ;;
815 $ac_cv_sizeof_long)
816 glib_ssize_type=long
817 ;;
818 $ac_cv_sizeof_long_long)
819 glib_ssize_type='long long'
820 ;;
821 $ac_cv_sizeof__int64)
822 glib_ssize_type='__int64'
823 ;;
824 *) AC_MSG_ERROR([No type matching ssize_t in size])
825 ;;
826 esac
828 dnl If int/long are the same size, we see which one produces
829 dnl warnings when used in the location as ssize_t. (This matters
830 dnl on Android where ssize_t is long and size_t is unsigned int)
831 dnl
832 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
833 test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
834 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
835 #if defined(_AIX) && !defined(__GNUC__)
836 #pragma options langlvl=stdc89
837 #endif
838 #include <stddef.h>
839 #ifdef HAVE_INTTYPES_H
840 # include <inttypes.h>
841 #endif
842 #ifdef HAVE_STDINT_H
843 # include <stdint.h>
844 #endif
845 #include <sys/types.h>
846 int main ()
847 {
848 ssize_t s = 1;
849 int *size_int = &s;
850 return (int)*size_int;
851 }
852 ]])],glib_ssize_type=int,
853 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
854 #if defined(_AIX) && !defined(__GNUC__)
855 #pragma options langlvl=stdc89
856 #endif
857 #include <stddef.h>
858 #ifdef HAVE_INTTYPES_H
859 # include <inttypes.h>
860 #endif
861 #ifdef HAVE_STDINT_H
862 # include <stdint.h>
863 #endif
864 #include <sys/types.h>
865 int main ()
866 {
867 ssize_t s = 1;
868 long *size_long = &s;
869 return (int)*size_long;
870 }
871 ]])],glib_ssize_type=long)])
872 ])
874 AC_MSG_RESULT($glib_ssize_type)
876 # Check for some functions
877 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk mkostemp link)
878 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
879 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
880 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
881 AC_CHECK_FUNCS(splice)
882 AC_CHECK_FUNCS(prlimit)
884 # To avoid finding a compatibility unusable statfs, which typically
885 # successfully compiles, but warns to use the newer statvfs interface:
886 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
887 AS_IF([test $ac_cv_header_sys_statfs_h = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
889 AC_MSG_CHECKING([whether to use statfs or statvfs])
890 # Some systems have both statfs and statvfs, pick the most "native" for these
891 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
892 [
893 # on solaris and irix, statfs doesn't even have the f_bavail field
894 AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
895 [ac_cv_func_statfs=no],
896 # else, at least on linux, statfs is the actual syscall
897 [ac_cv_func_statvfs=no])
898 ])
900 AS_IF([test x$ac_cv_func_statfs = xyes],
901 [
902 AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
903 AC_MSG_RESULT([statfs])
904 ],
905 [test x$ac_cv_func_statvfs = xyes],
906 [
907 AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
908 AC_MSG_RESULT([statvfs])
909 ],
910 [ AC_MSG_RESULT([neither])])
912 AC_CHECK_HEADERS(crt_externs.h)
913 AC_CHECK_FUNCS(_NSGetEnviron)
915 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
917 # Internet address families
918 if test $glib_native_win32 = yes; then
919 glib_inet_includes=["
920 #include <winsock2.h>
921 "]
922 else
923 glib_inet_includes=["
924 #include <sys/types.h>
925 #include <sys/socket.h>
926 "]
927 fi
929 glib_failed=false
930 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
931 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
932 # winsock defines this even though it doesn't support it
933 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
934 if $glib_failed ; then
935 AC_MSG_ERROR([Could not determine values for AF_INET* constants])
936 fi
938 glib_failed=false
939 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
940 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
941 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
942 if $glib_failed ; then
943 AC_MSG_ERROR([Could not determine values for MSG_* constants])
944 fi
946 AC_CHECK_FUNCS(endservent if_nametoindex if_indextoname sendmmsg recvmmsg)
948 AC_MSG_CHECKING([for SIOCGIFADDR])
949 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
950 [[
951 #include <sys/ioctl.h>
952 #include <net/if.h>
953 ]],
954 [[
955 struct ifreq ifr;
956 ioctl(0, SIOCGIFADDR, &ifr);
957 ]])], [
958 AC_MSG_RESULT(yes)
959 AC_DEFINE(HAVE_SIOCGIFADDR, 1, [SIOCGIFADDR is available])
960 ], [
961 AC_MSG_RESULT(no)
962 ])
964 AC_MSG_CHECKING([if ip_mreq_source.imr_interface has s_addr member])
965 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
966 [[
967 #include <netinet/in.h>
968 ]],
969 [[
970 struct ip_mreq_source mc_req_src;
971 mc_req_src.imr_interface.s_addr = 0;
972 ]])], [
973 AC_MSG_RESULT(yes)
974 ], [
975 AC_MSG_RESULT(no)
976 AC_DEFINE(BROKEN_IP_MREQ_SOURCE_STRUCT, 1, [struct ip_mreq_source definition is broken on Android NDK <= r16])
977 ])
979 AS_IF([test $glib_native_win32 = yes], [
980 # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
981 # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
982 # they aren't present at run-time (on Windows 2000).
983 AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
984 AC_SUBST(WSPIAPI_INCLUDE)
985 ], [
986 # Android does not have C_IN in public headers, we define it wherever necessary
987 AS_IF([test $glib_native_android != yes], [
988 AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
989 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
990 #include <arpa/nameser.h>],
991 [int qclass = C_IN;])],
992 [AC_MSG_RESULT([no])],
993 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
994 #include <arpa/nameser.h>
995 #include <arpa/nameser_compat.h>],
996 [int qclass = C_IN;])],
997 [AC_MSG_RESULT([yes])
998 NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
999 [AC_MSG_ERROR([could not compile test program either way])])])])
1000 AC_SUBST(NAMESER_COMPAT_INCLUDE)
1002 # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1003 NETWORK_LIBS=""
1004 AC_MSG_CHECKING([for res_query])
1005 AC_TRY_LINK([#include <sys/types.h>
1006 #include <netinet/in.h>
1007 #include <arpa/nameser.h>
1008 #include <resolv.h>
1009 ],[
1010 res_query("test", 0, 0, (void *)0, 0);
1011 ],[AC_MSG_RESULT([yes])],
1012 [save_libs="$LIBS"
1013 LIBS="-lresolv $LIBS"
1014 AC_TRY_LINK([#include <sys/types.h>
1015 #include <netinet/in.h>
1016 #include <arpa/nameser.h>
1017 #include <resolv.h>
1018 ],[
1019 res_query("test", 0, 0, (void *)0, 0);
1020 ],[AC_MSG_RESULT([in -lresolv])
1021 NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1022 [LIBS="-lbind $save_libs"
1023 AC_TRY_LINK([#include <resolv.h>],
1024 [res_query("test", 0, 0, (void *)0, 0);],
1025 [AC_MSG_RESULT([in -lbind])
1026 NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1027 [AC_MSG_ERROR(not found)])])
1028 LIBS="$save_libs"])
1029 AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1030 [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1031 [AC_MSG_ERROR(Could not find socket())]))
1032 save_libs="$LIBS"
1033 LIBS="$LIBS $NETWORK_LIBS"
1035 AC_MSG_CHECKING([for res_init])
1036 AC_TRY_LINK([#include <sys/types.h>
1037 #include <netinet/in.h>
1038 #include <arpa/nameser.h>
1039 #include <resolv.h>
1040 ],[
1041 res_init();
1042 ],[AC_MSG_RESULT([yes])
1043 AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1044 ],[AC_MSG_RESULT([no])])
1046 AC_MSG_CHECKING([for res_nclose])
1047 AC_TRY_LINK([#include <sys/types.h>
1048 #include <netinet/in.h>
1049 #include <arpa/nameser.h>
1050 #include <resolv.h>
1051 ],[
1052 struct __res_state res;
1053 res_nclose(&res);
1054 ],[AC_MSG_RESULT([yes])
1055 AC_DEFINE(HAVE_RES_NCLOSE, 1, [Define to 1 if you have the 'res_nclose' function.])
1056 ],[AC_MSG_RESULT([no])])
1058 AC_MSG_CHECKING([for res_ndestroy])
1059 AC_TRY_LINK([#include <sys/types.h>
1060 #include <netinet/in.h>
1061 #include <arpa/nameser.h>
1062 #include <resolv.h>
1063 ],[
1064 struct __res_state res;
1065 res_ndestroy(&res);
1066 ],[AC_MSG_RESULT([yes])
1067 AC_DEFINE(HAVE_RES_NDESTROY, 1, [Define to 1 if you have the 'res_ndestroy' function.])
1068 ],[AC_MSG_RESULT([no])])
1070 AC_MSG_CHECKING([for res_ninit])
1071 AC_TRY_LINK([#include <sys/types.h>
1072 #include <netinet/in.h>
1073 #include <arpa/nameser.h>
1074 #include <resolv.h>
1075 ],[
1076 struct __res_state res;
1077 res_ninit(&res);
1078 ],[AC_MSG_RESULT([yes])
1079 AC_DEFINE(HAVE_RES_NINIT, 1, [Define to 1 if you have the 'res_ninit' function.])
1080 ],[AC_MSG_RESULT([no])])
1082 AC_MSG_CHECKING([for res_nquery])
1083 AC_TRY_LINK([#include <sys/types.h>
1084 #include <netinet/in.h>
1085 #include <arpa/nameser.h>
1086 #include <resolv.h>
1087 ],[
1088 struct __res_state res;
1089 res_nquery(&res, "test", 0, 0, (void *)0, 0);
1090 ],[AC_MSG_RESULT([yes])
1091 AC_DEFINE(HAVE_RES_NQUERY, 1, [Define to 1 if you have the 'res_nquery' function.])
1092 ],[AC_MSG_RESULT([no])])
1093 LIBS="$save_libs"
1094 ])
1095 AC_SUBST(NETWORK_LIBS)
1097 AC_CHECK_HEADER([linux/netlink.h],
1098 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1099 [#include <sys/socket.h>])
1100 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1102 AC_CHECK_TYPE([struct ip_mreqn], [
1103 AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1104 [#include <netinet/in.h>])
1106 case $host in
1107 *-*-solaris* )
1108 AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1109 AC_DEFINE(_XOPEN_SOURCE, 2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1110 AC_DEFINE(__EXTENSIONS__, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1111 ;;
1112 esac
1114 dnl
1115 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1116 dnl
1117 AS_IF([test "$ac_cv_func_statfs" = yes], [
1118 AC_MSG_CHECKING([number of arguments to statfs()])
1119 AC_TRY_COMPILE([#include <unistd.h>
1120 #ifdef HAVE_SYS_PARAM_H
1121 #include <sys/param.h>
1122 #endif
1123 #ifdef HAVE_SYS_VFS_H
1124 #include <sys/vfs.h>
1125 #endif
1126 #ifdef HAVE_SYS_MOUNT_H
1127 #include <sys/mount.h>
1128 #endif
1129 #ifdef HAVE_SYS_STATFS_H
1130 #include <sys/statfs.h>
1131 #endif], [struct statfs st;
1132 statfs("/", &st);],[
1133 AC_MSG_RESULT([2])
1134 AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1135 AC_TRY_COMPILE([#include <unistd.h>
1136 #ifdef HAVE_SYS_PARAM_H
1137 #include <sys/param.h>
1138 #endif
1139 #ifdef HAVE_SYS_VFS_H
1140 #include <sys/vfs.h>
1141 #endif
1142 #ifdef HAVE_SYS_MOUNT_H
1143 #include <sys/mount.h>
1144 #endif
1145 #ifdef HAVE_SYS_STATFS_H
1146 #include <sys/statfs.h>
1147 #endif], [struct statfs st;
1148 statfs("/", &st, sizeof (st), 0);],[
1149 AC_MSG_RESULT([4])
1150 AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1151 AC_MSG_RESULT(unknown)
1152 AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1153 ])
1155 dnl
1156 dnl open takes O_DIRECTORY as an option
1157 dnl
1158 AC_MSG_CHECKING([open() option O_DIRECTORY])
1159 AC_TRY_COMPILE([#include <fcntl.h>
1160 #include <sys/types.h>
1161 #include <sys/stat.h>],
1162 [open(0, O_DIRECTORY, 0);],[
1163 AC_MSG_RESULT([yes])
1164 AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1165 AC_MSG_RESULT([no])])
1167 #
1168 # Check whether to use an included printf
1169 #
1170 AC_FUNC_VSNPRINTF_C99
1171 AC_FUNC_PRINTF_UNIX98
1173 AC_ARG_ENABLE(included-printf,
1174 [AS_HELP_STRING([--enable-included-printf],
1175 [use included printf [default=auto]])],
1176 enable_included_printf="$enableval")
1178 need_included_printf=no
1179 if test "x$enable_included_printf" = "xyes" ; then
1180 need_included_printf=yes
1181 fi
1182 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1183 need_included_printf=yes
1184 fi
1185 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1186 need_included_printf=yes
1187 fi
1188 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1189 test -z "$glib_cv_long_long_format" ; then
1190 need_included_printf=yes
1191 fi
1193 if test "x$enable_included_printf" = "xno" &&
1194 test "x$need_included_printf" = "xyes" ; then
1195 AC_MSG_ERROR([
1196 *** Your C library's printf doesn't appear to have the features that
1197 *** GLib needs, but you specified --enable-included-printf=no.])
1198 fi
1200 enable_included_printf=$need_included_printf
1202 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1203 AS_IF([test "$enable_included_printf" != "yes"], [
1204 AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1205 ], [
1206 if test -z "$glib_cv_long_long_format" ; then
1207 glib_cv_long_long_format="ll"
1208 fi
1209 AC_DEFINE(HAVE_VASPRINTF,1)
1210 ])
1212 # Checks needed for gnulib vasnprintf
1213 bh_C_SIGNED
1214 jm_AC_TYPE_LONG_LONG
1215 gt_TYPE_LONGDOUBLE
1216 gt_TYPE_WCHAR_T
1217 gt_TYPE_WINT_T
1218 AC_TYPE_SIZE_T
1219 AC_CHECK_TYPES(ptrdiff_t)
1220 jm_AC_TYPE_INTMAX_T
1221 AC_CHECK_FUNCS([snprintf strnlen wcslen wcsnlen mbrtowc wcrtomb])
1222 AC_FUNC_SNPRINTF_C99
1224 # Check if <sys/select.h> needs to be included for fd_set
1225 AC_MSG_CHECKING([for fd_set])
1226 AC_TRY_COMPILE([#include <sys/types.h>],
1227 [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1228 AS_IF([test "$gtk_ok" = "yes"], [
1229 AC_MSG_RESULT([yes, found in sys/types.h])
1230 ], [
1231 AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1232 if test "$gtk_ok" = "yes"; then
1233 # *** FIXME: give it a different name
1234 AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1235 AC_MSG_RESULT([yes, found in sys/select.h])
1236 else
1237 AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1238 AC_MSG_RESULT(no)
1239 fi
1240 ])
1242 dnl Check for nl_langinfo and CODESET
1243 AC_LANG_SAVE
1244 AC_LANG_C
1245 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1246 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1247 [char *codeset = nl_langinfo (CODESET);])],
1248 [glib_cv_langinfo_codeset=yes],
1249 [glib_cv_langinfo_codeset=no])])
1250 if test x$glib_cv_langinfo_codeset = xyes; then
1251 AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1252 fi
1254 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1255 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1256 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1257 [char *str;
1258 str = nl_langinfo (PM_STR);
1259 str = nl_langinfo (D_T_FMT);
1260 str = nl_langinfo (D_FMT);
1261 str = nl_langinfo (T_FMT);
1262 str = nl_langinfo (T_FMT_AMPM);
1263 str = nl_langinfo (MON_1);
1264 str = nl_langinfo (ABMON_12);
1265 str = nl_langinfo (DAY_1);
1266 str = nl_langinfo (ABDAY_7);])],
1267 [glib_cv_langinfo_time=yes],
1268 [glib_cv_langinfo_time=no])])
1269 if test x$glib_cv_langinfo_time = xyes; then
1270 AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1271 fi
1273 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1274 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1275 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1276 [char *str;
1277 str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1278 str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1279 str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1280 str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1281 str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1282 str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1283 str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1284 str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1285 str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1286 str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1287 [glib_cv_langinfo_outdigit=yes],
1288 [glib_cv_langinfo_outdigit=no])])
1289 if test x$glib_cv_langinfo_outdigit = xyes; then
1290 AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1291 fi
1293 dnl Check for nl_langinfo and ALTMON_n
1294 AC_CACHE_CHECK([for nl_langinfo (ALTMON_n)], glib_cv_langinfo_altmon,[
1295 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1296 [char *str;
1297 str = nl_langinfo (ALTMON_1);
1298 str = nl_langinfo (ALTMON_2);
1299 str = nl_langinfo (ALTMON_3);
1300 str = nl_langinfo (ALTMON_4);
1301 str = nl_langinfo (ALTMON_5);
1302 str = nl_langinfo (ALTMON_6);
1303 str = nl_langinfo (ALTMON_7);
1304 str = nl_langinfo (ALTMON_8);
1305 str = nl_langinfo (ALTMON_9);
1306 str = nl_langinfo (ALTMON_10);
1307 str = nl_langinfo (ALTMON_11);
1308 str = nl_langinfo (ALTMON_12);])],
1309 [glib_cv_langinfo_altmon=yes],
1310 [glib_cv_langinfo_altmon=no])])
1311 if test x$glib_cv_langinfo_altmon = xyes; then
1312 AC_DEFINE(HAVE_LANGINFO_ALTMON,1,[Have nl_langinfo (ALTMON_n)])
1313 fi
1315 dnl Check for nl_langinfo and _NL_ABALTMON_n
1316 AC_CACHE_CHECK([for nl_langinfo (_NL_ABALTMON_n)], glib_cv_langinfo_abaltmon,[
1317 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1318 [char *str;
1319 str = nl_langinfo (_NL_ABALTMON_1);
1320 str = nl_langinfo (_NL_ABALTMON_2);
1321 str = nl_langinfo (_NL_ABALTMON_3);
1322 str = nl_langinfo (_NL_ABALTMON_4);
1323 str = nl_langinfo (_NL_ABALTMON_5);
1324 str = nl_langinfo (_NL_ABALTMON_6);
1325 str = nl_langinfo (_NL_ABALTMON_7);
1326 str = nl_langinfo (_NL_ABALTMON_8);
1327 str = nl_langinfo (_NL_ABALTMON_9);
1328 str = nl_langinfo (_NL_ABALTMON_10);
1329 str = nl_langinfo (_NL_ABALTMON_11);
1330 str = nl_langinfo (_NL_ABALTMON_12);])],
1331 [glib_cv_langinfo_abaltmon=yes],
1332 [glib_cv_langinfo_abaltmon=no])])
1333 if test x$glib_cv_langinfo_abaltmon = xyes; then
1334 AC_DEFINE(HAVE_LANGINFO_ABALTMON,1,[Have nl_langinfo (_NL_ABALTMON_n)])
1335 fi
1336 AC_LANG_RESTORE
1338 dnl ****************************************
1339 dnl *** posix_memalign ***
1340 dnl ****************************************
1341 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1342 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1343 glib_cv_compliant_posix_memalign=0
1344 if test "$ac_cv_func_posix_memalign" = "yes" ; then
1345 AC_TRY_RUN([
1346 #define _XOPEN_SOURCE 600
1347 #include <stdlib.h> /* posix_memalign() should be defined here */
1348 /* some systems break if #include <malloc.h> used */
1349 static void test_memalign (size_t boundary, size_t size) {
1350 void *mem = 0;
1351 if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1352 exit (1);
1353 else
1354 free (mem);
1355 }
1356 int main() {
1357 test_memalign ( 128, 128 - 2 * sizeof (void*));
1358 test_memalign ( 256, 256 - 2 * sizeof (void*));
1359 test_memalign ( 512, 512 - 2 * sizeof (void*));
1360 test_memalign ( 1024, 1024 - 2 * sizeof (void*));
1361 test_memalign ( 2048, 2048 - 2 * sizeof (void*));
1362 test_memalign ( 4096, 4096 - 2 * sizeof (void*));
1363 test_memalign ( 8192, 8192 - 2 * sizeof (void*));
1364 test_memalign (16384, 16384 - 2 * sizeof (void*));
1365 test_memalign (32768, 32768 - 2 * sizeof (void*));
1366 exit (0); /* success */
1367 }
1368 ],
1369 [glib_cv_compliant_posix_memalign=1], [], [:])
1370 :
1371 fi
1372 ])
1373 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1374 AC_MSG_RESULT(yes)
1375 AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1376 ], [
1377 AC_MSG_RESULT(no)
1378 ])
1381 dnl ****************************************
1382 dnl *** strlcpy/strlcat ***
1383 dnl ****************************************
1384 # Check for strlcpy
1385 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1386 AC_TRY_RUN([#include <stdlib.h>
1387 #include <string.h>
1388 int main() {
1389 char p[10];
1390 (void) strlcpy (p, "hi", 10);
1391 if (strlcat (p, "bye", 0) != 3)
1392 return 1;
1393 return 0;
1394 }], glib_cv_have_strlcpy=yes,
1395 glib_cv_have_strlcpy=no,
1396 glib_cv_have_strlcpy=no)])
1397 if test "$glib_cv_have_strlcpy" = "yes"; then
1398 AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1399 fi
1402 dnl **********************
1403 dnl *** va_copy checks ***
1404 dnl **********************
1405 dnl we currently check for all three va_copy possibilities, so we get
1406 dnl all results in config.log for bug reports.
1407 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1408 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1409 #include <stdlib.h>
1410 void f (int i, ...) {
1411 va_list args1, args2;
1412 va_start (args1, i);
1413 va_copy (args2, args1);
1414 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1415 exit (1);
1416 va_end (args1); va_end (args2);
1417 }
1418 int main() {
1419 f (0, 42);
1420 return 0;
1421 }]])],
1422 [glib_cv_va_copy=yes],
1423 [glib_cv_va_copy=no])
1424 ])
1425 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1426 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1427 #include <stdlib.h>
1428 void f (int i, ...) {
1429 va_list args1, args2;
1430 va_start (args1, i);
1431 __va_copy (args2, args1);
1432 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1433 exit (1);
1434 va_end (args1); va_end (args2);
1435 }
1436 int main() {
1437 f (0, 42);
1438 return 0;
1439 }]])],
1440 [glib_cv___va_copy=yes],
1441 [glib_cv___va_copy=no])
1442 ])
1444 if test "x$glib_cv_va_copy" = "xyes"; then
1445 g_va_copy_func=va_copy
1446 else if test "x$glib_cv___va_copy" = "xyes"; then
1447 g_va_copy_func=__va_copy
1448 fi
1449 fi
1451 if test -n "$g_va_copy_func"; then
1452 AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1453 fi
1455 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1456 AC_TRY_RUN([#include <stdarg.h>
1457 #include <stdlib.h>
1458 void f (int i, ...) {
1459 va_list args1, args2;
1460 va_start (args1, i);
1461 args2 = args1;
1462 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1463 exit (1);
1464 va_end (args1); va_end (args2);
1465 }
1466 int main() {
1467 f (0, 42);
1468 return 0;
1469 }],
1470 [glib_cv_va_val_copy=yes],
1471 [glib_cv_va_val_copy=no],
1472 [glib_cv_va_val_copy=yes])
1473 ])
1475 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1476 AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1477 ])
1479 dnl ***********************
1480 dnl *** g_module checks ***
1481 dnl ***********************
1482 G_MODULE_LIBS=
1483 G_MODULE_LIBS_EXTRA=
1484 G_MODULE_PLUGIN_LIBS=
1485 if test x"$glib_native_win32" = xyes; then
1486 dnl No use for this on Win32
1487 G_MODULE_LDFLAGS=
1488 else
1489 export SED
1490 eval G_MODULE_LDFLAGS=$export_dynamic_flag_spec
1491 fi
1492 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1493 G_MODULE_NEED_USCORE=0
1494 G_MODULE_BROKEN_RTLD_GLOBAL=0
1495 G_MODULE_HAVE_DLERROR=0
1496 dnl *** force native WIN32 shared lib loader
1497 if test -z "$G_MODULE_IMPL"; then
1498 case "$host" in
1499 *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1500 esac
1501 fi
1502 dnl *** force native AIX library loader
1503 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1504 if test -z "$G_MODULE_IMPL"; then
1505 case "$host" in
1506 *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1507 esac
1508 fi
1509 dnl *** dlopen() and dlsym() in system libraries
1510 AS_IF([ test -z "$G_MODULE_IMPL"], [
1511 AC_CHECK_FUNC(dlopen,
1512 [AC_CHECK_FUNC(dlsym,
1513 [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1514 [])
1515 ])
1516 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1517 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1518 AC_CHECK_FUNC(NSLinkModule,
1519 [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1520 G_MODULE_NEED_USCORE=1],
1521 [])
1522 ])
1523 dnl *** dlopen() and dlsym() in libdl
1524 AS_IF([ test -z "$G_MODULE_IMPL"], [
1525 AC_CHECK_LIB(dl, dlopen,
1526 [AC_CHECK_LIB(dl, dlsym,
1527 [G_MODULE_LIBS=-ldl
1528 G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1529 [])
1530 ])
1531 dnl *** additional checks for G_MODULE_IMPL_DL
1532 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1533 LIBS_orig="$LIBS"
1534 LDFLAGS_orig="$LDFLAGS"
1535 LIBS="$G_MODULE_LIBS $LIBS"
1536 LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1537 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1538 echo "void glib_plugin_test(void) { }" > plugin.c
1539 ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1540 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1541 ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1542 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1543 -shrext ".o" -avoid-version plugin.lo \
1544 -rpath /dont/care >/dev/null 2>&1
1545 AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1546 glib_cv_rtldglobal_broken,[
1547 AC_TRY_RUN([
1548 #include <dlfcn.h>
1549 #ifndef RTLD_GLOBAL
1550 # define RTLD_GLOBAL 0
1551 #endif
1552 #ifndef RTLD_LAZY
1553 # define RTLD_LAZY 0
1554 #endif
1555 int glib_plugin_test;
1556 int main () {
1557 void *handle, *global, *local;
1558 global = &glib_plugin_test;
1559 handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1560 if (!handle) return 0;
1561 local = dlsym (handle, "glib_plugin_test");
1562 return global == local;
1563 } ],
1564 [glib_cv_rtldglobal_broken=no],
1565 [glib_cv_rtldglobal_broken=yes],
1566 [glib_cv_rtldglobal_broken=no])
1567 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1568 rmdir ${objdir} 2>/dev/null
1569 ])
1570 if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1571 G_MODULE_BROKEN_RTLD_GLOBAL=1
1572 else
1573 G_MODULE_BROKEN_RTLD_GLOBAL=0
1574 fi
1575 dnl *** check whether we need preceeding underscores
1576 AC_CACHE_CHECK([for preceeding underscore in symbols],
1577 glib_cv_uscore,[
1578 AC_TRY_RUN([#include <dlfcn.h>
1579 int glib_underscore_test (void) { return 42; }
1580 int main() {
1581 void *f1 = (void*)0, *f2 = (void*)0, *handle;
1582 handle = dlopen ((void*)0, 0);
1583 if (handle) {
1584 f1 = dlsym (handle, "glib_underscore_test");
1585 f2 = dlsym (handle, "_glib_underscore_test");
1586 } return (!f2 || f1);
1587 }],
1588 [glib_cv_uscore=yes],
1589 [glib_cv_uscore=no],
1590 [])
1591 rm -f plugin.c plugin.$ac_objext plugin.lo
1592 ])
1593 GLIB_ASSERT_SET(glib_cv_uscore)
1594 if test "x$glib_cv_uscore" = "xyes"; then
1595 G_MODULE_NEED_USCORE=1
1596 else
1597 G_MODULE_NEED_USCORE=0
1598 fi
1600 AC_CHECK_DECL([RTLD_LAZY],
1601 [AC_DEFINE(HAVE_RTLD_LAZY, 1, [Define to 1 if RTLD_LAZY is available])],
1602 [], [[#include <dlfcn.h>]])
1603 AC_CHECK_DECL([RTLD_NOW],
1604 [AC_DEFINE(HAVE_RTLD_NOW, 1, [Define to 1 if RTLD_NOW is available])],
1605 [], [[#include <dlfcn.h>]])
1606 AC_CHECK_DECL([RTLD_GLOBAL],
1607 [AC_DEFINE(HAVE_RTLD_GLOBAL, 1, [Define to 1 if RTLD_GLOBAL is available])],
1608 [], [[#include <dlfcn.h>]])
1610 LDFLAGS="$LDFLAGS_orig"
1611 dnl *** check for having dlerror()
1612 AC_CHECK_FUNC(dlerror,
1613 [G_MODULE_HAVE_DLERROR=1],
1614 [G_MODULE_HAVE_DLERROR=0])
1615 LIBS="$LIBS_orig"
1616 ])
1617 dnl *** done, have we got an implementation?
1618 if test -z "$G_MODULE_IMPL"; then
1619 G_MODULE_IMPL=0
1620 G_MODULE_SUPPORTED=false
1621 else
1622 G_MODULE_SUPPORTED=true
1623 fi
1625 AC_MSG_CHECKING(for the suffix of module shared libraries)
1626 export SED
1627 module=yes eval std_shrext=$shrext_cmds
1628 # chop the initial dot
1629 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1630 AC_MSG_RESULT(.$glib_gmodule_suffix)
1631 # any reason it may fail?
1632 if test "x$glib_gmodule_suffix" = x; then
1633 AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1634 fi
1636 AC_SUBST(G_MODULE_SUPPORTED)
1637 AC_SUBST(G_MODULE_IMPL)
1638 AC_SUBST(G_MODULE_LIBS)
1639 AC_SUBST(G_MODULE_LIBS_EXTRA)
1640 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1641 AC_SUBST(G_MODULE_LDFLAGS)
1642 AC_SUBST(G_MODULE_HAVE_DLERROR)
1643 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1644 AC_SUBST(G_MODULE_NEED_USCORE)
1645 AC_SUBST(GLIB_DEBUG_FLAGS)
1647 dnl **********************
1648 dnl *** g_spawn checks ***
1649 dnl **********************
1651 AC_MSG_CHECKING(for gspawn implementation)
1652 case "$host" in
1653 *-*-mingw*)
1654 GSPAWN=gspawn-win32.lo
1655 ;;
1656 *)
1657 GSPAWN=gspawn.lo
1658 ;;
1659 esac
1660 AC_MSG_RESULT($GSPAWN)
1661 AC_SUBST(GSPAWN)
1663 dnl *************************
1664 dnl *** GIOChannel checks ***
1665 dnl *************************
1667 AC_MSG_CHECKING(for GIOChannel implementation)
1668 case "$host" in
1669 *-*-mingw*)
1670 GIO=giowin32.lo
1671 ;;
1672 *)
1673 GIO=giounix.lo
1674 ;;
1675 esac
1676 AC_MSG_RESULT($GIO)
1677 AC_SUBST(GIO)
1679 dnl *********************************
1680 dnl *** Directory for GIO modules ***
1681 dnl *********************************
1683 AC_ARG_WITH(gio-module-dir,
1684 [AS_HELP_STRING([--with-gio-module-dir=DIR],
1685 [load gio modules from this directory [LIBDIR/gio/modules]])],
1686 [],
1687 [with_gio_module_dir='${libdir}/gio/modules'])
1688 GIO_MODULE_DIR=$with_gio_module_dir
1689 AC_SUBST(GIO_MODULE_DIR)
1691 dnl **********************************
1692 dnl *** Check for libselinux (GIO) ***
1693 dnl **********************************
1694 AC_ARG_ENABLE(selinux,
1695 AS_HELP_STRING([--disable-selinux],
1696 [build without selinux support]))
1697 msg_selinux=no
1698 SELINUX_LIBS=
1699 AS_IF([ test "x$enable_selinux" != "xno"], [
1701 AC_CHECK_LIB(selinux, is_selinux_enabled,
1702 [AC_CHECK_HEADERS(selinux/selinux.h,
1703 [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1704 [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1705 SELINUX_LIBS="-lselinux"
1706 msg_selinux=yes])
1707 ])
1708 ])
1709 ])
1710 AC_SUBST(SELINUX_LIBS)
1712 dnl *****************************
1713 dnl ** Check for inotify (GIO) **
1714 dnl *****************************
1715 inotify_support=no
1716 AC_CHECK_HEADERS([sys/inotify.h],
1717 [
1718 AC_CHECK_FUNCS(inotify_init1, [inotify_support=yes], [inotify_support=no])
1719 ])
1721 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1723 dnl ****************************
1724 dnl ** Check for kqueue (GIO) **
1725 dnl ****************************
1726 kqueue_support=no
1727 AC_CHECK_HEADERS([sys/event.h],
1728 [
1729 AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1730 ])
1732 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1734 dnl ****************************
1735 dnl *** Checks for FAM (GIO) ***
1736 dnl ****************************
1738 should_disable_fam=no
1740 AC_ARG_ENABLE(fam,
1741 AS_HELP_STRING([--disable-fam],
1742 [don't use fam for file system monitoring]),
1743 [
1744 if test "x$enable_fam" = "xno"; then
1745 should_disable_fam=yes
1746 fi
1747 ]
1748 )
1749 fam_support=no
1750 FAM_LIBS=
1751 if test "x$should_disable_fam" = "xno"; then
1752 AC_CHECK_LIB(fam, FAMOpen,
1753 [AC_CHECK_HEADERS(fam.h,
1754 [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1755 AC_CHECK_LIB(fam, FAMNoExists,
1756 AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1757 FAM_LIBS="-lfam"]
1758 fam_support=yes,
1759 AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1760 AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1761 AC_SUBST(FAM_LIBS)
1762 fi
1763 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1766 dnl *****************************
1767 dnl *** Check for xattr (GIO) ***
1768 dnl *****************************
1769 AC_ARG_ENABLE(xattr,
1770 AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1771 msg_xattr=no
1772 XATTR_LIBS=
1773 AS_IF([ test "x$enable_xattr" != "xno"], [
1775 dnl either glibc or libattr can provide xattr support
1777 dnl for both of them, we check for getxattr being in
1778 dnl the library and a valid xattr header.
1780 dnl try glibc
1781 AC_CHECK_LIB(c, getxattr,
1782 [AC_CHECK_HEADERS(sys/xattr.h,
1783 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1784 msg_xattr=yes])
1785 ])
1787 AS_IF([ test "x$msg_xattr" != "xyes"], [
1788 dnl failure. try libattr
1789 AC_CHECK_LIB(attr, getxattr,
1790 [AC_CHECK_HEADERS(attr/xattr.h,
1791 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1792 XATTR_LIBS="-lattr"
1793 msg_xattr=yes])
1794 ])
1795 ])
1797 AS_IF([ test "x$msg_xattr" = "xyes"], [
1798 AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1799 AC_TRY_COMPILE([
1800 #include <stdio.h>
1801 #ifdef HAVE_SYS_TYPES_H
1802 #include <sys/types.h>
1803 #endif
1804 #ifdef HAVE_SYS_XATTR_H
1805 #include <sys/xattr.h>
1806 #elif HAVE_ATTR_XATTR_H
1807 #include <attr/xattr.h>
1808 #endif
1809 ],
1810 [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1811 [
1812 AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1813 AC_MSG_RESULT([yes])
1814 ],
1815 [AC_MSG_RESULT([no])]
1816 )
1817 ])
1818 ])
1819 AC_SUBST(XATTR_LIBS)
1821 dnl ************************
1822 dnl *** check for libelf ***
1823 dnl ************************
1824 AC_ARG_ENABLE(libelf,
1825 AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1826 AS_IF([ test "x$enable_libelf" != "xno"],[
1827 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1828 AS_IF([ test $have_libelf = maybe ], [
1829 glib_save_LIBS=$LIBS
1830 AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1831 AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1832 AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1833 AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1834 LIBS=$glib_save_LIBS
1836 if test $have_libelf != no; then
1837 LIBELF_LIBS=-lelf
1838 have_libelf=yes
1839 fi
1840 ])
1841 ])
1843 if test x$have_libelf = xyes; then
1844 AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1845 fi
1847 dnl ************************
1848 dnl *** check for libmount ***
1849 dnl ************************
1851 dnl The fallback code doesn't really implement the same behaviors - e.g.
1852 dnl so on linux we want to require libmount unless specifically disabled
1853 dnl
1854 enable_libmount_default=${glib_os_linux:-no}
1855 AC_ARG_ENABLE(libmount,
1856 [AS_HELP_STRING([--enable-libmount],
1857 [build with libmount support [default for Linux]])],,
1858 [enable_libmount=$enable_libmount_default])
1859 AS_IF([ test "x$enable_libmount" = "xyes"],[
1860 PKG_CHECK_MODULES([LIBMOUNT], [mount >= 2.23], [have_libmount=yes], [have_libmount=no])
1861 if test $have_libmount = no ; then
1862 AC_MSG_ERROR([*** Could not find libmount])
1863 fi
1864 ])
1866 if test x$have_libmount = xyes; then
1867 AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available])
1868 fi
1869 AM_CONDITIONAL(HAVE_LIBMOUNT, [test x$have_libmount = xyes])
1871 dnl ****************************************
1872 dnl *** platform dependent source checks ***
1873 dnl ****************************************
1875 AC_MSG_CHECKING(for platform-dependent source)
1876 case "$host" in
1877 *-*-cygwin*|*-*-mingw*)
1878 PLATFORMDEP=gwin32.lo
1879 ;;
1880 *)
1881 PLATFORMDEP=
1882 ;;
1883 esac
1884 AC_MSG_RESULT($PLATFORMDEP)
1885 AC_SUBST(PLATFORMDEP)
1887 AC_MSG_CHECKING([whether to compile timeloop])
1888 case "$host" in
1889 *-*-cygwin*|*-*-mingw*|*-*-minix)
1890 enable_timeloop=no
1891 ;;
1892 *)
1893 enable_timeloop=yes
1894 ;;
1895 esac
1896 AC_MSG_RESULT($enable_timeloop)
1897 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1899 AC_MSG_CHECKING([if building for some Win32 platform])
1900 case "$host" in
1901 *-*-mingw*|*-*-cygwin*)
1902 platform_win32=yes
1903 ;;
1904 *)
1905 platform_win32=no
1906 ;;
1907 esac
1908 AC_MSG_RESULT($platform_win32)
1909 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1911 dnl ***********************
1912 dnl *** g_thread checks ***
1913 dnl ***********************
1915 AC_ARG_WITH(threads,
1916 [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1917 [specify a thread implementation to use])],
1918 [],
1919 [with_threads=yes])
1921 dnl error and warning message
1922 dnl *************************
1924 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1926 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1927 platform (normally it's "_REENTRANT"). I'll not use any flag on
1928 compilation now, but then your programs might not work.
1929 Please provide information on how it is done on your system."
1931 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1932 "
1934 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1935 provide information on your thread implementation."
1937 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1938 functions will not be MT-safe during their first call because
1939 there is no working 'getpwuid_r' on your system."
1941 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1942 because there is no 'localtime_r' on your system."
1944 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1945 linking threaded applications. As GLib cannot do that
1946 automatically, you will get an linkg error everytime you are
1947 not using the right compiler. In that case you have to relink
1948 with the right compiler. Ususally just '_r' is appended
1949 to the compiler name."
1951 dnl determination of thread implementation
1952 dnl ***************************************
1954 AC_MSG_CHECKING(for thread implementation)
1956 have_threads=no
1957 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1958 AS_IF([ test "x$have_threads" = xno], [
1959 AC_TRY_COMPILE([#include <pthread.h>],
1960 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1961 have_threads=posix)
1962 ])
1963 # Tru64Unix requires -pthread to find pthread.h. See #103020
1964 if test "x$have_threads" = xno; then
1965 glib_save_CPPFLAGS="$CPPFLAGS"
1966 CPPFLAGS="$CPPFLAGS -pthread"
1967 AC_TRY_COMPILE([#include <pthread.h>],
1968 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1969 have_threads=posix)
1970 CPPFLAGS="$glib_save_CPPFLAGS"
1971 fi
1972 ])
1973 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1974 case $host in
1975 *-*-mingw*)
1976 have_threads=win32
1977 ;;
1978 esac
1979 fi
1981 if test "x$have_threads" = xno; then
1982 AC_MSG_RESULT(none available)
1983 AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1984 else
1985 AC_MSG_RESULT($have_threads)
1986 fi
1989 dnl determination of G_THREAD_CFLAGS
1990 dnl ********************************
1992 G_THREAD_LIBS=
1993 G_THREAD_LIBS_EXTRA=
1994 G_THREAD_CFLAGS=
1996 dnl
1997 dnl Test program for basic POSIX threads functionality
1998 dnl
1999 m4_define([glib_thread_test],[
2000 #include <pthread.h>
2001 int check_me = 0;
2002 void* func(void* data) {check_me = 42; return &check_me;}
2003 int main()
2004 { pthread_t t;
2005 void *ret;
2006 pthread_create (&t, $1, func, 0);
2007 pthread_join (t, &ret);
2008 return (check_me != 42 || ret != &check_me);
2009 }])
2011 AS_IF([ test x"$have_threads" = xposix], [
2012 # First we test for posix, whether -pthread or -pthreads do the trick as
2013 # both CPPFLAG and LIBS.
2014 # One of them does for most gcc versions and some other platforms/compilers
2015 # too and could be considered as the canonical way to go.
2016 case $host in
2017 *-*-cygwin*|*-*-darwin*)
2018 # skip cygwin and darwin -pthread or -pthreads test
2019 ;;
2020 *-solaris*)
2021 # These compiler/linker flags work with both Sun Studio and gcc
2022 # Sun Studio expands -mt to -D_REENTRANT and -lthread
2023 # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2024 G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2025 G_THREAD_LIBS="-lpthread -lthread"
2026 ;;
2027 *)
2028 for flag in pthread pthreads mt; do
2029 glib_save_CFLAGS="$CFLAGS"
2030 CFLAGS="$CFLAGS -$flag"
2031 AC_TRY_RUN(glib_thread_test(0),
2032 glib_flag_works=yes,
2033 glib_flag_works=no,
2034 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2035 glib_flag_works=yes,
2036 glib_flag_works=no)])
2037 CFLAGS="$glib_save_CFLAGS"
2038 if test $glib_flag_works = yes ; then
2039 G_THREAD_CFLAGS=-$flag
2040 G_THREAD_LIBS=-$flag
2041 break;
2042 fi
2043 done
2044 ;;
2045 esac
2046 ])
2048 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2050 # The canonical -pthread[s] does not work. Try something different.
2052 case $host in
2053 *-aix*)
2054 if test x"$GCC" = xyes; then
2055 # GCC 3.0 and above needs -pthread.
2056 # Should be coverd by the case above.
2057 # GCC 2.x and below needs -mthreads
2058 G_THREAD_CFLAGS="-mthreads"
2059 G_THREAD_LIBS=$G_THREAD_CFLAGS
2060 else
2061 # We are probably using the aix compiler. Normaly a
2062 # program would have to be compiled with the _r variant
2063 # of the corresponding compiler, but we as GLib cannot
2064 # do that: but the good news is that for compiling the
2065 # only difference is the added -D_THREAD_SAFE compile
2066 # option. This is according to the "C for AIX User's
2067 # Guide".
2068 G_THREAD_CFLAGS="-D_THREAD_SAFE"
2069 fi
2070 ;;
2071 *-sysv5uw7*) # UnixWare 7
2072 # We are not using gcc with -pthread. Catched above.
2073 G_THREAD_CFLAGS="-Kthread"
2074 G_THREAD_LIBS=$G_THREAD_CFLAGS
2075 ;;
2076 *-mingw*)
2077 # No flag needed when using MSVCRT.DLL
2078 G_THREAD_CFLAGS=""
2079 ;;
2080 *)
2081 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2082 ;;
2083 esac
2084 ])
2086 # if we are not finding the localtime_r function, then we probably are
2087 # not using the proper multithread flag
2089 glib_save_CPPFLAGS="$CPPFLAGS"
2090 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2092 # First we test, whether localtime_r is declared in time.h
2093 # directly. Then we test whether a macro localtime_r exists, in
2094 # which case localtime_r in the test program is replaced and thus
2095 # if we still find localtime_r in the output, it is not defined as
2096 # a macro.
2098 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2099 [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2100 localtime_r(a,b)],
2101 AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2103 CPPFLAGS="$glib_save_CPPFLAGS"
2105 AC_MSG_CHECKING(thread related cflags)
2106 AC_MSG_RESULT($G_THREAD_CFLAGS)
2107 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2109 dnl determination of G_THREAD_LIBS
2110 dnl ******************************
2112 AS_IF([test x$have_threads = xposix], [
2113 glib_save_CPPFLAGS="$CPPFLAGS"
2114 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2115 AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2116 case $host in
2117 *-aix*)
2118 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2119 # probably using the aix compiler.
2120 AC_MSG_WARN($AIX_COMPILE_INFO)
2121 ;;
2122 *)
2123 G_THREAD_LIBS=error
2124 glib_save_LIBS="$LIBS"
2125 for thread_lib in "" pthread pthread32 pthreads thread; do
2126 if test x"$thread_lib" = x; then
2127 add_thread_lib=""
2128 IN=""
2129 else
2130 add_thread_lib="-l$thread_lib"
2131 IN=" in -l$thread_lib"
2132 fi
2133 if test x"$have_threads" = xposix; then
2134 defattr=0
2135 else
2136 defattr=pthread_attr_default
2137 fi
2139 LIBS="$add_thread_lib $glib_save_LIBS"
2141 AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2142 AC_TRY_RUN(glib_thread_test($defattr),
2143 glib_result=yes,
2144 glib_result=no,
2145 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2146 glib_result=yes,
2147 glib_result=no)])
2148 AC_MSG_RESULT($glib_result)
2150 if test "$glib_result" = "yes" ; then
2151 G_THREAD_LIBS="$add_thread_lib"
2152 break
2153 fi
2154 done
2155 if test "x$G_THREAD_LIBS" = xerror; then
2156 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2157 fi
2158 LIBS="$glib_save_LIBS"
2159 ;;
2160 esac
2161 ])
2163 g_threads_impl="POSIX"
2164 AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2165 AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2166 CPPFLAGS="$glib_save_CPPFLAGS"
2167 ], [test x$have_threads = xwin32], [
2168 AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2169 g_threads_impl="WIN32"
2170 ], [
2171 AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2172 g_threads_impl="NONE"
2173 G_THREAD_LIBS=error
2174 ])
2175 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2176 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2177 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2179 if test "x$G_THREAD_LIBS" = xerror; then
2180 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2181 fi
2183 AC_MSG_CHECKING(thread related libraries)
2184 AC_MSG_RESULT($G_THREAD_LIBS)
2186 dnl check for mt safe function variants and some posix functions
2187 dnl ************************************************************
2189 glib_save_LIBS="$LIBS"
2190 # we are not doing the following for now, as this might require glib
2191 # to always be linked with the thread libs on some platforms.
2192 # LIBS="$LIBS $G_THREAD_LIBS"
2193 AC_CHECK_FUNCS(localtime_r gmtime_r getpwuid_r getgrgid_r)
2195 LIBS="$G_THREAD_LIBS $LIBS"
2196 AS_IF([ test x"$have_threads" = xposix], [
2197 glib_save_CPPFLAGS="$CPPFLAGS"
2198 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2199 # This is not AC_CHECK_FUNC to also work with function
2200 # name mangling in header files.
2201 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2202 AC_LINK_IFELSE(
2203 [AC_LANG_PROGRAM(
2204 [#include <pthread.h>],
2205 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2206 [AC_MSG_RESULT(yes)
2207 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2208 [Have function pthread_attr_setstacksize])],
2209 [AC_MSG_RESULT(no)])
2210 AC_MSG_CHECKING(for pthread_condattr_setclock)
2211 AC_LINK_IFELSE(
2212 [AC_LANG_PROGRAM(
2213 [#include <pthread.h>],
2214 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2215 [AC_MSG_RESULT(yes)
2216 AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2217 [Have function pthread_condattr_setclock])],
2218 [AC_MSG_RESULT(no)])
2219 AC_MSG_CHECKING(for pthread_cond_timedwait_relative_np)
2220 AC_LINK_IFELSE(
2221 [AC_LANG_PROGRAM(
2222 [#include <pthread.h>],
2223 [pthread_cond_timedwait_relative_np(NULL, NULL, NULL)])],
2224 [AC_MSG_RESULT(yes)
2225 AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP,1,
2226 [Have function pthread_cond_timedwait_relative_np])],
2227 [AC_MSG_RESULT(no)])
2228 dnl Sets thread names on OS X 10.6, iOS 3.2 (and higher)
2229 AC_MSG_CHECKING(for pthread_setname_np(const char*))
2230 AC_LINK_IFELSE(
2231 [AC_LANG_PROGRAM(
2232 [#include <pthread.h>],
2233 [pthread_setname_np("example")])],
2234 [AC_MSG_RESULT(yes)
2235 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
2236 [Have function pthread_setname_np(const char*)])],
2237 [AC_MSG_RESULT(no)])
2238 dnl Sets thread names on Solaris 11.3 & higher
2239 AC_MSG_CHECKING(for pthread_setname_np(pthread_t, const char*))
2240 AC_LINK_IFELSE(
2241 [AC_LANG_PROGRAM(
2242 [#include <pthread.h>],
2243 [pthread_setname_np(pthread_self(), "example")])],
2244 [AC_MSG_RESULT(yes)
2245 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITH_TID,1,
2246 [Have function pthread_setname_np(pthread_t, const char*)])],
2247 [AC_MSG_RESULT(no)])
2248 AC_MSG_CHECKING(for pthread_getname_np(pthread_t, name, len))
2249 AC_LINK_IFELSE(
2250 [AC_LANG_PROGRAM(
2251 [#include <pthread.h>],
2252 [[char name[16]; pthread_getname_np(pthread_self(), name, 16);]])],
2253 [AC_MSG_RESULT(yes)
2254 AC_DEFINE(HAVE_PTHREAD_GETNAME_NP,1,
2255 [Have function pthread_getname_np(pthread_t, name, len)])],
2256 [AC_MSG_RESULT(no)])
2257 CPPFLAGS="$glib_save_CPPFLAGS"
2258 ])
2260 LIBS="$glib_save_LIBS"
2262 # now spit out all the warnings.
2263 if test "$ac_cv_func_getpwuid_r" != "yes"; then
2264 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2265 fi
2266 if test "$ac_cv_func_localtime_r" != "yes"; then
2267 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2268 fi
2270 #
2271 # Hack to deal with:
2272 #
2273 # a) GCC < 3.3 for Linux doesn't include -lpthread when
2274 # building shared libraries with linux.
2275 # b) FreeBSD doesn't do this either.
2276 #
2277 case $host in
2278 *android*)
2279 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2280 ;;
2281 *-*-freebsd*|*-*-linux*)
2282 G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2283 ;;
2284 *)
2285 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2286 ;;
2287 esac
2289 AC_SUBST(G_THREAD_CFLAGS)
2290 AC_SUBST(G_THREAD_LIBS)
2291 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2292 AC_SUBST(G_THREAD_LIBS_EXTRA)
2294 AC_CHECK_FUNCS(clock_gettime, [], [
2295 AC_CHECK_LIB(rt, clock_gettime, [
2296 G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2297 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2298 ])
2299 ])
2302 dnl ************************
2303 dnl *** g_atomic_* tests ***
2304 dnl ************************
2306 dnl We need to decide at configure time if GLib will use real atomic
2307 dnl operations ("lock free") or emulated ones with a mutex. This is
2308 dnl because we must put this information in glibconfig.h so we know if
2309 dnl it is safe or not to inline using compiler intrinsics directly from
2310 dnl the header.
2311 dnl
2312 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2313 dnl user is interested in knowing if they can use the atomic ops across
2314 dnl processes.
2315 dnl
2316 dnl We can currently support the atomic ops natively when building GLib
2317 dnl with recent versions of GCC or MSVC. MSVC doesn't run ./configure,
2318 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2319 dnl we are using GCC (and not mingw*).
2320 dnl
2321 dnl Note that the atomic ops are only available with GCC on x86 when
2322 dnl using -march=i486 or higher. If we detect that the atomic ops are
2323 dnl not available but would be available given the right flags, we want
2324 dnl to abort and advise the user to fix their CFLAGS. It's better to do
2325 dnl that then to silently fall back on emulated atomic ops just because
2326 dnl the user had the wrong build environment.
2328 dnl We may add other compilers here in the future...
2330 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2331 case $host in
2332 *-*-mingw*)
2333 glib_cv_g_atomic_lock_free=yes
2334 ;;
2335 *)
2336 AC_TRY_LINK([],
2337 [volatile int atomic = 2;\
2338 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2339 [glib_cv_g_atomic_lock_free=yes],
2340 [glib_cv_g_atomic_lock_free=no])
2341 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2342 SAVE_CFLAGS="${CFLAGS}"
2343 CFLAGS="-march=i486"
2344 AC_TRY_LINK([],
2345 [volatile int atomic = 2;\
2346 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2347 [AC_MSG_ERROR([GLib must be built with -march=i486 or later.])],
2348 [])
2349 CFLAGS="${SAVE_CFLAGS}"
2350 fi
2351 ;;
2352 esac])
2355 case $host in
2356 *-*-mingw*)
2357 ;;
2358 *)
2359 # Some compilers support atomic operations but do not define
2360 # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2361 if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2362 AC_TRY_LINK([],
2363 [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2364 [],
2365 [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2366 fi
2367 ;;
2368 esac
2370 dnl We need a more robust approach here...
2371 case $host_cpu in
2372 i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2373 glib_memory_barrier_needed=no
2374 ;;
2375 sparc*|alpha*|powerpc*|ia64)
2376 glib_memory_barrier_needed=yes
2377 ;;
2378 *)
2379 glib_memory_barrier_needed=yes
2380 ;;
2381 esac
2383 dnl ************************
2384 dnl ** Check for futex(2) **
2385 dnl ************************
2386 AC_CACHE_CHECK(for futex(2) system call,
2387 glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2388 #include <linux/futex.h>
2389 #include <sys/syscall.h>
2390 #include <unistd.h>
2391 ],[
2392 syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2393 ])],glib_cv_futex=yes,glib_cv_futex=no))
2394 if test x"$glib_cv_futex" = xyes; then
2395 AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2396 fi
2398 AC_CACHE_CHECK(for eventfd(2) system call,
2399 glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2400 #include <sys/eventfd.h>
2401 #include <unistd.h>
2402 ],[
2403 eventfd (0, EFD_CLOEXEC);
2404 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2405 if test x"$glib_cv_eventfd" = x"yes"; then
2406 AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2407 fi
2408 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2410 dnl ****************************************
2411 dnl *** GLib POLL* compatibility defines ***
2412 dnl ****************************************
2414 glib_poll_includes=["
2415 #include <sys/types.h>
2416 #include <poll.h>
2417 "]
2419 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2420 test $ac_cv_func_poll = yes ], [
2421 glib_failed=false
2422 GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2423 GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2424 GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2425 GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2426 GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2427 GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2428 if $glib_failed ; then
2429 AC_MSG_ERROR([Could not determine values for POLL* constants])
2430 fi
2431 ], [
2432 glib_cv_value_POLLIN=1
2433 glib_cv_value_POLLOUT=4
2434 glib_cv_value_POLLPRI=2
2435 glib_cv_value_POLLERR=8
2436 glib_cv_value_POLLHUP=16
2437 glib_cv_value_POLLNVAL=32
2438 ])
2440 AC_MSG_CHECKING([for broken poll])
2441 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2442 #include <stdlib.h>
2443 #include <fcntl.h>
2444 #include <poll.h>
2445 int main(void) {
2446 struct pollfd fds[1];
2447 int fd;
2448 fd = open("/dev/null", 1);
2449 fds[0].fd = fd;
2450 fds[0].events = POLLIN;
2451 fds[0].revents = 0;
2452 if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2453 exit(1); /* Does not work for devices -- fail */
2454 }
2455 exit(0);
2456 }]])],
2457 [broken_poll=no],
2458 [broken_poll=yes
2459 AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2460 [broken_poll="no (cross compiling)"])
2461 AC_MSG_RESULT($broken_poll)
2463 dnl *********************
2464 dnl *** GRegex checks ***
2465 dnl *********************
2467 PCRE_REQUIRED_VERSION=8.13
2469 # Check if we should use the internal or the system-supplied pcre
2470 AC_ARG_WITH(pcre,
2471 [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2472 [whether to use system PCRE [default=system]])],
2473 [],
2474 [with_pcre=system])
2476 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2478 AS_IF([ test "x$with_pcre" = xsystem], [
2479 PKG_CHECK_MODULES(PCRE,
2480 libpcre >= $PCRE_REQUIRED_VERSION)
2481 AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2482 glib_save_CFLAGS="$CFLAGS"
2483 glib_save_LIBS="$LIBS"
2484 CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2485 AC_TRY_RUN([#include <pcre.h>
2486 int main () {
2487 int support;
2488 pcre_config (PCRE_CONFIG_UTF8, &support);
2489 if (!support)
2490 return 1;
2491 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2492 if (!support)
2493 return 1;
2494 return 0;
2495 }],
2496 glib_cv_pcre_has_unicode=yes,
2497 glib_cv_pcre_has_unicode=no,
2498 glib_cv_pcre_has_unicode=yes)
2499 CFLAGS="$glib_save_CFLAGS"
2500 LIBS="$glib_save_LIBS"
2501 ])
2502 if test "$glib_cv_pcre_has_unicode" = "no"; then
2503 AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2504 fi
2505 AC_SUBST(PCRE_CFLAGS)
2506 AC_SUBST(PCRE_LIBS)
2507 AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2508 PCRE_REQUIRES=libpcre
2509 AC_SUBST(PCRE_REQUIRES)
2510 ], [
2511 # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2512 AS_IF([ test x"$GCC" = xyes], [
2513 AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2514 save_CFLAGS="$CFLAGS"
2515 CFLAGS="$CFLAGS -Wno-pointer-sign"
2516 AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2517 AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2518 CFLAGS="$save_CFLAGS"
2519 ])
2520 ])
2521 AC_SUBST(PCRE_WARN_CFLAGS)
2523 dnl **********************
2524 dnl *** Win32 API libs ***
2525 dnl **********************
2527 case $host in
2528 *-*-cygwin*)
2529 G_LIBS_EXTRA="-luser32 -lkernel32"
2530 ;;
2531 *-*-mingw*)
2532 G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2533 ;;
2534 *)
2535 G_LIBS_EXTRA=""
2536 ;;
2537 esac
2538 AC_SUBST(G_LIBS_EXTRA)
2540 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2541 dnl since we need it for g_iconv()
2543 AC_MSG_CHECKING([for EILSEQ])
2544 AC_TRY_COMPILE([
2545 #include <errno.h>
2546 ],
2547 [
2548 int error = EILSEQ;
2549 ], have_eilseq=yes, have_eilseq=no);
2550 AC_MSG_RESULT($have_eilseq)
2552 dnl Add a conditional we can use when cross-compiling, so we avoid running
2553 dnl binaries
2554 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2556 dnl **************************
2557 dnl *** Checks for gtk-doc ***
2558 dnl **************************
2559 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2560 # it on it's own line.
2561 m4_ifdef([GTK_DOC_CHECK], [
2562 GTK_DOC_CHECK([1.20], [--flavour no-tmpl])
2563 ],[
2564 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2565 ])
2567 AC_ARG_ENABLE(man,
2568 [AS_HELP_STRING([--enable-man],
2569 [generate man pages [default=auto]])],,
2570 enable_man=maybe)
2572 AS_IF([test "$enable_man" != no], [
2573 AC_PATH_PROG([XSLTPROC], [xsltproc])
2574 AS_IF([test -z "$XSLTPROC"], [
2575 AS_IF([test "$enable_man" = yes], [
2576 AC_MSG_ERROR([xsltproc is required for --enable-man])
2577 ])
2578 enable_man=no
2579 ])
2580 ])
2582 AS_IF([ test "$enable_man" != no ], [
2583 dnl check for DocBook DTD in the local catalog
2584 JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2585 [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2586 AS_IF([test "$have_docbook_dtd" != yes], [
2587 AS_IF([test "$enable_man" = yes ], [
2588 AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2589 ])
2590 enable_man=no
2591 ])
2592 ])
2594 AS_IF([test "$enable_man" != no], [
2595 dnl check for DocBook XSL stylesheets in the local catalog
2596 JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2597 [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2598 AS_IF([ test "$have_docbook_style" != yes ], [
2599 AS_IF([ test "$enable_man" = yes ], [
2600 AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2601 ])
2602 enable_man=no
2603 ])
2604 ])
2606 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2608 AC_MSG_CHECKING([whether to generate man pages])
2609 AS_IF([ test "$enable_man" != no ], [
2610 AC_MSG_RESULT([yes])
2611 ], [
2612 AC_MSG_RESULT([no])
2613 ])
2615 dnl
2616 dnl Tracing
2617 dnl
2619 AC_ARG_ENABLE([dtrace],
2620 [AS_HELP_STRING([--enable-dtrace],
2621 [include tracing support for dtrace])])
2622 have_dtrace=no
2623 AC_MSG_CHECKING([whether to include dtrace tracing support])
2624 AS_IF([ test "x$enable_dtrace" != xno], [
2625 if test x$glib_have_carbon = xyes; then
2626 AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2627 else
2628 AC_MSG_RESULT([yes])
2629 AC_CHECK_PROGS(DTRACE, dtrace)
2630 if test -z "$DTRACE"; then
2631 if test "x$enable_dtrace" = xyes; then
2632 AC_MSG_ERROR([dtrace not found])
2633 fi
2634 else
2635 AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2636 [if test "x$enable_dtrace" = xyes; then
2637 AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2638 fi])
2639 fi
2640 fi
2641 ], [
2642 AC_MSG_RESULT([no])
2643 ])
2644 if test "x$have_dtrace" = xyes; then
2645 AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2646 fi
2647 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2649 AC_MSG_CHECKING([whether to include systemtap tracing support])
2650 AC_ARG_ENABLE([systemtap],
2651 [AS_HELP_STRING([--enable-systemtap],
2652 [include tracing support for systemtap])])
2653 have_systemtap=no
2654 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2655 have_systemtap=yes
2656 fi
2657 AC_MSG_RESULT(${have_systemtap})
2659 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2661 AC_ARG_WITH([tapset-install-dir],
2662 AS_HELP_STRING([--with-tapset-install-dir=DIR],
2663 [path where systemtap tapsets are installed [DATADIR/systemtap/tapset/HOST_CPU]]),
2664 [if test "x${withval}" = x; then
2665 ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset/${host_cpu}"
2666 else
2667 ABS_TAPSET_DIR="${withval}"
2668 fi],
2669 [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset/${host_cpu}"])
2670 AC_SUBST(ABS_TAPSET_DIR)
2672 dnl ************************************
2673 dnl *** Enable lcov coverage reports ***
2674 dnl ************************************
2676 AC_ARG_ENABLE(coverage,
2677 AS_HELP_STRING([--enable-coverage],
2678 [enable coverage testing with gcov]),
2679 [use_gcov=$enableval], [use_gcov=no])
2681 AS_IF([ test "x$use_gcov" = "xyes"], [
2682 dnl we need gcc:
2683 if test "$GCC" != "yes"; then
2684 AC_MSG_ERROR([GCC is required for --enable-coverage])
2685 fi
2687 dnl Check if ccache is being used
2688 AC_CHECK_PROG(SHTOOL, shtool, shtool)
2689 case `$SHTOOL path $CC` in
2690 *ccache*[)] gcc_ccache=yes;;
2691 *[)] gcc_ccache=no;;
2692 esac
2694 if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2695 AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2696 fi
2698 ltp_version_list="1.6 1.7 1.8 1.9 1.10 1.12"
2699 AC_CHECK_PROG(LTP, lcov, lcov)
2700 AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2702 AS_IF([ test "$LTP" ], [
2703 AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2704 glib_cv_ltp_version=invalid
2705 ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2706 for ltp_check_version in $ltp_version_list; do
2707 if test "$ltp_version" = "$ltp_check_version"; then
2708 glib_cv_ltp_version="$ltp_check_version (ok)"
2709 fi
2710 done
2711 ])
2712 ], [
2713 ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2714 AC_MSG_ERROR([$ltp_msg])
2715 ])
2717 case $glib_cv_ltp_version in
2718 ""|invalid[)]
2719 ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2720 AC_MSG_ERROR([$ltp_msg])
2721 LTP="exit 0;"
2722 ;;
2723 esac
2725 if test -z "$LTP_GENHTML"; then
2726 AC_MSG_ERROR([Could not find genhtml from the LTP package])
2727 fi
2729 dnl Remove all optimization flags from CFLAGS
2730 changequote({,})
2731 CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2732 changequote([,])
2734 dnl Add the special gcc flags
2735 CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2736 LDFLAGS="$LDFLAGS -lgcov"
2737 ])
2739 dnl *******************************
2740 dnl *** Disable strict aliasing ***
2741 dnl *******************************
2742 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=791622
2743 AS_IF([test "${GCC}" = "yes"],[
2744 CFLAGS="$CFLAGS -fno-strict-aliasing"
2745 ])
2747 dnl ******************************
2748 dnl *** output the whole stuff ***
2749 dnl ******************************
2751 dnl this section will only be run if config.status is invoked with no
2752 dnl arguments, or with "glib/glibconfig.h" as an argument.
2753 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2754 [
2755 outfile=glib/glibconfig.h-tmp
2756 cat > $outfile <<\_______EOF
2757 /* glibconfig.h
2758 *
2759 * This is a generated file. Please modify 'configure.ac'
2760 */
2762 #ifndef __GLIBCONFIG_H__
2763 #define __GLIBCONFIG_H__
2765 #include <glib/gmacros.h>
2767 _______EOF
2769 echo '#include <limits.h>' >> $outfile
2770 echo '#include <float.h>' >> $outfile
2771 if test x$glib_values_h = xyes; then
2772 echo '#include <values.h>' >> $outfile
2773 fi
2774 if test "$glib_header_alloca_h" = "yes"; then
2775 echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2776 fi
2777 if test x$glib_included_printf != xyes; then
2778 echo "
2779 /* Specifies that GLib's g_print*() functions wrap the
2780 * system printf functions. This is useful to know, for example,
2781 * when using glibc's register_printf_function().
2782 */" >> $outfile
2783 echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2784 fi
2786 cat >> $outfile <<_______EOF
2788 G_BEGIN_DECLS
2790 #define G_MINFLOAT FLT_MIN
2791 #define G_MAXFLOAT FLT_MAX
2792 #define G_MINDOUBLE DBL_MIN
2793 #define G_MAXDOUBLE DBL_MAX
2794 #define G_MINSHORT SHRT_MIN
2795 #define G_MAXSHORT SHRT_MAX
2796 #define G_MAXUSHORT USHRT_MAX
2797 #define G_MININT INT_MIN
2798 #define G_MAXINT INT_MAX
2799 #define G_MAXUINT UINT_MAX
2800 #define G_MINLONG LONG_MIN
2801 #define G_MAXLONG LONG_MAX
2802 #define G_MAXULONG ULONG_MAX
2804 _______EOF
2807 ### this should always be true in a modern C/C++ compiler
2808 ### and is statically asserted by glib-init.c
2809 cat >>$outfile <<_______EOF
2810 typedef signed char gint8;
2811 typedef unsigned char guint8;
2812 _______EOF
2815 if test -n "$gint16"; then
2816 cat >>$outfile <<_______EOF
2817 typedef signed $gint16 gint16;
2818 typedef unsigned $gint16 guint16;
2819 #define G_GINT16_MODIFIER $gint16_modifier
2820 #define G_GINT16_FORMAT $gint16_format
2821 #define G_GUINT16_FORMAT $guint16_format
2822 _______EOF
2823 fi
2826 if test -n "$gint32"; then
2827 cat >>$outfile <<_______EOF
2828 typedef signed $gint32 gint32;
2829 typedef unsigned $gint32 guint32;
2830 #define G_GINT32_MODIFIER $gint32_modifier
2831 #define G_GINT32_FORMAT $gint32_format
2832 #define G_GUINT32_FORMAT $guint32_format
2833 _______EOF
2834 fi
2836 cat >>$outfile <<_______EOF
2837 #define G_HAVE_GINT64 1 /* deprecated, always true */
2839 ${glib_extension}typedef signed $gint64 gint64;
2840 ${glib_extension}typedef unsigned $gint64 guint64;
2842 #define G_GINT64_CONSTANT(val) $gint64_constant
2843 #define G_GUINT64_CONSTANT(val) $guint64_constant
2844 _______EOF
2846 if test x$gint64_format != x ; then
2847 cat >>$outfile <<_______EOF
2848 #define G_GINT64_MODIFIER $gint64_modifier
2849 #define G_GINT64_FORMAT $gint64_format
2850 #define G_GUINT64_FORMAT $guint64_format
2851 _______EOF
2852 else
2853 cat >>$outfile <<_______EOF
2854 #undef G_GINT64_MODIFIER
2855 #undef G_GINT64_FORMAT
2856 #undef G_GUINT64_FORMAT
2857 _______EOF
2858 fi
2860 cat >>$outfile <<_______EOF
2862 #define GLIB_SIZEOF_VOID_P $glib_void_p
2863 #define GLIB_SIZEOF_LONG $glib_long
2864 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2865 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2867 _______EOF
2869 cat >>$outfile <<_______EOF
2870 typedef signed $glib_ssize_type_define gssize;
2871 typedef unsigned $glib_size_type_define gsize;
2872 #define G_GSIZE_MODIFIER $gsize_modifier
2873 #define G_GSSIZE_MODIFIER $gssize_modifier
2874 #define G_GSIZE_FORMAT $gsize_format
2875 #define G_GSSIZE_FORMAT $gssize_format
2877 #define G_MAXSIZE G_MAXU$glib_msize_type
2878 #define G_MINSSIZE G_MIN$glib_mssize_type
2879 #define G_MAXSSIZE G_MAX$glib_mssize_type
2881 typedef gint64 goffset;
2882 #define G_MINOFFSET G_MININT64
2883 #define G_MAXOFFSET G_MAXINT64
2885 #define G_GOFFSET_MODIFIER G_GINT64_MODIFIER
2886 #define G_GOFFSET_FORMAT G_GINT64_FORMAT
2887 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2889 #define G_POLLFD_FORMAT $g_pollfd_format
2891 _______EOF
2893 if test -z "$glib_unknown_void_p"; then
2894 cat >>$outfile <<_______EOF
2896 #define GPOINTER_TO_INT(p) ((gint) ${glib_gpi_cast} (p))
2897 #define GPOINTER_TO_UINT(p) ((guint) ${glib_gpui_cast} (p))
2899 #define GINT_TO_POINTER(i) ((gpointer) ${glib_gpi_cast} (i))
2900 #define GUINT_TO_POINTER(u) ((gpointer) ${glib_gpui_cast} (u))
2902 typedef signed $glib_intptr_type_define gintptr;
2903 typedef unsigned $glib_intptr_type_define guintptr;
2905 #define G_GINTPTR_MODIFIER $gintptr_modifier
2906 #define G_GINTPTR_FORMAT $gintptr_format
2907 #define G_GUINTPTR_FORMAT $guintptr_format
2908 _______EOF
2909 else
2910 echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2911 fi
2915 cat >>$outfile <<_______EOF
2916 #ifndef G_DISABLE_DEPRECATED
2917 #define g_ATEXIT(proc) (atexit (proc))
2918 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2919 #endif
2920 $glib_defines
2921 $glib_os
2922 $glib_static_compilation
2924 $glib_vacopy
2926 _______EOF
2928 if test x$g_have_iso_c_varargs = xyes ; then
2929 cat >>$outfile <<_______EOF
2930 #ifndef __cplusplus
2931 # define G_HAVE_ISO_VARARGS 1
2932 #endif
2933 _______EOF
2934 fi
2935 if test x$g_have_iso_cxx_varargs = xyes ; then
2936 cat >>$outfile <<_______EOF
2937 #ifdef __cplusplus
2938 # define G_HAVE_ISO_VARARGS 1
2939 #endif
2940 _______EOF
2941 fi
2942 if test x$g_have_gnuc_varargs = xyes ; then
2943 cat >>$outfile <<_______EOF
2945 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2946 * is passed ISO vararg support is turned off, and there is no work
2947 * around to turn it on, so we unconditionally turn it off.
2948 */
2949 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2950 # undef G_HAVE_ISO_VARARGS
2951 #endif
2953 #define G_HAVE_GNUC_VARARGS 1
2954 _______EOF
2955 fi
2957 case x$g_stack_grows in
2958 xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2959 *) echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2960 esac
2963 echo >>$outfile
2964 if test x$g_have_eilseq = xno; then
2965 cat >>$outfile <<_______EOF
2966 #ifndef EILSEQ
2967 /* On some pre-C99 systems, EILSEQ is not defined.
2968 * The correspondence between this and the corresponding definition
2969 * in libiconv is essential.
2970 */
2971 # define EILSEQ ENOENT
2972 #endif
2973 _______EOF
2975 fi
2977 if test x$g_have_gnuc_visibility = xyes; then
2978 cat >>$outfile <<_______EOF
2979 #define G_HAVE_GNUC_VISIBILITY 1
2980 _______EOF
2981 fi
2982 cat >>$outfile <<_______EOF
2983 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2984 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2985 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2986 #define G_GNUC_INTERNAL __hidden
2987 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2988 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2989 #else
2990 #define G_GNUC_INTERNAL
2991 #endif
2992 _______EOF
2994 echo >>$outfile
2995 cat >>$outfile <<_______EOF
2996 #define G_THREADS_ENABLED
2997 #define G_THREADS_IMPL_$g_threads_impl_def
2998 _______EOF
3000 if test x"$g_memory_barrier_needed" != xno; then
3001 echo >>$outfile
3002 echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3003 fi
3004 if test x"$g_atomic_lock_free" = xyes; then
3005 echo >>$outfile
3006 echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3007 fi
3008 echo >>$outfile
3009 g_bit_sizes="16 32 64"
3010 for bits in $g_bit_sizes; do
3011 cat >>$outfile <<_______EOF
3012 #define GINT${bits}_TO_${g_bs_native}(val) ((gint${bits}) (val))
3013 #define GUINT${bits}_TO_${g_bs_native}(val) ((guint${bits}) (val))
3014 #define GINT${bits}_TO_${g_bs_alien}(val) ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3015 #define GUINT${bits}_TO_${g_bs_alien}(val) (GUINT${bits}_SWAP_LE_BE (val))
3016 _______EOF
3017 done
3019 cat >>$outfile <<_______EOF
3020 #define GLONG_TO_LE(val) ((glong) GINT${glongbits}_TO_LE (val))
3021 #define GULONG_TO_LE(val) ((gulong) GUINT${glongbits}_TO_LE (val))
3022 #define GLONG_TO_BE(val) ((glong) GINT${glongbits}_TO_BE (val))
3023 #define GULONG_TO_BE(val) ((gulong) GUINT${glongbits}_TO_BE (val))
3024 #define GINT_TO_LE(val) ((gint) GINT${gintbits}_TO_LE (val))
3025 #define GUINT_TO_LE(val) ((guint) GUINT${gintbits}_TO_LE (val))
3026 #define GINT_TO_BE(val) ((gint) GINT${gintbits}_TO_BE (val))
3027 #define GUINT_TO_BE(val) ((guint) GUINT${gintbits}_TO_BE (val))
3028 #define GSIZE_TO_LE(val) ((gsize) GUINT${gsizebits}_TO_LE (val))
3029 #define GSSIZE_TO_LE(val) ((gssize) GINT${gssizebits}_TO_LE (val))
3030 #define GSIZE_TO_BE(val) ((gsize) GUINT${gsizebits}_TO_BE (val))
3031 #define GSSIZE_TO_BE(val) ((gssize) GINT${gssizebits}_TO_BE (val))
3032 #define G_BYTE_ORDER $g_byte_order
3034 #define GLIB_SYSDEF_POLLIN =$g_pollin
3035 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3036 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3037 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3038 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3039 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3041 #define G_MODULE_SUFFIX "$g_module_suffix"
3043 typedef $g_pid_type GPid;
3044 #define G_PID_FORMAT $g_pid_format
3046 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3047 #define GLIB_SYSDEF_AF_INET $g_af_inet
3048 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3050 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3051 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3052 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3054 #define G_DIR_SEPARATOR '$g_dir_separator'
3055 #define G_DIR_SEPARATOR_S "$g_dir_separator"
3056 #define G_SEARCHPATH_SEPARATOR '$g_searchpath_separator'
3057 #define G_SEARCHPATH_SEPARATOR_S "$g_searchpath_separator"
3059 G_END_DECLS
3061 #endif /* __GLIBCONFIG_H__ */
3062 _______EOF
3065 if cmp -s $outfile glib/glibconfig.h; then
3066 AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3067 rm -f $outfile
3068 else
3069 mv $outfile glib/glibconfig.h
3070 fi
3071 ],[
3073 # Note that if two cases are the same, case goes with the first one.
3074 # Note also that this is inside an AC_OUTPUT_COMMAND. We do not depend
3075 # on variable expansion in case labels. Look at the generated config.status
3076 # for a hint.
3078 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3079 glib_header_alloca_h="$ac_cv_working_alloca_h"
3080 else
3081 glib_header_alloca_h="$ac_cv_header_alloca_h"
3082 fi
3084 if test x$enable_included_printf = xyes ; then
3085 glib_included_printf=yes
3086 fi
3088 case 2 in
3089 $ac_cv_sizeof_short)
3090 gint16=short
3091 gint16_modifier='"h"'
3092 gint16_format='"hi"'
3093 guint16_format='"hu"'
3094 ;;
3095 $ac_cv_sizeof_int)
3096 gint16=int
3097 gint16_modifier='""'
3098 gint16_format='"i"'
3099 guint16_format='"u"'
3100 ;;
3101 esac
3102 case 4 in
3103 $ac_cv_sizeof_short)
3104 gint32=short
3105 gint32_modifier='"h"'
3106 gint32_format='"hi"'
3107 guint32_format='"hu"'
3108 ;;
3109 $ac_cv_sizeof_int)
3110 gint32=int
3111 gint32_modifier='""'
3112 gint32_format='"i"'
3113 guint32_format='"u"'
3114 ;;
3115 $ac_cv_sizeof_long)
3116 gint32=long
3117 gint32_modifier='"l"'
3118 gint32_format='"li"'
3119 guint32_format='"lu"'
3120 ;;
3121 esac
3122 case 8 in
3123 $ac_cv_sizeof_int)
3124 gint64=int
3125 gint64_modifier='""'
3126 gint64_format='"i"'
3127 guint64_format='"u"'
3128 glib_extension=
3129 gint64_constant='(val)'
3130 guint64_constant='(val)'
3131 ;;
3132 $ac_cv_sizeof_long)
3133 gint64=long
3134 gint64_modifier='"l"'
3135 gint64_format='"li"'
3136 guint64_format='"lu"'
3137 glib_extension=
3138 gint64_constant='(val##L)'
3139 guint64_constant='(val##UL)'
3140 ;;
3141 $ac_cv_sizeof_long_long)
3142 gint64='long long'
3143 if test -n "$glib_cv_long_long_format"; then
3144 gint64_modifier='"'$glib_cv_long_long_format'"'
3145 gint64_format='"'$glib_cv_long_long_format'i"'
3146 guint64_format='"'$glib_cv_long_long_format'u"'
3147 fi
3148 glib_extension='G_GNUC_EXTENSION '
3149 gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3150 guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3151 ;;
3152 $ac_cv_sizeof___int64)
3153 gint64='__int64'
3154 if test -n "$glib_cv_long_long_format"; then
3155 gint64_modifier='"'$glib_cv_long_long_format'"'
3156 gint64_format='"'$glib_cv_long_long_format'i"'
3157 guint64_format='"'$glib_cv_long_long_format'u"'
3158 fi
3159 glib_extension=
3160 gint64_constant='(val##i64)'
3161 guint64_constant='(val##ui64)'
3162 ;;
3163 esac
3164 glib_size_t=$ac_cv_sizeof_size_t
3165 glib_ssize_t=$ac_cv_sizeof_ssize_t
3166 glib_size_type_define="$glib_size_type"
3167 glib_ssize_type_define="$glib_ssize_type"
3168 glib_void_p=$ac_cv_sizeof_void_p
3169 glib_long=$ac_cv_sizeof_long
3171 case "$glib_size_type" in
3172 short)
3173 gsize_modifier='"h"'
3174 gsize_format='"hu"'
3175 glib_msize_type='SHRT'
3176 ;;
3177 int)
3178 gsize_modifier='""'
3179 gsize_format='"u"'
3180 glib_msize_type='INT'
3181 ;;
3182 long)
3183 gsize_modifier='"l"'
3184 gsize_format='"lu"'
3185 glib_msize_type='LONG'
3186 ;;
3187 "long long"|__int64)
3188 gsize_modifier='"I64"'
3189 gsize_format='"I64u"'
3190 glib_msize_type='INT64'
3191 ;;
3192 esac
3194 case "$glib_ssize_type" in
3195 short)
3196 gssize_modifier='"h"'
3197 gssize_format='"hi"'
3198 glib_mssize_type='SHRT'
3199 ;;
3200 int)
3201 gssize_modifier='""'
3202 gssize_format='"i"'
3203 glib_mssize_type='INT'
3204 ;;
3205 long)
3206 gssize_modifier='"l"'
3207 gssize_format='"li"'
3208 glib_mssize_type='LONG'
3209 ;;
3210 "long long"|__int64)
3211 gssize_modifier='"I64"'
3212 gssize_format='"I64i"'
3213 glib_mssize_type='INT64'
3214 ;;
3215 esac
3217 gintbits=`expr $ac_cv_sizeof_int \* 8`
3218 glongbits=`expr $ac_cv_sizeof_long \* 8`
3219 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3220 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3222 case $ac_cv_sizeof_void_p in
3223 $ac_cv_sizeof_int)
3224 glib_intptr_type_define=int
3225 gintptr_modifier='""'
3226 gintptr_format='"i"'
3227 guintptr_format='"u"'
3228 glib_gpi_cast='(gint)'
3229 glib_gpui_cast='(guint)'
3230 ;;
3231 $ac_cv_sizeof_long)
3232 glib_intptr_type_define=long
3233 gintptr_modifier='"l"'
3234 gintptr_format='"li"'
3235 guintptr_format='"lu"'
3236 glib_gpi_cast='(glong)'
3237 glib_gpui_cast='(gulong)'
3238 ;;
3239 $ac_cv_sizeof_long_long)
3240 glib_intptr_type_define='long long'
3241 gintptr_modifier='"I64"'
3242 gintptr_format='"I64i"'
3243 guintptr_format='"I64u"'
3244 glib_gpi_cast='(gint64)'
3245 glib_gpui_cast='(guint64)'
3246 ;;
3247 $ac_cv_sizeof___int64)
3248 glib_intptr_type_define=__int64
3249 gintptr_modifier='"I64"'
3250 gintptr_format='"I64i"'
3251 guintptr_format='"I64u"'
3252 glib_gpi_cast='(gint64)'
3253 glib_gpui_cast='(guint64)'
3254 ;;
3255 *)
3256 glib_unknown_void_p=yes
3257 ;;
3258 esac
3261 glib_defines="
3262 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3263 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3264 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3265 "
3267 case xyes in
3268 x$glib_cv_va_copy) glib_vacopy='#define G_VA_COPY va_copy' ;;
3269 x$glib_cv___va_copy) glib_vacopy='#define G_VA_COPY __va_copy' ;;
3270 *) glib_vacopy=''
3271 esac
3273 if test x$glib_cv_va_val_copy = xno; then
3274 glib_vacopy="\$glib_vacopy
3275 #define G_VA_COPY_AS_ARRAY 1"
3276 fi
3278 g_have_gnuc_varargs=$g_have_gnuc_varargs
3279 g_have_iso_c_varargs=$g_have_iso_c_varargs
3280 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3282 g_have_gnuc_visibility=$g_have_gnuc_visibility
3283 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3285 if test x$ac_cv_c_bigendian = xyes; then
3286 g_byte_order=G_BIG_ENDIAN
3287 g_bs_native=BE
3288 g_bs_alien=LE
3289 else
3290 g_byte_order=G_LITTLE_ENDIAN
3291 g_bs_native=LE
3292 g_bs_alien=BE
3293 fi
3295 g_pollin=$glib_cv_value_POLLIN
3296 g_pollout=$glib_cv_value_POLLOUT
3297 g_pollpri=$glib_cv_value_POLLPRI
3298 g_pollhup=$glib_cv_value_POLLHUP
3299 g_pollerr=$glib_cv_value_POLLERR
3300 g_pollnval=$glib_cv_value_POLLNVAL
3302 # If a family is not found on the system, define that family to
3303 # a negative value, picking a different one for each undefined
3304 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3305 # This is needed because glib-mkenums doesn't handle optional
3306 # values in enums, and thus we have to have all existing values
3307 # defined in the enum.
3308 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3309 g_af_unix=$glib_cv_value_AF_UNIX
3310 else
3311 g_af_unix=-1
3312 fi
3313 g_af_inet=$glib_cv_value_AF_INET
3314 g_af_inet6=$glib_cv_value_AF_INET6
3316 g_msg_peek=$glib_cv_value_MSG_PEEK
3317 g_msg_oob=$glib_cv_value_MSG_OOB
3318 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3320 g_stack_grows=$glib_cv_stack_grows
3322 g_have_eilseq=$have_eilseq
3324 g_threads_impl_def=$g_threads_impl
3326 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3327 g_memory_barrier_needed="$glib_memory_barrier_needed"
3328 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3330 g_module_suffix="$glib_gmodule_suffix"
3331 g_dir_separator="$glib_dir_separator"
3332 g_searchpath_separator="$glib_searchpath_separator"
3334 g_pid_type="$glib_pid_type"
3335 g_pid_format="\"$glib_pid_format\""
3336 g_pollfd_format="\"$glib_pollfd_format\""
3338 case $host in
3339 *-*-cygwin*)
3340 glib_os="#define G_OS_UNIX
3341 #define G_PLATFORM_WIN32
3342 #define G_WITH_CYGWIN"
3343 ;;
3344 *-*-mingw*)
3345 glib_os="#define G_OS_WIN32
3346 #define G_PLATFORM_WIN32"
3347 ;;
3348 *)
3349 glib_os="#define G_OS_UNIX"
3350 ;;
3351 esac
3352 glib_static_compilation=""
3353 if test x$glib_win32_static_compilation = xyes; then
3354 glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3355 #define GOBJECT_STATIC_COMPILATION 1"
3356 fi
3357 ])
3359 # Redo enough to get guint32 and guint64 for the alignment checks below
3360 case 4 in
3361 $ac_cv_sizeof_short)
3362 gint32=short
3363 ;;
3364 $ac_cv_sizeof_int)
3365 gint32=int
3366 ;;
3367 $ac_cv_sizeof_long)
3368 gint32=long
3369 ;;
3370 esac
3371 case 8 in
3372 $ac_cv_sizeof_int)
3373 gint64=int
3374 ;;
3375 $ac_cv_sizeof_long)
3376 gint64=long
3377 ;;
3378 $ac_cv_sizeof_long_long)
3379 gint64='long long'
3380 ;;
3381 $ac_cv_sizeof___int64)
3382 gint64='__int64'
3383 ;;
3384 esac
3386 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3387 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3388 typedef unsigned $gint32 guint32;])
3389 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3390 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3391 typedef unsigned $gint64 guint64;])
3392 AC_CHECK_TYPE([unsigned long])
3393 AC_CHECK_ALIGNOF([unsigned long])
3395 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3396 #
3397 # 1.2.14 required for dbus_message_set_serial
3398 PKG_CHECK_MODULES(DBUS1,
3399 dbus-1 >= 1.2.14,
3400 [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3401 have_dbus1=no)
3402 AC_SUBST(DBUS1_CFLAGS)
3403 AC_SUBST(DBUS1_LIBS)
3404 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3406 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3407 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3409 # Check whether MSVC toolset is explicitly set
3410 AM_CONDITIONAL(MSVC_BASE_NO_TOOLSET_SET, [test x$MSVC_BASE_TOOLSET = x])
3411 AM_CONDITIONAL(MSVC_NO_TOOLSET_SET, [test x$MSVC_TOOLSET = x])
3413 dnl
3414 dnl Check for -Bsymbolic-functions linker flag used to avoid
3415 dnl intra-library PLT jumps, if available.
3416 dnl
3418 AC_ARG_ENABLE(Bsymbolic,
3419 [AS_HELP_STRING([--disable-Bsymbolic],
3420 [avoid linking with -Bsymbolic])],,
3421 [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3422 AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3423 LDFLAGS=-Wl,-Bsymbolic-functions
3424 LIBS=
3425 AC_TRY_LINK([], [return 0],
3426 AC_MSG_RESULT(yes)
3427 enable_Bsymbolic=yes,
3428 AC_MSG_RESULT(no)
3429 enable_Bsymbolic=no)
3430 LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3432 if test "x${enable_Bsymbolic}" = "xyes"; then
3433 GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3434 fi
3436 dnl
3437 dnl Check for -z,nodelete linker flag: the type system assumes that
3438 dnl libgobject stays loaded for the lifetime of the process.
3439 dnl Since ld.bfd does not treat wrong -z options as fatal by default,
3440 dnl we also try to check for the --fatal-warnings linker flag if
3441 dnl auto-detecting.
3442 dnl
3444 SAVED_CFLAGS="${CFLAGS}" SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3445 AC_MSG_CHECKING([for --fatal-warnings linker flag])
3446 CFLAGS="${SAVED_CFLAGS} ${shared_flag:- -shared}"
3447 LDFLAGS=-Wl,--fatal-warnings
3448 LIBS=
3449 AC_TRY_LINK([], [return 0],
3450 AC_MSG_RESULT(yes)
3451 [ldflags_fatal=-Wl,--fatal-warnings],
3452 AC_MSG_RESULT(no)
3453 ldflags_fatal=)
3455 AC_MSG_CHECKING([for -z,nodelete linker flag])
3456 LDFLAGS="$ldflags_fatal -Wl,-z,nodelete"
3457 AC_TRY_LINK([], [return 0],
3458 AC_MSG_RESULT(yes)
3459 enable_znodelete=yes,
3460 AC_MSG_RESULT(no)
3461 enable_znodelete=no)
3462 CFLAGS="${SAVED_CFLAGS}" LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"
3464 if test "x${enable_znodelete}" = "xyes"; then
3465 GLIB_LINK_FLAGS="$GLIB_LINK_FLAGS -Wl,-z,nodelete"
3466 fi
3468 AC_SUBST(GLIB_LINK_FLAGS)
3470 dnl
3471 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3472 dnl visibility attributes for symbol export control
3473 dnl
3474 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3475 case "$host" in
3476 *-*-mingw*)
3477 dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3478 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3479 [defines how to decorate public symbols while building])
3480 CFLAGS="${CFLAGS} -fvisibility=hidden"
3481 ;;
3482 *)
3483 dnl on other compilers, check if we can do -fvisibility=hidden
3484 SAVED_CFLAGS="${CFLAGS}"
3485 CFLAGS="-fvisibility=hidden"
3486 AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3487 AC_TRY_COMPILE([], [return 0],
3488 AC_MSG_RESULT(yes)
3489 enable_fvisibility_hidden=yes,
3490 AC_MSG_RESULT(no)
3491 enable_fvisibility_hidden=no)
3492 CFLAGS="${SAVED_CFLAGS}"
3494 AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3495 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3496 [defines how to decorate public symbols while building])
3497 GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3498 ])
3499 ;;
3500 esac
3501 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3503 dnl Compiler flags; macro originates from systemd
3504 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3505 AC_ARG_ENABLE(compile-warnings,
3506 [AS_HELP_STRING([--disable-compile-warnings],
3507 [Don't use builtin compiler warnings])],,
3508 enable_compile_warnings=yes)
3509 AS_IF([test "x$enable_compile_warnings" != xno], [
3510 CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3511 -Wall -Wstrict-prototypes -Wduplicated-branches -Wmisleading-indentation \
3512 -Werror=declaration-after-statement \
3513 -Werror=missing-prototypes -Werror=implicit-function-declaration \
3514 -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3515 -Werror=format=2 -Werror=missing-include-dirs])
3516 ])
3517 AC_SUBST(GLIB_WARN_CFLAGS)
3519 #
3520 # Define variables corresponding to the correct include paths to use for
3521 # in-tree building.
3522 #
3524 # for config.h:
3525 config_h_INCLUDES='-I$(top_builddir)'
3526 AC_SUBST(config_h_INCLUDES)
3528 # glib:
3529 # config.h
3530 # $(top_builddir)/glib: for glibconfig.h
3531 # $(top_srcdir)/glib: for glib.h
3532 # $(top_srcdir): for everything
3533 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3534 AC_SUBST(glib_INCLUDES)
3536 # gobject:
3537 # same as glib
3538 gobject_INCLUDES='$(glib_INCLUDES)'
3539 AC_SUBST(gobject_INCLUDES)
3541 # gmodule:
3542 # glib includes
3543 # $(top_srcdir)/gmodule: for gmodule.h
3544 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3545 AC_SUBST(gmodule_INCLUDES)
3547 # gio:
3548 # same as gmodule
3549 gio_INCLUDES='$(gmodule_INCLUDES)'
3550 AC_SUBST(gio_INCLUDES)
3553 AC_CONFIG_FILES([
3554 glib-2.0.pc
3555 gmodule-2.0.pc
3556 gmodule-export-2.0.pc
3557 gmodule-no-export-2.0.pc
3558 gthread-2.0.pc
3559 gobject-2.0.pc
3560 gio-2.0.pc
3561 gio-unix-2.0.pc
3562 gio-windows-2.0.pc
3563 glib-zip
3564 glib-gettextize
3565 Makefile
3566 build/Makefile
3567 build/win32/Makefile
3568 build/win32/dirent/Makefile
3569 win32/Makefile
3570 win32/vs9/Makefile
3571 win32/vs9/glib-version-paths.vsprops
3572 win32/vs10/Makefile
3573 win32/vs10/glib-version-paths.props
3574 win32/vs11/Makefile
3575 win32/vs12/Makefile
3576 win32/vs14/Makefile
3577 win32/vs15/Makefile
3578 glib/Makefile
3579 glib/libcharset/Makefile
3580 glib/gnulib/Makefile
3581 glib/pcre/Makefile
3582 glib/update-pcre/Makefile
3583 glib/tests/Makefile
3584 gmodule/Makefile
3585 gmodule/gmoduleconf.h
3586 gobject/Makefile
3587 gobject/glib-genmarshal
3588 gobject/glib-mkenums
3589 gobject/tests/Makefile
3590 gthread/Makefile
3591 gio/Makefile
3592 gio/gdbus-2.0/codegen/Makefile
3593 gio/gdbus-2.0/codegen/config.py
3594 gio/gnetworking.h
3595 gio/xdgmime/Makefile
3596 gio/inotify/Makefile
3597 gio/kqueue/Makefile
3598 gio/fam/Makefile
3599 gio/win32/Makefile
3600 gio/tests/Makefile
3601 gio/tests/gdbus-object-manager-example/Makefile
3602 gio/tests/services/Makefile
3603 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3604 gio/tests/modules/Makefile
3605 po/Makefile.in
3606 docs/Makefile
3607 docs/reference/Makefile
3608 docs/reference/glib/Makefile
3609 docs/reference/glib/version.xml
3610 docs/reference/gobject/Makefile
3611 docs/reference/gobject/version.xml
3612 docs/reference/gio/Makefile
3613 docs/reference/gio/version.xml
3614 tests/Makefile
3615 tests/gobject/Makefile
3616 tests/refcount/Makefile
3617 m4macros/Makefile
3618 subprojects/Makefile
3619 ])
3621 # We need this command because the configure script will not preserve
3622 # the same attributes of the template files
3623 AC_CONFIG_COMMANDS([chmod-scripts],
3624 [chmod 0755 glib-zip
3625 chmod 0755 glib-gettextize
3626 chmod 0755 gobject/glib-genmarshal
3627 chmod 0755 gobject/glib-mkenums])
3629 # we want to invoke this macro solely so that the config.status script
3630 # and automake generated makefiles know about these generated files.
3631 # They are only needed to distcheck the package
3632 if false; then
3633 AC_CONFIG_FILES([
3634 INSTALL
3635 README
3636 config.h.win32
3637 glib/glibconfig.h.win32
3638 glib/glib.rc
3639 gmodule/gmodule.rc
3640 gobject/gobject.rc
3641 gthread/gthread.rc
3642 gio/gio.rc
3643 ])
3644 fi
3646 AC_OUTPUT