| blob | cb13036a282f0e2d3060fde0f0aafe9d4a7530ff |
1 # Process this file with autoconf to produce a configure script.
2 AC_PREREQ([2.62])
4 dnl ***********************************
5 dnl *** include special GLib macros ***
6 dnl ***********************************
8 m4_define(glib_configure_ac)
10 #
11 # The following version number definitions apply to GLib, GModule, GObject,
12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
13 # all treated with the same interface and binary age.
14 #
15 # Making releases:
16 # glib_micro_version += 1;
17 # glib_interface_age += 1;
18 # glib_binary_age += 1;
19 # if any functions have been added, set glib_interface_age to 0.
20 # if backwards compatibility has been broken,
21 # set glib_binary_age _and_ glib_interface_age to 0.
22 #
23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
25 # for that version - see gversion.h for further information.
26 #
27 # in easier to understand terms:
28 #
29 # <mclasen> on the stable branch, interface age == micro
30 # <mclasen> on the unstable (ie master), interface age = 0
32 m4_define([glib_major_version], [2])
33 m4_define([glib_minor_version], [55])
34 m4_define([glib_micro_version], [0])
35 m4_define([glib_interface_age], [0])
36 m4_define([glib_binary_age],
37 [m4_eval(100 * glib_minor_version + glib_micro_version)])
38 m4_define([glib_version],
39 [glib_major_version.glib_minor_version.glib_micro_version])
41 # libtool version related macros
42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
43 m4_define([glib_lt_current],
44 [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
45 m4_define([glib_lt_revision], [glib_interface_age])
46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
47 m4_define([glib_lt_current_minus_age],
48 [m4_eval(glib_lt_current - glib_lt_age)])
50 # if the minor version number is odd, then we want debugging. Otherwise
51 # we only want minimal debugging support.
52 m4_define([glib_debug_default],
53 [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
56 AC_INIT(glib, [glib_version],
57 [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
59 AC_CONFIG_HEADERS([config.h])
60 AC_CONFIG_SRCDIR([glib/glib.h])
61 AC_CONFIG_MACRO_DIR([m4macros])
63 # Save this value here, since automake will set cflags later
64 cflags_set=${CFLAGS:+set}
66 AM_INIT_AUTOMAKE([1.13.3 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar subdir-objects])
67 AM_MAINTAINER_MODE([enable])
69 # Support silent build rules. Disable
70 # by either passing --disable-silent-rules to configure or passing V=1
71 # to make
72 AM_SILENT_RULES([yes])
74 GLIB_MAJOR_VERSION=glib_major_version
75 GLIB_MINOR_VERSION=glib_minor_version
76 GLIB_MICRO_VERSION=glib_micro_version
77 GLIB_INTERFACE_AGE=glib_interface_age
78 GLIB_BINARY_AGE=glib_binary_age
79 GLIB_VERSION=glib_version
81 AC_SUBST(GLIB_MAJOR_VERSION)
82 AC_SUBST(GLIB_MINOR_VERSION)
83 AC_SUBST(GLIB_MICRO_VERSION)
84 AC_SUBST(GLIB_VERSION)
85 AC_SUBST(GLIB_INTERFACE_AGE)
86 AC_SUBST(GLIB_BINARY_AGE)
88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
89 [Define to the GLIB major version])
90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
91 [Define to the GLIB minor version])
92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
93 [Define to the GLIB micro version])
94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
95 [Define to the GLIB interface age])
96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
97 [Define to the GLIB binary age])
99 # libtool versioning
100 LT_RELEASE=glib_lt_release
101 LT_CURRENT=glib_lt_current
102 LT_REVISION=glib_lt_revision
103 LT_AGE=glib_lt_age
104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
105 AC_SUBST(LT_RELEASE)
106 AC_SUBST(LT_CURRENT)
107 AC_SUBST(LT_REVISION)
108 AC_SUBST(LT_AGE)
109 AC_SUBST(LT_CURRENT_MINUS_AGE)
111 dnl Checks for programs.
112 AC_PROG_CC
113 AC_PROG_CPP
114 AC_USE_SYSTEM_EXTENSIONS
116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
118 AC_CANONICAL_HOST
120 dnl
122 AC_MSG_CHECKING([for Win32])
123 LIB_EXE_MACHINE_FLAG=X86
124 case "$host" in
125 *-*-mingw*)
126 glib_native_win32=yes
127 glib_pid_type='void *'
128 glib_pid_format='p'
129 glib_pollfd_format='%#x'
130 glib_cv_stack_grows=no
131 # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
132 # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
133 # (Sorry, I don't know exactly what is the problem, but it is related to
134 # floating point formatting and decimal point vs. comma.)
135 # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
136 # rigorous enough to notice, though.
137 # So preset the autoconf cache variables.
138 ac_cv_func_vsnprintf_c99=no
139 ac_cv_func_snprintf_c99=no
140 case "$host" in
141 x86_64-*-*)
142 LIB_EXE_MACHINE_FLAG=X64
143 glib_pollfd_format='%#I64x'
144 ;;
145 esac
147 AC_DEFINE([_WIN32_WINNT], [0x0601], [Target the Windows 7 API])
148 ;;
149 *)
150 glib_native_win32=no
151 glib_pid_type=int
152 glib_pid_format='i'
153 glib_pollfd_format='%d'
154 ;;
155 esac
156 case $host in
157 *-*-linux*)
158 glib_os_linux=yes
159 ;;
160 esac
162 AC_MSG_RESULT([$glib_native_win32])
164 AC_MSG_CHECKING([for the Android])
165 case $host in
166 *android*)
167 glib_native_android="yes"
168 ;;
169 *)
170 glib_native_android="no"
171 ;;
172 esac
173 AC_MSG_RESULT([$glib_native_android])
175 AC_SUBST(LIB_EXE_MACHINE_FLAG)
177 glib_have_carbon=no
178 AC_MSG_CHECKING([for Mac OS X Carbon support])
179 AC_TRY_CPP([
180 #include <Carbon/Carbon.h>
181 #include <CoreServices/CoreServices.h>
182 ], glib_have_carbon=yes)
184 AC_MSG_RESULT([$glib_have_carbon])
186 glib_have_cocoa=no
187 AC_MSG_CHECKING([for Mac OS X Cocoa support])
188 AC_TRY_CPP([
189 #include <Cocoa/Cocoa.h>
190 #ifdef GNUSTEP_BASE_VERSION
191 #error "Detected GNUstep, not Cocoa"
192 #endif
193 ], glib_have_cocoa=yes)
195 AC_MSG_RESULT([$glib_have_cocoa])
197 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
198 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
199 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
200 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
201 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
202 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
204 AS_IF([test "$glib_native_win32" = "yes"], [
205 AC_CHECK_TOOL(WINDRES, windres, no)
206 if test "$WINDRES" = no; then
207 AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
208 fi
209 AC_CHECK_TOOL(NM, nm, no)
210 if test "$NM" = no; then
211 AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
212 fi
213 AC_CHECK_TOOL(RANLIB, ranlib, :)
214 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
215 AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
216 ])
217 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
219 AS_IF([test "x$glib_have_carbon" = "xyes"], [
220 AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
221 CARBON_LIBS="-Wl,-framework,Carbon"
222 LDFLAGS="$LDFLAGS $CARBON_LIBS"
223 ], [CARBON_LIBS=""])
225 AC_SUBST([CARBON_LIBS])
226 ac_cv_have_os_x_9_or_later="no"
227 AS_IF([test "x$glib_have_cocoa" = "xyes"], [
228 AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
229 COCOA_LIBS="-Wl,-framework,Foundation"
230 LDFLAGS="$LDFLAGS $COCOA_LIBS"
231 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
232 #include <AvailabilityMacros.h>
233 #if MAC_OS_X_VERSION_MIN_REQUIRED < 1090
234 #error Compiling for minimum OS X version before 10.9
235 #endif
236 ]])],[ac_cv_have_os_x_9_or_later="yes"])
237 ], [COCOA_LIBS=""])
238 AM_CONDITIONAL([MAC_OS_X_9], [test "x$ac_cv_have_os_x_9_or_later" = xyes])
239 AC_SUBST([COCOA_LIBS])
241 dnl declare --enable-* args and collect ac_help strings
242 AC_ARG_ENABLE(debug,
243 AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
244 [turn on debugging @<:@default=glib_debug_default@:>@]),,
245 enable_debug=glib_debug_default)
247 AC_ARG_ENABLE(gc_friendly,
248 [AS_HELP_STRING([--enable-gc-friendly],
249 [turn on garbage collector friendliness [default=no]])],,
250 [enable_gc_friendly=no])
251 AC_ARG_ENABLE(mem_pools,
252 [AS_HELP_STRING([--disable-mem-pools],
253 [disable all glib memory pools])],,
254 [disable_mem_pools=no])
255 AC_ARG_ENABLE(rebuilds,
256 [AS_HELP_STRING([--disable-rebuilds],
257 [disable all source autogeneration rules])],,
258 [enable_rebuilds=yes])
260 GLIB_TESTS
262 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
263 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
264 AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
265 AC_MSG_RESULT([yes])
266 ], [ AC_MSG_RESULT([no]) ])
268 AC_MSG_CHECKING([whether to disable memory pools])
269 AS_IF([test "x$disable_mem_pools" = "xno"], [
270 AC_MSG_RESULT([no])
271 ], [
272 AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
273 AC_MSG_RESULT([yes])
274 ])
276 dnl location to install runtime libraries, e.g. ../../lib to install
277 dnl to /lib if libdir is /usr/lib
278 AC_ARG_WITH(runtime-libdir,
279 [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
280 [install runtime libraries relative to libdir])],
281 [],
282 [with_runtime_libdir=""])
283 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
284 AC_SUBST(GLIB_RUNTIME_LIBDIR)
285 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
287 dnl Check for a working C++ compiler, but do not bail out, if none is found.
288 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
289 AC_LANG_SAVE
290 AC_LANG_CPLUSPLUS
291 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
292 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
293 AC_LANG_RESTORE
295 AM_PROG_CC_C_O
296 AC_PROG_INSTALL
298 AC_SYS_LARGEFILE
300 PKG_PROG_PKG_CONFIG(0.16)
302 if test "x$enable_debug" = "xyes"; then
303 if test "x$cflags_set" != "x" ; then
304 case " $CFLAGS " in
305 *[[\ \ ]]-g[[\ \ ]]*) ;;
306 *) CFLAGS="$CFLAGS -g" ;;
307 esac
308 fi
309 GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
310 else
311 GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
313 if test "x$enable_debug" = "xno"; then
314 GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
315 fi
316 fi
318 # Ensure MSVC-compatible struct packing convention is used when
319 # compiling for Win32 with gcc.
320 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
321 # gcc2 uses "-fnative-struct".
322 if test x"$glib_native_win32" = xyes; then
323 if test x"$GCC" = xyes; then
324 msnative_struct=''
325 AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
326 if test -z "$ac_cv_prog_CC"; then
327 our_gcc="$CC"
328 else
329 our_gcc="$ac_cv_prog_CC"
330 fi
331 case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
332 2.)
333 if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
334 msnative_struct='-fnative-struct'
335 fi
336 ;;
337 *)
338 if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
339 msnative_struct='-mms-bitfields'
340 fi
341 ;;
342 esac
343 if test x"$msnative_struct" = x ; then
344 AC_MSG_RESULT([no way])
345 AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
346 else
347 CFLAGS="$CFLAGS $msnative_struct"
348 AC_MSG_RESULT([${msnative_struct}])
349 fi
350 fi
351 fi
352 GLIB_EXTRA_CFLAGS="${msnative_struct}"
353 AC_SUBST(GLIB_EXTRA_CFLAGS)
355 AC_EXEEXT
357 # define a MAINT-like variable REBUILD which is set if Perl
358 # and awk are found, so autogenerated sources can be rebuilt
359 AC_PROG_AWK
360 AC_CHECK_PROGS(PERL, [perl5 perl])
361 # We would like indent, but don't require it.
362 AC_CHECK_PROG(INDENT, indent, indent)
363 REBUILD=\#
364 if test "x$enable_rebuilds" = "xyes" && \
365 test -n "$PERL" && \
366 $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
367 test -n "$AWK" ; then
368 REBUILD=
369 fi
370 AC_SUBST(REBUILD)
372 # option to specify python interpreter to use; this just sets $PYTHON, so that
373 # we will fallback to reading $PYTHON if --with-python is not given, and
374 # python.m4 will get the expected input
375 AC_ARG_WITH(python,
376 AS_HELP_STRING([--with-python=PATH],
377 [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
378 [PYTHON="$withval"], [])
379 if test x"$PYTHON" = xyes; then
380 AC_MSG_ERROR([--with-python option requires a path or program argument])
381 fi
382 AM_PATH_PYTHON(2.7,,PYTHON="python2.7")
385 dnl ***********************
386 dnl *** Tests for iconv ***
387 dnl ***********************
388 dnl
389 dnl We do this before the gettext checks, to avoid distortion
391 dnl On Windows we use a native implementation
393 AS_IF([ test x"$glib_native_win32" = xyes], [
394 with_libiconv=native
395 ], [
396 AC_ARG_WITH(libiconv,
397 [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
398 [use the libiconv library])],,
399 [with_libiconv=maybe])
401 found_iconv=no
402 case $with_libiconv in
403 maybe)
404 # Check in the C library first
405 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
406 # Check if we have GNU libiconv
407 if test $found_iconv = "no"; then
408 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
409 fi
410 # Check if we have a iconv in -liconv, possibly from vendor
411 if test $found_iconv = "no"; then
412 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
413 fi
414 ;;
415 no)
416 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
417 ;;
418 gnu|yes)
419 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
420 ;;
421 native)
422 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
423 ;;
424 esac
426 if test "x$found_iconv" = "xno" ; then
427 AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
428 fi
429 ])
431 dnl
432 dnl zlib support
433 dnl
434 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
435 AS_IF([test "x$found_zlib" = "xno"], [
436 AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
437 if test "x$found_zlib" = "xno" ; then
438 AC_MSG_ERROR([*** Working zlib library and headers not found ***])
439 fi
440 ZLIB_LIBS='-lz'
441 AC_SUBST(ZLIB_LIBS)
442 ])
444 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
445 AC_SUBST(LIBFFI_CFLAGS)
446 AC_SUBST(LIBFFI_LIBS)
448 dnl
449 dnl gettext support
450 dnl
452 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
453 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
454 GLIB_GNU_GETTEXT
456 if test "$gt_cv_have_gettext" != "yes" ; then
457 AC_MSG_ERROR([
458 *** You must have either have gettext support in your C library, or use the
459 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html)
460 ])
461 fi
463 LIBS="$INTLLIBS $LIBS"
465 GETTEXT_PACKAGE=glib20
466 AC_SUBST(GETTEXT_PACKAGE)
467 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
468 [Define the gettext package to be used])
470 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
472 dnl
473 dnl Now we are done with gettext checks, figure out ICONV_LIBS
474 dnl
476 AS_IF([test x"$glib_native_win32" != xyes], [
477 if test x$with_libiconv != xno ; then
478 case " $INTLLIBS " in
479 *[[\ \ ]]-liconv[[\ \ ]]*) ;;
480 *) ICONV_LIBS="-liconv" ;;
481 esac
482 fi
483 ])
484 AC_SUBST(ICONV_LIBS)
486 case $with_libiconv in
487 gnu)
488 AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
489 ;;
490 native)
491 AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
492 ;;
493 esac
495 dnl Initialize libtool
496 LT_PREREQ([2.2])
497 LT_INIT([disable-static win32-dll])
498 dnl when using libtool 2.x create libtool early, because it's used in configure
499 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
502 AS_IF([test "$glib_native_win32" = "yes"], [
503 if test x$enable_static = xyes -a x$enable_shared = xyes; then
504 AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
505 fi
506 if test x$enable_static = xyes; then
507 glib_win32_static_compilation=yes
508 GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
509 #define GOBJECT_STATIC_COMPILATION 1"
510 AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
511 fi
512 ])
513 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
515 # Checks for library functions.
516 AC_FUNC_ALLOCA
517 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
518 AC_CHECK_FUNCS(timegm gmtime_r)
519 AC_FUNC_STRERROR_R()
521 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
522 [AC_TRY_LINK([#include <unistd.h>
523 extern int __libc_enable_secure;],
524 [return __libc_enable_secure;],
525 glib_cv_have_libc_enable_secure=yes,
526 glib_cv_have_libc_enable_secure=no)])
527 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
528 AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
529 [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
530 ])
532 AC_CHECK_SIZEOF(char)
533 AC_CHECK_SIZEOF(short)
534 AC_CHECK_SIZEOF(long)
535 AC_CHECK_SIZEOF(int)
536 AC_CHECK_SIZEOF(void *)
537 AC_CHECK_SIZEOF(long long)
538 AC_CHECK_SIZEOF(__int64)
540 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
541 [AC_TRY_LINK([#include <signal.h>
542 #include <sys/types.h>
543 sig_atomic_t val = 42;],
544 [return val == 42 ? 0 : 1],
545 ac_cv_type_sig_atomic_t=yes,
546 ac_cv_type_sig_atomic_t=no)])
547 if test x$ac_cv_type_sig_atomic_t = xyes; then
548 AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
549 [Define if you have the 'sig_atomic_t' type.])
550 fi
552 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
553 :
554 else
555 AC_MSG_ERROR([
556 *** GLib requires a 64 bit type. You might want to consider
557 *** using the GNU C compiler.
558 ])
559 fi
561 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
562 # long long is a 64 bit integer.
563 AC_MSG_CHECKING(for format to printf and scanf a guint64)
564 AC_CACHE_VAL(glib_cv_long_long_format,[
565 for format in ll q I64; do
566 AC_TRY_RUN([#include <stdio.h>
567 int main()
568 {
569 long long b, a = -0x3AFAFAFAFAFAFAFALL;
570 char buffer[1000];
571 sprintf (buffer, "%${format}u", a);
572 sscanf (buffer, "%${format}u", &b);
573 exit (b!=a);
574 }
575 ],
576 [glib_cv_long_long_format=${format}
577 break],
578 [],[:])
579 done])
580 AS_IF([ test -n "$glib_cv_long_long_format"], [
581 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
582 AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
583 if test x"$glib_cv_long_long_format" = xI64; then
584 AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
585 fi
586 ], [AC_MSG_RESULT(none)])
587 ],[ test x$ac_cv_sizeof___int64 = x8], [
588 # __int64 is a 64 bit integer.
589 AC_MSG_CHECKING(for format to printf and scanf a guint64)
590 # We know this is MSVCRT.DLL, and what the formats are
591 glib_cv_long_long_format=I64
592 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
593 AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
594 AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
595 ])
597 AC_C_CONST
599 dnl
600 dnl check in which direction the stack grows
601 dnl
602 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
603 AC_TRY_RUN([
604 volatile int *a = 0, *b = 0;
605 void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
606 int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
607 ],
608 glib_cv_stack_grows=yes
609 ,
610 glib_cv_stack_grows=no
611 ,)
612 ])
614 # check for flavours of varargs macros
615 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
616 AC_TRY_COMPILE([],[
617 int a(int p1, int p2, int p3);
618 #define call_a(...) a(1,__VA_ARGS__)
619 call_a(2,3);
620 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
621 AC_MSG_RESULT($g_have_iso_c_varargs)
623 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
624 AS_IF([test "$CXX" = ""], [
625 dnl No C++ compiler
626 g_have_iso_cxx_varargs=no
627 else
628 AC_LANG_CPLUSPLUS
629 AC_TRY_COMPILE([],[
630 int a(int p1, int p2, int p3);
631 #define call_a(...) a(1,__VA_ARGS__)
632 call_a(2,3);
633 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
634 AC_LANG_C
635 ])
636 AC_MSG_RESULT($g_have_iso_cxx_varargs)
638 AC_MSG_CHECKING(for GNUC varargs macros)
639 AC_TRY_COMPILE([],[
640 int a(int p1, int p2, int p3);
641 #define call_a(params...) a(1,params)
642 call_a(2,3);
643 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
644 AC_MSG_RESULT($g_have_gnuc_varargs)
646 # check for GNUC visibility support
647 AC_MSG_CHECKING(for GNUC visibility attribute)
648 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
649 void
650 __attribute__ ((visibility ("hidden")))
651 f_hidden (void)
652 {
653 }
654 void
655 __attribute__ ((visibility ("internal")))
656 f_internal (void)
657 {
658 }
659 void
660 __attribute__ ((visibility ("protected")))
661 f_protected (void)
662 {
663 }
664 void
665 __attribute__ ((visibility ("default")))
666 f_default (void)
667 {
668 }
669 int main (void)
670 {
671 f_hidden();
672 f_internal();
673 f_protected();
674 f_default();
675 return 0;
676 }
677 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
678 AC_MSG_RESULT($g_have_gnuc_visibility)
679 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
681 AC_MSG_CHECKING([whether using Sun Studio C compiler])
682 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
683 #else
684 # include "error: this is not Sun Studio."
685 #endif
686 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
687 AC_MSG_RESULT($g_have_sunstudio_visibility)
688 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
690 # check for bytesex stuff
691 AC_C_BIGENDIAN
692 if test x$ac_cv_c_bigendian = xuniversal ; then
693 AC_MSG_ERROR([Universal builds not supported: see https://bugs.gnome.org/742548])
694 fi
697 # check for header files
698 AC_CHECK_HEADERS([sys/param.h sys/resource.h mach/mach_time.h])
699 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
700 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
701 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
702 AC_CHECK_HEADERS([linux/magic.h])
703 AC_CHECK_HEADERS([termios.h])
705 # Some versions of MSC lack these
706 AC_CHECK_HEADERS([dirent.h sys/time.h])
708 # We don't care about this, but we need to keep including it in
709 # glibconfig.h for backward compatibility
710 AC_CHECK_HEADERS([values.h])
712 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
713 [#if HAVE_SYS_PARAM_H
714 #include <sys/param.h>
715 #endif
716 ])
717 AC_CHECK_FUNCS(sysctlbyname)
719 AC_HEADER_MAJOR
720 AC_CHECK_HEADERS([xlocale.h])
722 # check for structure fields
723 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec, struct stat.st_birthtime, struct stat.st_birthtimensec, struct stat.st_birthtim, struct stat.st_birthtim.tv_nsec])
724 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
725 #include <sys/stat.h>
726 #ifdef G_OS_UNIX
727 #include <unistd.h>
728 #endif
729 #ifdef HAVE_SYS_STATFS_H
730 #include <sys/statfs.h>
731 #endif
732 #ifdef HAVE_SYS_PARAM_H
733 #include <sys/param.h>
734 #endif
735 #ifdef HAVE_SYS_MOUNT_H
736 #include <sys/mount.h>
737 #endif])
738 # struct statvfs.f_basetype is available on Solaris but not for Linux.
739 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
740 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
741 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
743 AC_STRUCT_DIRENT_D_TYPE
745 # Checks for libcharset
746 AM_LANGINFO_CODESET
747 gl_GLIBC21
749 # check additional type sizes
750 AC_CHECK_SIZEOF(size_t)
752 dnl Try to figure out whether gsize should be long or int
753 AC_MSG_CHECKING([for the appropriate definition for size_t])
755 case $ac_cv_sizeof_size_t in
756 $ac_cv_sizeof_short)
757 glib_size_type=short
758 ;;
759 $ac_cv_sizeof_int)
760 glib_size_type=int
761 ;;
762 $ac_cv_sizeof_long)
763 glib_size_type=long
764 ;;
765 $ac_cv_sizeof_long_long)
766 glib_size_type='long long'
767 ;;
768 $ac_cv_sizeof__int64)
769 glib_size_type='__int64'
770 ;;
771 *) AC_MSG_ERROR([No type matching size_t in size])
772 ;;
773 esac
775 dnl If int/long are the same size, we see which one produces
776 dnl warnings when used in the location as size_t. (This matters
777 dnl on AIX with xlc)
778 dnl
779 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
780 test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
781 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
782 #if defined(_AIX) && !defined(__GNUC__)
783 #pragma options langlvl=stdc89
784 #endif
785 #include <stddef.h>
786 int main ()
787 {
788 size_t s = 1;
789 unsigned int *size_int = &s;
790 return (int)*size_int;
791 }
792 ]])],glib_size_type=int,
793 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
794 #if defined(_AIX) && !defined(__GNUC__)
795 #pragma options langlvl=stdc89
796 #endif
797 #include <stddef.h>
798 int main ()
799 {
800 size_t s = 1;
801 unsigned long *size_long = &s;
802 return (int)*size_long;
803 }
804 ]])],glib_size_type=long)])
805 ])
807 AC_MSG_RESULT(unsigned $glib_size_type)
809 AC_CHECK_SIZEOF(ssize_t)
811 dnl Try to figure out whether gssize should be long or int
812 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
814 case $ac_cv_sizeof_ssize_t in
815 $ac_cv_sizeof_short)
816 glib_ssize_type=short
817 ;;
818 $ac_cv_sizeof_int)
819 glib_ssize_type=int
820 ;;
821 $ac_cv_sizeof_long)
822 glib_ssize_type=long
823 ;;
824 $ac_cv_sizeof_long_long)
825 glib_ssize_type='long long'
826 ;;
827 $ac_cv_sizeof__int64)
828 glib_ssize_type='__int64'
829 ;;
830 *) AC_MSG_ERROR([No type matching ssize_t in size])
831 ;;
832 esac
834 dnl If int/long are the same size, we see which one produces
835 dnl warnings when used in the location as ssize_t. (This matters
836 dnl on Android where ssize_t is long and size_t is unsigned int)
837 dnl
838 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
839 test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
840 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
841 #if defined(_AIX) && !defined(__GNUC__)
842 #pragma options langlvl=stdc89
843 #endif
844 #include <stddef.h>
845 #ifdef HAVE_INTTYPES_H
846 # include <inttypes.h>
847 #endif
848 #ifdef HAVE_STDINT_H
849 # include <stdint.h>
850 #endif
851 #include <sys/types.h>
852 int main ()
853 {
854 ssize_t s = 1;
855 int *size_int = &s;
856 return (int)*size_int;
857 }
858 ]])],glib_ssize_type=int,
859 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
860 #if defined(_AIX) && !defined(__GNUC__)
861 #pragma options langlvl=stdc89
862 #endif
863 #include <stddef.h>
864 #ifdef HAVE_INTTYPES_H
865 # include <inttypes.h>
866 #endif
867 #ifdef HAVE_STDINT_H
868 # include <stdint.h>
869 #endif
870 #include <sys/types.h>
871 int main ()
872 {
873 ssize_t s = 1;
874 long *size_long = &s;
875 return (int)*size_long;
876 }
877 ]])],glib_ssize_type=long)])
878 ])
880 AC_MSG_RESULT($glib_ssize_type)
882 # Check for some functions
883 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk mkostemp)
884 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
885 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
886 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
887 AC_CHECK_FUNCS(splice)
888 AC_CHECK_FUNCS(prlimit)
890 # To avoid finding a compatibility unusable statfs, which typically
891 # successfully compiles, but warns to use the newer statvfs interface:
892 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
893 AS_IF([test $ac_cv_header_sys_statfs_h = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
895 AC_MSG_CHECKING([whether to use statfs or statvfs])
896 # Some systems have both statfs and statvfs, pick the most "native" for these
897 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
898 [
899 # on solaris and irix, statfs doesn't even have the f_bavail field
900 AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
901 [ac_cv_func_statfs=no],
902 # else, at least on linux, statfs is the actual syscall
903 [ac_cv_func_statvfs=no])
904 ])
906 AS_IF([test x$ac_cv_func_statfs = xyes],
907 [
908 AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
909 AC_MSG_RESULT([statfs])
910 ],
911 [test x$ac_cv_func_statvfs = xyes],
912 [
913 AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
914 AC_MSG_RESULT([statvfs])
915 ],
916 [ AC_MSG_RESULT([neither])])
918 AC_CHECK_HEADERS(crt_externs.h)
919 AC_CHECK_FUNCS(_NSGetEnviron)
921 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
923 # Internet address families
924 if test $glib_native_win32 = yes; then
925 glib_inet_includes=["
926 #include <winsock2.h>
927 "]
928 else
929 glib_inet_includes=["
930 #include <sys/types.h>
931 #include <sys/socket.h>
932 "]
933 fi
935 glib_failed=false
936 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
937 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
938 # winsock defines this even though it doesn't support it
939 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
940 if $glib_failed ; then
941 AC_MSG_ERROR([Could not determine values for AF_INET* constants])
942 fi
944 glib_failed=false
945 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
946 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
947 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
948 if $glib_failed ; then
949 AC_MSG_ERROR([Could not determine values for MSG_* constants])
950 fi
952 AC_CHECK_FUNCS(endservent if_nametoindex if_indextoname sendmmsg recvmmsg)
954 AC_MSG_CHECKING([for SIOCGIFADDR])
955 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
956 [[
957 #include <sys/ioctl.h>
958 #include <net/if.h>
959 ]],
960 [[
961 struct ifreq ifr;
962 ioctl(0, SIOCGIFADDR, &ifr);
963 ]])], [
964 AC_MSG_RESULT(yes)
965 AC_DEFINE(HAVE_SIOCGIFADDR, 1, [SIOCGIFADDR is available])
966 ], [
967 AC_MSG_RESULT(no)
968 ])
970 AS_IF([test $glib_native_win32 = yes], [
971 # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
972 # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
973 # they aren't present at run-time (on Windows 2000).
974 AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
975 AC_SUBST(WSPIAPI_INCLUDE)
976 ], [
977 # Android does not have C_IN in public headers, we define it wherever necessary
978 AS_IF([test $glib_native_android != yes], [
979 AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
980 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
981 #include <arpa/nameser.h>],
982 [int qclass = C_IN;])],
983 [AC_MSG_RESULT([no])],
984 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
985 #include <arpa/nameser.h>
986 #include <arpa/nameser_compat.h>],
987 [int qclass = C_IN;])],
988 [AC_MSG_RESULT([yes])
989 NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
990 [AC_MSG_ERROR([could not compile test program either way])])])])
991 AC_SUBST(NAMESER_COMPAT_INCLUDE)
993 # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
994 NETWORK_LIBS=""
995 AC_MSG_CHECKING([for res_query])
996 AC_TRY_LINK([#include <sys/types.h>
997 #include <netinet/in.h>
998 #include <arpa/nameser.h>
999 #include <resolv.h>
1000 ],[
1001 res_query("test", 0, 0, (void *)0, 0);
1002 ],[AC_MSG_RESULT([yes])],
1003 [save_libs="$LIBS"
1004 LIBS="-lresolv $LIBS"
1005 AC_TRY_LINK([#include <sys/types.h>
1006 #include <netinet/in.h>
1007 #include <arpa/nameser.h>
1008 #include <resolv.h>
1009 ],[
1010 res_query("test", 0, 0, (void *)0, 0);
1011 ],[AC_MSG_RESULT([in -lresolv])
1012 NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1013 [LIBS="-lbind $save_libs"
1014 AC_TRY_LINK([#include <resolv.h>],
1015 [res_query("test", 0, 0, (void *)0, 0);],
1016 [AC_MSG_RESULT([in -lbind])
1017 NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1018 [AC_MSG_ERROR(not found)])])
1019 LIBS="$save_libs"])
1020 AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1021 [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1022 [AC_MSG_ERROR(Could not find socket())]))
1023 save_libs="$LIBS"
1024 LIBS="$LIBS $NETWORK_LIBS"
1025 AC_MSG_CHECKING([for res_init])
1026 AC_TRY_LINK([#include <sys/types.h>
1027 #include <netinet/in.h>
1028 #include <arpa/nameser.h>
1029 #include <resolv.h>
1030 ],[
1031 res_init();
1032 ],[AC_MSG_RESULT([yes])
1033 AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1034 ],[AC_MSG_RESULT([no])])
1035 LIBS="$save_libs"
1036 ])
1037 AC_SUBST(NETWORK_LIBS)
1039 AC_CHECK_HEADER([linux/netlink.h],
1040 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1041 [#include <sys/socket.h>])
1042 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1044 AC_CHECK_TYPE([struct ip_mreqn], [
1045 AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1046 [#include <netinet/in.h>])
1048 case $host in
1049 *-*-solaris* )
1050 AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1051 AC_DEFINE(_XOPEN_SOURCE, 2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1052 AC_DEFINE(__EXTENSIONS__, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1053 ;;
1054 esac
1056 dnl
1057 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1058 dnl
1059 AS_IF([test "$ac_cv_func_statfs" = yes], [
1060 AC_MSG_CHECKING([number of arguments to statfs()])
1061 AC_TRY_COMPILE([#include <unistd.h>
1062 #ifdef HAVE_SYS_PARAM_H
1063 #include <sys/param.h>
1064 #endif
1065 #ifdef HAVE_SYS_VFS_H
1066 #include <sys/vfs.h>
1067 #endif
1068 #ifdef HAVE_SYS_MOUNT_H
1069 #include <sys/mount.h>
1070 #endif
1071 #ifdef HAVE_SYS_STATFS_H
1072 #include <sys/statfs.h>
1073 #endif], [struct statfs st;
1074 statfs("/", &st);],[
1075 AC_MSG_RESULT([2])
1076 AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1077 AC_TRY_COMPILE([#include <unistd.h>
1078 #ifdef HAVE_SYS_PARAM_H
1079 #include <sys/param.h>
1080 #endif
1081 #ifdef HAVE_SYS_VFS_H
1082 #include <sys/vfs.h>
1083 #endif
1084 #ifdef HAVE_SYS_MOUNT_H
1085 #include <sys/mount.h>
1086 #endif
1087 #ifdef HAVE_SYS_STATFS_H
1088 #include <sys/statfs.h>
1089 #endif], [struct statfs st;
1090 statfs("/", &st, sizeof (st), 0);],[
1091 AC_MSG_RESULT([4])
1092 AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1093 AC_MSG_RESULT(unknown)
1094 AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1095 ])
1097 dnl
1098 dnl open takes O_DIRECTORY as an option
1099 dnl
1100 AC_MSG_CHECKING([open() option O_DIRECTORY])
1101 AC_TRY_COMPILE([#include <fcntl.h>
1102 #include <sys/types.h>
1103 #include <sys/stat.h>],
1104 [open(0, O_DIRECTORY, 0);],[
1105 AC_MSG_RESULT([yes])
1106 AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1107 AC_MSG_RESULT([no])])
1109 #
1110 # Check whether to use an included printf
1111 #
1112 AC_FUNC_VSNPRINTF_C99
1113 AC_FUNC_PRINTF_UNIX98
1115 AC_ARG_ENABLE(included-printf,
1116 [AS_HELP_STRING([--enable-included-printf],
1117 [use included printf [default=auto]])],
1118 enable_included_printf="$enableval")
1120 need_included_printf=no
1121 if test "x$enable_included_printf" = "xyes" ; then
1122 need_included_printf=yes
1123 fi
1124 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1125 need_included_printf=yes
1126 fi
1127 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1128 need_included_printf=yes
1129 fi
1130 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1131 test -z "$glib_cv_long_long_format" ; then
1132 need_included_printf=yes
1133 fi
1135 if test "x$enable_included_printf" = "xno" &&
1136 test "x$need_included_printf" = "xyes" ; then
1137 AC_MSG_ERROR([
1138 *** Your C library's printf doesn't appear to have the features that
1139 *** GLib needs, but you specified --enable-included-printf=no.])
1140 fi
1142 enable_included_printf=$need_included_printf
1144 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1145 AS_IF([test "$enable_included_printf" != "yes"], [
1146 AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1147 ], [
1148 if test -z "$glib_cv_long_long_format" ; then
1149 glib_cv_long_long_format="ll"
1150 fi
1151 AC_DEFINE(HAVE_VASPRINTF,1)
1152 ])
1154 # Checks needed for gnulib vasnprintf
1155 bh_C_SIGNED
1156 jm_AC_TYPE_LONG_LONG
1157 gt_TYPE_LONGDOUBLE
1158 gt_TYPE_WCHAR_T
1159 gt_TYPE_WINT_T
1160 AC_TYPE_SIZE_T
1161 AC_CHECK_TYPES(ptrdiff_t)
1162 jm_AC_TYPE_INTMAX_T
1163 AC_CHECK_FUNCS([snprintf strnlen wcslen wcsnlen mbrtowc wcrtomb])
1164 AC_FUNC_SNPRINTF_C99
1166 # Check if <sys/select.h> needs to be included for fd_set
1167 AC_MSG_CHECKING([for fd_set])
1168 AC_TRY_COMPILE([#include <sys/types.h>],
1169 [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1170 AS_IF([test "$gtk_ok" = "yes"], [
1171 AC_MSG_RESULT([yes, found in sys/types.h])
1172 ], [
1173 AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1174 if test "$gtk_ok" = "yes"; then
1175 # *** FIXME: give it a different name
1176 AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1177 AC_MSG_RESULT([yes, found in sys/select.h])
1178 else
1179 AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1180 AC_MSG_RESULT(no)
1181 fi
1182 ])
1184 dnl Check for nl_langinfo and CODESET
1185 AC_LANG_SAVE
1186 AC_LANG_C
1187 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1188 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1189 [char *codeset = nl_langinfo (CODESET);])],
1190 [glib_cv_langinfo_codeset=yes],
1191 [glib_cv_langinfo_codeset=no])])
1192 if test x$glib_cv_langinfo_codeset = xyes; then
1193 AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1194 fi
1196 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1197 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1198 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1199 [char *str;
1200 str = nl_langinfo (PM_STR);
1201 str = nl_langinfo (D_T_FMT);
1202 str = nl_langinfo (D_FMT);
1203 str = nl_langinfo (T_FMT);
1204 str = nl_langinfo (T_FMT_AMPM);
1205 str = nl_langinfo (MON_1);
1206 str = nl_langinfo (ABMON_12);
1207 str = nl_langinfo (DAY_1);
1208 str = nl_langinfo (ABDAY_7);])],
1209 [glib_cv_langinfo_time=yes],
1210 [glib_cv_langinfo_time=no])])
1211 if test x$glib_cv_langinfo_time = xyes; then
1212 AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1213 fi
1215 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1216 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1217 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1218 [char *str;
1219 str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1220 str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1221 str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1222 str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1223 str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1224 str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1225 str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1226 str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1227 str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1228 str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1229 [glib_cv_langinfo_outdigit=yes],
1230 [glib_cv_langinfo_outdigit=no])])
1231 if test x$glib_cv_langinfo_outdigit = xyes; then
1232 AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1233 fi
1234 AC_LANG_RESTORE
1236 dnl ****************************************
1237 dnl *** posix_memalign ***
1238 dnl ****************************************
1239 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1240 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1241 glib_cv_compliant_posix_memalign=0
1242 if test "$ac_cv_func_posix_memalign" = "yes" ; then
1243 AC_TRY_RUN([
1244 #define _XOPEN_SOURCE 600
1245 #include <stdlib.h> /* posix_memalign() should be defined here */
1246 /* some systems break if #include <malloc.h> used */
1247 static void test_memalign (size_t boundary, size_t size) {
1248 void *mem = 0;
1249 if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1250 exit (1);
1251 else
1252 free (mem);
1253 }
1254 int main() {
1255 test_memalign ( 128, 128 - 2 * sizeof (void*));
1256 test_memalign ( 256, 256 - 2 * sizeof (void*));
1257 test_memalign ( 512, 512 - 2 * sizeof (void*));
1258 test_memalign ( 1024, 1024 - 2 * sizeof (void*));
1259 test_memalign ( 2048, 2048 - 2 * sizeof (void*));
1260 test_memalign ( 4096, 4096 - 2 * sizeof (void*));
1261 test_memalign ( 8192, 8192 - 2 * sizeof (void*));
1262 test_memalign (16384, 16384 - 2 * sizeof (void*));
1263 test_memalign (32768, 32768 - 2 * sizeof (void*));
1264 exit (0); /* success */
1265 }
1266 ],
1267 [glib_cv_compliant_posix_memalign=1], [], [:])
1268 :
1269 fi
1270 ])
1271 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1272 AC_MSG_RESULT(yes)
1273 AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1274 ], [
1275 AC_MSG_RESULT(no)
1276 ])
1279 dnl ****************************************
1280 dnl *** strlcpy/strlcat ***
1281 dnl ****************************************
1282 # Check for strlcpy
1283 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1284 AC_TRY_RUN([#include <stdlib.h>
1285 #include <string.h>
1286 int main() {
1287 char p[10];
1288 (void) strlcpy (p, "hi", 10);
1289 if (strlcat (p, "bye", 0) != 3)
1290 return 1;
1291 return 0;
1292 }], glib_cv_have_strlcpy=yes,
1293 glib_cv_have_strlcpy=no,
1294 glib_cv_have_strlcpy=no)])
1295 if test "$glib_cv_have_strlcpy" = "yes"; then
1296 AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1297 fi
1300 dnl **********************
1301 dnl *** va_copy checks ***
1302 dnl **********************
1303 dnl we currently check for all three va_copy possibilities, so we get
1304 dnl all results in config.log for bug reports.
1305 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1306 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1307 #include <stdlib.h>
1308 void f (int i, ...) {
1309 va_list args1, args2;
1310 va_start (args1, i);
1311 va_copy (args2, args1);
1312 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1313 exit (1);
1314 va_end (args1); va_end (args2);
1315 }
1316 int main() {
1317 f (0, 42);
1318 return 0;
1319 }]])],
1320 [glib_cv_va_copy=yes],
1321 [glib_cv_va_copy=no])
1322 ])
1323 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1324 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1325 #include <stdlib.h>
1326 void f (int i, ...) {
1327 va_list args1, args2;
1328 va_start (args1, i);
1329 __va_copy (args2, args1);
1330 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1331 exit (1);
1332 va_end (args1); va_end (args2);
1333 }
1334 int main() {
1335 f (0, 42);
1336 return 0;
1337 }]])],
1338 [glib_cv___va_copy=yes],
1339 [glib_cv___va_copy=no])
1340 ])
1342 if test "x$glib_cv_va_copy" = "xyes"; then
1343 g_va_copy_func=va_copy
1344 else if test "x$glib_cv___va_copy" = "xyes"; then
1345 g_va_copy_func=__va_copy
1346 fi
1347 fi
1349 if test -n "$g_va_copy_func"; then
1350 AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1351 fi
1353 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1354 AC_TRY_RUN([#include <stdarg.h>
1355 #include <stdlib.h>
1356 void f (int i, ...) {
1357 va_list args1, args2;
1358 va_start (args1, i);
1359 args2 = args1;
1360 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1361 exit (1);
1362 va_end (args1); va_end (args2);
1363 }
1364 int main() {
1365 f (0, 42);
1366 return 0;
1367 }],
1368 [glib_cv_va_val_copy=yes],
1369 [glib_cv_va_val_copy=no],
1370 [glib_cv_va_val_copy=yes])
1371 ])
1373 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1374 AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1375 ])
1377 dnl ***********************
1378 dnl *** g_module checks ***
1379 dnl ***********************
1380 G_MODULE_LIBS=
1381 G_MODULE_LIBS_EXTRA=
1382 G_MODULE_PLUGIN_LIBS=
1383 if test x"$glib_native_win32" = xyes; then
1384 dnl No use for this on Win32
1385 G_MODULE_LDFLAGS=
1386 else
1387 export SED
1388 eval G_MODULE_LDFLAGS=$export_dynamic_flag_spec
1389 fi
1390 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1391 G_MODULE_NEED_USCORE=0
1392 G_MODULE_BROKEN_RTLD_GLOBAL=0
1393 G_MODULE_HAVE_DLERROR=0
1394 dnl *** force native WIN32 shared lib loader
1395 if test -z "$G_MODULE_IMPL"; then
1396 case "$host" in
1397 *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1398 esac
1399 fi
1400 dnl *** force native AIX library loader
1401 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1402 if test -z "$G_MODULE_IMPL"; then
1403 case "$host" in
1404 *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1405 esac
1406 fi
1407 dnl *** dlopen() and dlsym() in system libraries
1408 AS_IF([ test -z "$G_MODULE_IMPL"], [
1409 AC_CHECK_FUNC(dlopen,
1410 [AC_CHECK_FUNC(dlsym,
1411 [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1412 [])
1413 ])
1414 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1415 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1416 AC_CHECK_FUNC(NSLinkModule,
1417 [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1418 G_MODULE_NEED_USCORE=1],
1419 [])
1420 ])
1421 dnl *** dlopen() and dlsym() in libdl
1422 AS_IF([ test -z "$G_MODULE_IMPL"], [
1423 AC_CHECK_LIB(dl, dlopen,
1424 [AC_CHECK_LIB(dl, dlsym,
1425 [G_MODULE_LIBS=-ldl
1426 G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1427 [])
1428 ])
1429 dnl *** additional checks for G_MODULE_IMPL_DL
1430 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1431 LIBS_orig="$LIBS"
1432 LDFLAGS_orig="$LDFLAGS"
1433 LIBS="$G_MODULE_LIBS $LIBS"
1434 LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1435 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1436 echo "void glib_plugin_test(void) { }" > plugin.c
1437 ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1438 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1439 ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1440 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1441 -shrext ".o" -avoid-version plugin.lo \
1442 -rpath /dont/care >/dev/null 2>&1
1443 AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1444 glib_cv_rtldglobal_broken,[
1445 AC_TRY_RUN([
1446 #include <dlfcn.h>
1447 #ifndef RTLD_GLOBAL
1448 # define RTLD_GLOBAL 0
1449 #endif
1450 #ifndef RTLD_LAZY
1451 # define RTLD_LAZY 0
1452 #endif
1453 int glib_plugin_test;
1454 int main () {
1455 void *handle, *global, *local;
1456 global = &glib_plugin_test;
1457 handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1458 if (!handle) return 0;
1459 local = dlsym (handle, "glib_plugin_test");
1460 return global == local;
1461 } ],
1462 [glib_cv_rtldglobal_broken=no],
1463 [glib_cv_rtldglobal_broken=yes],
1464 [glib_cv_rtldglobal_broken=no])
1465 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1466 rmdir ${objdir} 2>/dev/null
1467 ])
1468 if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1469 G_MODULE_BROKEN_RTLD_GLOBAL=1
1470 else
1471 G_MODULE_BROKEN_RTLD_GLOBAL=0
1472 fi
1473 dnl *** check whether we need preceeding underscores
1474 AC_CACHE_CHECK([for preceeding underscore in symbols],
1475 glib_cv_uscore,[
1476 AC_TRY_RUN([#include <dlfcn.h>
1477 int glib_underscore_test (void) { return 42; }
1478 int main() {
1479 void *f1 = (void*)0, *f2 = (void*)0, *handle;
1480 handle = dlopen ((void*)0, 0);
1481 if (handle) {
1482 f1 = dlsym (handle, "glib_underscore_test");
1483 f2 = dlsym (handle, "_glib_underscore_test");
1484 } return (!f2 || f1);
1485 }],
1486 [glib_cv_uscore=yes],
1487 [glib_cv_uscore=no],
1488 [])
1489 rm -f plugin.c plugin.$ac_objext plugin.lo
1490 ])
1491 GLIB_ASSERT_SET(glib_cv_uscore)
1492 if test "x$glib_cv_uscore" = "xyes"; then
1493 G_MODULE_NEED_USCORE=1
1494 else
1495 G_MODULE_NEED_USCORE=0
1496 fi
1498 AC_CHECK_DECL([RTLD_LAZY],
1499 [AC_DEFINE(HAVE_RTLD_LAZY, 1, [Define to 1 if RTLD_LAZY is available])],
1500 [], [[#include <dlfcn.h>]])
1501 AC_CHECK_DECL([RTLD_NOW],
1502 [AC_DEFINE(HAVE_RTLD_NOW, 1, [Define to 1 if RTLD_NOW is available])],
1503 [], [[#include <dlfcn.h>]])
1504 AC_CHECK_DECL([RTLD_GLOBAL],
1505 [AC_DEFINE(HAVE_RTLD_GLOBAL, 1, [Define to 1 if RTLD_GLOBAL is available])],
1506 [], [[#include <dlfcn.h>]])
1508 LDFLAGS="$LDFLAGS_orig"
1509 dnl *** check for having dlerror()
1510 AC_CHECK_FUNC(dlerror,
1511 [G_MODULE_HAVE_DLERROR=1],
1512 [G_MODULE_HAVE_DLERROR=0])
1513 LIBS="$LIBS_orig"
1514 ])
1515 dnl *** done, have we got an implementation?
1516 if test -z "$G_MODULE_IMPL"; then
1517 G_MODULE_IMPL=0
1518 G_MODULE_SUPPORTED=false
1519 else
1520 G_MODULE_SUPPORTED=true
1521 fi
1523 AC_MSG_CHECKING(for the suffix of module shared libraries)
1524 export SED
1525 module=yes eval std_shrext=$shrext_cmds
1526 # chop the initial dot
1527 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1528 AC_MSG_RESULT(.$glib_gmodule_suffix)
1529 # any reason it may fail?
1530 if test "x$glib_gmodule_suffix" = x; then
1531 AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1532 fi
1534 AC_SUBST(G_MODULE_SUPPORTED)
1535 AC_SUBST(G_MODULE_IMPL)
1536 AC_SUBST(G_MODULE_LIBS)
1537 AC_SUBST(G_MODULE_LIBS_EXTRA)
1538 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1539 AC_SUBST(G_MODULE_LDFLAGS)
1540 AC_SUBST(G_MODULE_HAVE_DLERROR)
1541 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1542 AC_SUBST(G_MODULE_NEED_USCORE)
1543 AC_SUBST(GLIB_DEBUG_FLAGS)
1545 dnl **********************
1546 dnl *** g_spawn checks ***
1547 dnl **********************
1549 AC_MSG_CHECKING(for gspawn implementation)
1550 case "$host" in
1551 *-*-mingw*)
1552 GSPAWN=gspawn-win32.lo
1553 ;;
1554 *)
1555 GSPAWN=gspawn.lo
1556 ;;
1557 esac
1558 AC_MSG_RESULT($GSPAWN)
1559 AC_SUBST(GSPAWN)
1561 dnl *************************
1562 dnl *** GIOChannel checks ***
1563 dnl *************************
1565 AC_MSG_CHECKING(for GIOChannel implementation)
1566 case "$host" in
1567 *-*-mingw*)
1568 GIO=giowin32.lo
1569 ;;
1570 *)
1571 GIO=giounix.lo
1572 ;;
1573 esac
1574 AC_MSG_RESULT($GIO)
1575 AC_SUBST(GIO)
1577 dnl *********************************
1578 dnl *** Directory for GIO modules ***
1579 dnl *********************************
1581 AC_ARG_WITH(gio-module-dir,
1582 [AS_HELP_STRING([--with-gio-module-dir=DIR],
1583 [load gio modules from this directory [LIBDIR/gio/modules]])],
1584 [],
1585 [with_gio_module_dir='${libdir}/gio/modules'])
1586 GIO_MODULE_DIR=$with_gio_module_dir
1587 AC_SUBST(GIO_MODULE_DIR)
1589 dnl **********************************
1590 dnl *** Check for libselinux (GIO) ***
1591 dnl **********************************
1592 AC_ARG_ENABLE(selinux,
1593 AS_HELP_STRING([--disable-selinux],
1594 [build without selinux support]))
1595 msg_selinux=no
1596 SELINUX_LIBS=
1597 AS_IF([ test "x$enable_selinux" != "xno"], [
1599 AC_CHECK_LIB(selinux, is_selinux_enabled,
1600 [AC_CHECK_HEADERS(selinux/selinux.h,
1601 [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1602 [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1603 SELINUX_LIBS="-lselinux"
1604 msg_selinux=yes])
1605 ])
1606 ])
1607 ])
1608 AC_SUBST(SELINUX_LIBS)
1610 dnl *****************************
1611 dnl ** Check for inotify (GIO) **
1612 dnl *****************************
1613 inotify_support=no
1614 AC_CHECK_HEADERS([sys/inotify.h],
1615 [
1616 AC_CHECK_FUNCS(inotify_init1, [inotify_support=yes], [inotify_support=no])
1617 ])
1619 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1621 dnl ****************************
1622 dnl ** Check for kqueue (GIO) **
1623 dnl ****************************
1624 kqueue_support=no
1625 AC_CHECK_HEADERS([sys/event.h],
1626 [
1627 AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1628 ])
1630 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1632 dnl ****************************
1633 dnl *** Checks for FAM (GIO) ***
1634 dnl ****************************
1636 should_disable_fam=no
1638 AC_ARG_ENABLE(fam,
1639 AS_HELP_STRING([--disable-fam],
1640 [don't use fam for file system monitoring]),
1641 [
1642 if test "x$enable_fam" = "xno"; then
1643 should_disable_fam=yes
1644 fi
1645 ]
1646 )
1647 fam_support=no
1648 FAM_LIBS=
1649 if test "x$should_disable_fam" = "xno"; then
1650 AC_CHECK_LIB(fam, FAMOpen,
1651 [AC_CHECK_HEADERS(fam.h,
1652 [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1653 AC_CHECK_LIB(fam, FAMNoExists,
1654 AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1655 FAM_LIBS="-lfam"]
1656 fam_support=yes,
1657 AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1658 AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1659 AC_SUBST(FAM_LIBS)
1660 fi
1661 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1664 dnl *****************************
1665 dnl *** Check for xattr (GIO) ***
1666 dnl *****************************
1667 AC_ARG_ENABLE(xattr,
1668 AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1669 msg_xattr=no
1670 XATTR_LIBS=
1671 AS_IF([ test "x$enable_xattr" != "xno"], [
1673 dnl either glibc or libattr can provide xattr support
1675 dnl for both of them, we check for getxattr being in
1676 dnl the library and a valid xattr header.
1678 dnl try glibc
1679 AC_CHECK_LIB(c, getxattr,
1680 [AC_CHECK_HEADERS(sys/xattr.h,
1681 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1682 msg_xattr=yes])
1683 ])
1685 AS_IF([ test "x$msg_xattr" != "xyes"], [
1686 dnl failure. try libattr
1687 AC_CHECK_LIB(attr, getxattr,
1688 [AC_CHECK_HEADERS(attr/xattr.h,
1689 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1690 XATTR_LIBS="-lattr"
1691 msg_xattr=yes])
1692 ])
1693 ])
1695 AS_IF([ test "x$msg_xattr" = "xyes"], [
1696 AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1697 AC_TRY_COMPILE([
1698 #include <stdio.h>
1699 #ifdef HAVE_SYS_TYPES_H
1700 #include <sys/types.h>
1701 #endif
1702 #ifdef HAVE_SYS_XATTR_H
1703 #include <sys/xattr.h>
1704 #elif HAVE_ATTR_XATTR_H
1705 #include <attr/xattr.h>
1706 #endif
1707 ],
1708 [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1709 [
1710 AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1711 AC_MSG_RESULT([yes])
1712 ],
1713 [AC_MSG_RESULT([no])]
1714 )
1715 ])
1716 ])
1717 AC_SUBST(XATTR_LIBS)
1719 dnl ************************
1720 dnl *** check for libelf ***
1721 dnl ************************
1722 AC_ARG_ENABLE(libelf,
1723 AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1724 AS_IF([ test "x$enable_libelf" != "xno"],[
1725 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1726 AS_IF([ test $have_libelf = maybe ], [
1727 glib_save_LIBS=$LIBS
1728 AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1729 AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1730 AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1731 AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1732 LIBS=$glib_save_LIBS
1734 if test $have_libelf != no; then
1735 LIBELF_LIBS=-lelf
1736 have_libelf=yes
1737 fi
1738 ])
1739 ])
1741 if test x$have_libelf = xyes; then
1742 AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1743 fi
1745 dnl ************************
1746 dnl *** check for libmount ***
1747 dnl ************************
1749 dnl The fallback code doesn't really implement the same behaviors - e.g.
1750 dnl so on linux we want to require libmount unless specifically disabled
1751 dnl
1752 enable_libmount_default=${glib_os_linux:-no}
1753 AC_ARG_ENABLE(libmount,
1754 [AS_HELP_STRING([--enable-libmount],
1755 [build with libmount support [default for Linux]])],,
1756 [enable_libmount=$enable_libmount_default])
1757 AS_IF([ test "x$enable_libmount" = "xyes"],[
1758 PKG_CHECK_MODULES([LIBMOUNT], [mount >= 2.28], [have_libmount=yes], [have_libmount=maybe])
1759 AS_IF([ test $have_libmount = maybe ], [
1760 glib_save_LIBS=$LIBS
1761 AC_CHECK_HEADER([libmount/libmount.h], [:], [have_libmount=no])
1763 # We used to check for mnt_unref_table(), but now for compat with
1764 # e.g. RHEL7 just use mnt_free_table(). Let's keep this check
1765 # anyways.
1766 AC_CHECK_LIB([mount], [mnt_free_table], [:], [have_libmount=no])
1767 LIBS=$glib_save_LIBS
1769 if test $have_libmount != no; then
1770 LIBMOUNT_LIBS=-lmount
1771 have_libmount=yes
1772 fi
1773 ])
1774 if test $have_libmount = no ; then
1775 AC_MSG_ERROR([*** Could not find libmount])
1776 fi
1777 ])
1779 if test x$have_libmount = xyes; then
1780 AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available])
1781 fi
1782 AM_CONDITIONAL(HAVE_LIBMOUNT, [test x$have_libmount = xyes])
1784 dnl ****************************************
1785 dnl *** platform dependent source checks ***
1786 dnl ****************************************
1788 AC_MSG_CHECKING(for platform-dependent source)
1789 case "$host" in
1790 *-*-cygwin*|*-*-mingw*)
1791 PLATFORMDEP=gwin32.lo
1792 ;;
1793 *)
1794 PLATFORMDEP=
1795 ;;
1796 esac
1797 AC_MSG_RESULT($PLATFORMDEP)
1798 AC_SUBST(PLATFORMDEP)
1800 AC_MSG_CHECKING([whether to compile timeloop])
1801 case "$host" in
1802 *-*-cygwin*|*-*-mingw*|*-*-minix)
1803 enable_timeloop=no
1804 ;;
1805 *)
1806 enable_timeloop=yes
1807 ;;
1808 esac
1809 AC_MSG_RESULT($enable_timeloop)
1810 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1812 AC_MSG_CHECKING([if building for some Win32 platform])
1813 case "$host" in
1814 *-*-mingw*|*-*-cygwin*)
1815 platform_win32=yes
1816 ;;
1817 *)
1818 platform_win32=no
1819 ;;
1820 esac
1821 AC_MSG_RESULT($platform_win32)
1822 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1824 dnl ***********************
1825 dnl *** g_thread checks ***
1826 dnl ***********************
1828 AC_ARG_WITH(threads,
1829 [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1830 [specify a thread implementation to use])],
1831 [],
1832 [with_threads=yes])
1834 dnl error and warning message
1835 dnl *************************
1837 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1839 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1840 platform (normally it's "_REENTRANT"). I'll not use any flag on
1841 compilation now, but then your programs might not work.
1842 Please provide information on how it is done on your system."
1844 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1845 "
1847 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1848 provide information on your thread implementation."
1850 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1851 functions will not be MT-safe during their first call because
1852 there is no working 'getpwuid_r' on your system."
1854 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1855 because there is no 'localtime_r' on your system."
1857 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1858 linking threaded applications. As GLib cannot do that
1859 automatically, you will get an linkg error everytime you are
1860 not using the right compiler. In that case you have to relink
1861 with the right compiler. Ususally just '_r' is appended
1862 to the compiler name."
1864 dnl determination of thread implementation
1865 dnl ***************************************
1867 AC_MSG_CHECKING(for thread implementation)
1869 have_threads=no
1870 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1871 AS_IF([ test "x$have_threads" = xno], [
1872 AC_TRY_COMPILE([#include <pthread.h>],
1873 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1874 have_threads=posix)
1875 ])
1876 # Tru64Unix requires -pthread to find pthread.h. See #103020
1877 if test "x$have_threads" = xno; then
1878 glib_save_CPPFLAGS="$CPPFLAGS"
1879 CPPFLAGS="$CPPFLAGS -pthread"
1880 AC_TRY_COMPILE([#include <pthread.h>],
1881 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1882 have_threads=posix)
1883 CPPFLAGS="$glib_save_CPPFLAGS"
1884 fi
1885 ])
1886 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1887 case $host in
1888 *-*-mingw*)
1889 have_threads=win32
1890 ;;
1891 esac
1892 fi
1894 if test "x$have_threads" = xno; then
1895 AC_MSG_RESULT(none available)
1896 AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1897 else
1898 AC_MSG_RESULT($have_threads)
1899 fi
1902 dnl determination of G_THREAD_CFLAGS
1903 dnl ********************************
1905 G_THREAD_LIBS=
1906 G_THREAD_LIBS_EXTRA=
1907 G_THREAD_CFLAGS=
1909 dnl
1910 dnl Test program for basic POSIX threads functionality
1911 dnl
1912 m4_define([glib_thread_test],[
1913 #include <pthread.h>
1914 int check_me = 0;
1915 void* func(void* data) {check_me = 42; return &check_me;}
1916 int main()
1917 { pthread_t t;
1918 void *ret;
1919 pthread_create (&t, $1, func, 0);
1920 pthread_join (t, &ret);
1921 return (check_me != 42 || ret != &check_me);
1922 }])
1924 AS_IF([ test x"$have_threads" = xposix], [
1925 # First we test for posix, whether -pthread or -pthreads do the trick as
1926 # both CPPFLAG and LIBS.
1927 # One of them does for most gcc versions and some other platforms/compilers
1928 # too and could be considered as the canonical way to go.
1929 case $host in
1930 *-*-cygwin*|*-*-darwin*)
1931 # skip cygwin and darwin -pthread or -pthreads test
1932 ;;
1933 *-solaris*)
1934 # These compiler/linker flags work with both Sun Studio and gcc
1935 # Sun Studio expands -mt to -D_REENTRANT and -lthread
1936 # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1937 G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1938 G_THREAD_LIBS="-lpthread -lthread"
1939 ;;
1940 *)
1941 for flag in pthread pthreads mt; do
1942 glib_save_CFLAGS="$CFLAGS"
1943 CFLAGS="$CFLAGS -$flag"
1944 AC_TRY_RUN(glib_thread_test(0),
1945 glib_flag_works=yes,
1946 glib_flag_works=no,
1947 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1948 glib_flag_works=yes,
1949 glib_flag_works=no)])
1950 CFLAGS="$glib_save_CFLAGS"
1951 if test $glib_flag_works = yes ; then
1952 G_THREAD_CFLAGS=-$flag
1953 G_THREAD_LIBS=-$flag
1954 break;
1955 fi
1956 done
1957 ;;
1958 esac
1959 ])
1961 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
1963 # The canonical -pthread[s] does not work. Try something different.
1965 case $host in
1966 *-aix*)
1967 if test x"$GCC" = xyes; then
1968 # GCC 3.0 and above needs -pthread.
1969 # Should be coverd by the case above.
1970 # GCC 2.x and below needs -mthreads
1971 G_THREAD_CFLAGS="-mthreads"
1972 G_THREAD_LIBS=$G_THREAD_CFLAGS
1973 else
1974 # We are probably using the aix compiler. Normaly a
1975 # program would have to be compiled with the _r variant
1976 # of the corresponding compiler, but we as GLib cannot
1977 # do that: but the good news is that for compiling the
1978 # only difference is the added -D_THREAD_SAFE compile
1979 # option. This is according to the "C for AIX User's
1980 # Guide".
1981 G_THREAD_CFLAGS="-D_THREAD_SAFE"
1982 fi
1983 ;;
1984 *-sysv5uw7*) # UnixWare 7
1985 # We are not using gcc with -pthread. Catched above.
1986 G_THREAD_CFLAGS="-Kthread"
1987 G_THREAD_LIBS=$G_THREAD_CFLAGS
1988 ;;
1989 *-mingw*)
1990 # No flag needed when using MSVCRT.DLL
1991 G_THREAD_CFLAGS=""
1992 ;;
1993 *)
1994 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1995 ;;
1996 esac
1997 ])
1999 # if we are not finding the localtime_r function, then we probably are
2000 # not using the proper multithread flag
2002 glib_save_CPPFLAGS="$CPPFLAGS"
2003 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2005 # First we test, whether localtime_r is declared in time.h
2006 # directly. Then we test whether a macro localtime_r exists, in
2007 # which case localtime_r in the test program is replaced and thus
2008 # if we still find localtime_r in the output, it is not defined as
2009 # a macro.
2011 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2012 [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2013 localtime_r(a,b)],
2014 AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2016 CPPFLAGS="$glib_save_CPPFLAGS"
2018 AC_MSG_CHECKING(thread related cflags)
2019 AC_MSG_RESULT($G_THREAD_CFLAGS)
2020 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2022 dnl determination of G_THREAD_LIBS
2023 dnl ******************************
2025 AS_IF([test x$have_threads = xposix], [
2026 glib_save_CPPFLAGS="$CPPFLAGS"
2027 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2028 AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2029 case $host in
2030 *-aix*)
2031 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2032 # probably using the aix compiler.
2033 AC_MSG_WARN($AIX_COMPILE_INFO)
2034 ;;
2035 *)
2036 G_THREAD_LIBS=error
2037 glib_save_LIBS="$LIBS"
2038 for thread_lib in "" pthread pthread32 pthreads thread; do
2039 if test x"$thread_lib" = x; then
2040 add_thread_lib=""
2041 IN=""
2042 else
2043 add_thread_lib="-l$thread_lib"
2044 IN=" in -l$thread_lib"
2045 fi
2046 if test x"$have_threads" = xposix; then
2047 defattr=0
2048 else
2049 defattr=pthread_attr_default
2050 fi
2052 LIBS="$add_thread_lib $glib_save_LIBS"
2054 AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2055 AC_TRY_RUN(glib_thread_test($defattr),
2056 glib_result=yes,
2057 glib_result=no,
2058 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2059 glib_result=yes,
2060 glib_result=no)])
2061 AC_MSG_RESULT($glib_result)
2063 if test "$glib_result" = "yes" ; then
2064 G_THREAD_LIBS="$add_thread_lib"
2065 break
2066 fi
2067 done
2068 if test "x$G_THREAD_LIBS" = xerror; then
2069 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2070 fi
2071 LIBS="$glib_save_LIBS"
2072 ;;
2073 esac
2074 ])
2076 g_threads_impl="POSIX"
2077 AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2078 AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2079 CPPFLAGS="$glib_save_CPPFLAGS"
2080 ], [test x$have_threads = xwin32], [
2081 AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2082 g_threads_impl="WIN32"
2083 ], [
2084 AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2085 g_threads_impl="NONE"
2086 G_THREAD_LIBS=error
2087 ])
2088 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2089 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2090 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2092 if test "x$G_THREAD_LIBS" = xerror; then
2093 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2094 fi
2096 AC_MSG_CHECKING(thread related libraries)
2097 AC_MSG_RESULT($G_THREAD_LIBS)
2099 dnl check for mt safe function variants and some posix functions
2100 dnl ************************************************************
2102 glib_save_LIBS="$LIBS"
2103 # we are not doing the following for now, as this might require glib
2104 # to always be linked with the thread libs on some platforms.
2105 # LIBS="$LIBS $G_THREAD_LIBS"
2106 AC_CHECK_FUNCS(localtime_r gmtime_r getpwuid_r getgrgid_r)
2108 LIBS="$G_THREAD_LIBS $LIBS"
2109 AS_IF([ test x"$have_threads" = xposix], [
2110 glib_save_CPPFLAGS="$CPPFLAGS"
2111 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2112 # This is not AC_CHECK_FUNC to also work with function
2113 # name mangling in header files.
2114 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2115 AC_LINK_IFELSE(
2116 [AC_LANG_PROGRAM(
2117 [#include <pthread.h>],
2118 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2119 [AC_MSG_RESULT(yes)
2120 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2121 [Have function pthread_attr_setstacksize])],
2122 [AC_MSG_RESULT(no)])
2123 AC_MSG_CHECKING(for pthread_condattr_setclock)
2124 AC_LINK_IFELSE(
2125 [AC_LANG_PROGRAM(
2126 [#include <pthread.h>],
2127 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2128 [AC_MSG_RESULT(yes)
2129 AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2130 [Have function pthread_condattr_setclock])],
2131 [AC_MSG_RESULT(no)])
2132 AC_MSG_CHECKING(for pthread_cond_timedwait_relative_np)
2133 AC_LINK_IFELSE(
2134 [AC_LANG_PROGRAM(
2135 [#include <pthread.h>],
2136 [pthread_cond_timedwait_relative_np(NULL, NULL, NULL)])],
2137 [AC_MSG_RESULT(yes)
2138 AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP,1,
2139 [Have function pthread_cond_timedwait_relative_np])],
2140 [AC_MSG_RESULT(no)])
2141 dnl Sets thread names on OS X 10.6, iOS 3.2 (and higher)
2142 AC_MSG_CHECKING(for pthread_setname_np(const char*))
2143 AC_LINK_IFELSE(
2144 [AC_LANG_PROGRAM(
2145 [#include <pthread.h>],
2146 [pthread_setname_np("example")])],
2147 [AC_MSG_RESULT(yes)
2148 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
2149 [Have function pthread_setname_np(const char*)])],
2150 [AC_MSG_RESULT(no)])
2151 dnl Sets thread names on Solaris 11.3 & higher
2152 AC_MSG_CHECKING(for pthread_setname_np(pthread_t, const char*))
2153 AC_LINK_IFELSE(
2154 [AC_LANG_PROGRAM(
2155 [#include <pthread.h>],
2156 [pthread_setname_np(pthread_self(), "example")])],
2157 [AC_MSG_RESULT(yes)
2158 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITH_TID,1,
2159 [Have function pthread_setname_np(pthread_t, const char*)])],
2160 [AC_MSG_RESULT(no)])
2161 CPPFLAGS="$glib_save_CPPFLAGS"
2162 ])
2164 LIBS="$glib_save_LIBS"
2166 # now spit out all the warnings.
2167 if test "$ac_cv_func_getpwuid_r" != "yes"; then
2168 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2169 fi
2170 if test "$ac_cv_func_localtime_r" != "yes"; then
2171 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2172 fi
2174 #
2175 # Hack to deal with:
2176 #
2177 # a) GCC < 3.3 for Linux doesn't include -lpthread when
2178 # building shared libraries with linux.
2179 # b) FreeBSD doesn't do this either.
2180 #
2181 case $host in
2182 *android*)
2183 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2184 ;;
2185 *-*-freebsd*|*-*-linux*)
2186 G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2187 ;;
2188 *)
2189 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2190 ;;
2191 esac
2193 AC_SUBST(G_THREAD_CFLAGS)
2194 AC_SUBST(G_THREAD_LIBS)
2195 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2196 AC_SUBST(G_THREAD_LIBS_EXTRA)
2198 AC_CHECK_FUNCS(clock_gettime, [], [
2199 AC_CHECK_LIB(rt, clock_gettime, [
2200 G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2201 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2202 ])
2203 ])
2206 dnl ************************
2207 dnl *** g_atomic_* tests ***
2208 dnl ************************
2210 dnl We need to decide at configure time if GLib will use real atomic
2211 dnl operations ("lock free") or emulated ones with a mutex. This is
2212 dnl because we must put this information in glibconfig.h so we know if
2213 dnl it is safe or not to inline using compiler intrinsics directly from
2214 dnl the header.
2215 dnl
2216 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2217 dnl user is interested in knowing if they can use the atomic ops across
2218 dnl processes.
2219 dnl
2220 dnl We can currently support the atomic ops natively when building GLib
2221 dnl with recent versions of GCC or MSVC. MSVC doesn't run ./configure,
2222 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2223 dnl we are using GCC (and not mingw*).
2224 dnl
2225 dnl Note that the atomic ops are only available with GCC on x86 when
2226 dnl using -march=i486 or higher. If we detect that the atomic ops are
2227 dnl not available but would be available given the right flags, we want
2228 dnl to abort and advise the user to fix their CFLAGS. It's better to do
2229 dnl that then to silently fall back on emulated atomic ops just because
2230 dnl the user had the wrong build environment.
2232 dnl We may add other compilers here in the future...
2234 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2235 case $host in
2236 *-*-mingw*)
2237 glib_cv_g_atomic_lock_free=yes
2238 ;;
2239 *)
2240 AC_TRY_LINK([],
2241 [volatile int atomic = 2;\
2242 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2243 [glib_cv_g_atomic_lock_free=yes],
2244 [glib_cv_g_atomic_lock_free=no])
2245 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2246 SAVE_CFLAGS="${CFLAGS}"
2247 CFLAGS="-march=i486"
2248 AC_TRY_LINK([],
2249 [volatile int atomic = 2;\
2250 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2251 [AC_MSG_ERROR([GLib must be built with -march=i486 or later.])],
2252 [])
2253 CFLAGS="${SAVE_CFLAGS}"
2254 fi
2255 ;;
2256 esac])
2259 case $host in
2260 *-*-mingw*)
2261 ;;
2262 *)
2263 # Some compilers support atomic operations but do not define
2264 # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2265 if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2266 AC_TRY_LINK([],
2267 [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2268 [],
2269 [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2270 fi
2271 ;;
2272 esac
2274 dnl We need a more robust approach here...
2275 case $host_cpu in
2276 i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2277 glib_memory_barrier_needed=no
2278 ;;
2279 sparc*|alpha*|powerpc*|ia64)
2280 glib_memory_barrier_needed=yes
2281 ;;
2282 *)
2283 glib_memory_barrier_needed=yes
2284 ;;
2285 esac
2287 dnl ************************
2288 dnl ** Check for futex(2) **
2289 dnl ************************
2290 AC_CACHE_CHECK(for futex(2) system call,
2291 glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2292 #include <linux/futex.h>
2293 #include <sys/syscall.h>
2294 #include <unistd.h>
2295 ],[
2296 syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2297 ])],glib_cv_futex=yes,glib_cv_futex=no))
2298 if test x"$glib_cv_futex" = xyes; then
2299 AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2300 fi
2302 AC_CACHE_CHECK(for eventfd(2) system call,
2303 glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2304 #include <sys/eventfd.h>
2305 #include <unistd.h>
2306 ],[
2307 eventfd (0, EFD_CLOEXEC);
2308 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2309 if test x"$glib_cv_eventfd" = x"yes"; then
2310 AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2311 fi
2312 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2314 dnl ****************************************
2315 dnl *** GLib POLL* compatibility defines ***
2316 dnl ****************************************
2318 glib_poll_includes=["
2319 #include <sys/types.h>
2320 #include <poll.h>
2321 "]
2323 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2324 test $ac_cv_func_poll = yes ], [
2325 glib_failed=false
2326 GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2327 GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2328 GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2329 GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2330 GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2331 GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2332 if $glib_failed ; then
2333 AC_MSG_ERROR([Could not determine values for POLL* constants])
2334 fi
2335 ], [
2336 glib_cv_value_POLLIN=1
2337 glib_cv_value_POLLOUT=4
2338 glib_cv_value_POLLPRI=2
2339 glib_cv_value_POLLERR=8
2340 glib_cv_value_POLLHUP=16
2341 glib_cv_value_POLLNVAL=32
2342 ])
2344 AC_MSG_CHECKING([for broken poll])
2345 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2346 #include <stdlib.h>
2347 #include <fcntl.h>
2348 #include <poll.h>
2349 int main(void) {
2350 struct pollfd fds[1];
2351 int fd;
2352 fd = open("/dev/null", 1);
2353 fds[0].fd = fd;
2354 fds[0].events = POLLIN;
2355 fds[0].revents = 0;
2356 if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2357 exit(1); /* Does not work for devices -- fail */
2358 }
2359 exit(0);
2360 }]])],
2361 [broken_poll=no],
2362 [broken_poll=yes
2363 AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2364 [broken_poll="no (cross compiling)"])
2365 AC_MSG_RESULT($broken_poll)
2367 dnl *********************
2368 dnl *** GRegex checks ***
2369 dnl *********************
2371 PCRE_REQUIRED_VERSION=8.13
2373 # Check if we should use the internal or the system-supplied pcre
2374 AC_ARG_WITH(pcre,
2375 [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2376 [whether to use system PCRE [default=system]])],
2377 [],
2378 [with_pcre=system])
2380 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2382 AS_IF([ test "x$with_pcre" = xsystem], [
2383 PKG_CHECK_MODULES(PCRE,
2384 libpcre >= $PCRE_REQUIRED_VERSION)
2385 AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2386 glib_save_CFLAGS="$CFLAGS"
2387 glib_save_LIBS="$LIBS"
2388 CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2389 AC_TRY_RUN([#include <pcre.h>
2390 int main () {
2391 int support;
2392 pcre_config (PCRE_CONFIG_UTF8, &support);
2393 if (!support)
2394 return 1;
2395 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2396 if (!support)
2397 return 1;
2398 return 0;
2399 }],
2400 glib_cv_pcre_has_unicode=yes,
2401 glib_cv_pcre_has_unicode=no,
2402 glib_cv_pcre_has_unicode=yes)
2403 CFLAGS="$glib_save_CFLAGS"
2404 LIBS="$glib_save_LIBS"
2405 ])
2406 if test "$glib_cv_pcre_has_unicode" = "no"; then
2407 AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2408 fi
2409 AC_SUBST(PCRE_CFLAGS)
2410 AC_SUBST(PCRE_LIBS)
2411 AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2412 PCRE_REQUIRES=libpcre
2413 AC_SUBST(PCRE_REQUIRES)
2414 ], [
2415 # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2416 AS_IF([ test x"$GCC" = xyes], [
2417 AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2418 save_CFLAGS="$CFLAGS"
2419 CFLAGS="$CFLAGS -Wno-pointer-sign"
2420 AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2421 AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2422 CFLAGS="$save_CFLAGS"
2423 ])
2424 ])
2425 AC_SUBST(PCRE_WARN_CFLAGS)
2427 dnl **********************
2428 dnl *** Win32 API libs ***
2429 dnl **********************
2431 case $host in
2432 *-*-cygwin*)
2433 G_LIBS_EXTRA="-luser32 -lkernel32"
2434 ;;
2435 *-*-mingw*)
2436 G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2437 ;;
2438 *)
2439 G_LIBS_EXTRA=""
2440 ;;
2441 esac
2442 AC_SUBST(G_LIBS_EXTRA)
2444 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2445 dnl since we need it for g_iconv()
2447 AC_MSG_CHECKING([for EILSEQ])
2448 AC_TRY_COMPILE([
2449 #include <errno.h>
2450 ],
2451 [
2452 int error = EILSEQ;
2453 ], have_eilseq=yes, have_eilseq=no);
2454 AC_MSG_RESULT($have_eilseq)
2456 dnl Add a conditional we can use when cross-compiling, so we avoid running
2457 dnl binaries
2458 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2460 dnl **************************
2461 dnl *** Checks for gtk-doc ***
2462 dnl **************************
2463 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2464 # it on it's own line.
2465 m4_ifdef([GTK_DOC_CHECK], [
2466 GTK_DOC_CHECK([1.20], [--flavour no-tmpl])
2467 ],[
2468 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2469 ])
2471 AC_ARG_ENABLE(man,
2472 [AS_HELP_STRING([--enable-man],
2473 [generate man pages [default=auto]])],,
2474 enable_man=maybe)
2476 AS_IF([test "$enable_man" != no], [
2477 AC_PATH_PROG([XSLTPROC], [xsltproc])
2478 AS_IF([test -z "$XSLTPROC"], [
2479 AS_IF([test "$enable_man" = yes], [
2480 AC_MSG_ERROR([xsltproc is required for --enable-man])
2481 ])
2482 enable_man=no
2483 ])
2484 ])
2486 AS_IF([ test "$enable_man" != no ], [
2487 dnl check for DocBook DTD in the local catalog
2488 JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2489 [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2490 AS_IF([test "$have_docbook_dtd" != yes], [
2491 AS_IF([test "$enable_man" = yes ], [
2492 AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2493 ])
2494 enable_man=no
2495 ])
2496 ])
2498 AS_IF([test "$enable_man" != no], [
2499 dnl check for DocBook XSL stylesheets in the local catalog
2500 JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2501 [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2502 AS_IF([ test "$have_docbook_style" != yes ], [
2503 AS_IF([ test "$enable_man" = yes ], [
2504 AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2505 ])
2506 enable_man=no
2507 ])
2508 ])
2510 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2512 AC_MSG_CHECKING([whether to generate man pages])
2513 AS_IF([ test "$enable_man" != no ], [
2514 AC_MSG_RESULT([yes])
2515 ], [
2516 AC_MSG_RESULT([no])
2517 ])
2519 dnl
2520 dnl Tracing
2521 dnl
2523 AC_ARG_ENABLE([dtrace],
2524 [AS_HELP_STRING([--enable-dtrace],
2525 [include tracing support for dtrace])])
2526 have_dtrace=no
2527 AC_MSG_CHECKING([whether to include dtrace tracing support])
2528 AS_IF([ test "x$enable_dtrace" != xno], [
2529 if test x$glib_have_carbon = xyes; then
2530 AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2531 else
2532 AC_MSG_RESULT([yes])
2533 AC_CHECK_PROGS(DTRACE, dtrace)
2534 if test -z "$DTRACE"; then
2535 if test "x$enable_dtrace" = xyes; then
2536 AC_MSG_ERROR([dtrace not found])
2537 fi
2538 else
2539 AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2540 [if test "x$enable_dtrace" = xyes; then
2541 AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2542 fi])
2543 fi
2544 fi
2545 ], [
2546 AC_MSG_RESULT([no])
2547 ])
2548 if test "x$have_dtrace" = xyes; then
2549 AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2550 fi
2551 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2553 AC_MSG_CHECKING([whether to include systemtap tracing support])
2554 AC_ARG_ENABLE([systemtap],
2555 [AS_HELP_STRING([--enable-systemtap],
2556 [include tracing support for systemtap])])
2557 have_systemtap=no
2558 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2559 have_systemtap=yes
2560 fi
2561 AC_MSG_RESULT(${have_systemtap})
2563 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2565 AC_ARG_WITH([tapset-install-dir],
2566 AS_HELP_STRING([--with-tapset-install-dir=DIR],
2567 [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2568 [if test "x${withval}" = x; then
2569 ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2570 else
2571 ABS_TAPSET_DIR="${withval}"
2572 fi],
2573 [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2574 AC_SUBST(ABS_TAPSET_DIR)
2576 dnl ************************************
2577 dnl *** Enable lcov coverage reports ***
2578 dnl ************************************
2580 AC_ARG_ENABLE(coverage,
2581 AS_HELP_STRING([--enable-coverage],
2582 [enable coverage testing with gcov]),
2583 [use_gcov=$enableval], [use_gcov=no])
2585 AS_IF([ test "x$use_gcov" = "xyes"], [
2586 dnl we need gcc:
2587 if test "$GCC" != "yes"; then
2588 AC_MSG_ERROR([GCC is required for --enable-coverage])
2589 fi
2591 dnl Check if ccache is being used
2592 AC_CHECK_PROG(SHTOOL, shtool, shtool)
2593 case `$SHTOOL path $CC` in
2594 *ccache*[)] gcc_ccache=yes;;
2595 *[)] gcc_ccache=no;;
2596 esac
2598 if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2599 AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2600 fi
2602 ltp_version_list="1.6 1.7 1.8 1.9 1.10 1.12"
2603 AC_CHECK_PROG(LTP, lcov, lcov)
2604 AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2606 AS_IF([ test "$LTP" ], [
2607 AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2608 glib_cv_ltp_version=invalid
2609 ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2610 for ltp_check_version in $ltp_version_list; do
2611 if test "$ltp_version" = "$ltp_check_version"; then
2612 glib_cv_ltp_version="$ltp_check_version (ok)"
2613 fi
2614 done
2615 ])
2616 ], [
2617 ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2618 AC_MSG_ERROR([$ltp_msg])
2619 ])
2621 case $glib_cv_ltp_version in
2622 ""|invalid[)]
2623 ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2624 AC_MSG_ERROR([$ltp_msg])
2625 LTP="exit 0;"
2626 ;;
2627 esac
2629 if test -z "$LTP_GENHTML"; then
2630 AC_MSG_ERROR([Could not find genhtml from the LTP package])
2631 fi
2633 dnl Remove all optimization flags from CFLAGS
2634 changequote({,})
2635 CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2636 changequote([,])
2638 dnl Add the special gcc flags
2639 CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2640 LDFLAGS="$LDFLAGS -lgcov"
2641 ])
2643 dnl ******************************
2644 dnl *** output the whole stuff ***
2645 dnl ******************************
2647 dnl this section will only be run if config.status is invoked with no
2648 dnl arguments, or with "glib/glibconfig.h" as an argument.
2649 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2650 [
2651 outfile=glib/glibconfig.h-tmp
2652 cat > $outfile <<\_______EOF
2653 /* glibconfig.h
2654 *
2655 * This is a generated file. Please modify 'configure.ac'
2656 */
2658 #ifndef __GLIBCONFIG_H__
2659 #define __GLIBCONFIG_H__
2661 #include <glib/gmacros.h>
2663 _______EOF
2665 echo '#include <limits.h>' >> $outfile
2666 echo '#include <float.h>' >> $outfile
2667 if test x$glib_values_h = xyes; then
2668 echo '#include <values.h>' >> $outfile
2669 fi
2670 if test "$glib_header_alloca_h" = "yes"; then
2671 echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2672 fi
2673 if test x$glib_included_printf != xyes; then
2674 echo "
2675 /* Specifies that GLib's g_print*() functions wrap the
2676 * system printf functions. This is useful to know, for example,
2677 * when using glibc's register_printf_function().
2678 */" >> $outfile
2679 echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2680 fi
2682 cat >> $outfile <<_______EOF
2684 G_BEGIN_DECLS
2686 #define G_MINFLOAT FLT_MIN
2687 #define G_MAXFLOAT FLT_MAX
2688 #define G_MINDOUBLE DBL_MIN
2689 #define G_MAXDOUBLE DBL_MAX
2690 #define G_MINSHORT SHRT_MIN
2691 #define G_MAXSHORT SHRT_MAX
2692 #define G_MAXUSHORT USHRT_MAX
2693 #define G_MININT INT_MIN
2694 #define G_MAXINT INT_MAX
2695 #define G_MAXUINT UINT_MAX
2696 #define G_MINLONG LONG_MIN
2697 #define G_MAXLONG LONG_MAX
2698 #define G_MAXULONG ULONG_MAX
2700 _______EOF
2703 ### this should always be true in a modern C/C++ compiler
2704 ### and is statically asserted by glib-init.c
2705 cat >>$outfile <<_______EOF
2706 typedef signed char gint8;
2707 typedef unsigned char guint8;
2708 _______EOF
2711 if test -n "$gint16"; then
2712 cat >>$outfile <<_______EOF
2713 typedef signed $gint16 gint16;
2714 typedef unsigned $gint16 guint16;
2715 #define G_GINT16_MODIFIER $gint16_modifier
2716 #define G_GINT16_FORMAT $gint16_format
2717 #define G_GUINT16_FORMAT $guint16_format
2718 _______EOF
2719 fi
2722 if test -n "$gint32"; then
2723 cat >>$outfile <<_______EOF
2724 typedef signed $gint32 gint32;
2725 typedef unsigned $gint32 guint32;
2726 #define G_GINT32_MODIFIER $gint32_modifier
2727 #define G_GINT32_FORMAT $gint32_format
2728 #define G_GUINT32_FORMAT $guint32_format
2729 _______EOF
2730 fi
2732 cat >>$outfile <<_______EOF
2733 #define G_HAVE_GINT64 1 /* deprecated, always true */
2735 ${glib_extension}typedef signed $gint64 gint64;
2736 ${glib_extension}typedef unsigned $gint64 guint64;
2738 #define G_GINT64_CONSTANT(val) $gint64_constant
2739 #define G_GUINT64_CONSTANT(val) $guint64_constant
2740 _______EOF
2742 if test x$gint64_format != x ; then
2743 cat >>$outfile <<_______EOF
2744 #define G_GINT64_MODIFIER $gint64_modifier
2745 #define G_GINT64_FORMAT $gint64_format
2746 #define G_GUINT64_FORMAT $guint64_format
2747 _______EOF
2748 else
2749 cat >>$outfile <<_______EOF
2750 #undef G_GINT64_MODIFIER
2751 #undef G_GINT64_FORMAT
2752 #undef G_GUINT64_FORMAT
2753 _______EOF
2754 fi
2756 cat >>$outfile <<_______EOF
2758 #define GLIB_SIZEOF_VOID_P $glib_void_p
2759 #define GLIB_SIZEOF_LONG $glib_long
2760 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2761 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2763 _______EOF
2765 cat >>$outfile <<_______EOF
2766 typedef signed $glib_ssize_type_define gssize;
2767 typedef unsigned $glib_size_type_define gsize;
2768 #define G_GSIZE_MODIFIER $gsize_modifier
2769 #define G_GSSIZE_MODIFIER $gssize_modifier
2770 #define G_GSIZE_FORMAT $gsize_format
2771 #define G_GSSIZE_FORMAT $gssize_format
2773 #define G_MAXSIZE G_MAXU$glib_msize_type
2774 #define G_MINSSIZE G_MIN$glib_mssize_type
2775 #define G_MAXSSIZE G_MAX$glib_mssize_type
2777 typedef gint64 goffset;
2778 #define G_MINOFFSET G_MININT64
2779 #define G_MAXOFFSET G_MAXINT64
2781 #define G_GOFFSET_MODIFIER G_GINT64_MODIFIER
2782 #define G_GOFFSET_FORMAT G_GINT64_FORMAT
2783 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2785 #define G_POLLFD_FORMAT $g_pollfd_format
2787 _______EOF
2789 if test -z "$glib_unknown_void_p"; then
2790 cat >>$outfile <<_______EOF
2792 #define GPOINTER_TO_INT(p) ((gint) ${glib_gpi_cast} (p))
2793 #define GPOINTER_TO_UINT(p) ((guint) ${glib_gpui_cast} (p))
2795 #define GINT_TO_POINTER(i) ((gpointer) ${glib_gpi_cast} (i))
2796 #define GUINT_TO_POINTER(u) ((gpointer) ${glib_gpui_cast} (u))
2798 typedef signed $glib_intptr_type_define gintptr;
2799 typedef unsigned $glib_intptr_type_define guintptr;
2801 #define G_GINTPTR_MODIFIER $gintptr_modifier
2802 #define G_GINTPTR_FORMAT $gintptr_format
2803 #define G_GUINTPTR_FORMAT $guintptr_format
2804 _______EOF
2805 else
2806 echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2807 fi
2811 cat >>$outfile <<_______EOF
2812 #ifndef G_DISABLE_DEPRECATED
2813 #define g_ATEXIT(proc) (atexit (proc))
2814 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2815 #endif
2816 $glib_defines
2817 $glib_os
2818 $glib_static_compilation
2820 $glib_vacopy
2822 _______EOF
2824 if test x$g_have_iso_c_varargs = xyes ; then
2825 cat >>$outfile <<_______EOF
2826 #ifndef __cplusplus
2827 # define G_HAVE_ISO_VARARGS 1
2828 #endif
2829 _______EOF
2830 fi
2831 if test x$g_have_iso_cxx_varargs = xyes ; then
2832 cat >>$outfile <<_______EOF
2833 #ifdef __cplusplus
2834 # define G_HAVE_ISO_VARARGS 1
2835 #endif
2836 _______EOF
2837 fi
2838 if test x$g_have_gnuc_varargs = xyes ; then
2839 cat >>$outfile <<_______EOF
2841 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2842 * is passed ISO vararg support is turned off, and there is no work
2843 * around to turn it on, so we unconditionally turn it off.
2844 */
2845 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2846 # undef G_HAVE_ISO_VARARGS
2847 #endif
2849 #define G_HAVE_GNUC_VARARGS 1
2850 _______EOF
2851 fi
2853 case x$g_stack_grows in
2854 xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2855 *) echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2856 esac
2859 echo >>$outfile
2860 if test x$g_have_eilseq = xno; then
2861 cat >>$outfile <<_______EOF
2862 #ifndef EILSEQ
2863 /* On some pre-C99 systems, EILSEQ is not defined.
2864 * The correspondence between this and the corresponding definition
2865 * in libiconv is essential.
2866 */
2867 # define EILSEQ ENOENT
2868 #endif
2869 _______EOF
2871 fi
2873 if test x$g_have_gnuc_visibility = xyes; then
2874 cat >>$outfile <<_______EOF
2875 #define G_HAVE_GNUC_VISIBILITY 1
2876 _______EOF
2877 fi
2878 cat >>$outfile <<_______EOF
2879 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2880 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2881 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2882 #define G_GNUC_INTERNAL __hidden
2883 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2884 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2885 #else
2886 #define G_GNUC_INTERNAL
2887 #endif
2888 _______EOF
2890 echo >>$outfile
2891 cat >>$outfile <<_______EOF
2892 #define G_THREADS_ENABLED
2893 #define G_THREADS_IMPL_$g_threads_impl_def
2894 _______EOF
2896 if test x"$g_memory_barrier_needed" != xno; then
2897 echo >>$outfile
2898 echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2899 fi
2900 if test x"$g_atomic_lock_free" = xyes; then
2901 echo >>$outfile
2902 echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
2903 fi
2904 echo >>$outfile
2905 g_bit_sizes="16 32 64"
2906 for bits in $g_bit_sizes; do
2907 cat >>$outfile <<_______EOF
2908 #define GINT${bits}_TO_${g_bs_native}(val) ((gint${bits}) (val))
2909 #define GUINT${bits}_TO_${g_bs_native}(val) ((guint${bits}) (val))
2910 #define GINT${bits}_TO_${g_bs_alien}(val) ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2911 #define GUINT${bits}_TO_${g_bs_alien}(val) (GUINT${bits}_SWAP_LE_BE (val))
2912 _______EOF
2913 done
2915 cat >>$outfile <<_______EOF
2916 #define GLONG_TO_LE(val) ((glong) GINT${glongbits}_TO_LE (val))
2917 #define GULONG_TO_LE(val) ((gulong) GUINT${glongbits}_TO_LE (val))
2918 #define GLONG_TO_BE(val) ((glong) GINT${glongbits}_TO_BE (val))
2919 #define GULONG_TO_BE(val) ((gulong) GUINT${glongbits}_TO_BE (val))
2920 #define GINT_TO_LE(val) ((gint) GINT${gintbits}_TO_LE (val))
2921 #define GUINT_TO_LE(val) ((guint) GUINT${gintbits}_TO_LE (val))
2922 #define GINT_TO_BE(val) ((gint) GINT${gintbits}_TO_BE (val))
2923 #define GUINT_TO_BE(val) ((guint) GUINT${gintbits}_TO_BE (val))
2924 #define GSIZE_TO_LE(val) ((gsize) GUINT${gsizebits}_TO_LE (val))
2925 #define GSSIZE_TO_LE(val) ((gssize) GINT${gssizebits}_TO_LE (val))
2926 #define GSIZE_TO_BE(val) ((gsize) GUINT${gsizebits}_TO_BE (val))
2927 #define GSSIZE_TO_BE(val) ((gssize) GINT${gssizebits}_TO_BE (val))
2928 #define G_BYTE_ORDER $g_byte_order
2930 #define GLIB_SYSDEF_POLLIN =$g_pollin
2931 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2932 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2933 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2934 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2935 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2937 #define G_MODULE_SUFFIX "$g_module_suffix"
2939 typedef $g_pid_type GPid;
2940 #define G_PID_FORMAT $g_pid_format
2942 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
2943 #define GLIB_SYSDEF_AF_INET $g_af_inet
2944 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
2946 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
2947 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
2948 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
2950 G_END_DECLS
2952 #endif /* __GLIBCONFIG_H__ */
2953 _______EOF
2956 if cmp -s $outfile glib/glibconfig.h; then
2957 AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
2958 rm -f $outfile
2959 else
2960 mv $outfile glib/glibconfig.h
2961 fi
2962 ],[
2964 # Note that if two cases are the same, case goes with the first one.
2965 # Note also that this is inside an AC_OUTPUT_COMMAND. We do not depend
2966 # on variable expansion in case labels. Look at the generated config.status
2967 # for a hint.
2969 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2970 glib_header_alloca_h="$ac_cv_working_alloca_h"
2971 else
2972 glib_header_alloca_h="$ac_cv_header_alloca_h"
2973 fi
2975 if test x$enable_included_printf = xyes ; then
2976 glib_included_printf=yes
2977 fi
2979 case 2 in
2980 $ac_cv_sizeof_short)
2981 gint16=short
2982 gint16_modifier='"h"'
2983 gint16_format='"hi"'
2984 guint16_format='"hu"'
2985 ;;
2986 $ac_cv_sizeof_int)
2987 gint16=int
2988 gint16_modifier='""'
2989 gint16_format='"i"'
2990 guint16_format='"u"'
2991 ;;
2992 esac
2993 case 4 in
2994 $ac_cv_sizeof_short)
2995 gint32=short
2996 gint32_modifier='"h"'
2997 gint32_format='"hi"'
2998 guint32_format='"hu"'
2999 ;;
3000 $ac_cv_sizeof_int)
3001 gint32=int
3002 gint32_modifier='""'
3003 gint32_format='"i"'
3004 guint32_format='"u"'
3005 ;;
3006 $ac_cv_sizeof_long)
3007 gint32=long
3008 gint32_modifier='"l"'
3009 gint32_format='"li"'
3010 guint32_format='"lu"'
3011 ;;
3012 esac
3013 case 8 in
3014 $ac_cv_sizeof_int)
3015 gint64=int
3016 gint64_modifier='""'
3017 gint64_format='"i"'
3018 guint64_format='"u"'
3019 glib_extension=
3020 gint64_constant='(val)'
3021 guint64_constant='(val)'
3022 ;;
3023 $ac_cv_sizeof_long)
3024 gint64=long
3025 gint64_modifier='"l"'
3026 gint64_format='"li"'
3027 guint64_format='"lu"'
3028 glib_extension=
3029 gint64_constant='(val##L)'
3030 guint64_constant='(val##UL)'
3031 ;;
3032 $ac_cv_sizeof_long_long)
3033 gint64='long long'
3034 if test -n "$glib_cv_long_long_format"; then
3035 gint64_modifier='"'$glib_cv_long_long_format'"'
3036 gint64_format='"'$glib_cv_long_long_format'i"'
3037 guint64_format='"'$glib_cv_long_long_format'u"'
3038 fi
3039 glib_extension='G_GNUC_EXTENSION '
3040 gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3041 guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3042 ;;
3043 $ac_cv_sizeof___int64)
3044 gint64='__int64'
3045 if test -n "$glib_cv_long_long_format"; then
3046 gint64_modifier='"'$glib_cv_long_long_format'"'
3047 gint64_format='"'$glib_cv_long_long_format'i"'
3048 guint64_format='"'$glib_cv_long_long_format'u"'
3049 fi
3050 glib_extension=
3051 gint64_constant='(val##i64)'
3052 guint64_constant='(val##ui64)'
3053 ;;
3054 esac
3055 glib_size_t=$ac_cv_sizeof_size_t
3056 glib_ssize_t=$ac_cv_sizeof_ssize_t
3057 glib_size_type_define="$glib_size_type"
3058 glib_ssize_type_define="$glib_ssize_type"
3059 glib_void_p=$ac_cv_sizeof_void_p
3060 glib_long=$ac_cv_sizeof_long
3062 case "$glib_size_type" in
3063 short)
3064 gsize_modifier='"h"'
3065 gsize_format='"hu"'
3066 glib_msize_type='SHRT'
3067 ;;
3068 int)
3069 gsize_modifier='""'
3070 gsize_format='"u"'
3071 glib_msize_type='INT'
3072 ;;
3073 long)
3074 gsize_modifier='"l"'
3075 gsize_format='"lu"'
3076 glib_msize_type='LONG'
3077 ;;
3078 "long long"|__int64)
3079 gsize_modifier='"I64"'
3080 gsize_format='"I64u"'
3081 glib_msize_type='INT64'
3082 ;;
3083 esac
3085 case "$glib_ssize_type" in
3086 short)
3087 gssize_modifier='"h"'
3088 gssize_format='"hi"'
3089 glib_mssize_type='SHRT'
3090 ;;
3091 int)
3092 gssize_modifier='""'
3093 gssize_format='"i"'
3094 glib_mssize_type='INT'
3095 ;;
3096 long)
3097 gssize_modifier='"l"'
3098 gssize_format='"li"'
3099 glib_mssize_type='LONG'
3100 ;;
3101 "long long"|__int64)
3102 gssize_modifier='"I64"'
3103 gssize_format='"I64i"'
3104 glib_mssize_type='INT64'
3105 ;;
3106 esac
3108 gintbits=`expr $ac_cv_sizeof_int \* 8`
3109 glongbits=`expr $ac_cv_sizeof_long \* 8`
3110 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3111 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3113 case $ac_cv_sizeof_void_p in
3114 $ac_cv_sizeof_int)
3115 glib_intptr_type_define=int
3116 gintptr_modifier='""'
3117 gintptr_format='"i"'
3118 guintptr_format='"u"'
3119 glib_gpi_cast='(gint)'
3120 glib_gpui_cast='(guint)'
3121 ;;
3122 $ac_cv_sizeof_long)
3123 glib_intptr_type_define=long
3124 gintptr_modifier='"l"'
3125 gintptr_format='"li"'
3126 guintptr_format='"lu"'
3127 glib_gpi_cast='(glong)'
3128 glib_gpui_cast='(gulong)'
3129 ;;
3130 $ac_cv_sizeof_long_long)
3131 glib_intptr_type_define='long long'
3132 gintptr_modifier='"I64"'
3133 gintptr_format='"I64i"'
3134 guintptr_format='"I64u"'
3135 glib_gpi_cast='(gint64)'
3136 glib_gpui_cast='(guint64)'
3137 ;;
3138 $ac_cv_sizeof___int64)
3139 glib_intptr_type_define=__int64
3140 gintptr_modifier='"I64"'
3141 gintptr_format='"I64i"'
3142 guintptr_format='"I64u"'
3143 glib_gpi_cast='(gint64)'
3144 glib_gpui_cast='(guint64)'
3145 ;;
3146 *)
3147 glib_unknown_void_p=yes
3148 ;;
3149 esac
3152 glib_defines="
3153 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3154 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3155 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3156 "
3158 case xyes in
3159 x$glib_cv_va_copy) glib_vacopy='#define G_VA_COPY va_copy' ;;
3160 x$glib_cv___va_copy) glib_vacopy='#define G_VA_COPY __va_copy' ;;
3161 *) glib_vacopy=''
3162 esac
3164 if test x$glib_cv_va_val_copy = xno; then
3165 glib_vacopy="\$glib_vacopy
3166 #define G_VA_COPY_AS_ARRAY 1"
3167 fi
3169 g_have_gnuc_varargs=$g_have_gnuc_varargs
3170 g_have_iso_c_varargs=$g_have_iso_c_varargs
3171 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3173 g_have_gnuc_visibility=$g_have_gnuc_visibility
3174 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3176 if test x$ac_cv_c_bigendian = xyes; then
3177 g_byte_order=G_BIG_ENDIAN
3178 g_bs_native=BE
3179 g_bs_alien=LE
3180 else
3181 g_byte_order=G_LITTLE_ENDIAN
3182 g_bs_native=LE
3183 g_bs_alien=BE
3184 fi
3186 g_pollin=$glib_cv_value_POLLIN
3187 g_pollout=$glib_cv_value_POLLOUT
3188 g_pollpri=$glib_cv_value_POLLPRI
3189 g_pollhup=$glib_cv_value_POLLHUP
3190 g_pollerr=$glib_cv_value_POLLERR
3191 g_pollnval=$glib_cv_value_POLLNVAL
3193 # If a family is not found on the system, define that family to
3194 # a negative value, picking a different one for each undefined
3195 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3196 # This is needed because glib-mkenums doesn't handle optional
3197 # values in enums, and thus we have to have all existing values
3198 # defined in the enum.
3199 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3200 g_af_unix=$glib_cv_value_AF_UNIX
3201 else
3202 g_af_unix=-1
3203 fi
3204 g_af_inet=$glib_cv_value_AF_INET
3205 g_af_inet6=$glib_cv_value_AF_INET6
3207 g_msg_peek=$glib_cv_value_MSG_PEEK
3208 g_msg_oob=$glib_cv_value_MSG_OOB
3209 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3211 g_stack_grows=$glib_cv_stack_grows
3213 g_have_eilseq=$have_eilseq
3215 g_threads_impl_def=$g_threads_impl
3217 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3218 g_memory_barrier_needed="$glib_memory_barrier_needed"
3219 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3221 g_module_suffix="$glib_gmodule_suffix"
3222 g_pid_type="$glib_pid_type"
3223 g_pid_format="\"$glib_pid_format\""
3224 g_pollfd_format="\"$glib_pollfd_format\""
3226 case $host in
3227 *-*-cygwin*)
3228 glib_os="#define G_OS_UNIX
3229 #define G_PLATFORM_WIN32
3230 #define G_WITH_CYGWIN"
3231 ;;
3232 *-*-mingw*)
3233 glib_os="#define G_OS_WIN32
3234 #define G_PLATFORM_WIN32"
3235 ;;
3236 *)
3237 glib_os="#define G_OS_UNIX"
3238 ;;
3239 esac
3240 glib_static_compilation=""
3241 if test x$glib_win32_static_compilation = xyes; then
3242 glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3243 #define GOBJECT_STATIC_COMPILATION 1"
3244 fi
3245 ])
3247 # Redo enough to get guint32 and guint64 for the alignment checks below
3248 case 4 in
3249 $ac_cv_sizeof_short)
3250 gint32=short
3251 ;;
3252 $ac_cv_sizeof_int)
3253 gint32=int
3254 ;;
3255 $ac_cv_sizeof_long)
3256 gint32=long
3257 ;;
3258 esac
3259 case 8 in
3260 $ac_cv_sizeof_int)
3261 gint64=int
3262 ;;
3263 $ac_cv_sizeof_long)
3264 gint64=long
3265 ;;
3266 $ac_cv_sizeof_long_long)
3267 gint64='long long'
3268 ;;
3269 $ac_cv_sizeof___int64)
3270 gint64='__int64'
3271 ;;
3272 esac
3274 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3275 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3276 typedef unsigned $gint32 guint32;])
3277 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3278 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3279 typedef unsigned $gint64 guint64;])
3280 AC_CHECK_TYPE([unsigned long])
3281 AC_CHECK_ALIGNOF([unsigned long])
3283 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3284 #
3285 # 1.2.14 required for dbus_message_set_serial
3286 PKG_CHECK_MODULES(DBUS1,
3287 dbus-1 >= 1.2.14,
3288 [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3289 have_dbus1=no)
3290 AC_SUBST(DBUS1_CFLAGS)
3291 AC_SUBST(DBUS1_LIBS)
3292 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3294 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3295 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3297 # Check whether MSVC toolset is explicitly set
3298 AM_CONDITIONAL(MSVC_BASE_NO_TOOLSET_SET, [test x$MSVC_BASE_TOOLSET = x])
3299 AM_CONDITIONAL(MSVC_NO_TOOLSET_SET, [test x$MSVC_TOOLSET = x])
3301 dnl
3302 dnl Check for -Bsymbolic-functions linker flag used to avoid
3303 dnl intra-library PLT jumps, if available.
3304 dnl
3306 AC_ARG_ENABLE(Bsymbolic,
3307 [AS_HELP_STRING([--disable-Bsymbolic],
3308 [avoid linking with -Bsymbolic])],,
3309 [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3310 AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3311 LDFLAGS=-Wl,-Bsymbolic-functions
3312 LIBS=
3313 AC_TRY_LINK([], [return 0],
3314 AC_MSG_RESULT(yes)
3315 enable_Bsymbolic=yes,
3316 AC_MSG_RESULT(no)
3317 enable_Bsymbolic=no)
3318 LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3320 if test "x${enable_Bsymbolic}" = "xyes"; then
3321 GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3322 fi
3324 dnl
3325 dnl Check for -z,nodelete linker flag: the type system assumes that
3326 dnl libgobject stays loaded for the lifetime of the process.
3327 dnl Since ld.bfd does not treat wrong -z options as fatal by default,
3328 dnl we also try to check for the --fatal-warnings linker flag if
3329 dnl auto-detecting.
3330 dnl
3332 AC_ARG_ENABLE([znodelete],
3333 [AS_HELP_STRING([--disable-znodelete],
3334 [avoid linking with -z,nodelete])],,
3335 [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3336 AC_MSG_CHECKING([for --fatal-warnings linker flag])
3337 LDFLAGS=-Wl,--fatal-warnings
3338 LIBS=
3339 AC_TRY_LINK([], [return 0],
3340 AC_MSG_RESULT(yes)
3341 [ldflags_fatal=-Wl,--fatal-warnings],
3342 AC_MSG_RESULT(no)
3343 ldflags_fatal=)
3344 AC_MSG_CHECKING([for -z,nodelete linker flag])
3345 LDFLAGS="$ldflags_fatal -Wl,-z,nodelete"
3346 AC_TRY_LINK([], [return 0],
3347 AC_MSG_RESULT(yes)
3348 enable_znodelete=yes,
3349 AC_MSG_RESULT(no)
3350 enable_znodelete=no)
3351 LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3353 if test "x${enable_znodelete}" = "xyes"; then
3354 GLIB_LINK_FLAGS="$GLIB_LINK_FLAGS -Wl,-z,nodelete"
3355 fi
3357 AC_SUBST(GLIB_LINK_FLAGS)
3359 dnl
3360 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3361 dnl visibility attributes for symbol export control
3362 dnl
3363 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3364 case "$host" in
3365 *-*-mingw*)
3366 dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3367 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3368 [defines how to decorate public symbols while building])
3369 CFLAGS="${CFLAGS} -fvisibility=hidden"
3370 ;;
3371 *)
3372 dnl on other compilers, check if we can do -fvisibility=hidden
3373 SAVED_CFLAGS="${CFLAGS}"
3374 CFLAGS="-fvisibility=hidden"
3375 AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3376 AC_TRY_COMPILE([], [return 0],
3377 AC_MSG_RESULT(yes)
3378 enable_fvisibility_hidden=yes,
3379 AC_MSG_RESULT(no)
3380 enable_fvisibility_hidden=no)
3381 CFLAGS="${SAVED_CFLAGS}"
3383 AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3384 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3385 [defines how to decorate public symbols while building])
3386 GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3387 ])
3388 ;;
3389 esac
3390 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3392 dnl Compiler flags; macro originates from systemd
3393 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3394 AC_ARG_ENABLE(compile-warnings,
3395 [AS_HELP_STRING([--disable-compile-warnings],
3396 [Don't use builtin compiler warnings])],,
3397 enable_compile_warnings=yes)
3398 AS_IF([test "x$enable_compile_warnings" != xno], [
3399 CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3400 -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3401 -Werror=missing-prototypes -Werror=implicit-function-declaration \
3402 -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3403 -Werror=format=2 -Werror=missing-include-dirs])
3404 ])
3405 AC_SUBST(GLIB_WARN_CFLAGS)
3407 #
3408 # Define variables corresponding to the correct include paths to use for
3409 # in-tree building.
3410 #
3412 # for config.h:
3413 config_h_INCLUDES='-I$(top_builddir)'
3414 AC_SUBST(config_h_INCLUDES)
3416 # glib:
3417 # config.h
3418 # $(top_builddir)/glib: for glibconfig.h
3419 # $(top_srcdir)/glib: for glib.h
3420 # $(top_srcdir): for everything
3421 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3422 AC_SUBST(glib_INCLUDES)
3424 # gobject:
3425 # same as glib
3426 gobject_INCLUDES='$(glib_INCLUDES)'
3427 AC_SUBST(gobject_INCLUDES)
3429 # gmodule:
3430 # glib includes
3431 # $(top_srcdir)/gmodule: for gmodule.h
3432 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3433 AC_SUBST(gmodule_INCLUDES)
3435 # gio:
3436 # same as gmodule
3437 gio_INCLUDES='$(gmodule_INCLUDES)'
3438 AC_SUBST(gio_INCLUDES)
3441 AC_CONFIG_FILES([
3442 glib-2.0.pc
3443 gmodule-2.0.pc
3444 gmodule-export-2.0.pc
3445 gmodule-no-export-2.0.pc
3446 gthread-2.0.pc
3447 gobject-2.0.pc
3448 gio-2.0.pc
3449 gio-unix-2.0.pc
3450 gio-windows-2.0.pc
3451 glib-zip
3452 glib-gettextize
3453 Makefile
3454 build/Makefile
3455 build/win32/Makefile
3456 build/win32/dirent/Makefile
3457 win32/Makefile
3458 win32/vs9/Makefile
3459 win32/vs9/glib-version-paths.vsprops
3460 win32/vs10/Makefile
3461 win32/vs10/glib-version-paths.props
3462 win32/vs11/Makefile
3463 win32/vs12/Makefile
3464 win32/vs14/Makefile
3465 win32/vs15/Makefile
3466 glib/Makefile
3467 glib/libcharset/Makefile
3468 glib/gnulib/Makefile
3469 glib/pcre/Makefile
3470 glib/update-pcre/Makefile
3471 glib/tests/Makefile
3472 gmodule/Makefile
3473 gmodule/gmoduleconf.h
3474 gobject/Makefile
3475 gobject/glib-genmarshal
3476 gobject/glib-mkenums
3477 gobject/tests/Makefile
3478 gthread/Makefile
3479 gio/Makefile
3480 gio/gdbus-2.0/codegen/Makefile
3481 gio/gdbus-2.0/codegen/config.py
3482 gio/gnetworking.h
3483 gio/xdgmime/Makefile
3484 gio/inotify/Makefile
3485 gio/kqueue/Makefile
3486 gio/fam/Makefile
3487 gio/win32/Makefile
3488 gio/tests/Makefile
3489 gio/tests/gdbus-object-manager-example/Makefile
3490 gio/tests/services/Makefile
3491 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3492 gio/tests/modules/Makefile
3493 po/Makefile.in
3494 docs/Makefile
3495 docs/reference/Makefile
3496 docs/reference/glib/Makefile
3497 docs/reference/glib/version.xml
3498 docs/reference/gobject/Makefile
3499 docs/reference/gobject/version.xml
3500 docs/reference/gio/Makefile
3501 docs/reference/gio/version.xml
3502 tests/Makefile
3503 tests/gobject/Makefile
3504 tests/refcount/Makefile
3505 m4macros/Makefile
3506 ])
3508 AC_CONFIG_COMMANDS([chmod-scripts],
3509 [chmod 0755 glib-zip
3510 chmod 0755 glib-gettextize
3511 chmod 0755 gobject/glib-genmarshal
3512 chmod 0755 gobject/glib-mkenums])
3514 # we want to invoke this macro solely so that the config.status script
3515 # and automake generated makefiles know about these generated files.
3516 # They are only needed to distcheck the package
3517 if false; then
3518 AC_CONFIG_FILES([
3519 INSTALL
3520 README
3521 config.h.win32
3522 glib/glibconfig.h.win32
3523 glib/glib.rc
3524 gmodule/gmodule.rc
3525 gobject/gobject.rc
3526 gthread/gthread.rc
3527 gio/gio.rc
3528 ])
3529 fi
3531 AC_OUTPUT