| blob | d102b13ec96a23c01afbdd339510ab5259ae3887 |
1 # Process this file with autoconf to produce a configure script.
2 AC_PREREQ([2.62])
4 dnl ***********************************
5 dnl *** include special GLib macros ***
6 dnl ***********************************
8 m4_define(glib_configure_ac)
10 #
11 # The following version number definitions apply to GLib, GModule, GObject,
12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
13 # all treated with the same interface and binary age.
14 #
15 # Making releases:
16 # glib_micro_version += 1;
17 # glib_interface_age += 1;
18 # glib_binary_age += 1;
19 # if any functions have been added, set glib_interface_age to 0.
20 # if backwards compatibility has been broken,
21 # set glib_binary_age _and_ glib_interface_age to 0.
22 #
23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
25 # for that version - see gversion.h for further information.
26 #
27 # in easier to understand terms:
28 #
29 # <mclasen> on the stable branch, interface age == micro
30 # <mclasen> on the unstable (ie master), interface age = 0
32 m4_define([glib_major_version], [2])
33 m4_define([glib_minor_version], [53])
34 m4_define([glib_micro_version], [0])
35 m4_define([glib_interface_age], [0])
36 m4_define([glib_binary_age],
37 [m4_eval(100 * glib_minor_version + glib_micro_version)])
38 m4_define([glib_version],
39 [glib_major_version.glib_minor_version.glib_micro_version])
41 # libtool version related macros
42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
43 m4_define([glib_lt_current],
44 [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
45 m4_define([glib_lt_revision], [glib_interface_age])
46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
47 m4_define([glib_lt_current_minus_age],
48 [m4_eval(glib_lt_current - glib_lt_age)])
50 # if the minor version number is odd, then we want debugging. Otherwise
51 # we only want minimal debugging support.
52 m4_define([glib_debug_default],
53 [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
56 AC_INIT(glib, [glib_version],
57 [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
59 AC_CONFIG_HEADERS([config.h])
60 AC_CONFIG_SRCDIR([glib/glib.h])
61 AC_CONFIG_MACRO_DIR([m4macros])
63 # Save this value here, since automake will set cflags later
64 cflags_set=${CFLAGS:+set}
66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
67 AM_MAINTAINER_MODE([enable])
69 # Support silent build rules. Disable
70 # by either passing --disable-silent-rules to configure or passing V=1
71 # to make
72 AM_SILENT_RULES([yes])
74 GLIB_MAJOR_VERSION=glib_major_version
75 GLIB_MINOR_VERSION=glib_minor_version
76 GLIB_MICRO_VERSION=glib_micro_version
77 GLIB_INTERFACE_AGE=glib_interface_age
78 GLIB_BINARY_AGE=glib_binary_age
79 GLIB_VERSION=glib_version
81 AC_SUBST(GLIB_MAJOR_VERSION)
82 AC_SUBST(GLIB_MINOR_VERSION)
83 AC_SUBST(GLIB_MICRO_VERSION)
84 AC_SUBST(GLIB_VERSION)
85 AC_SUBST(GLIB_INTERFACE_AGE)
86 AC_SUBST(GLIB_BINARY_AGE)
88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
89 [Define to the GLIB major version])
90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
91 [Define to the GLIB minor version])
92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
93 [Define to the GLIB micro version])
94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
95 [Define to the GLIB interface age])
96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
97 [Define to the GLIB binary age])
99 # libtool versioning
100 LT_RELEASE=glib_lt_release
101 LT_CURRENT=glib_lt_current
102 LT_REVISION=glib_lt_revision
103 LT_AGE=glib_lt_age
104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
105 AC_SUBST(LT_RELEASE)
106 AC_SUBST(LT_CURRENT)
107 AC_SUBST(LT_REVISION)
108 AC_SUBST(LT_AGE)
109 AC_SUBST(LT_CURRENT_MINUS_AGE)
111 dnl Checks for programs.
112 AC_PROG_CC
113 AC_PROG_CPP
114 AC_USE_SYSTEM_EXTENSIONS
116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
118 AC_CANONICAL_HOST
120 dnl
122 AC_MSG_CHECKING([for Win32])
123 LIB_EXE_MACHINE_FLAG=X86
124 case "$host" in
125 *-*-mingw*)
126 glib_native_win32=yes
127 glib_pid_type='void *'
128 glib_pid_format='p'
129 glib_pollfd_format='%#x'
130 glib_cv_stack_grows=no
131 # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
132 # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
133 # (Sorry, I don't know exactly what is the problem, but it is related to
134 # floating point formatting and decimal point vs. comma.)
135 # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
136 # rigorous enough to notice, though.
137 # So preset the autoconf cache variables.
138 ac_cv_func_vsnprintf_c99=no
139 ac_cv_func_snprintf_c99=no
140 case "$host" in
141 x86_64-*-*)
142 LIB_EXE_MACHINE_FLAG=X64
143 glib_pollfd_format='%#I64x'
144 ;;
145 esac
147 AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
148 ;;
149 *)
150 glib_native_win32=no
151 glib_pid_type=int
152 glib_pid_format='i'
153 glib_pollfd_format='%d'
154 ;;
155 esac
156 case $host in
157 *-*-linux*)
158 glib_os_linux=yes
159 ;;
160 esac
162 AC_MSG_RESULT([$glib_native_win32])
164 AC_MSG_CHECKING([for the Android])
165 case $host in
166 *android*)
167 glib_native_android="yes"
168 ;;
169 *)
170 glib_native_android="no"
171 ;;
172 esac
173 AC_MSG_RESULT([$glib_native_android])
175 AC_SUBST(LIB_EXE_MACHINE_FLAG)
177 glib_have_carbon=no
178 AC_MSG_CHECKING([for Mac OS X Carbon support])
179 AC_TRY_CPP([
180 #include <Carbon/Carbon.h>
181 #include <CoreServices/CoreServices.h>
182 ], glib_have_carbon=yes)
184 AC_MSG_RESULT([$glib_have_carbon])
186 glib_have_cocoa=no
187 AC_MSG_CHECKING([for Mac OS X Cocoa support])
188 AC_TRY_CPP([
189 #include <Cocoa/Cocoa.h>
190 #ifdef GNUSTEP_BASE_VERSION
191 #error "Detected GNUstep, not Cocoa"
192 #endif
193 ], glib_have_cocoa=yes)
195 AC_MSG_RESULT([$glib_have_cocoa])
197 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
198 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
199 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
200 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
201 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
202 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
204 AS_IF([test "$glib_native_win32" = "yes"], [
205 AC_CHECK_TOOL(WINDRES, windres, no)
206 if test "$WINDRES" = no; then
207 AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
208 fi
209 AC_CHECK_TOOL(NM, nm, no)
210 if test "$NM" = no; then
211 AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
212 fi
213 AC_CHECK_TOOL(RANLIB, ranlib, :)
214 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
215 AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
216 ])
217 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
219 AS_IF([test "x$glib_have_carbon" = "xyes"], [
220 AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
221 CARBON_LIBS="-Wl,-framework,Carbon"
222 LDFLAGS="$LDFLAGS $CARBON_LIBS"
223 ], [CARBON_LIBS=""])
225 AC_SUBST([CARBON_LIBS])
226 ac_cv_have_os_x_9_or_later="no"
227 AS_IF([test "x$glib_have_cocoa" = "xyes"], [
228 AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
229 COCOA_LIBS="-Wl,-framework,Foundation"
230 LDFLAGS="$LDFLAGS $COCOA_LIBS"
231 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
232 #include <AvailabilityMacros.h>
233 #if MAC_OS_X_VERSION_MIN_REQUIRED < 1090
234 #error Compiling for minimum OS X version before 10.9
235 #endif
236 ]])],[ac_cv_have_os_x_9_or_later="yes"])
237 ], [COCOA_LIBS=""])
238 AM_CONDITIONAL([MAC_OS_X_9], [test "x$ac_cv_have_os_x_9_or_later" = xyes])
239 AC_SUBST([COCOA_LIBS])
241 dnl declare --enable-* args and collect ac_help strings
242 AC_ARG_ENABLE(debug,
243 AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
244 [turn on debugging @<:@default=glib_debug_default@:>@]),,
245 enable_debug=glib_debug_default)
247 AC_ARG_ENABLE(gc_friendly,
248 [AS_HELP_STRING([--enable-gc-friendly],
249 [turn on garbage collector friendliness [default=no]])],,
250 [enable_gc_friendly=no])
251 AC_ARG_ENABLE(mem_pools,
252 [AS_HELP_STRING([--disable-mem-pools],
253 [disable all glib memory pools])],,
254 [disable_mem_pools=no])
255 AC_ARG_ENABLE(rebuilds,
256 [AS_HELP_STRING([--disable-rebuilds],
257 [disable all source autogeneration rules])],,
258 [enable_rebuilds=yes])
260 GLIB_TESTS
262 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
263 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
264 AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
265 AC_MSG_RESULT([yes])
266 ], [ AC_MSG_RESULT([no]) ])
268 AC_MSG_CHECKING([whether to disable memory pools])
269 AS_IF([test "x$disable_mem_pools" = "xno"], [
270 AC_MSG_RESULT([no])
271 ], [
272 AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
273 AC_MSG_RESULT([yes])
274 ])
276 dnl location to install runtime libraries, e.g. ../../lib to install
277 dnl to /lib if libdir is /usr/lib
278 AC_ARG_WITH(runtime-libdir,
279 [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
280 [install runtime libraries relative to libdir])],
281 [],
282 [with_runtime_libdir=""])
283 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
284 AC_SUBST(GLIB_RUNTIME_LIBDIR)
285 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
287 dnl Check for a working C++ compiler, but do not bail out, if none is found.
288 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
289 AC_LANG_SAVE
290 AC_LANG_CPLUSPLUS
291 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
292 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
293 AC_LANG_RESTORE
295 AM_PROG_CC_C_O
296 AC_PROG_INSTALL
298 AC_SYS_LARGEFILE
300 PKG_PROG_PKG_CONFIG(0.16)
302 if test "x$enable_debug" = "xyes"; then
303 if test "x$cflags_set" != "x" ; then
304 case " $CFLAGS " in
305 *[[\ \ ]]-g[[\ \ ]]*) ;;
306 *) CFLAGS="$CFLAGS -g" ;;
307 esac
308 fi
309 GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
310 else
311 GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
313 if test "x$enable_debug" = "xno"; then
314 GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
315 fi
316 fi
318 # Ensure MSVC-compatible struct packing convention is used when
319 # compiling for Win32 with gcc.
320 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
321 # gcc2 uses "-fnative-struct".
322 if test x"$glib_native_win32" = xyes; then
323 if test x"$GCC" = xyes; then
324 msnative_struct=''
325 AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
326 if test -z "$ac_cv_prog_CC"; then
327 our_gcc="$CC"
328 else
329 our_gcc="$ac_cv_prog_CC"
330 fi
331 case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
332 2.)
333 if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
334 msnative_struct='-fnative-struct'
335 fi
336 ;;
337 *)
338 if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
339 msnative_struct='-mms-bitfields'
340 fi
341 ;;
342 esac
343 if test x"$msnative_struct" = x ; then
344 AC_MSG_RESULT([no way])
345 AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
346 else
347 CFLAGS="$CFLAGS $msnative_struct"
348 AC_MSG_RESULT([${msnative_struct}])
349 fi
350 fi
351 fi
352 GLIB_EXTRA_CFLAGS="${msnative_struct}"
353 AC_SUBST(GLIB_EXTRA_CFLAGS)
355 AC_EXEEXT
357 # define a MAINT-like variable REBUILD which is set if Perl
358 # and awk are found, so autogenerated sources can be rebuilt
359 AC_PROG_AWK
360 AC_CHECK_PROGS(PERL, [perl5 perl])
361 # We would like indent, but don't require it.
362 AC_CHECK_PROG(INDENT, indent, indent)
363 REBUILD=\#
364 if test "x$enable_rebuilds" = "xyes" && \
365 test -n "$PERL" && \
366 $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
367 test -n "$AWK" ; then
368 REBUILD=
369 fi
370 AC_SUBST(REBUILD)
372 # Need full path to Perl for glib-mkenums
373 #
374 if test "x$PERL" != x ; then
375 AC_PATH_PROG(PERL_PATH, [$PERL])
376 fi
377 if test "x$PERL_PATH" = x ; then
378 PERL_PATH="/usr/bin/env perl"
379 fi
380 AC_SUBST(PERL_PATH)
382 # option to specify python interpreter to use; this just sets $PYTHON, so that
383 # we will fallback to reading $PYTHON if --with-python is not given, and
384 # python.m4 will get the expected input
385 AC_ARG_WITH(python,
386 AS_HELP_STRING([--with-python=PATH],
387 [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
388 [PYTHON="$withval"], [])
389 if test x"$PYTHON" = xyes; then
390 AC_MSG_ERROR([--with-python option requires a path or program argument])
391 fi
392 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
395 dnl ***********************
396 dnl *** Tests for iconv ***
397 dnl ***********************
398 dnl
399 dnl We do this before the gettext checks, to avoid distortion
401 dnl On Windows we use a native implementation
403 AS_IF([ test x"$glib_native_win32" = xyes], [
404 with_libiconv=native
405 ], [
406 AC_ARG_WITH(libiconv,
407 [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
408 [use the libiconv library])],,
409 [with_libiconv=maybe])
411 found_iconv=no
412 case $with_libiconv in
413 maybe)
414 # Check in the C library first
415 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
416 # Check if we have GNU libiconv
417 if test $found_iconv = "no"; then
418 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
419 fi
420 # Check if we have a iconv in -liconv, possibly from vendor
421 if test $found_iconv = "no"; then
422 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
423 fi
424 ;;
425 no)
426 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
427 ;;
428 gnu|yes)
429 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
430 ;;
431 native)
432 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
433 ;;
434 esac
436 if test "x$found_iconv" = "xno" ; then
437 AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
438 fi
439 ])
441 dnl
442 dnl zlib support
443 dnl
444 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
445 AS_IF([test "x$found_zlib" = "xno"], [
446 AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
447 if test "x$found_zlib" = "xno" ; then
448 AC_MSG_ERROR([*** Working zlib library and headers not found ***])
449 fi
450 ZLIB_LIBS='-lz'
451 AC_SUBST(ZLIB_LIBS)
452 ])
454 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
455 AC_SUBST(LIBFFI_CFLAGS)
456 AC_SUBST(LIBFFI_LIBS)
458 dnl
459 dnl gettext support
460 dnl
462 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
463 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
464 GLIB_GNU_GETTEXT
466 if test "$gt_cv_have_gettext" != "yes" ; then
467 AC_MSG_ERROR([
468 *** You must have either have gettext support in your C library, or use the
469 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
470 ])
471 fi
473 LIBS="$INTLLIBS $LIBS"
475 GETTEXT_PACKAGE=glib20
476 AC_SUBST(GETTEXT_PACKAGE)
477 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
478 [Define the gettext package to be used])
480 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
482 dnl
483 dnl Now we are done with gettext checks, figure out ICONV_LIBS
484 dnl
486 AS_IF([test x"$glib_native_win32" != xyes], [
487 if test x$with_libiconv != xno ; then
488 case " $INTLLIBS " in
489 *[[\ \ ]]-liconv[[\ \ ]]*) ;;
490 *) ICONV_LIBS="-liconv" ;;
491 esac
492 fi
493 ])
494 AC_SUBST(ICONV_LIBS)
496 case $with_libiconv in
497 gnu)
498 AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
499 ;;
500 native)
501 AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
502 ;;
503 esac
505 dnl Initialize libtool
506 LT_PREREQ([2.2])
507 LT_INIT([disable-static win32-dll])
508 dnl when using libtool 2.x create libtool early, because it's used in configure
509 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
512 AS_IF([test "$glib_native_win32" = "yes"], [
513 if test x$enable_static = xyes -a x$enable_shared = xyes; then
514 AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
515 fi
516 if test x$enable_static = xyes; then
517 glib_win32_static_compilation=yes
518 GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
519 #define GOBJECT_STATIC_COMPILATION 1"
520 AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
521 fi
522 ])
523 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
525 # Checks for library functions.
526 AC_FUNC_ALLOCA
527 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
528 AC_CHECK_FUNCS(timegm gmtime_r strerror_r)
530 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
531 [AC_TRY_LINK([#include <unistd.h>
532 extern int __libc_enable_secure;],
533 [return __libc_enable_secure;],
534 glib_cv_have_libc_enable_secure=yes,
535 glib_cv_have_libc_enable_secure=no)])
536 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
537 AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
538 [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
539 ])
541 AC_CHECK_SIZEOF(char)
542 AC_CHECK_SIZEOF(short)
543 AC_CHECK_SIZEOF(long)
544 AC_CHECK_SIZEOF(int)
545 AC_CHECK_SIZEOF(void *)
546 AC_CHECK_SIZEOF(long long)
547 AC_CHECK_SIZEOF(__int64)
549 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
550 [AC_TRY_LINK([#include <signal.h>
551 #include <sys/types.h>
552 sig_atomic_t val = 42;],
553 [return val == 42 ? 0 : 1],
554 ac_cv_type_sig_atomic_t=yes,
555 ac_cv_type_sig_atomic_t=no)])
556 if test x$ac_cv_type_sig_atomic_t = xyes; then
557 AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
558 [Define if you have the 'sig_atomic_t' type.])
559 fi
561 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
562 :
563 else
564 AC_MSG_ERROR([
565 *** GLib requires a 64 bit type. You might want to consider
566 *** using the GNU C compiler.
567 ])
568 fi
570 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
571 # long long is a 64 bit integer.
572 AC_MSG_CHECKING(for format to printf and scanf a guint64)
573 AC_CACHE_VAL(glib_cv_long_long_format,[
574 for format in ll q I64; do
575 AC_TRY_RUN([#include <stdio.h>
576 int main()
577 {
578 long long b, a = -0x3AFAFAFAFAFAFAFALL;
579 char buffer[1000];
580 sprintf (buffer, "%${format}u", a);
581 sscanf (buffer, "%${format}u", &b);
582 exit (b!=a);
583 }
584 ],
585 [glib_cv_long_long_format=${format}
586 break],
587 [],[:])
588 done])
589 AS_IF([ test -n "$glib_cv_long_long_format"], [
590 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
591 AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
592 if test x"$glib_cv_long_long_format" = xI64; then
593 AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
594 fi
595 ], [AC_MSG_RESULT(none)])
596 ],[ test x$ac_cv_sizeof___int64 = x8], [
597 # __int64 is a 64 bit integer.
598 AC_MSG_CHECKING(for format to printf and scanf a guint64)
599 # We know this is MSVCRT.DLL, and what the formats are
600 glib_cv_long_long_format=I64
601 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
602 AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
603 AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
604 ])
606 AC_C_CONST
608 dnl
609 dnl check in which direction the stack grows
610 dnl
611 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
612 AC_TRY_RUN([
613 volatile int *a = 0, *b = 0;
614 void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
615 int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
616 ],
617 glib_cv_stack_grows=yes
618 ,
619 glib_cv_stack_grows=no
620 ,)
621 ])
623 # check for flavours of varargs macros
624 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
625 AC_TRY_COMPILE([],[
626 int a(int p1, int p2, int p3);
627 #define call_a(...) a(1,__VA_ARGS__)
628 call_a(2,3);
629 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
630 AC_MSG_RESULT($g_have_iso_c_varargs)
632 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
633 AS_IF([test "$CXX" = ""], [
634 dnl No C++ compiler
635 g_have_iso_cxx_varargs=no
636 else
637 AC_LANG_CPLUSPLUS
638 AC_TRY_COMPILE([],[
639 int a(int p1, int p2, int p3);
640 #define call_a(...) a(1,__VA_ARGS__)
641 call_a(2,3);
642 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
643 AC_LANG_C
644 ])
645 AC_MSG_RESULT($g_have_iso_cxx_varargs)
647 AC_MSG_CHECKING(for GNUC varargs macros)
648 AC_TRY_COMPILE([],[
649 int a(int p1, int p2, int p3);
650 #define call_a(params...) a(1,params)
651 call_a(2,3);
652 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
653 AC_MSG_RESULT($g_have_gnuc_varargs)
655 # check for GNUC visibility support
656 AC_MSG_CHECKING(for GNUC visibility attribute)
657 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
658 void
659 __attribute__ ((visibility ("hidden")))
660 f_hidden (void)
661 {
662 }
663 void
664 __attribute__ ((visibility ("internal")))
665 f_internal (void)
666 {
667 }
668 void
669 __attribute__ ((visibility ("protected")))
670 f_protected (void)
671 {
672 }
673 void
674 __attribute__ ((visibility ("default")))
675 f_default (void)
676 {
677 }
678 int main (void)
679 {
680 f_hidden();
681 f_internal();
682 f_protected();
683 f_default();
684 return 0;
685 }
686 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
687 AC_MSG_RESULT($g_have_gnuc_visibility)
688 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
690 AC_MSG_CHECKING([whether using Sun Studio C compiler])
691 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
692 #else
693 # include "error: this is not Sun Studio."
694 #endif
695 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
696 AC_MSG_RESULT($g_have_sunstudio_visibility)
697 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
699 # check for bytesex stuff
700 AC_C_BIGENDIAN
701 if test x$ac_cv_c_bigendian = xuniversal ; then
702 AC_MSG_ERROR([Universal builds not supported: see https://bugs.gnome.org/742548])
703 fi
706 # check for header files
707 AC_CHECK_HEADERS([sys/param.h sys/resource.h mach/mach_time.h])
708 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
709 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
710 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
711 AC_CHECK_HEADERS([linux/magic.h])
712 AC_CHECK_HEADERS([termios.h])
714 # Some versions of MSC lack these
715 AC_CHECK_HEADERS([dirent.h sys/time.h])
717 # We don't care about this, but we need to keep including it in
718 # glibconfig.h for backward compatibility
719 AC_CHECK_HEADERS([values.h])
721 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
722 [#if HAVE_SYS_PARAM_H
723 #include <sys/param.h>
724 #endif
725 ])
726 AC_CHECK_FUNCS(sysctlbyname)
728 AC_HEADER_MAJOR
729 AC_CHECK_HEADERS([xlocale.h])
731 # check for structure fields
732 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec, struct stat.st_birthtime, struct stat.st_birthtimensec, struct stat.st_birthtim, struct stat.st_birthtim.tv_nsec])
733 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
734 #include <sys/stat.h>
735 #ifdef G_OS_UNIX
736 #include <unistd.h>
737 #endif
738 #ifdef HAVE_SYS_STATFS_H
739 #include <sys/statfs.h>
740 #endif
741 #ifdef HAVE_SYS_PARAM_H
742 #include <sys/param.h>
743 #endif
744 #ifdef HAVE_SYS_MOUNT_H
745 #include <sys/mount.h>
746 #endif])
747 # struct statvfs.f_basetype is available on Solaris but not for Linux.
748 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
749 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
750 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
752 AC_STRUCT_DIRENT_D_TYPE
754 # Checks for libcharset
755 AM_LANGINFO_CODESET
756 gl_GLIBC21
758 # check additional type sizes
759 AC_CHECK_SIZEOF(size_t)
761 dnl Try to figure out whether gsize should be long or int
762 AC_MSG_CHECKING([for the appropriate definition for size_t])
764 case $ac_cv_sizeof_size_t in
765 $ac_cv_sizeof_short)
766 glib_size_type=short
767 ;;
768 $ac_cv_sizeof_int)
769 glib_size_type=int
770 ;;
771 $ac_cv_sizeof_long)
772 glib_size_type=long
773 ;;
774 $ac_cv_sizeof_long_long)
775 glib_size_type='long long'
776 ;;
777 $ac_cv_sizeof__int64)
778 glib_size_type='__int64'
779 ;;
780 *) AC_MSG_ERROR([No type matching size_t in size])
781 ;;
782 esac
784 dnl If int/long are the same size, we see which one produces
785 dnl warnings when used in the location as size_t. (This matters
786 dnl on AIX with xlc)
787 dnl
788 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
789 test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
790 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
791 #if defined(_AIX) && !defined(__GNUC__)
792 #pragma options langlvl=stdc89
793 #endif
794 #include <stddef.h>
795 int main ()
796 {
797 size_t s = 1;
798 unsigned int *size_int = &s;
799 return (int)*size_int;
800 }
801 ]])],glib_size_type=int,
802 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
803 #if defined(_AIX) && !defined(__GNUC__)
804 #pragma options langlvl=stdc89
805 #endif
806 #include <stddef.h>
807 int main ()
808 {
809 size_t s = 1;
810 unsigned long *size_long = &s;
811 return (int)*size_long;
812 }
813 ]])],glib_size_type=long)])
814 ])
816 AC_MSG_RESULT(unsigned $glib_size_type)
818 AC_CHECK_SIZEOF(ssize_t)
820 dnl Try to figure out whether gssize should be long or int
821 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
823 case $ac_cv_sizeof_ssize_t in
824 $ac_cv_sizeof_short)
825 glib_ssize_type=short
826 ;;
827 $ac_cv_sizeof_int)
828 glib_ssize_type=int
829 ;;
830 $ac_cv_sizeof_long)
831 glib_ssize_type=long
832 ;;
833 $ac_cv_sizeof_long_long)
834 glib_ssize_type='long long'
835 ;;
836 $ac_cv_sizeof__int64)
837 glib_ssize_type='__int64'
838 ;;
839 *) AC_MSG_ERROR([No type matching ssize_t in size])
840 ;;
841 esac
843 dnl If int/long are the same size, we see which one produces
844 dnl warnings when used in the location as ssize_t. (This matters
845 dnl on Android where ssize_t is long and size_t is unsigned int)
846 dnl
847 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
848 test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
849 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
850 #if defined(_AIX) && !defined(__GNUC__)
851 #pragma options langlvl=stdc89
852 #endif
853 #include <stddef.h>
854 #ifdef HAVE_INTTYPES_H
855 # include <inttypes.h>
856 #endif
857 #ifdef HAVE_STDINT_H
858 # include <stdint.h>
859 #endif
860 #include <sys/types.h>
861 int main ()
862 {
863 ssize_t s = 1;
864 int *size_int = &s;
865 return (int)*size_int;
866 }
867 ]])],glib_ssize_type=int,
868 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
869 #if defined(_AIX) && !defined(__GNUC__)
870 #pragma options langlvl=stdc89
871 #endif
872 #include <stddef.h>
873 #ifdef HAVE_INTTYPES_H
874 # include <inttypes.h>
875 #endif
876 #ifdef HAVE_STDINT_H
877 # include <stdint.h>
878 #endif
879 #include <sys/types.h>
880 int main ()
881 {
882 ssize_t s = 1;
883 long *size_long = &s;
884 return (int)*size_long;
885 }
886 ]])],glib_ssize_type=long)])
887 ])
889 AC_MSG_RESULT($glib_ssize_type)
891 # Check for some functions
892 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
893 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
894 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
895 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
896 AC_CHECK_FUNCS(splice)
897 AC_CHECK_FUNCS(prlimit)
899 # To avoid finding a compatibility unusable statfs, which typically
900 # successfully compiles, but warns to use the newer statvfs interface:
901 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
902 AS_IF([test $ac_cv_header_sys_statfs_h = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
904 AC_MSG_CHECKING([whether to use statfs or statvfs])
905 # Some systems have both statfs and statvfs, pick the most "native" for these
906 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
907 [
908 # on solaris and irix, statfs doesn't even have the f_bavail field
909 AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
910 [ac_cv_func_statfs=no],
911 # else, at least on linux, statfs is the actual syscall
912 [ac_cv_func_statvfs=no])
913 ])
915 AS_IF([test x$ac_cv_func_statfs = xyes],
916 [
917 AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
918 AC_MSG_RESULT([statfs])
919 ],
920 [test x$ac_cv_func_statvfs = xyes],
921 [
922 AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
923 AC_MSG_RESULT([statvfs])
924 ],
925 [ AC_MSG_RESULT([neither])])
927 AC_CHECK_HEADERS(crt_externs.h)
928 AC_CHECK_FUNCS(_NSGetEnviron)
930 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
932 # Internet address families
933 if test $glib_native_win32 = yes; then
934 glib_inet_includes=["
935 #include <winsock2.h>
936 "]
937 else
938 glib_inet_includes=["
939 #include <sys/types.h>
940 #include <sys/socket.h>
941 "]
942 fi
944 glib_failed=false
945 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
946 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
947 # winsock defines this even though it doesn't support it
948 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
949 if $glib_failed ; then
950 AC_MSG_ERROR([Could not determine values for AF_INET* constants])
951 fi
953 glib_failed=false
954 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
955 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
956 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
957 if $glib_failed ; then
958 AC_MSG_ERROR([Could not determine values for MSG_* constants])
959 fi
961 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex if_indextoname sendmmsg recvmmsg)
963 AS_IF([test $glib_native_win32 = yes], [
964 # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
965 # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
966 # they aren't present at run-time (on Windows 2000).
967 AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
968 AC_SUBST(WSPIAPI_INCLUDE)
969 ], [
970 # Android does not have C_IN in public headers, we define it wherever necessary
971 AS_IF([test $glib_native_android != yes], [
972 AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
973 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
974 #include <arpa/nameser.h>],
975 [int qclass = C_IN;])],
976 [AC_MSG_RESULT([no])],
977 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
978 #include <arpa/nameser.h>
979 #include <arpa/nameser_compat.h>],
980 [int qclass = C_IN;])],
981 [AC_MSG_RESULT([yes])
982 NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
983 [AC_MSG_ERROR([could not compile test program either way])])])])
984 AC_SUBST(NAMESER_COMPAT_INCLUDE)
986 # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
987 NETWORK_LIBS=""
988 AC_MSG_CHECKING([for res_query])
989 AC_TRY_LINK([#include <sys/types.h>
990 #include <netinet/in.h>
991 #include <arpa/nameser.h>
992 #include <resolv.h>
993 ],[
994 res_query("test", 0, 0, (void *)0, 0);
995 ],[AC_MSG_RESULT([yes])],
996 [save_libs="$LIBS"
997 LIBS="-lresolv $LIBS"
998 AC_TRY_LINK([#include <sys/types.h>
999 #include <netinet/in.h>
1000 #include <arpa/nameser.h>
1001 #include <resolv.h>
1002 ],[
1003 res_query("test", 0, 0, (void *)0, 0);
1004 ],[AC_MSG_RESULT([in -lresolv])
1005 NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1006 [LIBS="-lbind $save_libs"
1007 AC_TRY_LINK([#include <resolv.h>],
1008 [res_query("test", 0, 0, (void *)0, 0);],
1009 [AC_MSG_RESULT([in -lbind])
1010 NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1011 [AC_MSG_ERROR(not found)])])
1012 LIBS="$save_libs"])
1013 AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1014 [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1015 [AC_MSG_ERROR(Could not find socket())]))
1016 save_libs="$LIBS"
1017 LIBS="$LIBS $NETWORK_LIBS"
1018 AC_MSG_CHECKING([for res_init])
1019 AC_TRY_LINK([#include <sys/types.h>
1020 #include <netinet/in.h>
1021 #include <arpa/nameser.h>
1022 #include <resolv.h>
1023 ],[
1024 res_init();
1025 ],[AC_MSG_RESULT([yes])
1026 AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1027 ],[AC_MSG_RESULT([no])])
1028 LIBS="$save_libs"
1029 ])
1030 AC_SUBST(NETWORK_LIBS)
1032 AC_CHECK_HEADER([linux/netlink.h],
1033 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1034 [#include <sys/socket.h>])
1035 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1037 AC_CHECK_TYPE([struct ip_mreqn], [
1038 AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1039 [#include <netinet/in.h>])
1041 case $host in
1042 *-*-solaris* )
1043 AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1044 AC_DEFINE(_XOPEN_SOURCE, 2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1045 AC_DEFINE(__EXTENSIONS__, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1046 ;;
1047 esac
1049 dnl
1050 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1051 dnl
1052 AS_IF([test "$ac_cv_func_statfs" = yes], [
1053 AC_MSG_CHECKING([number of arguments to statfs()])
1054 AC_TRY_COMPILE([#include <unistd.h>
1055 #ifdef HAVE_SYS_PARAM_H
1056 #include <sys/param.h>
1057 #endif
1058 #ifdef HAVE_SYS_VFS_H
1059 #include <sys/vfs.h>
1060 #endif
1061 #ifdef HAVE_SYS_MOUNT_H
1062 #include <sys/mount.h>
1063 #endif
1064 #ifdef HAVE_SYS_STATFS_H
1065 #include <sys/statfs.h>
1066 #endif], [struct statfs st;
1067 statfs("/", &st);],[
1068 AC_MSG_RESULT([2])
1069 AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1070 AC_TRY_COMPILE([#include <unistd.h>
1071 #ifdef HAVE_SYS_PARAM_H
1072 #include <sys/param.h>
1073 #endif
1074 #ifdef HAVE_SYS_VFS_H
1075 #include <sys/vfs.h>
1076 #endif
1077 #ifdef HAVE_SYS_MOUNT_H
1078 #include <sys/mount.h>
1079 #endif
1080 #ifdef HAVE_SYS_STATFS_H
1081 #include <sys/statfs.h>
1082 #endif], [struct statfs st;
1083 statfs("/", &st, sizeof (st), 0);],[
1084 AC_MSG_RESULT([4])
1085 AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1086 AC_MSG_RESULT(unknown)
1087 AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1088 ])
1090 dnl
1091 dnl open takes O_DIRECTORY as an option
1092 dnl
1093 AC_MSG_CHECKING([open() option O_DIRECTORY])
1094 AC_TRY_COMPILE([#include <fcntl.h>
1095 #include <sys/types.h>
1096 #include <sys/stat.h>],
1097 [open(0, O_DIRECTORY, 0);],[
1098 AC_MSG_RESULT([yes])
1099 AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1100 AC_MSG_RESULT([no])])
1102 #
1103 # Check whether to use an included printf
1104 #
1105 AC_FUNC_VSNPRINTF_C99
1106 AC_FUNC_PRINTF_UNIX98
1108 AC_ARG_ENABLE(included-printf,
1109 [AS_HELP_STRING([--enable-included-printf],
1110 [use included printf [default=auto]])],
1111 enable_included_printf="$enableval")
1113 need_included_printf=no
1114 if test "x$enable_included_printf" = "xyes" ; then
1115 need_included_printf=yes
1116 fi
1117 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1118 need_included_printf=yes
1119 fi
1120 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1121 need_included_printf=yes
1122 fi
1123 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1124 test -z "$glib_cv_long_long_format" ; then
1125 need_included_printf=yes
1126 fi
1128 if test "x$enable_included_printf" = "xno" &&
1129 test "x$need_included_printf" = "xyes" ; then
1130 AC_MSG_ERROR([
1131 *** Your C library's printf doesn't appear to have the features that
1132 *** GLib needs, but you specified --enable-included-printf=no.])
1133 fi
1135 enable_included_printf=$need_included_printf
1137 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1138 AS_IF([test "$enable_included_printf" != "yes"], [
1139 AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1140 ], [
1141 if test -z "$glib_cv_long_long_format" ; then
1142 glib_cv_long_long_format="ll"
1143 fi
1144 AC_DEFINE(HAVE_VASPRINTF,1)
1145 ])
1147 # Checks needed for gnulib vasnprintf
1148 bh_C_SIGNED
1149 jm_AC_TYPE_LONG_LONG
1150 gt_TYPE_LONGDOUBLE
1151 gt_TYPE_WCHAR_T
1152 gt_TYPE_WINT_T
1153 AC_TYPE_SIZE_T
1154 AC_CHECK_TYPES(ptrdiff_t)
1155 jm_AC_TYPE_INTMAX_T
1156 AC_CHECK_FUNCS([snprintf strnlen wcslen wcsnlen mbrtowc wcrtomb])
1157 AC_FUNC_SNPRINTF_C99
1159 # Check if <sys/select.h> needs to be included for fd_set
1160 AC_MSG_CHECKING([for fd_set])
1161 AC_TRY_COMPILE([#include <sys/types.h>],
1162 [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1163 AS_IF([test "$gtk_ok" = "yes"], [
1164 AC_MSG_RESULT([yes, found in sys/types.h])
1165 ], [
1166 AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1167 if test "$gtk_ok" = "yes"; then
1168 # *** FIXME: give it a different name
1169 AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1170 AC_MSG_RESULT([yes, found in sys/select.h])
1171 else
1172 AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1173 AC_MSG_RESULT(no)
1174 fi
1175 ])
1177 dnl Check for nl_langinfo and CODESET
1178 AC_LANG_SAVE
1179 AC_LANG_C
1180 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1181 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1182 [char *codeset = nl_langinfo (CODESET);])],
1183 [glib_cv_langinfo_codeset=yes],
1184 [glib_cv_langinfo_codeset=no])])
1185 if test x$glib_cv_langinfo_codeset = xyes; then
1186 AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1187 fi
1189 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1190 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1191 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1192 [char *str;
1193 str = nl_langinfo (PM_STR);
1194 str = nl_langinfo (D_T_FMT);
1195 str = nl_langinfo (D_FMT);
1196 str = nl_langinfo (T_FMT);
1197 str = nl_langinfo (T_FMT_AMPM);
1198 str = nl_langinfo (MON_1);
1199 str = nl_langinfo (ABMON_12);
1200 str = nl_langinfo (DAY_1);
1201 str = nl_langinfo (ABDAY_7);])],
1202 [glib_cv_langinfo_time=yes],
1203 [glib_cv_langinfo_time=no])])
1204 if test x$glib_cv_langinfo_time = xyes; then
1205 AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1206 fi
1208 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1209 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1210 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1211 [char *str;
1212 str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1213 str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1214 str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1215 str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1216 str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1217 str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1218 str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1219 str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1220 str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1221 str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1222 [glib_cv_langinfo_outdigit=yes],
1223 [glib_cv_langinfo_outdigit=no])])
1224 if test x$glib_cv_langinfo_outdigit = xyes; then
1225 AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1226 fi
1227 AC_LANG_RESTORE
1229 dnl ****************************************
1230 dnl *** posix_memalign ***
1231 dnl ****************************************
1232 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1233 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1234 glib_cv_compliant_posix_memalign=0
1235 if test "$ac_cv_func_posix_memalign" = "yes" ; then
1236 AC_TRY_RUN([
1237 #define _XOPEN_SOURCE 600
1238 #include <stdlib.h> /* posix_memalign() should be defined here */
1239 /* some systems break if #include <malloc.h> used */
1240 static void test_memalign (size_t boundary, size_t size) {
1241 void *mem = 0;
1242 if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1243 exit (1);
1244 else
1245 free (mem);
1246 }
1247 int main() {
1248 test_memalign ( 128, 128 - 2 * sizeof (void*));
1249 test_memalign ( 256, 256 - 2 * sizeof (void*));
1250 test_memalign ( 512, 512 - 2 * sizeof (void*));
1251 test_memalign ( 1024, 1024 - 2 * sizeof (void*));
1252 test_memalign ( 2048, 2048 - 2 * sizeof (void*));
1253 test_memalign ( 4096, 4096 - 2 * sizeof (void*));
1254 test_memalign ( 8192, 8192 - 2 * sizeof (void*));
1255 test_memalign (16384, 16384 - 2 * sizeof (void*));
1256 test_memalign (32768, 32768 - 2 * sizeof (void*));
1257 exit (0); /* success */
1258 }
1259 ],
1260 [glib_cv_compliant_posix_memalign=1], [], [:])
1261 :
1262 fi
1263 ])
1264 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1265 AC_MSG_RESULT(yes)
1266 AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1267 ], [
1268 AC_MSG_RESULT(no)
1269 ])
1272 dnl ****************************************
1273 dnl *** strlcpy/strlcat ***
1274 dnl ****************************************
1275 # Check for strlcpy
1276 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1277 AC_TRY_RUN([#include <stdlib.h>
1278 #include <string.h>
1279 int main() {
1280 char p[10];
1281 (void) strlcpy (p, "hi", 10);
1282 if (strlcat (p, "bye", 0) != 3)
1283 return 1;
1284 return 0;
1285 }], glib_cv_have_strlcpy=yes,
1286 glib_cv_have_strlcpy=no,
1287 glib_cv_have_strlcpy=no)])
1288 if test "$glib_cv_have_strlcpy" = "yes"; then
1289 AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1290 fi
1293 dnl **********************
1294 dnl *** va_copy checks ***
1295 dnl **********************
1296 dnl we currently check for all three va_copy possibilities, so we get
1297 dnl all results in config.log for bug reports.
1298 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1299 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1300 #include <stdlib.h>
1301 void f (int i, ...) {
1302 va_list args1, args2;
1303 va_start (args1, i);
1304 va_copy (args2, args1);
1305 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1306 exit (1);
1307 va_end (args1); va_end (args2);
1308 }
1309 int main() {
1310 f (0, 42);
1311 return 0;
1312 }]])],
1313 [glib_cv_va_copy=yes],
1314 [glib_cv_va_copy=no])
1315 ])
1316 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1317 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1318 #include <stdlib.h>
1319 void f (int i, ...) {
1320 va_list args1, args2;
1321 va_start (args1, i);
1322 __va_copy (args2, args1);
1323 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1324 exit (1);
1325 va_end (args1); va_end (args2);
1326 }
1327 int main() {
1328 f (0, 42);
1329 return 0;
1330 }]])],
1331 [glib_cv___va_copy=yes],
1332 [glib_cv___va_copy=no])
1333 ])
1335 if test "x$glib_cv_va_copy" = "xyes"; then
1336 g_va_copy_func=va_copy
1337 else if test "x$glib_cv___va_copy" = "xyes"; then
1338 g_va_copy_func=__va_copy
1339 fi
1340 fi
1342 if test -n "$g_va_copy_func"; then
1343 AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1344 fi
1346 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1347 AC_TRY_RUN([#include <stdarg.h>
1348 #include <stdlib.h>
1349 void f (int i, ...) {
1350 va_list args1, args2;
1351 va_start (args1, i);
1352 args2 = args1;
1353 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1354 exit (1);
1355 va_end (args1); va_end (args2);
1356 }
1357 int main() {
1358 f (0, 42);
1359 return 0;
1360 }],
1361 [glib_cv_va_val_copy=yes],
1362 [glib_cv_va_val_copy=no],
1363 [glib_cv_va_val_copy=yes])
1364 ])
1366 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1367 AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1368 ])
1370 dnl ***********************
1371 dnl *** g_module checks ***
1372 dnl ***********************
1373 G_MODULE_LIBS=
1374 G_MODULE_LIBS_EXTRA=
1375 G_MODULE_PLUGIN_LIBS=
1376 if test x"$glib_native_win32" = xyes; then
1377 dnl No use for this on Win32
1378 G_MODULE_LDFLAGS=
1379 else
1380 export SED
1381 G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1382 fi
1383 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1384 G_MODULE_NEED_USCORE=0
1385 G_MODULE_BROKEN_RTLD_GLOBAL=0
1386 G_MODULE_HAVE_DLERROR=0
1387 dnl *** force native WIN32 shared lib loader
1388 if test -z "$G_MODULE_IMPL"; then
1389 case "$host" in
1390 *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1391 esac
1392 fi
1393 dnl *** force native AIX library loader
1394 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1395 if test -z "$G_MODULE_IMPL"; then
1396 case "$host" in
1397 *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1398 esac
1399 fi
1400 dnl *** dlopen() and dlsym() in system libraries
1401 AS_IF([ test -z "$G_MODULE_IMPL"], [
1402 AC_CHECK_FUNC(dlopen,
1403 [AC_CHECK_FUNC(dlsym,
1404 [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1405 [])
1406 ])
1407 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1408 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1409 AC_CHECK_FUNC(NSLinkModule,
1410 [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1411 G_MODULE_NEED_USCORE=1],
1412 [])
1413 ])
1414 dnl *** dlopen() and dlsym() in libdl
1415 AS_IF([ test -z "$G_MODULE_IMPL"], [
1416 AC_CHECK_LIB(dl, dlopen,
1417 [AC_CHECK_LIB(dl, dlsym,
1418 [G_MODULE_LIBS=-ldl
1419 G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1420 [])
1421 ])
1422 dnl *** additional checks for G_MODULE_IMPL_DL
1423 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1424 LIBS_orig="$LIBS"
1425 LDFLAGS_orig="$LDFLAGS"
1426 LIBS="$G_MODULE_LIBS $LIBS"
1427 LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1428 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1429 echo "void glib_plugin_test(void) { }" > plugin.c
1430 ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1431 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1432 ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1433 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1434 -shrext ".o" -avoid-version plugin.lo \
1435 -rpath /dont/care >/dev/null 2>&1
1436 eval `./libtool --config | grep ^objdir`
1437 AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1438 glib_cv_rtldglobal_broken,[
1439 AC_TRY_RUN([
1440 #include <dlfcn.h>
1441 #ifndef RTLD_GLOBAL
1442 # define RTLD_GLOBAL 0
1443 #endif
1444 #ifndef RTLD_LAZY
1445 # define RTLD_LAZY 0
1446 #endif
1447 int glib_plugin_test;
1448 int main () {
1449 void *handle, *global, *local;
1450 global = &glib_plugin_test;
1451 handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1452 if (!handle) return 0;
1453 local = dlsym (handle, "glib_plugin_test");
1454 return global == local;
1455 } ],
1456 [glib_cv_rtldglobal_broken=no],
1457 [glib_cv_rtldglobal_broken=yes],
1458 [glib_cv_rtldglobal_broken=no])
1459 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1460 rmdir ${objdir} 2>/dev/null
1461 ])
1462 if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1463 G_MODULE_BROKEN_RTLD_GLOBAL=1
1464 else
1465 G_MODULE_BROKEN_RTLD_GLOBAL=0
1466 fi
1467 dnl *** check whether we need preceeding underscores
1468 AC_CACHE_CHECK([for preceeding underscore in symbols],
1469 glib_cv_uscore,[
1470 AC_TRY_RUN([#include <dlfcn.h>
1471 int glib_underscore_test (void) { return 42; }
1472 int main() {
1473 void *f1 = (void*)0, *f2 = (void*)0, *handle;
1474 handle = dlopen ((void*)0, 0);
1475 if (handle) {
1476 f1 = dlsym (handle, "glib_underscore_test");
1477 f2 = dlsym (handle, "_glib_underscore_test");
1478 } return (!f2 || f1);
1479 }],
1480 [glib_cv_uscore=yes],
1481 [glib_cv_uscore=no],
1482 [])
1483 rm -f plugin.c plugin.$ac_objext plugin.lo
1484 ])
1485 GLIB_ASSERT_SET(glib_cv_uscore)
1486 if test "x$glib_cv_uscore" = "xyes"; then
1487 G_MODULE_NEED_USCORE=1
1488 else
1489 G_MODULE_NEED_USCORE=0
1490 fi
1492 LDFLAGS="$LDFLAGS_orig"
1493 dnl *** check for having dlerror()
1494 AC_CHECK_FUNC(dlerror,
1495 [G_MODULE_HAVE_DLERROR=1],
1496 [G_MODULE_HAVE_DLERROR=0])
1497 LIBS="$LIBS_orig"
1498 ])
1499 dnl *** done, have we got an implementation?
1500 if test -z "$G_MODULE_IMPL"; then
1501 G_MODULE_IMPL=0
1502 G_MODULE_SUPPORTED=false
1503 else
1504 G_MODULE_SUPPORTED=true
1505 fi
1507 AC_MSG_CHECKING(for the suffix of module shared libraries)
1508 export SED
1509 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1510 eval $shrext_cmds
1511 module=yes eval std_shrext=$shrext_cmds
1512 # chop the initial dot
1513 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1514 AC_MSG_RESULT(.$glib_gmodule_suffix)
1515 # any reason it may fail?
1516 if test "x$glib_gmodule_suffix" = x; then
1517 AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1518 fi
1520 AC_SUBST(G_MODULE_SUPPORTED)
1521 AC_SUBST(G_MODULE_IMPL)
1522 AC_SUBST(G_MODULE_LIBS)
1523 AC_SUBST(G_MODULE_LIBS_EXTRA)
1524 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1525 AC_SUBST(G_MODULE_LDFLAGS)
1526 AC_SUBST(G_MODULE_HAVE_DLERROR)
1527 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1528 AC_SUBST(G_MODULE_NEED_USCORE)
1529 AC_SUBST(GLIB_DEBUG_FLAGS)
1531 dnl **********************
1532 dnl *** g_spawn checks ***
1533 dnl **********************
1535 AC_MSG_CHECKING(for gspawn implementation)
1536 case "$host" in
1537 *-*-mingw*)
1538 GSPAWN=gspawn-win32.lo
1539 ;;
1540 *)
1541 GSPAWN=gspawn.lo
1542 ;;
1543 esac
1544 AC_MSG_RESULT($GSPAWN)
1545 AC_SUBST(GSPAWN)
1547 dnl *************************
1548 dnl *** GIOChannel checks ***
1549 dnl *************************
1551 AC_MSG_CHECKING(for GIOChannel implementation)
1552 case "$host" in
1553 *-*-mingw*)
1554 GIO=giowin32.lo
1555 ;;
1556 *)
1557 GIO=giounix.lo
1558 ;;
1559 esac
1560 AC_MSG_RESULT($GIO)
1561 AC_SUBST(GIO)
1563 dnl *********************************
1564 dnl *** Directory for GIO modules ***
1565 dnl *********************************
1567 AC_ARG_WITH(gio-module-dir,
1568 [AS_HELP_STRING([--with-gio-module-dir=DIR],
1569 [load gio modules from this directory [LIBDIR/gio/modules]])],
1570 [],
1571 [with_gio_module_dir='${libdir}/gio/modules'])
1572 GIO_MODULE_DIR=$with_gio_module_dir
1573 AC_SUBST(GIO_MODULE_DIR)
1575 dnl **********************************
1576 dnl *** Check for libselinux (GIO) ***
1577 dnl **********************************
1578 AC_ARG_ENABLE(selinux,
1579 AS_HELP_STRING([--disable-selinux],
1580 [build without selinux support]))
1581 msg_selinux=no
1582 SELINUX_LIBS=
1583 AS_IF([ test "x$enable_selinux" != "xno"], [
1585 AC_CHECK_LIB(selinux, is_selinux_enabled,
1586 [AC_CHECK_HEADERS(selinux/selinux.h,
1587 [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1588 [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1589 SELINUX_LIBS="-lselinux"
1590 msg_selinux=yes])
1591 ])
1592 ])
1593 ])
1594 AC_SUBST(SELINUX_LIBS)
1596 dnl *****************************
1597 dnl ** Check for inotify (GIO) **
1598 dnl *****************************
1599 inotify_support=no
1600 AC_CHECK_HEADERS([sys/inotify.h],
1601 [
1602 AC_CHECK_FUNCS(inotify_init1, [inotify_support=yes], [inotify_support=no])
1603 ])
1605 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1607 dnl ****************************
1608 dnl ** Check for kqueue (GIO) **
1609 dnl ****************************
1610 kqueue_support=no
1611 AC_CHECK_HEADERS([sys/event.h],
1612 [
1613 AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1614 ])
1616 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1618 dnl ****************************
1619 dnl *** Checks for FAM (GIO) ***
1620 dnl ****************************
1622 should_disable_fam=no
1624 AC_ARG_ENABLE(fam,
1625 AS_HELP_STRING([--disable-fam],
1626 [don't use fam for file system monitoring]),
1627 [
1628 if test "x$enable_fam" = "xno"; then
1629 should_disable_fam=yes
1630 fi
1631 ]
1632 )
1633 fam_support=no
1634 FAM_LIBS=
1635 if test "x$should_disable_fam" = "xno"; then
1636 AC_CHECK_LIB(fam, FAMOpen,
1637 [AC_CHECK_HEADERS(fam.h,
1638 [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1639 AC_CHECK_LIB(fam, FAMNoExists,
1640 AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1641 FAM_LIBS="-lfam"]
1642 fam_support=yes,
1643 AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1644 AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1645 AC_SUBST(FAM_LIBS)
1646 fi
1647 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1650 dnl *****************************
1651 dnl *** Check for xattr (GIO) ***
1652 dnl *****************************
1653 AC_ARG_ENABLE(xattr,
1654 AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1655 msg_xattr=no
1656 XATTR_LIBS=
1657 AS_IF([ test "x$enable_xattr" != "xno"], [
1659 dnl either glibc or libattr can provide xattr support
1661 dnl for both of them, we check for getxattr being in
1662 dnl the library and a valid xattr header.
1664 dnl try glibc
1665 AC_CHECK_LIB(c, getxattr,
1666 [AC_CHECK_HEADERS(sys/xattr.h,
1667 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1668 msg_xattr=yes])
1669 ])
1671 AS_IF([ test "x$msg_xattr" != "xyes"], [
1672 dnl failure. try libattr
1673 AC_CHECK_LIB(attr, getxattr,
1674 [AC_CHECK_HEADERS(attr/xattr.h,
1675 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1676 XATTR_LIBS="-lattr"
1677 msg_xattr=yes])
1678 ])
1679 ])
1681 AS_IF([ test "x$msg_xattr" = "xyes"], [
1682 AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1683 AC_TRY_COMPILE([
1684 #include <stdio.h>
1685 #ifdef HAVE_SYS_TYPES_H
1686 #include <sys/types.h>
1687 #endif
1688 #ifdef HAVE_SYS_XATTR_H
1689 #include <sys/xattr.h>
1690 #elif HAVE_ATTR_XATTR_H
1691 #include <attr/xattr.h>
1692 #endif
1693 ],
1694 [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1695 [
1696 AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1697 AC_MSG_RESULT([yes])
1698 ],
1699 [AC_MSG_RESULT([no])]
1700 )
1701 ])
1702 ])
1703 AC_SUBST(XATTR_LIBS)
1705 dnl ************************
1706 dnl *** check for libelf ***
1707 dnl ************************
1708 AC_ARG_ENABLE(libelf,
1709 AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1710 AS_IF([ test "x$enable_libelf" != "xno"],[
1711 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1712 AS_IF([ test $have_libelf = maybe ], [
1713 glib_save_LIBS=$LIBS
1714 AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1715 AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1716 AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1717 AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1718 LIBS=$glib_save_LIBS
1720 if test $have_libelf != no; then
1721 LIBELF_LIBS=-lelf
1722 have_libelf=yes
1723 fi
1724 ])
1725 ])
1727 if test x$have_libelf = xyes; then
1728 AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1729 fi
1731 dnl ************************
1732 dnl *** check for libmount ***
1733 dnl ************************
1735 dnl The fallback code doesn't really implement the same behaviors - e.g.
1736 dnl so on linux we want to require libmount unless specifically disabled
1737 dnl
1738 enable_libmount_default=${glib_os_linux:-no}
1739 AC_ARG_ENABLE(libmount,
1740 [AS_HELP_STRING([--enable-libmount],
1741 [build with libmount support [default for Linux]])],,
1742 [enable_libmount=$enable_libmount_default])
1743 AS_IF([ test "x$enable_libmount" = "xyes"],[
1744 PKG_CHECK_MODULES([LIBMOUNT], [mount >= 2.28], [have_libmount=yes], [have_libmount=maybe])
1745 AS_IF([ test $have_libmount = maybe ], [
1746 glib_save_LIBS=$LIBS
1747 AC_CHECK_HEADER([libmount/libmount.h], [:], [have_libmount=no])
1748 LIBS=$glib_save_LIBS
1750 if test $have_libmount != no; then
1751 LIBMOUNT_LIBS=-lmount
1752 have_libmount=yes
1753 fi
1754 ])
1755 if test $have_libmount = no ; then
1756 AC_MSG_ERROR([*** Could not find libmount])
1757 fi
1758 ])
1760 if test x$have_libmount = xyes; then
1761 AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available])
1762 fi
1763 AM_CONDITIONAL(HAVE_LIBMOUNT, [test x$have_libmount = xyes])
1765 dnl ****************************************
1766 dnl *** platform dependent source checks ***
1767 dnl ****************************************
1769 AC_MSG_CHECKING(for platform-dependent source)
1770 case "$host" in
1771 *-*-cygwin*|*-*-mingw*)
1772 PLATFORMDEP=gwin32.lo
1773 ;;
1774 *)
1775 PLATFORMDEP=
1776 ;;
1777 esac
1778 AC_MSG_RESULT($PLATFORMDEP)
1779 AC_SUBST(PLATFORMDEP)
1781 AC_MSG_CHECKING([whether to compile timeloop])
1782 case "$host" in
1783 *-*-cygwin*|*-*-mingw*|*-*-minix)
1784 enable_timeloop=no
1785 ;;
1786 *)
1787 enable_timeloop=yes
1788 ;;
1789 esac
1790 AC_MSG_RESULT($enable_timeloop)
1791 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1793 AC_MSG_CHECKING([if building for some Win32 platform])
1794 case "$host" in
1795 *-*-mingw*|*-*-cygwin*)
1796 platform_win32=yes
1797 ;;
1798 *)
1799 platform_win32=no
1800 ;;
1801 esac
1802 AC_MSG_RESULT($platform_win32)
1803 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1805 dnl ***********************
1806 dnl *** g_thread checks ***
1807 dnl ***********************
1809 AC_ARG_WITH(threads,
1810 [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1811 [specify a thread implementation to use])],
1812 [],
1813 [with_threads=yes])
1815 dnl error and warning message
1816 dnl *************************
1818 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1820 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1821 platform (normally it's "_REENTRANT"). I'll not use any flag on
1822 compilation now, but then your programs might not work.
1823 Please provide information on how it is done on your system."
1825 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1826 "
1828 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1829 provide information on your thread implementation."
1831 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1832 functions will not be MT-safe during their first call because
1833 there is no working 'getpwuid_r' on your system."
1835 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1836 because there is no 'localtime_r' on your system."
1838 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1839 linking threaded applications. As GLib cannot do that
1840 automatically, you will get an linkg error everytime you are
1841 not using the right compiler. In that case you have to relink
1842 with the right compiler. Ususally just '_r' is appended
1843 to the compiler name."
1845 dnl determination of thread implementation
1846 dnl ***************************************
1848 AC_MSG_CHECKING(for thread implementation)
1850 have_threads=no
1851 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1852 AS_IF([ test "x$have_threads" = xno], [
1853 AC_TRY_COMPILE([#include <pthread.h>],
1854 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1855 have_threads=posix)
1856 ])
1857 # Tru64Unix requires -pthread to find pthread.h. See #103020
1858 if test "x$have_threads" = xno; then
1859 glib_save_CPPFLAGS="$CPPFLAGS"
1860 CPPFLAGS="$CPPFLAGS -pthread"
1861 AC_TRY_COMPILE([#include <pthread.h>],
1862 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1863 have_threads=posix)
1864 CPPFLAGS="$glib_save_CPPFLAGS"
1865 fi
1866 ])
1867 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1868 case $host in
1869 *-*-mingw*)
1870 have_threads=win32
1871 ;;
1872 esac
1873 fi
1875 if test "x$have_threads" = xno; then
1876 AC_MSG_RESULT(none available)
1877 AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1878 else
1879 AC_MSG_RESULT($have_threads)
1880 fi
1883 dnl determination of G_THREAD_CFLAGS
1884 dnl ********************************
1886 G_THREAD_LIBS=
1887 G_THREAD_LIBS_EXTRA=
1888 G_THREAD_CFLAGS=
1890 dnl
1891 dnl Test program for basic POSIX threads functionality
1892 dnl
1893 m4_define([glib_thread_test],[
1894 #include <pthread.h>
1895 int check_me = 0;
1896 void* func(void* data) {check_me = 42; return &check_me;}
1897 int main()
1898 { pthread_t t;
1899 void *ret;
1900 pthread_create (&t, $1, func, 0);
1901 pthread_join (t, &ret);
1902 return (check_me != 42 || ret != &check_me);
1903 }])
1905 AS_IF([ test x"$have_threads" = xposix], [
1906 # First we test for posix, whether -pthread or -pthreads do the trick as
1907 # both CPPFLAG and LIBS.
1908 # One of them does for most gcc versions and some other platforms/compilers
1909 # too and could be considered as the canonical way to go.
1910 case $host in
1911 *-*-cygwin*|*-*-darwin*)
1912 # skip cygwin and darwin -pthread or -pthreads test
1913 ;;
1914 *-solaris*)
1915 # These compiler/linker flags work with both Sun Studio and gcc
1916 # Sun Studio expands -mt to -D_REENTRANT and -lthread
1917 # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1918 G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1919 G_THREAD_LIBS="-lpthread -lthread"
1920 ;;
1921 *)
1922 for flag in pthread pthreads mt; do
1923 glib_save_CFLAGS="$CFLAGS"
1924 CFLAGS="$CFLAGS -$flag"
1925 AC_TRY_RUN(glib_thread_test(0),
1926 glib_flag_works=yes,
1927 glib_flag_works=no,
1928 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1929 glib_flag_works=yes,
1930 glib_flag_works=no)])
1931 CFLAGS="$glib_save_CFLAGS"
1932 if test $glib_flag_works = yes ; then
1933 G_THREAD_CFLAGS=-$flag
1934 G_THREAD_LIBS=-$flag
1935 break;
1936 fi
1937 done
1938 ;;
1939 esac
1940 ])
1942 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
1944 # The canonical -pthread[s] does not work. Try something different.
1946 case $host in
1947 *-aix*)
1948 if test x"$GCC" = xyes; then
1949 # GCC 3.0 and above needs -pthread.
1950 # Should be coverd by the case above.
1951 # GCC 2.x and below needs -mthreads
1952 G_THREAD_CFLAGS="-mthreads"
1953 G_THREAD_LIBS=$G_THREAD_CFLAGS
1954 else
1955 # We are probably using the aix compiler. Normaly a
1956 # program would have to be compiled with the _r variant
1957 # of the corresponding compiler, but we as GLib cannot
1958 # do that: but the good news is that for compiling the
1959 # only difference is the added -D_THREAD_SAFE compile
1960 # option. This is according to the "C for AIX User's
1961 # Guide".
1962 G_THREAD_CFLAGS="-D_THREAD_SAFE"
1963 fi
1964 ;;
1965 *-sysv5uw7*) # UnixWare 7
1966 # We are not using gcc with -pthread. Catched above.
1967 G_THREAD_CFLAGS="-Kthread"
1968 G_THREAD_LIBS=$G_THREAD_CFLAGS
1969 ;;
1970 *-mingw*)
1971 # No flag needed when using MSVCRT.DLL
1972 G_THREAD_CFLAGS=""
1973 ;;
1974 *)
1975 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1976 ;;
1977 esac
1978 ])
1980 # if we are not finding the localtime_r function, then we probably are
1981 # not using the proper multithread flag
1983 glib_save_CPPFLAGS="$CPPFLAGS"
1984 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1986 # First we test, whether localtime_r is declared in time.h
1987 # directly. Then we test whether a macro localtime_r exists, in
1988 # which case localtime_r in the test program is replaced and thus
1989 # if we still find localtime_r in the output, it is not defined as
1990 # a macro.
1992 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1993 [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1994 localtime_r(a,b)],
1995 AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1997 CPPFLAGS="$glib_save_CPPFLAGS"
1999 AC_MSG_CHECKING(thread related cflags)
2000 AC_MSG_RESULT($G_THREAD_CFLAGS)
2001 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2003 dnl determination of G_THREAD_LIBS
2004 dnl ******************************
2006 AS_IF([test x$have_threads = xposix], [
2007 glib_save_CPPFLAGS="$CPPFLAGS"
2008 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2009 AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2010 case $host in
2011 *-aix*)
2012 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2013 # probably using the aix compiler.
2014 AC_MSG_WARN($AIX_COMPILE_INFO)
2015 ;;
2016 *)
2017 G_THREAD_LIBS=error
2018 glib_save_LIBS="$LIBS"
2019 for thread_lib in "" pthread pthread32 pthreads thread; do
2020 if test x"$thread_lib" = x; then
2021 add_thread_lib=""
2022 IN=""
2023 else
2024 add_thread_lib="-l$thread_lib"
2025 IN=" in -l$thread_lib"
2026 fi
2027 if test x"$have_threads" = xposix; then
2028 defattr=0
2029 else
2030 defattr=pthread_attr_default
2031 fi
2033 LIBS="$add_thread_lib $glib_save_LIBS"
2035 AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2036 AC_TRY_RUN(glib_thread_test($defattr),
2037 glib_result=yes,
2038 glib_result=no,
2039 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2040 glib_result=yes,
2041 glib_result=no)])
2042 AC_MSG_RESULT($glib_result)
2044 if test "$glib_result" = "yes" ; then
2045 G_THREAD_LIBS="$add_thread_lib"
2046 break
2047 fi
2048 done
2049 if test "x$G_THREAD_LIBS" = xerror; then
2050 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2051 fi
2052 LIBS="$glib_save_LIBS"
2053 ;;
2054 esac
2055 ])
2057 g_threads_impl="POSIX"
2058 AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2059 AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2060 CPPFLAGS="$glib_save_CPPFLAGS"
2061 ], [test x$have_threads = xwin32], [
2062 AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2063 g_threads_impl="WIN32"
2064 ], [
2065 AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2066 g_threads_impl="NONE"
2067 G_THREAD_LIBS=error
2068 ])
2069 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2070 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2071 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2073 if test "x$G_THREAD_LIBS" = xerror; then
2074 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2075 fi
2077 AC_MSG_CHECKING(thread related libraries)
2078 AC_MSG_RESULT($G_THREAD_LIBS)
2080 dnl check for mt safe function variants and some posix functions
2081 dnl ************************************************************
2083 glib_save_LIBS="$LIBS"
2084 # we are not doing the following for now, as this might require glib
2085 # to always be linked with the thread libs on some platforms.
2086 # LIBS="$LIBS $G_THREAD_LIBS"
2087 AC_CHECK_FUNCS(localtime_r gmtime_r getpwuid_r getgrgid_r)
2089 LIBS="$G_THREAD_LIBS $LIBS"
2090 AS_IF([ test x"$have_threads" = xposix], [
2091 glib_save_CPPFLAGS="$CPPFLAGS"
2092 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2093 # This is not AC_CHECK_FUNC to also work with function
2094 # name mangling in header files.
2095 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2096 AC_LINK_IFELSE(
2097 [AC_LANG_PROGRAM(
2098 [#include <pthread.h>],
2099 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2100 [AC_MSG_RESULT(yes)
2101 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2102 [Have function pthread_attr_setstacksize])],
2103 [AC_MSG_RESULT(no)])
2104 AC_MSG_CHECKING(for pthread_condattr_setclock)
2105 AC_LINK_IFELSE(
2106 [AC_LANG_PROGRAM(
2107 [#include <pthread.h>],
2108 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2109 [AC_MSG_RESULT(yes)
2110 AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2111 [Have function pthread_condattr_setclock])],
2112 [AC_MSG_RESULT(no)])
2113 AC_MSG_CHECKING(for pthread_cond_timedwait_relative_np)
2114 AC_LINK_IFELSE(
2115 [AC_LANG_PROGRAM(
2116 [#include <pthread.h>],
2117 [pthread_cond_timedwait_relative_np(NULL, NULL, NULL)])],
2118 [AC_MSG_RESULT(yes)
2119 AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP,1,
2120 [Have function pthread_cond_timedwait_relative_np])],
2121 [AC_MSG_RESULT(no)])
2122 dnl Sets thread names on OS X 10.6, iOS 3.2 (and higher)
2123 AC_MSG_CHECKING(for pthread_setname_np(const char*))
2124 AC_LINK_IFELSE(
2125 [AC_LANG_PROGRAM(
2126 [#include <pthread.h>],
2127 [pthread_setname_np("example")])],
2128 [AC_MSG_RESULT(yes)
2129 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
2130 [Have function pthread_setname_np(const char*)])],
2131 [AC_MSG_RESULT(no)])
2132 dnl Sets thread names on Solaris 11.3 & higher
2133 AC_MSG_CHECKING(for pthread_setname_np(pthread_t, const char*))
2134 AC_LINK_IFELSE(
2135 [AC_LANG_PROGRAM(
2136 [#include <pthread.h>],
2137 [pthread_setname_np(pthread_self(), "example")])],
2138 [AC_MSG_RESULT(yes)
2139 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITH_TID,1,
2140 [Have function pthread_setname_np(pthread_t, const char*)])],
2141 [AC_MSG_RESULT(no)])
2142 CPPFLAGS="$glib_save_CPPFLAGS"
2143 ])
2145 LIBS="$glib_save_LIBS"
2147 # now spit out all the warnings.
2148 if test "$ac_cv_func_getpwuid_r" != "yes"; then
2149 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2150 fi
2151 if test "$ac_cv_func_localtime_r" != "yes"; then
2152 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2153 fi
2155 #
2156 # Hack to deal with:
2157 #
2158 # a) GCC < 3.3 for Linux doesn't include -lpthread when
2159 # building shared libraries with linux.
2160 # b) FreeBSD doesn't do this either.
2161 #
2162 case $host in
2163 *android*)
2164 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2165 ;;
2166 *-*-freebsd*|*-*-linux*)
2167 G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2168 ;;
2169 *)
2170 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2171 ;;
2172 esac
2174 AC_SUBST(G_THREAD_CFLAGS)
2175 AC_SUBST(G_THREAD_LIBS)
2176 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2177 AC_SUBST(G_THREAD_LIBS_EXTRA)
2179 AC_CHECK_FUNCS(clock_gettime, [], [
2180 AC_CHECK_LIB(rt, clock_gettime, [
2181 G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2182 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2183 ])
2184 ])
2187 dnl ************************
2188 dnl *** g_atomic_* tests ***
2189 dnl ************************
2191 dnl We need to decide at configure time if GLib will use real atomic
2192 dnl operations ("lock free") or emulated ones with a mutex. This is
2193 dnl because we must put this information in glibconfig.h so we know if
2194 dnl it is safe or not to inline using compiler intrinsics directly from
2195 dnl the header.
2196 dnl
2197 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2198 dnl user is interested in knowing if they can use the atomic ops across
2199 dnl processes.
2200 dnl
2201 dnl We can currently support the atomic ops natively when building GLib
2202 dnl with recent versions of GCC or MSVC. MSVC doesn't run ./configure,
2203 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2204 dnl we are using GCC (and not mingw*).
2205 dnl
2206 dnl Note that the atomic ops are only available with GCC on x86 when
2207 dnl using -march=i486 or higher. If we detect that the atomic ops are
2208 dnl not available but would be available given the right flags, we want
2209 dnl to abort and advise the user to fix their CFLAGS. It's better to do
2210 dnl that then to silently fall back on emulated atomic ops just because
2211 dnl the user had the wrong build environment.
2213 dnl We may add other compilers here in the future...
2215 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2216 case $host in
2217 *-*-mingw*)
2218 glib_cv_g_atomic_lock_free=yes
2219 ;;
2220 *)
2221 AC_TRY_LINK([],
2222 [volatile int atomic = 2;\
2223 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2224 [glib_cv_g_atomic_lock_free=yes],
2225 [glib_cv_g_atomic_lock_free=no])
2226 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2227 SAVE_CFLAGS="${CFLAGS}"
2228 CFLAGS="-march=i486"
2229 AC_TRY_LINK([],
2230 [volatile int atomic = 2;\
2231 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2232 [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2233 [])
2234 CFLAGS="${SAVE_CFLAGS}"
2235 fi
2236 ;;
2237 esac])
2240 case $host in
2241 *-*-mingw*)
2242 ;;
2243 *)
2244 # Some compilers support atomic operations but do not define
2245 # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2246 if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2247 AC_TRY_LINK([],
2248 [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2249 [],
2250 [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2251 fi
2252 ;;
2253 esac
2255 dnl We need a more robust approach here...
2256 case $host_cpu in
2257 i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2258 glib_memory_barrier_needed=no
2259 ;;
2260 sparc*|alpha*|powerpc*|ia64)
2261 glib_memory_barrier_needed=yes
2262 ;;
2263 *)
2264 glib_memory_barrier_needed=yes
2265 ;;
2266 esac
2268 dnl ************************
2269 dnl ** Check for futex(2) **
2270 dnl ************************
2271 AC_CACHE_CHECK(for futex(2) system call,
2272 glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2273 #include <linux/futex.h>
2274 #include <sys/syscall.h>
2275 #include <unistd.h>
2276 ],[
2277 syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2278 ])],glib_cv_futex=yes,glib_cv_futex=no))
2279 if test x"$glib_cv_futex" = xyes; then
2280 AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2281 fi
2283 AC_CACHE_CHECK(for eventfd(2) system call,
2284 glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2285 #include <sys/eventfd.h>
2286 #include <unistd.h>
2287 ],[
2288 eventfd (0, EFD_CLOEXEC);
2289 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2290 if test x"$glib_cv_eventfd" = x"yes"; then
2291 AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2292 fi
2293 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2295 dnl ****************************************
2296 dnl *** GLib POLL* compatibility defines ***
2297 dnl ****************************************
2299 glib_poll_includes=["
2300 #include <sys/types.h>
2301 #include <poll.h>
2302 "]
2304 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2305 test $ac_cv_func_poll = yes ], [
2306 glib_failed=false
2307 GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2308 GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2309 GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2310 GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2311 GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2312 GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2313 if $glib_failed ; then
2314 AC_MSG_ERROR([Could not determine values for POLL* constants])
2315 fi
2316 ], [
2317 glib_cv_value_POLLIN=1
2318 glib_cv_value_POLLOUT=4
2319 glib_cv_value_POLLPRI=2
2320 glib_cv_value_POLLERR=8
2321 glib_cv_value_POLLHUP=16
2322 glib_cv_value_POLLNVAL=32
2323 ])
2325 AC_MSG_CHECKING([for broken poll])
2326 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2327 #include <stdlib.h>
2328 #include <fcntl.h>
2329 #include <poll.h>
2330 int main(void) {
2331 struct pollfd fds[1];
2332 int fd;
2333 fd = open("/dev/null", 1);
2334 fds[0].fd = fd;
2335 fds[0].events = POLLIN;
2336 fds[0].revents = 0;
2337 if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2338 exit(1); /* Does not work for devices -- fail */
2339 }
2340 exit(0);
2341 }]])],
2342 [broken_poll=no],
2343 [broken_poll=yes
2344 AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2345 [broken_poll="no (cross compiling)"])
2346 AC_MSG_RESULT($broken_poll)
2348 dnl *********************
2349 dnl *** GRegex checks ***
2350 dnl *********************
2352 PCRE_REQUIRED_VERSION=8.13
2354 # Check if we should use the internal or the system-supplied pcre
2355 AC_ARG_WITH(pcre,
2356 [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2357 [whether to use system PCRE [default=system]])],
2358 [],
2359 [with_pcre=system])
2361 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2363 AS_IF([ test "x$with_pcre" = xsystem], [
2364 PKG_CHECK_MODULES(PCRE,
2365 libpcre >= $PCRE_REQUIRED_VERSION)
2366 AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2367 glib_save_CFLAGS="$CFLAGS"
2368 glib_save_LIBS="$LIBS"
2369 CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2370 AC_TRY_RUN([#include <pcre.h>
2371 int main () {
2372 int support;
2373 pcre_config (PCRE_CONFIG_UTF8, &support);
2374 if (!support)
2375 return 1;
2376 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2377 if (!support)
2378 return 1;
2379 return 0;
2380 }],
2381 glib_cv_pcre_has_unicode=yes,
2382 glib_cv_pcre_has_unicode=no,
2383 glib_cv_pcre_has_unicode=yes)
2384 CFLAGS="$glib_save_CFLAGS"
2385 LIBS="$glib_save_LIBS"
2386 ])
2387 if test "$glib_cv_pcre_has_unicode" = "no"; then
2388 AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2389 fi
2390 AC_SUBST(PCRE_CFLAGS)
2391 AC_SUBST(PCRE_LIBS)
2392 AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2393 PCRE_REQUIRES=libpcre
2394 AC_SUBST(PCRE_REQUIRES)
2395 ], [
2396 # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2397 AS_IF([ test x"$GCC" = xyes], [
2398 AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2399 save_CFLAGS="$CFLAGS"
2400 CFLAGS="$CFLAGS -Wno-pointer-sign"
2401 AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2402 AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2403 CFLAGS="$save_CFLAGS"
2404 ])
2405 ])
2406 AC_SUBST(PCRE_WARN_CFLAGS)
2408 dnl **********************
2409 dnl *** Win32 API libs ***
2410 dnl **********************
2412 case $host in
2413 *-*-cygwin*)
2414 G_LIBS_EXTRA="-luser32 -lkernel32"
2415 ;;
2416 *-*-mingw*)
2417 G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2418 ;;
2419 *)
2420 G_LIBS_EXTRA=""
2421 ;;
2422 esac
2423 AC_SUBST(G_LIBS_EXTRA)
2425 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2426 dnl since we need it for g_iconv()
2428 AC_MSG_CHECKING([for EILSEQ])
2429 AC_TRY_COMPILE([
2430 #include <errno.h>
2431 ],
2432 [
2433 int error = EILSEQ;
2434 ], have_eilseq=yes, have_eilseq=no);
2435 AC_MSG_RESULT($have_eilseq)
2437 dnl Add a conditional we can use when cross-compiling, so we avoid running
2438 dnl binaries
2439 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2441 dnl **************************
2442 dnl *** Checks for gtk-doc ***
2443 dnl **************************
2444 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2445 # it on it's own line.
2446 m4_ifdef([GTK_DOC_CHECK], [
2447 GTK_DOC_CHECK([1.20], [--flavour no-tmpl])
2448 ],[
2449 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2450 ])
2452 AC_ARG_ENABLE(man,
2453 [AS_HELP_STRING([--enable-man],
2454 [generate man pages [default=auto]])],,
2455 enable_man=maybe)
2457 AS_IF([test "$enable_man" != no], [
2458 AC_PATH_PROG([XSLTPROC], [xsltproc])
2459 AS_IF([test -z "$XSLTPROC"], [
2460 AS_IF([test "$enable_man" = yes], [
2461 AC_MSG_ERROR([xsltproc is required for --enable-man])
2462 ])
2463 enable_man=no
2464 ])
2465 ])
2467 AS_IF([ test "$enable_man" != no ], [
2468 dnl check for DocBook DTD in the local catalog
2469 JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2470 [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2471 AS_IF([test "$have_docbook_dtd" != yes], [
2472 AS_IF([test "$enable_man" = yes ], [
2473 AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2474 ])
2475 enable_man=no
2476 ])
2477 ])
2479 AS_IF([test "$enable_man" != no], [
2480 dnl check for DocBook XSL stylesheets in the local catalog
2481 JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2482 [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2483 AS_IF([ test "$have_docbook_style" != yes ], [
2484 AS_IF([ test "$enable_man" = yes ], [
2485 AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2486 ])
2487 enable_man=no
2488 ])
2489 ])
2491 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2493 AC_MSG_CHECKING([whether to generate man pages])
2494 AS_IF([ test "$enable_man" != no ], [
2495 AC_MSG_RESULT([yes])
2496 ], [
2497 AC_MSG_RESULT([no])
2498 ])
2500 dnl
2501 dnl Tracing
2502 dnl
2504 AC_ARG_ENABLE([dtrace],
2505 [AS_HELP_STRING([--enable-dtrace],
2506 [include tracing support for dtrace])])
2507 have_dtrace=no
2508 AC_MSG_CHECKING([whether to include dtrace tracing support])
2509 AS_IF([ test "x$enable_dtrace" != xno], [
2510 if test x$glib_have_carbon = xyes; then
2511 AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2512 else
2513 AC_MSG_RESULT([yes])
2514 AC_CHECK_PROGS(DTRACE, dtrace)
2515 if test -z "$DTRACE"; then
2516 if test "x$enable_dtrace" = xyes; then
2517 AC_MSG_ERROR([dtrace not found])
2518 fi
2519 else
2520 AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2521 [if test "x$enable_dtrace" = xyes; then
2522 AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2523 fi])
2524 fi
2525 fi
2526 ], [
2527 AC_MSG_RESULT([no])
2528 ])
2529 if test "x$have_dtrace" = xyes; then
2530 AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2531 fi
2532 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2534 AC_MSG_CHECKING([whether to include systemtap tracing support])
2535 AC_ARG_ENABLE([systemtap],
2536 [AS_HELP_STRING([--enable-systemtap],
2537 [include tracing support for systemtap])])
2538 have_systemtap=no
2539 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2540 have_systemtap=yes
2541 fi
2542 AC_MSG_RESULT(${have_systemtap})
2544 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2546 AC_ARG_WITH([tapset-install-dir],
2547 AS_HELP_STRING([--with-tapset-install-dir=DIR],
2548 [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2549 [if test "x${withval}" = x; then
2550 ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2551 else
2552 ABS_TAPSET_DIR="${withval}"
2553 fi],
2554 [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2555 AC_SUBST(ABS_TAPSET_DIR)
2557 dnl ************************************
2558 dnl *** Enable lcov coverage reports ***
2559 dnl ************************************
2561 AC_ARG_ENABLE(coverage,
2562 AS_HELP_STRING([--enable-coverage],
2563 [enable coverage testing with gcov]),
2564 [use_gcov=$enableval], [use_gcov=no])
2566 AS_IF([ test "x$use_gcov" = "xyes"], [
2567 dnl we need gcc:
2568 if test "$GCC" != "yes"; then
2569 AC_MSG_ERROR([GCC is required for --enable-coverage])
2570 fi
2572 dnl Check if ccache is being used
2573 AC_CHECK_PROG(SHTOOL, shtool, shtool)
2574 case `$SHTOOL path $CC` in
2575 *ccache*[)] gcc_ccache=yes;;
2576 *[)] gcc_ccache=no;;
2577 esac
2579 if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2580 AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2581 fi
2583 ltp_version_list="1.6 1.7 1.8 1.9 1.10"
2584 AC_CHECK_PROG(LTP, lcov, lcov)
2585 AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2587 AS_IF([ test "$LTP" ], [
2588 AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2589 glib_cv_ltp_version=invalid
2590 ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2591 for ltp_check_version in $ltp_version_list; do
2592 if test "$ltp_version" = "$ltp_check_version"; then
2593 glib_cv_ltp_version="$ltp_check_version (ok)"
2594 fi
2595 done
2596 ])
2597 ], [
2598 ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2599 AC_MSG_ERROR([$ltp_msg])
2600 ])
2602 case $glib_cv_ltp_version in
2603 ""|invalid[)]
2604 ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2605 AC_MSG_ERROR([$ltp_msg])
2606 LTP="exit 0;"
2607 ;;
2608 esac
2610 if test -z "$LTP_GENHTML"; then
2611 AC_MSG_ERROR([Could not find genhtml from the LTP package])
2612 fi
2614 dnl Remove all optimization flags from CFLAGS
2615 changequote({,})
2616 CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2617 changequote([,])
2619 dnl Add the special gcc flags
2620 CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2621 LDFLAGS="$LDFLAGS -lgcov"
2622 ])
2624 dnl ******************************
2625 dnl *** output the whole stuff ***
2626 dnl ******************************
2628 dnl this section will only be run if config.status is invoked with no
2629 dnl arguments, or with "glib/glibconfig.h" as an argument.
2630 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2631 [
2632 outfile=glib/glibconfig.h-tmp
2633 cat > $outfile <<\_______EOF
2634 /* glibconfig.h
2635 *
2636 * This is a generated file. Please modify 'configure.ac'
2637 */
2639 #ifndef __GLIBCONFIG_H__
2640 #define __GLIBCONFIG_H__
2642 #include <glib/gmacros.h>
2644 _______EOF
2646 echo '#include <limits.h>' >> $outfile
2647 echo '#include <float.h>' >> $outfile
2648 if test x$glib_values_h = xyes; then
2649 echo '#include <values.h>' >> $outfile
2650 fi
2651 if test "$glib_header_alloca_h" = "yes"; then
2652 echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2653 fi
2654 if test x$glib_included_printf != xyes; then
2655 echo "
2656 /* Specifies that GLib's g_print*() functions wrap the
2657 * system printf functions. This is useful to know, for example,
2658 * when using glibc's register_printf_function().
2659 */" >> $outfile
2660 echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2661 fi
2663 cat >> $outfile <<_______EOF
2665 G_BEGIN_DECLS
2667 #define G_MINFLOAT FLT_MIN
2668 #define G_MAXFLOAT FLT_MAX
2669 #define G_MINDOUBLE DBL_MIN
2670 #define G_MAXDOUBLE DBL_MAX
2671 #define G_MINSHORT SHRT_MIN
2672 #define G_MAXSHORT SHRT_MAX
2673 #define G_MAXUSHORT USHRT_MAX
2674 #define G_MININT INT_MIN
2675 #define G_MAXINT INT_MAX
2676 #define G_MAXUINT UINT_MAX
2677 #define G_MINLONG LONG_MIN
2678 #define G_MAXLONG LONG_MAX
2679 #define G_MAXULONG ULONG_MAX
2681 _______EOF
2684 ### this should always be true in a modern C/C++ compiler
2685 ### and is statically asserted by glib-init.c
2686 cat >>$outfile <<_______EOF
2687 typedef signed char gint8;
2688 typedef unsigned char guint8;
2689 _______EOF
2692 if test -n "$gint16"; then
2693 cat >>$outfile <<_______EOF
2694 typedef signed $gint16 gint16;
2695 typedef unsigned $gint16 guint16;
2696 #define G_GINT16_MODIFIER $gint16_modifier
2697 #define G_GINT16_FORMAT $gint16_format
2698 #define G_GUINT16_FORMAT $guint16_format
2699 _______EOF
2700 fi
2703 if test -n "$gint32"; then
2704 cat >>$outfile <<_______EOF
2705 typedef signed $gint32 gint32;
2706 typedef unsigned $gint32 guint32;
2707 #define G_GINT32_MODIFIER $gint32_modifier
2708 #define G_GINT32_FORMAT $gint32_format
2709 #define G_GUINT32_FORMAT $guint32_format
2710 _______EOF
2711 fi
2713 cat >>$outfile <<_______EOF
2714 #define G_HAVE_GINT64 1 /* deprecated, always true */
2716 ${glib_extension}typedef signed $gint64 gint64;
2717 ${glib_extension}typedef unsigned $gint64 guint64;
2719 #define G_GINT64_CONSTANT(val) $gint64_constant
2720 #define G_GUINT64_CONSTANT(val) $guint64_constant
2721 _______EOF
2723 if test x$gint64_format != x ; then
2724 cat >>$outfile <<_______EOF
2725 #define G_GINT64_MODIFIER $gint64_modifier
2726 #define G_GINT64_FORMAT $gint64_format
2727 #define G_GUINT64_FORMAT $guint64_format
2728 _______EOF
2729 else
2730 cat >>$outfile <<_______EOF
2731 #undef G_GINT64_MODIFIER
2732 #undef G_GINT64_FORMAT
2733 #undef G_GUINT64_FORMAT
2734 _______EOF
2735 fi
2737 cat >>$outfile <<_______EOF
2739 #define GLIB_SIZEOF_VOID_P $glib_void_p
2740 #define GLIB_SIZEOF_LONG $glib_long
2741 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2742 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2744 _______EOF
2746 cat >>$outfile <<_______EOF
2747 typedef signed $glib_ssize_type_define gssize;
2748 typedef unsigned $glib_size_type_define gsize;
2749 #define G_GSIZE_MODIFIER $gsize_modifier
2750 #define G_GSSIZE_MODIFIER $gssize_modifier
2751 #define G_GSIZE_FORMAT $gsize_format
2752 #define G_GSSIZE_FORMAT $gssize_format
2754 #define G_MAXSIZE G_MAXU$glib_msize_type
2755 #define G_MINSSIZE G_MIN$glib_mssize_type
2756 #define G_MAXSSIZE G_MAX$glib_mssize_type
2758 typedef gint64 goffset;
2759 #define G_MINOFFSET G_MININT64
2760 #define G_MAXOFFSET G_MAXINT64
2762 #define G_GOFFSET_MODIFIER G_GINT64_MODIFIER
2763 #define G_GOFFSET_FORMAT G_GINT64_FORMAT
2764 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2766 #define G_POLLFD_FORMAT $g_pollfd_format
2768 _______EOF
2770 if test -z "$glib_unknown_void_p"; then
2771 cat >>$outfile <<_______EOF
2773 #define GPOINTER_TO_INT(p) ((gint) ${glib_gpi_cast} (p))
2774 #define GPOINTER_TO_UINT(p) ((guint) ${glib_gpui_cast} (p))
2776 #define GINT_TO_POINTER(i) ((gpointer) ${glib_gpi_cast} (i))
2777 #define GUINT_TO_POINTER(u) ((gpointer) ${glib_gpui_cast} (u))
2779 typedef signed $glib_intptr_type_define gintptr;
2780 typedef unsigned $glib_intptr_type_define guintptr;
2782 #define G_GINTPTR_MODIFIER $gintptr_modifier
2783 #define G_GINTPTR_FORMAT $gintptr_format
2784 #define G_GUINTPTR_FORMAT $guintptr_format
2785 _______EOF
2786 else
2787 echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2788 fi
2792 cat >>$outfile <<_______EOF
2793 #ifndef G_DISABLE_DEPRECATED
2794 #define g_ATEXIT(proc) (atexit (proc))
2795 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2796 #endif
2797 $glib_defines
2798 $glib_os
2799 $glib_static_compilation
2801 $glib_vacopy
2803 _______EOF
2805 if test x$g_have_iso_c_varargs = xyes ; then
2806 cat >>$outfile <<_______EOF
2807 #ifndef __cplusplus
2808 # define G_HAVE_ISO_VARARGS 1
2809 #endif
2810 _______EOF
2811 fi
2812 if test x$g_have_iso_cxx_varargs = xyes ; then
2813 cat >>$outfile <<_______EOF
2814 #ifdef __cplusplus
2815 # define G_HAVE_ISO_VARARGS 1
2816 #endif
2817 _______EOF
2818 fi
2819 if test x$g_have_gnuc_varargs = xyes ; then
2820 cat >>$outfile <<_______EOF
2822 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2823 * is passed ISO vararg support is turned off, and there is no work
2824 * around to turn it on, so we unconditionally turn it off.
2825 */
2826 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2827 # undef G_HAVE_ISO_VARARGS
2828 #endif
2830 #define G_HAVE_GNUC_VARARGS 1
2831 _______EOF
2832 fi
2834 case x$g_stack_grows in
2835 xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2836 *) echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2837 esac
2840 echo >>$outfile
2841 if test x$g_have_eilseq = xno; then
2842 cat >>$outfile <<_______EOF
2843 #ifndef EILSEQ
2844 /* On some pre-C99 systems, EILSEQ is not defined.
2845 * The correspondence between this and the corresponding definition
2846 * in libiconv is essential.
2847 */
2848 # define EILSEQ ENOENT
2849 #endif
2850 _______EOF
2852 fi
2854 if test x$g_have_gnuc_visibility = xyes; then
2855 cat >>$outfile <<_______EOF
2856 #define G_HAVE_GNUC_VISIBILITY 1
2857 _______EOF
2858 fi
2859 cat >>$outfile <<_______EOF
2860 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2861 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2862 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2863 #define G_GNUC_INTERNAL __hidden
2864 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2865 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2866 #else
2867 #define G_GNUC_INTERNAL
2868 #endif
2869 _______EOF
2871 echo >>$outfile
2872 cat >>$outfile <<_______EOF
2873 #define G_THREADS_ENABLED
2874 #define G_THREADS_IMPL_$g_threads_impl_def
2875 _______EOF
2877 if test x"$g_memory_barrier_needed" != xno; then
2878 echo >>$outfile
2879 echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2880 fi
2881 if test x"$g_atomic_lock_free" = xyes; then
2882 echo >>$outfile
2883 echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
2884 fi
2885 echo >>$outfile
2886 g_bit_sizes="16 32 64"
2887 for bits in $g_bit_sizes; do
2888 cat >>$outfile <<_______EOF
2889 #define GINT${bits}_TO_${g_bs_native}(val) ((gint${bits}) (val))
2890 #define GUINT${bits}_TO_${g_bs_native}(val) ((guint${bits}) (val))
2891 #define GINT${bits}_TO_${g_bs_alien}(val) ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2892 #define GUINT${bits}_TO_${g_bs_alien}(val) (GUINT${bits}_SWAP_LE_BE (val))
2893 _______EOF
2894 done
2896 cat >>$outfile <<_______EOF
2897 #define GLONG_TO_LE(val) ((glong) GINT${glongbits}_TO_LE (val))
2898 #define GULONG_TO_LE(val) ((gulong) GUINT${glongbits}_TO_LE (val))
2899 #define GLONG_TO_BE(val) ((glong) GINT${glongbits}_TO_BE (val))
2900 #define GULONG_TO_BE(val) ((gulong) GUINT${glongbits}_TO_BE (val))
2901 #define GINT_TO_LE(val) ((gint) GINT${gintbits}_TO_LE (val))
2902 #define GUINT_TO_LE(val) ((guint) GUINT${gintbits}_TO_LE (val))
2903 #define GINT_TO_BE(val) ((gint) GINT${gintbits}_TO_BE (val))
2904 #define GUINT_TO_BE(val) ((guint) GUINT${gintbits}_TO_BE (val))
2905 #define GSIZE_TO_LE(val) ((gsize) GUINT${gsizebits}_TO_LE (val))
2906 #define GSSIZE_TO_LE(val) ((gssize) GINT${gssizebits}_TO_LE (val))
2907 #define GSIZE_TO_BE(val) ((gsize) GUINT${gsizebits}_TO_BE (val))
2908 #define GSSIZE_TO_BE(val) ((gssize) GINT${gssizebits}_TO_BE (val))
2909 #define G_BYTE_ORDER $g_byte_order
2911 #define GLIB_SYSDEF_POLLIN =$g_pollin
2912 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2913 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2914 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2915 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2916 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2918 #define G_MODULE_SUFFIX "$g_module_suffix"
2920 typedef $g_pid_type GPid;
2921 #define G_PID_FORMAT $g_pid_format
2923 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
2924 #define GLIB_SYSDEF_AF_INET $g_af_inet
2925 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
2927 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
2928 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
2929 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
2931 G_END_DECLS
2933 #endif /* __GLIBCONFIG_H__ */
2934 _______EOF
2937 if cmp -s $outfile glib/glibconfig.h; then
2938 AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
2939 rm -f $outfile
2940 else
2941 mv $outfile glib/glibconfig.h
2942 fi
2943 ],[
2945 # Note that if two cases are the same, case goes with the first one.
2946 # Note also that this is inside an AC_OUTPUT_COMMAND. We do not depend
2947 # on variable expansion in case labels. Look at the generated config.status
2948 # for a hint.
2950 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2951 glib_header_alloca_h="$ac_cv_working_alloca_h"
2952 else
2953 glib_header_alloca_h="$ac_cv_header_alloca_h"
2954 fi
2956 if test x$enable_included_printf = xyes ; then
2957 glib_included_printf=yes
2958 fi
2960 case 2 in
2961 $ac_cv_sizeof_short)
2962 gint16=short
2963 gint16_modifier='"h"'
2964 gint16_format='"hi"'
2965 guint16_format='"hu"'
2966 ;;
2967 $ac_cv_sizeof_int)
2968 gint16=int
2969 gint16_modifier='""'
2970 gint16_format='"i"'
2971 guint16_format='"u"'
2972 ;;
2973 esac
2974 case 4 in
2975 $ac_cv_sizeof_short)
2976 gint32=short
2977 gint32_modifier='"h"'
2978 gint32_format='"hi"'
2979 guint32_format='"hu"'
2980 ;;
2981 $ac_cv_sizeof_int)
2982 gint32=int
2983 gint32_modifier='""'
2984 gint32_format='"i"'
2985 guint32_format='"u"'
2986 ;;
2987 $ac_cv_sizeof_long)
2988 gint32=long
2989 gint32_modifier='"l"'
2990 gint32_format='"li"'
2991 guint32_format='"lu"'
2992 ;;
2993 esac
2994 case 8 in
2995 $ac_cv_sizeof_int)
2996 gint64=int
2997 gint64_modifier='""'
2998 gint64_format='"i"'
2999 guint64_format='"u"'
3000 glib_extension=
3001 gint64_constant='(val)'
3002 guint64_constant='(val)'
3003 ;;
3004 $ac_cv_sizeof_long)
3005 gint64=long
3006 gint64_modifier='"l"'
3007 gint64_format='"li"'
3008 guint64_format='"lu"'
3009 glib_extension=
3010 gint64_constant='(val##L)'
3011 guint64_constant='(val##UL)'
3012 ;;
3013 $ac_cv_sizeof_long_long)
3014 gint64='long long'
3015 if test -n "$glib_cv_long_long_format"; then
3016 gint64_modifier='"'$glib_cv_long_long_format'"'
3017 gint64_format='"'$glib_cv_long_long_format'i"'
3018 guint64_format='"'$glib_cv_long_long_format'u"'
3019 fi
3020 glib_extension='G_GNUC_EXTENSION '
3021 gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3022 guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3023 ;;
3024 $ac_cv_sizeof___int64)
3025 gint64='__int64'
3026 if test -n "$glib_cv_long_long_format"; then
3027 gint64_modifier='"'$glib_cv_long_long_format'"'
3028 gint64_format='"'$glib_cv_long_long_format'i"'
3029 guint64_format='"'$glib_cv_long_long_format'u"'
3030 fi
3031 glib_extension=
3032 gint64_constant='(val##i64)'
3033 guint64_constant='(val##ui64)'
3034 ;;
3035 esac
3036 glib_size_t=$ac_cv_sizeof_size_t
3037 glib_ssize_t=$ac_cv_sizeof_ssize_t
3038 glib_size_type_define="$glib_size_type"
3039 glib_ssize_type_define="$glib_ssize_type"
3040 glib_void_p=$ac_cv_sizeof_void_p
3041 glib_long=$ac_cv_sizeof_long
3043 case "$glib_size_type" in
3044 short)
3045 gsize_modifier='"h"'
3046 gsize_format='"hu"'
3047 glib_msize_type='SHRT'
3048 ;;
3049 int)
3050 gsize_modifier='""'
3051 gsize_format='"u"'
3052 glib_msize_type='INT'
3053 ;;
3054 long)
3055 gsize_modifier='"l"'
3056 gsize_format='"lu"'
3057 glib_msize_type='LONG'
3058 ;;
3059 "long long"|__int64)
3060 gsize_modifier='"I64"'
3061 gsize_format='"I64u"'
3062 glib_msize_type='INT64'
3063 ;;
3064 esac
3066 case "$glib_ssize_type" in
3067 short)
3068 gssize_modifier='"h"'
3069 gssize_format='"hi"'
3070 glib_mssize_type='SHRT'
3071 ;;
3072 int)
3073 gssize_modifier='""'
3074 gssize_format='"i"'
3075 glib_mssize_type='INT'
3076 ;;
3077 long)
3078 gssize_modifier='"l"'
3079 gssize_format='"li"'
3080 glib_mssize_type='LONG'
3081 ;;
3082 "long long"|__int64)
3083 gssize_modifier='"I64"'
3084 gssize_format='"I64i"'
3085 glib_mssize_type='INT64'
3086 ;;
3087 esac
3089 gintbits=`expr $ac_cv_sizeof_int \* 8`
3090 glongbits=`expr $ac_cv_sizeof_long \* 8`
3091 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3092 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3094 case $ac_cv_sizeof_void_p in
3095 $ac_cv_sizeof_int)
3096 glib_intptr_type_define=int
3097 gintptr_modifier='""'
3098 gintptr_format='"i"'
3099 guintptr_format='"u"'
3100 glib_gpi_cast='(gint)'
3101 glib_gpui_cast='(guint)'
3102 ;;
3103 $ac_cv_sizeof_long)
3104 glib_intptr_type_define=long
3105 gintptr_modifier='"l"'
3106 gintptr_format='"li"'
3107 guintptr_format='"lu"'
3108 glib_gpi_cast='(glong)'
3109 glib_gpui_cast='(gulong)'
3110 ;;
3111 $ac_cv_sizeof_long_long)
3112 glib_intptr_type_define='long long'
3113 gintptr_modifier='"I64"'
3114 gintptr_format='"I64i"'
3115 guintptr_format='"I64u"'
3116 glib_gpi_cast='(gint64)'
3117 glib_gpui_cast='(guint64)'
3118 ;;
3119 $ac_cv_sizeof___int64)
3120 glib_intptr_type_define=__int64
3121 gintptr_modifier='"I64"'
3122 gintptr_format='"I64i"'
3123 guintptr_format='"I64u"'
3124 glib_gpi_cast='(gint64)'
3125 glib_gpui_cast='(guint64)'
3126 ;;
3127 *)
3128 glib_unknown_void_p=yes
3129 ;;
3130 esac
3133 glib_defines="
3134 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3135 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3136 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3137 "
3139 case xyes in
3140 x$glib_cv_va_copy) glib_vacopy='#define G_VA_COPY va_copy' ;;
3141 x$glib_cv___va_copy) glib_vacopy='#define G_VA_COPY __va_copy' ;;
3142 *) glib_vacopy=''
3143 esac
3145 if test x$glib_cv_va_val_copy = xno; then
3146 glib_vacopy="\$glib_vacopy
3147 #define G_VA_COPY_AS_ARRAY 1"
3148 fi
3150 g_have_gnuc_varargs=$g_have_gnuc_varargs
3151 g_have_iso_c_varargs=$g_have_iso_c_varargs
3152 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3154 g_have_gnuc_visibility=$g_have_gnuc_visibility
3155 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3157 if test x$ac_cv_c_bigendian = xyes; then
3158 g_byte_order=G_BIG_ENDIAN
3159 g_bs_native=BE
3160 g_bs_alien=LE
3161 else
3162 g_byte_order=G_LITTLE_ENDIAN
3163 g_bs_native=LE
3164 g_bs_alien=BE
3165 fi
3167 g_pollin=$glib_cv_value_POLLIN
3168 g_pollout=$glib_cv_value_POLLOUT
3169 g_pollpri=$glib_cv_value_POLLPRI
3170 g_pollhup=$glib_cv_value_POLLHUP
3171 g_pollerr=$glib_cv_value_POLLERR
3172 g_pollnval=$glib_cv_value_POLLNVAL
3174 # If a family is not found on the system, define that family to
3175 # a negative value, picking a different one for each undefined
3176 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3177 # This is needed because glib-mkenums doesn't handle optional
3178 # values in enums, and thus we have to have all existing values
3179 # defined in the enum.
3180 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3181 g_af_unix=$glib_cv_value_AF_UNIX
3182 else
3183 g_af_unix=-1
3184 fi
3185 g_af_inet=$glib_cv_value_AF_INET
3186 g_af_inet6=$glib_cv_value_AF_INET6
3188 g_msg_peek=$glib_cv_value_MSG_PEEK
3189 g_msg_oob=$glib_cv_value_MSG_OOB
3190 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3192 g_stack_grows=$glib_cv_stack_grows
3194 g_have_eilseq=$have_eilseq
3196 g_threads_impl_def=$g_threads_impl
3198 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3199 g_memory_barrier_needed="$glib_memory_barrier_needed"
3200 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3202 g_module_suffix="$glib_gmodule_suffix"
3203 g_pid_type="$glib_pid_type"
3204 g_pid_format="\"$glib_pid_format\""
3205 g_pollfd_format="\"$glib_pollfd_format\""
3207 case $host in
3208 *-*-cygwin*)
3209 glib_os="#define G_OS_UNIX
3210 #define G_PLATFORM_WIN32
3211 #define G_WITH_CYGWIN"
3212 ;;
3213 *-*-mingw*)
3214 glib_os="#define G_OS_WIN32
3215 #define G_PLATFORM_WIN32"
3216 ;;
3217 *)
3218 glib_os="#define G_OS_UNIX"
3219 ;;
3220 esac
3221 glib_static_compilation=""
3222 if test x$glib_win32_static_compilation = xyes; then
3223 glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3224 #define GOBJECT_STATIC_COMPILATION 1"
3225 fi
3226 ])
3228 # Redo enough to get guint32 and guint64 for the alignment checks below
3229 case 4 in
3230 $ac_cv_sizeof_short)
3231 gint32=short
3232 ;;
3233 $ac_cv_sizeof_int)
3234 gint32=int
3235 ;;
3236 $ac_cv_sizeof_long)
3237 gint32=long
3238 ;;
3239 esac
3240 case 8 in
3241 $ac_cv_sizeof_int)
3242 gint64=int
3243 ;;
3244 $ac_cv_sizeof_long)
3245 gint64=long
3246 ;;
3247 $ac_cv_sizeof_long_long)
3248 gint64='long long'
3249 ;;
3250 $ac_cv_sizeof___int64)
3251 gint64='__int64'
3252 ;;
3253 esac
3255 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3256 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3257 typedef unsigned $gint32 guint32;])
3258 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3259 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3260 typedef unsigned $gint64 guint64;])
3261 AC_CHECK_TYPE([unsigned long])
3262 AC_CHECK_ALIGNOF([unsigned long])
3264 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3265 #
3266 # 1.2.14 required for dbus_message_set_serial
3267 PKG_CHECK_MODULES(DBUS1,
3268 dbus-1 >= 1.2.14,
3269 [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3270 have_dbus1=no)
3271 AC_SUBST(DBUS1_CFLAGS)
3272 AC_SUBST(DBUS1_LIBS)
3273 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3275 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3276 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3278 # Check whether MSVC toolset is explicitly set
3279 AM_CONDITIONAL(MSVC_BASE_NO_TOOLSET_SET, [test x$MSVC_BASE_TOOLSET = x])
3280 AM_CONDITIONAL(MSVC_NO_TOOLSET_SET, [test x$MSVC_TOOLSET = x])
3282 dnl
3283 dnl Check for -Bsymbolic-functions linker flag used to avoid
3284 dnl intra-library PLT jumps, if available.
3285 dnl
3287 AC_ARG_ENABLE(Bsymbolic,
3288 [AS_HELP_STRING([--disable-Bsymbolic],
3289 [avoid linking with -Bsymbolic])],,
3290 [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3291 AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3292 LDFLAGS=-Wl,-Bsymbolic-functions
3293 LIBS=
3294 AC_TRY_LINK([], [return 0],
3295 AC_MSG_RESULT(yes)
3296 enable_Bsymbolic=yes,
3297 AC_MSG_RESULT(no)
3298 enable_Bsymbolic=no)
3299 LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3301 if test "x${enable_Bsymbolic}" = "xyes"; then
3302 GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3303 fi
3305 dnl
3306 dnl Check for -z,nodelete linker flag: the type system assumes that
3307 dnl libgobject stays loaded for the lifetime of the process.
3308 dnl Since ld.bfd does not treat wrong -z options as fatal by default,
3309 dnl we also try to check for the --fatal-warnings linker flag if
3310 dnl auto-detecting.
3311 dnl
3313 AC_ARG_ENABLE([znodelete],
3314 [AS_HELP_STRING([--disable-znodelete],
3315 [avoid linking with -z,nodelete])],,
3316 [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3317 AC_MSG_CHECKING([for --fatal-warnings linker flag])
3318 LDFLAGS=-Wl,--fatal-warnings
3319 LIBS=
3320 AC_TRY_LINK([], [return 0],
3321 AC_MSG_RESULT(yes)
3322 [ldflags_fatal=-Wl,--fatal-warnings],
3323 AC_MSG_RESULT(no)
3324 ldflags_fatal=)
3325 AC_MSG_CHECKING([for -z,nodelete linker flag])
3326 LDFLAGS="$ldflags_fatal -Wl,-z,nodelete"
3327 AC_TRY_LINK([], [return 0],
3328 AC_MSG_RESULT(yes)
3329 enable_znodelete=yes,
3330 AC_MSG_RESULT(no)
3331 enable_znodelete=no)
3332 LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3334 if test "x${enable_znodelete}" = "xyes"; then
3335 GLIB_LINK_FLAGS="$GLIB_LINK_FLAGS -Wl,-z,nodelete"
3336 fi
3338 AC_SUBST(GLIB_LINK_FLAGS)
3340 dnl
3341 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3342 dnl visibility attributes for symbol export control
3343 dnl
3344 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3345 case "$host" in
3346 *-*-mingw*)
3347 dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3348 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3349 [defines how to decorate public symbols while building])
3350 CFLAGS="${CFLAGS} -fvisibility=hidden"
3351 ;;
3352 *)
3353 dnl on other compilers, check if we can do -fvisibility=hidden
3354 SAVED_CFLAGS="${CFLAGS}"
3355 CFLAGS="-fvisibility=hidden"
3356 AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3357 AC_TRY_COMPILE([], [return 0],
3358 AC_MSG_RESULT(yes)
3359 enable_fvisibility_hidden=yes,
3360 AC_MSG_RESULT(no)
3361 enable_fvisibility_hidden=no)
3362 CFLAGS="${SAVED_CFLAGS}"
3364 AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3365 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3366 [defines how to decorate public symbols while building])
3367 GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3368 ])
3369 ;;
3370 esac
3371 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3373 dnl Compiler flags; macro originates from systemd
3374 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3375 AC_ARG_ENABLE(compile-warnings,
3376 [AS_HELP_STRING([--disable-compile-warnings],
3377 [Don't use builtin compiler warnings])],,
3378 enable_compile_warnings=yes)
3379 AS_IF([test "x$enable_compile_warnings" = xyes], [
3380 CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3381 -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3382 -Werror=missing-prototypes -Werror=implicit-function-declaration \
3383 -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3384 -Werror=format=2 -Werror=missing-include-dirs])
3385 ])
3386 AC_SUBST(GLIB_WARN_CFLAGS)
3388 #
3389 # Define variables corresponding to the correct include paths to use for
3390 # in-tree building.
3391 #
3393 # for config.h:
3394 config_h_INCLUDES='-I$(top_builddir)'
3395 AC_SUBST(config_h_INCLUDES)
3397 # glib:
3398 # config.h
3399 # $(top_builddir)/glib: for glibconfig.h
3400 # $(top_srcdir)/glib: for glib.h
3401 # $(top_srcdir): for everything
3402 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3403 AC_SUBST(glib_INCLUDES)
3405 # gobject:
3406 # same as glib
3407 gobject_INCLUDES='$(glib_INCLUDES)'
3408 AC_SUBST(gobject_INCLUDES)
3410 # gmodule:
3411 # glib includes
3412 # $(top_srcdir)/gmodule: for gmodule.h
3413 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3414 AC_SUBST(gmodule_INCLUDES)
3416 # gio:
3417 # same as gmodule
3418 gio_INCLUDES='$(gmodule_INCLUDES)'
3419 AC_SUBST(gio_INCLUDES)
3422 AC_CONFIG_FILES([
3423 glib-2.0.pc
3424 gmodule-2.0.pc
3425 gmodule-export-2.0.pc
3426 gmodule-no-export-2.0.pc
3427 gthread-2.0.pc
3428 gobject-2.0.pc
3429 gio-2.0.pc
3430 gio-unix-2.0.pc
3431 gio-windows-2.0.pc
3432 glib-zip
3433 glib-gettextize
3434 Makefile
3435 build/Makefile
3436 build/win32/Makefile
3437 build/win32/dirent/Makefile
3438 win32/Makefile
3439 win32/vs9/Makefile
3440 win32/vs9/glib-version-paths.vsprops
3441 win32/vs10/Makefile
3442 win32/vs10/glib-version-paths.props
3443 win32/vs11/Makefile
3444 win32/vs12/Makefile
3445 win32/vs14/Makefile
3446 win32/vs15/Makefile
3447 glib/Makefile
3448 glib/libcharset/Makefile
3449 glib/gnulib/Makefile
3450 glib/pcre/Makefile
3451 glib/update-pcre/Makefile
3452 glib/tests/Makefile
3453 gmodule/Makefile
3454 gmodule/gmoduleconf.h
3455 gobject/Makefile
3456 gobject/glib-mkenums
3457 gobject/tests/Makefile
3458 gthread/Makefile
3459 gio/Makefile
3460 gio/gdbus-2.0/codegen/Makefile
3461 gio/gdbus-2.0/codegen/config.py
3462 gio/gnetworking.h
3463 gio/xdgmime/Makefile
3464 gio/inotify/Makefile
3465 gio/kqueue/Makefile
3466 gio/fam/Makefile
3467 gio/win32/Makefile
3468 gio/tests/Makefile
3469 gio/tests/gdbus-object-manager-example/Makefile
3470 gio/tests/services/Makefile
3471 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3472 gio/tests/modules/Makefile
3473 po/Makefile.in
3474 docs/Makefile
3475 docs/reference/Makefile
3476 docs/reference/glib/Makefile
3477 docs/reference/glib/version.xml
3478 docs/reference/gobject/Makefile
3479 docs/reference/gobject/version.xml
3480 docs/reference/gio/Makefile
3481 docs/reference/gio/version.xml
3482 tests/Makefile
3483 tests/gobject/Makefile
3484 tests/refcount/Makefile
3485 m4macros/Makefile
3486 ])
3488 AC_CONFIG_COMMANDS([chmod-scripts],
3489 [chmod 0755 glib-zip
3490 chmod 0755 glib-gettextize
3491 chmod 0755 gobject/glib-mkenums])
3493 # we want to invoke this macro solely so that the config.status script
3494 # and automake generated makefiles know about these generated files.
3495 # They are only needed to distcheck the package
3496 if false; then
3497 AC_CONFIG_FILES([
3498 INSTALL
3499 README
3500 config.h.win32
3501 glib/glibconfig.h.win32
3502 glib/makefile.msc
3503 glib/glib.rc
3504 gmodule/makefile.msc
3505 gmodule/gmodule.rc
3506 gobject/makefile.msc
3507 gobject/gobject.rc
3508 gthread/makefile.msc
3509 gthread/gthread.rc
3510 gio/gio.rc
3511 tests/makefile.msc
3512 ])
3513 fi
3515 AC_OUTPUT