| blob | 06fac48af3cb101f6f6c33d2c69e9f2a34f93c20 |
1 # Process this file with autoconf to produce a configure script.
2 AC_PREREQ([2.62])
4 dnl ***********************************
5 dnl *** include special GLib macros ***
6 dnl ***********************************
8 m4_define(glib_configure_ac)
10 #
11 # The following version number definitions apply to GLib, GModule, GObject,
12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
13 # all treated with the same interface and binary age.
14 #
15 # Making releases:
16 # glib_micro_version += 1;
17 # glib_interface_age += 1;
18 # glib_binary_age += 1;
19 # if any functions have been added, set glib_interface_age to 0.
20 # if backwards compatibility has been broken,
21 # set glib_binary_age _and_ glib_interface_age to 0.
22 #
23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
25 # for that version - see gversion.h for further information.
26 #
27 # in easier to understand terms:
28 #
29 # <mclasen> on the stable branch, interface age == micro
30 # <mclasen> on the unstable (ie master), interface age = 0
32 m4_define([glib_major_version], [2])
33 m4_define([glib_minor_version], [57])
34 m4_define([glib_micro_version], [1])
35 m4_define([glib_interface_age], [0])
36 m4_define([glib_binary_age],
37 [m4_eval(100 * glib_minor_version + glib_micro_version)])
38 m4_define([glib_version],
39 [glib_major_version.glib_minor_version.glib_micro_version])
41 # libtool version related macros
42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
43 m4_define([glib_lt_current],
44 [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
45 m4_define([glib_lt_revision], [glib_interface_age])
46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
47 m4_define([glib_lt_current_minus_age],
48 [m4_eval(glib_lt_current - glib_lt_age)])
50 # if the minor version number is odd, then we want debugging. Otherwise
51 # we only want minimal debugging support.
52 m4_define([glib_debug_default],
53 [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
56 AC_INIT(glib, [glib_version],
57 [https://gitlab.gnome.org/GNOME/glib/issues/new])
59 AC_CONFIG_HEADERS([config.h])
60 AC_CONFIG_SRCDIR([glib/glib.h])
61 AC_CONFIG_MACRO_DIR([m4macros])
63 # Save this value here, since automake will set cflags later
64 cflags_set=${CFLAGS:+set}
66 AM_INIT_AUTOMAKE([1.13.3 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar subdir-objects])
67 AM_MAINTAINER_MODE([enable])
69 # Support silent build rules. Disable
70 # by either passing --disable-silent-rules to configure or passing V=1
71 # to make
72 AM_SILENT_RULES([yes])
74 GLIB_MAJOR_VERSION=glib_major_version
75 GLIB_MINOR_VERSION=glib_minor_version
76 GLIB_MICRO_VERSION=glib_micro_version
77 GLIB_INTERFACE_AGE=glib_interface_age
78 GLIB_BINARY_AGE=glib_binary_age
79 GLIB_VERSION=glib_version
81 AC_SUBST(GLIB_MAJOR_VERSION)
82 AC_SUBST(GLIB_MINOR_VERSION)
83 AC_SUBST(GLIB_MICRO_VERSION)
84 AC_SUBST(GLIB_VERSION)
85 AC_SUBST(GLIB_INTERFACE_AGE)
86 AC_SUBST(GLIB_BINARY_AGE)
88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
89 [Define to the GLIB major version])
90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
91 [Define to the GLIB minor version])
92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
93 [Define to the GLIB micro version])
94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
95 [Define to the GLIB interface age])
96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
97 [Define to the GLIB binary age])
99 # libtool versioning
100 LT_RELEASE=glib_lt_release
101 LT_CURRENT=glib_lt_current
102 LT_REVISION=glib_lt_revision
103 LT_AGE=glib_lt_age
104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
105 AC_SUBST(LT_RELEASE)
106 AC_SUBST(LT_CURRENT)
107 AC_SUBST(LT_REVISION)
108 AC_SUBST(LT_AGE)
109 AC_SUBST(LT_CURRENT_MINUS_AGE)
111 dnl Checks for programs.
112 AC_PROG_CC
113 AC_PROG_CPP
114 AC_USE_SYSTEM_EXTENSIONS
116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
118 AC_CANONICAL_HOST
120 dnl
122 AC_MSG_CHECKING([for Win32])
123 LIB_EXE_MACHINE_FLAG=X86
124 case "$host" in
125 *-*-mingw*)
126 glib_native_win32=yes
127 glib_pid_type='void *'
128 glib_pid_format='p'
129 glib_pollfd_format='%#x'
130 glib_dir_separator='\\\\'
131 glib_searchpath_separator=';'
132 glib_cv_stack_grows=no
133 # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
134 # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
135 # (Sorry, I don't know exactly what is the problem, but it is related to
136 # floating point formatting and decimal point vs. comma.)
137 # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
138 # rigorous enough to notice, though.
139 # So preset the autoconf cache variables.
140 ac_cv_func_vsnprintf_c99=no
141 ac_cv_func_snprintf_c99=no
142 case "$host" in
143 x86_64-*-*)
144 LIB_EXE_MACHINE_FLAG=X64
145 glib_pollfd_format='%#I64x'
146 ;;
147 esac
149 AC_DEFINE([_WIN32_WINNT], [0x0601], [Target the Windows 7 API])
150 ;;
151 *)
152 glib_native_win32=no
153 glib_pid_type=int
154 glib_pid_format='i'
155 glib_pollfd_format='%d'
156 glib_dir_separator='/'
157 glib_searchpath_separator=':'
158 ;;
159 esac
160 case $host in
161 *-*-linux*)
162 glib_os_linux=yes
163 ;;
164 esac
166 AC_MSG_RESULT([$glib_native_win32])
168 AC_MSG_CHECKING([for the Android])
169 case $host in
170 *android*)
171 glib_native_android="yes"
172 ;;
173 *)
174 glib_native_android="no"
175 ;;
176 esac
177 AC_MSG_RESULT([$glib_native_android])
179 AC_SUBST(LIB_EXE_MACHINE_FLAG)
181 glib_have_carbon=no
182 AC_MSG_CHECKING([for Mac OS X Carbon support])
183 AC_TRY_CPP([
184 #include <Carbon/Carbon.h>
185 #include <CoreServices/CoreServices.h>
186 ], glib_have_carbon=yes)
188 AC_MSG_RESULT([$glib_have_carbon])
190 glib_have_cocoa=no
191 AC_MSG_CHECKING([for Mac OS X Cocoa support])
192 AC_TRY_CPP([
193 #include <Cocoa/Cocoa.h>
194 #ifdef GNUSTEP_BASE_VERSION
195 #error "Detected GNUstep, not Cocoa"
196 #endif
197 ], glib_have_cocoa=yes)
199 AC_MSG_RESULT([$glib_have_cocoa])
201 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
202 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
203 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
204 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
205 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
206 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
208 AS_IF([test "$glib_native_win32" = "yes"], [
209 AC_CHECK_TOOL(WINDRES, windres, no)
210 if test "$WINDRES" = no; then
211 AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
212 fi
213 AC_CHECK_TOOL(NM, nm, no)
214 if test "$NM" = no; then
215 AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
216 fi
217 AC_CHECK_TOOL(RANLIB, ranlib, :)
218 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
219 AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
220 ])
221 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
223 AS_IF([test "x$glib_have_carbon" = "xyes"], [
224 AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
225 CARBON_LIBS="-Wl,-framework,Carbon"
226 LDFLAGS="$LDFLAGS $CARBON_LIBS"
227 ], [CARBON_LIBS=""])
229 AC_SUBST([CARBON_LIBS])
230 ac_cv_have_os_x_9_or_later="no"
231 AS_IF([test "x$glib_have_cocoa" = "xyes"], [
232 AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
233 COCOA_LIBS="-Wl,-framework,Foundation -Wl,-framework,AppKit"
234 LDFLAGS="$LDFLAGS $COCOA_LIBS"
235 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
236 #include <AvailabilityMacros.h>
237 #if MAC_OS_X_VERSION_MIN_REQUIRED < 1090
238 #error Compiling for minimum OS X version before 10.9
239 #endif
240 ]])],[ac_cv_have_os_x_9_or_later="yes"])
241 ], [COCOA_LIBS=""])
242 AM_CONDITIONAL([MAC_OS_X_9], [test "x$ac_cv_have_os_x_9_or_later" = xyes])
243 AC_SUBST([COCOA_LIBS])
245 dnl declare --enable-* args and collect ac_help strings
246 AC_ARG_ENABLE(debug,
247 AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
248 [turn on debugging @<:@default=glib_debug_default@:>@]),,
249 enable_debug=glib_debug_default)
251 GLIB_TESTS
253 dnl location to install runtime libraries, e.g. ../../lib to install
254 dnl to /lib if libdir is /usr/lib
255 AC_ARG_WITH(runtime-libdir,
256 [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
257 [install runtime libraries relative to libdir])],
258 [],
259 [with_runtime_libdir=""])
260 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
261 AC_SUBST(GLIB_RUNTIME_LIBDIR)
262 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
264 dnl Check for a working C++ compiler, but do not bail out, if none is found.
265 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
266 AC_LANG_SAVE
267 AC_LANG_CPLUSPLUS
268 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
269 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
270 AC_LANG_RESTORE
272 AM_PROG_CC_C_O
273 AC_PROG_INSTALL
275 AC_SYS_LARGEFILE
277 PKG_PROG_PKG_CONFIG(0.16)
279 if test "x$enable_debug" = "xyes"; then
280 if test "x$cflags_set" != "x" ; then
281 case " $CFLAGS " in
282 *[[\ \ ]]-g[[\ \ ]]*) ;;
283 *) CFLAGS="$CFLAGS -g" ;;
284 esac
285 fi
286 GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
287 else
288 GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
290 if test "x$enable_debug" = "xno"; then
291 GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
292 fi
293 fi
295 # Ensure MSVC-compatible struct packing convention is used when
296 # compiling for Win32 with gcc.
297 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
298 # gcc2 uses "-fnative-struct".
299 if test x"$glib_native_win32" = xyes; then
300 if test x"$GCC" = xyes; then
301 msnative_struct=''
302 AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
303 if test -z "$ac_cv_prog_CC"; then
304 our_gcc="$CC"
305 else
306 our_gcc="$ac_cv_prog_CC"
307 fi
308 case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
309 2.)
310 if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
311 msnative_struct='-fnative-struct'
312 fi
313 ;;
314 *)
315 if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
316 msnative_struct='-mms-bitfields'
317 fi
318 ;;
319 esac
320 if test x"$msnative_struct" = x ; then
321 AC_MSG_RESULT([no way])
322 AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
323 else
324 CFLAGS="$CFLAGS $msnative_struct"
325 AC_MSG_RESULT([${msnative_struct}])
326 fi
327 fi
328 fi
329 GLIB_EXTRA_CFLAGS="${msnative_struct}"
330 AC_SUBST(GLIB_EXTRA_CFLAGS)
332 AC_EXEEXT
334 AC_PROG_AWK
335 AC_CHECK_PROGS(PERL, [perl5 perl])
337 # option to specify python interpreter to use; this just sets $PYTHON, so that
338 # we will fallback to reading $PYTHON if --with-python is not given, and
339 # python.m4 will get the expected input
340 AC_ARG_WITH(python,
341 AS_HELP_STRING([--with-python=PATH],
342 [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
343 [PYTHON="$withval"], [])
344 if test x"$PYTHON" = xyes; then
345 AC_MSG_ERROR([--with-python option requires a path or program argument])
346 fi
347 AM_PATH_PYTHON(2.7,,PYTHON="python2.7")
350 dnl ***********************
351 dnl *** Tests for iconv ***
352 dnl ***********************
353 dnl
354 dnl We do this before the gettext checks, to avoid distortion
356 dnl On Windows we use a native implementation
358 AS_IF([ test x"$glib_native_win32" = xyes], [
359 with_libiconv=native
360 ], [
361 AC_ARG_WITH(libiconv,
362 [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
363 [use the libiconv library])],,
364 [with_libiconv=maybe])
366 found_iconv=no
367 case $with_libiconv in
368 maybe)
369 # Check in the C library first
370 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
371 # Check if we have GNU libiconv
372 if test $found_iconv = "no"; then
373 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
374 fi
375 # Check if we have a iconv in -liconv, possibly from vendor
376 if test $found_iconv = "no"; then
377 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
378 fi
379 ;;
380 no)
381 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
382 ;;
383 gnu|yes)
384 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
385 ;;
386 native)
387 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
388 ;;
389 esac
391 if test "x$found_iconv" = "xno" ; then
392 AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
393 fi
394 ])
396 dnl
397 dnl zlib support
398 dnl
399 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
400 AS_IF([test "x$found_zlib" = "xno"], [
401 AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
402 if test "x$found_zlib" = "xno" ; then
403 AC_MSG_ERROR([*** Working zlib library and headers not found ***])
404 fi
405 ZLIB_LIBS='-lz'
406 AC_SUBST(ZLIB_LIBS)
407 ])
409 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
410 AC_SUBST(LIBFFI_CFLAGS)
411 AC_SUBST(LIBFFI_LIBS)
413 dnl
414 dnl gettext support
415 dnl
417 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
418 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
419 GLIB_GNU_GETTEXT
421 if test "$gt_cv_have_gettext" != "yes" ; then
422 AC_MSG_ERROR([
423 *** You must have either have gettext support in your C library, or use the
424 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html)
425 ])
426 fi
428 LIBS="$INTLLIBS $LIBS"
430 GETTEXT_PACKAGE=glib20
431 AC_SUBST(GETTEXT_PACKAGE)
432 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
433 [Define the gettext package to be used])
435 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
437 dnl
438 dnl Now we are done with gettext checks, figure out ICONV_LIBS
439 dnl
441 AS_IF([test x"$glib_native_win32" != xyes], [
442 if test x$with_libiconv != xno ; then
443 case " $INTLLIBS " in
444 *[[\ \ ]]-liconv[[\ \ ]]*) ;;
445 *) ICONV_LIBS="-liconv" ;;
446 esac
447 fi
448 ])
449 AC_SUBST(ICONV_LIBS)
451 case $with_libiconv in
452 gnu)
453 AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
454 ;;
455 native)
456 AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
457 ;;
458 esac
460 dnl Initialize libtool
461 LT_PREREQ([2.2])
462 LT_INIT([disable-static win32-dll])
463 dnl when using libtool 2.x create libtool early, because it's used in configure
464 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
467 AS_IF([test "$glib_native_win32" = "yes"], [
468 if test x$enable_static = xyes -a x$enable_shared = xyes; then
469 AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
470 fi
471 if test x$enable_static = xyes; then
472 glib_win32_static_compilation=yes
473 GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
474 #define GOBJECT_STATIC_COMPILATION 1"
475 AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
476 fi
477 ])
478 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
480 # Checks for library functions.
481 AC_FUNC_ALLOCA
482 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
483 AC_CHECK_FUNCS(timegm gmtime_r posix_spawn)
484 AC_FUNC_STRERROR_R()
486 AC_CHECK_SIZEOF(char)
487 AC_CHECK_SIZEOF(short)
488 AC_CHECK_SIZEOF(long)
489 AC_CHECK_SIZEOF(int)
490 AC_CHECK_SIZEOF(void *)
491 AC_CHECK_SIZEOF(long long)
492 AC_CHECK_SIZEOF(__int64)
494 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
495 [AC_TRY_LINK([#include <signal.h>
496 #include <sys/types.h>
497 sig_atomic_t val = 42;],
498 [return val == 42 ? 0 : 1],
499 ac_cv_type_sig_atomic_t=yes,
500 ac_cv_type_sig_atomic_t=no)])
501 if test x$ac_cv_type_sig_atomic_t = xyes; then
502 AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
503 [Define if you have the 'sig_atomic_t' type.])
504 fi
506 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
507 :
508 else
509 AC_MSG_ERROR([
510 *** GLib requires a 64 bit type. You might want to consider
511 *** using the GNU C compiler.
512 ])
513 fi
515 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
516 # long long is a 64 bit integer.
517 AC_MSG_CHECKING(for format to printf and scanf a guint64)
518 AC_CACHE_VAL(glib_cv_long_long_format,[
519 for format in ll q I64; do
520 AC_TRY_RUN([#include <stdio.h>
521 int main()
522 {
523 long long b, a = -0x3AFAFAFAFAFAFAFALL;
524 char buffer[1000];
525 sprintf (buffer, "%${format}u", a);
526 sscanf (buffer, "%${format}u", &b);
527 exit (b!=a);
528 }
529 ],
530 [glib_cv_long_long_format=${format}
531 break],
532 [],[:])
533 done])
534 AS_IF([ test -n "$glib_cv_long_long_format"], [
535 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
536 ], [AC_MSG_RESULT(none)])
537 ],[ test x$ac_cv_sizeof___int64 = x8], [
538 # __int64 is a 64 bit integer.
539 AC_MSG_CHECKING(for format to printf and scanf a guint64)
540 # We know this is MSVCRT.DLL, and what the formats are
541 glib_cv_long_long_format=I64
542 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
543 ])
545 AC_C_CONST
547 dnl
548 dnl check in which direction the stack grows
549 dnl
550 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
551 AC_TRY_RUN([
552 volatile int *a = 0, *b = 0;
553 void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
554 int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
555 ],
556 glib_cv_stack_grows=yes
557 ,
558 glib_cv_stack_grows=no
559 ,)
560 ])
562 # check for flavours of varargs macros
563 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
564 AC_TRY_COMPILE([],[
565 int a(int p1, int p2, int p3);
566 #define call_a(...) a(1,__VA_ARGS__)
567 call_a(2,3);
568 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
569 AC_MSG_RESULT($g_have_iso_c_varargs)
571 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
572 AS_IF([test "$CXX" = ""], [
573 dnl No C++ compiler
574 g_have_iso_cxx_varargs=no
575 else
576 AC_LANG_CPLUSPLUS
577 AC_TRY_COMPILE([],[
578 int a(int p1, int p2, int p3);
579 #define call_a(...) a(1,__VA_ARGS__)
580 call_a(2,3);
581 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
582 AC_LANG_C
583 ])
584 AC_MSG_RESULT($g_have_iso_cxx_varargs)
586 AC_MSG_CHECKING(for GNUC varargs macros)
587 AC_TRY_COMPILE([],[
588 int a(int p1, int p2, int p3);
589 #define call_a(params...) a(1,params)
590 call_a(2,3);
591 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
592 AC_MSG_RESULT($g_have_gnuc_varargs)
594 # check for GNUC visibility support
595 AC_MSG_CHECKING(for GNUC visibility attribute)
596 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
597 void
598 __attribute__ ((visibility ("hidden")))
599 f_hidden (void)
600 {
601 }
602 void
603 __attribute__ ((visibility ("internal")))
604 f_internal (void)
605 {
606 }
607 void
608 __attribute__ ((visibility ("protected")))
609 f_protected (void)
610 {
611 }
612 void
613 __attribute__ ((visibility ("default")))
614 f_default (void)
615 {
616 }
617 int main (void)
618 {
619 f_hidden();
620 f_internal();
621 f_protected();
622 f_default();
623 return 0;
624 }
625 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
626 AC_MSG_RESULT($g_have_gnuc_visibility)
627 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
629 AC_MSG_CHECKING([whether using Sun Studio C compiler])
630 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
631 #else
632 # include "error: this is not Sun Studio."
633 #endif
634 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
635 AC_MSG_RESULT($g_have_sunstudio_visibility)
636 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
638 # check for bytesex stuff
639 AC_C_BIGENDIAN
640 if test x$ac_cv_c_bigendian = xuniversal ; then
641 AC_MSG_ERROR([Universal builds not supported: see https://bugzilla.gnome.org/show_bug.cgi?id=742548])
642 fi
645 # check for header files
646 AC_CHECK_HEADERS([sys/param.h sys/resource.h mach/mach_time.h])
647 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
648 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h sys/auxv.h])
649 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
650 AC_CHECK_HEADERS([linux/magic.h])
651 AC_CHECK_HEADERS([termios.h])
653 # Some versions of MSC lack these
654 AC_CHECK_HEADERS([dirent.h sys/time.h])
656 # We don't care about this, but we need to keep including it in
657 # glibconfig.h for backward compatibility
658 AC_CHECK_HEADERS([values.h])
660 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
661 [#if HAVE_SYS_PARAM_H
662 #include <sys/param.h>
663 #endif
664 ])
665 AC_CHECK_FUNCS(sysctlbyname)
667 AC_HEADER_MAJOR
668 AS_IF([test "$ac_cv_header_sys_types_h_makedev" = "yes"],
669 [AC_DEFINE([MAJOR_IN_TYPES], [1], [Define to 1 if `major', `minor', and `makedev' are declared in <sys/types.h>.])])
670 AC_CHECK_HEADERS([xlocale.h])
672 # check for structure fields
673 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec, struct stat.st_birthtime, struct stat.st_birthtimensec, struct stat.st_birthtim, struct stat.st_birthtim.tv_nsec])
674 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
675 #include <sys/stat.h>
676 #ifdef G_OS_UNIX
677 #include <unistd.h>
678 #endif
679 #ifdef HAVE_SYS_STATFS_H
680 #include <sys/statfs.h>
681 #endif
682 #ifdef HAVE_SYS_PARAM_H
683 #include <sys/param.h>
684 #endif
685 #ifdef HAVE_SYS_MOUNT_H
686 #include <sys/mount.h>
687 #endif])
688 # struct statvfs.f_basetype is available on Solaris but not for Linux.
689 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
690 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
691 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
693 AC_STRUCT_DIRENT_D_TYPE
695 # Checks for libcharset
696 AM_LANGINFO_CODESET
697 gl_GLIBC21
698 AC_ARG_WITH(charsetalias-dir,
699 AS_HELP_STRING([--with-charsetalias-dir=DIR], [directory for charset.alias file [LIBDIR]]),
700 [],
701 [with_charsetalias_dir='${libdir}'])
702 GLIB_CHARSETALIAS_DIR=$with_charsetalias_dir
703 AC_SUBST(GLIB_CHARSETALIAS_DIR)
705 # check additional type sizes
706 AC_CHECK_SIZEOF(size_t)
708 dnl Try to figure out whether gsize should be long or int
709 AC_MSG_CHECKING([for the appropriate definition for size_t])
711 case $ac_cv_sizeof_size_t in
712 $ac_cv_sizeof_short)
713 glib_size_type=short
714 ;;
715 $ac_cv_sizeof_int)
716 glib_size_type=int
717 ;;
718 $ac_cv_sizeof_long)
719 glib_size_type=long
720 ;;
721 $ac_cv_sizeof_long_long)
722 glib_size_type='long long'
723 ;;
724 $ac_cv_sizeof__int64)
725 glib_size_type='__int64'
726 ;;
727 *) AC_MSG_ERROR([No type matching size_t in size])
728 ;;
729 esac
731 dnl If int/long are the same size, we see which one produces
732 dnl warnings when used in the location as size_t. (This matters
733 dnl on AIX with xlc)
734 dnl
735 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
736 test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
737 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
738 #if defined(_AIX) && !defined(__GNUC__)
739 #pragma options langlvl=stdc89
740 #endif
741 #include <stddef.h>
742 int main ()
743 {
744 size_t s = 1;
745 unsigned int *size_int = &s;
746 return (int)*size_int;
747 }
748 ]])],glib_size_type=int,
749 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
750 #if defined(_AIX) && !defined(__GNUC__)
751 #pragma options langlvl=stdc89
752 #endif
753 #include <stddef.h>
754 int main ()
755 {
756 size_t s = 1;
757 unsigned long *size_long = &s;
758 return (int)*size_long;
759 }
760 ]])],glib_size_type=long)])
761 ])
763 AC_MSG_RESULT(unsigned $glib_size_type)
765 AC_CHECK_SIZEOF(ssize_t)
767 dnl Try to figure out whether gssize should be long or int
768 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
770 case $ac_cv_sizeof_ssize_t in
771 $ac_cv_sizeof_short)
772 glib_ssize_type=short
773 ;;
774 $ac_cv_sizeof_int)
775 glib_ssize_type=int
776 ;;
777 $ac_cv_sizeof_long)
778 glib_ssize_type=long
779 ;;
780 $ac_cv_sizeof_long_long)
781 glib_ssize_type='long long'
782 ;;
783 $ac_cv_sizeof__int64)
784 glib_ssize_type='__int64'
785 ;;
786 *) AC_MSG_ERROR([No type matching ssize_t in size])
787 ;;
788 esac
790 dnl If int/long are the same size, we see which one produces
791 dnl warnings when used in the location as ssize_t. (This matters
792 dnl on Android where ssize_t is long and size_t is unsigned int)
793 dnl
794 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
795 test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
796 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
797 #if defined(_AIX) && !defined(__GNUC__)
798 #pragma options langlvl=stdc89
799 #endif
800 #include <stddef.h>
801 #ifdef HAVE_INTTYPES_H
802 # include <inttypes.h>
803 #endif
804 #ifdef HAVE_STDINT_H
805 # include <stdint.h>
806 #endif
807 #include <sys/types.h>
808 int main ()
809 {
810 ssize_t s = 1;
811 int *size_int = &s;
812 return (int)*size_int;
813 }
814 ]])],glib_ssize_type=int,
815 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
816 #if defined(_AIX) && !defined(__GNUC__)
817 #pragma options langlvl=stdc89
818 #endif
819 #include <stddef.h>
820 #ifdef HAVE_INTTYPES_H
821 # include <inttypes.h>
822 #endif
823 #ifdef HAVE_STDINT_H
824 # include <stdint.h>
825 #endif
826 #include <sys/types.h>
827 int main ()
828 {
829 ssize_t s = 1;
830 long *size_long = &s;
831 return (int)*size_long;
832 }
833 ]])],glib_ssize_type=long)])
834 ])
836 AC_MSG_RESULT($glib_ssize_type)
838 # Check for some functions
839 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk mkostemp link)
840 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
841 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
842 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
843 AC_CHECK_FUNCS(splice)
844 AC_CHECK_FUNCS(prlimit)
846 # To avoid finding a compatibility unusable statfs, which typically
847 # successfully compiles, but warns to use the newer statvfs interface:
848 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
849 AS_IF([test $ac_cv_header_sys_statfs_h = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
851 AC_MSG_CHECKING([whether to use statfs or statvfs])
852 # Some systems have both statfs and statvfs, pick the most "native" for these
853 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
854 [
855 # on solaris and irix, statfs doesn't even have the f_bavail field
856 AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
857 [ac_cv_func_statfs=no],
858 # else, at least on linux, statfs is the actual syscall
859 [ac_cv_func_statvfs=no])
860 ])
862 AS_IF([test x$ac_cv_func_statfs = xyes],
863 [
864 AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
865 AC_MSG_RESULT([statfs])
866 ],
867 [test x$ac_cv_func_statvfs = xyes],
868 [
869 AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
870 AC_MSG_RESULT([statvfs])
871 ],
872 [ AC_MSG_RESULT([neither])])
874 AC_CHECK_HEADERS(crt_externs.h)
875 AC_CHECK_FUNCS(_NSGetEnviron)
877 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
879 # Internet address families
880 if test $glib_native_win32 = yes; then
881 glib_inet_includes=["
882 #include <winsock2.h>
883 "]
884 else
885 glib_inet_includes=["
886 #include <sys/types.h>
887 #include <sys/socket.h>
888 "]
889 fi
891 glib_failed=false
892 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
893 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
894 # winsock defines this even though it doesn't support it
895 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
896 if $glib_failed ; then
897 AC_MSG_ERROR([Could not determine values for AF_INET* constants])
898 fi
900 glib_failed=false
901 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
902 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
903 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
904 if $glib_failed ; then
905 AC_MSG_ERROR([Could not determine values for MSG_* constants])
906 fi
908 AC_CHECK_FUNCS(endservent if_nametoindex if_indextoname sendmmsg recvmmsg)
910 AC_MSG_CHECKING([for SIOCGIFADDR])
911 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
912 [[
913 #include <sys/ioctl.h>
914 #include <net/if.h>
915 ]],
916 [[
917 struct ifreq ifr;
918 ioctl(0, SIOCGIFADDR, &ifr);
919 ]])], [
920 AC_MSG_RESULT(yes)
921 AC_DEFINE(HAVE_SIOCGIFADDR, 1, [SIOCGIFADDR is available])
922 ], [
923 AC_MSG_RESULT(no)
924 ])
926 AC_MSG_CHECKING([if ip_mreq_source.imr_interface has s_addr member])
927 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
928 [[
929 #include <netinet/in.h>
930 ]],
931 [[
932 struct ip_mreq_source mc_req_src;
933 mc_req_src.imr_interface.s_addr = 0;
934 ]])], [
935 AC_MSG_RESULT(yes)
936 ], [
937 AC_MSG_RESULT(no)
938 AC_DEFINE(BROKEN_IP_MREQ_SOURCE_STRUCT, 1, [struct ip_mreq_source definition is broken on Android NDK <= r16])
939 ])
941 AS_IF([test $glib_native_win32 = yes], [
942 # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
943 # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
944 # they aren't present at run-time (on Windows 2000).
945 AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
946 AC_SUBST(WSPIAPI_INCLUDE)
947 ], [
948 # Android does not have C_IN in public headers, we define it wherever necessary
949 AS_IF([test $glib_native_android != yes], [
950 AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
951 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
952 #include <arpa/nameser.h>],
953 [int qclass = C_IN;])],
954 [AC_MSG_RESULT([no])],
955 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
956 #include <arpa/nameser.h>
957 #include <arpa/nameser_compat.h>],
958 [int qclass = C_IN;])],
959 [AC_MSG_RESULT([yes])
960 NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
961 [AC_MSG_ERROR([could not compile test program either way])])])])
962 AC_SUBST(NAMESER_COMPAT_INCLUDE)
964 # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
965 NETWORK_LIBS=""
966 AC_MSG_CHECKING([for res_query])
967 AC_TRY_LINK([#include <sys/types.h>
968 #include <netinet/in.h>
969 #include <arpa/nameser.h>
970 #include <resolv.h>
971 ],[
972 res_query("test", 0, 0, (void *)0, 0);
973 ],[AC_MSG_RESULT([yes])],
974 [save_libs="$LIBS"
975 LIBS="-lresolv $LIBS"
976 AC_TRY_LINK([#include <sys/types.h>
977 #include <netinet/in.h>
978 #include <arpa/nameser.h>
979 #include <resolv.h>
980 ],[
981 res_query("test", 0, 0, (void *)0, 0);
982 ],[AC_MSG_RESULT([in -lresolv])
983 NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
984 [LIBS="-lbind $save_libs"
985 AC_TRY_LINK([#include <resolv.h>],
986 [res_query("test", 0, 0, (void *)0, 0);],
987 [AC_MSG_RESULT([in -lbind])
988 NETWORK_LIBS="-lbind $NETWORK_LIBS"],
989 [AC_MSG_ERROR(not found)])])
990 LIBS="$save_libs"])
991 AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
992 [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
993 [AC_MSG_ERROR(Could not find socket())]))
994 save_libs="$LIBS"
995 LIBS="$LIBS $NETWORK_LIBS"
997 AC_MSG_CHECKING([for res_init])
998 AC_TRY_LINK([#include <sys/types.h>
999 #include <netinet/in.h>
1000 #include <arpa/nameser.h>
1001 #include <resolv.h>
1002 ],[
1003 res_init();
1004 ],[AC_MSG_RESULT([yes])
1005 AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1006 ],[AC_MSG_RESULT([no])])
1008 AC_MSG_CHECKING([for res_nclose])
1009 AC_TRY_LINK([#include <sys/types.h>
1010 #include <netinet/in.h>
1011 #include <arpa/nameser.h>
1012 #include <resolv.h>
1013 ],[
1014 struct __res_state res;
1015 res_nclose(&res);
1016 ],[AC_MSG_RESULT([yes])
1017 AC_DEFINE(HAVE_RES_NCLOSE, 1, [Define to 1 if you have the 'res_nclose' function.])
1018 ],[AC_MSG_RESULT([no])])
1020 AC_MSG_CHECKING([for res_ndestroy])
1021 AC_TRY_LINK([#include <sys/types.h>
1022 #include <netinet/in.h>
1023 #include <arpa/nameser.h>
1024 #include <resolv.h>
1025 ],[
1026 struct __res_state res;
1027 res_ndestroy(&res);
1028 ],[AC_MSG_RESULT([yes])
1029 AC_DEFINE(HAVE_RES_NDESTROY, 1, [Define to 1 if you have the 'res_ndestroy' function.])
1030 ],[AC_MSG_RESULT([no])])
1032 AC_MSG_CHECKING([for res_ninit])
1033 AC_TRY_LINK([#include <sys/types.h>
1034 #include <netinet/in.h>
1035 #include <arpa/nameser.h>
1036 #include <resolv.h>
1037 ],[
1038 struct __res_state res;
1039 res_ninit(&res);
1040 ],[AC_MSG_RESULT([yes])
1041 AC_DEFINE(HAVE_RES_NINIT, 1, [Define to 1 if you have the 'res_ninit' function.])
1042 ],[AC_MSG_RESULT([no])])
1044 AC_MSG_CHECKING([for res_nquery])
1045 AC_TRY_LINK([#include <sys/types.h>
1046 #include <netinet/in.h>
1047 #include <arpa/nameser.h>
1048 #include <resolv.h>
1049 ],[
1050 struct __res_state res;
1051 res_nquery(&res, "test", 0, 0, (void *)0, 0);
1052 ],[AC_MSG_RESULT([yes])
1053 AC_DEFINE(HAVE_RES_NQUERY, 1, [Define to 1 if you have the 'res_nquery' function.])
1054 ],[AC_MSG_RESULT([no])])
1055 LIBS="$save_libs"
1056 ])
1057 AC_SUBST(NETWORK_LIBS)
1059 AC_CHECK_HEADER([linux/netlink.h],
1060 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1061 [#include <sys/socket.h>])
1062 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1064 AC_CHECK_TYPE([struct ip_mreqn], [
1065 AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1066 [#include <netinet/in.h>])
1068 case $host in
1069 *-*-solaris* )
1070 AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1071 AC_DEFINE(_XOPEN_SOURCE, 2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1072 AC_DEFINE(__EXTENSIONS__, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1073 ;;
1074 esac
1076 dnl
1077 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1078 dnl
1079 AS_IF([test "$ac_cv_func_statfs" = yes], [
1080 AC_MSG_CHECKING([number of arguments to statfs()])
1081 AC_TRY_COMPILE([#include <unistd.h>
1082 #ifdef HAVE_SYS_PARAM_H
1083 #include <sys/param.h>
1084 #endif
1085 #ifdef HAVE_SYS_VFS_H
1086 #include <sys/vfs.h>
1087 #endif
1088 #ifdef HAVE_SYS_MOUNT_H
1089 #include <sys/mount.h>
1090 #endif
1091 #ifdef HAVE_SYS_STATFS_H
1092 #include <sys/statfs.h>
1093 #endif], [struct statfs st;
1094 statfs("/", &st);],[
1095 AC_MSG_RESULT([2])
1096 AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1097 AC_TRY_COMPILE([#include <unistd.h>
1098 #ifdef HAVE_SYS_PARAM_H
1099 #include <sys/param.h>
1100 #endif
1101 #ifdef HAVE_SYS_VFS_H
1102 #include <sys/vfs.h>
1103 #endif
1104 #ifdef HAVE_SYS_MOUNT_H
1105 #include <sys/mount.h>
1106 #endif
1107 #ifdef HAVE_SYS_STATFS_H
1108 #include <sys/statfs.h>
1109 #endif], [struct statfs st;
1110 statfs("/", &st, sizeof (st), 0);],[
1111 AC_MSG_RESULT([4])
1112 AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1113 AC_MSG_RESULT(unknown)
1114 AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1115 ])
1117 dnl
1118 dnl open takes O_DIRECTORY as an option
1119 dnl
1120 AC_MSG_CHECKING([open() option O_DIRECTORY])
1121 AC_TRY_COMPILE([#include <fcntl.h>
1122 #include <sys/types.h>
1123 #include <sys/stat.h>],
1124 [open(0, O_DIRECTORY, 0);],[
1125 AC_MSG_RESULT([yes])
1126 AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1127 AC_MSG_RESULT([no])])
1129 #
1130 # Check whether to use an included printf
1131 #
1132 AC_FUNC_VSNPRINTF_C99
1133 AC_FUNC_PRINTF_UNIX98
1135 AC_ARG_ENABLE(included-printf,
1136 [AS_HELP_STRING([--enable-included-printf],
1137 [use included printf [default=auto]])],
1138 enable_included_printf="$enableval")
1140 need_included_printf=no
1141 if test "x$enable_included_printf" = "xyes" ; then
1142 need_included_printf=yes
1143 fi
1144 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1145 need_included_printf=yes
1146 fi
1147 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1148 need_included_printf=yes
1149 fi
1150 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1151 test -z "$glib_cv_long_long_format" ; then
1152 need_included_printf=yes
1153 fi
1155 if test "x$enable_included_printf" = "xno" &&
1156 test "x$need_included_printf" = "xyes" ; then
1157 AC_MSG_ERROR([
1158 *** Your C library's printf doesn't appear to have the features that
1159 *** GLib needs, but you specified --enable-included-printf=no.])
1160 fi
1162 enable_included_printf=$need_included_printf
1164 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1165 AS_IF([test "$enable_included_printf" != "yes"], [
1166 AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1167 ], [
1168 if test -z "$glib_cv_long_long_format" ; then
1169 glib_cv_long_long_format="ll"
1170 fi
1171 AC_DEFINE(HAVE_VASPRINTF,1)
1172 ])
1174 # Checks needed for gnulib vasnprintf
1175 bh_C_SIGNED
1176 jm_AC_TYPE_LONG_LONG
1177 gt_TYPE_LONGDOUBLE
1178 gt_TYPE_WCHAR_T
1179 gt_TYPE_WINT_T
1180 AC_TYPE_SIZE_T
1181 AC_CHECK_TYPES(ptrdiff_t)
1182 jm_AC_TYPE_INTMAX_T
1183 AC_CHECK_FUNCS([snprintf strnlen wcslen wcsnlen mbrtowc wcrtomb])
1184 AC_FUNC_SNPRINTF_C99
1186 dnl Check for nl_langinfo and CODESET
1187 AC_LANG_SAVE
1188 AC_LANG_C
1189 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1190 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1191 [char *codeset = nl_langinfo (CODESET);])],
1192 [glib_cv_langinfo_codeset=yes],
1193 [glib_cv_langinfo_codeset=no])])
1194 if test x$glib_cv_langinfo_codeset = xyes; then
1195 AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1196 fi
1198 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1199 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1200 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1201 [char *str;
1202 str = nl_langinfo (PM_STR);
1203 str = nl_langinfo (D_T_FMT);
1204 str = nl_langinfo (D_FMT);
1205 str = nl_langinfo (T_FMT);
1206 str = nl_langinfo (T_FMT_AMPM);
1207 str = nl_langinfo (MON_1);
1208 str = nl_langinfo (ABMON_12);
1209 str = nl_langinfo (DAY_1);
1210 str = nl_langinfo (ABDAY_7);])],
1211 [glib_cv_langinfo_time=yes],
1212 [glib_cv_langinfo_time=no])])
1213 if test x$glib_cv_langinfo_time = xyes; then
1214 AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1215 fi
1217 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1218 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1219 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1220 [char *str;
1221 str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1222 str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1223 str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1224 str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1225 str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1226 str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1227 str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1228 str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1229 str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1230 str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1231 [glib_cv_langinfo_outdigit=yes],
1232 [glib_cv_langinfo_outdigit=no])])
1233 if test x$glib_cv_langinfo_outdigit = xyes; then
1234 AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1235 fi
1237 dnl Check for nl_langinfo and ALTMON_n
1238 AC_CACHE_CHECK([for nl_langinfo (ALTMON_n)], glib_cv_langinfo_altmon,[
1239 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1240 [char *str;
1241 str = nl_langinfo (ALTMON_1);
1242 str = nl_langinfo (ALTMON_2);
1243 str = nl_langinfo (ALTMON_3);
1244 str = nl_langinfo (ALTMON_4);
1245 str = nl_langinfo (ALTMON_5);
1246 str = nl_langinfo (ALTMON_6);
1247 str = nl_langinfo (ALTMON_7);
1248 str = nl_langinfo (ALTMON_8);
1249 str = nl_langinfo (ALTMON_9);
1250 str = nl_langinfo (ALTMON_10);
1251 str = nl_langinfo (ALTMON_11);
1252 str = nl_langinfo (ALTMON_12);])],
1253 [glib_cv_langinfo_altmon=yes],
1254 [glib_cv_langinfo_altmon=no])])
1255 if test x$glib_cv_langinfo_altmon = xyes; then
1256 AC_DEFINE(HAVE_LANGINFO_ALTMON,1,[Have nl_langinfo (ALTMON_n)])
1257 fi
1259 dnl Check for nl_langinfo and _NL_ABALTMON_n
1260 AC_CACHE_CHECK([for nl_langinfo (_NL_ABALTMON_n)], glib_cv_langinfo_abaltmon,[
1261 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1262 [char *str;
1263 str = nl_langinfo (_NL_ABALTMON_1);
1264 str = nl_langinfo (_NL_ABALTMON_2);
1265 str = nl_langinfo (_NL_ABALTMON_3);
1266 str = nl_langinfo (_NL_ABALTMON_4);
1267 str = nl_langinfo (_NL_ABALTMON_5);
1268 str = nl_langinfo (_NL_ABALTMON_6);
1269 str = nl_langinfo (_NL_ABALTMON_7);
1270 str = nl_langinfo (_NL_ABALTMON_8);
1271 str = nl_langinfo (_NL_ABALTMON_9);
1272 str = nl_langinfo (_NL_ABALTMON_10);
1273 str = nl_langinfo (_NL_ABALTMON_11);
1274 str = nl_langinfo (_NL_ABALTMON_12);])],
1275 [glib_cv_langinfo_abaltmon=yes],
1276 [glib_cv_langinfo_abaltmon=no])])
1277 if test x$glib_cv_langinfo_abaltmon = xyes; then
1278 AC_DEFINE(HAVE_LANGINFO_ABALTMON,1,[Have nl_langinfo (_NL_ABALTMON_n)])
1279 fi
1280 AC_LANG_RESTORE
1283 dnl ****************************************
1284 dnl *** strlcpy/strlcat ***
1285 dnl ****************************************
1286 # Check for strlcpy
1287 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1288 AC_TRY_RUN([#include <stdlib.h>
1289 #include <string.h>
1290 int main() {
1291 char p[10];
1292 (void) strlcpy (p, "hi", 10);
1293 if (strlcat (p, "bye", 0) != 3)
1294 return 1;
1295 return 0;
1296 }], glib_cv_have_strlcpy=yes,
1297 glib_cv_have_strlcpy=no,
1298 glib_cv_have_strlcpy=no)])
1299 if test "$glib_cv_have_strlcpy" = "yes"; then
1300 AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1301 fi
1304 dnl **********************
1305 dnl *** va_copy checks ***
1306 dnl **********************
1307 dnl we currently check for all three va_copy possibilities, so we get
1308 dnl all results in config.log for bug reports.
1309 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1310 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1311 #include <stdlib.h>
1312 void f (int i, ...) {
1313 va_list args1, args2;
1314 va_start (args1, i);
1315 va_copy (args2, args1);
1316 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1317 exit (1);
1318 va_end (args1); va_end (args2);
1319 }
1320 int main() {
1321 f (0, 42);
1322 return 0;
1323 }]])],
1324 [glib_cv_va_copy=yes],
1325 [glib_cv_va_copy=no])
1326 ])
1327 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1328 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1329 #include <stdlib.h>
1330 void f (int i, ...) {
1331 va_list args1, args2;
1332 va_start (args1, i);
1333 __va_copy (args2, args1);
1334 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1335 exit (1);
1336 va_end (args1); va_end (args2);
1337 }
1338 int main() {
1339 f (0, 42);
1340 return 0;
1341 }]])],
1342 [glib_cv___va_copy=yes],
1343 [glib_cv___va_copy=no])
1344 ])
1346 if test "x$glib_cv_va_copy" = "xyes"; then
1347 g_va_copy_func=va_copy
1348 else if test "x$glib_cv___va_copy" = "xyes"; then
1349 g_va_copy_func=__va_copy
1350 fi
1351 fi
1353 if test -n "$g_va_copy_func"; then
1354 AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1355 fi
1357 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1358 AC_TRY_RUN([#include <stdarg.h>
1359 #include <stdlib.h>
1360 void f (int i, ...) {
1361 va_list args1, args2;
1362 va_start (args1, i);
1363 args2 = args1;
1364 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1365 exit (1);
1366 va_end (args1); va_end (args2);
1367 }
1368 int main() {
1369 f (0, 42);
1370 return 0;
1371 }],
1372 [glib_cv_va_val_copy=yes],
1373 [glib_cv_va_val_copy=no],
1374 [glib_cv_va_val_copy=yes])
1375 ])
1377 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1378 AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1379 ])
1381 dnl ***********************
1382 dnl *** g_module checks ***
1383 dnl ***********************
1384 G_MODULE_LIBS=
1385 G_MODULE_LIBS_EXTRA=
1386 G_MODULE_PLUGIN_LIBS=
1387 if test x"$glib_native_win32" = xyes; then
1388 dnl No use for this on Win32
1389 G_MODULE_LDFLAGS=
1390 else
1391 export SED
1392 eval G_MODULE_LDFLAGS=$export_dynamic_flag_spec
1393 fi
1394 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1395 G_MODULE_NEED_USCORE=0
1396 G_MODULE_BROKEN_RTLD_GLOBAL=0
1397 G_MODULE_HAVE_DLERROR=0
1398 dnl *** force native WIN32 shared lib loader
1399 if test -z "$G_MODULE_IMPL"; then
1400 case "$host" in
1401 *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1402 esac
1403 fi
1404 dnl *** force native AIX library loader
1405 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1406 if test -z "$G_MODULE_IMPL"; then
1407 case "$host" in
1408 *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1409 esac
1410 fi
1411 dnl *** dlopen() and dlsym() in system libraries
1412 AS_IF([ test -z "$G_MODULE_IMPL"], [
1413 AC_CHECK_FUNC(dlopen,
1414 [AC_CHECK_FUNC(dlsym,
1415 [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1416 [])
1417 ])
1418 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1419 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1420 AC_CHECK_FUNC(NSLinkModule,
1421 [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1422 G_MODULE_NEED_USCORE=1],
1423 [])
1424 ])
1425 dnl *** dlopen() and dlsym() in libdl
1426 AS_IF([ test -z "$G_MODULE_IMPL"], [
1427 AC_CHECK_LIB(dl, dlopen,
1428 [AC_CHECK_LIB(dl, dlsym,
1429 [G_MODULE_LIBS=-ldl
1430 G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1431 [])
1432 ])
1433 dnl *** additional checks for G_MODULE_IMPL_DL
1434 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1435 LIBS_orig="$LIBS"
1436 LDFLAGS_orig="$LDFLAGS"
1437 LIBS="$G_MODULE_LIBS $LIBS"
1438 LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1439 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1440 echo "void glib_plugin_test(void) { }" > plugin.c
1441 ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1442 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1443 ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1444 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1445 -shrext ".o" -avoid-version plugin.lo \
1446 -rpath /dont/care >/dev/null 2>&1
1447 AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1448 glib_cv_rtldglobal_broken,[
1449 AC_TRY_RUN([
1450 #include <dlfcn.h>
1451 #ifndef RTLD_GLOBAL
1452 # define RTLD_GLOBAL 0
1453 #endif
1454 #ifndef RTLD_LAZY
1455 # define RTLD_LAZY 0
1456 #endif
1457 int glib_plugin_test;
1458 int main () {
1459 void *handle, *global, *local;
1460 global = &glib_plugin_test;
1461 handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1462 if (!handle) return 0;
1463 local = dlsym (handle, "glib_plugin_test");
1464 return global == local;
1465 } ],
1466 [glib_cv_rtldglobal_broken=no],
1467 [glib_cv_rtldglobal_broken=yes],
1468 [glib_cv_rtldglobal_broken=no])
1469 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1470 rmdir ${objdir} 2>/dev/null
1471 ])
1472 if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1473 G_MODULE_BROKEN_RTLD_GLOBAL=1
1474 else
1475 G_MODULE_BROKEN_RTLD_GLOBAL=0
1476 fi
1477 dnl *** check whether we need preceeding underscores
1478 AC_CACHE_CHECK([for preceeding underscore in symbols],
1479 glib_cv_uscore,[
1480 AC_TRY_RUN([#include <dlfcn.h>
1481 int glib_underscore_test (void) { return 42; }
1482 int main() {
1483 void *f1 = (void*)0, *f2 = (void*)0, *handle;
1484 handle = dlopen ((void*)0, 0);
1485 if (handle) {
1486 f1 = dlsym (handle, "glib_underscore_test");
1487 f2 = dlsym (handle, "_glib_underscore_test");
1488 } return (!f2 || f1);
1489 }],
1490 [glib_cv_uscore=yes],
1491 [glib_cv_uscore=no],
1492 [])
1493 rm -f plugin.c plugin.$ac_objext plugin.lo
1494 ])
1495 GLIB_ASSERT_SET(glib_cv_uscore)
1496 if test "x$glib_cv_uscore" = "xyes"; then
1497 G_MODULE_NEED_USCORE=1
1498 else
1499 G_MODULE_NEED_USCORE=0
1500 fi
1502 AC_CHECK_DECL([RTLD_LAZY],
1503 [AC_DEFINE(HAVE_RTLD_LAZY, 1, [Define to 1 if RTLD_LAZY is available])],
1504 [], [[#include <dlfcn.h>]])
1505 AC_CHECK_DECL([RTLD_NOW],
1506 [AC_DEFINE(HAVE_RTLD_NOW, 1, [Define to 1 if RTLD_NOW is available])],
1507 [], [[#include <dlfcn.h>]])
1508 AC_CHECK_DECL([RTLD_GLOBAL],
1509 [AC_DEFINE(HAVE_RTLD_GLOBAL, 1, [Define to 1 if RTLD_GLOBAL is available])],
1510 [], [[#include <dlfcn.h>]])
1512 LDFLAGS="$LDFLAGS_orig"
1513 dnl *** check for having dlerror()
1514 AC_CHECK_FUNC(dlerror,
1515 [G_MODULE_HAVE_DLERROR=1],
1516 [G_MODULE_HAVE_DLERROR=0])
1517 LIBS="$LIBS_orig"
1518 ])
1519 dnl *** done, have we got an implementation?
1520 if test -z "$G_MODULE_IMPL"; then
1521 G_MODULE_IMPL=0
1522 G_MODULE_SUPPORTED=false
1523 else
1524 G_MODULE_SUPPORTED=true
1525 fi
1527 AC_MSG_CHECKING(for the suffix of module shared libraries)
1528 export SED
1529 module=yes eval std_shrext=$shrext_cmds
1530 # chop the initial dot
1531 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1532 AC_MSG_RESULT(.$glib_gmodule_suffix)
1533 # any reason it may fail?
1534 if test "x$glib_gmodule_suffix" = x; then
1535 AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1536 fi
1538 AC_SUBST(G_MODULE_SUPPORTED)
1539 AC_SUBST(G_MODULE_IMPL)
1540 AC_SUBST(G_MODULE_LIBS)
1541 AC_SUBST(G_MODULE_LIBS_EXTRA)
1542 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1543 AC_SUBST(G_MODULE_LDFLAGS)
1544 AC_SUBST(G_MODULE_HAVE_DLERROR)
1545 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1546 AC_SUBST(G_MODULE_NEED_USCORE)
1547 AC_SUBST(GLIB_DEBUG_FLAGS)
1549 dnl **********************
1550 dnl *** g_spawn checks ***
1551 dnl **********************
1553 AC_MSG_CHECKING(for gspawn implementation)
1554 case "$host" in
1555 *-*-mingw*)
1556 GSPAWN=gspawn-win32.lo
1557 ;;
1558 *)
1559 GSPAWN=gspawn.lo
1560 ;;
1561 esac
1562 AC_MSG_RESULT($GSPAWN)
1563 AC_SUBST(GSPAWN)
1565 dnl *************************
1566 dnl *** GIOChannel checks ***
1567 dnl *************************
1569 AC_MSG_CHECKING(for GIOChannel implementation)
1570 case "$host" in
1571 *-*-mingw*)
1572 GIO=giowin32.lo
1573 ;;
1574 *)
1575 GIO=giounix.lo
1576 ;;
1577 esac
1578 AC_MSG_RESULT($GIO)
1579 AC_SUBST(GIO)
1581 dnl *********************************
1582 dnl *** Directory for GIO modules ***
1583 dnl *********************************
1585 AC_ARG_WITH(gio-module-dir,
1586 [AS_HELP_STRING([--with-gio-module-dir=DIR],
1587 [load gio modules from this directory [LIBDIR/gio/modules]])],
1588 [],
1589 [with_gio_module_dir='${libdir}/gio/modules'])
1590 GIO_MODULE_DIR=$with_gio_module_dir
1591 AC_SUBST(GIO_MODULE_DIR)
1593 dnl **********************************
1594 dnl *** Check for libselinux (GIO) ***
1595 dnl **********************************
1596 AC_ARG_ENABLE(selinux,
1597 AS_HELP_STRING([--disable-selinux],
1598 [build without selinux support]))
1599 msg_selinux=no
1600 SELINUX_LIBS=
1601 AS_IF([ test "x$enable_selinux" != "xno"], [
1603 AC_CHECK_LIB(selinux, is_selinux_enabled,
1604 [AC_CHECK_HEADERS(selinux/selinux.h,
1605 [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1606 [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1607 SELINUX_LIBS="-lselinux"
1608 msg_selinux=yes])
1609 ])
1610 ])
1611 ])
1612 AC_SUBST(SELINUX_LIBS)
1614 dnl *****************************
1615 dnl ** Check for inotify (GIO) **
1616 dnl *****************************
1617 inotify_support=no
1618 AC_CHECK_HEADERS([sys/inotify.h],
1619 [
1620 AC_CHECK_FUNCS(inotify_init1, [inotify_support=yes], [inotify_support=no])
1621 ])
1623 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1625 dnl ****************************
1626 dnl ** Check for kqueue (GIO) **
1627 dnl ****************************
1628 kqueue_support=no
1629 AC_CHECK_HEADERS([sys/event.h],
1630 [
1631 AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1632 ])
1634 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1636 dnl ****************************
1637 dnl *** Checks for FAM (GIO) ***
1638 dnl ****************************
1640 should_disable_fam=no
1642 AC_ARG_ENABLE(fam,
1643 AS_HELP_STRING([--disable-fam],
1644 [don't use fam for file system monitoring]),
1645 [
1646 if test "x$enable_fam" = "xno"; then
1647 should_disable_fam=yes
1648 fi
1649 ]
1650 )
1651 fam_support=no
1652 FAM_LIBS=
1653 if test "x$should_disable_fam" = "xno"; then
1654 AC_CHECK_LIB(fam, FAMOpen,
1655 [AC_CHECK_HEADERS(fam.h,
1656 [AC_CHECK_LIB(fam, FAMNoExists,
1657 AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1658 FAM_LIBS="-lfam"]
1659 fam_support=yes,
1660 AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1661 AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1662 AC_SUBST(FAM_LIBS)
1663 fi
1664 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1667 dnl *****************************
1668 dnl *** Check for xattr (GIO) ***
1669 dnl *****************************
1670 AC_ARG_ENABLE(xattr,
1671 AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1672 msg_xattr=no
1673 XATTR_LIBS=
1674 AS_IF([ test "x$enable_xattr" != "xno"], [
1676 dnl either glibc or libattr can provide xattr support
1678 dnl for both of them, we check for getxattr being in
1679 dnl the library and a valid xattr header.
1681 dnl try glibc
1682 AC_CHECK_LIB(c, getxattr,
1683 [AC_CHECK_HEADERS(sys/xattr.h,
1684 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1685 msg_xattr=yes])
1686 ])
1688 AS_IF([ test "x$msg_xattr" != "xyes"], [
1689 dnl failure. try libattr
1690 AC_CHECK_LIB(attr, getxattr,
1691 [AC_CHECK_HEADERS(attr/xattr.h,
1692 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1693 XATTR_LIBS="-lattr"
1694 msg_xattr=yes])
1695 ])
1696 ])
1698 AS_IF([ test "x$msg_xattr" = "xyes"], [
1699 AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1700 AC_TRY_COMPILE([
1701 #include <stdio.h>
1702 #ifdef HAVE_SYS_TYPES_H
1703 #include <sys/types.h>
1704 #endif
1705 #ifdef HAVE_SYS_XATTR_H
1706 #include <sys/xattr.h>
1707 #elif HAVE_ATTR_XATTR_H
1708 #include <attr/xattr.h>
1709 #endif
1710 ],
1711 [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1712 [
1713 AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1714 AC_MSG_RESULT([yes])
1715 ],
1716 [AC_MSG_RESULT([no])]
1717 )
1718 ])
1719 ])
1720 AC_SUBST(XATTR_LIBS)
1722 dnl ************************
1723 dnl *** check for libelf ***
1724 dnl ************************
1725 AC_ARG_ENABLE(libelf,
1726 AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1727 AS_IF([ test "x$enable_libelf" != "xno"],[
1728 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1729 AS_IF([ test $have_libelf = maybe ], [
1730 glib_save_LIBS=$LIBS
1731 AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1732 AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1733 AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1734 AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1735 LIBS=$glib_save_LIBS
1737 if test $have_libelf != no; then
1738 LIBELF_LIBS=-lelf
1739 have_libelf=yes
1740 fi
1741 ])
1742 ])
1744 if test x$have_libelf = xyes; then
1745 AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1746 fi
1748 dnl ************************
1749 dnl *** check for libmount ***
1750 dnl ************************
1752 dnl The fallback code doesn't really implement the same behaviors - e.g.
1753 dnl so on linux we want to require libmount unless specifically disabled
1754 dnl
1755 enable_libmount_default=${glib_os_linux:-no}
1756 AC_ARG_ENABLE(libmount,
1757 [AS_HELP_STRING([--enable-libmount],
1758 [build with libmount support [default for Linux]])],,
1759 [enable_libmount=$enable_libmount_default])
1760 AS_IF([ test "x$enable_libmount" = "xyes"],[
1761 PKG_CHECK_MODULES([LIBMOUNT], [mount >= 2.23], [have_libmount=yes], [have_libmount=no])
1762 if test $have_libmount = no ; then
1763 AC_MSG_ERROR([*** Could not find libmount])
1764 fi
1765 ])
1767 if test x$have_libmount = xyes; then
1768 AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available])
1769 fi
1770 AM_CONDITIONAL(HAVE_LIBMOUNT, [test x$have_libmount = xyes])
1772 dnl ****************************************
1773 dnl *** platform dependent source checks ***
1774 dnl ****************************************
1776 AC_MSG_CHECKING(for platform-dependent source)
1777 case "$host" in
1778 *-*-cygwin*|*-*-mingw*)
1779 PLATFORMDEP=gwin32.lo
1780 ;;
1781 *)
1782 PLATFORMDEP=
1783 ;;
1784 esac
1785 AC_MSG_RESULT($PLATFORMDEP)
1786 AC_SUBST(PLATFORMDEP)
1788 AC_MSG_CHECKING([whether to compile timeloop])
1789 case "$host" in
1790 *-*-cygwin*|*-*-mingw*|*-*-minix)
1791 enable_timeloop=no
1792 ;;
1793 *)
1794 enable_timeloop=yes
1795 ;;
1796 esac
1797 AC_MSG_RESULT($enable_timeloop)
1798 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1800 AC_MSG_CHECKING([if building for some Win32 platform])
1801 case "$host" in
1802 *-*-mingw*|*-*-cygwin*)
1803 platform_win32=yes
1804 ;;
1805 *)
1806 platform_win32=no
1807 ;;
1808 esac
1809 AC_MSG_RESULT($platform_win32)
1810 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1812 dnl ***********************
1813 dnl *** g_thread checks ***
1814 dnl ***********************
1816 AC_ARG_WITH(threads,
1817 [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1818 [specify a thread implementation to use])],
1819 [],
1820 [with_threads=yes])
1822 dnl error and warning message
1823 dnl *************************
1825 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1827 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1828 platform (normally it's "_REENTRANT"). I'll not use any flag on
1829 compilation now, but then your programs might not work.
1830 Please provide information on how it is done on your system."
1832 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1833 "
1835 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1836 provide information on your thread implementation."
1838 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1839 functions will not be MT-safe during their first call because
1840 there is no working 'getpwuid_r' on your system."
1842 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1843 because there is no 'localtime_r' on your system."
1845 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1846 linking threaded applications. As GLib cannot do that
1847 automatically, you will get an linkg error everytime you are
1848 not using the right compiler. In that case you have to relink
1849 with the right compiler. Ususally just '_r' is appended
1850 to the compiler name."
1852 dnl determination of thread implementation
1853 dnl ***************************************
1855 AC_MSG_CHECKING(for thread implementation)
1857 have_threads=no
1858 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1859 AS_IF([ test "x$have_threads" = xno], [
1860 AC_TRY_COMPILE([#include <pthread.h>],
1861 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1862 have_threads=posix)
1863 ])
1864 # Tru64Unix requires -pthread to find pthread.h. See #103020
1865 if test "x$have_threads" = xno; then
1866 glib_save_CPPFLAGS="$CPPFLAGS"
1867 CPPFLAGS="$CPPFLAGS -pthread"
1868 AC_TRY_COMPILE([#include <pthread.h>],
1869 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1870 have_threads=posix)
1871 CPPFLAGS="$glib_save_CPPFLAGS"
1872 fi
1873 ])
1874 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1875 case $host in
1876 *-*-mingw*)
1877 have_threads=win32
1878 ;;
1879 esac
1880 fi
1882 if test "x$have_threads" = xno; then
1883 AC_MSG_RESULT(none available)
1884 AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1885 else
1886 AC_MSG_RESULT($have_threads)
1887 fi
1890 dnl determination of G_THREAD_CFLAGS
1891 dnl ********************************
1893 G_THREAD_LIBS=
1894 G_THREAD_LIBS_EXTRA=
1895 G_THREAD_CFLAGS=
1897 dnl
1898 dnl Test program for basic POSIX threads functionality
1899 dnl
1900 m4_define([glib_thread_test],[
1901 #include <pthread.h>
1902 int check_me = 0;
1903 void* func(void* data) {check_me = 42; return &check_me;}
1904 int main()
1905 { pthread_t t;
1906 void *ret;
1907 pthread_create (&t, $1, func, 0);
1908 pthread_join (t, &ret);
1909 return (check_me != 42 || ret != &check_me);
1910 }])
1912 AS_IF([ test x"$have_threads" = xposix], [
1913 # First we test for posix, whether -pthread or -pthreads do the trick as
1914 # both CPPFLAG and LIBS.
1915 # One of them does for most gcc versions and some other platforms/compilers
1916 # too and could be considered as the canonical way to go.
1917 case $host in
1918 *-*-cygwin*|*-*-darwin*)
1919 # skip cygwin and darwin -pthread or -pthreads test
1920 ;;
1921 *-solaris*)
1922 # These compiler/linker flags work with both Sun Studio and gcc
1923 # Sun Studio expands -mt to -D_REENTRANT and -lthread
1924 # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1925 G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1926 G_THREAD_LIBS="-lpthread -lthread"
1927 ;;
1928 *)
1929 for flag in pthread pthreads mt; do
1930 glib_save_CFLAGS="$CFLAGS"
1931 CFLAGS="$CFLAGS -$flag"
1932 AC_TRY_RUN(glib_thread_test(0),
1933 glib_flag_works=yes,
1934 glib_flag_works=no,
1935 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1936 glib_flag_works=yes,
1937 glib_flag_works=no)])
1938 CFLAGS="$glib_save_CFLAGS"
1939 if test $glib_flag_works = yes ; then
1940 G_THREAD_CFLAGS=-$flag
1941 G_THREAD_LIBS=-$flag
1942 break;
1943 fi
1944 done
1945 ;;
1946 esac
1947 ])
1949 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
1951 # The canonical -pthread[s] does not work. Try something different.
1953 case $host in
1954 *-aix*)
1955 if test x"$GCC" = xyes; then
1956 # GCC 3.0 and above needs -pthread.
1957 # Should be coverd by the case above.
1958 # GCC 2.x and below needs -mthreads
1959 G_THREAD_CFLAGS="-mthreads"
1960 G_THREAD_LIBS=$G_THREAD_CFLAGS
1961 else
1962 # We are probably using the aix compiler. Normaly a
1963 # program would have to be compiled with the _r variant
1964 # of the corresponding compiler, but we as GLib cannot
1965 # do that: but the good news is that for compiling the
1966 # only difference is the added -D_THREAD_SAFE compile
1967 # option. This is according to the "C for AIX User's
1968 # Guide".
1969 G_THREAD_CFLAGS="-D_THREAD_SAFE"
1970 fi
1971 ;;
1972 *-sysv5uw7*) # UnixWare 7
1973 # We are not using gcc with -pthread. Catched above.
1974 G_THREAD_CFLAGS="-Kthread"
1975 G_THREAD_LIBS=$G_THREAD_CFLAGS
1976 ;;
1977 *-mingw*)
1978 # No flag needed when using MSVCRT.DLL
1979 G_THREAD_CFLAGS=""
1980 ;;
1981 *)
1982 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1983 ;;
1984 esac
1985 ])
1987 # if we are not finding the localtime_r function, then we probably are
1988 # not using the proper multithread flag
1990 glib_save_CPPFLAGS="$CPPFLAGS"
1991 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1993 # First we test, whether localtime_r is declared in time.h
1994 # directly. Then we test whether a macro localtime_r exists, in
1995 # which case localtime_r in the test program is replaced and thus
1996 # if we still find localtime_r in the output, it is not defined as
1997 # a macro.
1999 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2000 [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2001 localtime_r(a,b)],
2002 AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2004 CPPFLAGS="$glib_save_CPPFLAGS"
2006 AC_MSG_CHECKING(thread related cflags)
2007 AC_MSG_RESULT($G_THREAD_CFLAGS)
2008 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2010 dnl determination of G_THREAD_LIBS
2011 dnl ******************************
2013 AS_IF([test x$have_threads = xposix], [
2014 glib_save_CPPFLAGS="$CPPFLAGS"
2015 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2016 AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2017 case $host in
2018 *-aix*)
2019 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2020 # probably using the aix compiler.
2021 AC_MSG_WARN($AIX_COMPILE_INFO)
2022 ;;
2023 *)
2024 G_THREAD_LIBS=error
2025 glib_save_LIBS="$LIBS"
2026 for thread_lib in "" pthread pthread32 pthreads thread; do
2027 if test x"$thread_lib" = x; then
2028 add_thread_lib=""
2029 IN=""
2030 else
2031 add_thread_lib="-l$thread_lib"
2032 IN=" in -l$thread_lib"
2033 fi
2034 if test x"$have_threads" = xposix; then
2035 defattr=0
2036 else
2037 defattr=pthread_attr_default
2038 fi
2040 LIBS="$add_thread_lib $glib_save_LIBS"
2042 AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2043 AC_TRY_RUN(glib_thread_test($defattr),
2044 glib_result=yes,
2045 glib_result=no,
2046 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2047 glib_result=yes,
2048 glib_result=no)])
2049 AC_MSG_RESULT($glib_result)
2051 if test "$glib_result" = "yes" ; then
2052 G_THREAD_LIBS="$add_thread_lib"
2053 break
2054 fi
2055 done
2056 if test "x$G_THREAD_LIBS" = xerror; then
2057 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2058 fi
2059 LIBS="$glib_save_LIBS"
2060 ;;
2061 esac
2062 ])
2064 g_threads_impl="POSIX"
2065 AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2066 AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2067 CPPFLAGS="$glib_save_CPPFLAGS"
2068 ], [test x$have_threads = xwin32], [
2069 AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2070 g_threads_impl="WIN32"
2071 ], [
2072 g_threads_impl="NONE"
2073 G_THREAD_LIBS=error
2074 ])
2075 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2076 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2078 if test "x$G_THREAD_LIBS" = xerror; then
2079 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2080 fi
2082 AC_MSG_CHECKING(thread related libraries)
2083 AC_MSG_RESULT($G_THREAD_LIBS)
2085 dnl check for mt safe function variants and some posix functions
2086 dnl ************************************************************
2088 glib_save_LIBS="$LIBS"
2089 # we are not doing the following for now, as this might require glib
2090 # to always be linked with the thread libs on some platforms.
2091 # LIBS="$LIBS $G_THREAD_LIBS"
2092 AC_CHECK_FUNCS(localtime_r gmtime_r getpwuid_r getgrgid_r)
2094 LIBS="$G_THREAD_LIBS $LIBS"
2095 AS_IF([ test x"$have_threads" = xposix], [
2096 glib_save_CPPFLAGS="$CPPFLAGS"
2097 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2098 # This is not AC_CHECK_FUNC to also work with function
2099 # name mangling in header files.
2100 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2101 AC_LINK_IFELSE(
2102 [AC_LANG_PROGRAM(
2103 [#include <pthread.h>],
2104 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2105 [AC_MSG_RESULT(yes)
2106 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2107 [Have function pthread_attr_setstacksize])],
2108 [AC_MSG_RESULT(no)])
2109 AC_MSG_CHECKING(for pthread_condattr_setclock)
2110 AC_LINK_IFELSE(
2111 [AC_LANG_PROGRAM(
2112 [#include <pthread.h>],
2113 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2114 [AC_MSG_RESULT(yes)
2115 AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2116 [Have function pthread_condattr_setclock])],
2117 [AC_MSG_RESULT(no)])
2118 AC_MSG_CHECKING(for pthread_cond_timedwait_relative_np)
2119 AC_LINK_IFELSE(
2120 [AC_LANG_PROGRAM(
2121 [#include <pthread.h>],
2122 [pthread_cond_timedwait_relative_np(NULL, NULL, NULL)])],
2123 [AC_MSG_RESULT(yes)
2124 AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP,1,
2125 [Have function pthread_cond_timedwait_relative_np])],
2126 [AC_MSG_RESULT(no)])
2127 dnl Sets thread names on OS X 10.6, iOS 3.2 (and higher)
2128 AC_MSG_CHECKING(for pthread_setname_np(const char*))
2129 AC_LINK_IFELSE(
2130 [AC_LANG_PROGRAM(
2131 [#include <pthread.h>],
2132 [pthread_setname_np("example")])],
2133 [AC_MSG_RESULT(yes)
2134 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
2135 [Have function pthread_setname_np(const char*)])],
2136 [AC_MSG_RESULT(no)])
2137 dnl Sets thread names on Solaris 11.3 & higher
2138 AC_MSG_CHECKING(for pthread_setname_np(pthread_t, const char*))
2139 AC_LINK_IFELSE(
2140 [AC_LANG_PROGRAM(
2141 [#include <pthread.h>],
2142 [pthread_setname_np(pthread_self(), "example")])],
2143 [AC_MSG_RESULT(yes)
2144 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITH_TID,1,
2145 [Have function pthread_setname_np(pthread_t, const char*)])],
2146 [AC_MSG_RESULT(no)])
2147 AC_MSG_CHECKING(for pthread_getname_np(pthread_t, name, len))
2148 AC_LINK_IFELSE(
2149 [AC_LANG_PROGRAM(
2150 [#include <pthread.h>],
2151 [[char name[16]; pthread_getname_np(pthread_self(), name, 16);]])],
2152 [AC_MSG_RESULT(yes)
2153 AC_DEFINE(HAVE_PTHREAD_GETNAME_NP,1,
2154 [Have function pthread_getname_np(pthread_t, name, len)])],
2155 [AC_MSG_RESULT(no)])
2156 CPPFLAGS="$glib_save_CPPFLAGS"
2157 ])
2159 LIBS="$glib_save_LIBS"
2161 # now spit out all the warnings.
2162 if test "$ac_cv_func_getpwuid_r" != "yes"; then
2163 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2164 fi
2165 if test "$ac_cv_func_localtime_r" != "yes"; then
2166 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2167 fi
2169 #
2170 # Hack to deal with:
2171 #
2172 # a) GCC < 3.3 for Linux doesn't include -lpthread when
2173 # building shared libraries with linux.
2174 # b) FreeBSD doesn't do this either.
2175 #
2176 case $host in
2177 *android*)
2178 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2179 ;;
2180 *-*-freebsd*|*-*-linux*)
2181 G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2182 ;;
2183 *)
2184 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2185 ;;
2186 esac
2188 AC_SUBST(G_THREAD_CFLAGS)
2189 AC_SUBST(G_THREAD_LIBS)
2190 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2191 AC_SUBST(G_THREAD_LIBS_EXTRA)
2193 AC_CHECK_FUNCS(clock_gettime, [], [
2194 AC_CHECK_LIB(rt, clock_gettime, [
2195 G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2196 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2197 ])
2198 ])
2201 dnl ************************
2202 dnl *** g_atomic_* tests ***
2203 dnl ************************
2205 dnl We need to decide at configure time if GLib will use real atomic
2206 dnl operations ("lock free") or emulated ones with a mutex. This is
2207 dnl because we must put this information in glibconfig.h so we know if
2208 dnl it is safe or not to inline using compiler intrinsics directly from
2209 dnl the header.
2210 dnl
2211 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2212 dnl user is interested in knowing if they can use the atomic ops across
2213 dnl processes.
2214 dnl
2215 dnl We can currently support the atomic ops natively when building GLib
2216 dnl with recent versions of GCC or MSVC. MSVC doesn't run ./configure,
2217 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2218 dnl we are using GCC (and not mingw*).
2219 dnl
2220 dnl Note that the atomic ops are only available with GCC on x86 when
2221 dnl using -march=i486 or higher. If we detect that the atomic ops are
2222 dnl not available but would be available given the right flags, we want
2223 dnl to abort and advise the user to fix their CFLAGS. It's better to do
2224 dnl that then to silently fall back on emulated atomic ops just because
2225 dnl the user had the wrong build environment.
2227 dnl We may add other compilers here in the future...
2229 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2230 case $host in
2231 *-*-mingw*)
2232 glib_cv_g_atomic_lock_free=yes
2233 ;;
2234 *)
2235 AC_TRY_LINK([],
2236 [volatile int atomic = 2;\
2237 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2238 [glib_cv_g_atomic_lock_free=yes],
2239 [glib_cv_g_atomic_lock_free=no])
2240 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2241 SAVE_CFLAGS="${CFLAGS}"
2242 CFLAGS="-march=i486"
2243 AC_TRY_LINK([],
2244 [volatile int atomic = 2;\
2245 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2246 [AC_MSG_ERROR([GLib must be built with -march=i486 or later.])],
2247 [])
2248 CFLAGS="${SAVE_CFLAGS}"
2249 fi
2250 ;;
2251 esac])
2254 case $host in
2255 *-*-mingw*)
2256 ;;
2257 *)
2258 # Some compilers support atomic operations but do not define
2259 # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2260 if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2261 AC_TRY_LINK([],
2262 [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2263 [],
2264 [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2265 fi
2266 ;;
2267 esac
2269 dnl We need a more robust approach here...
2270 case $host_cpu in
2271 i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2272 glib_memory_barrier_needed=no
2273 ;;
2274 sparc*|alpha*|powerpc*|ia64)
2275 glib_memory_barrier_needed=yes
2276 ;;
2277 *)
2278 glib_memory_barrier_needed=yes
2279 ;;
2280 esac
2282 dnl ************************
2283 dnl ** Check for futex(2) **
2284 dnl ************************
2285 AC_CACHE_CHECK(for futex(2) system call,
2286 glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2287 #include <linux/futex.h>
2288 #include <sys/syscall.h>
2289 #include <unistd.h>
2290 ],[
2291 syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2292 ])],glib_cv_futex=yes,glib_cv_futex=no))
2293 if test x"$glib_cv_futex" = xyes; then
2294 AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2295 fi
2297 AC_CACHE_CHECK(for eventfd(2) system call,
2298 glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2299 #include <sys/eventfd.h>
2300 #include <unistd.h>
2301 ],[
2302 eventfd (0, EFD_CLOEXEC);
2303 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2304 if test x"$glib_cv_eventfd" = x"yes"; then
2305 AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2306 fi
2307 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2309 dnl ****************************************
2310 dnl *** GLib POLL* compatibility defines ***
2311 dnl ****************************************
2313 glib_poll_includes=["
2314 #include <sys/types.h>
2315 #include <poll.h>
2316 "]
2318 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2319 test $ac_cv_func_poll = yes ], [
2320 glib_failed=false
2321 GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2322 GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2323 GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2324 GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2325 GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2326 GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2327 if $glib_failed ; then
2328 AC_MSG_ERROR([Could not determine values for POLL* constants])
2329 fi
2330 ], [
2331 glib_cv_value_POLLIN=1
2332 glib_cv_value_POLLOUT=4
2333 glib_cv_value_POLLPRI=2
2334 glib_cv_value_POLLERR=8
2335 glib_cv_value_POLLHUP=16
2336 glib_cv_value_POLLNVAL=32
2337 ])
2339 AC_MSG_CHECKING([for broken poll])
2340 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2341 #include <stdlib.h>
2342 #include <fcntl.h>
2343 #include <poll.h>
2344 int main(void) {
2345 struct pollfd fds[1];
2346 int fd;
2347 fd = open("/dev/null", 1);
2348 fds[0].fd = fd;
2349 fds[0].events = POLLIN;
2350 fds[0].revents = 0;
2351 if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2352 exit(1); /* Does not work for devices -- fail */
2353 }
2354 exit(0);
2355 }]])],
2356 [broken_poll=no],
2357 [broken_poll=yes
2358 AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2359 [broken_poll="no (cross compiling)"])
2360 AC_MSG_RESULT($broken_poll)
2362 dnl *********************
2363 dnl *** GRegex checks ***
2364 dnl *********************
2366 PCRE_REQUIRED_VERSION=8.13
2368 # Check if we should use the internal or the system-supplied pcre
2369 AC_ARG_WITH(pcre,
2370 [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2371 [whether to use system PCRE [default=system]])],
2372 [],
2373 [with_pcre=system])
2375 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2377 AS_IF([ test "x$with_pcre" = xsystem], [
2378 PKG_CHECK_MODULES(PCRE,
2379 libpcre >= $PCRE_REQUIRED_VERSION)
2380 AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2381 glib_save_CFLAGS="$CFLAGS"
2382 glib_save_LIBS="$LIBS"
2383 CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2384 AC_TRY_RUN([#include <pcre.h>
2385 int main () {
2386 int support;
2387 pcre_config (PCRE_CONFIG_UTF8, &support);
2388 if (!support)
2389 return 1;
2390 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2391 if (!support)
2392 return 1;
2393 return 0;
2394 }],
2395 glib_cv_pcre_has_unicode=yes,
2396 glib_cv_pcre_has_unicode=no,
2397 glib_cv_pcre_has_unicode=yes)
2398 CFLAGS="$glib_save_CFLAGS"
2399 LIBS="$glib_save_LIBS"
2400 ])
2401 if test "$glib_cv_pcre_has_unicode" = "no"; then
2402 AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2403 fi
2404 AC_SUBST(PCRE_CFLAGS)
2405 AC_SUBST(PCRE_LIBS)
2406 AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2407 PCRE_REQUIRES=libpcre
2408 AC_SUBST(PCRE_REQUIRES)
2409 ], [
2410 # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2411 AS_IF([ test x"$GCC" = xyes], [
2412 AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2413 save_CFLAGS="$CFLAGS"
2414 CFLAGS="$CFLAGS -Wno-pointer-sign"
2415 AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2416 AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2417 CFLAGS="$save_CFLAGS"
2418 ])
2419 ])
2420 AC_SUBST(PCRE_WARN_CFLAGS)
2422 dnl **********************
2423 dnl *** Win32 API libs ***
2424 dnl **********************
2426 case $host in
2427 *-*-cygwin*)
2428 G_LIBS_EXTRA="-luser32 -lkernel32"
2429 ;;
2430 *-*-mingw*)
2431 G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2432 ;;
2433 *)
2434 G_LIBS_EXTRA=""
2435 ;;
2436 esac
2437 AC_SUBST(G_LIBS_EXTRA)
2439 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2440 dnl since we need it for g_iconv()
2442 AC_MSG_CHECKING([for EILSEQ])
2443 AC_TRY_COMPILE([
2444 #include <errno.h>
2445 ],
2446 [
2447 int error = EILSEQ;
2448 ], have_eilseq=yes, have_eilseq=no);
2449 AC_MSG_RESULT($have_eilseq)
2451 dnl Add a conditional we can use when cross-compiling, so we avoid running
2452 dnl binaries
2453 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2455 dnl **************************
2456 dnl *** Checks for gtk-doc ***
2457 dnl **************************
2458 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2459 # it on it's own line.
2460 m4_ifdef([GTK_DOC_CHECK], [
2461 GTK_DOC_CHECK([1.20], [--flavour no-tmpl])
2462 ],[
2463 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2464 ])
2466 AC_ARG_ENABLE(man,
2467 [AS_HELP_STRING([--enable-man],
2468 [generate man pages [default=auto]])],,
2469 enable_man=maybe)
2471 AS_IF([test "$enable_man" != no], [
2472 AC_PATH_PROG([XSLTPROC], [xsltproc])
2473 AS_IF([test -z "$XSLTPROC"], [
2474 AS_IF([test "$enable_man" = yes], [
2475 AC_MSG_ERROR([xsltproc is required for --enable-man])
2476 ])
2477 enable_man=no
2478 ])
2479 ])
2481 AS_IF([ test "$enable_man" != no ], [
2482 dnl check for DocBook DTD in the local catalog
2483 JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2484 [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2485 AS_IF([test "$have_docbook_dtd" != yes], [
2486 AS_IF([test "$enable_man" = yes ], [
2487 AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2488 ])
2489 enable_man=no
2490 ])
2491 ])
2493 AS_IF([test "$enable_man" != no], [
2494 dnl check for DocBook XSL stylesheets in the local catalog
2495 JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2496 [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2497 AS_IF([ test "$have_docbook_style" != yes ], [
2498 AS_IF([ test "$enable_man" = yes ], [
2499 AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2500 ])
2501 enable_man=no
2502 ])
2503 ])
2505 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2507 AC_MSG_CHECKING([whether to generate man pages])
2508 AS_IF([ test "$enable_man" != no ], [
2509 AC_MSG_RESULT([yes])
2510 ], [
2511 AC_MSG_RESULT([no])
2512 ])
2514 dnl
2515 dnl Tracing
2516 dnl
2518 AC_ARG_ENABLE([dtrace],
2519 [AS_HELP_STRING([--enable-dtrace],
2520 [include tracing support for dtrace])])
2521 have_dtrace=no
2522 AC_MSG_CHECKING([whether to include dtrace tracing support])
2523 AS_IF([ test "x$enable_dtrace" != xno], [
2524 if test x$glib_have_carbon = xyes; then
2525 AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2526 else
2527 AC_MSG_RESULT([yes])
2528 AC_CHECK_PROGS(DTRACE, dtrace)
2529 if test -z "$DTRACE"; then
2530 if test "x$enable_dtrace" = xyes; then
2531 AC_MSG_ERROR([dtrace not found])
2532 fi
2533 else
2534 AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2535 [if test "x$enable_dtrace" = xyes; then
2536 AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2537 fi])
2538 fi
2539 fi
2540 ], [
2541 AC_MSG_RESULT([no])
2542 ])
2543 if test "x$have_dtrace" = xyes; then
2544 AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2545 fi
2546 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2548 AC_MSG_CHECKING([whether to include systemtap tracing support])
2549 AC_ARG_ENABLE([systemtap],
2550 [AS_HELP_STRING([--enable-systemtap],
2551 [include tracing support for systemtap])])
2552 have_systemtap=no
2553 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2554 have_systemtap=yes
2555 fi
2556 AC_MSG_RESULT(${have_systemtap})
2558 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2560 AC_ARG_WITH([tapset-install-dir],
2561 AS_HELP_STRING([--with-tapset-install-dir=DIR],
2562 [path where systemtap tapsets are installed [DATADIR/systemtap/tapset/HOST_CPU]]),
2563 [if test "x${withval}" = x; then
2564 ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset/${host_cpu}"
2565 else
2566 ABS_TAPSET_DIR="${withval}"
2567 fi],
2568 [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset/${host_cpu}"])
2569 AC_SUBST(ABS_TAPSET_DIR)
2571 dnl ************************************
2572 dnl *** Enable lcov coverage reports ***
2573 dnl ************************************
2575 AC_ARG_ENABLE(coverage,
2576 AS_HELP_STRING([--enable-coverage],
2577 [enable coverage testing with gcov]),
2578 [use_gcov=$enableval], [use_gcov=no])
2580 AS_IF([ test "x$use_gcov" = "xyes"], [
2581 dnl we need gcc:
2582 if test "$GCC" != "yes"; then
2583 AC_MSG_ERROR([GCC is required for --enable-coverage])
2584 fi
2586 dnl Check if ccache is being used
2587 AC_CHECK_PROG(SHTOOL, shtool, shtool)
2588 case `$SHTOOL path $CC` in
2589 *ccache*[)] gcc_ccache=yes;;
2590 *[)] gcc_ccache=no;;
2591 esac
2593 if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2594 AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2595 fi
2597 ltp_version_list="1.6 1.7 1.8 1.9 1.10 1.12"
2598 AC_CHECK_PROG(LTP, lcov, lcov)
2599 AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2601 AS_IF([ test "$LTP" ], [
2602 AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2603 glib_cv_ltp_version=invalid
2604 ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2605 for ltp_check_version in $ltp_version_list; do
2606 if test "$ltp_version" = "$ltp_check_version"; then
2607 glib_cv_ltp_version="$ltp_check_version (ok)"
2608 fi
2609 done
2610 ])
2611 ], [
2612 ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2613 AC_MSG_ERROR([$ltp_msg])
2614 ])
2616 case $glib_cv_ltp_version in
2617 ""|invalid[)]
2618 ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2619 AC_MSG_ERROR([$ltp_msg])
2620 LTP="exit 0;"
2621 ;;
2622 esac
2624 if test -z "$LTP_GENHTML"; then
2625 AC_MSG_ERROR([Could not find genhtml from the LTP package])
2626 fi
2628 dnl Remove all optimization flags from CFLAGS
2629 changequote({,})
2630 CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2631 changequote([,])
2633 dnl Add the special gcc flags
2634 CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2635 LDFLAGS="$LDFLAGS -lgcov"
2636 ])
2638 dnl *******************************
2639 dnl *** Disable strict aliasing ***
2640 dnl *******************************
2641 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=791622
2642 AS_IF([test "${GCC}" = "yes"],[
2643 CFLAGS="$CFLAGS -fno-strict-aliasing"
2644 ])
2646 dnl ******************************
2647 dnl *** output the whole stuff ***
2648 dnl ******************************
2650 dnl this section will only be run if config.status is invoked with no
2651 dnl arguments, or with "glib/glibconfig.h" as an argument.
2652 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2653 [
2654 outfile=glib/glibconfig.h-tmp
2655 cat > $outfile <<\_______EOF
2656 /* glibconfig.h
2657 *
2658 * This is a generated file. Please modify 'configure.ac'
2659 */
2661 #ifndef __GLIBCONFIG_H__
2662 #define __GLIBCONFIG_H__
2664 #include <glib/gmacros.h>
2666 _______EOF
2668 echo '#include <limits.h>' >> $outfile
2669 echo '#include <float.h>' >> $outfile
2670 if test x$glib_values_h = xyes; then
2671 echo '#include <values.h>' >> $outfile
2672 fi
2673 if test "$glib_header_alloca_h" = "yes"; then
2674 echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2675 fi
2676 if test x$glib_included_printf != xyes; then
2677 echo "
2678 /* Specifies that GLib's g_print*() functions wrap the
2679 * system printf functions. This is useful to know, for example,
2680 * when using glibc's register_printf_function().
2681 */" >> $outfile
2682 echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2683 fi
2685 cat >> $outfile <<_______EOF
2687 G_BEGIN_DECLS
2689 #define G_MINFLOAT FLT_MIN
2690 #define G_MAXFLOAT FLT_MAX
2691 #define G_MINDOUBLE DBL_MIN
2692 #define G_MAXDOUBLE DBL_MAX
2693 #define G_MINSHORT SHRT_MIN
2694 #define G_MAXSHORT SHRT_MAX
2695 #define G_MAXUSHORT USHRT_MAX
2696 #define G_MININT INT_MIN
2697 #define G_MAXINT INT_MAX
2698 #define G_MAXUINT UINT_MAX
2699 #define G_MINLONG LONG_MIN
2700 #define G_MAXLONG LONG_MAX
2701 #define G_MAXULONG ULONG_MAX
2703 _______EOF
2706 ### this should always be true in a modern C/C++ compiler
2707 ### and is statically asserted by glib-init.c
2708 cat >>$outfile <<_______EOF
2709 typedef signed char gint8;
2710 typedef unsigned char guint8;
2711 _______EOF
2714 if test -n "$gint16"; then
2715 cat >>$outfile <<_______EOF
2716 typedef signed $gint16 gint16;
2717 typedef unsigned $gint16 guint16;
2718 #define G_GINT16_MODIFIER $gint16_modifier
2719 #define G_GINT16_FORMAT $gint16_format
2720 #define G_GUINT16_FORMAT $guint16_format
2721 _______EOF
2722 fi
2725 if test -n "$gint32"; then
2726 cat >>$outfile <<_______EOF
2727 typedef signed $gint32 gint32;
2728 typedef unsigned $gint32 guint32;
2729 #define G_GINT32_MODIFIER $gint32_modifier
2730 #define G_GINT32_FORMAT $gint32_format
2731 #define G_GUINT32_FORMAT $guint32_format
2732 _______EOF
2733 fi
2735 cat >>$outfile <<_______EOF
2736 #define G_HAVE_GINT64 1 /* deprecated, always true */
2738 ${glib_extension}typedef signed $gint64 gint64;
2739 ${glib_extension}typedef unsigned $gint64 guint64;
2741 #define G_GINT64_CONSTANT(val) $gint64_constant
2742 #define G_GUINT64_CONSTANT(val) $guint64_constant
2743 _______EOF
2745 if test x$gint64_format != x ; then
2746 cat >>$outfile <<_______EOF
2747 #define G_GINT64_MODIFIER $gint64_modifier
2748 #define G_GINT64_FORMAT $gint64_format
2749 #define G_GUINT64_FORMAT $guint64_format
2750 _______EOF
2751 else
2752 cat >>$outfile <<_______EOF
2753 #undef G_GINT64_MODIFIER
2754 #undef G_GINT64_FORMAT
2755 #undef G_GUINT64_FORMAT
2756 _______EOF
2757 fi
2759 cat >>$outfile <<_______EOF
2761 #define GLIB_SIZEOF_VOID_P $glib_void_p
2762 #define GLIB_SIZEOF_LONG $glib_long
2763 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2764 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2766 _______EOF
2768 cat >>$outfile <<_______EOF
2769 typedef signed $glib_ssize_type_define gssize;
2770 typedef unsigned $glib_size_type_define gsize;
2771 #define G_GSIZE_MODIFIER $gsize_modifier
2772 #define G_GSSIZE_MODIFIER $gssize_modifier
2773 #define G_GSIZE_FORMAT $gsize_format
2774 #define G_GSSIZE_FORMAT $gssize_format
2776 #define G_MAXSIZE G_MAXU$glib_msize_type
2777 #define G_MINSSIZE G_MIN$glib_mssize_type
2778 #define G_MAXSSIZE G_MAX$glib_mssize_type
2780 typedef gint64 goffset;
2781 #define G_MINOFFSET G_MININT64
2782 #define G_MAXOFFSET G_MAXINT64
2784 #define G_GOFFSET_MODIFIER G_GINT64_MODIFIER
2785 #define G_GOFFSET_FORMAT G_GINT64_FORMAT
2786 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2788 #define G_POLLFD_FORMAT $g_pollfd_format
2790 _______EOF
2792 if test -z "$glib_unknown_void_p"; then
2793 cat >>$outfile <<_______EOF
2795 #define GPOINTER_TO_INT(p) ((gint) ${glib_gpi_cast} (p))
2796 #define GPOINTER_TO_UINT(p) ((guint) ${glib_gpui_cast} (p))
2798 #define GINT_TO_POINTER(i) ((gpointer) ${glib_gpi_cast} (i))
2799 #define GUINT_TO_POINTER(u) ((gpointer) ${glib_gpui_cast} (u))
2801 typedef signed $glib_intptr_type_define gintptr;
2802 typedef unsigned $glib_intptr_type_define guintptr;
2804 #define G_GINTPTR_MODIFIER $gintptr_modifier
2805 #define G_GINTPTR_FORMAT $gintptr_format
2806 #define G_GUINTPTR_FORMAT $guintptr_format
2807 _______EOF
2808 else
2809 echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2810 fi
2814 cat >>$outfile <<_______EOF
2815 #ifndef G_DISABLE_DEPRECATED
2816 #define g_ATEXIT(proc) (atexit (proc))
2817 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2818 #endif
2819 $glib_defines
2820 $glib_os
2821 $glib_static_compilation
2823 $glib_vacopy
2825 _______EOF
2827 if test x$g_have_iso_c_varargs = xyes ; then
2828 cat >>$outfile <<_______EOF
2829 #ifndef __cplusplus
2830 # define G_HAVE_ISO_VARARGS 1
2831 #endif
2832 _______EOF
2833 fi
2834 if test x$g_have_iso_cxx_varargs = xyes ; then
2835 cat >>$outfile <<_______EOF
2836 #ifdef __cplusplus
2837 # define G_HAVE_ISO_VARARGS 1
2838 #endif
2839 _______EOF
2840 fi
2841 if test x$g_have_gnuc_varargs = xyes ; then
2842 cat >>$outfile <<_______EOF
2844 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2845 * is passed ISO vararg support is turned off, and there is no work
2846 * around to turn it on, so we unconditionally turn it off.
2847 */
2848 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2849 # undef G_HAVE_ISO_VARARGS
2850 #endif
2852 #define G_HAVE_GNUC_VARARGS 1
2853 _______EOF
2854 fi
2856 case x$g_stack_grows in
2857 xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2858 *) echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2859 esac
2862 echo >>$outfile
2863 if test x$g_have_eilseq = xno; then
2864 cat >>$outfile <<_______EOF
2865 #ifndef EILSEQ
2866 /* On some pre-C99 systems, EILSEQ is not defined.
2867 * The correspondence between this and the corresponding definition
2868 * in libiconv is essential.
2869 */
2870 # define EILSEQ ENOENT
2871 #endif
2872 _______EOF
2874 fi
2876 if test x$g_have_gnuc_visibility = xyes; then
2877 cat >>$outfile <<_______EOF
2878 #define G_HAVE_GNUC_VISIBILITY 1
2879 _______EOF
2880 fi
2881 cat >>$outfile <<_______EOF
2882 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2883 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2884 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2885 #define G_GNUC_INTERNAL __hidden
2886 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2887 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2888 #else
2889 #define G_GNUC_INTERNAL
2890 #endif
2891 _______EOF
2893 echo >>$outfile
2894 cat >>$outfile <<_______EOF
2895 #define G_THREADS_ENABLED
2896 #define G_THREADS_IMPL_$g_threads_impl_def
2897 _______EOF
2899 if test x"$g_memory_barrier_needed" != xno; then
2900 echo >>$outfile
2901 echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2902 fi
2903 if test x"$g_atomic_lock_free" = xyes; then
2904 echo >>$outfile
2905 echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
2906 fi
2907 echo >>$outfile
2908 g_bit_sizes="16 32 64"
2909 for bits in $g_bit_sizes; do
2910 cat >>$outfile <<_______EOF
2911 #define GINT${bits}_TO_${g_bs_native}(val) ((gint${bits}) (val))
2912 #define GUINT${bits}_TO_${g_bs_native}(val) ((guint${bits}) (val))
2913 #define GINT${bits}_TO_${g_bs_alien}(val) ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2914 #define GUINT${bits}_TO_${g_bs_alien}(val) (GUINT${bits}_SWAP_LE_BE (val))
2915 _______EOF
2916 done
2918 cat >>$outfile <<_______EOF
2919 #define GLONG_TO_LE(val) ((glong) GINT${glongbits}_TO_LE (val))
2920 #define GULONG_TO_LE(val) ((gulong) GUINT${glongbits}_TO_LE (val))
2921 #define GLONG_TO_BE(val) ((glong) GINT${glongbits}_TO_BE (val))
2922 #define GULONG_TO_BE(val) ((gulong) GUINT${glongbits}_TO_BE (val))
2923 #define GINT_TO_LE(val) ((gint) GINT${gintbits}_TO_LE (val))
2924 #define GUINT_TO_LE(val) ((guint) GUINT${gintbits}_TO_LE (val))
2925 #define GINT_TO_BE(val) ((gint) GINT${gintbits}_TO_BE (val))
2926 #define GUINT_TO_BE(val) ((guint) GUINT${gintbits}_TO_BE (val))
2927 #define GSIZE_TO_LE(val) ((gsize) GUINT${gsizebits}_TO_LE (val))
2928 #define GSSIZE_TO_LE(val) ((gssize) GINT${gssizebits}_TO_LE (val))
2929 #define GSIZE_TO_BE(val) ((gsize) GUINT${gsizebits}_TO_BE (val))
2930 #define GSSIZE_TO_BE(val) ((gssize) GINT${gssizebits}_TO_BE (val))
2931 #define G_BYTE_ORDER $g_byte_order
2933 #define GLIB_SYSDEF_POLLIN =$g_pollin
2934 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2935 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2936 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2937 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2938 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2940 #define G_MODULE_SUFFIX "$g_module_suffix"
2942 typedef $g_pid_type GPid;
2943 #define G_PID_FORMAT $g_pid_format
2945 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
2946 #define GLIB_SYSDEF_AF_INET $g_af_inet
2947 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
2949 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
2950 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
2951 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
2953 #define G_DIR_SEPARATOR '$g_dir_separator'
2954 #define G_DIR_SEPARATOR_S "$g_dir_separator"
2955 #define G_SEARCHPATH_SEPARATOR '$g_searchpath_separator'
2956 #define G_SEARCHPATH_SEPARATOR_S "$g_searchpath_separator"
2958 G_END_DECLS
2960 #endif /* __GLIBCONFIG_H__ */
2961 _______EOF
2964 if cmp -s $outfile glib/glibconfig.h; then
2965 AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
2966 rm -f $outfile
2967 else
2968 mv $outfile glib/glibconfig.h
2969 fi
2970 ],[
2972 # Note that if two cases are the same, case goes with the first one.
2973 # Note also that this is inside an AC_OUTPUT_COMMAND. We do not depend
2974 # on variable expansion in case labels. Look at the generated config.status
2975 # for a hint.
2977 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2978 glib_header_alloca_h="$ac_cv_working_alloca_h"
2979 else
2980 glib_header_alloca_h="$ac_cv_header_alloca_h"
2981 fi
2983 if test x$enable_included_printf = xyes ; then
2984 glib_included_printf=yes
2985 fi
2987 case 2 in
2988 $ac_cv_sizeof_short)
2989 gint16=short
2990 gint16_modifier='"h"'
2991 gint16_format='"hi"'
2992 guint16_format='"hu"'
2993 ;;
2994 $ac_cv_sizeof_int)
2995 gint16=int
2996 gint16_modifier='""'
2997 gint16_format='"i"'
2998 guint16_format='"u"'
2999 ;;
3000 esac
3001 case 4 in
3002 $ac_cv_sizeof_short)
3003 gint32=short
3004 gint32_modifier='"h"'
3005 gint32_format='"hi"'
3006 guint32_format='"hu"'
3007 ;;
3008 $ac_cv_sizeof_int)
3009 gint32=int
3010 gint32_modifier='""'
3011 gint32_format='"i"'
3012 guint32_format='"u"'
3013 ;;
3014 $ac_cv_sizeof_long)
3015 gint32=long
3016 gint32_modifier='"l"'
3017 gint32_format='"li"'
3018 guint32_format='"lu"'
3019 ;;
3020 esac
3021 case 8 in
3022 $ac_cv_sizeof_int)
3023 gint64=int
3024 gint64_modifier='""'
3025 gint64_format='"i"'
3026 guint64_format='"u"'
3027 glib_extension=
3028 gint64_constant='(val)'
3029 guint64_constant='(val)'
3030 ;;
3031 $ac_cv_sizeof_long)
3032 gint64=long
3033 gint64_modifier='"l"'
3034 gint64_format='"li"'
3035 guint64_format='"lu"'
3036 glib_extension=
3037 gint64_constant='(val##L)'
3038 guint64_constant='(val##UL)'
3039 ;;
3040 $ac_cv_sizeof_long_long)
3041 gint64='long long'
3042 if test -n "$glib_cv_long_long_format"; then
3043 gint64_modifier='"'$glib_cv_long_long_format'"'
3044 gint64_format='"'$glib_cv_long_long_format'i"'
3045 guint64_format='"'$glib_cv_long_long_format'u"'
3046 fi
3047 glib_extension='G_GNUC_EXTENSION '
3048 gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3049 guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3050 ;;
3051 $ac_cv_sizeof___int64)
3052 gint64='__int64'
3053 if test -n "$glib_cv_long_long_format"; then
3054 gint64_modifier='"'$glib_cv_long_long_format'"'
3055 gint64_format='"'$glib_cv_long_long_format'i"'
3056 guint64_format='"'$glib_cv_long_long_format'u"'
3057 fi
3058 glib_extension=
3059 gint64_constant='(val##i64)'
3060 guint64_constant='(val##ui64)'
3061 ;;
3062 esac
3063 glib_size_t=$ac_cv_sizeof_size_t
3064 glib_ssize_t=$ac_cv_sizeof_ssize_t
3065 glib_size_type_define="$glib_size_type"
3066 glib_ssize_type_define="$glib_ssize_type"
3067 glib_void_p=$ac_cv_sizeof_void_p
3068 glib_long=$ac_cv_sizeof_long
3070 case "$glib_size_type" in
3071 short)
3072 gsize_modifier='"h"'
3073 gsize_format='"hu"'
3074 glib_msize_type='SHRT'
3075 ;;
3076 int)
3077 gsize_modifier='""'
3078 gsize_format='"u"'
3079 glib_msize_type='INT'
3080 ;;
3081 long)
3082 gsize_modifier='"l"'
3083 gsize_format='"lu"'
3084 glib_msize_type='LONG'
3085 ;;
3086 "long long"|__int64)
3087 gsize_modifier='"I64"'
3088 gsize_format='"I64u"'
3089 glib_msize_type='INT64'
3090 ;;
3091 esac
3093 case "$glib_ssize_type" in
3094 short)
3095 gssize_modifier='"h"'
3096 gssize_format='"hi"'
3097 glib_mssize_type='SHRT'
3098 ;;
3099 int)
3100 gssize_modifier='""'
3101 gssize_format='"i"'
3102 glib_mssize_type='INT'
3103 ;;
3104 long)
3105 gssize_modifier='"l"'
3106 gssize_format='"li"'
3107 glib_mssize_type='LONG'
3108 ;;
3109 "long long"|__int64)
3110 gssize_modifier='"I64"'
3111 gssize_format='"I64i"'
3112 glib_mssize_type='INT64'
3113 ;;
3114 esac
3116 gintbits=`expr $ac_cv_sizeof_int \* 8`
3117 glongbits=`expr $ac_cv_sizeof_long \* 8`
3118 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3119 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3121 case $ac_cv_sizeof_void_p in
3122 $ac_cv_sizeof_int)
3123 glib_intptr_type_define=int
3124 gintptr_modifier='""'
3125 gintptr_format='"i"'
3126 guintptr_format='"u"'
3127 glib_gpi_cast='(gint)'
3128 glib_gpui_cast='(guint)'
3129 ;;
3130 $ac_cv_sizeof_long)
3131 glib_intptr_type_define=long
3132 gintptr_modifier='"l"'
3133 gintptr_format='"li"'
3134 guintptr_format='"lu"'
3135 glib_gpi_cast='(glong)'
3136 glib_gpui_cast='(gulong)'
3137 ;;
3138 $ac_cv_sizeof_long_long)
3139 glib_intptr_type_define='long long'
3140 gintptr_modifier='"I64"'
3141 gintptr_format='"I64i"'
3142 guintptr_format='"I64u"'
3143 glib_gpi_cast='(gint64)'
3144 glib_gpui_cast='(guint64)'
3145 ;;
3146 $ac_cv_sizeof___int64)
3147 glib_intptr_type_define=__int64
3148 gintptr_modifier='"I64"'
3149 gintptr_format='"I64i"'
3150 guintptr_format='"I64u"'
3151 glib_gpi_cast='(gint64)'
3152 glib_gpui_cast='(guint64)'
3153 ;;
3154 *)
3155 glib_unknown_void_p=yes
3156 ;;
3157 esac
3160 glib_defines="
3161 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3162 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3163 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3164 "
3166 case xyes in
3167 x$glib_cv_va_copy) glib_vacopy='#define G_VA_COPY va_copy' ;;
3168 x$glib_cv___va_copy) glib_vacopy='#define G_VA_COPY __va_copy' ;;
3169 *) glib_vacopy=''
3170 esac
3172 if test x$glib_cv_va_val_copy = xno; then
3173 glib_vacopy="\$glib_vacopy
3174 #define G_VA_COPY_AS_ARRAY 1"
3175 fi
3177 g_have_gnuc_varargs=$g_have_gnuc_varargs
3178 g_have_iso_c_varargs=$g_have_iso_c_varargs
3179 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3181 g_have_gnuc_visibility=$g_have_gnuc_visibility
3182 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3184 if test x$ac_cv_c_bigendian = xyes; then
3185 g_byte_order=G_BIG_ENDIAN
3186 g_bs_native=BE
3187 g_bs_alien=LE
3188 else
3189 g_byte_order=G_LITTLE_ENDIAN
3190 g_bs_native=LE
3191 g_bs_alien=BE
3192 fi
3194 g_pollin=$glib_cv_value_POLLIN
3195 g_pollout=$glib_cv_value_POLLOUT
3196 g_pollpri=$glib_cv_value_POLLPRI
3197 g_pollhup=$glib_cv_value_POLLHUP
3198 g_pollerr=$glib_cv_value_POLLERR
3199 g_pollnval=$glib_cv_value_POLLNVAL
3201 # If a family is not found on the system, define that family to
3202 # a negative value, picking a different one for each undefined
3203 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3204 # This is needed because glib-mkenums doesn't handle optional
3205 # values in enums, and thus we have to have all existing values
3206 # defined in the enum.
3207 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3208 g_af_unix=$glib_cv_value_AF_UNIX
3209 else
3210 g_af_unix=-1
3211 fi
3212 g_af_inet=$glib_cv_value_AF_INET
3213 g_af_inet6=$glib_cv_value_AF_INET6
3215 g_msg_peek=$glib_cv_value_MSG_PEEK
3216 g_msg_oob=$glib_cv_value_MSG_OOB
3217 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3219 g_stack_grows=$glib_cv_stack_grows
3221 g_have_eilseq=$have_eilseq
3223 g_threads_impl_def=$g_threads_impl
3225 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3226 g_memory_barrier_needed="$glib_memory_barrier_needed"
3227 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3229 g_module_suffix="$glib_gmodule_suffix"
3230 g_dir_separator="$glib_dir_separator"
3231 g_searchpath_separator="$glib_searchpath_separator"
3233 g_pid_type="$glib_pid_type"
3234 g_pid_format="\"$glib_pid_format\""
3235 g_pollfd_format="\"$glib_pollfd_format\""
3237 case $host in
3238 *-*-cygwin*)
3239 glib_os="#define G_OS_UNIX
3240 #define G_PLATFORM_WIN32
3241 #define G_WITH_CYGWIN"
3242 ;;
3243 *-*-mingw*)
3244 glib_os="#define G_OS_WIN32
3245 #define G_PLATFORM_WIN32"
3246 ;;
3247 *)
3248 glib_os="#define G_OS_UNIX"
3249 ;;
3250 esac
3251 glib_static_compilation=""
3252 if test x$glib_win32_static_compilation = xyes; then
3253 glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3254 #define GOBJECT_STATIC_COMPILATION 1"
3255 fi
3256 ])
3258 # Redo enough to get guint32 and guint64 for the alignment checks below
3259 case 4 in
3260 $ac_cv_sizeof_short)
3261 gint32=short
3262 ;;
3263 $ac_cv_sizeof_int)
3264 gint32=int
3265 ;;
3266 $ac_cv_sizeof_long)
3267 gint32=long
3268 ;;
3269 esac
3270 case 8 in
3271 $ac_cv_sizeof_int)
3272 gint64=int
3273 ;;
3274 $ac_cv_sizeof_long)
3275 gint64=long
3276 ;;
3277 $ac_cv_sizeof_long_long)
3278 gint64='long long'
3279 ;;
3280 $ac_cv_sizeof___int64)
3281 gint64='__int64'
3282 ;;
3283 esac
3285 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3286 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3287 typedef unsigned $gint32 guint32;])
3288 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3289 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3290 typedef unsigned $gint64 guint64;])
3291 AC_CHECK_TYPE([unsigned long])
3292 AC_CHECK_ALIGNOF([unsigned long])
3294 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3295 #
3296 # 1.2.14 required for dbus_message_set_serial
3297 PKG_CHECK_MODULES(DBUS1,
3298 dbus-1 >= 1.2.14,
3299 [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3300 have_dbus1=no)
3301 AC_SUBST(DBUS1_CFLAGS)
3302 AC_SUBST(DBUS1_LIBS)
3303 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3305 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3306 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3308 # Check whether MSVC toolset is explicitly set
3309 AM_CONDITIONAL(MSVC_BASE_NO_TOOLSET_SET, [test x$MSVC_BASE_TOOLSET = x])
3310 AM_CONDITIONAL(MSVC_NO_TOOLSET_SET, [test x$MSVC_TOOLSET = x])
3312 dnl
3313 dnl Check for -Bsymbolic-functions linker flag used to avoid
3314 dnl intra-library PLT jumps, if available.
3315 dnl
3317 AC_ARG_ENABLE(Bsymbolic,
3318 [AS_HELP_STRING([--disable-Bsymbolic],
3319 [avoid linking with -Bsymbolic])],,
3320 [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3321 AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3322 LDFLAGS=-Wl,-Bsymbolic-functions
3323 LIBS=
3324 AC_TRY_LINK([], [return 0],
3325 AC_MSG_RESULT(yes)
3326 enable_Bsymbolic=yes,
3327 AC_MSG_RESULT(no)
3328 enable_Bsymbolic=no)
3329 LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3331 if test "x${enable_Bsymbolic}" = "xyes"; then
3332 GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3333 fi
3335 dnl
3336 dnl Check for -z,nodelete linker flag: the type system assumes that
3337 dnl libgobject stays loaded for the lifetime of the process.
3338 dnl Since ld.bfd does not treat wrong -z options as fatal by default,
3339 dnl we also try to check for the --fatal-warnings linker flag if
3340 dnl auto-detecting.
3341 dnl
3343 SAVED_CFLAGS="${CFLAGS}" SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3344 AC_MSG_CHECKING([for --fatal-warnings linker flag])
3345 CFLAGS="${SAVED_CFLAGS} ${shared_flag:- -shared}"
3346 LDFLAGS=-Wl,--fatal-warnings
3347 LIBS=
3348 AC_TRY_LINK([], [return 0],
3349 AC_MSG_RESULT(yes)
3350 [ldflags_fatal=-Wl,--fatal-warnings],
3351 AC_MSG_RESULT(no)
3352 ldflags_fatal=)
3354 AC_MSG_CHECKING([for -z,nodelete linker flag])
3355 LDFLAGS="$ldflags_fatal -Wl,-z,nodelete"
3356 AC_TRY_LINK([], [return 0],
3357 AC_MSG_RESULT(yes)
3358 enable_znodelete=yes,
3359 AC_MSG_RESULT(no)
3360 enable_znodelete=no)
3361 CFLAGS="${SAVED_CFLAGS}" LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"
3363 if test "x${enable_znodelete}" = "xyes"; then
3364 GLIB_LINK_FLAGS="$GLIB_LINK_FLAGS -Wl,-z,nodelete"
3365 fi
3367 AC_SUBST(GLIB_LINK_FLAGS)
3369 dnl
3370 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3371 dnl visibility attributes for symbol export control
3372 dnl
3373 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3374 case "$host" in
3375 *-*-mingw*)
3376 dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3377 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3378 [defines how to decorate public symbols while building])
3379 CFLAGS="${CFLAGS} -fvisibility=hidden"
3380 ;;
3381 *)
3382 dnl on other compilers, check if we can do -fvisibility=hidden
3383 SAVED_CFLAGS="${CFLAGS}"
3384 CFLAGS="-fvisibility=hidden"
3385 AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3386 AC_TRY_COMPILE([], [return 0],
3387 AC_MSG_RESULT(yes)
3388 enable_fvisibility_hidden=yes,
3389 AC_MSG_RESULT(no)
3390 enable_fvisibility_hidden=no)
3391 CFLAGS="${SAVED_CFLAGS}"
3393 AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3394 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3395 [defines how to decorate public symbols while building])
3396 GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3397 ])
3398 ;;
3399 esac
3400 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3402 dnl Compiler flags; macro originates from systemd
3403 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3404 AC_ARG_ENABLE(compile-warnings,
3405 [AS_HELP_STRING([--disable-compile-warnings],
3406 [Don't use builtin compiler warnings])],,
3407 enable_compile_warnings=yes)
3408 AS_IF([test "x$enable_compile_warnings" != xno], [
3409 CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3410 -Wall -Wstrict-prototypes -Wduplicated-branches -Wmisleading-indentation \
3411 -Werror=declaration-after-statement \
3412 -Werror=missing-prototypes -Werror=implicit-function-declaration \
3413 -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3414 -Werror=format=2 -Werror=missing-include-dirs])
3415 ])
3416 AC_SUBST(GLIB_WARN_CFLAGS)
3418 #
3419 # Define variables corresponding to the correct include paths to use for
3420 # in-tree building.
3421 #
3423 # for config.h:
3424 config_h_INCLUDES='-I$(top_builddir)'
3425 AC_SUBST(config_h_INCLUDES)
3427 # glib:
3428 # config.h
3429 # $(top_builddir)/glib: for glibconfig.h
3430 # $(top_srcdir)/glib: for glib.h
3431 # $(top_srcdir): for everything
3432 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3433 AC_SUBST(glib_INCLUDES)
3435 # gobject:
3436 # same as glib
3437 gobject_INCLUDES='$(glib_INCLUDES)'
3438 AC_SUBST(gobject_INCLUDES)
3440 # gmodule:
3441 # glib includes
3442 # $(top_srcdir)/gmodule: for gmodule.h
3443 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3444 AC_SUBST(gmodule_INCLUDES)
3446 # gio:
3447 # same as gmodule
3448 gio_INCLUDES='$(gmodule_INCLUDES)'
3449 AC_SUBST(gio_INCLUDES)
3452 AC_CONFIG_FILES([
3453 glib-2.0.pc
3454 gmodule-2.0.pc
3455 gmodule-export-2.0.pc
3456 gmodule-no-export-2.0.pc
3457 gthread-2.0.pc
3458 gobject-2.0.pc
3459 gio-2.0.pc
3460 gio-unix-2.0.pc
3461 gio-windows-2.0.pc
3462 glib-gettextize
3463 Makefile
3464 build/Makefile
3465 build/win32/Makefile
3466 build/win32/dirent/Makefile
3467 glib/Makefile
3468 glib/libcharset/Makefile
3469 glib/gnulib/Makefile
3470 glib/pcre/Makefile
3471 glib/update-pcre/Makefile
3472 glib/tests/Makefile
3473 gmodule/Makefile
3474 gmodule/gmoduleconf.h
3475 gobject/Makefile
3476 gobject/glib-genmarshal
3477 gobject/glib-mkenums
3478 gobject/tests/Makefile
3479 gthread/Makefile
3480 gio/Makefile
3481 gio/gdbus-2.0/codegen/Makefile
3482 gio/gdbus-2.0/codegen/config.py
3483 gio/gnetworking.h
3484 gio/xdgmime/Makefile
3485 gio/inotify/Makefile
3486 gio/kqueue/Makefile
3487 gio/fam/Makefile
3488 gio/win32/Makefile
3489 gio/tests/Makefile
3490 gio/tests/gdbus-object-manager-example/Makefile
3491 gio/tests/services/Makefile
3492 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3493 gio/tests/modules/Makefile
3494 po/Makefile.in
3495 docs/Makefile
3496 docs/reference/Makefile
3497 docs/reference/glib/Makefile
3498 docs/reference/glib/version.xml
3499 docs/reference/gobject/Makefile
3500 docs/reference/gobject/version.xml
3501 docs/reference/gio/Makefile
3502 docs/reference/gio/version.xml
3503 tests/Makefile
3504 tests/gobject/Makefile
3505 tests/refcount/Makefile
3506 m4macros/Makefile
3507 subprojects/Makefile
3508 ])
3510 # We need this command because the configure script will not preserve
3511 # the same attributes of the template files
3512 AC_CONFIG_COMMANDS([chmod-scripts],
3513 [chmod 0755 glib-gettextize
3514 chmod 0755 gobject/glib-genmarshal
3515 chmod 0755 gobject/glib-mkenums])
3517 # we want to invoke this macro solely so that the config.status script
3518 # and automake generated makefiles know about these generated files.
3519 # They are only needed to distcheck the package
3520 if false; then
3521 AC_CONFIG_FILES([
3522 INSTALL
3523 glib/glib.rc
3524 gmodule/gmodule.rc
3525 gobject/gobject.rc
3526 gthread/gthread.rc
3527 gio/gio.rc
3528 ])
3529 fi
3531 AC_OUTPUT