| blob | fd6c0d953bbb699174d61ae8a19a986ab3de8f5b |
1 # Process this file with autoconf to produce a configure script.
2 AC_PREREQ([2.62])
4 dnl ***********************************
5 dnl *** include special GLib macros ***
6 dnl ***********************************
8 m4_define(glib_configure_ac)
10 #
11 # The following version number definitions apply to GLib, GModule, GObject,
12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
13 # all treated with the same interface and binary age.
14 #
15 # Making releases:
16 # glib_micro_version += 1;
17 # glib_interface_age += 1;
18 # glib_binary_age += 1;
19 # if any functions have been added, set glib_interface_age to 0.
20 # if backwards compatibility has been broken,
21 # set glib_binary_age _and_ glib_interface_age to 0.
22 #
23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
25 # for that version - see gversion.h for further information.
26 #
27 # in easier to understand terms:
28 #
29 # <mclasen> on the stable branch, interface age == micro
30 # <mclasen> on the unstable (ie master), interface age = 0
32 m4_define([glib_major_version], [2])
33 m4_define([glib_minor_version], [57])
34 m4_define([glib_micro_version], [1])
35 m4_define([glib_interface_age], [0])
36 m4_define([glib_binary_age],
37 [m4_eval(100 * glib_minor_version + glib_micro_version)])
38 m4_define([glib_version],
39 [glib_major_version.glib_minor_version.glib_micro_version])
41 # libtool version related macros
42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
43 m4_define([glib_lt_current],
44 [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
45 m4_define([glib_lt_revision], [glib_interface_age])
46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
47 m4_define([glib_lt_current_minus_age],
48 [m4_eval(glib_lt_current - glib_lt_age)])
50 # if the minor version number is odd, then we want debugging. Otherwise
51 # we only want minimal debugging support.
52 m4_define([glib_debug_default],
53 [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
56 AC_INIT(glib, [glib_version],
57 [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
59 AC_CONFIG_HEADERS([config.h])
60 AC_CONFIG_SRCDIR([glib/glib.h])
61 AC_CONFIG_MACRO_DIR([m4macros])
63 # Save this value here, since automake will set cflags later
64 cflags_set=${CFLAGS:+set}
66 AM_INIT_AUTOMAKE([1.13.3 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar subdir-objects])
67 AM_MAINTAINER_MODE([enable])
69 # Support silent build rules. Disable
70 # by either passing --disable-silent-rules to configure or passing V=1
71 # to make
72 AM_SILENT_RULES([yes])
74 GLIB_MAJOR_VERSION=glib_major_version
75 GLIB_MINOR_VERSION=glib_minor_version
76 GLIB_MICRO_VERSION=glib_micro_version
77 GLIB_INTERFACE_AGE=glib_interface_age
78 GLIB_BINARY_AGE=glib_binary_age
79 GLIB_VERSION=glib_version
81 AC_SUBST(GLIB_MAJOR_VERSION)
82 AC_SUBST(GLIB_MINOR_VERSION)
83 AC_SUBST(GLIB_MICRO_VERSION)
84 AC_SUBST(GLIB_VERSION)
85 AC_SUBST(GLIB_INTERFACE_AGE)
86 AC_SUBST(GLIB_BINARY_AGE)
88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
89 [Define to the GLIB major version])
90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
91 [Define to the GLIB minor version])
92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
93 [Define to the GLIB micro version])
94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
95 [Define to the GLIB interface age])
96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
97 [Define to the GLIB binary age])
99 # libtool versioning
100 LT_RELEASE=glib_lt_release
101 LT_CURRENT=glib_lt_current
102 LT_REVISION=glib_lt_revision
103 LT_AGE=glib_lt_age
104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
105 AC_SUBST(LT_RELEASE)
106 AC_SUBST(LT_CURRENT)
107 AC_SUBST(LT_REVISION)
108 AC_SUBST(LT_AGE)
109 AC_SUBST(LT_CURRENT_MINUS_AGE)
111 dnl Checks for programs.
112 AC_PROG_CC
113 AC_PROG_CPP
114 AC_USE_SYSTEM_EXTENSIONS
116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
118 AC_CANONICAL_HOST
120 dnl
122 AC_MSG_CHECKING([for Win32])
123 LIB_EXE_MACHINE_FLAG=X86
124 case "$host" in
125 *-*-mingw*)
126 glib_native_win32=yes
127 glib_pid_type='void *'
128 glib_pid_format='p'
129 glib_pollfd_format='%#x'
130 glib_dir_separator='\\\\'
131 glib_searchpath_separator=';'
132 glib_cv_stack_grows=no
133 # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
134 # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
135 # (Sorry, I don't know exactly what is the problem, but it is related to
136 # floating point formatting and decimal point vs. comma.)
137 # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
138 # rigorous enough to notice, though.
139 # So preset the autoconf cache variables.
140 ac_cv_func_vsnprintf_c99=no
141 ac_cv_func_snprintf_c99=no
142 case "$host" in
143 x86_64-*-*)
144 LIB_EXE_MACHINE_FLAG=X64
145 glib_pollfd_format='%#I64x'
146 ;;
147 esac
149 AC_DEFINE([_WIN32_WINNT], [0x0601], [Target the Windows 7 API])
150 ;;
151 *)
152 glib_native_win32=no
153 glib_pid_type=int
154 glib_pid_format='i'
155 glib_pollfd_format='%d'
156 glib_dir_separator='/'
157 glib_searchpath_separator=':'
158 ;;
159 esac
160 case $host in
161 *-*-linux*)
162 glib_os_linux=yes
163 ;;
164 esac
166 AC_MSG_RESULT([$glib_native_win32])
168 AC_MSG_CHECKING([for the Android])
169 case $host in
170 *android*)
171 glib_native_android="yes"
172 ;;
173 *)
174 glib_native_android="no"
175 ;;
176 esac
177 AC_MSG_RESULT([$glib_native_android])
179 AC_SUBST(LIB_EXE_MACHINE_FLAG)
181 glib_have_carbon=no
182 AC_MSG_CHECKING([for Mac OS X Carbon support])
183 AC_TRY_CPP([
184 #include <Carbon/Carbon.h>
185 #include <CoreServices/CoreServices.h>
186 ], glib_have_carbon=yes)
188 AC_MSG_RESULT([$glib_have_carbon])
190 glib_have_cocoa=no
191 AC_MSG_CHECKING([for Mac OS X Cocoa support])
192 AC_TRY_CPP([
193 #include <Cocoa/Cocoa.h>
194 #ifdef GNUSTEP_BASE_VERSION
195 #error "Detected GNUstep, not Cocoa"
196 #endif
197 ], glib_have_cocoa=yes)
199 AC_MSG_RESULT([$glib_have_cocoa])
201 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
202 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
203 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
204 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
205 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
206 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
208 AS_IF([test "$glib_native_win32" = "yes"], [
209 AC_CHECK_TOOL(WINDRES, windres, no)
210 if test "$WINDRES" = no; then
211 AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
212 fi
213 AC_CHECK_TOOL(NM, nm, no)
214 if test "$NM" = no; then
215 AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
216 fi
217 AC_CHECK_TOOL(RANLIB, ranlib, :)
218 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
219 AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
220 ])
221 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
223 AS_IF([test "x$glib_have_carbon" = "xyes"], [
224 AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
225 CARBON_LIBS="-Wl,-framework,Carbon"
226 LDFLAGS="$LDFLAGS $CARBON_LIBS"
227 ], [CARBON_LIBS=""])
229 AC_SUBST([CARBON_LIBS])
230 ac_cv_have_os_x_9_or_later="no"
231 AS_IF([test "x$glib_have_cocoa" = "xyes"], [
232 AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
233 COCOA_LIBS="-Wl,-framework,Foundation -Wl,-framework,AppKit"
234 LDFLAGS="$LDFLAGS $COCOA_LIBS"
235 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
236 #include <AvailabilityMacros.h>
237 #if MAC_OS_X_VERSION_MIN_REQUIRED < 1090
238 #error Compiling for minimum OS X version before 10.9
239 #endif
240 ]])],[ac_cv_have_os_x_9_or_later="yes"])
241 ], [COCOA_LIBS=""])
242 AM_CONDITIONAL([MAC_OS_X_9], [test "x$ac_cv_have_os_x_9_or_later" = xyes])
243 AC_SUBST([COCOA_LIBS])
245 dnl declare --enable-* args and collect ac_help strings
246 AC_ARG_ENABLE(debug,
247 AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
248 [turn on debugging @<:@default=glib_debug_default@:>@]),,
249 enable_debug=glib_debug_default)
251 AC_ARG_ENABLE(gc_friendly,
252 [AS_HELP_STRING([--enable-gc-friendly],
253 [turn on garbage collector friendliness [default=no]])],,
254 [enable_gc_friendly=no])
255 AC_ARG_ENABLE(mem_pools,
256 [AS_HELP_STRING([--disable-mem-pools],
257 [disable all glib memory pools])],,
258 [disable_mem_pools=no])
260 GLIB_TESTS
262 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
263 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
264 AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
265 AC_MSG_RESULT([yes])
266 ], [ AC_MSG_RESULT([no]) ])
268 AC_MSG_CHECKING([whether to disable memory pools])
269 AS_IF([test "x$disable_mem_pools" = "xno"], [
270 AC_MSG_RESULT([no])
271 ], [
272 AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
273 AC_MSG_RESULT([yes])
274 ])
276 dnl location to install runtime libraries, e.g. ../../lib to install
277 dnl to /lib if libdir is /usr/lib
278 AC_ARG_WITH(runtime-libdir,
279 [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
280 [install runtime libraries relative to libdir])],
281 [],
282 [with_runtime_libdir=""])
283 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
284 AC_SUBST(GLIB_RUNTIME_LIBDIR)
285 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
287 dnl Check for a working C++ compiler, but do not bail out, if none is found.
288 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
289 AC_LANG_SAVE
290 AC_LANG_CPLUSPLUS
291 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
292 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
293 AC_LANG_RESTORE
295 AM_PROG_CC_C_O
296 AC_PROG_INSTALL
298 AC_SYS_LARGEFILE
300 PKG_PROG_PKG_CONFIG(0.16)
302 if test "x$enable_debug" = "xyes"; then
303 if test "x$cflags_set" != "x" ; then
304 case " $CFLAGS " in
305 *[[\ \ ]]-g[[\ \ ]]*) ;;
306 *) CFLAGS="$CFLAGS -g" ;;
307 esac
308 fi
309 GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
310 else
311 GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
313 if test "x$enable_debug" = "xno"; then
314 GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
315 fi
316 fi
318 # Ensure MSVC-compatible struct packing convention is used when
319 # compiling for Win32 with gcc.
320 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
321 # gcc2 uses "-fnative-struct".
322 if test x"$glib_native_win32" = xyes; then
323 if test x"$GCC" = xyes; then
324 msnative_struct=''
325 AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
326 if test -z "$ac_cv_prog_CC"; then
327 our_gcc="$CC"
328 else
329 our_gcc="$ac_cv_prog_CC"
330 fi
331 case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
332 2.)
333 if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
334 msnative_struct='-fnative-struct'
335 fi
336 ;;
337 *)
338 if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
339 msnative_struct='-mms-bitfields'
340 fi
341 ;;
342 esac
343 if test x"$msnative_struct" = x ; then
344 AC_MSG_RESULT([no way])
345 AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
346 else
347 CFLAGS="$CFLAGS $msnative_struct"
348 AC_MSG_RESULT([${msnative_struct}])
349 fi
350 fi
351 fi
352 GLIB_EXTRA_CFLAGS="${msnative_struct}"
353 AC_SUBST(GLIB_EXTRA_CFLAGS)
355 AC_EXEEXT
357 AC_PROG_AWK
358 AC_CHECK_PROGS(PERL, [perl5 perl])
360 # option to specify python interpreter to use; this just sets $PYTHON, so that
361 # we will fallback to reading $PYTHON if --with-python is not given, and
362 # python.m4 will get the expected input
363 AC_ARG_WITH(python,
364 AS_HELP_STRING([--with-python=PATH],
365 [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
366 [PYTHON="$withval"], [])
367 if test x"$PYTHON" = xyes; then
368 AC_MSG_ERROR([--with-python option requires a path or program argument])
369 fi
370 AM_PATH_PYTHON(2.7,,PYTHON="python2.7")
373 dnl ***********************
374 dnl *** Tests for iconv ***
375 dnl ***********************
376 dnl
377 dnl We do this before the gettext checks, to avoid distortion
379 dnl On Windows we use a native implementation
381 AS_IF([ test x"$glib_native_win32" = xyes], [
382 with_libiconv=native
383 ], [
384 AC_ARG_WITH(libiconv,
385 [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
386 [use the libiconv library])],,
387 [with_libiconv=maybe])
389 found_iconv=no
390 case $with_libiconv in
391 maybe)
392 # Check in the C library first
393 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
394 # Check if we have GNU libiconv
395 if test $found_iconv = "no"; then
396 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
397 fi
398 # Check if we have a iconv in -liconv, possibly from vendor
399 if test $found_iconv = "no"; then
400 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
401 fi
402 ;;
403 no)
404 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
405 ;;
406 gnu|yes)
407 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
408 ;;
409 native)
410 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
411 ;;
412 esac
414 if test "x$found_iconv" = "xno" ; then
415 AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
416 fi
417 ])
419 dnl
420 dnl zlib support
421 dnl
422 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
423 AS_IF([test "x$found_zlib" = "xno"], [
424 AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
425 if test "x$found_zlib" = "xno" ; then
426 AC_MSG_ERROR([*** Working zlib library and headers not found ***])
427 fi
428 ZLIB_LIBS='-lz'
429 AC_SUBST(ZLIB_LIBS)
430 ])
432 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
433 AC_SUBST(LIBFFI_CFLAGS)
434 AC_SUBST(LIBFFI_LIBS)
436 dnl
437 dnl gettext support
438 dnl
440 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
441 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
442 GLIB_GNU_GETTEXT
444 if test "$gt_cv_have_gettext" != "yes" ; then
445 AC_MSG_ERROR([
446 *** You must have either have gettext support in your C library, or use the
447 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html)
448 ])
449 fi
451 LIBS="$INTLLIBS $LIBS"
453 GETTEXT_PACKAGE=glib20
454 AC_SUBST(GETTEXT_PACKAGE)
455 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
456 [Define the gettext package to be used])
458 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
460 dnl
461 dnl Now we are done with gettext checks, figure out ICONV_LIBS
462 dnl
464 AS_IF([test x"$glib_native_win32" != xyes], [
465 if test x$with_libiconv != xno ; then
466 case " $INTLLIBS " in
467 *[[\ \ ]]-liconv[[\ \ ]]*) ;;
468 *) ICONV_LIBS="-liconv" ;;
469 esac
470 fi
471 ])
472 AC_SUBST(ICONV_LIBS)
474 case $with_libiconv in
475 gnu)
476 AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
477 ;;
478 native)
479 AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
480 ;;
481 esac
483 dnl Initialize libtool
484 LT_PREREQ([2.2])
485 LT_INIT([disable-static win32-dll])
486 dnl when using libtool 2.x create libtool early, because it's used in configure
487 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
490 AS_IF([test "$glib_native_win32" = "yes"], [
491 if test x$enable_static = xyes -a x$enable_shared = xyes; then
492 AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
493 fi
494 if test x$enable_static = xyes; then
495 glib_win32_static_compilation=yes
496 GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
497 #define GOBJECT_STATIC_COMPILATION 1"
498 AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
499 fi
500 ])
501 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
503 # Checks for library functions.
504 AC_FUNC_ALLOCA
505 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
506 AC_CHECK_FUNCS(timegm gmtime_r)
507 AC_FUNC_STRERROR_R()
509 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
510 [AC_TRY_LINK([#include <unistd.h>
511 extern int __libc_enable_secure;],
512 [return __libc_enable_secure;],
513 glib_cv_have_libc_enable_secure=yes,
514 glib_cv_have_libc_enable_secure=no)])
515 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
516 AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
517 [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
518 ])
520 AC_CHECK_SIZEOF(char)
521 AC_CHECK_SIZEOF(short)
522 AC_CHECK_SIZEOF(long)
523 AC_CHECK_SIZEOF(int)
524 AC_CHECK_SIZEOF(void *)
525 AC_CHECK_SIZEOF(long long)
526 AC_CHECK_SIZEOF(__int64)
528 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
529 [AC_TRY_LINK([#include <signal.h>
530 #include <sys/types.h>
531 sig_atomic_t val = 42;],
532 [return val == 42 ? 0 : 1],
533 ac_cv_type_sig_atomic_t=yes,
534 ac_cv_type_sig_atomic_t=no)])
535 if test x$ac_cv_type_sig_atomic_t = xyes; then
536 AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
537 [Define if you have the 'sig_atomic_t' type.])
538 fi
540 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
541 :
542 else
543 AC_MSG_ERROR([
544 *** GLib requires a 64 bit type. You might want to consider
545 *** using the GNU C compiler.
546 ])
547 fi
549 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
550 # long long is a 64 bit integer.
551 AC_MSG_CHECKING(for format to printf and scanf a guint64)
552 AC_CACHE_VAL(glib_cv_long_long_format,[
553 for format in ll q I64; do
554 AC_TRY_RUN([#include <stdio.h>
555 int main()
556 {
557 long long b, a = -0x3AFAFAFAFAFAFAFALL;
558 char buffer[1000];
559 sprintf (buffer, "%${format}u", a);
560 sscanf (buffer, "%${format}u", &b);
561 exit (b!=a);
562 }
563 ],
564 [glib_cv_long_long_format=${format}
565 break],
566 [],[:])
567 done])
568 AS_IF([ test -n "$glib_cv_long_long_format"], [
569 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
570 AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
571 if test x"$glib_cv_long_long_format" = xI64; then
572 AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
573 fi
574 ], [AC_MSG_RESULT(none)])
575 ],[ test x$ac_cv_sizeof___int64 = x8], [
576 # __int64 is a 64 bit integer.
577 AC_MSG_CHECKING(for format to printf and scanf a guint64)
578 # We know this is MSVCRT.DLL, and what the formats are
579 glib_cv_long_long_format=I64
580 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
581 AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
582 AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
583 ])
585 AC_C_CONST
587 dnl
588 dnl check in which direction the stack grows
589 dnl
590 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
591 AC_TRY_RUN([
592 volatile int *a = 0, *b = 0;
593 void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
594 int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
595 ],
596 glib_cv_stack_grows=yes
597 ,
598 glib_cv_stack_grows=no
599 ,)
600 ])
602 # check for flavours of varargs macros
603 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
604 AC_TRY_COMPILE([],[
605 int a(int p1, int p2, int p3);
606 #define call_a(...) a(1,__VA_ARGS__)
607 call_a(2,3);
608 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
609 AC_MSG_RESULT($g_have_iso_c_varargs)
611 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
612 AS_IF([test "$CXX" = ""], [
613 dnl No C++ compiler
614 g_have_iso_cxx_varargs=no
615 else
616 AC_LANG_CPLUSPLUS
617 AC_TRY_COMPILE([],[
618 int a(int p1, int p2, int p3);
619 #define call_a(...) a(1,__VA_ARGS__)
620 call_a(2,3);
621 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
622 AC_LANG_C
623 ])
624 AC_MSG_RESULT($g_have_iso_cxx_varargs)
626 AC_MSG_CHECKING(for GNUC varargs macros)
627 AC_TRY_COMPILE([],[
628 int a(int p1, int p2, int p3);
629 #define call_a(params...) a(1,params)
630 call_a(2,3);
631 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
632 AC_MSG_RESULT($g_have_gnuc_varargs)
634 # check for GNUC visibility support
635 AC_MSG_CHECKING(for GNUC visibility attribute)
636 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
637 void
638 __attribute__ ((visibility ("hidden")))
639 f_hidden (void)
640 {
641 }
642 void
643 __attribute__ ((visibility ("internal")))
644 f_internal (void)
645 {
646 }
647 void
648 __attribute__ ((visibility ("protected")))
649 f_protected (void)
650 {
651 }
652 void
653 __attribute__ ((visibility ("default")))
654 f_default (void)
655 {
656 }
657 int main (void)
658 {
659 f_hidden();
660 f_internal();
661 f_protected();
662 f_default();
663 return 0;
664 }
665 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
666 AC_MSG_RESULT($g_have_gnuc_visibility)
667 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
669 AC_MSG_CHECKING([whether using Sun Studio C compiler])
670 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
671 #else
672 # include "error: this is not Sun Studio."
673 #endif
674 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
675 AC_MSG_RESULT($g_have_sunstudio_visibility)
676 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
678 # check for bytesex stuff
679 AC_C_BIGENDIAN
680 if test x$ac_cv_c_bigendian = xuniversal ; then
681 AC_MSG_ERROR([Universal builds not supported: see https://bugzilla.gnome.org/show_bug.cgi?id=742548])
682 fi
685 # check for header files
686 AC_CHECK_HEADERS([sys/param.h sys/resource.h mach/mach_time.h])
687 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
688 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
689 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
690 AC_CHECK_HEADERS([linux/magic.h])
691 AC_CHECK_HEADERS([termios.h])
693 # Some versions of MSC lack these
694 AC_CHECK_HEADERS([dirent.h sys/time.h])
696 # We don't care about this, but we need to keep including it in
697 # glibconfig.h for backward compatibility
698 AC_CHECK_HEADERS([values.h])
700 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
701 [#if HAVE_SYS_PARAM_H
702 #include <sys/param.h>
703 #endif
704 ])
705 AC_CHECK_FUNCS(sysctlbyname)
707 AC_HEADER_MAJOR
708 AC_CHECK_HEADERS([xlocale.h])
710 # check for structure fields
711 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec, struct stat.st_birthtime, struct stat.st_birthtimensec, struct stat.st_birthtim, struct stat.st_birthtim.tv_nsec])
712 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
713 #include <sys/stat.h>
714 #ifdef G_OS_UNIX
715 #include <unistd.h>
716 #endif
717 #ifdef HAVE_SYS_STATFS_H
718 #include <sys/statfs.h>
719 #endif
720 #ifdef HAVE_SYS_PARAM_H
721 #include <sys/param.h>
722 #endif
723 #ifdef HAVE_SYS_MOUNT_H
724 #include <sys/mount.h>
725 #endif])
726 # struct statvfs.f_basetype is available on Solaris but not for Linux.
727 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
728 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
729 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
731 AC_STRUCT_DIRENT_D_TYPE
733 # Checks for libcharset
734 AM_LANGINFO_CODESET
735 gl_GLIBC21
736 AC_ARG_WITH(charsetalias-dir,
737 AS_HELP_STRING([--with-charsetalias-dir=DIR], [directory for charset.alias file [LIBDIR]]),
738 [],
739 [with_charsetalias_dir='${libdir}'])
740 GLIB_CHARSETALIAS_DIR=$with_charsetalias_dir
741 AC_SUBST(GLIB_CHARSETALIAS_DIR)
743 # check additional type sizes
744 AC_CHECK_SIZEOF(size_t)
746 dnl Try to figure out whether gsize should be long or int
747 AC_MSG_CHECKING([for the appropriate definition for size_t])
749 case $ac_cv_sizeof_size_t in
750 $ac_cv_sizeof_short)
751 glib_size_type=short
752 ;;
753 $ac_cv_sizeof_int)
754 glib_size_type=int
755 ;;
756 $ac_cv_sizeof_long)
757 glib_size_type=long
758 ;;
759 $ac_cv_sizeof_long_long)
760 glib_size_type='long long'
761 ;;
762 $ac_cv_sizeof__int64)
763 glib_size_type='__int64'
764 ;;
765 *) AC_MSG_ERROR([No type matching size_t in size])
766 ;;
767 esac
769 dnl If int/long are the same size, we see which one produces
770 dnl warnings when used in the location as size_t. (This matters
771 dnl on AIX with xlc)
772 dnl
773 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
774 test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
775 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
776 #if defined(_AIX) && !defined(__GNUC__)
777 #pragma options langlvl=stdc89
778 #endif
779 #include <stddef.h>
780 int main ()
781 {
782 size_t s = 1;
783 unsigned int *size_int = &s;
784 return (int)*size_int;
785 }
786 ]])],glib_size_type=int,
787 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
788 #if defined(_AIX) && !defined(__GNUC__)
789 #pragma options langlvl=stdc89
790 #endif
791 #include <stddef.h>
792 int main ()
793 {
794 size_t s = 1;
795 unsigned long *size_long = &s;
796 return (int)*size_long;
797 }
798 ]])],glib_size_type=long)])
799 ])
801 AC_MSG_RESULT(unsigned $glib_size_type)
803 AC_CHECK_SIZEOF(ssize_t)
805 dnl Try to figure out whether gssize should be long or int
806 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
808 case $ac_cv_sizeof_ssize_t in
809 $ac_cv_sizeof_short)
810 glib_ssize_type=short
811 ;;
812 $ac_cv_sizeof_int)
813 glib_ssize_type=int
814 ;;
815 $ac_cv_sizeof_long)
816 glib_ssize_type=long
817 ;;
818 $ac_cv_sizeof_long_long)
819 glib_ssize_type='long long'
820 ;;
821 $ac_cv_sizeof__int64)
822 glib_ssize_type='__int64'
823 ;;
824 *) AC_MSG_ERROR([No type matching ssize_t in size])
825 ;;
826 esac
828 dnl If int/long are the same size, we see which one produces
829 dnl warnings when used in the location as ssize_t. (This matters
830 dnl on Android where ssize_t is long and size_t is unsigned int)
831 dnl
832 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
833 test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
834 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
835 #if defined(_AIX) && !defined(__GNUC__)
836 #pragma options langlvl=stdc89
837 #endif
838 #include <stddef.h>
839 #ifdef HAVE_INTTYPES_H
840 # include <inttypes.h>
841 #endif
842 #ifdef HAVE_STDINT_H
843 # include <stdint.h>
844 #endif
845 #include <sys/types.h>
846 int main ()
847 {
848 ssize_t s = 1;
849 int *size_int = &s;
850 return (int)*size_int;
851 }
852 ]])],glib_ssize_type=int,
853 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
854 #if defined(_AIX) && !defined(__GNUC__)
855 #pragma options langlvl=stdc89
856 #endif
857 #include <stddef.h>
858 #ifdef HAVE_INTTYPES_H
859 # include <inttypes.h>
860 #endif
861 #ifdef HAVE_STDINT_H
862 # include <stdint.h>
863 #endif
864 #include <sys/types.h>
865 int main ()
866 {
867 ssize_t s = 1;
868 long *size_long = &s;
869 return (int)*size_long;
870 }
871 ]])],glib_ssize_type=long)])
872 ])
874 AC_MSG_RESULT($glib_ssize_type)
876 # Check for some functions
877 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk mkostemp link)
878 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
879 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
880 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
881 AC_CHECK_FUNCS(splice)
882 AC_CHECK_FUNCS(prlimit)
884 # To avoid finding a compatibility unusable statfs, which typically
885 # successfully compiles, but warns to use the newer statvfs interface:
886 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
887 AS_IF([test $ac_cv_header_sys_statfs_h = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
889 AC_MSG_CHECKING([whether to use statfs or statvfs])
890 # Some systems have both statfs and statvfs, pick the most "native" for these
891 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
892 [
893 # on solaris and irix, statfs doesn't even have the f_bavail field
894 AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
895 [ac_cv_func_statfs=no],
896 # else, at least on linux, statfs is the actual syscall
897 [ac_cv_func_statvfs=no])
898 ])
900 AS_IF([test x$ac_cv_func_statfs = xyes],
901 [
902 AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
903 AC_MSG_RESULT([statfs])
904 ],
905 [test x$ac_cv_func_statvfs = xyes],
906 [
907 AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
908 AC_MSG_RESULT([statvfs])
909 ],
910 [ AC_MSG_RESULT([neither])])
912 AC_CHECK_HEADERS(crt_externs.h)
913 AC_CHECK_FUNCS(_NSGetEnviron)
915 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
917 # Internet address families
918 if test $glib_native_win32 = yes; then
919 glib_inet_includes=["
920 #include <winsock2.h>
921 "]
922 else
923 glib_inet_includes=["
924 #include <sys/types.h>
925 #include <sys/socket.h>
926 "]
927 fi
929 glib_failed=false
930 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
931 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
932 # winsock defines this even though it doesn't support it
933 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
934 if $glib_failed ; then
935 AC_MSG_ERROR([Could not determine values for AF_INET* constants])
936 fi
938 glib_failed=false
939 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
940 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
941 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
942 if $glib_failed ; then
943 AC_MSG_ERROR([Could not determine values for MSG_* constants])
944 fi
946 AC_CHECK_FUNCS(endservent if_nametoindex if_indextoname sendmmsg recvmmsg)
948 AC_MSG_CHECKING([for SIOCGIFADDR])
949 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
950 [[
951 #include <sys/ioctl.h>
952 #include <net/if.h>
953 ]],
954 [[
955 struct ifreq ifr;
956 ioctl(0, SIOCGIFADDR, &ifr);
957 ]])], [
958 AC_MSG_RESULT(yes)
959 AC_DEFINE(HAVE_SIOCGIFADDR, 1, [SIOCGIFADDR is available])
960 ], [
961 AC_MSG_RESULT(no)
962 ])
964 AC_MSG_CHECKING([if ip_mreq_source.imr_interface has s_addr member])
965 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
966 [[
967 #include <netinet/in.h>
968 ]],
969 [[
970 struct ip_mreq_source mc_req_src;
971 mc_req_src.imr_interface.s_addr = 0;
972 ]])], [
973 AC_MSG_RESULT(yes)
974 ], [
975 AC_MSG_RESULT(no)
976 AC_DEFINE(BROKEN_IP_MREQ_SOURCE_STRUCT, 1, [struct ip_mreq_source definition is broken on Android NDK <= r16])
977 ])
979 AS_IF([test $glib_native_win32 = yes], [
980 # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
981 # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
982 # they aren't present at run-time (on Windows 2000).
983 AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
984 AC_SUBST(WSPIAPI_INCLUDE)
985 ], [
986 # Android does not have C_IN in public headers, we define it wherever necessary
987 AS_IF([test $glib_native_android != yes], [
988 AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
989 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
990 #include <arpa/nameser.h>],
991 [int qclass = C_IN;])],
992 [AC_MSG_RESULT([no])],
993 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
994 #include <arpa/nameser.h>
995 #include <arpa/nameser_compat.h>],
996 [int qclass = C_IN;])],
997 [AC_MSG_RESULT([yes])
998 NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
999 [AC_MSG_ERROR([could not compile test program either way])])])])
1000 AC_SUBST(NAMESER_COMPAT_INCLUDE)
1002 # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1003 NETWORK_LIBS=""
1004 AC_MSG_CHECKING([for res_query])
1005 AC_TRY_LINK([#include <sys/types.h>
1006 #include <netinet/in.h>
1007 #include <arpa/nameser.h>
1008 #include <resolv.h>
1009 ],[
1010 res_query("test", 0, 0, (void *)0, 0);
1011 ],[AC_MSG_RESULT([yes])],
1012 [save_libs="$LIBS"
1013 LIBS="-lresolv $LIBS"
1014 AC_TRY_LINK([#include <sys/types.h>
1015 #include <netinet/in.h>
1016 #include <arpa/nameser.h>
1017 #include <resolv.h>
1018 ],[
1019 res_query("test", 0, 0, (void *)0, 0);
1020 ],[AC_MSG_RESULT([in -lresolv])
1021 NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1022 [LIBS="-lbind $save_libs"
1023 AC_TRY_LINK([#include <resolv.h>],
1024 [res_query("test", 0, 0, (void *)0, 0);],
1025 [AC_MSG_RESULT([in -lbind])
1026 NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1027 [AC_MSG_ERROR(not found)])])
1028 LIBS="$save_libs"])
1029 AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1030 [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1031 [AC_MSG_ERROR(Could not find socket())]))
1032 save_libs="$LIBS"
1033 LIBS="$LIBS $NETWORK_LIBS"
1035 AC_MSG_CHECKING([for res_init])
1036 AC_TRY_LINK([#include <sys/types.h>
1037 #include <netinet/in.h>
1038 #include <arpa/nameser.h>
1039 #include <resolv.h>
1040 ],[
1041 res_init();
1042 ],[AC_MSG_RESULT([yes])
1043 AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1044 ],[AC_MSG_RESULT([no])])
1046 AC_MSG_CHECKING([for res_nclose])
1047 AC_TRY_LINK([#include <sys/types.h>
1048 #include <netinet/in.h>
1049 #include <arpa/nameser.h>
1050 #include <resolv.h>
1051 ],[
1052 struct __res_state res;
1053 res_nclose(&res);
1054 ],[AC_MSG_RESULT([yes])
1055 AC_DEFINE(HAVE_RES_NCLOSE, 1, [Define to 1 if you have the 'res_nclose' function.])
1056 ],[AC_MSG_RESULT([no])])
1058 AC_MSG_CHECKING([for res_ndestroy])
1059 AC_TRY_LINK([#include <sys/types.h>
1060 #include <netinet/in.h>
1061 #include <arpa/nameser.h>
1062 #include <resolv.h>
1063 ],[
1064 struct __res_state res;
1065 res_ndestroy(&res);
1066 ],[AC_MSG_RESULT([yes])
1067 AC_DEFINE(HAVE_RES_NDESTROY, 1, [Define to 1 if you have the 'res_ndestroy' function.])
1068 ],[AC_MSG_RESULT([no])])
1070 AC_MSG_CHECKING([for res_ninit])
1071 AC_TRY_LINK([#include <sys/types.h>
1072 #include <netinet/in.h>
1073 #include <arpa/nameser.h>
1074 #include <resolv.h>
1075 ],[
1076 struct __res_state res;
1077 res_ninit(&res);
1078 ],[AC_MSG_RESULT([yes])
1079 AC_DEFINE(HAVE_RES_NINIT, 1, [Define to 1 if you have the 'res_ninit' function.])
1080 ],[AC_MSG_RESULT([no])])
1082 AC_MSG_CHECKING([for res_nquery])
1083 AC_TRY_LINK([#include <sys/types.h>
1084 #include <netinet/in.h>
1085 #include <arpa/nameser.h>
1086 #include <resolv.h>
1087 ],[
1088 struct __res_state res;
1089 res_nquery(&res, "test", 0, 0, (void *)0, 0);
1090 ],[AC_MSG_RESULT([yes])
1091 AC_DEFINE(HAVE_RES_NQUERY, 1, [Define to 1 if you have the 'res_nquery' function.])
1092 ],[AC_MSG_RESULT([no])])
1093 LIBS="$save_libs"
1094 ])
1095 AC_SUBST(NETWORK_LIBS)
1097 AC_CHECK_HEADER([linux/netlink.h],
1098 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1099 [#include <sys/socket.h>])
1100 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1102 AC_CHECK_TYPE([struct ip_mreqn], [
1103 AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1104 [#include <netinet/in.h>])
1106 case $host in
1107 *-*-solaris* )
1108 AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1109 AC_DEFINE(_XOPEN_SOURCE, 2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1110 AC_DEFINE(__EXTENSIONS__, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1111 ;;
1112 esac
1114 dnl
1115 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1116 dnl
1117 AS_IF([test "$ac_cv_func_statfs" = yes], [
1118 AC_MSG_CHECKING([number of arguments to statfs()])
1119 AC_TRY_COMPILE([#include <unistd.h>
1120 #ifdef HAVE_SYS_PARAM_H
1121 #include <sys/param.h>
1122 #endif
1123 #ifdef HAVE_SYS_VFS_H
1124 #include <sys/vfs.h>
1125 #endif
1126 #ifdef HAVE_SYS_MOUNT_H
1127 #include <sys/mount.h>
1128 #endif
1129 #ifdef HAVE_SYS_STATFS_H
1130 #include <sys/statfs.h>
1131 #endif], [struct statfs st;
1132 statfs("/", &st);],[
1133 AC_MSG_RESULT([2])
1134 AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1135 AC_TRY_COMPILE([#include <unistd.h>
1136 #ifdef HAVE_SYS_PARAM_H
1137 #include <sys/param.h>
1138 #endif
1139 #ifdef HAVE_SYS_VFS_H
1140 #include <sys/vfs.h>
1141 #endif
1142 #ifdef HAVE_SYS_MOUNT_H
1143 #include <sys/mount.h>
1144 #endif
1145 #ifdef HAVE_SYS_STATFS_H
1146 #include <sys/statfs.h>
1147 #endif], [struct statfs st;
1148 statfs("/", &st, sizeof (st), 0);],[
1149 AC_MSG_RESULT([4])
1150 AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1151 AC_MSG_RESULT(unknown)
1152 AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1153 ])
1155 dnl
1156 dnl open takes O_DIRECTORY as an option
1157 dnl
1158 AC_MSG_CHECKING([open() option O_DIRECTORY])
1159 AC_TRY_COMPILE([#include <fcntl.h>
1160 #include <sys/types.h>
1161 #include <sys/stat.h>],
1162 [open(0, O_DIRECTORY, 0);],[
1163 AC_MSG_RESULT([yes])
1164 AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1165 AC_MSG_RESULT([no])])
1167 #
1168 # Check whether to use an included printf
1169 #
1170 AC_FUNC_VSNPRINTF_C99
1171 AC_FUNC_PRINTF_UNIX98
1173 AC_ARG_ENABLE(included-printf,
1174 [AS_HELP_STRING([--enable-included-printf],
1175 [use included printf [default=auto]])],
1176 enable_included_printf="$enableval")
1178 need_included_printf=no
1179 if test "x$enable_included_printf" = "xyes" ; then
1180 need_included_printf=yes
1181 fi
1182 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1183 need_included_printf=yes
1184 fi
1185 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1186 need_included_printf=yes
1187 fi
1188 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1189 test -z "$glib_cv_long_long_format" ; then
1190 need_included_printf=yes
1191 fi
1193 if test "x$enable_included_printf" = "xno" &&
1194 test "x$need_included_printf" = "xyes" ; then
1195 AC_MSG_ERROR([
1196 *** Your C library's printf doesn't appear to have the features that
1197 *** GLib needs, but you specified --enable-included-printf=no.])
1198 fi
1200 enable_included_printf=$need_included_printf
1202 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1203 AS_IF([test "$enable_included_printf" != "yes"], [
1204 AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1205 ], [
1206 if test -z "$glib_cv_long_long_format" ; then
1207 glib_cv_long_long_format="ll"
1208 fi
1209 AC_DEFINE(HAVE_VASPRINTF,1)
1210 ])
1212 # Checks needed for gnulib vasnprintf
1213 bh_C_SIGNED
1214 jm_AC_TYPE_LONG_LONG
1215 gt_TYPE_LONGDOUBLE
1216 gt_TYPE_WCHAR_T
1217 gt_TYPE_WINT_T
1218 AC_TYPE_SIZE_T
1219 AC_CHECK_TYPES(ptrdiff_t)
1220 jm_AC_TYPE_INTMAX_T
1221 AC_CHECK_FUNCS([snprintf strnlen wcslen wcsnlen mbrtowc wcrtomb])
1222 AC_FUNC_SNPRINTF_C99
1224 dnl Check for nl_langinfo and CODESET
1225 AC_LANG_SAVE
1226 AC_LANG_C
1227 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1228 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1229 [char *codeset = nl_langinfo (CODESET);])],
1230 [glib_cv_langinfo_codeset=yes],
1231 [glib_cv_langinfo_codeset=no])])
1232 if test x$glib_cv_langinfo_codeset = xyes; then
1233 AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1234 fi
1236 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1237 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1238 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1239 [char *str;
1240 str = nl_langinfo (PM_STR);
1241 str = nl_langinfo (D_T_FMT);
1242 str = nl_langinfo (D_FMT);
1243 str = nl_langinfo (T_FMT);
1244 str = nl_langinfo (T_FMT_AMPM);
1245 str = nl_langinfo (MON_1);
1246 str = nl_langinfo (ABMON_12);
1247 str = nl_langinfo (DAY_1);
1248 str = nl_langinfo (ABDAY_7);])],
1249 [glib_cv_langinfo_time=yes],
1250 [glib_cv_langinfo_time=no])])
1251 if test x$glib_cv_langinfo_time = xyes; then
1252 AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1253 fi
1255 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1256 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1257 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1258 [char *str;
1259 str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1260 str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1261 str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1262 str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1263 str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1264 str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1265 str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1266 str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1267 str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1268 str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1269 [glib_cv_langinfo_outdigit=yes],
1270 [glib_cv_langinfo_outdigit=no])])
1271 if test x$glib_cv_langinfo_outdigit = xyes; then
1272 AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1273 fi
1275 dnl Check for nl_langinfo and ALTMON_n
1276 AC_CACHE_CHECK([for nl_langinfo (ALTMON_n)], glib_cv_langinfo_altmon,[
1277 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1278 [char *str;
1279 str = nl_langinfo (ALTMON_1);
1280 str = nl_langinfo (ALTMON_2);
1281 str = nl_langinfo (ALTMON_3);
1282 str = nl_langinfo (ALTMON_4);
1283 str = nl_langinfo (ALTMON_5);
1284 str = nl_langinfo (ALTMON_6);
1285 str = nl_langinfo (ALTMON_7);
1286 str = nl_langinfo (ALTMON_8);
1287 str = nl_langinfo (ALTMON_9);
1288 str = nl_langinfo (ALTMON_10);
1289 str = nl_langinfo (ALTMON_11);
1290 str = nl_langinfo (ALTMON_12);])],
1291 [glib_cv_langinfo_altmon=yes],
1292 [glib_cv_langinfo_altmon=no])])
1293 if test x$glib_cv_langinfo_altmon = xyes; then
1294 AC_DEFINE(HAVE_LANGINFO_ALTMON,1,[Have nl_langinfo (ALTMON_n)])
1295 fi
1297 dnl Check for nl_langinfo and _NL_ABALTMON_n
1298 AC_CACHE_CHECK([for nl_langinfo (_NL_ABALTMON_n)], glib_cv_langinfo_abaltmon,[
1299 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1300 [char *str;
1301 str = nl_langinfo (_NL_ABALTMON_1);
1302 str = nl_langinfo (_NL_ABALTMON_2);
1303 str = nl_langinfo (_NL_ABALTMON_3);
1304 str = nl_langinfo (_NL_ABALTMON_4);
1305 str = nl_langinfo (_NL_ABALTMON_5);
1306 str = nl_langinfo (_NL_ABALTMON_6);
1307 str = nl_langinfo (_NL_ABALTMON_7);
1308 str = nl_langinfo (_NL_ABALTMON_8);
1309 str = nl_langinfo (_NL_ABALTMON_9);
1310 str = nl_langinfo (_NL_ABALTMON_10);
1311 str = nl_langinfo (_NL_ABALTMON_11);
1312 str = nl_langinfo (_NL_ABALTMON_12);])],
1313 [glib_cv_langinfo_abaltmon=yes],
1314 [glib_cv_langinfo_abaltmon=no])])
1315 if test x$glib_cv_langinfo_abaltmon = xyes; then
1316 AC_DEFINE(HAVE_LANGINFO_ABALTMON,1,[Have nl_langinfo (_NL_ABALTMON_n)])
1317 fi
1318 AC_LANG_RESTORE
1321 dnl ****************************************
1322 dnl *** strlcpy/strlcat ***
1323 dnl ****************************************
1324 # Check for strlcpy
1325 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1326 AC_TRY_RUN([#include <stdlib.h>
1327 #include <string.h>
1328 int main() {
1329 char p[10];
1330 (void) strlcpy (p, "hi", 10);
1331 if (strlcat (p, "bye", 0) != 3)
1332 return 1;
1333 return 0;
1334 }], glib_cv_have_strlcpy=yes,
1335 glib_cv_have_strlcpy=no,
1336 glib_cv_have_strlcpy=no)])
1337 if test "$glib_cv_have_strlcpy" = "yes"; then
1338 AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1339 fi
1342 dnl **********************
1343 dnl *** va_copy checks ***
1344 dnl **********************
1345 dnl we currently check for all three va_copy possibilities, so we get
1346 dnl all results in config.log for bug reports.
1347 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1348 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1349 #include <stdlib.h>
1350 void f (int i, ...) {
1351 va_list args1, args2;
1352 va_start (args1, i);
1353 va_copy (args2, args1);
1354 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1355 exit (1);
1356 va_end (args1); va_end (args2);
1357 }
1358 int main() {
1359 f (0, 42);
1360 return 0;
1361 }]])],
1362 [glib_cv_va_copy=yes],
1363 [glib_cv_va_copy=no])
1364 ])
1365 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1366 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1367 #include <stdlib.h>
1368 void f (int i, ...) {
1369 va_list args1, args2;
1370 va_start (args1, i);
1371 __va_copy (args2, args1);
1372 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1373 exit (1);
1374 va_end (args1); va_end (args2);
1375 }
1376 int main() {
1377 f (0, 42);
1378 return 0;
1379 }]])],
1380 [glib_cv___va_copy=yes],
1381 [glib_cv___va_copy=no])
1382 ])
1384 if test "x$glib_cv_va_copy" = "xyes"; then
1385 g_va_copy_func=va_copy
1386 else if test "x$glib_cv___va_copy" = "xyes"; then
1387 g_va_copy_func=__va_copy
1388 fi
1389 fi
1391 if test -n "$g_va_copy_func"; then
1392 AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1393 fi
1395 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1396 AC_TRY_RUN([#include <stdarg.h>
1397 #include <stdlib.h>
1398 void f (int i, ...) {
1399 va_list args1, args2;
1400 va_start (args1, i);
1401 args2 = args1;
1402 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1403 exit (1);
1404 va_end (args1); va_end (args2);
1405 }
1406 int main() {
1407 f (0, 42);
1408 return 0;
1409 }],
1410 [glib_cv_va_val_copy=yes],
1411 [glib_cv_va_val_copy=no],
1412 [glib_cv_va_val_copy=yes])
1413 ])
1415 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1416 AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1417 ])
1419 dnl ***********************
1420 dnl *** g_module checks ***
1421 dnl ***********************
1422 G_MODULE_LIBS=
1423 G_MODULE_LIBS_EXTRA=
1424 G_MODULE_PLUGIN_LIBS=
1425 if test x"$glib_native_win32" = xyes; then
1426 dnl No use for this on Win32
1427 G_MODULE_LDFLAGS=
1428 else
1429 export SED
1430 eval G_MODULE_LDFLAGS=$export_dynamic_flag_spec
1431 fi
1432 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1433 G_MODULE_NEED_USCORE=0
1434 G_MODULE_BROKEN_RTLD_GLOBAL=0
1435 G_MODULE_HAVE_DLERROR=0
1436 dnl *** force native WIN32 shared lib loader
1437 if test -z "$G_MODULE_IMPL"; then
1438 case "$host" in
1439 *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1440 esac
1441 fi
1442 dnl *** force native AIX library loader
1443 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1444 if test -z "$G_MODULE_IMPL"; then
1445 case "$host" in
1446 *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1447 esac
1448 fi
1449 dnl *** dlopen() and dlsym() in system libraries
1450 AS_IF([ test -z "$G_MODULE_IMPL"], [
1451 AC_CHECK_FUNC(dlopen,
1452 [AC_CHECK_FUNC(dlsym,
1453 [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1454 [])
1455 ])
1456 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1457 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1458 AC_CHECK_FUNC(NSLinkModule,
1459 [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1460 G_MODULE_NEED_USCORE=1],
1461 [])
1462 ])
1463 dnl *** dlopen() and dlsym() in libdl
1464 AS_IF([ test -z "$G_MODULE_IMPL"], [
1465 AC_CHECK_LIB(dl, dlopen,
1466 [AC_CHECK_LIB(dl, dlsym,
1467 [G_MODULE_LIBS=-ldl
1468 G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1469 [])
1470 ])
1471 dnl *** additional checks for G_MODULE_IMPL_DL
1472 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1473 LIBS_orig="$LIBS"
1474 LDFLAGS_orig="$LDFLAGS"
1475 LIBS="$G_MODULE_LIBS $LIBS"
1476 LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1477 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1478 echo "void glib_plugin_test(void) { }" > plugin.c
1479 ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1480 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1481 ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1482 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1483 -shrext ".o" -avoid-version plugin.lo \
1484 -rpath /dont/care >/dev/null 2>&1
1485 AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1486 glib_cv_rtldglobal_broken,[
1487 AC_TRY_RUN([
1488 #include <dlfcn.h>
1489 #ifndef RTLD_GLOBAL
1490 # define RTLD_GLOBAL 0
1491 #endif
1492 #ifndef RTLD_LAZY
1493 # define RTLD_LAZY 0
1494 #endif
1495 int glib_plugin_test;
1496 int main () {
1497 void *handle, *global, *local;
1498 global = &glib_plugin_test;
1499 handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1500 if (!handle) return 0;
1501 local = dlsym (handle, "glib_plugin_test");
1502 return global == local;
1503 } ],
1504 [glib_cv_rtldglobal_broken=no],
1505 [glib_cv_rtldglobal_broken=yes],
1506 [glib_cv_rtldglobal_broken=no])
1507 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1508 rmdir ${objdir} 2>/dev/null
1509 ])
1510 if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1511 G_MODULE_BROKEN_RTLD_GLOBAL=1
1512 else
1513 G_MODULE_BROKEN_RTLD_GLOBAL=0
1514 fi
1515 dnl *** check whether we need preceeding underscores
1516 AC_CACHE_CHECK([for preceeding underscore in symbols],
1517 glib_cv_uscore,[
1518 AC_TRY_RUN([#include <dlfcn.h>
1519 int glib_underscore_test (void) { return 42; }
1520 int main() {
1521 void *f1 = (void*)0, *f2 = (void*)0, *handle;
1522 handle = dlopen ((void*)0, 0);
1523 if (handle) {
1524 f1 = dlsym (handle, "glib_underscore_test");
1525 f2 = dlsym (handle, "_glib_underscore_test");
1526 } return (!f2 || f1);
1527 }],
1528 [glib_cv_uscore=yes],
1529 [glib_cv_uscore=no],
1530 [])
1531 rm -f plugin.c plugin.$ac_objext plugin.lo
1532 ])
1533 GLIB_ASSERT_SET(glib_cv_uscore)
1534 if test "x$glib_cv_uscore" = "xyes"; then
1535 G_MODULE_NEED_USCORE=1
1536 else
1537 G_MODULE_NEED_USCORE=0
1538 fi
1540 AC_CHECK_DECL([RTLD_LAZY],
1541 [AC_DEFINE(HAVE_RTLD_LAZY, 1, [Define to 1 if RTLD_LAZY is available])],
1542 [], [[#include <dlfcn.h>]])
1543 AC_CHECK_DECL([RTLD_NOW],
1544 [AC_DEFINE(HAVE_RTLD_NOW, 1, [Define to 1 if RTLD_NOW is available])],
1545 [], [[#include <dlfcn.h>]])
1546 AC_CHECK_DECL([RTLD_GLOBAL],
1547 [AC_DEFINE(HAVE_RTLD_GLOBAL, 1, [Define to 1 if RTLD_GLOBAL is available])],
1548 [], [[#include <dlfcn.h>]])
1550 LDFLAGS="$LDFLAGS_orig"
1551 dnl *** check for having dlerror()
1552 AC_CHECK_FUNC(dlerror,
1553 [G_MODULE_HAVE_DLERROR=1],
1554 [G_MODULE_HAVE_DLERROR=0])
1555 LIBS="$LIBS_orig"
1556 ])
1557 dnl *** done, have we got an implementation?
1558 if test -z "$G_MODULE_IMPL"; then
1559 G_MODULE_IMPL=0
1560 G_MODULE_SUPPORTED=false
1561 else
1562 G_MODULE_SUPPORTED=true
1563 fi
1565 AC_MSG_CHECKING(for the suffix of module shared libraries)
1566 export SED
1567 module=yes eval std_shrext=$shrext_cmds
1568 # chop the initial dot
1569 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1570 AC_MSG_RESULT(.$glib_gmodule_suffix)
1571 # any reason it may fail?
1572 if test "x$glib_gmodule_suffix" = x; then
1573 AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1574 fi
1576 AC_SUBST(G_MODULE_SUPPORTED)
1577 AC_SUBST(G_MODULE_IMPL)
1578 AC_SUBST(G_MODULE_LIBS)
1579 AC_SUBST(G_MODULE_LIBS_EXTRA)
1580 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1581 AC_SUBST(G_MODULE_LDFLAGS)
1582 AC_SUBST(G_MODULE_HAVE_DLERROR)
1583 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1584 AC_SUBST(G_MODULE_NEED_USCORE)
1585 AC_SUBST(GLIB_DEBUG_FLAGS)
1587 dnl **********************
1588 dnl *** g_spawn checks ***
1589 dnl **********************
1591 AC_MSG_CHECKING(for gspawn implementation)
1592 case "$host" in
1593 *-*-mingw*)
1594 GSPAWN=gspawn-win32.lo
1595 ;;
1596 *)
1597 GSPAWN=gspawn.lo
1598 ;;
1599 esac
1600 AC_MSG_RESULT($GSPAWN)
1601 AC_SUBST(GSPAWN)
1603 dnl *************************
1604 dnl *** GIOChannel checks ***
1605 dnl *************************
1607 AC_MSG_CHECKING(for GIOChannel implementation)
1608 case "$host" in
1609 *-*-mingw*)
1610 GIO=giowin32.lo
1611 ;;
1612 *)
1613 GIO=giounix.lo
1614 ;;
1615 esac
1616 AC_MSG_RESULT($GIO)
1617 AC_SUBST(GIO)
1619 dnl *********************************
1620 dnl *** Directory for GIO modules ***
1621 dnl *********************************
1623 AC_ARG_WITH(gio-module-dir,
1624 [AS_HELP_STRING([--with-gio-module-dir=DIR],
1625 [load gio modules from this directory [LIBDIR/gio/modules]])],
1626 [],
1627 [with_gio_module_dir='${libdir}/gio/modules'])
1628 GIO_MODULE_DIR=$with_gio_module_dir
1629 AC_SUBST(GIO_MODULE_DIR)
1631 dnl **********************************
1632 dnl *** Check for libselinux (GIO) ***
1633 dnl **********************************
1634 AC_ARG_ENABLE(selinux,
1635 AS_HELP_STRING([--disable-selinux],
1636 [build without selinux support]))
1637 msg_selinux=no
1638 SELINUX_LIBS=
1639 AS_IF([ test "x$enable_selinux" != "xno"], [
1641 AC_CHECK_LIB(selinux, is_selinux_enabled,
1642 [AC_CHECK_HEADERS(selinux/selinux.h,
1643 [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1644 [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1645 SELINUX_LIBS="-lselinux"
1646 msg_selinux=yes])
1647 ])
1648 ])
1649 ])
1650 AC_SUBST(SELINUX_LIBS)
1652 dnl *****************************
1653 dnl ** Check for inotify (GIO) **
1654 dnl *****************************
1655 inotify_support=no
1656 AC_CHECK_HEADERS([sys/inotify.h],
1657 [
1658 AC_CHECK_FUNCS(inotify_init1, [inotify_support=yes], [inotify_support=no])
1659 ])
1661 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1663 dnl ****************************
1664 dnl ** Check for kqueue (GIO) **
1665 dnl ****************************
1666 kqueue_support=no
1667 AC_CHECK_HEADERS([sys/event.h],
1668 [
1669 AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1670 ])
1672 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1674 dnl ****************************
1675 dnl *** Checks for FAM (GIO) ***
1676 dnl ****************************
1678 should_disable_fam=no
1680 AC_ARG_ENABLE(fam,
1681 AS_HELP_STRING([--disable-fam],
1682 [don't use fam for file system monitoring]),
1683 [
1684 if test "x$enable_fam" = "xno"; then
1685 should_disable_fam=yes
1686 fi
1687 ]
1688 )
1689 fam_support=no
1690 FAM_LIBS=
1691 if test "x$should_disable_fam" = "xno"; then
1692 AC_CHECK_LIB(fam, FAMOpen,
1693 [AC_CHECK_HEADERS(fam.h,
1694 [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1695 AC_CHECK_LIB(fam, FAMNoExists,
1696 AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1697 FAM_LIBS="-lfam"]
1698 fam_support=yes,
1699 AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1700 AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1701 AC_SUBST(FAM_LIBS)
1702 fi
1703 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1706 dnl *****************************
1707 dnl *** Check for xattr (GIO) ***
1708 dnl *****************************
1709 AC_ARG_ENABLE(xattr,
1710 AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1711 msg_xattr=no
1712 XATTR_LIBS=
1713 AS_IF([ test "x$enable_xattr" != "xno"], [
1715 dnl either glibc or libattr can provide xattr support
1717 dnl for both of them, we check for getxattr being in
1718 dnl the library and a valid xattr header.
1720 dnl try glibc
1721 AC_CHECK_LIB(c, getxattr,
1722 [AC_CHECK_HEADERS(sys/xattr.h,
1723 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1724 msg_xattr=yes])
1725 ])
1727 AS_IF([ test "x$msg_xattr" != "xyes"], [
1728 dnl failure. try libattr
1729 AC_CHECK_LIB(attr, getxattr,
1730 [AC_CHECK_HEADERS(attr/xattr.h,
1731 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1732 XATTR_LIBS="-lattr"
1733 msg_xattr=yes])
1734 ])
1735 ])
1737 AS_IF([ test "x$msg_xattr" = "xyes"], [
1738 AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1739 AC_TRY_COMPILE([
1740 #include <stdio.h>
1741 #ifdef HAVE_SYS_TYPES_H
1742 #include <sys/types.h>
1743 #endif
1744 #ifdef HAVE_SYS_XATTR_H
1745 #include <sys/xattr.h>
1746 #elif HAVE_ATTR_XATTR_H
1747 #include <attr/xattr.h>
1748 #endif
1749 ],
1750 [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1751 [
1752 AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1753 AC_MSG_RESULT([yes])
1754 ],
1755 [AC_MSG_RESULT([no])]
1756 )
1757 ])
1758 ])
1759 AC_SUBST(XATTR_LIBS)
1761 dnl ************************
1762 dnl *** check for libelf ***
1763 dnl ************************
1764 AC_ARG_ENABLE(libelf,
1765 AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1766 AS_IF([ test "x$enable_libelf" != "xno"],[
1767 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1768 AS_IF([ test $have_libelf = maybe ], [
1769 glib_save_LIBS=$LIBS
1770 AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1771 AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1772 AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1773 AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1774 LIBS=$glib_save_LIBS
1776 if test $have_libelf != no; then
1777 LIBELF_LIBS=-lelf
1778 have_libelf=yes
1779 fi
1780 ])
1781 ])
1783 if test x$have_libelf = xyes; then
1784 AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1785 fi
1787 dnl ************************
1788 dnl *** check for libmount ***
1789 dnl ************************
1791 dnl The fallback code doesn't really implement the same behaviors - e.g.
1792 dnl so on linux we want to require libmount unless specifically disabled
1793 dnl
1794 enable_libmount_default=${glib_os_linux:-no}
1795 AC_ARG_ENABLE(libmount,
1796 [AS_HELP_STRING([--enable-libmount],
1797 [build with libmount support [default for Linux]])],,
1798 [enable_libmount=$enable_libmount_default])
1799 AS_IF([ test "x$enable_libmount" = "xyes"],[
1800 PKG_CHECK_MODULES([LIBMOUNT], [mount >= 2.23], [have_libmount=yes], [have_libmount=no])
1801 if test $have_libmount = no ; then
1802 AC_MSG_ERROR([*** Could not find libmount])
1803 fi
1804 ])
1806 if test x$have_libmount = xyes; then
1807 AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available])
1808 fi
1809 AM_CONDITIONAL(HAVE_LIBMOUNT, [test x$have_libmount = xyes])
1811 dnl ****************************************
1812 dnl *** platform dependent source checks ***
1813 dnl ****************************************
1815 AC_MSG_CHECKING(for platform-dependent source)
1816 case "$host" in
1817 *-*-cygwin*|*-*-mingw*)
1818 PLATFORMDEP=gwin32.lo
1819 ;;
1820 *)
1821 PLATFORMDEP=
1822 ;;
1823 esac
1824 AC_MSG_RESULT($PLATFORMDEP)
1825 AC_SUBST(PLATFORMDEP)
1827 AC_MSG_CHECKING([whether to compile timeloop])
1828 case "$host" in
1829 *-*-cygwin*|*-*-mingw*|*-*-minix)
1830 enable_timeloop=no
1831 ;;
1832 *)
1833 enable_timeloop=yes
1834 ;;
1835 esac
1836 AC_MSG_RESULT($enable_timeloop)
1837 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1839 AC_MSG_CHECKING([if building for some Win32 platform])
1840 case "$host" in
1841 *-*-mingw*|*-*-cygwin*)
1842 platform_win32=yes
1843 ;;
1844 *)
1845 platform_win32=no
1846 ;;
1847 esac
1848 AC_MSG_RESULT($platform_win32)
1849 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1851 dnl ***********************
1852 dnl *** g_thread checks ***
1853 dnl ***********************
1855 AC_ARG_WITH(threads,
1856 [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1857 [specify a thread implementation to use])],
1858 [],
1859 [with_threads=yes])
1861 dnl error and warning message
1862 dnl *************************
1864 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1866 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1867 platform (normally it's "_REENTRANT"). I'll not use any flag on
1868 compilation now, but then your programs might not work.
1869 Please provide information on how it is done on your system."
1871 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1872 "
1874 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1875 provide information on your thread implementation."
1877 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1878 functions will not be MT-safe during their first call because
1879 there is no working 'getpwuid_r' on your system."
1881 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1882 because there is no 'localtime_r' on your system."
1884 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1885 linking threaded applications. As GLib cannot do that
1886 automatically, you will get an linkg error everytime you are
1887 not using the right compiler. In that case you have to relink
1888 with the right compiler. Ususally just '_r' is appended
1889 to the compiler name."
1891 dnl determination of thread implementation
1892 dnl ***************************************
1894 AC_MSG_CHECKING(for thread implementation)
1896 have_threads=no
1897 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1898 AS_IF([ test "x$have_threads" = xno], [
1899 AC_TRY_COMPILE([#include <pthread.h>],
1900 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1901 have_threads=posix)
1902 ])
1903 # Tru64Unix requires -pthread to find pthread.h. See #103020
1904 if test "x$have_threads" = xno; then
1905 glib_save_CPPFLAGS="$CPPFLAGS"
1906 CPPFLAGS="$CPPFLAGS -pthread"
1907 AC_TRY_COMPILE([#include <pthread.h>],
1908 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1909 have_threads=posix)
1910 CPPFLAGS="$glib_save_CPPFLAGS"
1911 fi
1912 ])
1913 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1914 case $host in
1915 *-*-mingw*)
1916 have_threads=win32
1917 ;;
1918 esac
1919 fi
1921 if test "x$have_threads" = xno; then
1922 AC_MSG_RESULT(none available)
1923 AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1924 else
1925 AC_MSG_RESULT($have_threads)
1926 fi
1929 dnl determination of G_THREAD_CFLAGS
1930 dnl ********************************
1932 G_THREAD_LIBS=
1933 G_THREAD_LIBS_EXTRA=
1934 G_THREAD_CFLAGS=
1936 dnl
1937 dnl Test program for basic POSIX threads functionality
1938 dnl
1939 m4_define([glib_thread_test],[
1940 #include <pthread.h>
1941 int check_me = 0;
1942 void* func(void* data) {check_me = 42; return &check_me;}
1943 int main()
1944 { pthread_t t;
1945 void *ret;
1946 pthread_create (&t, $1, func, 0);
1947 pthread_join (t, &ret);
1948 return (check_me != 42 || ret != &check_me);
1949 }])
1951 AS_IF([ test x"$have_threads" = xposix], [
1952 # First we test for posix, whether -pthread or -pthreads do the trick as
1953 # both CPPFLAG and LIBS.
1954 # One of them does for most gcc versions and some other platforms/compilers
1955 # too and could be considered as the canonical way to go.
1956 case $host in
1957 *-*-cygwin*|*-*-darwin*)
1958 # skip cygwin and darwin -pthread or -pthreads test
1959 ;;
1960 *-solaris*)
1961 # These compiler/linker flags work with both Sun Studio and gcc
1962 # Sun Studio expands -mt to -D_REENTRANT and -lthread
1963 # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1964 G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1965 G_THREAD_LIBS="-lpthread -lthread"
1966 ;;
1967 *)
1968 for flag in pthread pthreads mt; do
1969 glib_save_CFLAGS="$CFLAGS"
1970 CFLAGS="$CFLAGS -$flag"
1971 AC_TRY_RUN(glib_thread_test(0),
1972 glib_flag_works=yes,
1973 glib_flag_works=no,
1974 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1975 glib_flag_works=yes,
1976 glib_flag_works=no)])
1977 CFLAGS="$glib_save_CFLAGS"
1978 if test $glib_flag_works = yes ; then
1979 G_THREAD_CFLAGS=-$flag
1980 G_THREAD_LIBS=-$flag
1981 break;
1982 fi
1983 done
1984 ;;
1985 esac
1986 ])
1988 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
1990 # The canonical -pthread[s] does not work. Try something different.
1992 case $host in
1993 *-aix*)
1994 if test x"$GCC" = xyes; then
1995 # GCC 3.0 and above needs -pthread.
1996 # Should be coverd by the case above.
1997 # GCC 2.x and below needs -mthreads
1998 G_THREAD_CFLAGS="-mthreads"
1999 G_THREAD_LIBS=$G_THREAD_CFLAGS
2000 else
2001 # We are probably using the aix compiler. Normaly a
2002 # program would have to be compiled with the _r variant
2003 # of the corresponding compiler, but we as GLib cannot
2004 # do that: but the good news is that for compiling the
2005 # only difference is the added -D_THREAD_SAFE compile
2006 # option. This is according to the "C for AIX User's
2007 # Guide".
2008 G_THREAD_CFLAGS="-D_THREAD_SAFE"
2009 fi
2010 ;;
2011 *-sysv5uw7*) # UnixWare 7
2012 # We are not using gcc with -pthread. Catched above.
2013 G_THREAD_CFLAGS="-Kthread"
2014 G_THREAD_LIBS=$G_THREAD_CFLAGS
2015 ;;
2016 *-mingw*)
2017 # No flag needed when using MSVCRT.DLL
2018 G_THREAD_CFLAGS=""
2019 ;;
2020 *)
2021 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2022 ;;
2023 esac
2024 ])
2026 # if we are not finding the localtime_r function, then we probably are
2027 # not using the proper multithread flag
2029 glib_save_CPPFLAGS="$CPPFLAGS"
2030 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2032 # First we test, whether localtime_r is declared in time.h
2033 # directly. Then we test whether a macro localtime_r exists, in
2034 # which case localtime_r in the test program is replaced and thus
2035 # if we still find localtime_r in the output, it is not defined as
2036 # a macro.
2038 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2039 [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2040 localtime_r(a,b)],
2041 AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2043 CPPFLAGS="$glib_save_CPPFLAGS"
2045 AC_MSG_CHECKING(thread related cflags)
2046 AC_MSG_RESULT($G_THREAD_CFLAGS)
2047 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2049 dnl determination of G_THREAD_LIBS
2050 dnl ******************************
2052 AS_IF([test x$have_threads = xposix], [
2053 glib_save_CPPFLAGS="$CPPFLAGS"
2054 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2055 AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2056 case $host in
2057 *-aix*)
2058 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2059 # probably using the aix compiler.
2060 AC_MSG_WARN($AIX_COMPILE_INFO)
2061 ;;
2062 *)
2063 G_THREAD_LIBS=error
2064 glib_save_LIBS="$LIBS"
2065 for thread_lib in "" pthread pthread32 pthreads thread; do
2066 if test x"$thread_lib" = x; then
2067 add_thread_lib=""
2068 IN=""
2069 else
2070 add_thread_lib="-l$thread_lib"
2071 IN=" in -l$thread_lib"
2072 fi
2073 if test x"$have_threads" = xposix; then
2074 defattr=0
2075 else
2076 defattr=pthread_attr_default
2077 fi
2079 LIBS="$add_thread_lib $glib_save_LIBS"
2081 AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2082 AC_TRY_RUN(glib_thread_test($defattr),
2083 glib_result=yes,
2084 glib_result=no,
2085 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2086 glib_result=yes,
2087 glib_result=no)])
2088 AC_MSG_RESULT($glib_result)
2090 if test "$glib_result" = "yes" ; then
2091 G_THREAD_LIBS="$add_thread_lib"
2092 break
2093 fi
2094 done
2095 if test "x$G_THREAD_LIBS" = xerror; then
2096 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2097 fi
2098 LIBS="$glib_save_LIBS"
2099 ;;
2100 esac
2101 ])
2103 g_threads_impl="POSIX"
2104 AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2105 AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2106 CPPFLAGS="$glib_save_CPPFLAGS"
2107 ], [test x$have_threads = xwin32], [
2108 AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2109 g_threads_impl="WIN32"
2110 ], [
2111 AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2112 g_threads_impl="NONE"
2113 G_THREAD_LIBS=error
2114 ])
2115 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2116 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2117 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2119 if test "x$G_THREAD_LIBS" = xerror; then
2120 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2121 fi
2123 AC_MSG_CHECKING(thread related libraries)
2124 AC_MSG_RESULT($G_THREAD_LIBS)
2126 dnl check for mt safe function variants and some posix functions
2127 dnl ************************************************************
2129 glib_save_LIBS="$LIBS"
2130 # we are not doing the following for now, as this might require glib
2131 # to always be linked with the thread libs on some platforms.
2132 # LIBS="$LIBS $G_THREAD_LIBS"
2133 AC_CHECK_FUNCS(localtime_r gmtime_r getpwuid_r getgrgid_r)
2135 LIBS="$G_THREAD_LIBS $LIBS"
2136 AS_IF([ test x"$have_threads" = xposix], [
2137 glib_save_CPPFLAGS="$CPPFLAGS"
2138 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2139 # This is not AC_CHECK_FUNC to also work with function
2140 # name mangling in header files.
2141 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2142 AC_LINK_IFELSE(
2143 [AC_LANG_PROGRAM(
2144 [#include <pthread.h>],
2145 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2146 [AC_MSG_RESULT(yes)
2147 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2148 [Have function pthread_attr_setstacksize])],
2149 [AC_MSG_RESULT(no)])
2150 AC_MSG_CHECKING(for pthread_condattr_setclock)
2151 AC_LINK_IFELSE(
2152 [AC_LANG_PROGRAM(
2153 [#include <pthread.h>],
2154 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2155 [AC_MSG_RESULT(yes)
2156 AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2157 [Have function pthread_condattr_setclock])],
2158 [AC_MSG_RESULT(no)])
2159 AC_MSG_CHECKING(for pthread_cond_timedwait_relative_np)
2160 AC_LINK_IFELSE(
2161 [AC_LANG_PROGRAM(
2162 [#include <pthread.h>],
2163 [pthread_cond_timedwait_relative_np(NULL, NULL, NULL)])],
2164 [AC_MSG_RESULT(yes)
2165 AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP,1,
2166 [Have function pthread_cond_timedwait_relative_np])],
2167 [AC_MSG_RESULT(no)])
2168 dnl Sets thread names on OS X 10.6, iOS 3.2 (and higher)
2169 AC_MSG_CHECKING(for pthread_setname_np(const char*))
2170 AC_LINK_IFELSE(
2171 [AC_LANG_PROGRAM(
2172 [#include <pthread.h>],
2173 [pthread_setname_np("example")])],
2174 [AC_MSG_RESULT(yes)
2175 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
2176 [Have function pthread_setname_np(const char*)])],
2177 [AC_MSG_RESULT(no)])
2178 dnl Sets thread names on Solaris 11.3 & higher
2179 AC_MSG_CHECKING(for pthread_setname_np(pthread_t, const char*))
2180 AC_LINK_IFELSE(
2181 [AC_LANG_PROGRAM(
2182 [#include <pthread.h>],
2183 [pthread_setname_np(pthread_self(), "example")])],
2184 [AC_MSG_RESULT(yes)
2185 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITH_TID,1,
2186 [Have function pthread_setname_np(pthread_t, const char*)])],
2187 [AC_MSG_RESULT(no)])
2188 AC_MSG_CHECKING(for pthread_getname_np(pthread_t, name, len))
2189 AC_LINK_IFELSE(
2190 [AC_LANG_PROGRAM(
2191 [#include <pthread.h>],
2192 [[char name[16]; pthread_getname_np(pthread_self(), name, 16);]])],
2193 [AC_MSG_RESULT(yes)
2194 AC_DEFINE(HAVE_PTHREAD_GETNAME_NP,1,
2195 [Have function pthread_getname_np(pthread_t, name, len)])],
2196 [AC_MSG_RESULT(no)])
2197 CPPFLAGS="$glib_save_CPPFLAGS"
2198 ])
2200 LIBS="$glib_save_LIBS"
2202 # now spit out all the warnings.
2203 if test "$ac_cv_func_getpwuid_r" != "yes"; then
2204 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2205 fi
2206 if test "$ac_cv_func_localtime_r" != "yes"; then
2207 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2208 fi
2210 #
2211 # Hack to deal with:
2212 #
2213 # a) GCC < 3.3 for Linux doesn't include -lpthread when
2214 # building shared libraries with linux.
2215 # b) FreeBSD doesn't do this either.
2216 #
2217 case $host in
2218 *android*)
2219 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2220 ;;
2221 *-*-freebsd*|*-*-linux*)
2222 G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2223 ;;
2224 *)
2225 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2226 ;;
2227 esac
2229 AC_SUBST(G_THREAD_CFLAGS)
2230 AC_SUBST(G_THREAD_LIBS)
2231 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2232 AC_SUBST(G_THREAD_LIBS_EXTRA)
2234 AC_CHECK_FUNCS(clock_gettime, [], [
2235 AC_CHECK_LIB(rt, clock_gettime, [
2236 G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2237 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2238 ])
2239 ])
2242 dnl ************************
2243 dnl *** g_atomic_* tests ***
2244 dnl ************************
2246 dnl We need to decide at configure time if GLib will use real atomic
2247 dnl operations ("lock free") or emulated ones with a mutex. This is
2248 dnl because we must put this information in glibconfig.h so we know if
2249 dnl it is safe or not to inline using compiler intrinsics directly from
2250 dnl the header.
2251 dnl
2252 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2253 dnl user is interested in knowing if they can use the atomic ops across
2254 dnl processes.
2255 dnl
2256 dnl We can currently support the atomic ops natively when building GLib
2257 dnl with recent versions of GCC or MSVC. MSVC doesn't run ./configure,
2258 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2259 dnl we are using GCC (and not mingw*).
2260 dnl
2261 dnl Note that the atomic ops are only available with GCC on x86 when
2262 dnl using -march=i486 or higher. If we detect that the atomic ops are
2263 dnl not available but would be available given the right flags, we want
2264 dnl to abort and advise the user to fix their CFLAGS. It's better to do
2265 dnl that then to silently fall back on emulated atomic ops just because
2266 dnl the user had the wrong build environment.
2268 dnl We may add other compilers here in the future...
2270 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2271 case $host in
2272 *-*-mingw*)
2273 glib_cv_g_atomic_lock_free=yes
2274 ;;
2275 *)
2276 AC_TRY_LINK([],
2277 [volatile int atomic = 2;\
2278 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2279 [glib_cv_g_atomic_lock_free=yes],
2280 [glib_cv_g_atomic_lock_free=no])
2281 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2282 SAVE_CFLAGS="${CFLAGS}"
2283 CFLAGS="-march=i486"
2284 AC_TRY_LINK([],
2285 [volatile int atomic = 2;\
2286 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2287 [AC_MSG_ERROR([GLib must be built with -march=i486 or later.])],
2288 [])
2289 CFLAGS="${SAVE_CFLAGS}"
2290 fi
2291 ;;
2292 esac])
2295 case $host in
2296 *-*-mingw*)
2297 ;;
2298 *)
2299 # Some compilers support atomic operations but do not define
2300 # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2301 if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2302 AC_TRY_LINK([],
2303 [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2304 [],
2305 [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2306 fi
2307 ;;
2308 esac
2310 dnl We need a more robust approach here...
2311 case $host_cpu in
2312 i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2313 glib_memory_barrier_needed=no
2314 ;;
2315 sparc*|alpha*|powerpc*|ia64)
2316 glib_memory_barrier_needed=yes
2317 ;;
2318 *)
2319 glib_memory_barrier_needed=yes
2320 ;;
2321 esac
2323 dnl ************************
2324 dnl ** Check for futex(2) **
2325 dnl ************************
2326 AC_CACHE_CHECK(for futex(2) system call,
2327 glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2328 #include <linux/futex.h>
2329 #include <sys/syscall.h>
2330 #include <unistd.h>
2331 ],[
2332 syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2333 ])],glib_cv_futex=yes,glib_cv_futex=no))
2334 if test x"$glib_cv_futex" = xyes; then
2335 AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2336 fi
2338 AC_CACHE_CHECK(for eventfd(2) system call,
2339 glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2340 #include <sys/eventfd.h>
2341 #include <unistd.h>
2342 ],[
2343 eventfd (0, EFD_CLOEXEC);
2344 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2345 if test x"$glib_cv_eventfd" = x"yes"; then
2346 AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2347 fi
2348 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2350 dnl ****************************************
2351 dnl *** GLib POLL* compatibility defines ***
2352 dnl ****************************************
2354 glib_poll_includes=["
2355 #include <sys/types.h>
2356 #include <poll.h>
2357 "]
2359 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2360 test $ac_cv_func_poll = yes ], [
2361 glib_failed=false
2362 GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2363 GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2364 GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2365 GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2366 GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2367 GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2368 if $glib_failed ; then
2369 AC_MSG_ERROR([Could not determine values for POLL* constants])
2370 fi
2371 ], [
2372 glib_cv_value_POLLIN=1
2373 glib_cv_value_POLLOUT=4
2374 glib_cv_value_POLLPRI=2
2375 glib_cv_value_POLLERR=8
2376 glib_cv_value_POLLHUP=16
2377 glib_cv_value_POLLNVAL=32
2378 ])
2380 AC_MSG_CHECKING([for broken poll])
2381 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2382 #include <stdlib.h>
2383 #include <fcntl.h>
2384 #include <poll.h>
2385 int main(void) {
2386 struct pollfd fds[1];
2387 int fd;
2388 fd = open("/dev/null", 1);
2389 fds[0].fd = fd;
2390 fds[0].events = POLLIN;
2391 fds[0].revents = 0;
2392 if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2393 exit(1); /* Does not work for devices -- fail */
2394 }
2395 exit(0);
2396 }]])],
2397 [broken_poll=no],
2398 [broken_poll=yes
2399 AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2400 [broken_poll="no (cross compiling)"])
2401 AC_MSG_RESULT($broken_poll)
2403 dnl *********************
2404 dnl *** GRegex checks ***
2405 dnl *********************
2407 PCRE_REQUIRED_VERSION=8.13
2409 # Check if we should use the internal or the system-supplied pcre
2410 AC_ARG_WITH(pcre,
2411 [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2412 [whether to use system PCRE [default=system]])],
2413 [],
2414 [with_pcre=system])
2416 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2418 AS_IF([ test "x$with_pcre" = xsystem], [
2419 PKG_CHECK_MODULES(PCRE,
2420 libpcre >= $PCRE_REQUIRED_VERSION)
2421 AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2422 glib_save_CFLAGS="$CFLAGS"
2423 glib_save_LIBS="$LIBS"
2424 CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2425 AC_TRY_RUN([#include <pcre.h>
2426 int main () {
2427 int support;
2428 pcre_config (PCRE_CONFIG_UTF8, &support);
2429 if (!support)
2430 return 1;
2431 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2432 if (!support)
2433 return 1;
2434 return 0;
2435 }],
2436 glib_cv_pcre_has_unicode=yes,
2437 glib_cv_pcre_has_unicode=no,
2438 glib_cv_pcre_has_unicode=yes)
2439 CFLAGS="$glib_save_CFLAGS"
2440 LIBS="$glib_save_LIBS"
2441 ])
2442 if test "$glib_cv_pcre_has_unicode" = "no"; then
2443 AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2444 fi
2445 AC_SUBST(PCRE_CFLAGS)
2446 AC_SUBST(PCRE_LIBS)
2447 AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2448 PCRE_REQUIRES=libpcre
2449 AC_SUBST(PCRE_REQUIRES)
2450 ], [
2451 # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2452 AS_IF([ test x"$GCC" = xyes], [
2453 AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2454 save_CFLAGS="$CFLAGS"
2455 CFLAGS="$CFLAGS -Wno-pointer-sign"
2456 AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2457 AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2458 CFLAGS="$save_CFLAGS"
2459 ])
2460 ])
2461 AC_SUBST(PCRE_WARN_CFLAGS)
2463 dnl **********************
2464 dnl *** Win32 API libs ***
2465 dnl **********************
2467 case $host in
2468 *-*-cygwin*)
2469 G_LIBS_EXTRA="-luser32 -lkernel32"
2470 ;;
2471 *-*-mingw*)
2472 G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2473 ;;
2474 *)
2475 G_LIBS_EXTRA=""
2476 ;;
2477 esac
2478 AC_SUBST(G_LIBS_EXTRA)
2480 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2481 dnl since we need it for g_iconv()
2483 AC_MSG_CHECKING([for EILSEQ])
2484 AC_TRY_COMPILE([
2485 #include <errno.h>
2486 ],
2487 [
2488 int error = EILSEQ;
2489 ], have_eilseq=yes, have_eilseq=no);
2490 AC_MSG_RESULT($have_eilseq)
2492 dnl Add a conditional we can use when cross-compiling, so we avoid running
2493 dnl binaries
2494 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2496 dnl **************************
2497 dnl *** Checks for gtk-doc ***
2498 dnl **************************
2499 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2500 # it on it's own line.
2501 m4_ifdef([GTK_DOC_CHECK], [
2502 GTK_DOC_CHECK([1.20], [--flavour no-tmpl])
2503 ],[
2504 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2505 ])
2507 AC_ARG_ENABLE(man,
2508 [AS_HELP_STRING([--enable-man],
2509 [generate man pages [default=auto]])],,
2510 enable_man=maybe)
2512 AS_IF([test "$enable_man" != no], [
2513 AC_PATH_PROG([XSLTPROC], [xsltproc])
2514 AS_IF([test -z "$XSLTPROC"], [
2515 AS_IF([test "$enable_man" = yes], [
2516 AC_MSG_ERROR([xsltproc is required for --enable-man])
2517 ])
2518 enable_man=no
2519 ])
2520 ])
2522 AS_IF([ test "$enable_man" != no ], [
2523 dnl check for DocBook DTD in the local catalog
2524 JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2525 [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2526 AS_IF([test "$have_docbook_dtd" != yes], [
2527 AS_IF([test "$enable_man" = yes ], [
2528 AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2529 ])
2530 enable_man=no
2531 ])
2532 ])
2534 AS_IF([test "$enable_man" != no], [
2535 dnl check for DocBook XSL stylesheets in the local catalog
2536 JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2537 [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2538 AS_IF([ test "$have_docbook_style" != yes ], [
2539 AS_IF([ test "$enable_man" = yes ], [
2540 AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2541 ])
2542 enable_man=no
2543 ])
2544 ])
2546 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2548 AC_MSG_CHECKING([whether to generate man pages])
2549 AS_IF([ test "$enable_man" != no ], [
2550 AC_MSG_RESULT([yes])
2551 ], [
2552 AC_MSG_RESULT([no])
2553 ])
2555 dnl
2556 dnl Tracing
2557 dnl
2559 AC_ARG_ENABLE([dtrace],
2560 [AS_HELP_STRING([--enable-dtrace],
2561 [include tracing support for dtrace])])
2562 have_dtrace=no
2563 AC_MSG_CHECKING([whether to include dtrace tracing support])
2564 AS_IF([ test "x$enable_dtrace" != xno], [
2565 if test x$glib_have_carbon = xyes; then
2566 AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2567 else
2568 AC_MSG_RESULT([yes])
2569 AC_CHECK_PROGS(DTRACE, dtrace)
2570 if test -z "$DTRACE"; then
2571 if test "x$enable_dtrace" = xyes; then
2572 AC_MSG_ERROR([dtrace not found])
2573 fi
2574 else
2575 AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2576 [if test "x$enable_dtrace" = xyes; then
2577 AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2578 fi])
2579 fi
2580 fi
2581 ], [
2582 AC_MSG_RESULT([no])
2583 ])
2584 if test "x$have_dtrace" = xyes; then
2585 AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2586 fi
2587 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2589 AC_MSG_CHECKING([whether to include systemtap tracing support])
2590 AC_ARG_ENABLE([systemtap],
2591 [AS_HELP_STRING([--enable-systemtap],
2592 [include tracing support for systemtap])])
2593 have_systemtap=no
2594 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2595 have_systemtap=yes
2596 fi
2597 AC_MSG_RESULT(${have_systemtap})
2599 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2601 AC_ARG_WITH([tapset-install-dir],
2602 AS_HELP_STRING([--with-tapset-install-dir=DIR],
2603 [path where systemtap tapsets are installed [DATADIR/systemtap/tapset/HOST_CPU]]),
2604 [if test "x${withval}" = x; then
2605 ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset/${host_cpu}"
2606 else
2607 ABS_TAPSET_DIR="${withval}"
2608 fi],
2609 [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset/${host_cpu}"])
2610 AC_SUBST(ABS_TAPSET_DIR)
2612 dnl ************************************
2613 dnl *** Enable lcov coverage reports ***
2614 dnl ************************************
2616 AC_ARG_ENABLE(coverage,
2617 AS_HELP_STRING([--enable-coverage],
2618 [enable coverage testing with gcov]),
2619 [use_gcov=$enableval], [use_gcov=no])
2621 AS_IF([ test "x$use_gcov" = "xyes"], [
2622 dnl we need gcc:
2623 if test "$GCC" != "yes"; then
2624 AC_MSG_ERROR([GCC is required for --enable-coverage])
2625 fi
2627 dnl Check if ccache is being used
2628 AC_CHECK_PROG(SHTOOL, shtool, shtool)
2629 case `$SHTOOL path $CC` in
2630 *ccache*[)] gcc_ccache=yes;;
2631 *[)] gcc_ccache=no;;
2632 esac
2634 if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2635 AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2636 fi
2638 ltp_version_list="1.6 1.7 1.8 1.9 1.10 1.12"
2639 AC_CHECK_PROG(LTP, lcov, lcov)
2640 AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2642 AS_IF([ test "$LTP" ], [
2643 AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2644 glib_cv_ltp_version=invalid
2645 ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2646 for ltp_check_version in $ltp_version_list; do
2647 if test "$ltp_version" = "$ltp_check_version"; then
2648 glib_cv_ltp_version="$ltp_check_version (ok)"
2649 fi
2650 done
2651 ])
2652 ], [
2653 ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2654 AC_MSG_ERROR([$ltp_msg])
2655 ])
2657 case $glib_cv_ltp_version in
2658 ""|invalid[)]
2659 ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2660 AC_MSG_ERROR([$ltp_msg])
2661 LTP="exit 0;"
2662 ;;
2663 esac
2665 if test -z "$LTP_GENHTML"; then
2666 AC_MSG_ERROR([Could not find genhtml from the LTP package])
2667 fi
2669 dnl Remove all optimization flags from CFLAGS
2670 changequote({,})
2671 CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2672 changequote([,])
2674 dnl Add the special gcc flags
2675 CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2676 LDFLAGS="$LDFLAGS -lgcov"
2677 ])
2679 dnl *******************************
2680 dnl *** Disable strict aliasing ***
2681 dnl *******************************
2682 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=791622
2683 AS_IF([test "${GCC}" = "yes"],[
2684 CFLAGS="$CFLAGS -fno-strict-aliasing"
2685 ])
2687 dnl ******************************
2688 dnl *** output the whole stuff ***
2689 dnl ******************************
2691 dnl this section will only be run if config.status is invoked with no
2692 dnl arguments, or with "glib/glibconfig.h" as an argument.
2693 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2694 [
2695 outfile=glib/glibconfig.h-tmp
2696 cat > $outfile <<\_______EOF
2697 /* glibconfig.h
2698 *
2699 * This is a generated file. Please modify 'configure.ac'
2700 */
2702 #ifndef __GLIBCONFIG_H__
2703 #define __GLIBCONFIG_H__
2705 #include <glib/gmacros.h>
2707 _______EOF
2709 echo '#include <limits.h>' >> $outfile
2710 echo '#include <float.h>' >> $outfile
2711 if test x$glib_values_h = xyes; then
2712 echo '#include <values.h>' >> $outfile
2713 fi
2714 if test "$glib_header_alloca_h" = "yes"; then
2715 echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2716 fi
2717 if test x$glib_included_printf != xyes; then
2718 echo "
2719 /* Specifies that GLib's g_print*() functions wrap the
2720 * system printf functions. This is useful to know, for example,
2721 * when using glibc's register_printf_function().
2722 */" >> $outfile
2723 echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2724 fi
2726 cat >> $outfile <<_______EOF
2728 G_BEGIN_DECLS
2730 #define G_MINFLOAT FLT_MIN
2731 #define G_MAXFLOAT FLT_MAX
2732 #define G_MINDOUBLE DBL_MIN
2733 #define G_MAXDOUBLE DBL_MAX
2734 #define G_MINSHORT SHRT_MIN
2735 #define G_MAXSHORT SHRT_MAX
2736 #define G_MAXUSHORT USHRT_MAX
2737 #define G_MININT INT_MIN
2738 #define G_MAXINT INT_MAX
2739 #define G_MAXUINT UINT_MAX
2740 #define G_MINLONG LONG_MIN
2741 #define G_MAXLONG LONG_MAX
2742 #define G_MAXULONG ULONG_MAX
2744 _______EOF
2747 ### this should always be true in a modern C/C++ compiler
2748 ### and is statically asserted by glib-init.c
2749 cat >>$outfile <<_______EOF
2750 typedef signed char gint8;
2751 typedef unsigned char guint8;
2752 _______EOF
2755 if test -n "$gint16"; then
2756 cat >>$outfile <<_______EOF
2757 typedef signed $gint16 gint16;
2758 typedef unsigned $gint16 guint16;
2759 #define G_GINT16_MODIFIER $gint16_modifier
2760 #define G_GINT16_FORMAT $gint16_format
2761 #define G_GUINT16_FORMAT $guint16_format
2762 _______EOF
2763 fi
2766 if test -n "$gint32"; then
2767 cat >>$outfile <<_______EOF
2768 typedef signed $gint32 gint32;
2769 typedef unsigned $gint32 guint32;
2770 #define G_GINT32_MODIFIER $gint32_modifier
2771 #define G_GINT32_FORMAT $gint32_format
2772 #define G_GUINT32_FORMAT $guint32_format
2773 _______EOF
2774 fi
2776 cat >>$outfile <<_______EOF
2777 #define G_HAVE_GINT64 1 /* deprecated, always true */
2779 ${glib_extension}typedef signed $gint64 gint64;
2780 ${glib_extension}typedef unsigned $gint64 guint64;
2782 #define G_GINT64_CONSTANT(val) $gint64_constant
2783 #define G_GUINT64_CONSTANT(val) $guint64_constant
2784 _______EOF
2786 if test x$gint64_format != x ; then
2787 cat >>$outfile <<_______EOF
2788 #define G_GINT64_MODIFIER $gint64_modifier
2789 #define G_GINT64_FORMAT $gint64_format
2790 #define G_GUINT64_FORMAT $guint64_format
2791 _______EOF
2792 else
2793 cat >>$outfile <<_______EOF
2794 #undef G_GINT64_MODIFIER
2795 #undef G_GINT64_FORMAT
2796 #undef G_GUINT64_FORMAT
2797 _______EOF
2798 fi
2800 cat >>$outfile <<_______EOF
2802 #define GLIB_SIZEOF_VOID_P $glib_void_p
2803 #define GLIB_SIZEOF_LONG $glib_long
2804 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2805 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2807 _______EOF
2809 cat >>$outfile <<_______EOF
2810 typedef signed $glib_ssize_type_define gssize;
2811 typedef unsigned $glib_size_type_define gsize;
2812 #define G_GSIZE_MODIFIER $gsize_modifier
2813 #define G_GSSIZE_MODIFIER $gssize_modifier
2814 #define G_GSIZE_FORMAT $gsize_format
2815 #define G_GSSIZE_FORMAT $gssize_format
2817 #define G_MAXSIZE G_MAXU$glib_msize_type
2818 #define G_MINSSIZE G_MIN$glib_mssize_type
2819 #define G_MAXSSIZE G_MAX$glib_mssize_type
2821 typedef gint64 goffset;
2822 #define G_MINOFFSET G_MININT64
2823 #define G_MAXOFFSET G_MAXINT64
2825 #define G_GOFFSET_MODIFIER G_GINT64_MODIFIER
2826 #define G_GOFFSET_FORMAT G_GINT64_FORMAT
2827 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2829 #define G_POLLFD_FORMAT $g_pollfd_format
2831 _______EOF
2833 if test -z "$glib_unknown_void_p"; then
2834 cat >>$outfile <<_______EOF
2836 #define GPOINTER_TO_INT(p) ((gint) ${glib_gpi_cast} (p))
2837 #define GPOINTER_TO_UINT(p) ((guint) ${glib_gpui_cast} (p))
2839 #define GINT_TO_POINTER(i) ((gpointer) ${glib_gpi_cast} (i))
2840 #define GUINT_TO_POINTER(u) ((gpointer) ${glib_gpui_cast} (u))
2842 typedef signed $glib_intptr_type_define gintptr;
2843 typedef unsigned $glib_intptr_type_define guintptr;
2845 #define G_GINTPTR_MODIFIER $gintptr_modifier
2846 #define G_GINTPTR_FORMAT $gintptr_format
2847 #define G_GUINTPTR_FORMAT $guintptr_format
2848 _______EOF
2849 else
2850 echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2851 fi
2855 cat >>$outfile <<_______EOF
2856 #ifndef G_DISABLE_DEPRECATED
2857 #define g_ATEXIT(proc) (atexit (proc))
2858 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2859 #endif
2860 $glib_defines
2861 $glib_os
2862 $glib_static_compilation
2864 $glib_vacopy
2866 _______EOF
2868 if test x$g_have_iso_c_varargs = xyes ; then
2869 cat >>$outfile <<_______EOF
2870 #ifndef __cplusplus
2871 # define G_HAVE_ISO_VARARGS 1
2872 #endif
2873 _______EOF
2874 fi
2875 if test x$g_have_iso_cxx_varargs = xyes ; then
2876 cat >>$outfile <<_______EOF
2877 #ifdef __cplusplus
2878 # define G_HAVE_ISO_VARARGS 1
2879 #endif
2880 _______EOF
2881 fi
2882 if test x$g_have_gnuc_varargs = xyes ; then
2883 cat >>$outfile <<_______EOF
2885 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2886 * is passed ISO vararg support is turned off, and there is no work
2887 * around to turn it on, so we unconditionally turn it off.
2888 */
2889 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2890 # undef G_HAVE_ISO_VARARGS
2891 #endif
2893 #define G_HAVE_GNUC_VARARGS 1
2894 _______EOF
2895 fi
2897 case x$g_stack_grows in
2898 xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2899 *) echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2900 esac
2903 echo >>$outfile
2904 if test x$g_have_eilseq = xno; then
2905 cat >>$outfile <<_______EOF
2906 #ifndef EILSEQ
2907 /* On some pre-C99 systems, EILSEQ is not defined.
2908 * The correspondence between this and the corresponding definition
2909 * in libiconv is essential.
2910 */
2911 # define EILSEQ ENOENT
2912 #endif
2913 _______EOF
2915 fi
2917 if test x$g_have_gnuc_visibility = xyes; then
2918 cat >>$outfile <<_______EOF
2919 #define G_HAVE_GNUC_VISIBILITY 1
2920 _______EOF
2921 fi
2922 cat >>$outfile <<_______EOF
2923 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2924 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2925 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2926 #define G_GNUC_INTERNAL __hidden
2927 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2928 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2929 #else
2930 #define G_GNUC_INTERNAL
2931 #endif
2932 _______EOF
2934 echo >>$outfile
2935 cat >>$outfile <<_______EOF
2936 #define G_THREADS_ENABLED
2937 #define G_THREADS_IMPL_$g_threads_impl_def
2938 _______EOF
2940 if test x"$g_memory_barrier_needed" != xno; then
2941 echo >>$outfile
2942 echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2943 fi
2944 if test x"$g_atomic_lock_free" = xyes; then
2945 echo >>$outfile
2946 echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
2947 fi
2948 echo >>$outfile
2949 g_bit_sizes="16 32 64"
2950 for bits in $g_bit_sizes; do
2951 cat >>$outfile <<_______EOF
2952 #define GINT${bits}_TO_${g_bs_native}(val) ((gint${bits}) (val))
2953 #define GUINT${bits}_TO_${g_bs_native}(val) ((guint${bits}) (val))
2954 #define GINT${bits}_TO_${g_bs_alien}(val) ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2955 #define GUINT${bits}_TO_${g_bs_alien}(val) (GUINT${bits}_SWAP_LE_BE (val))
2956 _______EOF
2957 done
2959 cat >>$outfile <<_______EOF
2960 #define GLONG_TO_LE(val) ((glong) GINT${glongbits}_TO_LE (val))
2961 #define GULONG_TO_LE(val) ((gulong) GUINT${glongbits}_TO_LE (val))
2962 #define GLONG_TO_BE(val) ((glong) GINT${glongbits}_TO_BE (val))
2963 #define GULONG_TO_BE(val) ((gulong) GUINT${glongbits}_TO_BE (val))
2964 #define GINT_TO_LE(val) ((gint) GINT${gintbits}_TO_LE (val))
2965 #define GUINT_TO_LE(val) ((guint) GUINT${gintbits}_TO_LE (val))
2966 #define GINT_TO_BE(val) ((gint) GINT${gintbits}_TO_BE (val))
2967 #define GUINT_TO_BE(val) ((guint) GUINT${gintbits}_TO_BE (val))
2968 #define GSIZE_TO_LE(val) ((gsize) GUINT${gsizebits}_TO_LE (val))
2969 #define GSSIZE_TO_LE(val) ((gssize) GINT${gssizebits}_TO_LE (val))
2970 #define GSIZE_TO_BE(val) ((gsize) GUINT${gsizebits}_TO_BE (val))
2971 #define GSSIZE_TO_BE(val) ((gssize) GINT${gssizebits}_TO_BE (val))
2972 #define G_BYTE_ORDER $g_byte_order
2974 #define GLIB_SYSDEF_POLLIN =$g_pollin
2975 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2976 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2977 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2978 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2979 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2981 #define G_MODULE_SUFFIX "$g_module_suffix"
2983 typedef $g_pid_type GPid;
2984 #define G_PID_FORMAT $g_pid_format
2986 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
2987 #define GLIB_SYSDEF_AF_INET $g_af_inet
2988 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
2990 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
2991 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
2992 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
2994 #define G_DIR_SEPARATOR '$g_dir_separator'
2995 #define G_DIR_SEPARATOR_S "$g_dir_separator"
2996 #define G_SEARCHPATH_SEPARATOR '$g_searchpath_separator'
2997 #define G_SEARCHPATH_SEPARATOR_S "$g_searchpath_separator"
2999 G_END_DECLS
3001 #endif /* __GLIBCONFIG_H__ */
3002 _______EOF
3005 if cmp -s $outfile glib/glibconfig.h; then
3006 AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3007 rm -f $outfile
3008 else
3009 mv $outfile glib/glibconfig.h
3010 fi
3011 ],[
3013 # Note that if two cases are the same, case goes with the first one.
3014 # Note also that this is inside an AC_OUTPUT_COMMAND. We do not depend
3015 # on variable expansion in case labels. Look at the generated config.status
3016 # for a hint.
3018 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3019 glib_header_alloca_h="$ac_cv_working_alloca_h"
3020 else
3021 glib_header_alloca_h="$ac_cv_header_alloca_h"
3022 fi
3024 if test x$enable_included_printf = xyes ; then
3025 glib_included_printf=yes
3026 fi
3028 case 2 in
3029 $ac_cv_sizeof_short)
3030 gint16=short
3031 gint16_modifier='"h"'
3032 gint16_format='"hi"'
3033 guint16_format='"hu"'
3034 ;;
3035 $ac_cv_sizeof_int)
3036 gint16=int
3037 gint16_modifier='""'
3038 gint16_format='"i"'
3039 guint16_format='"u"'
3040 ;;
3041 esac
3042 case 4 in
3043 $ac_cv_sizeof_short)
3044 gint32=short
3045 gint32_modifier='"h"'
3046 gint32_format='"hi"'
3047 guint32_format='"hu"'
3048 ;;
3049 $ac_cv_sizeof_int)
3050 gint32=int
3051 gint32_modifier='""'
3052 gint32_format='"i"'
3053 guint32_format='"u"'
3054 ;;
3055 $ac_cv_sizeof_long)
3056 gint32=long
3057 gint32_modifier='"l"'
3058 gint32_format='"li"'
3059 guint32_format='"lu"'
3060 ;;
3061 esac
3062 case 8 in
3063 $ac_cv_sizeof_int)
3064 gint64=int
3065 gint64_modifier='""'
3066 gint64_format='"i"'
3067 guint64_format='"u"'
3068 glib_extension=
3069 gint64_constant='(val)'
3070 guint64_constant='(val)'
3071 ;;
3072 $ac_cv_sizeof_long)
3073 gint64=long
3074 gint64_modifier='"l"'
3075 gint64_format='"li"'
3076 guint64_format='"lu"'
3077 glib_extension=
3078 gint64_constant='(val##L)'
3079 guint64_constant='(val##UL)'
3080 ;;
3081 $ac_cv_sizeof_long_long)
3082 gint64='long long'
3083 if test -n "$glib_cv_long_long_format"; then
3084 gint64_modifier='"'$glib_cv_long_long_format'"'
3085 gint64_format='"'$glib_cv_long_long_format'i"'
3086 guint64_format='"'$glib_cv_long_long_format'u"'
3087 fi
3088 glib_extension='G_GNUC_EXTENSION '
3089 gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3090 guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3091 ;;
3092 $ac_cv_sizeof___int64)
3093 gint64='__int64'
3094 if test -n "$glib_cv_long_long_format"; then
3095 gint64_modifier='"'$glib_cv_long_long_format'"'
3096 gint64_format='"'$glib_cv_long_long_format'i"'
3097 guint64_format='"'$glib_cv_long_long_format'u"'
3098 fi
3099 glib_extension=
3100 gint64_constant='(val##i64)'
3101 guint64_constant='(val##ui64)'
3102 ;;
3103 esac
3104 glib_size_t=$ac_cv_sizeof_size_t
3105 glib_ssize_t=$ac_cv_sizeof_ssize_t
3106 glib_size_type_define="$glib_size_type"
3107 glib_ssize_type_define="$glib_ssize_type"
3108 glib_void_p=$ac_cv_sizeof_void_p
3109 glib_long=$ac_cv_sizeof_long
3111 case "$glib_size_type" in
3112 short)
3113 gsize_modifier='"h"'
3114 gsize_format='"hu"'
3115 glib_msize_type='SHRT'
3116 ;;
3117 int)
3118 gsize_modifier='""'
3119 gsize_format='"u"'
3120 glib_msize_type='INT'
3121 ;;
3122 long)
3123 gsize_modifier='"l"'
3124 gsize_format='"lu"'
3125 glib_msize_type='LONG'
3126 ;;
3127 "long long"|__int64)
3128 gsize_modifier='"I64"'
3129 gsize_format='"I64u"'
3130 glib_msize_type='INT64'
3131 ;;
3132 esac
3134 case "$glib_ssize_type" in
3135 short)
3136 gssize_modifier='"h"'
3137 gssize_format='"hi"'
3138 glib_mssize_type='SHRT'
3139 ;;
3140 int)
3141 gssize_modifier='""'
3142 gssize_format='"i"'
3143 glib_mssize_type='INT'
3144 ;;
3145 long)
3146 gssize_modifier='"l"'
3147 gssize_format='"li"'
3148 glib_mssize_type='LONG'
3149 ;;
3150 "long long"|__int64)
3151 gssize_modifier='"I64"'
3152 gssize_format='"I64i"'
3153 glib_mssize_type='INT64'
3154 ;;
3155 esac
3157 gintbits=`expr $ac_cv_sizeof_int \* 8`
3158 glongbits=`expr $ac_cv_sizeof_long \* 8`
3159 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3160 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3162 case $ac_cv_sizeof_void_p in
3163 $ac_cv_sizeof_int)
3164 glib_intptr_type_define=int
3165 gintptr_modifier='""'
3166 gintptr_format='"i"'
3167 guintptr_format='"u"'
3168 glib_gpi_cast='(gint)'
3169 glib_gpui_cast='(guint)'
3170 ;;
3171 $ac_cv_sizeof_long)
3172 glib_intptr_type_define=long
3173 gintptr_modifier='"l"'
3174 gintptr_format='"li"'
3175 guintptr_format='"lu"'
3176 glib_gpi_cast='(glong)'
3177 glib_gpui_cast='(gulong)'
3178 ;;
3179 $ac_cv_sizeof_long_long)
3180 glib_intptr_type_define='long long'
3181 gintptr_modifier='"I64"'
3182 gintptr_format='"I64i"'
3183 guintptr_format='"I64u"'
3184 glib_gpi_cast='(gint64)'
3185 glib_gpui_cast='(guint64)'
3186 ;;
3187 $ac_cv_sizeof___int64)
3188 glib_intptr_type_define=__int64
3189 gintptr_modifier='"I64"'
3190 gintptr_format='"I64i"'
3191 guintptr_format='"I64u"'
3192 glib_gpi_cast='(gint64)'
3193 glib_gpui_cast='(guint64)'
3194 ;;
3195 *)
3196 glib_unknown_void_p=yes
3197 ;;
3198 esac
3201 glib_defines="
3202 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3203 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3204 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3205 "
3207 case xyes in
3208 x$glib_cv_va_copy) glib_vacopy='#define G_VA_COPY va_copy' ;;
3209 x$glib_cv___va_copy) glib_vacopy='#define G_VA_COPY __va_copy' ;;
3210 *) glib_vacopy=''
3211 esac
3213 if test x$glib_cv_va_val_copy = xno; then
3214 glib_vacopy="\$glib_vacopy
3215 #define G_VA_COPY_AS_ARRAY 1"
3216 fi
3218 g_have_gnuc_varargs=$g_have_gnuc_varargs
3219 g_have_iso_c_varargs=$g_have_iso_c_varargs
3220 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3222 g_have_gnuc_visibility=$g_have_gnuc_visibility
3223 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3225 if test x$ac_cv_c_bigendian = xyes; then
3226 g_byte_order=G_BIG_ENDIAN
3227 g_bs_native=BE
3228 g_bs_alien=LE
3229 else
3230 g_byte_order=G_LITTLE_ENDIAN
3231 g_bs_native=LE
3232 g_bs_alien=BE
3233 fi
3235 g_pollin=$glib_cv_value_POLLIN
3236 g_pollout=$glib_cv_value_POLLOUT
3237 g_pollpri=$glib_cv_value_POLLPRI
3238 g_pollhup=$glib_cv_value_POLLHUP
3239 g_pollerr=$glib_cv_value_POLLERR
3240 g_pollnval=$glib_cv_value_POLLNVAL
3242 # If a family is not found on the system, define that family to
3243 # a negative value, picking a different one for each undefined
3244 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3245 # This is needed because glib-mkenums doesn't handle optional
3246 # values in enums, and thus we have to have all existing values
3247 # defined in the enum.
3248 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3249 g_af_unix=$glib_cv_value_AF_UNIX
3250 else
3251 g_af_unix=-1
3252 fi
3253 g_af_inet=$glib_cv_value_AF_INET
3254 g_af_inet6=$glib_cv_value_AF_INET6
3256 g_msg_peek=$glib_cv_value_MSG_PEEK
3257 g_msg_oob=$glib_cv_value_MSG_OOB
3258 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3260 g_stack_grows=$glib_cv_stack_grows
3262 g_have_eilseq=$have_eilseq
3264 g_threads_impl_def=$g_threads_impl
3266 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3267 g_memory_barrier_needed="$glib_memory_barrier_needed"
3268 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3270 g_module_suffix="$glib_gmodule_suffix"
3271 g_dir_separator="$glib_dir_separator"
3272 g_searchpath_separator="$glib_searchpath_separator"
3274 g_pid_type="$glib_pid_type"
3275 g_pid_format="\"$glib_pid_format\""
3276 g_pollfd_format="\"$glib_pollfd_format\""
3278 case $host in
3279 *-*-cygwin*)
3280 glib_os="#define G_OS_UNIX
3281 #define G_PLATFORM_WIN32
3282 #define G_WITH_CYGWIN"
3283 ;;
3284 *-*-mingw*)
3285 glib_os="#define G_OS_WIN32
3286 #define G_PLATFORM_WIN32"
3287 ;;
3288 *)
3289 glib_os="#define G_OS_UNIX"
3290 ;;
3291 esac
3292 glib_static_compilation=""
3293 if test x$glib_win32_static_compilation = xyes; then
3294 glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3295 #define GOBJECT_STATIC_COMPILATION 1"
3296 fi
3297 ])
3299 # Redo enough to get guint32 and guint64 for the alignment checks below
3300 case 4 in
3301 $ac_cv_sizeof_short)
3302 gint32=short
3303 ;;
3304 $ac_cv_sizeof_int)
3305 gint32=int
3306 ;;
3307 $ac_cv_sizeof_long)
3308 gint32=long
3309 ;;
3310 esac
3311 case 8 in
3312 $ac_cv_sizeof_int)
3313 gint64=int
3314 ;;
3315 $ac_cv_sizeof_long)
3316 gint64=long
3317 ;;
3318 $ac_cv_sizeof_long_long)
3319 gint64='long long'
3320 ;;
3321 $ac_cv_sizeof___int64)
3322 gint64='__int64'
3323 ;;
3324 esac
3326 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3327 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3328 typedef unsigned $gint32 guint32;])
3329 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3330 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3331 typedef unsigned $gint64 guint64;])
3332 AC_CHECK_TYPE([unsigned long])
3333 AC_CHECK_ALIGNOF([unsigned long])
3335 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3336 #
3337 # 1.2.14 required for dbus_message_set_serial
3338 PKG_CHECK_MODULES(DBUS1,
3339 dbus-1 >= 1.2.14,
3340 [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3341 have_dbus1=no)
3342 AC_SUBST(DBUS1_CFLAGS)
3343 AC_SUBST(DBUS1_LIBS)
3344 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3346 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3347 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3349 # Check whether MSVC toolset is explicitly set
3350 AM_CONDITIONAL(MSVC_BASE_NO_TOOLSET_SET, [test x$MSVC_BASE_TOOLSET = x])
3351 AM_CONDITIONAL(MSVC_NO_TOOLSET_SET, [test x$MSVC_TOOLSET = x])
3353 dnl
3354 dnl Check for -Bsymbolic-functions linker flag used to avoid
3355 dnl intra-library PLT jumps, if available.
3356 dnl
3358 AC_ARG_ENABLE(Bsymbolic,
3359 [AS_HELP_STRING([--disable-Bsymbolic],
3360 [avoid linking with -Bsymbolic])],,
3361 [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3362 AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3363 LDFLAGS=-Wl,-Bsymbolic-functions
3364 LIBS=
3365 AC_TRY_LINK([], [return 0],
3366 AC_MSG_RESULT(yes)
3367 enable_Bsymbolic=yes,
3368 AC_MSG_RESULT(no)
3369 enable_Bsymbolic=no)
3370 LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3372 if test "x${enable_Bsymbolic}" = "xyes"; then
3373 GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3374 fi
3376 dnl
3377 dnl Check for -z,nodelete linker flag: the type system assumes that
3378 dnl libgobject stays loaded for the lifetime of the process.
3379 dnl Since ld.bfd does not treat wrong -z options as fatal by default,
3380 dnl we also try to check for the --fatal-warnings linker flag if
3381 dnl auto-detecting.
3382 dnl
3384 SAVED_CFLAGS="${CFLAGS}" SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3385 AC_MSG_CHECKING([for --fatal-warnings linker flag])
3386 CFLAGS="${SAVED_CFLAGS} ${shared_flag:- -shared}"
3387 LDFLAGS=-Wl,--fatal-warnings
3388 LIBS=
3389 AC_TRY_LINK([], [return 0],
3390 AC_MSG_RESULT(yes)
3391 [ldflags_fatal=-Wl,--fatal-warnings],
3392 AC_MSG_RESULT(no)
3393 ldflags_fatal=)
3395 AC_MSG_CHECKING([for -z,nodelete linker flag])
3396 LDFLAGS="$ldflags_fatal -Wl,-z,nodelete"
3397 AC_TRY_LINK([], [return 0],
3398 AC_MSG_RESULT(yes)
3399 enable_znodelete=yes,
3400 AC_MSG_RESULT(no)
3401 enable_znodelete=no)
3402 CFLAGS="${SAVED_CFLAGS}" LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"
3404 if test "x${enable_znodelete}" = "xyes"; then
3405 GLIB_LINK_FLAGS="$GLIB_LINK_FLAGS -Wl,-z,nodelete"
3406 fi
3408 AC_SUBST(GLIB_LINK_FLAGS)
3410 dnl
3411 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3412 dnl visibility attributes for symbol export control
3413 dnl
3414 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3415 case "$host" in
3416 *-*-mingw*)
3417 dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3418 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3419 [defines how to decorate public symbols while building])
3420 CFLAGS="${CFLAGS} -fvisibility=hidden"
3421 ;;
3422 *)
3423 dnl on other compilers, check if we can do -fvisibility=hidden
3424 SAVED_CFLAGS="${CFLAGS}"
3425 CFLAGS="-fvisibility=hidden"
3426 AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3427 AC_TRY_COMPILE([], [return 0],
3428 AC_MSG_RESULT(yes)
3429 enable_fvisibility_hidden=yes,
3430 AC_MSG_RESULT(no)
3431 enable_fvisibility_hidden=no)
3432 CFLAGS="${SAVED_CFLAGS}"
3434 AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3435 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3436 [defines how to decorate public symbols while building])
3437 GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3438 ])
3439 ;;
3440 esac
3441 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3443 dnl Compiler flags; macro originates from systemd
3444 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3445 AC_ARG_ENABLE(compile-warnings,
3446 [AS_HELP_STRING([--disable-compile-warnings],
3447 [Don't use builtin compiler warnings])],,
3448 enable_compile_warnings=yes)
3449 AS_IF([test "x$enable_compile_warnings" != xno], [
3450 CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3451 -Wall -Wstrict-prototypes -Wduplicated-branches -Wmisleading-indentation \
3452 -Werror=declaration-after-statement \
3453 -Werror=missing-prototypes -Werror=implicit-function-declaration \
3454 -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3455 -Werror=format=2 -Werror=missing-include-dirs])
3456 ])
3457 AC_SUBST(GLIB_WARN_CFLAGS)
3459 #
3460 # Define variables corresponding to the correct include paths to use for
3461 # in-tree building.
3462 #
3464 # for config.h:
3465 config_h_INCLUDES='-I$(top_builddir)'
3466 AC_SUBST(config_h_INCLUDES)
3468 # glib:
3469 # config.h
3470 # $(top_builddir)/glib: for glibconfig.h
3471 # $(top_srcdir)/glib: for glib.h
3472 # $(top_srcdir): for everything
3473 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3474 AC_SUBST(glib_INCLUDES)
3476 # gobject:
3477 # same as glib
3478 gobject_INCLUDES='$(glib_INCLUDES)'
3479 AC_SUBST(gobject_INCLUDES)
3481 # gmodule:
3482 # glib includes
3483 # $(top_srcdir)/gmodule: for gmodule.h
3484 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3485 AC_SUBST(gmodule_INCLUDES)
3487 # gio:
3488 # same as gmodule
3489 gio_INCLUDES='$(gmodule_INCLUDES)'
3490 AC_SUBST(gio_INCLUDES)
3493 AC_CONFIG_FILES([
3494 glib-2.0.pc
3495 gmodule-2.0.pc
3496 gmodule-export-2.0.pc
3497 gmodule-no-export-2.0.pc
3498 gthread-2.0.pc
3499 gobject-2.0.pc
3500 gio-2.0.pc
3501 gio-unix-2.0.pc
3502 gio-windows-2.0.pc
3503 glib-zip
3504 glib-gettextize
3505 Makefile
3506 build/Makefile
3507 build/win32/Makefile
3508 build/win32/dirent/Makefile
3509 win32/Makefile
3510 win32/vs9/Makefile
3511 win32/vs9/glib-version-paths.vsprops
3512 win32/vs10/Makefile
3513 win32/vs10/glib-version-paths.props
3514 win32/vs11/Makefile
3515 win32/vs12/Makefile
3516 win32/vs14/Makefile
3517 win32/vs15/Makefile
3518 glib/Makefile
3519 glib/libcharset/Makefile
3520 glib/gnulib/Makefile
3521 glib/pcre/Makefile
3522 glib/update-pcre/Makefile
3523 glib/tests/Makefile
3524 gmodule/Makefile
3525 gmodule/gmoduleconf.h
3526 gobject/Makefile
3527 gobject/glib-genmarshal
3528 gobject/glib-mkenums
3529 gobject/tests/Makefile
3530 gthread/Makefile
3531 gio/Makefile
3532 gio/gdbus-2.0/codegen/Makefile
3533 gio/gdbus-2.0/codegen/config.py
3534 gio/gnetworking.h
3535 gio/xdgmime/Makefile
3536 gio/inotify/Makefile
3537 gio/kqueue/Makefile
3538 gio/fam/Makefile
3539 gio/win32/Makefile
3540 gio/tests/Makefile
3541 gio/tests/gdbus-object-manager-example/Makefile
3542 gio/tests/services/Makefile
3543 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3544 gio/tests/modules/Makefile
3545 po/Makefile.in
3546 docs/Makefile
3547 docs/reference/Makefile
3548 docs/reference/glib/Makefile
3549 docs/reference/glib/version.xml
3550 docs/reference/gobject/Makefile
3551 docs/reference/gobject/version.xml
3552 docs/reference/gio/Makefile
3553 docs/reference/gio/version.xml
3554 tests/Makefile
3555 tests/gobject/Makefile
3556 tests/refcount/Makefile
3557 m4macros/Makefile
3558 subprojects/Makefile
3559 ])
3561 # We need this command because the configure script will not preserve
3562 # the same attributes of the template files
3563 AC_CONFIG_COMMANDS([chmod-scripts],
3564 [chmod 0755 glib-zip
3565 chmod 0755 glib-gettextize
3566 chmod 0755 gobject/glib-genmarshal
3567 chmod 0755 gobject/glib-mkenums])
3569 # we want to invoke this macro solely so that the config.status script
3570 # and automake generated makefiles know about these generated files.
3571 # They are only needed to distcheck the package
3572 if false; then
3573 AC_CONFIG_FILES([
3574 INSTALL
3575 README
3576 config.h.win32
3577 glib/glibconfig.h.win32
3578 glib/glib.rc
3579 gmodule/gmodule.rc
3580 gobject/gobject.rc
3581 gthread/gthread.rc
3582 gio/gio.rc
3583 ])
3584 fi
3586 AC_OUTPUT