| blob | bc6000381bf8a1eba856170598c1d432ff9782dc |
1 # Process this file with autoconf to produce a configure script.
2 AC_PREREQ([2.62])
4 dnl ***********************************
5 dnl *** include special GLib macros ***
6 dnl ***********************************
8 m4_define(glib_configure_ac)
10 #
11 # The following version number definitions apply to GLib, GModule, GObject,
12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
13 # all treated with the same interface and binary age.
14 #
15 # Making releases:
16 # glib_micro_version += 1;
17 # glib_interface_age += 1;
18 # glib_binary_age += 1;
19 # if any functions have been added, set glib_interface_age to 0.
20 # if backwards compatibility has been broken,
21 # set glib_binary_age _and_ glib_interface_age to 0.
22 #
23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
25 # for that version - see gversion.h for further information.
26 #
27 # in easier to understand terms:
28 #
29 # <mclasen> on the stable branch, interface age == micro
30 # <mclasen> on the unstable (ie master), interface age = 0
32 m4_define([glib_major_version], [2])
33 m4_define([glib_minor_version], [57])
34 m4_define([glib_micro_version], [2])
35 m4_define([glib_interface_age], [0])
36 m4_define([glib_binary_age],
37 [m4_eval(100 * glib_minor_version + glib_micro_version)])
38 m4_define([glib_version],
39 [glib_major_version.glib_minor_version.glib_micro_version])
41 # libtool version related macros
42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
43 m4_define([glib_lt_current],
44 [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
45 m4_define([glib_lt_revision], [glib_interface_age])
46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
47 m4_define([glib_lt_current_minus_age],
48 [m4_eval(glib_lt_current - glib_lt_age)])
50 # if the minor version number is odd, then we want debugging. Otherwise
51 # we only want minimal debugging support.
52 m4_define([glib_debug_default],
53 [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
56 AC_INIT(glib, [glib_version],
57 [https://gitlab.gnome.org/GNOME/glib/issues/new])
59 AC_CONFIG_HEADERS([config.h])
60 AC_CONFIG_SRCDIR([glib/glib.h])
61 AC_CONFIG_MACRO_DIR([m4macros])
63 # Save this value here, since automake will set cflags later
64 cflags_set=${CFLAGS:+set}
66 AM_INIT_AUTOMAKE([1.13.3 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar subdir-objects])
67 AM_MAINTAINER_MODE([enable])
69 # Support silent build rules. Disable
70 # by either passing --disable-silent-rules to configure or passing V=1
71 # to make
72 AM_SILENT_RULES([yes])
74 GLIB_MAJOR_VERSION=glib_major_version
75 GLIB_MINOR_VERSION=glib_minor_version
76 GLIB_MICRO_VERSION=glib_micro_version
77 GLIB_INTERFACE_AGE=glib_interface_age
78 GLIB_BINARY_AGE=glib_binary_age
79 GLIB_VERSION=glib_version
81 AC_SUBST(GLIB_MAJOR_VERSION)
82 AC_SUBST(GLIB_MINOR_VERSION)
83 AC_SUBST(GLIB_MICRO_VERSION)
84 AC_SUBST(GLIB_VERSION)
85 AC_SUBST(GLIB_INTERFACE_AGE)
86 AC_SUBST(GLIB_BINARY_AGE)
88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
89 [Define to the GLIB major version])
90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
91 [Define to the GLIB minor version])
92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
93 [Define to the GLIB micro version])
94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
95 [Define to the GLIB interface age])
96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
97 [Define to the GLIB binary age])
99 # libtool versioning
100 LT_RELEASE=glib_lt_release
101 LT_CURRENT=glib_lt_current
102 LT_REVISION=glib_lt_revision
103 LT_AGE=glib_lt_age
104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
105 AC_SUBST(LT_RELEASE)
106 AC_SUBST(LT_CURRENT)
107 AC_SUBST(LT_REVISION)
108 AC_SUBST(LT_AGE)
109 AC_SUBST(LT_CURRENT_MINUS_AGE)
111 dnl Checks for programs.
112 AC_PROG_CC
113 AC_PROG_CPP
114 AC_USE_SYSTEM_EXTENSIONS
116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
118 AC_CANONICAL_HOST
120 dnl
122 AC_MSG_CHECKING([for Win32])
123 LIB_EXE_MACHINE_FLAG=X86
124 case "$host" in
125 *-*-mingw*)
126 glib_native_win32=yes
127 glib_pid_type='void *'
128 glib_pid_format='p'
129 glib_pollfd_format='%#x'
130 glib_dir_separator='\\\\'
131 glib_searchpath_separator=';'
132 glib_cv_stack_grows=no
133 # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
134 # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
135 # (Sorry, I don't know exactly what is the problem, but it is related to
136 # floating point formatting and decimal point vs. comma.)
137 # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
138 # rigorous enough to notice, though.
139 # So preset the autoconf cache variables.
140 ac_cv_func_vsnprintf_c99=no
141 ac_cv_func_snprintf_c99=no
142 case "$host" in
143 x86_64-*-*)
144 LIB_EXE_MACHINE_FLAG=X64
145 glib_pollfd_format='%#I64x'
146 ;;
147 esac
149 AC_DEFINE([_WIN32_WINNT], [0x0601], [Target the Windows 7 API])
150 ;;
151 *)
152 glib_native_win32=no
153 glib_pid_type=int
154 glib_pid_format='i'
155 glib_pollfd_format='%d'
156 glib_dir_separator='/'
157 glib_searchpath_separator=':'
158 ;;
159 esac
160 case $host in
161 *-*-linux*)
162 glib_os_linux=yes
163 ;;
164 esac
166 AC_MSG_RESULT([$glib_native_win32])
168 AC_MSG_CHECKING([for the Android])
169 case $host in
170 *android*)
171 glib_native_android="yes"
172 ;;
173 *)
174 glib_native_android="no"
175 ;;
176 esac
177 AC_MSG_RESULT([$glib_native_android])
179 AC_SUBST(LIB_EXE_MACHINE_FLAG)
181 glib_have_carbon=no
182 AC_MSG_CHECKING([for Mac OS X Carbon support])
183 AC_TRY_CPP([
184 #include <Carbon/Carbon.h>
185 #include <CoreServices/CoreServices.h>
186 ], glib_have_carbon=yes)
188 AC_MSG_RESULT([$glib_have_carbon])
190 glib_have_cocoa=no
191 AC_MSG_CHECKING([for Mac OS X Cocoa support])
192 AC_TRY_CPP([
193 #include <Cocoa/Cocoa.h>
194 #ifdef GNUSTEP_BASE_VERSION
195 #error "Detected GNUstep, not Cocoa"
196 #endif
197 ], glib_have_cocoa=yes)
199 AC_MSG_RESULT([$glib_have_cocoa])
201 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
202 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
203 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
204 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
205 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
206 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
208 AS_IF([test "$glib_native_win32" = "yes"], [
209 AC_CHECK_TOOL(WINDRES, windres, no)
210 if test "$WINDRES" = no; then
211 AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
212 fi
213 AC_CHECK_TOOL(NM, nm, no)
214 if test "$NM" = no; then
215 AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
216 fi
217 AC_CHECK_TOOL(RANLIB, ranlib, :)
218 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
219 AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
220 ])
221 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
223 AS_IF([test "x$glib_have_carbon" = "xyes"], [
224 AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
225 CARBON_LIBS="-Wl,-framework,Carbon"
226 LDFLAGS="$LDFLAGS $CARBON_LIBS"
227 ], [CARBON_LIBS=""])
229 AC_SUBST([CARBON_LIBS])
230 ac_cv_have_os_x_9_or_later="no"
231 AS_IF([test "x$glib_have_cocoa" = "xyes"], [
232 AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
233 COCOA_LIBS="-Wl,-framework,Foundation -Wl,-framework,AppKit"
234 LDFLAGS="$LDFLAGS $COCOA_LIBS"
235 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
236 #include <AvailabilityMacros.h>
237 #if MAC_OS_X_VERSION_MIN_REQUIRED < 1090
238 #error Compiling for minimum OS X version before 10.9
239 #endif
240 ]])],[ac_cv_have_os_x_9_or_later="yes"])
241 ], [COCOA_LIBS=""])
242 AM_CONDITIONAL([MAC_OS_X_9], [test "x$ac_cv_have_os_x_9_or_later" = xyes])
243 AC_SUBST([COCOA_LIBS])
245 dnl declare --enable-* args and collect ac_help strings
246 AC_ARG_ENABLE(debug,
247 AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
248 [turn on debugging @<:@default=glib_debug_default@:>@]),,
249 enable_debug=glib_debug_default)
251 GLIB_TESTS
253 dnl location to install runtime libraries, e.g. ../../lib to install
254 dnl to /lib if libdir is /usr/lib
255 AC_ARG_WITH(runtime-libdir,
256 [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
257 [install runtime libraries relative to libdir])],
258 [],
259 [with_runtime_libdir=""])
260 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
261 AC_SUBST(GLIB_RUNTIME_LIBDIR)
262 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
264 dnl Check for a working C++ compiler, but do not bail out, if none is found.
265 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
266 AC_LANG_SAVE
267 AC_LANG_CPLUSPLUS
268 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
269 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
270 AC_LANG_RESTORE
272 AM_PROG_CC_C_O
273 AC_PROG_INSTALL
275 AC_SYS_LARGEFILE
277 PKG_PROG_PKG_CONFIG(0.16)
279 if test "x$enable_debug" = "xyes"; then
280 if test "x$cflags_set" != "x" ; then
281 case " $CFLAGS " in
282 *[[\ \ ]]-g[[\ \ ]]*) ;;
283 *) CFLAGS="$CFLAGS -g" ;;
284 esac
285 fi
286 GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
287 else
288 GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
290 if test "x$enable_debug" = "xno"; then
291 GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
292 fi
293 fi
295 # Ensure MSVC-compatible struct packing convention is used when
296 # compiling for Win32 with gcc.
297 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
298 # gcc2 uses "-fnative-struct".
299 if test x"$glib_native_win32" = xyes; then
300 if test x"$GCC" = xyes; then
301 msnative_struct=''
302 AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
303 if test -z "$ac_cv_prog_CC"; then
304 our_gcc="$CC"
305 else
306 our_gcc="$ac_cv_prog_CC"
307 fi
308 case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
309 2.)
310 if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
311 msnative_struct='-fnative-struct'
312 fi
313 ;;
314 *)
315 if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
316 msnative_struct='-mms-bitfields'
317 fi
318 ;;
319 esac
320 if test x"$msnative_struct" = x ; then
321 AC_MSG_RESULT([no way])
322 AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
323 else
324 CFLAGS="$CFLAGS $msnative_struct"
325 AC_MSG_RESULT([${msnative_struct}])
326 fi
327 fi
328 fi
329 GLIB_EXTRA_CFLAGS="${msnative_struct}"
330 AC_SUBST(GLIB_EXTRA_CFLAGS)
332 AC_EXEEXT
334 AC_PROG_AWK
336 # option to specify python interpreter to use; this just sets $PYTHON, so that
337 # we will fallback to reading $PYTHON if --with-python is not given, and
338 # python.m4 will get the expected input
339 AC_ARG_WITH(python,
340 AS_HELP_STRING([--with-python=PATH],
341 [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
342 [PYTHON="$withval"], [])
343 if test x"$PYTHON" = xyes; then
344 AC_MSG_ERROR([--with-python option requires a path or program argument])
345 fi
346 AM_PATH_PYTHON(2.7,,PYTHON="python2.7")
349 dnl ***********************
350 dnl *** Tests for iconv ***
351 dnl ***********************
352 dnl
353 dnl We do this before the gettext checks, to avoid distortion
355 dnl On Windows we use a native implementation
357 AS_IF([ test x"$glib_native_win32" = xyes], [
358 with_libiconv=native
359 ], [
360 AC_ARG_WITH(libiconv,
361 [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
362 [use the libiconv library])],,
363 [with_libiconv=maybe])
365 found_iconv=no
366 case $with_libiconv in
367 maybe)
368 # Check in the C library first
369 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
370 # Check if we have GNU libiconv
371 if test $found_iconv = "no"; then
372 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
373 fi
374 # Check if we have a iconv in -liconv, possibly from vendor
375 if test $found_iconv = "no"; then
376 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
377 fi
378 ;;
379 no)
380 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
381 ;;
382 gnu|yes)
383 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
384 ;;
385 native)
386 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
387 ;;
388 esac
390 if test "x$found_iconv" = "xno" ; then
391 AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
392 fi
393 ])
395 dnl
396 dnl zlib support
397 dnl
398 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
399 AS_IF([test "x$found_zlib" = "xno"], [
400 AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
401 if test "x$found_zlib" = "xno" ; then
402 AC_MSG_ERROR([*** Working zlib library and headers not found ***])
403 fi
404 ZLIB_LIBS='-lz'
405 AC_SUBST(ZLIB_LIBS)
406 ])
408 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
409 AC_SUBST(LIBFFI_CFLAGS)
410 AC_SUBST(LIBFFI_LIBS)
412 dnl
413 dnl gettext support
414 dnl
416 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
417 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
418 GLIB_GNU_GETTEXT
420 if test "$gt_cv_have_gettext" != "yes" ; then
421 AC_MSG_ERROR([
422 *** You must have either have gettext support in your C library, or use the
423 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html)
424 ])
425 fi
427 LIBS="$INTLLIBS $LIBS"
429 GETTEXT_PACKAGE=glib20
430 AC_SUBST(GETTEXT_PACKAGE)
431 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
432 [Define the gettext package to be used])
434 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
436 dnl
437 dnl Now we are done with gettext checks, figure out ICONV_LIBS
438 dnl
440 AS_IF([test x"$glib_native_win32" != xyes], [
441 if test x$with_libiconv != xno ; then
442 case " $INTLLIBS " in
443 *[[\ \ ]]-liconv[[\ \ ]]*) ;;
444 *) ICONV_LIBS="-liconv" ;;
445 esac
446 fi
447 ])
448 AC_SUBST(ICONV_LIBS)
450 case $with_libiconv in
451 gnu)
452 AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
453 ;;
454 native)
455 AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
456 ;;
457 esac
459 dnl Initialize libtool
460 LT_PREREQ([2.2])
461 LT_INIT([disable-static win32-dll])
462 dnl when using libtool 2.x create libtool early, because it's used in configure
463 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
466 AS_IF([test "$glib_native_win32" = "yes"], [
467 if test x$enable_static = xyes -a x$enable_shared = xyes; then
468 AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
469 fi
470 if test x$enable_static = xyes; then
471 glib_win32_static_compilation=yes
472 GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
473 #define GOBJECT_STATIC_COMPILATION 1"
474 AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
475 fi
476 ])
477 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
479 # Checks for library functions.
480 AC_FUNC_ALLOCA
481 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
482 AC_CHECK_FUNCS(timegm gmtime_r posix_spawn)
483 AC_FUNC_STRERROR_R()
485 AC_CHECK_SIZEOF(char)
486 AC_CHECK_SIZEOF(short)
487 AC_CHECK_SIZEOF(long)
488 AC_CHECK_SIZEOF(int)
489 AC_CHECK_SIZEOF(void *)
490 AC_CHECK_SIZEOF(long long)
491 AC_CHECK_SIZEOF(__int64)
493 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
494 [AC_TRY_LINK([#include <signal.h>
495 #include <sys/types.h>
496 sig_atomic_t val = 42;],
497 [return val == 42 ? 0 : 1],
498 ac_cv_type_sig_atomic_t=yes,
499 ac_cv_type_sig_atomic_t=no)])
500 if test x$ac_cv_type_sig_atomic_t = xyes; then
501 AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
502 [Define if you have the 'sig_atomic_t' type.])
503 fi
505 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
506 :
507 else
508 AC_MSG_ERROR([
509 *** GLib requires a 64 bit type. You might want to consider
510 *** using the GNU C compiler.
511 ])
512 fi
514 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
515 # long long is a 64 bit integer.
516 AC_MSG_CHECKING(for format to printf and scanf a guint64)
517 AC_CACHE_VAL(glib_cv_long_long_format,[
518 for format in ll q I64; do
519 AC_TRY_RUN([#include <stdio.h>
520 int main()
521 {
522 long long b, a = -0x3AFAFAFAFAFAFAFALL;
523 char buffer[1000];
524 sprintf (buffer, "%${format}u", a);
525 sscanf (buffer, "%${format}u", &b);
526 exit (b!=a);
527 }
528 ],
529 [glib_cv_long_long_format=${format}
530 break],
531 [],[:])
532 done])
533 AS_IF([ test -n "$glib_cv_long_long_format"], [
534 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
535 ], [AC_MSG_RESULT(none)])
536 ],[ test x$ac_cv_sizeof___int64 = x8], [
537 # __int64 is a 64 bit integer.
538 AC_MSG_CHECKING(for format to printf and scanf a guint64)
539 # We know this is MSVCRT.DLL, and what the formats are
540 glib_cv_long_long_format=I64
541 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
542 ])
544 AC_C_CONST
546 dnl
547 dnl check in which direction the stack grows
548 dnl
549 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
550 AC_TRY_RUN([
551 volatile int *a = 0, *b = 0;
552 void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
553 int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
554 ],
555 glib_cv_stack_grows=yes
556 ,
557 glib_cv_stack_grows=no
558 ,)
559 ])
561 # check for flavours of varargs macros
562 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
563 AC_TRY_COMPILE([],[
564 int a(int p1, int p2, int p3);
565 #define call_a(...) a(1,__VA_ARGS__)
566 call_a(2,3);
567 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
568 AC_MSG_RESULT($g_have_iso_c_varargs)
570 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
571 AS_IF([test "$CXX" = ""], [
572 dnl No C++ compiler
573 g_have_iso_cxx_varargs=no
574 else
575 AC_LANG_CPLUSPLUS
576 AC_TRY_COMPILE([],[
577 int a(int p1, int p2, int p3);
578 #define call_a(...) a(1,__VA_ARGS__)
579 call_a(2,3);
580 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
581 AC_LANG_C
582 ])
583 AC_MSG_RESULT($g_have_iso_cxx_varargs)
585 AC_MSG_CHECKING(for GNUC varargs macros)
586 AC_TRY_COMPILE([],[
587 int a(int p1, int p2, int p3);
588 #define call_a(params...) a(1,params)
589 call_a(2,3);
590 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
591 AC_MSG_RESULT($g_have_gnuc_varargs)
593 # check for GNUC visibility support
594 AC_MSG_CHECKING(for GNUC visibility attribute)
595 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
596 void
597 __attribute__ ((visibility ("hidden")))
598 f_hidden (void)
599 {
600 }
601 void
602 __attribute__ ((visibility ("internal")))
603 f_internal (void)
604 {
605 }
606 void
607 __attribute__ ((visibility ("protected")))
608 f_protected (void)
609 {
610 }
611 void
612 __attribute__ ((visibility ("default")))
613 f_default (void)
614 {
615 }
616 int main (void)
617 {
618 f_hidden();
619 f_internal();
620 f_protected();
621 f_default();
622 return 0;
623 }
624 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
625 AC_MSG_RESULT($g_have_gnuc_visibility)
626 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
628 AC_MSG_CHECKING([whether using Sun Studio C compiler])
629 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
630 #else
631 # include "error: this is not Sun Studio."
632 #endif
633 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
634 AC_MSG_RESULT($g_have_sunstudio_visibility)
635 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
637 # check for bytesex stuff
638 AC_C_BIGENDIAN
639 if test x$ac_cv_c_bigendian = xuniversal ; then
640 AC_MSG_ERROR([Universal builds not supported: see https://bugzilla.gnome.org/show_bug.cgi?id=742548])
641 fi
644 # check for header files
645 AC_CHECK_HEADERS([sys/param.h sys/resource.h mach/mach_time.h])
646 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
647 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h sys/auxv.h])
648 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
649 AC_CHECK_HEADERS([linux/magic.h])
650 AC_CHECK_HEADERS([termios.h])
652 # Some versions of MSC lack these
653 AC_CHECK_HEADERS([dirent.h sys/time.h])
655 # We don't care about this, but we need to keep including it in
656 # glibconfig.h for backward compatibility
657 AC_CHECK_HEADERS([values.h])
659 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
660 [#if HAVE_SYS_PARAM_H
661 #include <sys/param.h>
662 #endif
663 ])
664 AC_CHECK_FUNCS(sysctlbyname)
666 AC_HEADER_MAJOR
667 AS_IF([test "$ac_cv_header_sys_types_h_makedev" = "yes"],
668 [AC_DEFINE([MAJOR_IN_TYPES], [1], [Define to 1 if `major', `minor', and `makedev' are declared in <sys/types.h>.])])
669 AC_CHECK_HEADERS([xlocale.h])
671 # check for structure fields
672 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec, struct stat.st_birthtime, struct stat.st_birthtimensec, struct stat.st_birthtim, struct stat.st_birthtim.tv_nsec])
673 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
674 #include <sys/stat.h>
675 #ifdef G_OS_UNIX
676 #include <unistd.h>
677 #endif
678 #ifdef HAVE_SYS_STATFS_H
679 #include <sys/statfs.h>
680 #endif
681 #ifdef HAVE_SYS_PARAM_H
682 #include <sys/param.h>
683 #endif
684 #ifdef HAVE_SYS_MOUNT_H
685 #include <sys/mount.h>
686 #endif])
687 # struct statvfs.f_basetype is available on Solaris but not for Linux.
688 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
689 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
690 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
692 AC_STRUCT_DIRENT_D_TYPE
694 # Checks for libcharset
695 AM_LANGINFO_CODESET
696 gl_GLIBC21
697 AC_ARG_WITH(charsetalias-dir,
698 AS_HELP_STRING([--with-charsetalias-dir=DIR], [directory for charset.alias file [LIBDIR]]),
699 [],
700 [with_charsetalias_dir='${libdir}'])
701 GLIB_CHARSETALIAS_DIR=$with_charsetalias_dir
702 AC_SUBST(GLIB_CHARSETALIAS_DIR)
704 # check additional type sizes
705 AC_CHECK_SIZEOF(size_t)
707 dnl Try to figure out whether gsize should be long or int
708 AC_MSG_CHECKING([for the appropriate definition for size_t])
710 case $ac_cv_sizeof_size_t in
711 $ac_cv_sizeof_short)
712 glib_size_type=short
713 ;;
714 $ac_cv_sizeof_int)
715 glib_size_type=int
716 ;;
717 $ac_cv_sizeof_long)
718 glib_size_type=long
719 ;;
720 $ac_cv_sizeof_long_long)
721 glib_size_type='long long'
722 ;;
723 $ac_cv_sizeof__int64)
724 glib_size_type='__int64'
725 ;;
726 *) AC_MSG_ERROR([No type matching size_t in size])
727 ;;
728 esac
730 dnl If int/long are the same size, we see which one produces
731 dnl warnings when used in the location as size_t. (This matters
732 dnl on AIX with xlc)
733 dnl
734 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
735 test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
736 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
737 #if defined(_AIX) && !defined(__GNUC__)
738 #pragma options langlvl=stdc89
739 #endif
740 #include <stddef.h>
741 int main ()
742 {
743 size_t s = 1;
744 unsigned int *size_int = &s;
745 return (int)*size_int;
746 }
747 ]])],glib_size_type=int,
748 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
749 #if defined(_AIX) && !defined(__GNUC__)
750 #pragma options langlvl=stdc89
751 #endif
752 #include <stddef.h>
753 int main ()
754 {
755 size_t s = 1;
756 unsigned long *size_long = &s;
757 return (int)*size_long;
758 }
759 ]])],glib_size_type=long)])
760 ])
762 AC_MSG_RESULT(unsigned $glib_size_type)
764 AC_CHECK_SIZEOF(ssize_t)
766 dnl Try to figure out whether gssize should be long or int
767 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
769 case $ac_cv_sizeof_ssize_t in
770 $ac_cv_sizeof_short)
771 glib_ssize_type=short
772 ;;
773 $ac_cv_sizeof_int)
774 glib_ssize_type=int
775 ;;
776 $ac_cv_sizeof_long)
777 glib_ssize_type=long
778 ;;
779 $ac_cv_sizeof_long_long)
780 glib_ssize_type='long long'
781 ;;
782 $ac_cv_sizeof__int64)
783 glib_ssize_type='__int64'
784 ;;
785 *) AC_MSG_ERROR([No type matching ssize_t in size])
786 ;;
787 esac
789 dnl If int/long are the same size, we see which one produces
790 dnl warnings when used in the location as ssize_t. (This matters
791 dnl on Android where ssize_t is long and size_t is unsigned int)
792 dnl
793 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
794 test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
795 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
796 #if defined(_AIX) && !defined(__GNUC__)
797 #pragma options langlvl=stdc89
798 #endif
799 #include <stddef.h>
800 #ifdef HAVE_INTTYPES_H
801 # include <inttypes.h>
802 #endif
803 #ifdef HAVE_STDINT_H
804 # include <stdint.h>
805 #endif
806 #include <sys/types.h>
807 int main ()
808 {
809 ssize_t s = 1;
810 int *size_int = &s;
811 return (int)*size_int;
812 }
813 ]])],glib_ssize_type=int,
814 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
815 #if defined(_AIX) && !defined(__GNUC__)
816 #pragma options langlvl=stdc89
817 #endif
818 #include <stddef.h>
819 #ifdef HAVE_INTTYPES_H
820 # include <inttypes.h>
821 #endif
822 #ifdef HAVE_STDINT_H
823 # include <stdint.h>
824 #endif
825 #include <sys/types.h>
826 int main ()
827 {
828 ssize_t s = 1;
829 long *size_long = &s;
830 return (int)*size_long;
831 }
832 ]])],glib_ssize_type=long)])
833 ])
835 AC_MSG_RESULT($glib_ssize_type)
837 # Check for some functions
838 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk mkostemp link)
839 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
840 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
841 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
842 AC_CHECK_FUNCS(splice)
843 AC_CHECK_FUNCS(prlimit)
845 # To avoid finding a compatibility unusable statfs, which typically
846 # successfully compiles, but warns to use the newer statvfs interface:
847 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
848 AS_IF([test $ac_cv_header_sys_statfs_h = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
850 AC_MSG_CHECKING([whether to use statfs or statvfs])
851 # Some systems have both statfs and statvfs, pick the most "native" for these
852 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
853 [
854 # on solaris and irix, statfs doesn't even have the f_bavail field
855 AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
856 [ac_cv_func_statfs=no],
857 # else, at least on linux, statfs is the actual syscall
858 [ac_cv_func_statvfs=no])
859 ])
861 AS_IF([test x$ac_cv_func_statfs = xyes],
862 [
863 AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
864 AC_MSG_RESULT([statfs])
865 ],
866 [test x$ac_cv_func_statvfs = xyes],
867 [
868 AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
869 AC_MSG_RESULT([statvfs])
870 ],
871 [ AC_MSG_RESULT([neither])])
873 AC_CHECK_HEADERS(crt_externs.h)
874 AC_CHECK_FUNCS(_NSGetEnviron)
876 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
878 # Internet address families
879 if test $glib_native_win32 = yes; then
880 glib_inet_includes=["
881 #include <winsock2.h>
882 "]
883 else
884 glib_inet_includes=["
885 #include <sys/types.h>
886 #include <sys/socket.h>
887 "]
888 fi
890 glib_failed=false
891 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
892 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
893 # winsock defines this even though it doesn't support it
894 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
895 if $glib_failed ; then
896 AC_MSG_ERROR([Could not determine values for AF_INET* constants])
897 fi
899 glib_failed=false
900 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
901 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
902 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
903 if $glib_failed ; then
904 AC_MSG_ERROR([Could not determine values for MSG_* constants])
905 fi
907 AC_CHECK_FUNCS(endservent if_nametoindex if_indextoname sendmmsg recvmmsg)
909 AC_MSG_CHECKING([for SIOCGIFADDR])
910 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
911 [[
912 #include <sys/ioctl.h>
913 #include <net/if.h>
914 ]],
915 [[
916 struct ifreq ifr;
917 ioctl(0, SIOCGIFADDR, &ifr);
918 ]])], [
919 AC_MSG_RESULT(yes)
920 AC_DEFINE(HAVE_SIOCGIFADDR, 1, [SIOCGIFADDR is available])
921 ], [
922 AC_MSG_RESULT(no)
923 ])
925 AC_MSG_CHECKING([if ip_mreq_source.imr_interface has s_addr member])
926 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
927 [[
928 #include <netinet/in.h>
929 ]],
930 [[
931 struct ip_mreq_source mc_req_src;
932 mc_req_src.imr_interface.s_addr = 0;
933 ]])], [
934 AC_MSG_RESULT(yes)
935 ], [
936 AC_MSG_RESULT(no)
937 AC_DEFINE(BROKEN_IP_MREQ_SOURCE_STRUCT, 1, [struct ip_mreq_source definition is broken on Android NDK <= r16])
938 ])
940 AS_IF([test $glib_native_win32 = yes], [
941 # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
942 # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
943 # they aren't present at run-time (on Windows 2000).
944 AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
945 AC_SUBST(WSPIAPI_INCLUDE)
946 ], [
947 # Android does not have C_IN in public headers, we define it wherever necessary
948 AS_IF([test $glib_native_android != yes], [
949 AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
950 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
951 #include <arpa/nameser.h>],
952 [int qclass = C_IN;])],
953 [AC_MSG_RESULT([no])],
954 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
955 #include <arpa/nameser.h>
956 #include <arpa/nameser_compat.h>],
957 [int qclass = C_IN;])],
958 [AC_MSG_RESULT([yes])
959 NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
960 [AC_MSG_ERROR([could not compile test program either way])])])])
961 AC_SUBST(NAMESER_COMPAT_INCLUDE)
963 # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
964 NETWORK_LIBS=""
965 AC_MSG_CHECKING([for res_query])
966 AC_TRY_LINK([#include <sys/types.h>
967 #include <netinet/in.h>
968 #include <arpa/nameser.h>
969 #include <resolv.h>
970 ],[
971 res_query("test", 0, 0, (void *)0, 0);
972 ],[AC_MSG_RESULT([yes])],
973 [save_libs="$LIBS"
974 LIBS="-lresolv $LIBS"
975 AC_TRY_LINK([#include <sys/types.h>
976 #include <netinet/in.h>
977 #include <arpa/nameser.h>
978 #include <resolv.h>
979 ],[
980 res_query("test", 0, 0, (void *)0, 0);
981 ],[AC_MSG_RESULT([in -lresolv])
982 NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
983 [LIBS="-lbind $save_libs"
984 AC_TRY_LINK([#include <resolv.h>],
985 [res_query("test", 0, 0, (void *)0, 0);],
986 [AC_MSG_RESULT([in -lbind])
987 NETWORK_LIBS="-lbind $NETWORK_LIBS"],
988 [AC_MSG_ERROR(not found)])])
989 LIBS="$save_libs"])
990 AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
991 [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
992 [AC_MSG_ERROR(Could not find socket())]))
993 save_libs="$LIBS"
994 LIBS="$LIBS $NETWORK_LIBS"
996 AC_MSG_CHECKING([for res_init])
997 AC_TRY_LINK([#include <sys/types.h>
998 #include <netinet/in.h>
999 #include <arpa/nameser.h>
1000 #include <resolv.h>
1001 ],[
1002 res_init();
1003 ],[AC_MSG_RESULT([yes])
1004 AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1005 ],[AC_MSG_RESULT([no])])
1007 AC_MSG_CHECKING([for res_nclose])
1008 AC_TRY_LINK([#include <sys/types.h>
1009 #include <netinet/in.h>
1010 #include <arpa/nameser.h>
1011 #include <resolv.h>
1012 ],[
1013 struct __res_state res;
1014 res_nclose(&res);
1015 ],[AC_MSG_RESULT([yes])
1016 AC_DEFINE(HAVE_RES_NCLOSE, 1, [Define to 1 if you have the 'res_nclose' function.])
1017 ],[AC_MSG_RESULT([no])])
1019 AC_MSG_CHECKING([for res_ndestroy])
1020 AC_TRY_LINK([#include <sys/types.h>
1021 #include <netinet/in.h>
1022 #include <arpa/nameser.h>
1023 #include <resolv.h>
1024 ],[
1025 struct __res_state res;
1026 res_ndestroy(&res);
1027 ],[AC_MSG_RESULT([yes])
1028 AC_DEFINE(HAVE_RES_NDESTROY, 1, [Define to 1 if you have the 'res_ndestroy' function.])
1029 ],[AC_MSG_RESULT([no])])
1031 AC_MSG_CHECKING([for res_ninit])
1032 AC_TRY_LINK([#include <sys/types.h>
1033 #include <netinet/in.h>
1034 #include <arpa/nameser.h>
1035 #include <resolv.h>
1036 ],[
1037 struct __res_state res;
1038 res_ninit(&res);
1039 ],[AC_MSG_RESULT([yes])
1040 AC_DEFINE(HAVE_RES_NINIT, 1, [Define to 1 if you have the 'res_ninit' function.])
1041 ],[AC_MSG_RESULT([no])])
1043 AC_MSG_CHECKING([for res_nquery])
1044 AC_TRY_LINK([#include <sys/types.h>
1045 #include <netinet/in.h>
1046 #include <arpa/nameser.h>
1047 #include <resolv.h>
1048 ],[
1049 struct __res_state res;
1050 res_nquery(&res, "test", 0, 0, (void *)0, 0);
1051 ],[AC_MSG_RESULT([yes])
1052 AC_DEFINE(HAVE_RES_NQUERY, 1, [Define to 1 if you have the 'res_nquery' function.])
1053 ],[AC_MSG_RESULT([no])])
1054 LIBS="$save_libs"
1055 ])
1056 AC_SUBST(NETWORK_LIBS)
1058 AC_CHECK_HEADER([linux/netlink.h],
1059 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1060 [#include <sys/socket.h>])
1061 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1063 AC_CHECK_TYPE([struct ip_mreqn], [
1064 AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1065 [#include <netinet/in.h>])
1067 case $host in
1068 *-*-solaris* )
1069 AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1070 AC_DEFINE(_XOPEN_SOURCE, 2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1071 AC_DEFINE(__EXTENSIONS__, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1072 ;;
1073 esac
1075 dnl
1076 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1077 dnl
1078 AS_IF([test "$ac_cv_func_statfs" = yes], [
1079 AC_MSG_CHECKING([number of arguments to statfs()])
1080 AC_TRY_COMPILE([#include <unistd.h>
1081 #ifdef HAVE_SYS_PARAM_H
1082 #include <sys/param.h>
1083 #endif
1084 #ifdef HAVE_SYS_VFS_H
1085 #include <sys/vfs.h>
1086 #endif
1087 #ifdef HAVE_SYS_MOUNT_H
1088 #include <sys/mount.h>
1089 #endif
1090 #ifdef HAVE_SYS_STATFS_H
1091 #include <sys/statfs.h>
1092 #endif], [struct statfs st;
1093 statfs("/", &st);],[
1094 AC_MSG_RESULT([2])
1095 AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1096 AC_TRY_COMPILE([#include <unistd.h>
1097 #ifdef HAVE_SYS_PARAM_H
1098 #include <sys/param.h>
1099 #endif
1100 #ifdef HAVE_SYS_VFS_H
1101 #include <sys/vfs.h>
1102 #endif
1103 #ifdef HAVE_SYS_MOUNT_H
1104 #include <sys/mount.h>
1105 #endif
1106 #ifdef HAVE_SYS_STATFS_H
1107 #include <sys/statfs.h>
1108 #endif], [struct statfs st;
1109 statfs("/", &st, sizeof (st), 0);],[
1110 AC_MSG_RESULT([4])
1111 AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1112 AC_MSG_RESULT(unknown)
1113 AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1114 ])
1116 dnl
1117 dnl open takes O_DIRECTORY as an option
1118 dnl
1119 AC_MSG_CHECKING([open() option O_DIRECTORY])
1120 AC_TRY_COMPILE([#include <fcntl.h>
1121 #include <sys/types.h>
1122 #include <sys/stat.h>],
1123 [open(0, O_DIRECTORY, 0);],[
1124 AC_MSG_RESULT([yes])
1125 AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1126 AC_MSG_RESULT([no])])
1128 #
1129 # Check whether to use an included printf
1130 #
1131 AC_FUNC_VSNPRINTF_C99
1132 AC_FUNC_PRINTF_UNIX98
1134 AC_ARG_ENABLE(included-printf,
1135 [AS_HELP_STRING([--enable-included-printf],
1136 [use included printf [default=auto]])],
1137 enable_included_printf="$enableval")
1139 need_included_printf=no
1140 if test "x$enable_included_printf" = "xyes" ; then
1141 need_included_printf=yes
1142 fi
1143 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1144 need_included_printf=yes
1145 fi
1146 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1147 need_included_printf=yes
1148 fi
1149 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1150 test -z "$glib_cv_long_long_format" ; then
1151 need_included_printf=yes
1152 fi
1154 if test "x$enable_included_printf" = "xno" &&
1155 test "x$need_included_printf" = "xyes" ; then
1156 AC_MSG_ERROR([
1157 *** Your C library's printf doesn't appear to have the features that
1158 *** GLib needs, but you specified --enable-included-printf=no.])
1159 fi
1161 enable_included_printf=$need_included_printf
1163 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1164 AS_IF([test "$enable_included_printf" != "yes"], [
1165 AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1166 ], [
1167 if test -z "$glib_cv_long_long_format" ; then
1168 glib_cv_long_long_format="ll"
1169 fi
1170 AC_DEFINE(HAVE_VASPRINTF,1)
1171 ])
1173 # Checks needed for gnulib vasnprintf
1174 bh_C_SIGNED
1175 jm_AC_TYPE_LONG_LONG
1176 gt_TYPE_LONGDOUBLE
1177 gt_TYPE_WCHAR_T
1178 gt_TYPE_WINT_T
1179 AC_TYPE_SIZE_T
1180 AC_CHECK_TYPES(ptrdiff_t)
1181 jm_AC_TYPE_INTMAX_T
1182 AC_CHECK_FUNCS([snprintf strnlen wcslen wcsnlen mbrtowc wcrtomb])
1183 AC_FUNC_SNPRINTF_C99
1185 dnl Check for nl_langinfo and CODESET
1186 AC_LANG_SAVE
1187 AC_LANG_C
1188 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1189 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1190 [char *codeset = nl_langinfo (CODESET);])],
1191 [glib_cv_langinfo_codeset=yes],
1192 [glib_cv_langinfo_codeset=no])])
1193 if test x$glib_cv_langinfo_codeset = xyes; then
1194 AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1195 fi
1197 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1198 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1199 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1200 [char *str;
1201 str = nl_langinfo (PM_STR);
1202 str = nl_langinfo (D_T_FMT);
1203 str = nl_langinfo (D_FMT);
1204 str = nl_langinfo (T_FMT);
1205 str = nl_langinfo (T_FMT_AMPM);
1206 str = nl_langinfo (MON_1);
1207 str = nl_langinfo (ABMON_12);
1208 str = nl_langinfo (DAY_1);
1209 str = nl_langinfo (ABDAY_7);])],
1210 [glib_cv_langinfo_time=yes],
1211 [glib_cv_langinfo_time=no])])
1212 if test x$glib_cv_langinfo_time = xyes; then
1213 AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1214 fi
1216 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1217 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1218 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1219 [char *str;
1220 str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1221 str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1222 str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1223 str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1224 str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1225 str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1226 str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1227 str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1228 str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1229 str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1230 [glib_cv_langinfo_outdigit=yes],
1231 [glib_cv_langinfo_outdigit=no])])
1232 if test x$glib_cv_langinfo_outdigit = xyes; then
1233 AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1234 fi
1236 dnl Check for nl_langinfo and ALTMON_n
1237 AC_CACHE_CHECK([for nl_langinfo (ALTMON_n)], glib_cv_langinfo_altmon,[
1238 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1239 [char *str;
1240 str = nl_langinfo (ALTMON_1);
1241 str = nl_langinfo (ALTMON_2);
1242 str = nl_langinfo (ALTMON_3);
1243 str = nl_langinfo (ALTMON_4);
1244 str = nl_langinfo (ALTMON_5);
1245 str = nl_langinfo (ALTMON_6);
1246 str = nl_langinfo (ALTMON_7);
1247 str = nl_langinfo (ALTMON_8);
1248 str = nl_langinfo (ALTMON_9);
1249 str = nl_langinfo (ALTMON_10);
1250 str = nl_langinfo (ALTMON_11);
1251 str = nl_langinfo (ALTMON_12);])],
1252 [glib_cv_langinfo_altmon=yes],
1253 [glib_cv_langinfo_altmon=no])])
1254 if test x$glib_cv_langinfo_altmon = xyes; then
1255 AC_DEFINE(HAVE_LANGINFO_ALTMON,1,[Have nl_langinfo (ALTMON_n)])
1256 fi
1258 dnl Check for nl_langinfo and _NL_ABALTMON_n
1259 AC_CACHE_CHECK([for nl_langinfo (_NL_ABALTMON_n)], glib_cv_langinfo_abaltmon,[
1260 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1261 [char *str;
1262 str = nl_langinfo (_NL_ABALTMON_1);
1263 str = nl_langinfo (_NL_ABALTMON_2);
1264 str = nl_langinfo (_NL_ABALTMON_3);
1265 str = nl_langinfo (_NL_ABALTMON_4);
1266 str = nl_langinfo (_NL_ABALTMON_5);
1267 str = nl_langinfo (_NL_ABALTMON_6);
1268 str = nl_langinfo (_NL_ABALTMON_7);
1269 str = nl_langinfo (_NL_ABALTMON_8);
1270 str = nl_langinfo (_NL_ABALTMON_9);
1271 str = nl_langinfo (_NL_ABALTMON_10);
1272 str = nl_langinfo (_NL_ABALTMON_11);
1273 str = nl_langinfo (_NL_ABALTMON_12);])],
1274 [glib_cv_langinfo_abaltmon=yes],
1275 [glib_cv_langinfo_abaltmon=no])])
1276 if test x$glib_cv_langinfo_abaltmon = xyes; then
1277 AC_DEFINE(HAVE_LANGINFO_ABALTMON,1,[Have nl_langinfo (_NL_ABALTMON_n)])
1278 fi
1279 AC_LANG_RESTORE
1282 dnl ****************************************
1283 dnl *** strlcpy/strlcat ***
1284 dnl ****************************************
1285 # Check for strlcpy
1286 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1287 AC_TRY_RUN([#include <stdlib.h>
1288 #include <string.h>
1289 int main() {
1290 char p[10];
1291 (void) strlcpy (p, "hi", 10);
1292 if (strlcat (p, "bye", 0) != 3)
1293 return 1;
1294 return 0;
1295 }], glib_cv_have_strlcpy=yes,
1296 glib_cv_have_strlcpy=no,
1297 glib_cv_have_strlcpy=no)])
1298 if test "$glib_cv_have_strlcpy" = "yes"; then
1299 AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1300 fi
1303 dnl **********************
1304 dnl *** va_copy checks ***
1305 dnl **********************
1306 dnl we currently check for all three va_copy possibilities, so we get
1307 dnl all results in config.log for bug reports.
1308 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1309 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1310 #include <stdlib.h>
1311 void f (int i, ...) {
1312 va_list args1, args2;
1313 va_start (args1, i);
1314 va_copy (args2, args1);
1315 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1316 exit (1);
1317 va_end (args1); va_end (args2);
1318 }
1319 int main() {
1320 f (0, 42);
1321 return 0;
1322 }]])],
1323 [glib_cv_va_copy=yes],
1324 [glib_cv_va_copy=no])
1325 ])
1326 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1327 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1328 #include <stdlib.h>
1329 void f (int i, ...) {
1330 va_list args1, args2;
1331 va_start (args1, i);
1332 __va_copy (args2, args1);
1333 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1334 exit (1);
1335 va_end (args1); va_end (args2);
1336 }
1337 int main() {
1338 f (0, 42);
1339 return 0;
1340 }]])],
1341 [glib_cv___va_copy=yes],
1342 [glib_cv___va_copy=no])
1343 ])
1345 if test "x$glib_cv_va_copy" = "xyes"; then
1346 g_va_copy_func=va_copy
1347 else if test "x$glib_cv___va_copy" = "xyes"; then
1348 g_va_copy_func=__va_copy
1349 fi
1350 fi
1352 if test -n "$g_va_copy_func"; then
1353 AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1354 fi
1356 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1357 AC_TRY_RUN([#include <stdarg.h>
1358 #include <stdlib.h>
1359 void f (int i, ...) {
1360 va_list args1, args2;
1361 va_start (args1, i);
1362 args2 = args1;
1363 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1364 exit (1);
1365 va_end (args1); va_end (args2);
1366 }
1367 int main() {
1368 f (0, 42);
1369 return 0;
1370 }],
1371 [glib_cv_va_val_copy=yes],
1372 [glib_cv_va_val_copy=no],
1373 [glib_cv_va_val_copy=yes])
1374 ])
1376 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1377 AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1378 ])
1380 dnl ***********************
1381 dnl *** g_module checks ***
1382 dnl ***********************
1383 G_MODULE_LIBS=
1384 G_MODULE_LIBS_EXTRA=
1385 G_MODULE_PLUGIN_LIBS=
1386 if test x"$glib_native_win32" = xyes; then
1387 dnl No use for this on Win32
1388 G_MODULE_LDFLAGS=
1389 else
1390 export SED
1391 eval G_MODULE_LDFLAGS=$export_dynamic_flag_spec
1392 fi
1393 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1394 G_MODULE_NEED_USCORE=0
1395 G_MODULE_BROKEN_RTLD_GLOBAL=0
1396 G_MODULE_HAVE_DLERROR=0
1397 dnl *** force native WIN32 shared lib loader
1398 if test -z "$G_MODULE_IMPL"; then
1399 case "$host" in
1400 *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1401 esac
1402 fi
1403 dnl *** force native AIX library loader
1404 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1405 if test -z "$G_MODULE_IMPL"; then
1406 case "$host" in
1407 *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1408 esac
1409 fi
1410 dnl *** dlopen() and dlsym() in system libraries
1411 AS_IF([ test -z "$G_MODULE_IMPL"], [
1412 AC_CHECK_FUNC(dlopen,
1413 [AC_CHECK_FUNC(dlsym,
1414 [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1415 [])
1416 ])
1417 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1418 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1419 AC_CHECK_FUNC(NSLinkModule,
1420 [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1421 G_MODULE_NEED_USCORE=1],
1422 [])
1423 ])
1424 dnl *** dlopen() and dlsym() in libdl
1425 AS_IF([ test -z "$G_MODULE_IMPL"], [
1426 AC_CHECK_LIB(dl, dlopen,
1427 [AC_CHECK_LIB(dl, dlsym,
1428 [G_MODULE_LIBS=-ldl
1429 G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1430 [])
1431 ])
1432 dnl *** additional checks for G_MODULE_IMPL_DL
1433 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1434 LIBS_orig="$LIBS"
1435 LDFLAGS_orig="$LDFLAGS"
1436 LIBS="$G_MODULE_LIBS $LIBS"
1437 LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1438 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1439 echo "void glib_plugin_test(void) { }" > plugin.c
1440 ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1441 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1442 ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1443 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1444 -shrext ".o" -avoid-version plugin.lo \
1445 -rpath /dont/care >/dev/null 2>&1
1446 AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1447 glib_cv_rtldglobal_broken,[
1448 AC_TRY_RUN([
1449 #include <dlfcn.h>
1450 #ifndef RTLD_GLOBAL
1451 # define RTLD_GLOBAL 0
1452 #endif
1453 #ifndef RTLD_LAZY
1454 # define RTLD_LAZY 0
1455 #endif
1456 int glib_plugin_test;
1457 int main () {
1458 void *handle, *global, *local;
1459 global = &glib_plugin_test;
1460 handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1461 if (!handle) return 0;
1462 local = dlsym (handle, "glib_plugin_test");
1463 return global == local;
1464 } ],
1465 [glib_cv_rtldglobal_broken=no],
1466 [glib_cv_rtldglobal_broken=yes],
1467 [glib_cv_rtldglobal_broken=no])
1468 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1469 rmdir ${objdir} 2>/dev/null
1470 ])
1471 if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1472 G_MODULE_BROKEN_RTLD_GLOBAL=1
1473 else
1474 G_MODULE_BROKEN_RTLD_GLOBAL=0
1475 fi
1476 dnl *** check whether we need preceeding underscores
1477 AC_CACHE_CHECK([for preceeding underscore in symbols],
1478 glib_cv_uscore,[
1479 AC_TRY_RUN([#include <dlfcn.h>
1480 int glib_underscore_test (void) { return 42; }
1481 int main() {
1482 void *f1 = (void*)0, *f2 = (void*)0, *handle;
1483 handle = dlopen ((void*)0, 0);
1484 if (handle) {
1485 f1 = dlsym (handle, "glib_underscore_test");
1486 f2 = dlsym (handle, "_glib_underscore_test");
1487 } return (!f2 || f1);
1488 }],
1489 [glib_cv_uscore=yes],
1490 [glib_cv_uscore=no],
1491 [])
1492 rm -f plugin.c plugin.$ac_objext plugin.lo
1493 ])
1494 GLIB_ASSERT_SET(glib_cv_uscore)
1495 if test "x$glib_cv_uscore" = "xyes"; then
1496 G_MODULE_NEED_USCORE=1
1497 else
1498 G_MODULE_NEED_USCORE=0
1499 fi
1501 AC_CHECK_DECL([RTLD_LAZY],
1502 [AC_DEFINE(HAVE_RTLD_LAZY, 1, [Define to 1 if RTLD_LAZY is available])],
1503 [], [[#include <dlfcn.h>]])
1504 AC_CHECK_DECL([RTLD_NOW],
1505 [AC_DEFINE(HAVE_RTLD_NOW, 1, [Define to 1 if RTLD_NOW is available])],
1506 [], [[#include <dlfcn.h>]])
1507 AC_CHECK_DECL([RTLD_GLOBAL],
1508 [AC_DEFINE(HAVE_RTLD_GLOBAL, 1, [Define to 1 if RTLD_GLOBAL is available])],
1509 [], [[#include <dlfcn.h>]])
1511 LDFLAGS="$LDFLAGS_orig"
1512 dnl *** check for having dlerror()
1513 AC_CHECK_FUNC(dlerror,
1514 [G_MODULE_HAVE_DLERROR=1],
1515 [G_MODULE_HAVE_DLERROR=0])
1516 LIBS="$LIBS_orig"
1517 ])
1518 dnl *** done, have we got an implementation?
1519 if test -z "$G_MODULE_IMPL"; then
1520 G_MODULE_IMPL=0
1521 G_MODULE_SUPPORTED=false
1522 else
1523 G_MODULE_SUPPORTED=true
1524 fi
1526 AC_MSG_CHECKING(for the suffix of module shared libraries)
1527 export SED
1528 module=yes eval std_shrext=$shrext_cmds
1529 # chop the initial dot
1530 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1531 AC_MSG_RESULT(.$glib_gmodule_suffix)
1532 # any reason it may fail?
1533 if test "x$glib_gmodule_suffix" = x; then
1534 AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1535 fi
1537 AC_SUBST(G_MODULE_SUPPORTED)
1538 AC_SUBST(G_MODULE_IMPL)
1539 AC_SUBST(G_MODULE_LIBS)
1540 AC_SUBST(G_MODULE_LIBS_EXTRA)
1541 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1542 AC_SUBST(G_MODULE_LDFLAGS)
1543 AC_SUBST(G_MODULE_HAVE_DLERROR)
1544 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1545 AC_SUBST(G_MODULE_NEED_USCORE)
1546 AC_SUBST(GLIB_DEBUG_FLAGS)
1548 dnl **********************
1549 dnl *** g_spawn checks ***
1550 dnl **********************
1552 AC_MSG_CHECKING(for gspawn implementation)
1553 case "$host" in
1554 *-*-mingw*)
1555 GSPAWN=gspawn-win32.lo
1556 ;;
1557 *)
1558 GSPAWN=gspawn.lo
1559 ;;
1560 esac
1561 AC_MSG_RESULT($GSPAWN)
1562 AC_SUBST(GSPAWN)
1564 dnl *************************
1565 dnl *** GIOChannel checks ***
1566 dnl *************************
1568 AC_MSG_CHECKING(for GIOChannel implementation)
1569 case "$host" in
1570 *-*-mingw*)
1571 GIO=giowin32.lo
1572 ;;
1573 *)
1574 GIO=giounix.lo
1575 ;;
1576 esac
1577 AC_MSG_RESULT($GIO)
1578 AC_SUBST(GIO)
1580 dnl *********************************
1581 dnl *** Directory for GIO modules ***
1582 dnl *********************************
1584 AC_ARG_WITH(gio-module-dir,
1585 [AS_HELP_STRING([--with-gio-module-dir=DIR],
1586 [load gio modules from this directory [LIBDIR/gio/modules]])],
1587 [],
1588 [with_gio_module_dir='${libdir}/gio/modules'])
1589 GIO_MODULE_DIR=$with_gio_module_dir
1590 AC_SUBST(GIO_MODULE_DIR)
1592 dnl **********************************
1593 dnl *** Check for libselinux (GIO) ***
1594 dnl **********************************
1595 AC_ARG_ENABLE(selinux,
1596 AS_HELP_STRING([--disable-selinux],
1597 [build without selinux support]))
1598 msg_selinux=no
1599 SELINUX_LIBS=
1600 AS_IF([ test "x$enable_selinux" != "xno"], [
1602 AC_CHECK_LIB(selinux, is_selinux_enabled,
1603 [AC_CHECK_HEADERS(selinux/selinux.h,
1604 [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1605 [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1606 SELINUX_LIBS="-lselinux"
1607 msg_selinux=yes])
1608 ])
1609 ])
1610 ])
1611 AC_SUBST(SELINUX_LIBS)
1613 dnl *****************************
1614 dnl ** Check for inotify (GIO) **
1615 dnl *****************************
1616 inotify_support=no
1617 AC_CHECK_HEADERS([sys/inotify.h],
1618 [
1619 AC_CHECK_FUNCS(inotify_init1, [inotify_support=yes], [inotify_support=no])
1620 ])
1622 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1624 dnl ****************************
1625 dnl ** Check for kqueue (GIO) **
1626 dnl ****************************
1627 kqueue_support=no
1628 AC_CHECK_HEADERS([sys/event.h],
1629 [
1630 AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1631 ])
1633 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1635 dnl ****************************
1636 dnl *** Checks for FAM (GIO) ***
1637 dnl ****************************
1639 should_disable_fam=no
1641 AC_ARG_ENABLE(fam,
1642 AS_HELP_STRING([--disable-fam],
1643 [don't use fam for file system monitoring]),
1644 [
1645 if test "x$enable_fam" = "xno"; then
1646 should_disable_fam=yes
1647 fi
1648 ]
1649 )
1650 fam_support=no
1651 FAM_LIBS=
1652 if test "x$should_disable_fam" = "xno"; then
1653 AC_CHECK_LIB(fam, FAMOpen,
1654 [AC_CHECK_HEADERS(fam.h,
1655 [AC_CHECK_LIB(fam, FAMNoExists,
1656 AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1657 FAM_LIBS="-lfam"]
1658 fam_support=yes,
1659 AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1660 AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1661 AC_SUBST(FAM_LIBS)
1662 fi
1663 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1666 dnl *****************************
1667 dnl *** Check for xattr (GIO) ***
1668 dnl *****************************
1669 AC_ARG_ENABLE(xattr,
1670 AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1671 msg_xattr=no
1672 XATTR_LIBS=
1673 AS_IF([ test "x$enable_xattr" != "xno"], [
1675 dnl either glibc or libattr can provide xattr support
1677 dnl for both of them, we check for getxattr being in
1678 dnl the library and a valid xattr header.
1680 dnl try glibc
1681 AC_CHECK_LIB(c, getxattr,
1682 [AC_CHECK_HEADERS(sys/xattr.h,
1683 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1684 msg_xattr=yes])
1685 ])
1687 AS_IF([ test "x$msg_xattr" != "xyes"], [
1688 dnl failure. try libattr
1689 AC_CHECK_LIB(attr, getxattr,
1690 [AC_CHECK_HEADERS(attr/xattr.h,
1691 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1692 XATTR_LIBS="-lattr"
1693 msg_xattr=yes])
1694 ])
1695 ])
1697 AS_IF([ test "x$msg_xattr" = "xyes"], [
1698 AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1699 AC_TRY_COMPILE([
1700 #include <stdio.h>
1701 #ifdef HAVE_SYS_TYPES_H
1702 #include <sys/types.h>
1703 #endif
1704 #ifdef HAVE_SYS_XATTR_H
1705 #include <sys/xattr.h>
1706 #elif HAVE_ATTR_XATTR_H
1707 #include <attr/xattr.h>
1708 #endif
1709 ],
1710 [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1711 [
1712 AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1713 AC_MSG_RESULT([yes])
1714 ],
1715 [AC_MSG_RESULT([no])]
1716 )
1717 ])
1718 ])
1719 AC_SUBST(XATTR_LIBS)
1721 dnl ************************
1722 dnl *** check for libelf ***
1723 dnl ************************
1724 AC_ARG_ENABLE(libelf,
1725 AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1726 AS_IF([ test "x$enable_libelf" != "xno"],[
1727 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1728 AS_IF([ test $have_libelf = maybe ], [
1729 glib_save_LIBS=$LIBS
1730 AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1731 AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1732 AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1733 AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1734 LIBS=$glib_save_LIBS
1736 if test $have_libelf != no; then
1737 LIBELF_LIBS=-lelf
1738 have_libelf=yes
1739 fi
1740 ])
1741 ])
1743 if test x$have_libelf = xyes; then
1744 AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1745 fi
1747 dnl ************************
1748 dnl *** check for libmount ***
1749 dnl ************************
1751 dnl The fallback code doesn't really implement the same behaviors - e.g.
1752 dnl so on linux we want to require libmount unless specifically disabled
1753 dnl
1754 enable_libmount_default=${glib_os_linux:-no}
1755 AC_ARG_ENABLE(libmount,
1756 [AS_HELP_STRING([--enable-libmount],
1757 [build with libmount support [default for Linux]])],,
1758 [enable_libmount=$enable_libmount_default])
1759 AS_IF([ test "x$enable_libmount" = "xyes"],[
1760 PKG_CHECK_MODULES([LIBMOUNT], [mount >= 2.23], [have_libmount=yes], [have_libmount=no])
1761 if test $have_libmount = no ; then
1762 AC_MSG_ERROR([*** Could not find libmount])
1763 fi
1764 ])
1766 if test x$have_libmount = xyes; then
1767 AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available])
1768 fi
1769 AM_CONDITIONAL(HAVE_LIBMOUNT, [test x$have_libmount = xyes])
1771 dnl ****************************************
1772 dnl *** platform dependent source checks ***
1773 dnl ****************************************
1775 AC_MSG_CHECKING(for platform-dependent source)
1776 case "$host" in
1777 *-*-cygwin*|*-*-mingw*)
1778 PLATFORMDEP=gwin32.lo
1779 ;;
1780 *)
1781 PLATFORMDEP=
1782 ;;
1783 esac
1784 AC_MSG_RESULT($PLATFORMDEP)
1785 AC_SUBST(PLATFORMDEP)
1787 AC_MSG_CHECKING([whether to compile timeloop])
1788 case "$host" in
1789 *-*-cygwin*|*-*-mingw*|*-*-minix)
1790 enable_timeloop=no
1791 ;;
1792 *)
1793 enable_timeloop=yes
1794 ;;
1795 esac
1796 AC_MSG_RESULT($enable_timeloop)
1797 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1799 AC_MSG_CHECKING([if building for some Win32 platform])
1800 case "$host" in
1801 *-*-mingw*|*-*-cygwin*)
1802 platform_win32=yes
1803 ;;
1804 *)
1805 platform_win32=no
1806 ;;
1807 esac
1808 AC_MSG_RESULT($platform_win32)
1809 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1811 dnl ***********************
1812 dnl *** g_thread checks ***
1813 dnl ***********************
1815 AC_ARG_WITH(threads,
1816 [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1817 [specify a thread implementation to use])],
1818 [],
1819 [with_threads=yes])
1821 dnl error and warning message
1822 dnl *************************
1824 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1826 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1827 platform (normally it's "_REENTRANT"). I'll not use any flag on
1828 compilation now, but then your programs might not work.
1829 Please provide information on how it is done on your system."
1831 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1832 "
1834 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1835 provide information on your thread implementation."
1837 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1838 functions will not be MT-safe during their first call because
1839 there is no working 'getpwuid_r' on your system."
1841 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1842 because there is no 'localtime_r' on your system."
1844 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1845 linking threaded applications. As GLib cannot do that
1846 automatically, you will get an linkg error everytime you are
1847 not using the right compiler. In that case you have to relink
1848 with the right compiler. Ususally just '_r' is appended
1849 to the compiler name."
1851 dnl determination of thread implementation
1852 dnl ***************************************
1854 AC_MSG_CHECKING(for thread implementation)
1856 have_threads=no
1857 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1858 AS_IF([ test "x$have_threads" = xno], [
1859 AC_TRY_COMPILE([#include <pthread.h>],
1860 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1861 have_threads=posix)
1862 ])
1863 # Tru64Unix requires -pthread to find pthread.h. See #103020
1864 if test "x$have_threads" = xno; then
1865 glib_save_CPPFLAGS="$CPPFLAGS"
1866 CPPFLAGS="$CPPFLAGS -pthread"
1867 AC_TRY_COMPILE([#include <pthread.h>],
1868 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1869 have_threads=posix)
1870 CPPFLAGS="$glib_save_CPPFLAGS"
1871 fi
1872 ])
1873 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1874 case $host in
1875 *-*-mingw*)
1876 have_threads=win32
1877 ;;
1878 esac
1879 fi
1881 if test "x$have_threads" = xno; then
1882 AC_MSG_RESULT(none available)
1883 AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1884 else
1885 AC_MSG_RESULT($have_threads)
1886 fi
1889 dnl determination of G_THREAD_CFLAGS
1890 dnl ********************************
1892 G_THREAD_LIBS=
1893 G_THREAD_LIBS_EXTRA=
1894 G_THREAD_CFLAGS=
1896 dnl
1897 dnl Test program for basic POSIX threads functionality
1898 dnl
1899 m4_define([glib_thread_test],[
1900 #include <pthread.h>
1901 int check_me = 0;
1902 void* func(void* data) {check_me = 42; return &check_me;}
1903 int main()
1904 { pthread_t t;
1905 void *ret;
1906 pthread_create (&t, $1, func, 0);
1907 pthread_join (t, &ret);
1908 return (check_me != 42 || ret != &check_me);
1909 }])
1911 AS_IF([ test x"$have_threads" = xposix], [
1912 # First we test for posix, whether -pthread or -pthreads do the trick as
1913 # both CPPFLAG and LIBS.
1914 # One of them does for most gcc versions and some other platforms/compilers
1915 # too and could be considered as the canonical way to go.
1916 case $host in
1917 *-*-cygwin*|*-*-darwin*)
1918 # skip cygwin and darwin -pthread or -pthreads test
1919 ;;
1920 *-solaris*)
1921 # These compiler/linker flags work with both Sun Studio and gcc
1922 # Sun Studio expands -mt to -D_REENTRANT and -lthread
1923 # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1924 G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1925 G_THREAD_LIBS="-lpthread -lthread"
1926 ;;
1927 *)
1928 for flag in pthread pthreads mt; do
1929 glib_save_CFLAGS="$CFLAGS"
1930 CFLAGS="$CFLAGS -$flag"
1931 AC_TRY_RUN(glib_thread_test(0),
1932 glib_flag_works=yes,
1933 glib_flag_works=no,
1934 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1935 glib_flag_works=yes,
1936 glib_flag_works=no)])
1937 CFLAGS="$glib_save_CFLAGS"
1938 if test $glib_flag_works = yes ; then
1939 G_THREAD_CFLAGS=-$flag
1940 G_THREAD_LIBS=-$flag
1941 break;
1942 fi
1943 done
1944 ;;
1945 esac
1946 ])
1948 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
1950 # The canonical -pthread[s] does not work. Try something different.
1952 case $host in
1953 *-aix*)
1954 if test x"$GCC" = xyes; then
1955 # GCC 3.0 and above needs -pthread.
1956 # Should be coverd by the case above.
1957 # GCC 2.x and below needs -mthreads
1958 G_THREAD_CFLAGS="-mthreads"
1959 G_THREAD_LIBS=$G_THREAD_CFLAGS
1960 else
1961 # We are probably using the aix compiler. Normaly a
1962 # program would have to be compiled with the _r variant
1963 # of the corresponding compiler, but we as GLib cannot
1964 # do that: but the good news is that for compiling the
1965 # only difference is the added -D_THREAD_SAFE compile
1966 # option. This is according to the "C for AIX User's
1967 # Guide".
1968 G_THREAD_CFLAGS="-D_THREAD_SAFE"
1969 fi
1970 ;;
1971 *-sysv5uw7*) # UnixWare 7
1972 # We are not using gcc with -pthread. Catched above.
1973 G_THREAD_CFLAGS="-Kthread"
1974 G_THREAD_LIBS=$G_THREAD_CFLAGS
1975 ;;
1976 *-mingw*)
1977 # No flag needed when using MSVCRT.DLL
1978 G_THREAD_CFLAGS=""
1979 ;;
1980 *)
1981 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1982 ;;
1983 esac
1984 ])
1986 # if we are not finding the localtime_r function, then we probably are
1987 # not using the proper multithread flag
1989 glib_save_CPPFLAGS="$CPPFLAGS"
1990 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1992 # First we test, whether localtime_r is declared in time.h
1993 # directly. Then we test whether a macro localtime_r exists, in
1994 # which case localtime_r in the test program is replaced and thus
1995 # if we still find localtime_r in the output, it is not defined as
1996 # a macro.
1998 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1999 [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2000 localtime_r(a,b)],
2001 AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2003 CPPFLAGS="$glib_save_CPPFLAGS"
2005 AC_MSG_CHECKING(thread related cflags)
2006 AC_MSG_RESULT($G_THREAD_CFLAGS)
2007 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2009 dnl determination of G_THREAD_LIBS
2010 dnl ******************************
2012 AS_IF([test x$have_threads = xposix], [
2013 glib_save_CPPFLAGS="$CPPFLAGS"
2014 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2015 AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2016 case $host in
2017 *-aix*)
2018 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2019 # probably using the aix compiler.
2020 AC_MSG_WARN($AIX_COMPILE_INFO)
2021 ;;
2022 *)
2023 G_THREAD_LIBS=error
2024 glib_save_LIBS="$LIBS"
2025 for thread_lib in "" pthread pthread32 pthreads thread; do
2026 if test x"$thread_lib" = x; then
2027 add_thread_lib=""
2028 IN=""
2029 else
2030 add_thread_lib="-l$thread_lib"
2031 IN=" in -l$thread_lib"
2032 fi
2033 if test x"$have_threads" = xposix; then
2034 defattr=0
2035 else
2036 defattr=pthread_attr_default
2037 fi
2039 LIBS="$add_thread_lib $glib_save_LIBS"
2041 AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2042 AC_TRY_RUN(glib_thread_test($defattr),
2043 glib_result=yes,
2044 glib_result=no,
2045 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2046 glib_result=yes,
2047 glib_result=no)])
2048 AC_MSG_RESULT($glib_result)
2050 if test "$glib_result" = "yes" ; then
2051 G_THREAD_LIBS="$add_thread_lib"
2052 break
2053 fi
2054 done
2055 if test "x$G_THREAD_LIBS" = xerror; then
2056 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2057 fi
2058 LIBS="$glib_save_LIBS"
2059 ;;
2060 esac
2061 ])
2063 g_threads_impl="POSIX"
2064 AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2065 AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2066 CPPFLAGS="$glib_save_CPPFLAGS"
2067 ], [test x$have_threads = xwin32], [
2068 AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2069 g_threads_impl="WIN32"
2070 ], [
2071 g_threads_impl="NONE"
2072 G_THREAD_LIBS=error
2073 ])
2074 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2075 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2077 if test "x$G_THREAD_LIBS" = xerror; then
2078 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2079 fi
2081 AC_MSG_CHECKING(thread related libraries)
2082 AC_MSG_RESULT($G_THREAD_LIBS)
2084 dnl check for mt safe function variants and some posix functions
2085 dnl ************************************************************
2087 glib_save_LIBS="$LIBS"
2088 # we are not doing the following for now, as this might require glib
2089 # to always be linked with the thread libs on some platforms.
2090 # LIBS="$LIBS $G_THREAD_LIBS"
2091 AC_CHECK_FUNCS(localtime_r gmtime_r getpwuid_r getgrgid_r)
2093 LIBS="$G_THREAD_LIBS $LIBS"
2094 AS_IF([ test x"$have_threads" = xposix], [
2095 glib_save_CPPFLAGS="$CPPFLAGS"
2096 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2097 # This is not AC_CHECK_FUNC to also work with function
2098 # name mangling in header files.
2099 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2100 AC_LINK_IFELSE(
2101 [AC_LANG_PROGRAM(
2102 [#include <pthread.h>],
2103 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2104 [AC_MSG_RESULT(yes)
2105 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2106 [Have function pthread_attr_setstacksize])],
2107 [AC_MSG_RESULT(no)])
2108 AC_MSG_CHECKING(for pthread_condattr_setclock)
2109 AC_LINK_IFELSE(
2110 [AC_LANG_PROGRAM(
2111 [#include <pthread.h>],
2112 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2113 [AC_MSG_RESULT(yes)
2114 AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2115 [Have function pthread_condattr_setclock])],
2116 [AC_MSG_RESULT(no)])
2117 AC_MSG_CHECKING(for pthread_cond_timedwait_relative_np)
2118 AC_LINK_IFELSE(
2119 [AC_LANG_PROGRAM(
2120 [#include <pthread.h>],
2121 [pthread_cond_timedwait_relative_np(NULL, NULL, NULL)])],
2122 [AC_MSG_RESULT(yes)
2123 AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP,1,
2124 [Have function pthread_cond_timedwait_relative_np])],
2125 [AC_MSG_RESULT(no)])
2126 dnl Sets thread names on OS X 10.6, iOS 3.2 (and higher)
2127 AC_MSG_CHECKING(for pthread_setname_np(const char*))
2128 AC_LINK_IFELSE(
2129 [AC_LANG_PROGRAM(
2130 [#include <pthread.h>],
2131 [pthread_setname_np("example")])],
2132 [AC_MSG_RESULT(yes)
2133 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
2134 [Have function pthread_setname_np(const char*)])],
2135 [AC_MSG_RESULT(no)])
2136 dnl Sets thread names on Solaris 11.3 & higher
2137 AC_MSG_CHECKING(for pthread_setname_np(pthread_t, const char*))
2138 AC_LINK_IFELSE(
2139 [AC_LANG_PROGRAM(
2140 [#include <pthread.h>],
2141 [pthread_setname_np(pthread_self(), "example")])],
2142 [AC_MSG_RESULT(yes)
2143 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITH_TID,1,
2144 [Have function pthread_setname_np(pthread_t, const char*)])],
2145 [AC_MSG_RESULT(no)])
2146 AC_MSG_CHECKING(for pthread_getname_np(pthread_t, name, len))
2147 AC_LINK_IFELSE(
2148 [AC_LANG_PROGRAM(
2149 [#include <pthread.h>],
2150 [[char name[16]; pthread_getname_np(pthread_self(), name, 16);]])],
2151 [AC_MSG_RESULT(yes)
2152 AC_DEFINE(HAVE_PTHREAD_GETNAME_NP,1,
2153 [Have function pthread_getname_np(pthread_t, name, len)])],
2154 [AC_MSG_RESULT(no)])
2155 CPPFLAGS="$glib_save_CPPFLAGS"
2156 ])
2158 LIBS="$glib_save_LIBS"
2160 # now spit out all the warnings.
2161 if test "$ac_cv_func_getpwuid_r" != "yes"; then
2162 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2163 fi
2164 if test "$ac_cv_func_localtime_r" != "yes"; then
2165 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2166 fi
2168 #
2169 # Hack to deal with:
2170 #
2171 # a) GCC < 3.3 for Linux doesn't include -lpthread when
2172 # building shared libraries with linux.
2173 # b) FreeBSD doesn't do this either.
2174 #
2175 case $host in
2176 *android*)
2177 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2178 ;;
2179 *-*-freebsd*|*-*-linux*)
2180 G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2181 ;;
2182 *)
2183 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2184 ;;
2185 esac
2187 AC_SUBST(G_THREAD_CFLAGS)
2188 AC_SUBST(G_THREAD_LIBS)
2189 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2190 AC_SUBST(G_THREAD_LIBS_EXTRA)
2192 AC_CHECK_FUNCS(clock_gettime, [], [
2193 AC_CHECK_LIB(rt, clock_gettime, [
2194 G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2195 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2196 ])
2197 ])
2200 dnl ************************
2201 dnl *** g_atomic_* tests ***
2202 dnl ************************
2204 dnl We need to decide at configure time if GLib will use real atomic
2205 dnl operations ("lock free") or emulated ones with a mutex. This is
2206 dnl because we must put this information in glibconfig.h so we know if
2207 dnl it is safe or not to inline using compiler intrinsics directly from
2208 dnl the header.
2209 dnl
2210 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2211 dnl user is interested in knowing if they can use the atomic ops across
2212 dnl processes.
2213 dnl
2214 dnl We can currently support the atomic ops natively when building GLib
2215 dnl with recent versions of GCC or MSVC. MSVC doesn't run ./configure,
2216 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2217 dnl we are using GCC (and not mingw*).
2218 dnl
2219 dnl Note that the atomic ops are only available with GCC on x86 when
2220 dnl using -march=i486 or higher. If we detect that the atomic ops are
2221 dnl not available but would be available given the right flags, we want
2222 dnl to abort and advise the user to fix their CFLAGS. It's better to do
2223 dnl that then to silently fall back on emulated atomic ops just because
2224 dnl the user had the wrong build environment.
2226 dnl We may add other compilers here in the future...
2228 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2229 case $host in
2230 *-*-mingw*)
2231 glib_cv_g_atomic_lock_free=yes
2232 ;;
2233 *)
2234 AC_TRY_LINK([],
2235 [volatile int atomic = 2;\
2236 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2237 [glib_cv_g_atomic_lock_free=yes],
2238 [glib_cv_g_atomic_lock_free=no])
2239 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2240 SAVE_CFLAGS="${CFLAGS}"
2241 CFLAGS="-march=i486"
2242 AC_TRY_LINK([],
2243 [volatile int atomic = 2;\
2244 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2245 [AC_MSG_ERROR([GLib must be built with -march=i486 or later.])],
2246 [])
2247 CFLAGS="${SAVE_CFLAGS}"
2248 fi
2249 ;;
2250 esac])
2253 case $host in
2254 *-*-mingw*)
2255 ;;
2256 *)
2257 # Some compilers support atomic operations but do not define
2258 # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2259 if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2260 AC_TRY_LINK([],
2261 [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2262 [],
2263 [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2264 fi
2265 ;;
2266 esac
2268 dnl We need a more robust approach here...
2269 case $host_cpu in
2270 i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2271 glib_memory_barrier_needed=no
2272 ;;
2273 sparc*|alpha*|powerpc*|ia64)
2274 glib_memory_barrier_needed=yes
2275 ;;
2276 *)
2277 glib_memory_barrier_needed=yes
2278 ;;
2279 esac
2281 dnl ************************
2282 dnl ** Check for futex(2) **
2283 dnl ************************
2284 AC_CACHE_CHECK(for futex(2) system call,
2285 glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2286 #include <linux/futex.h>
2287 #include <sys/syscall.h>
2288 #include <unistd.h>
2289 ],[
2290 syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2291 ])],glib_cv_futex=yes,glib_cv_futex=no))
2292 if test x"$glib_cv_futex" = xyes; then
2293 AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2294 fi
2296 AC_CACHE_CHECK(for eventfd(2) system call,
2297 glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2298 #include <sys/eventfd.h>
2299 #include <unistd.h>
2300 ],[
2301 eventfd (0, EFD_CLOEXEC);
2302 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2303 if test x"$glib_cv_eventfd" = x"yes"; then
2304 AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2305 fi
2306 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2308 dnl ****************************************
2309 dnl *** GLib POLL* compatibility defines ***
2310 dnl ****************************************
2312 glib_poll_includes=["
2313 #include <sys/types.h>
2314 #include <poll.h>
2315 "]
2317 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2318 test $ac_cv_func_poll = yes ], [
2319 glib_failed=false
2320 GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2321 GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2322 GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2323 GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2324 GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2325 GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2326 if $glib_failed ; then
2327 AC_MSG_ERROR([Could not determine values for POLL* constants])
2328 fi
2329 ], [
2330 glib_cv_value_POLLIN=1
2331 glib_cv_value_POLLOUT=4
2332 glib_cv_value_POLLPRI=2
2333 glib_cv_value_POLLERR=8
2334 glib_cv_value_POLLHUP=16
2335 glib_cv_value_POLLNVAL=32
2336 ])
2338 AC_MSG_CHECKING([for broken poll])
2339 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2340 #include <stdlib.h>
2341 #include <fcntl.h>
2342 #include <poll.h>
2343 int main(void) {
2344 struct pollfd fds[1];
2345 int fd;
2346 fd = open("/dev/null", 1);
2347 fds[0].fd = fd;
2348 fds[0].events = POLLIN;
2349 fds[0].revents = 0;
2350 if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2351 exit(1); /* Does not work for devices -- fail */
2352 }
2353 exit(0);
2354 }]])],
2355 [broken_poll=no],
2356 [broken_poll=yes
2357 AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2358 [broken_poll="no (cross compiling)"])
2359 AC_MSG_RESULT($broken_poll)
2361 dnl *********************
2362 dnl *** GRegex checks ***
2363 dnl *********************
2365 PCRE_REQUIRED_VERSION=8.31
2367 # Check if we should use the internal or the system-supplied pcre
2368 AC_ARG_WITH(pcre,
2369 [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2370 [whether to use system PCRE [default=system]])],
2371 [],
2372 [with_pcre=system])
2374 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2376 AS_IF([ test "x$with_pcre" = xsystem], [
2377 PKG_CHECK_MODULES(PCRE,
2378 libpcre >= $PCRE_REQUIRED_VERSION)
2379 AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2380 glib_save_CFLAGS="$CFLAGS"
2381 glib_save_LIBS="$LIBS"
2382 CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2383 AC_TRY_RUN([#include <pcre.h>
2384 int main () {
2385 int support;
2386 pcre_config (PCRE_CONFIG_UTF8, &support);
2387 if (!support)
2388 return 1;
2389 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2390 if (!support)
2391 return 1;
2392 return 0;
2393 }],
2394 glib_cv_pcre_has_unicode=yes,
2395 glib_cv_pcre_has_unicode=no,
2396 glib_cv_pcre_has_unicode=yes)
2397 CFLAGS="$glib_save_CFLAGS"
2398 LIBS="$glib_save_LIBS"
2399 ])
2400 if test "$glib_cv_pcre_has_unicode" = "no"; then
2401 AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2402 fi
2403 AC_SUBST(PCRE_CFLAGS)
2404 AC_SUBST(PCRE_LIBS)
2405 AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2406 PCRE_REQUIRES=libpcre
2407 AC_SUBST(PCRE_REQUIRES)
2408 ], [
2409 # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2410 AS_IF([ test x"$GCC" = xyes], [
2411 AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2412 save_CFLAGS="$CFLAGS"
2413 CFLAGS="$CFLAGS -Wno-pointer-sign"
2414 AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2415 AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2416 CFLAGS="$save_CFLAGS"
2417 ])
2418 ])
2419 AC_SUBST(PCRE_WARN_CFLAGS)
2421 dnl **********************
2422 dnl *** Win32 API libs ***
2423 dnl **********************
2425 case $host in
2426 *-*-cygwin*)
2427 G_LIBS_EXTRA="-luser32 -lkernel32"
2428 ;;
2429 *-*-mingw*)
2430 G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2431 ;;
2432 *)
2433 G_LIBS_EXTRA=""
2434 ;;
2435 esac
2436 AC_SUBST(G_LIBS_EXTRA)
2438 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2439 dnl since we need it for g_iconv()
2441 AC_MSG_CHECKING([for EILSEQ])
2442 AC_TRY_COMPILE([
2443 #include <errno.h>
2444 ],
2445 [
2446 int error = EILSEQ;
2447 ], have_eilseq=yes, have_eilseq=no);
2448 AC_MSG_RESULT($have_eilseq)
2450 dnl Add a conditional we can use when cross-compiling, so we avoid running
2451 dnl binaries
2452 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2454 dnl **************************
2455 dnl *** Checks for gtk-doc ***
2456 dnl **************************
2457 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2458 # it on it's own line.
2459 m4_ifdef([GTK_DOC_CHECK], [
2460 GTK_DOC_CHECK([1.20], [--flavour no-tmpl])
2461 ],[
2462 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2463 ])
2465 AC_ARG_ENABLE(man,
2466 [AS_HELP_STRING([--enable-man],
2467 [generate man pages [default=auto]])],,
2468 enable_man=maybe)
2470 AS_IF([test "$enable_man" != no], [
2471 AC_PATH_PROG([XSLTPROC], [xsltproc])
2472 AS_IF([test -z "$XSLTPROC"], [
2473 AS_IF([test "$enable_man" = yes], [
2474 AC_MSG_ERROR([xsltproc is required for --enable-man])
2475 ])
2476 enable_man=no
2477 ])
2478 ])
2480 AS_IF([ test "$enable_man" != no ], [
2481 dnl check for DocBook DTD in the local catalog
2482 JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2483 [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2484 AS_IF([test "$have_docbook_dtd" != yes], [
2485 AS_IF([test "$enable_man" = yes ], [
2486 AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2487 ])
2488 enable_man=no
2489 ])
2490 ])
2492 AS_IF([test "$enable_man" != no], [
2493 dnl check for DocBook XSL stylesheets in the local catalog
2494 JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2495 [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2496 AS_IF([ test "$have_docbook_style" != yes ], [
2497 AS_IF([ test "$enable_man" = yes ], [
2498 AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2499 ])
2500 enable_man=no
2501 ])
2502 ])
2504 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2506 AC_MSG_CHECKING([whether to generate man pages])
2507 AS_IF([ test "$enable_man" != no ], [
2508 AC_MSG_RESULT([yes])
2509 ], [
2510 AC_MSG_RESULT([no])
2511 ])
2513 dnl
2514 dnl Tracing
2515 dnl
2517 AC_ARG_ENABLE([dtrace],
2518 [AS_HELP_STRING([--enable-dtrace],
2519 [include tracing support for dtrace])])
2520 have_dtrace=no
2521 AC_MSG_CHECKING([whether to include dtrace tracing support])
2522 AS_IF([ test "x$enable_dtrace" != xno], [
2523 if test x$glib_have_carbon = xyes; then
2524 AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2525 else
2526 AC_MSG_RESULT([yes])
2527 AC_CHECK_PROGS(DTRACE, dtrace)
2528 if test -z "$DTRACE"; then
2529 if test "x$enable_dtrace" = xyes; then
2530 AC_MSG_ERROR([dtrace not found])
2531 fi
2532 else
2533 AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2534 [if test "x$enable_dtrace" = xyes; then
2535 AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2536 fi])
2537 fi
2538 fi
2539 ], [
2540 AC_MSG_RESULT([no])
2541 ])
2542 if test "x$have_dtrace" = xyes; then
2543 AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2544 fi
2545 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2547 AC_MSG_CHECKING([whether to include systemtap tracing support])
2548 AC_ARG_ENABLE([systemtap],
2549 [AS_HELP_STRING([--enable-systemtap],
2550 [include tracing support for systemtap])])
2551 have_systemtap=no
2552 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2553 have_systemtap=yes
2554 fi
2555 AC_MSG_RESULT(${have_systemtap})
2557 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2559 AC_ARG_WITH([tapset-install-dir],
2560 AS_HELP_STRING([--with-tapset-install-dir=DIR],
2561 [path where systemtap tapsets are installed [DATADIR/systemtap/tapset/HOST_CPU]]),
2562 [if test "x${withval}" = x; then
2563 ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset/${host_cpu}"
2564 else
2565 ABS_TAPSET_DIR="${withval}"
2566 fi],
2567 [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset/${host_cpu}"])
2568 AC_SUBST(ABS_TAPSET_DIR)
2570 dnl ************************************
2571 dnl *** Enable lcov coverage reports ***
2572 dnl ************************************
2574 AC_ARG_ENABLE(coverage,
2575 AS_HELP_STRING([--enable-coverage],
2576 [enable coverage testing with gcov]),
2577 [use_gcov=$enableval], [use_gcov=no])
2579 AS_IF([ test "x$use_gcov" = "xyes"], [
2580 dnl we need gcc:
2581 if test "$GCC" != "yes"; then
2582 AC_MSG_ERROR([GCC is required for --enable-coverage])
2583 fi
2585 dnl Check if ccache is being used
2586 AC_CHECK_PROG(SHTOOL, shtool, shtool)
2587 case `$SHTOOL path $CC` in
2588 *ccache*[)] gcc_ccache=yes;;
2589 *[)] gcc_ccache=no;;
2590 esac
2592 if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2593 AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2594 fi
2596 ltp_version_list="1.6 1.7 1.8 1.9 1.10 1.12"
2597 AC_CHECK_PROG(LTP, lcov, lcov)
2598 AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2600 AS_IF([ test "$LTP" ], [
2601 AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2602 glib_cv_ltp_version=invalid
2603 ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2604 for ltp_check_version in $ltp_version_list; do
2605 if test "$ltp_version" = "$ltp_check_version"; then
2606 glib_cv_ltp_version="$ltp_check_version (ok)"
2607 fi
2608 done
2609 ])
2610 ], [
2611 ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2612 AC_MSG_ERROR([$ltp_msg])
2613 ])
2615 case $glib_cv_ltp_version in
2616 ""|invalid[)]
2617 ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2618 AC_MSG_ERROR([$ltp_msg])
2619 LTP="exit 0;"
2620 ;;
2621 esac
2623 if test -z "$LTP_GENHTML"; then
2624 AC_MSG_ERROR([Could not find genhtml from the LTP package])
2625 fi
2627 dnl Remove all optimization flags from CFLAGS
2628 changequote({,})
2629 CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2630 changequote([,])
2632 dnl Add the special gcc flags
2633 CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2634 LDFLAGS="$LDFLAGS -lgcov"
2635 ])
2637 dnl *******************************
2638 dnl *** Disable strict aliasing ***
2639 dnl *******************************
2640 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=791622
2641 AS_IF([test "${GCC}" = "yes"],[
2642 CFLAGS="$CFLAGS -fno-strict-aliasing"
2643 ])
2645 dnl ******************************
2646 dnl *** output the whole stuff ***
2647 dnl ******************************
2649 dnl this section will only be run if config.status is invoked with no
2650 dnl arguments, or with "glib/glibconfig.h" as an argument.
2651 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2652 [
2653 outfile=glib/glibconfig.h-tmp
2654 cat > $outfile <<\_______EOF
2655 /* glibconfig.h
2656 *
2657 * This is a generated file. Please modify 'configure.ac'
2658 */
2660 #ifndef __GLIBCONFIG_H__
2661 #define __GLIBCONFIG_H__
2663 #include <glib/gmacros.h>
2665 _______EOF
2667 echo '#include <limits.h>' >> $outfile
2668 echo '#include <float.h>' >> $outfile
2669 if test x$glib_values_h = xyes; then
2670 echo '#include <values.h>' >> $outfile
2671 fi
2672 if test "$glib_header_alloca_h" = "yes"; then
2673 echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2674 fi
2675 if test x$glib_included_printf != xyes; then
2676 echo "
2677 /* Specifies that GLib's g_print*() functions wrap the
2678 * system printf functions. This is useful to know, for example,
2679 * when using glibc's register_printf_function().
2680 */" >> $outfile
2681 echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2682 fi
2684 cat >> $outfile <<_______EOF
2686 G_BEGIN_DECLS
2688 #define G_MINFLOAT FLT_MIN
2689 #define G_MAXFLOAT FLT_MAX
2690 #define G_MINDOUBLE DBL_MIN
2691 #define G_MAXDOUBLE DBL_MAX
2692 #define G_MINSHORT SHRT_MIN
2693 #define G_MAXSHORT SHRT_MAX
2694 #define G_MAXUSHORT USHRT_MAX
2695 #define G_MININT INT_MIN
2696 #define G_MAXINT INT_MAX
2697 #define G_MAXUINT UINT_MAX
2698 #define G_MINLONG LONG_MIN
2699 #define G_MAXLONG LONG_MAX
2700 #define G_MAXULONG ULONG_MAX
2702 _______EOF
2705 ### this should always be true in a modern C/C++ compiler
2706 ### and is statically asserted by glib-init.c
2707 cat >>$outfile <<_______EOF
2708 typedef signed char gint8;
2709 typedef unsigned char guint8;
2710 _______EOF
2713 if test -n "$gint16"; then
2714 cat >>$outfile <<_______EOF
2715 typedef signed $gint16 gint16;
2716 typedef unsigned $gint16 guint16;
2717 #define G_GINT16_MODIFIER $gint16_modifier
2718 #define G_GINT16_FORMAT $gint16_format
2719 #define G_GUINT16_FORMAT $guint16_format
2720 _______EOF
2721 fi
2724 if test -n "$gint32"; then
2725 cat >>$outfile <<_______EOF
2726 typedef signed $gint32 gint32;
2727 typedef unsigned $gint32 guint32;
2728 #define G_GINT32_MODIFIER $gint32_modifier
2729 #define G_GINT32_FORMAT $gint32_format
2730 #define G_GUINT32_FORMAT $guint32_format
2731 _______EOF
2732 fi
2734 cat >>$outfile <<_______EOF
2735 #define G_HAVE_GINT64 1 /* deprecated, always true */
2737 ${glib_extension}typedef signed $gint64 gint64;
2738 ${glib_extension}typedef unsigned $gint64 guint64;
2740 #define G_GINT64_CONSTANT(val) $gint64_constant
2741 #define G_GUINT64_CONSTANT(val) $guint64_constant
2742 _______EOF
2744 if test x$gint64_format != x ; then
2745 cat >>$outfile <<_______EOF
2746 #define G_GINT64_MODIFIER $gint64_modifier
2747 #define G_GINT64_FORMAT $gint64_format
2748 #define G_GUINT64_FORMAT $guint64_format
2749 _______EOF
2750 else
2751 cat >>$outfile <<_______EOF
2752 #undef G_GINT64_MODIFIER
2753 #undef G_GINT64_FORMAT
2754 #undef G_GUINT64_FORMAT
2755 _______EOF
2756 fi
2758 cat >>$outfile <<_______EOF
2760 #define GLIB_SIZEOF_VOID_P $glib_void_p
2761 #define GLIB_SIZEOF_LONG $glib_long
2762 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2763 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2765 _______EOF
2767 cat >>$outfile <<_______EOF
2768 typedef signed $glib_ssize_type_define gssize;
2769 typedef unsigned $glib_size_type_define gsize;
2770 #define G_GSIZE_MODIFIER $gsize_modifier
2771 #define G_GSSIZE_MODIFIER $gssize_modifier
2772 #define G_GSIZE_FORMAT $gsize_format
2773 #define G_GSSIZE_FORMAT $gssize_format
2775 #define G_MAXSIZE G_MAXU$glib_msize_type
2776 #define G_MINSSIZE G_MIN$glib_mssize_type
2777 #define G_MAXSSIZE G_MAX$glib_mssize_type
2779 typedef gint64 goffset;
2780 #define G_MINOFFSET G_MININT64
2781 #define G_MAXOFFSET G_MAXINT64
2783 #define G_GOFFSET_MODIFIER G_GINT64_MODIFIER
2784 #define G_GOFFSET_FORMAT G_GINT64_FORMAT
2785 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2787 #define G_POLLFD_FORMAT $g_pollfd_format
2789 _______EOF
2791 if test -z "$glib_unknown_void_p"; then
2792 cat >>$outfile <<_______EOF
2794 #define GPOINTER_TO_INT(p) ((gint) ${glib_gpi_cast} (p))
2795 #define GPOINTER_TO_UINT(p) ((guint) ${glib_gpui_cast} (p))
2797 #define GINT_TO_POINTER(i) ((gpointer) ${glib_gpi_cast} (i))
2798 #define GUINT_TO_POINTER(u) ((gpointer) ${glib_gpui_cast} (u))
2800 typedef signed $glib_intptr_type_define gintptr;
2801 typedef unsigned $glib_intptr_type_define guintptr;
2803 #define G_GINTPTR_MODIFIER $gintptr_modifier
2804 #define G_GINTPTR_FORMAT $gintptr_format
2805 #define G_GUINTPTR_FORMAT $guintptr_format
2806 _______EOF
2807 else
2808 echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2809 fi
2813 cat >>$outfile <<_______EOF
2814 #ifndef G_DISABLE_DEPRECATED
2815 #define g_ATEXIT(proc) (atexit (proc))
2816 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2817 #endif
2818 $glib_defines
2819 $glib_os
2820 $glib_static_compilation
2822 $glib_vacopy
2824 _______EOF
2826 if test x$g_have_iso_c_varargs = xyes ; then
2827 cat >>$outfile <<_______EOF
2828 #ifndef __cplusplus
2829 # define G_HAVE_ISO_VARARGS 1
2830 #endif
2831 _______EOF
2832 fi
2833 if test x$g_have_iso_cxx_varargs = xyes ; then
2834 cat >>$outfile <<_______EOF
2835 #ifdef __cplusplus
2836 # define G_HAVE_ISO_VARARGS 1
2837 #endif
2838 _______EOF
2839 fi
2840 if test x$g_have_gnuc_varargs = xyes ; then
2841 cat >>$outfile <<_______EOF
2843 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2844 * is passed ISO vararg support is turned off, and there is no work
2845 * around to turn it on, so we unconditionally turn it off.
2846 */
2847 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2848 # undef G_HAVE_ISO_VARARGS
2849 #endif
2851 #define G_HAVE_GNUC_VARARGS 1
2852 _______EOF
2853 fi
2855 case x$g_stack_grows in
2856 xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2857 *) echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2858 esac
2861 echo >>$outfile
2862 if test x$g_have_eilseq = xno; then
2863 cat >>$outfile <<_______EOF
2864 #ifndef EILSEQ
2865 /* On some pre-C99 systems, EILSEQ is not defined.
2866 * The correspondence between this and the corresponding definition
2867 * in libiconv is essential.
2868 */
2869 # define EILSEQ ENOENT
2870 #endif
2871 _______EOF
2873 fi
2875 if test x$g_have_gnuc_visibility = xyes; then
2876 cat >>$outfile <<_______EOF
2877 #define G_HAVE_GNUC_VISIBILITY 1
2878 _______EOF
2879 fi
2880 cat >>$outfile <<_______EOF
2881 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2882 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2883 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2884 #define G_GNUC_INTERNAL __hidden
2885 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2886 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2887 #else
2888 #define G_GNUC_INTERNAL
2889 #endif
2890 _______EOF
2892 echo >>$outfile
2893 cat >>$outfile <<_______EOF
2894 #define G_THREADS_ENABLED
2895 #define G_THREADS_IMPL_$g_threads_impl_def
2896 _______EOF
2898 if test x"$g_memory_barrier_needed" != xno; then
2899 echo >>$outfile
2900 echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2901 fi
2902 if test x"$g_atomic_lock_free" = xyes; then
2903 echo >>$outfile
2904 echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
2905 fi
2906 echo >>$outfile
2907 g_bit_sizes="16 32 64"
2908 for bits in $g_bit_sizes; do
2909 cat >>$outfile <<_______EOF
2910 #define GINT${bits}_TO_${g_bs_native}(val) ((gint${bits}) (val))
2911 #define GUINT${bits}_TO_${g_bs_native}(val) ((guint${bits}) (val))
2912 #define GINT${bits}_TO_${g_bs_alien}(val) ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2913 #define GUINT${bits}_TO_${g_bs_alien}(val) (GUINT${bits}_SWAP_LE_BE (val))
2914 _______EOF
2915 done
2917 cat >>$outfile <<_______EOF
2918 #define GLONG_TO_LE(val) ((glong) GINT${glongbits}_TO_LE (val))
2919 #define GULONG_TO_LE(val) ((gulong) GUINT${glongbits}_TO_LE (val))
2920 #define GLONG_TO_BE(val) ((glong) GINT${glongbits}_TO_BE (val))
2921 #define GULONG_TO_BE(val) ((gulong) GUINT${glongbits}_TO_BE (val))
2922 #define GINT_TO_LE(val) ((gint) GINT${gintbits}_TO_LE (val))
2923 #define GUINT_TO_LE(val) ((guint) GUINT${gintbits}_TO_LE (val))
2924 #define GINT_TO_BE(val) ((gint) GINT${gintbits}_TO_BE (val))
2925 #define GUINT_TO_BE(val) ((guint) GUINT${gintbits}_TO_BE (val))
2926 #define GSIZE_TO_LE(val) ((gsize) GUINT${gsizebits}_TO_LE (val))
2927 #define GSSIZE_TO_LE(val) ((gssize) GINT${gssizebits}_TO_LE (val))
2928 #define GSIZE_TO_BE(val) ((gsize) GUINT${gsizebits}_TO_BE (val))
2929 #define GSSIZE_TO_BE(val) ((gssize) GINT${gssizebits}_TO_BE (val))
2930 #define G_BYTE_ORDER $g_byte_order
2932 #define GLIB_SYSDEF_POLLIN =$g_pollin
2933 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2934 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2935 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2936 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2937 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2939 #define G_MODULE_SUFFIX "$g_module_suffix"
2941 typedef $g_pid_type GPid;
2942 #define G_PID_FORMAT $g_pid_format
2944 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
2945 #define GLIB_SYSDEF_AF_INET $g_af_inet
2946 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
2948 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
2949 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
2950 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
2952 #define G_DIR_SEPARATOR '$g_dir_separator'
2953 #define G_DIR_SEPARATOR_S "$g_dir_separator"
2954 #define G_SEARCHPATH_SEPARATOR '$g_searchpath_separator'
2955 #define G_SEARCHPATH_SEPARATOR_S "$g_searchpath_separator"
2957 G_END_DECLS
2959 #endif /* __GLIBCONFIG_H__ */
2960 _______EOF
2963 if cmp -s $outfile glib/glibconfig.h; then
2964 AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
2965 rm -f $outfile
2966 else
2967 mv $outfile glib/glibconfig.h
2968 fi
2969 ],[
2971 # Note that if two cases are the same, case goes with the first one.
2972 # Note also that this is inside an AC_OUTPUT_COMMAND. We do not depend
2973 # on variable expansion in case labels. Look at the generated config.status
2974 # for a hint.
2976 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2977 glib_header_alloca_h="$ac_cv_working_alloca_h"
2978 else
2979 glib_header_alloca_h="$ac_cv_header_alloca_h"
2980 fi
2982 if test x$enable_included_printf = xyes ; then
2983 glib_included_printf=yes
2984 fi
2986 case 2 in
2987 $ac_cv_sizeof_short)
2988 gint16=short
2989 gint16_modifier='"h"'
2990 gint16_format='"hi"'
2991 guint16_format='"hu"'
2992 ;;
2993 $ac_cv_sizeof_int)
2994 gint16=int
2995 gint16_modifier='""'
2996 gint16_format='"i"'
2997 guint16_format='"u"'
2998 ;;
2999 esac
3000 case 4 in
3001 $ac_cv_sizeof_short)
3002 gint32=short
3003 gint32_modifier='"h"'
3004 gint32_format='"hi"'
3005 guint32_format='"hu"'
3006 ;;
3007 $ac_cv_sizeof_int)
3008 gint32=int
3009 gint32_modifier='""'
3010 gint32_format='"i"'
3011 guint32_format='"u"'
3012 ;;
3013 $ac_cv_sizeof_long)
3014 gint32=long
3015 gint32_modifier='"l"'
3016 gint32_format='"li"'
3017 guint32_format='"lu"'
3018 ;;
3019 esac
3020 case 8 in
3021 $ac_cv_sizeof_int)
3022 gint64=int
3023 gint64_modifier='""'
3024 gint64_format='"i"'
3025 guint64_format='"u"'
3026 glib_extension=
3027 gint64_constant='(val)'
3028 guint64_constant='(val)'
3029 ;;
3030 $ac_cv_sizeof_long)
3031 gint64=long
3032 gint64_modifier='"l"'
3033 gint64_format='"li"'
3034 guint64_format='"lu"'
3035 glib_extension=
3036 gint64_constant='(val##L)'
3037 guint64_constant='(val##UL)'
3038 ;;
3039 $ac_cv_sizeof_long_long)
3040 gint64='long long'
3041 if test -n "$glib_cv_long_long_format"; then
3042 gint64_modifier='"'$glib_cv_long_long_format'"'
3043 gint64_format='"'$glib_cv_long_long_format'i"'
3044 guint64_format='"'$glib_cv_long_long_format'u"'
3045 fi
3046 glib_extension='G_GNUC_EXTENSION '
3047 gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3048 guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3049 ;;
3050 $ac_cv_sizeof___int64)
3051 gint64='__int64'
3052 if test -n "$glib_cv_long_long_format"; then
3053 gint64_modifier='"'$glib_cv_long_long_format'"'
3054 gint64_format='"'$glib_cv_long_long_format'i"'
3055 guint64_format='"'$glib_cv_long_long_format'u"'
3056 fi
3057 glib_extension=
3058 gint64_constant='(val##i64)'
3059 guint64_constant='(val##ui64)'
3060 ;;
3061 esac
3062 glib_size_t=$ac_cv_sizeof_size_t
3063 glib_ssize_t=$ac_cv_sizeof_ssize_t
3064 glib_size_type_define="$glib_size_type"
3065 glib_ssize_type_define="$glib_ssize_type"
3066 glib_void_p=$ac_cv_sizeof_void_p
3067 glib_long=$ac_cv_sizeof_long
3069 case "$glib_size_type" in
3070 short)
3071 gsize_modifier='"h"'
3072 gsize_format='"hu"'
3073 glib_msize_type='SHRT'
3074 ;;
3075 int)
3076 gsize_modifier='""'
3077 gsize_format='"u"'
3078 glib_msize_type='INT'
3079 ;;
3080 long)
3081 gsize_modifier='"l"'
3082 gsize_format='"lu"'
3083 glib_msize_type='LONG'
3084 ;;
3085 "long long"|__int64)
3086 gsize_modifier='"I64"'
3087 gsize_format='"I64u"'
3088 glib_msize_type='INT64'
3089 ;;
3090 esac
3092 case "$glib_ssize_type" in
3093 short)
3094 gssize_modifier='"h"'
3095 gssize_format='"hi"'
3096 glib_mssize_type='SHRT'
3097 ;;
3098 int)
3099 gssize_modifier='""'
3100 gssize_format='"i"'
3101 glib_mssize_type='INT'
3102 ;;
3103 long)
3104 gssize_modifier='"l"'
3105 gssize_format='"li"'
3106 glib_mssize_type='LONG'
3107 ;;
3108 "long long"|__int64)
3109 gssize_modifier='"I64"'
3110 gssize_format='"I64i"'
3111 glib_mssize_type='INT64'
3112 ;;
3113 esac
3115 gintbits=`expr $ac_cv_sizeof_int \* 8`
3116 glongbits=`expr $ac_cv_sizeof_long \* 8`
3117 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3118 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3120 case $ac_cv_sizeof_void_p in
3121 $ac_cv_sizeof_int)
3122 glib_intptr_type_define=int
3123 gintptr_modifier='""'
3124 gintptr_format='"i"'
3125 guintptr_format='"u"'
3126 glib_gpi_cast='(gint)'
3127 glib_gpui_cast='(guint)'
3128 ;;
3129 $ac_cv_sizeof_long)
3130 glib_intptr_type_define=long
3131 gintptr_modifier='"l"'
3132 gintptr_format='"li"'
3133 guintptr_format='"lu"'
3134 glib_gpi_cast='(glong)'
3135 glib_gpui_cast='(gulong)'
3136 ;;
3137 $ac_cv_sizeof_long_long)
3138 glib_intptr_type_define='long long'
3139 gintptr_modifier='"I64"'
3140 gintptr_format='"I64i"'
3141 guintptr_format='"I64u"'
3142 glib_gpi_cast='(gint64)'
3143 glib_gpui_cast='(guint64)'
3144 ;;
3145 $ac_cv_sizeof___int64)
3146 glib_intptr_type_define=__int64
3147 gintptr_modifier='"I64"'
3148 gintptr_format='"I64i"'
3149 guintptr_format='"I64u"'
3150 glib_gpi_cast='(gint64)'
3151 glib_gpui_cast='(guint64)'
3152 ;;
3153 *)
3154 glib_unknown_void_p=yes
3155 ;;
3156 esac
3159 glib_defines="
3160 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3161 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3162 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3163 "
3165 case xyes in
3166 x$glib_cv_va_copy) glib_vacopy='#define G_VA_COPY va_copy' ;;
3167 x$glib_cv___va_copy) glib_vacopy='#define G_VA_COPY __va_copy' ;;
3168 *) glib_vacopy=''
3169 esac
3171 if test x$glib_cv_va_val_copy = xno; then
3172 glib_vacopy="\$glib_vacopy
3173 #define G_VA_COPY_AS_ARRAY 1"
3174 fi
3176 g_have_gnuc_varargs=$g_have_gnuc_varargs
3177 g_have_iso_c_varargs=$g_have_iso_c_varargs
3178 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3180 g_have_gnuc_visibility=$g_have_gnuc_visibility
3181 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3183 if test x$ac_cv_c_bigendian = xyes; then
3184 g_byte_order=G_BIG_ENDIAN
3185 g_bs_native=BE
3186 g_bs_alien=LE
3187 else
3188 g_byte_order=G_LITTLE_ENDIAN
3189 g_bs_native=LE
3190 g_bs_alien=BE
3191 fi
3193 g_pollin=$glib_cv_value_POLLIN
3194 g_pollout=$glib_cv_value_POLLOUT
3195 g_pollpri=$glib_cv_value_POLLPRI
3196 g_pollhup=$glib_cv_value_POLLHUP
3197 g_pollerr=$glib_cv_value_POLLERR
3198 g_pollnval=$glib_cv_value_POLLNVAL
3200 # If a family is not found on the system, define that family to
3201 # a negative value, picking a different one for each undefined
3202 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3203 # This is needed because glib-mkenums doesn't handle optional
3204 # values in enums, and thus we have to have all existing values
3205 # defined in the enum.
3206 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3207 g_af_unix=$glib_cv_value_AF_UNIX
3208 else
3209 g_af_unix=-1
3210 fi
3211 g_af_inet=$glib_cv_value_AF_INET
3212 g_af_inet6=$glib_cv_value_AF_INET6
3214 g_msg_peek=$glib_cv_value_MSG_PEEK
3215 g_msg_oob=$glib_cv_value_MSG_OOB
3216 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3218 g_stack_grows=$glib_cv_stack_grows
3220 g_have_eilseq=$have_eilseq
3222 g_threads_impl_def=$g_threads_impl
3224 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3225 g_memory_barrier_needed="$glib_memory_barrier_needed"
3226 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3228 g_module_suffix="$glib_gmodule_suffix"
3229 g_dir_separator="$glib_dir_separator"
3230 g_searchpath_separator="$glib_searchpath_separator"
3232 g_pid_type="$glib_pid_type"
3233 g_pid_format="\"$glib_pid_format\""
3234 g_pollfd_format="\"$glib_pollfd_format\""
3236 case $host in
3237 *-*-cygwin*)
3238 glib_os="#define G_OS_UNIX
3239 #define G_PLATFORM_WIN32
3240 #define G_WITH_CYGWIN"
3241 ;;
3242 *-*-mingw*)
3243 glib_os="#define G_OS_WIN32
3244 #define G_PLATFORM_WIN32"
3245 ;;
3246 *)
3247 glib_os="#define G_OS_UNIX"
3248 ;;
3249 esac
3250 glib_static_compilation=""
3251 if test x$glib_win32_static_compilation = xyes; then
3252 glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3253 #define GOBJECT_STATIC_COMPILATION 1"
3254 fi
3255 ])
3257 # Redo enough to get guint32 and guint64 for the alignment checks below
3258 case 4 in
3259 $ac_cv_sizeof_short)
3260 gint32=short
3261 ;;
3262 $ac_cv_sizeof_int)
3263 gint32=int
3264 ;;
3265 $ac_cv_sizeof_long)
3266 gint32=long
3267 ;;
3268 esac
3269 case 8 in
3270 $ac_cv_sizeof_int)
3271 gint64=int
3272 ;;
3273 $ac_cv_sizeof_long)
3274 gint64=long
3275 ;;
3276 $ac_cv_sizeof_long_long)
3277 gint64='long long'
3278 ;;
3279 $ac_cv_sizeof___int64)
3280 gint64='__int64'
3281 ;;
3282 esac
3284 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3285 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3286 typedef unsigned $gint32 guint32;])
3287 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3288 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3289 typedef unsigned $gint64 guint64;])
3290 AC_CHECK_TYPE([unsigned long])
3291 AC_CHECK_ALIGNOF([unsigned long])
3293 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3294 #
3295 # 1.2.14 required for dbus_message_set_serial
3296 PKG_CHECK_MODULES(DBUS1,
3297 dbus-1 >= 1.2.14,
3298 [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3299 have_dbus1=no)
3300 AC_SUBST(DBUS1_CFLAGS)
3301 AC_SUBST(DBUS1_LIBS)
3302 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3304 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3305 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3307 # Check whether MSVC toolset is explicitly set
3308 AM_CONDITIONAL(MSVC_BASE_NO_TOOLSET_SET, [test x$MSVC_BASE_TOOLSET = x])
3309 AM_CONDITIONAL(MSVC_NO_TOOLSET_SET, [test x$MSVC_TOOLSET = x])
3311 dnl
3312 dnl Check for -Bsymbolic-functions linker flag used to avoid
3313 dnl intra-library PLT jumps, if available.
3314 dnl
3316 AC_ARG_ENABLE(Bsymbolic,
3317 [AS_HELP_STRING([--disable-Bsymbolic],
3318 [avoid linking with -Bsymbolic])],,
3319 [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3320 AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3321 LDFLAGS=-Wl,-Bsymbolic-functions
3322 LIBS=
3323 AC_TRY_LINK([], [return 0],
3324 AC_MSG_RESULT(yes)
3325 enable_Bsymbolic=yes,
3326 AC_MSG_RESULT(no)
3327 enable_Bsymbolic=no)
3328 LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3330 if test "x${enable_Bsymbolic}" = "xyes"; then
3331 GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3332 fi
3334 dnl
3335 dnl Check for -z,nodelete linker flag: the type system assumes that
3336 dnl libgobject stays loaded for the lifetime of the process.
3337 dnl Since ld.bfd does not treat wrong -z options as fatal by default,
3338 dnl we also try to check for the --fatal-warnings linker flag if
3339 dnl auto-detecting.
3340 dnl
3342 SAVED_CFLAGS="${CFLAGS}" SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3343 AC_MSG_CHECKING([for --fatal-warnings linker flag])
3344 CFLAGS="${SAVED_CFLAGS} ${shared_flag:- -shared}"
3345 LDFLAGS=-Wl,--fatal-warnings
3346 LIBS=
3347 AC_TRY_LINK([], [return 0],
3348 AC_MSG_RESULT(yes)
3349 [ldflags_fatal=-Wl,--fatal-warnings],
3350 AC_MSG_RESULT(no)
3351 ldflags_fatal=)
3353 AC_MSG_CHECKING([for -z,nodelete linker flag])
3354 LDFLAGS="$ldflags_fatal -Wl,-z,nodelete"
3355 AC_TRY_LINK([], [return 0],
3356 AC_MSG_RESULT(yes)
3357 enable_znodelete=yes,
3358 AC_MSG_RESULT(no)
3359 enable_znodelete=no)
3360 CFLAGS="${SAVED_CFLAGS}" LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"
3362 if test "x${enable_znodelete}" = "xyes"; then
3363 GLIB_LINK_FLAGS="$GLIB_LINK_FLAGS -Wl,-z,nodelete"
3364 fi
3366 AC_SUBST(GLIB_LINK_FLAGS)
3368 dnl
3369 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3370 dnl visibility attributes for symbol export control
3371 dnl
3372 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3373 case "$host" in
3374 *-*-mingw*)
3375 dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3376 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3377 [defines how to decorate public symbols while building])
3378 CFLAGS="${CFLAGS} -fvisibility=hidden"
3379 ;;
3380 *)
3381 dnl on other compilers, check if we can do -fvisibility=hidden
3382 SAVED_CFLAGS="${CFLAGS}"
3383 CFLAGS="-fvisibility=hidden"
3384 AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3385 AC_TRY_COMPILE([], [return 0],
3386 AC_MSG_RESULT(yes)
3387 enable_fvisibility_hidden=yes,
3388 AC_MSG_RESULT(no)
3389 enable_fvisibility_hidden=no)
3390 CFLAGS="${SAVED_CFLAGS}"
3392 AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3393 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3394 [defines how to decorate public symbols while building])
3395 GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3396 ])
3397 ;;
3398 esac
3399 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3401 dnl Compiler flags; macro originates from systemd
3402 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3403 AC_ARG_ENABLE(compile-warnings,
3404 [AS_HELP_STRING([--disable-compile-warnings],
3405 [Don't use builtin compiler warnings])],,
3406 enable_compile_warnings=yes)
3407 AS_IF([test "x$enable_compile_warnings" != xno], [
3408 CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3409 -Wall -Wstrict-prototypes -Wduplicated-branches -Wmisleading-indentation \
3410 -Wno-bad-function-cast \
3411 -Werror=declaration-after-statement \
3412 -Werror=missing-prototypes -Werror=implicit-function-declaration \
3413 -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3414 -Werror=format=2 -Werror=missing-include-dirs])
3415 ])
3416 AC_SUBST(GLIB_WARN_CFLAGS)
3418 #
3419 # Define variables corresponding to the correct include paths to use for
3420 # in-tree building.
3421 #
3423 # for config.h:
3424 config_h_INCLUDES='-I$(top_builddir)'
3425 AC_SUBST(config_h_INCLUDES)
3427 # glib:
3428 # config.h
3429 # $(top_builddir)/glib: for glibconfig.h
3430 # $(top_srcdir)/glib: for glib.h
3431 # $(top_srcdir): for everything
3432 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3433 AC_SUBST(glib_INCLUDES)
3435 # gobject:
3436 # same as glib
3437 gobject_INCLUDES='$(glib_INCLUDES)'
3438 AC_SUBST(gobject_INCLUDES)
3440 # gmodule:
3441 # glib includes
3442 # $(top_srcdir)/gmodule: for gmodule.h
3443 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3444 AC_SUBST(gmodule_INCLUDES)
3446 # gio:
3447 # same as gmodule
3448 gio_INCLUDES='$(gmodule_INCLUDES)'
3449 AC_SUBST(gio_INCLUDES)
3452 AC_CONFIG_FILES([
3453 glib-2.0.pc
3454 gmodule-2.0.pc
3455 gmodule-export-2.0.pc
3456 gmodule-no-export-2.0.pc
3457 gthread-2.0.pc
3458 gobject-2.0.pc
3459 gio-2.0.pc
3460 gio-unix-2.0.pc
3461 gio-windows-2.0.pc
3462 glib-gettextize
3463 Makefile
3464 build/Makefile
3465 build/win32/Makefile
3466 build/win32/dirent/Makefile
3467 glib/Makefile
3468 glib/libcharset/Makefile
3469 glib/gnulib/Makefile
3470 glib/pcre/Makefile
3471 glib/update-pcre/Makefile
3472 glib/tests/Makefile
3473 gmodule/Makefile
3474 gmodule/gmoduleconf.h
3475 gobject/Makefile
3476 gobject/glib-genmarshal
3477 gobject/glib-mkenums
3478 gobject/tests/Makefile
3479 gthread/Makefile
3480 gio/Makefile
3481 gio/gdbus-2.0/codegen/Makefile
3482 gio/gdbus-2.0/codegen/config.py
3483 gio/gnetworking.h
3484 gio/xdgmime/Makefile
3485 gio/inotify/Makefile
3486 gio/kqueue/Makefile
3487 gio/fam/Makefile
3488 gio/win32/Makefile
3489 gio/tests/Makefile
3490 gio/tests/gdbus-object-manager-example/Makefile
3491 gio/tests/services/Makefile
3492 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3493 gio/tests/modules/Makefile
3494 po/Makefile.in
3495 docs/Makefile
3496 docs/reference/Makefile
3497 docs/reference/glib/Makefile
3498 docs/reference/glib/version.xml
3499 docs/reference/gobject/Makefile
3500 docs/reference/gobject/version.xml
3501 docs/reference/gio/Makefile
3502 docs/reference/gio/version.xml
3503 tests/Makefile
3504 tests/gobject/Makefile
3505 tests/refcount/Makefile
3506 m4macros/Makefile
3507 subprojects/Makefile
3508 ])
3510 # We need this command because the configure script will not preserve
3511 # the same attributes of the template files
3512 AC_CONFIG_COMMANDS([chmod-scripts],
3513 [chmod 0755 glib-gettextize
3514 chmod 0755 gobject/glib-genmarshal
3515 chmod 0755 gobject/glib-mkenums])
3517 # we want to invoke this macro solely so that the config.status script
3518 # and automake generated makefiles know about these generated files.
3519 # They are only needed to distcheck the package
3520 if false; then
3521 AC_CONFIG_FILES([
3522 INSTALL
3523 glib/glib.rc
3524 gmodule/gmodule.rc
3525 gobject/gobject.rc
3526 gthread/gthread.rc
3527 gio/gio.rc
3528 ])
3529 fi
3531 AC_OUTPUT