| blob | 2be847aa41c369ce3e2c1691c56481b19d4c4529 |
1 project('glib', 'c', 'cpp',
2 version : '2.57.1',
3 meson_version : '>= 0.47.0',
4 default_options : [
5 'buildtype=debugoptimized',
6 'warning_level=1',
7 'c_std=gnu89'
8 ]
9 )
11 cc = meson.get_compiler('c')
12 cxx = meson.get_compiler('cpp')
14 cc_can_run = not meson.is_cross_build() or meson.has_exe_wrapper()
16 if cc.get_id() == 'msvc'
17 # Ignore several spurious warnings for things glib does very commonly
18 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
19 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
20 # NOTE: Only add warnings here if you are sure they're spurious
21 add_project_arguments('/wd4035', '/wd4715', '/wd4116',
22 '/wd4046', '/wd4068', '/wo4090', '/FImsvc_recommended_pragmas.h',language : 'c')
23 # Disable SAFESEH with MSVC for plugins and libs that use external deps that
24 # are built with MinGW
25 noseh_link_args = ['/SAFESEH:NO']
26 # Set the input and exec encoding to utf-8, like is the default with GCC
27 add_project_arguments(cc.get_supported_arguments(['/utf-8']), language: 'c')
28 else
29 noseh_link_args = []
30 # -mms-bitfields vs -fnative-struct ?
31 endif
33 host_system = host_machine.system()
35 glib_version = meson.project_version()
36 glib_api_version = '2.0'
37 version_arr = glib_version.split('.')
38 major_version = version_arr[0].to_int()
39 minor_version = version_arr[1].to_int()
40 micro_version = version_arr[2].to_int()
42 interface_age = minor_version.is_odd() ? 0 : micro_version
43 binary_age = 100 * minor_version + micro_version
45 soversion = 0
46 # Maintain compatibility with previous libtool versioning
47 # current = minor * 100 + micro
48 library_version = '@0@.@1@.@2@'.format(soversion, binary_age - interface_age, interface_age)
50 configinc = include_directories('.')
51 glibinc = include_directories('glib')
52 gobjectinc = include_directories('gobject')
53 gmoduleinc = include_directories('gmodule')
54 gioinc = include_directories('gio')
56 glib_prefix = get_option('prefix')
57 glib_bindir = join_paths(glib_prefix, get_option('bindir'))
58 glib_libdir = join_paths(glib_prefix, get_option('libdir'))
59 glib_datadir = join_paths(glib_prefix, get_option('datadir'))
60 glib_pkgdatadir = join_paths(glib_datadir, 'glib-2.0')
61 glib_includedir = join_paths(glib_prefix, get_option('includedir'))
62 glib_giomodulesdir = get_option('gio_module_dir')
63 if glib_giomodulesdir == ''
64 glib_giomodulesdir = join_paths(glib_libdir, 'gio', 'modules')
65 endif
67 glib_pkgconfigreldir = join_paths(glib_libdir, 'pkgconfig')
69 add_project_arguments('-D_GNU_SOURCE', language: 'c')
71 # Disable strict aliasing;
72 # see https://bugzilla.gnome.org/show_bug.cgi?id=791622
73 if cc.has_argument('-fno-strict-aliasing')
74 add_project_arguments('-fno-strict-aliasing', language: 'c')
75 endif
77 ########################
78 # Configuration begins #
79 ########################
80 glib_conf = configuration_data()
81 glibconfig_conf = configuration_data()
83 # accumulated list of defines as we check for them, so we can easily
84 # use them later in test programs (autoconf does this automatically)
85 glib_conf_prefix = ''
87 glib_conf.set('GLIB_MAJOR_VERSION', major_version)
88 glib_conf.set('GLIB_MINOR_VERSION', minor_version)
89 glib_conf.set('GLIB_MICRO_VERSION', micro_version)
90 glib_conf.set('GLIB_INTERFACE_AGE', interface_age)
91 glib_conf.set('GLIB_BINARY_AGE', binary_age)
92 glib_conf.set_quoted('GETTEXT_PACKAGE', 'glib20')
93 glib_conf.set_quoted('PACKAGE_BUGREPORT', 'https://gitlab.gnome.org/GNOME/glib/issues/new')
94 glib_conf.set_quoted('PACKAGE_NAME', 'glib')
95 glib_conf.set_quoted('PACKAGE_STRING', 'glib @0@'.format(meson.project_version()))
96 glib_conf.set_quoted('PACKAGE_TARNAME', 'glib')
97 glib_conf.set_quoted('PACKAGE_URL', '')
98 glib_conf.set_quoted('PACKAGE_VERSION', meson.project_version())
99 glib_conf.set('ENABLE_NLS', 1)
101 # used by the .rc.in files
102 glibconfig_conf.set('LT_CURRENT_MINUS_AGE', soversion)
104 glib_conf.set('_GNU_SOURCE', 1)
106 if host_system == 'windows'
107 # Poll doesn't work on devices on Windows
108 glib_conf.set('BROKEN_POLL', true)
109 endif
111 # Check for GNU visibility attributes
112 g_have_gnuc_visibility = cc.compiles('''
113 void
114 __attribute__ ((visibility ("hidden")))
115 f_hidden (void)
116 {
117 }
118 void
119 __attribute__ ((visibility ("internal")))
120 f_internal (void)
121 {
122 }
123 void
124 __attribute__ ((visibility ("protected")))
125 f_protected (void)
126 {
127 }
128 void
129 __attribute__ ((visibility ("default")))
130 f_default (void)
131 {
132 }
133 int main (void)
134 {
135 f_hidden();
136 f_internal();
137 f_protected();
138 f_default();
139 return 0;
140 }
141 ''',
142 # Not supported by MSVC, but MSVC also won't support visibility,
143 # so it's OK to pass -Werror explicitly. Replace with
144 # override_options : 'werror=true' once that is supported
145 args: ['-Werror'],
146 name : 'GNU C visibility attributes test')
148 if g_have_gnuc_visibility
149 glibconfig_conf.set('G_HAVE_GNUC_VISIBILITY', '1')
150 endif
152 # Detect and set symbol visibility
153 glib_hidden_visibility_args = []
154 if get_option('default_library') != 'static'
155 if host_system == 'windows'
156 glib_conf.set('DLL_EXPORT', true)
157 if cc.get_id() == 'msvc'
158 glib_conf.set('_GLIB_EXTERN', '__declspec(dllexport) extern')
159 elif cc.has_argument('-fvisibility=hidden')
160 glib_conf.set('_GLIB_EXTERN', '__attribute__((visibility("default"))) __declspec(dllexport) extern')
161 glib_hidden_visibility_args = ['-fvisibility=hidden']
162 endif
163 elif cc.has_argument('-fvisibility=hidden')
164 glib_conf.set('_GLIB_EXTERN', '__attribute__((visibility("default"))) extern')
165 glib_hidden_visibility_args = ['-fvisibility=hidden']
166 endif
167 endif
169 if host_system == 'windows' and get_option('default_library') == 'static'
170 glibconfig_conf.set('GLIB_STATIC_COMPILATION', '1')
171 glibconfig_conf.set('GOBJECT_STATIC_COMPILATION', '1')
172 endif
174 # FIXME: what about Cygwin (G_WITH_CYGWIN)
175 if host_system == 'windows'
176 glib_os = '''#define G_OS_WIN32
177 #define G_PLATFORM_WIN32'''
178 else
179 glib_os = '#define G_OS_UNIX'
180 endif
181 glibconfig_conf.set('glib_os', glib_os)
183 # We need to know the build type to determine what .lib files we need on Visual Studio
184 # for dependencies that don't normally come with pkg-config files for Visual Studio builds
185 buildtype = get_option('buildtype')
187 glib_debug_cflags = []
188 if buildtype.startswith('debug')
189 glib_debug_cflags += ['-DG_ENABLE_DEBUG']
190 elif buildtype == 'release'
191 glib_debug_cflags += ['-DG_DISABLE_CAST_CHECKS']
192 endif
194 add_project_arguments(glib_debug_cflags, language: 'c')
196 # check for header files
198 headers = [
199 'alloca.h',
200 'crt_externs.h',
201 'dirent.h', # MSC does not come with this by default
202 'float.h',
203 'fstab.h',
204 'grp.h',
205 'inttypes.h',
206 'limits.h',
207 'linux/magic.h',
208 'locale.h',
209 'mach/mach_time.h',
210 'memory.h',
211 'mntent.h',
212 'poll.h',
213 'pwd.h',
214 'sched.h',
215 'stdint.h',
216 'stdlib.h',
217 'string.h',
218 'strings.h',
219 'sys/auxv.h',
220 'sys/event.h',
221 'sys/filio.h',
222 'sys/inotify.h',
223 'sys/mkdev.h',
224 'sys/mntctl.h',
225 'sys/mnttab.h',
226 'sys/mount.h',
227 'sys/param.h',
228 'sys/resource.h',
229 'sys/select.h',
230 'sys/statfs.h',
231 'sys/stat.h',
232 'sys/statvfs.h',
233 'sys/sysctl.h',
234 'sys/time.h', # MSC does not come with this by default
235 'sys/times.h',
236 'sys/types.h',
237 'sys/uio.h',
238 'sys/vfs.h',
239 'sys/vfstab.h',
240 'sys/vmount.h',
241 'sys/wait.h',
242 'termios.h',
243 'unistd.h',
244 'values.h',
245 'xlocale.h',
246 ]
248 foreach h : headers
249 if cc.has_header(h)
250 define = 'HAVE_' + h.underscorify().to_upper()
251 glib_conf.set(define, 1)
252 glib_conf_prefix = glib_conf_prefix + '#define @0@ 1\n'.format(define)
253 endif
254 endforeach
256 # FIXME: Use cc.check_header from Meson 0.47.
257 # FreeBSD includes a malloc.h which always throw compilation error.
258 if cc.compiles('#include <malloc.h>', name : 'malloc.h')
259 glib_conf.set('HAVE_MALLOC_H', 1)
260 glib_conf_prefix = glib_conf_prefix + '#define HAVE_MALLOC_H 1\n'
261 endif
263 if cc.has_header('linux/netlink.h')
264 glib_conf.set('HAVE_NETLINK', 1)
265 endif
267 if glib_conf.has('HAVE_LOCALE_H')
268 if cc.has_header_symbol('locale.h', 'LC_MESSAGES')
269 glib_conf.set('HAVE_LC_MESSAGES', 1)
270 endif
271 endif
273 struct_stat_blkprefix = '''
274 #include <sys/types.h>
275 #include <sys/stat.h>
276 #ifdef HAVE_UNISTD_H
277 #include <unistd.h>
278 #endif
279 #ifdef HAVE_SYS_STATFS_H
280 #include <sys/statfs.h>
281 #endif
282 #ifdef HAVE_SYS_PARAM_H
283 #include <sys/param.h>
284 #endif
285 #ifdef HAVE_SYS_MOUNT_H
286 #include <sys/mount.h>
287 #endif
288 '''
290 struct_members = [
291 [ 'stat', 'st_mtimensec' ],
292 [ 'stat', 'st_mtim.tv_nsec' ],
293 [ 'stat', 'st_atimensec' ],
294 [ 'stat', 'st_atim.tv_nsec' ],
295 [ 'stat', 'st_ctimensec' ],
296 [ 'stat', 'st_ctim.tv_nsec' ],
297 [ 'stat', 'st_birthtime' ],
298 [ 'stat', 'st_birthtimensec' ],
299 [ 'stat', 'st_birthtim' ],
300 [ 'stat', 'st_birthtim.tv_nsec' ],
301 [ 'stat', 'st_blksize', struct_stat_blkprefix ],
302 [ 'stat', 'st_blocks', struct_stat_blkprefix ],
303 [ 'statfs', 'f_fstypename', struct_stat_blkprefix ],
304 [ 'statfs', 'f_bavail', struct_stat_blkprefix ],
305 [ 'dirent', 'd_type', '''#include <sys/types.h>
306 #include <dirent.h>''' ],
307 [ 'statvfs', 'f_basetype', '#include <sys/statvfs.h>' ],
308 [ 'statvfs', 'f_fstypename', '#include <sys/statvfs.h>' ],
309 [ 'tm', 'tm_gmtoff', '#include <time.h>' ],
310 [ 'tm', '__tm_gmtoff', '#include <time.h>' ],
311 ]
313 foreach m : struct_members
314 header_check_prefix = glib_conf_prefix
315 if m.length() == 3
316 header_check_prefix = header_check_prefix + m[2]
317 else
318 header_check_prefix = header_check_prefix + '#include <sys/stat.h>'
319 endif
320 if cc.has_member('struct ' + m[0], m[1], prefix : header_check_prefix)
321 define = 'HAVE_STRUCT_@0@_@1@'.format(m[0].to_upper(), m[1].underscorify().to_upper())
322 glib_conf.set(define, 1)
323 glib_conf_prefix = glib_conf_prefix + '#define @0@ 1\n'.format(define)
324 else
325 endif
326 endforeach
328 # Compiler flags
329 if cc.get_id() == 'gcc' or cc.get_id() == 'clang'
330 test_c_args = [
331 '-Wall',
332 '-Wduplicated-branches',
333 '-Wmisleading-indentation',
334 '-Wstrict-prototypes',
335 '-Wunused',
336 '-Werror=declaration-after-statement',
337 '-Werror=format=2',
338 '-Werror=format-security',
339 '-Werror=implicit-function-declaration',
340 '-Werror=init-self',
341 '-Werror=missing-include-dirs',
342 '-Werror=missing-prototypes',
343 '-Werror=pointer-arith',
344 ]
345 test_c_link_args = [
346 '-Wl,-z,nodelete',
347 ]
348 if get_option('bsymbolic_functions')
349 test_c_link_args += ['-Wl,-Bsymbolic-functions']
350 endif
351 else
352 test_c_args = []
353 test_c_link_args = []
354 endif
356 add_project_arguments(cc.get_supported_arguments(test_c_args), language: 'c')
358 # FIXME: We cannot build some of the GResource tests with -z nodelete, which
359 # means we cannot use that flag in add_project_link_arguments(), and must add
360 # it to the relevant targets manually. We do the same with -Bsymbolic-functions
361 # because that is what the autotools build did.
362 # See https://github.com/mesonbuild/meson/pull/3520 for a way to eventually
363 # improve this.
364 glib_link_flags = cc.get_supported_link_arguments(test_c_link_args)
366 # Windows Support (7+)
367 if host_system == 'windows'
368 glib_conf.set('_WIN32_WINNT', '0x0601')
369 endif
371 functions = [
372 'alloca',
373 'endmntent',
374 'endservent',
375 'fallocate',
376 'fchmod',
377 'fchown',
378 'fdwalk',
379 'fsync',
380 'getc_unlocked',
381 'getfsstat',
382 'getgrgid_r',
383 'getmntent_r',
384 'getpwuid_r',
385 'getresuid',
386 'getvfsstat',
387 'gmtime_r',
388 'hasmntopt',
389 'inotify_init1',
390 'issetugid',
391 'kevent',
392 'kqueue',
393 'lchmod',
394 'lchown',
395 'link',
396 'localtime_r',
397 'lstat',
398 'mbrtowc',
399 'memalign',
400 'mmap',
401 'newlocale',
402 'pipe2',
403 'poll',
404 'prlimit',
405 'readlink',
406 'recvmmsg',
407 'sendmmsg',
408 'setenv',
409 'setmntent',
410 'strerror_r',
411 'strnlen',
412 'strsignal',
413 'strtod_l',
414 'strtoll_l',
415 'strtoull_l',
416 'symlink',
417 'timegm',
418 'unsetenv',
419 'uselocale',
420 'utimes',
421 'valloc',
422 'vasprintf',
423 'vsnprintf',
424 'wcrtomb',
425 'wcslen',
426 'wcsnlen',
427 'sysctlbyname',
428 '_NSGetEnviron',
429 ]
431 if glib_conf.has('HAVE_SYS_STATVFS_H')
432 functions += ['statvfs']
433 else
434 have_func_statvfs = false
435 endif
436 if glib_conf.has('HAVE_SYS_STATFS_H') or glib_conf.has('HAVE_SYS_MOUNT_H')
437 functions += ['statfs']
438 else
439 have_func_statfs = false
440 endif
442 if host_system == 'windows'
443 iphlpapi_dep = cc.find_library('iphlpapi')
444 iphlpapi_funcs = ['if_nametoindex', 'if_indextoname']
445 foreach ifunc : iphlpapi_funcs
446 iphl_prefix = '''#define _WIN32_WINNT @0@
447 #include <winsock2.h>
448 #include <iphlpapi.h>'''.format(glib_conf.get('_WIN32_WINNT'))
449 if cc.has_function(ifunc,
450 prefix : iphl_prefix,
451 dependencies : iphlpapi_dep)
452 idefine = 'HAVE_' + ifunc.underscorify().to_upper()
453 glib_conf.set(idefine, 1)
454 glib_conf_prefix = glib_conf_prefix + '#define @0@ 1\n'.format(idefine)
455 set_variable('have_func_' + ifunc, true)
456 else
457 set_variable('have_func_' + ifunc, false)
458 endif
459 endforeach
460 else
461 functions += ['if_indextoname', 'if_nametoindex']
462 endif
464 # AIX splice is something else
465 if host_system != 'aix'
466 functions += ['splice']
467 endif
469 foreach f : functions
470 if cc.has_function(f)
471 define = 'HAVE_' + f.underscorify().to_upper()
472 glib_conf.set(define, 1)
473 glib_conf_prefix = glib_conf_prefix + '#define @0@ 1\n'.format(define)
474 set_variable('have_func_' + f, true)
475 else
476 set_variable('have_func_' + f, false)
477 endif
478 endforeach
480 # Check that stpcpy() is usable; must use header
481 if cc.has_function('stpcpy', prefix : '#include <string.h>')
482 glib_conf.set('HAVE_STPCPY', 1)
483 endif
485 # Check that posix_memalign() is usable; must use header
486 if cc.has_function('posix_memalign', prefix : '#include <stdlib.h>')
487 glib_conf.set('HAVE_POSIX_MEMALIGN', 1)
488 endif
490 # Check that posix_spawn() is usable; must use header
491 if cc.has_function('posix_spawn', prefix : '#include <spawn.h>')
492 glib_conf.set('HAVE_POSIX_SPAWN', 1)
493 endif
495 # Check whether strerror_r returns char *
496 if have_func_strerror_r
497 if cc.compiles('''#define _GNU_SOURCE
498 #include <string.h>
499 int func (void) {
500 char error_string[256];
501 char *ptr = strerror_r (-2, error_string, 256);
502 char c = *strerror_r (-2, error_string, 256);
503 return c != 0 && ptr != (void*) 0L;
504 }
505 ''',
506 name : 'strerror_r() returns char *')
507 glib_conf.set('STRERROR_R_CHAR_P', 1,
508 description: 'Defined if strerror_r returns char *')
509 endif
510 endif
512 # Special-case these functions that have alternative names on Windows/MSVC
513 if cc.has_function('snprintf') or cc.has_header_symbol('stdio.h', 'snprintf')
514 glib_conf.set('HAVE_SNPRINTF', 1)
515 glib_conf_prefix = glib_conf_prefix + '#define HAVE_SNPRINTF 1\n'
516 elif cc.has_function('_snprintf') or cc.has_header_symbol('stdio.h', '_snprintf')
517 hack_define = '1\n#define snprintf _snprintf'
518 glib_conf.set('HAVE_SNPRINTF', hack_define)
519 glib_conf_prefix = glib_conf_prefix + '#define HAVE_SNPRINTF ' + hack_define
520 endif
522 if cc.has_function('strcasecmp')
523 glib_conf.set('HAVE_STRCASECMP', 1)
524 glib_conf_prefix = glib_conf_prefix + '#define HAVE_STRCASECMP 1\n'
525 elif cc.has_function('_stricmp')
526 hack_define = '1\n#define strcasecmp _stricmp'
527 glib_conf.set('HAVE_STRCASECMP', hack_define)
528 glib_conf_prefix = glib_conf_prefix + '#define HAVE_STRCASECMP ' + hack_define
529 endif
531 if cc.has_function('strncasecmp')
532 glib_conf.set('HAVE_STRNCASECMP', 1)
533 glib_conf_prefix = glib_conf_prefix + '#define HAVE_STRNCASECMP 1\n'
534 elif cc.has_function('_strnicmp')
535 hack_define = '1\n#define strncasecmp _strnicmp'
536 glib_conf.set('HAVE_STRNCASECMP', hack_define)
537 glib_conf_prefix = glib_conf_prefix + '#define HAVE_STRNCASECMP ' + hack_define
538 endif
540 if cc.has_header_symbol('sys/sysmacros.h', 'major')
541 glib_conf.set('MAJOR_IN_SYSMACROS', 1)
542 elif cc.has_header_symbol('sys/mkdev.h', 'major')
543 glib_conf.set('MAJOR_IN_MKDEV', 1)
544 elif cc.has_header_symbol('sys/types.h', 'major')
545 glib_conf.set('MAJOR_IN_TYPES', 1)
546 endif
548 if cc.has_header_symbol('dlfcn.h', 'RTLD_LAZY')
549 glib_conf.set('HAVE_RTLD_LAZY', 1)
550 endif
552 if cc.has_header_symbol('dlfcn.h', 'RTLD_NOW')
553 glib_conf.set('HAVE_RTLD_NOW', 1)
554 endif
556 if cc.has_header_symbol('dlfcn.h', 'RTLD_GLOBAL')
557 glib_conf.set('HAVE_RTLD_GLOBAL', 1)
558 endif
560 # Check whether to use statfs or statvfs
561 # Some systems have both statfs and statvfs, pick the most "native" for these
562 if have_func_statfs and have_func_statvfs
563 # on solaris and irix, statfs doesn't even have the f_bavail field
564 if not glib_conf.has('HAVE_STRUCT_STATFS_F_BAVAIL')
565 have_func_statfs = false
566 else
567 # at least on linux, statfs is the actual syscall
568 have_func_statvfs = false
569 endif
570 endif
571 if have_func_statfs
572 glib_conf.set('USE_STATFS', 1)
573 stat_func_to_use = 'statfs'
574 elif have_func_statvfs
575 glib_conf.set('USE_STATVFS', 1)
576 stat_func_to_use = 'statvfs'
577 else
578 stat_func_to_use = 'neither'
579 endif
580 message('Checking whether to use statfs or statvfs .. ' + stat_func_to_use)
582 if host_system == 'linux'
583 if cc.has_function('mkostemp',
584 prefix: '''#define _GNU_SOURCE
585 #include <stdlib.h>''')
586 glib_conf.set('HAVE_MKOSTEMP', 1)
587 endif
588 endif
590 osx_ldflags = []
591 glib_have_os_x_9_or_later = false
592 glib_have_carbon = false
593 glib_have_cocoa = false
594 if host_system == 'darwin'
595 add_languages('objc')
596 objcc = meson.get_compiler('objc')
598 osx_ldflags += ['-Wl,-framework,CoreFoundation']
600 # Mac OS X Carbon support
601 glib_have_carbon = objcc.compiles('''#include <Carbon/Carbon.h>
602 #include <CoreServices/CoreServices.h>''',
603 name : 'Mac OS X Carbon support')
605 if glib_have_carbon
606 glib_conf.set('HAVE_CARBON', true)
607 osx_ldflags += '-Wl,-framework,Carbon'
608 glib_have_os_x_9_or_later = objcc.compiles('''#include <AvailabilityMacros.h>
609 #if MAC_OS_X_VERSION_MIN_REQUIRED < 1090
610 #error Compiling for minimum OS X version before 10.9
611 #endif''',
612 name : 'OS X 9 or later')
613 endif
615 # Mac OS X Cocoa support
616 glib_have_cocoa = objcc.compiles('''#include <Cocoa/Cocoa.h>
617 #ifdef GNUSTEP_BASE_VERSION
618 #error "Detected GNUstep, not Cocoa"
619 #endif''',
620 name : 'Mac OS X Cocoa support')
622 if glib_have_cocoa
623 glib_conf.set('HAVE_COCOA', true)
624 osx_ldflags += ['-Wl,-framework,Foundation', '-Wl,-framework,AppKit']
625 endif
627 # FIXME: libgio mix C and objC source files and there is no way to reliably
628 # know which language flags it's going to use to link. Add to both languages
629 # for now. See https://github.com/mesonbuild/meson/issues/3585.
630 add_project_link_arguments(osx_ldflags, language : ['objc', 'c'])
631 endif
633 # Check for futex(2)
634 if cc.links('''#include <linux/futex.h>
635 #include <sys/syscall.h>
636 #include <unistd.h>
637 int main (int argc, char ** argv) {
638 syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
639 return 0;
640 }''', name : 'futex(2) system call')
641 glib_conf.set('HAVE_FUTEX', 1)
642 endif
644 # Check for eventfd(2)
645 if cc.links('''#include <sys/eventfd.h>
646 #include <unistd.h>
647 int main (int argc, char ** argv) {
648 eventfd (0, EFD_CLOEXEC);
649 return 0;
650 }''', name : 'eventfd(2) system call')
651 glib_conf.set('HAVE_EVENTFD', 1)
652 endif
654 clock_gettime_test_code = '''
655 #include <time.h>
656 struct timespec t;
657 int main (int argc, char ** argv) {
658 return clock_gettime(CLOCK_REALTIME, &t);
659 }'''
660 librt = []
661 if cc.links(clock_gettime_test_code, name : 'clock_gettime')
662 glib_conf.set('HAVE_CLOCK_GETTIME', 1)
663 elif cc.links(clock_gettime_test_code, args : '-lrt', name : 'clock_gettime in librt')
664 glib_conf.set('HAVE_CLOCK_GETTIME', 1)
665 librt = cc.find_library('rt')
666 endif
668 # if statfs() takes 2 arguments (Posix) or 4 (Solaris)
669 if have_func_statfs
670 if cc.compiles(glib_conf_prefix + '''
671 #include <unistd.h>
672 #ifdef HAVE_SYS_PARAM_H
673 #include <sys/param.h>
674 #endif
675 #ifdef HAVE_SYS_VFS_H
676 #include <sys/vfs.h>
677 #endif
678 #ifdef HAVE_SYS_MOUNT_H
679 #include <sys/mount.h>
680 #endif
681 #ifdef HAVE_SYS_STATFS_H
682 #include <sys/statfs.h>
683 #endif
684 void some_func (void) {
685 struct statfs st;
686 statfs("/", &st);
687 }''', name : 'number of arguments to statfs() (n=2)')
688 glib_conf.set('STATFS_ARGS', 2)
689 elif cc.compiles(glib_conf_prefix + '''
690 #include <unistd.h>
691 #ifdef HAVE_SYS_PARAM_H
692 #include <sys/param.h>
693 #endif
694 #ifdef HAVE_SYS_VFS_H
695 #include <sys/vfs.h>
696 #endif
697 #ifdef HAVE_SYS_MOUNT_H
698 #include <sys/mount.h>
699 #endif
700 #ifdef HAVE_SYS_STATFS_H
701 #include <sys/statfs.h>
702 #endif
703 void some_func (void) {
704 struct statfs st;
705 statfs("/", &st, sizeof (st), 0);
706 }''', name : 'number of arguments to statfs() (n=4)')
707 glib_conf.set('STATFS_ARGS', 4)
708 else
709 error('Unable to determine number of arguments to statfs()')
710 endif
711 endif
713 # open takes O_DIRECTORY as an option
714 #AC_MSG_CHECKING([])
715 if cc.compiles('''#include <fcntl.h>
716 #include <sys/types.h>
717 #include <sys/stat.h>],
718 void some_func (void) {
719 open(0, O_DIRECTORY, 0);
720 }''', name : 'open() option O_DIRECTORY')
721 glib_conf.set('HAVE_OPEN_O_DIRECTORY', 1)
722 endif
724 # Check whether there is a vsnprintf() function with C99 semantics installed.
725 # AC_FUNC_VSNPRINTF_C99
726 # Check whether there is a snprintf() function with C99 semantics installed.
727 # AC_FUNC_SNPRINTF_C99
729 have_good_vsnprintf = false
730 have_good_snprintf = false
732 if host_system == 'windows' and cc.get_id() == 'msvc'
733 # Unfortunately the Visual Studio 2015+ implementations of C99-style
734 # snprintf and vsnprintf don't seem to be quite good enough.
735 # (Sorry, I don't know exactly what is the problem,
736 # but it is related to floating point formatting and decimal point vs. comma.)
737 # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
738 # rigorous enough to notice, though.
739 glib_conf.set('HAVE_C99_SNPRINTF', false)
740 glib_conf.set('HAVE_C99_VSNPRINTF', false)
741 else
742 vsnprintf_c99_test_code = '''
743 #include <stdio.h>
744 #include <stdarg.h>
746 int
747 doit(char * s, ...)
748 {
749 char buffer[32];
750 va_list args;
751 int r;
753 va_start(args, s);
754 r = vsnprintf(buffer, 5, s, args);
755 va_end(args);
757 if (r != 7)
758 exit(1);
760 /* AIX 5.1 and Solaris seems to have a half-baked vsnprintf()
761 implementation. The above will return 7 but if you replace
762 the size of the buffer with 0, it borks! */
763 va_start(args, s);
764 r = vsnprintf(buffer, 0, s, args);
765 va_end(args);
767 if (r != 7)
768 exit(1);
770 exit(0);
771 }
773 int
774 main(void)
775 {
776 doit("1234567");
777 exit(1);
778 }'''
780 if cc_can_run
781 rres = cc.run(vsnprintf_c99_test_code, name : 'C99 vsnprintf')
782 if rres.compiled() and rres.returncode() == 0
783 glib_conf.set('HAVE_C99_VSNPRINTF', 1)
784 have_good_vsnprintf = true
785 endif
786 else
787 have_good_vsnprintf = meson.get_cross_property('have_c99_vsnprintf', false)
788 glib_conf.set('HAVE_C99_VSNPRINTF', have_good_vsnprintf)
789 endif
791 snprintf_c99_test_code = '''
792 #include <stdio.h>
793 #include <stdarg.h>
795 int
796 doit()
797 {
798 char buffer[32];
799 va_list args;
800 int r;
802 r = snprintf(buffer, 5, "1234567");
804 if (r != 7)
805 exit(1);
807 r = snprintf(buffer, 0, "1234567");
809 if (r != 7)
810 exit(1);
812 r = snprintf(NULL, 0, "1234567");
814 if (r != 7)
815 exit(1);
817 exit(0);
818 }
820 int
821 main(void)
822 {
823 doit();
824 exit(1);
825 }'''
827 if cc_can_run
828 rres = cc.run(snprintf_c99_test_code, name : 'C99 snprintf')
829 if rres.compiled() and rres.returncode() == 0
830 glib_conf.set('HAVE_C99_SNPRINTF', 1)
831 have_good_snprintf = true
832 endif
833 else
834 have_good_snprintf = meson.get_cross_property('have_c99_snprintf', false)
835 glib_conf.set('HAVE_C99_SNPRINTF', have_good_snprintf)
836 endif
837 endif
839 if host_system == 'windows'
840 glib_conf.set_quoted('EXEEXT', '.exe')
841 else
842 glib_conf.set('EXEEXT', '')
843 endif
845 if have_good_vsnprintf and have_good_snprintf
846 # Our printf is 'good' only if vsnpintf()/snprintf() supports C99 well enough
847 glib_conf.set('HAVE_GOOD_PRINTF', 1) # FIXME: Check for HAVE_UNIX98_PRINTF?
848 else
849 glib_conf.set('HAVE_VASPRINTF', 1)
850 endif
852 # Check whether the printf() family supports Unix98 %n$ positional parameters
853 # AC_FUNC_PRINTF_UNIX98
854 # Nothing uses HAVE_UNIX98_PRINTF
857 # Check for nl_langinfo and CODESET
858 # FIXME: Check for HAVE_BIND_TEXTDOMAIN_CODESET
859 if cc.links('''#include <langinfo.h>
860 int main (int argc, char ** argv) {
861 char *codeset = nl_langinfo (CODESET);
862 return 0;
863 }''', name : 'nl_langinfo and CODESET')
864 glib_conf.set('HAVE_LANGINFO_CODESET', 1)
865 glib_conf.set('HAVE_CODESET', 1)
866 endif
868 # Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
869 if cc.links('''#include <langinfo.h>
870 int main (int argc, char ** argv) {
871 char *str;
872 str = nl_langinfo (PM_STR);
873 str = nl_langinfo (D_T_FMT);
874 str = nl_langinfo (D_FMT);
875 str = nl_langinfo (T_FMT);
876 str = nl_langinfo (T_FMT_AMPM);
877 str = nl_langinfo (MON_1);
878 str = nl_langinfo (ABMON_12);
879 str = nl_langinfo (DAY_1);
880 str = nl_langinfo (ABDAY_7);
881 return 0;
882 }''', name : 'nl_langinfo (PM_STR)')
883 glib_conf.set('HAVE_LANGINFO_TIME', 1)
884 endif
885 if cc.links('''#include <langinfo.h>
886 int main (int argc, char ** argv) {
887 char *str;
888 str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
889 str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
890 str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
891 str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
892 str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
893 str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
894 str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
895 str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
896 str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
897 str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);
898 return 0;
899 }''', name : 'nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)')
900 glib_conf.set('HAVE_LANGINFO_OUTDIGIT', 1)
901 endif
903 # Check for nl_langinfo and alternative month names
904 if cc.links('''#ifndef _GNU_SOURCE
905 # define _GNU_SOURCE
906 #endif
907 #include <langinfo.h>
908 int main (int argc, char ** argv) {
909 char *str;
910 str = nl_langinfo (ALTMON_1);
911 str = nl_langinfo (ALTMON_2);
912 str = nl_langinfo (ALTMON_3);
913 str = nl_langinfo (ALTMON_4);
914 str = nl_langinfo (ALTMON_5);
915 str = nl_langinfo (ALTMON_6);
916 str = nl_langinfo (ALTMON_7);
917 str = nl_langinfo (ALTMON_8);
918 str = nl_langinfo (ALTMON_9);
919 str = nl_langinfo (ALTMON_10);
920 str = nl_langinfo (ALTMON_11);
921 str = nl_langinfo (ALTMON_12);
922 return 0;
923 }''', name : 'nl_langinfo (ALTMON_n)')
924 glib_conf.set('HAVE_LANGINFO_ALTMON', 1)
925 endif
927 # Check for nl_langinfo and abbreviated alternative month names
928 if cc.links('''#ifndef _GNU_SOURCE
929 # define _GNU_SOURCE
930 #endif
931 #include <langinfo.h>
932 int main (int argc, char ** argv) {
933 char *str;
934 str = nl_langinfo (_NL_ALTMON_1);
935 str = nl_langinfo (_NL_ALTMON_2);
936 str = nl_langinfo (_NL_ALTMON_3);
937 str = nl_langinfo (_NL_ALTMON_4);
938 str = nl_langinfo (_NL_ALTMON_5);
939 str = nl_langinfo (_NL_ALTMON_6);
940 str = nl_langinfo (_NL_ALTMON_7);
941 str = nl_langinfo (_NL_ALTMON_8);
942 str = nl_langinfo (_NL_ALTMON_9);
943 str = nl_langinfo (_NL_ALTMON_10);
944 str = nl_langinfo (_NL_ALTMON_11);
945 str = nl_langinfo (_NL_ALTMON_12);
946 return 0;
947 }''', name : 'nl_langinfo (_NL_ALTMON_n)')
948 glib_conf.set('HAVE_LANGINFO_ABALTMON', 1)
949 endif
951 # Check if C compiler supports the 'signed' keyword
952 if not cc.compiles('''signed char x;''', name : 'signed')
953 glib_conf.set('signed', '/* NOOP */')
954 endif
956 # Check if the ptrdiff_t type exists
957 if cc.has_header_symbol('stddef.h', 'ptrdiff_t')
958 glib_conf.set('HAVE_PTRDIFF_T', 1)
959 endif
961 # Check for sig_atomic_t type
962 if cc.links('''#include <signal.h>
963 #include <sys/types.h>
964 sig_atomic_t val = 42;
965 int main (int argc, char ** argv) {
966 return val == 42 ? 0 : 1;
967 }''', name : 'sig_atomic_t')
968 glib_conf.set('HAVE_SIG_ATOMIC_T', 1)
969 endif
971 # Check if 'long long' works
972 # jm_AC_TYPE_LONG_LONG
973 if cc.compiles('''long long ll = 1LL;
974 int i = 63;
975 int some_func (void) {
976 long long llmax = (long long) -1;
977 return ll << i | ll >> i | llmax / ll | llmax % ll;
978 }''', name : 'long long')
979 glib_conf.set('HAVE_LONG_LONG', 1)
980 have_long_long = true
981 else
982 have_long_long = false
983 endif
985 # Test whether the compiler supports the 'long double' type.
986 if cc.compiles('''/* The Stardent Vistra knows sizeof(long double), but does not support it. */
987 long double foo = 0.0;
988 /* On Ultrix 4.3 cc, long double is 4 and double is 8. */
989 int array [2*(sizeof(long double) >= sizeof(double)) - 1];''',
990 name : 'long double')
991 glib_conf.set('HAVE_LONG_DOUBLE', 1)
992 endif
994 # Test whether <stddef.h> has the 'wchar_t' type.
995 if cc.has_header_symbol('stddef.h', 'wchar_t')
996 glib_conf.set('HAVE_WCHAR_T', 1)
997 endif
999 # Test whether <wchar.h> has the 'wint_t' type.
1000 if cc.has_header_symbol('wchar.h', 'wint_t')
1001 glib_conf.set('HAVE_WINT_T', 1)
1002 endif
1004 found_uintmax_t = false
1006 # Define HAVE_INTTYPES_H_WITH_UINTMAX if <inttypes.h> exists,
1007 # doesn't clash with <sys/types.h>, and declares uintmax_t.
1008 # jm_AC_HEADER_INTTYPES_H
1009 if cc.compiles('''#include <sys/types.h>
1010 #include <inttypes.h>
1011 void some_func (void) {
1012 uintmax_t i = (uintmax_t) -1;
1013 }''', name : 'uintmax_t in inttypes.h')
1014 glib_conf.set('HAVE_INTTYPES_H_WITH_UINTMAX', 1)
1015 found_uintmax_t = true
1016 endif
1018 # Define HAVE_STDINT_H_WITH_UINTMAX if <stdint.h> exists,
1019 # doesn't clash with <sys/types.h>, and declares uintmax_t.
1020 # jm_AC_HEADER_STDINT_H
1021 if cc.compiles('''#include <sys/types.h>
1022 #include <stdint.h>
1023 void some_func (void) {
1024 uintmax_t i = (uintmax_t) -1;
1025 }''', name : 'uintmax_t in stdint.h')
1026 glib_conf.set('HAVE_STDINT_H_WITH_UINTMAX', 1)
1027 found_uintmax_t = true
1028 endif
1030 # Define intmax_t to 'long' or 'long long'
1031 # if it is not already defined in <stdint.h> or <inttypes.h>.
1032 # For simplicity, we assume that a header file defines 'intmax_t' if and
1033 # only if it defines 'uintmax_t'.
1034 if found_uintmax_t
1035 glib_conf.set('HAVE_INTMAX_T', 1)
1036 elif have_long_long
1037 glib_conf.set('intmax_t', 'long long')
1038 else
1039 glib_conf.set('intmax_t', 'long')
1040 endif
1042 char_size = cc.sizeof('char')
1043 short_size = cc.sizeof('short')
1044 int_size = cc.sizeof('int')
1045 voidp_size = cc.sizeof('void*')
1046 long_size = cc.sizeof('long')
1047 if have_long_long
1048 long_long_size = cc.sizeof('long long')
1049 else
1050 long_long_size = 0
1051 endif
1052 sizet_size = cc.sizeof('size_t')
1053 if cc.get_id() == 'msvc'
1054 ssizet_size = cc.sizeof('SSIZE_T', prefix : '#include <BaseTsd.h>')
1055 else
1056 ssizet_size = cc.sizeof('ssize_t')
1057 endif
1059 int64_m = 'll'
1060 char_align = cc.alignment('char')
1061 short_align = cc.alignment('short')
1062 int_align = cc.alignment('int')
1063 voidp_align = cc.alignment('void*')
1064 long_align = cc.alignment('long')
1065 long_long_align = cc.alignment('long long')
1066 # NOTE: We don't check for size of __int64 because long long is guaranteed to
1067 # be 64-bit in C99, and it is available on all supported compilers
1068 sizet_align = cc.alignment('size_t')
1070 glib_conf.set('ALIGNOF_UNSIGNED_LONG', long_align)
1072 glib_conf.set('SIZEOF_CHAR', char_size)
1073 glib_conf.set('SIZEOF_INT', int_size)
1074 glib_conf.set('SIZEOF_SHORT', short_size)
1075 glib_conf.set('SIZEOF_LONG', long_size)
1076 glib_conf.set('SIZEOF_LONG_LONG', long_long_size)
1077 glib_conf.set('SIZEOF_SIZE_T', sizet_size)
1078 glib_conf.set('SIZEOF_SSIZE_T', ssizet_size)
1079 glib_conf.set('SIZEOF_VOID_P', voidp_size)
1081 if short_size == 2
1082 gint16 = 'short'
1083 gint16_modifier='h'
1084 gint16_format='hi'
1085 guint16_format='hu'
1086 elif int_size == 2
1087 gint16 = 'int'
1088 gint16_modifier=''
1089 gint16_format='i'
1090 guint16_format='u'
1091 else
1092 error('Compiler provides no native 16-bit integer type')
1093 endif
1094 glibconfig_conf.set('gint16', gint16)
1095 glibconfig_conf.set_quoted('gint16_modifier', gint16_modifier)
1096 glibconfig_conf.set_quoted('gint16_format', gint16_format)
1097 glibconfig_conf.set_quoted('guint16_format', guint16_format)
1099 if short_size == 4
1100 gint32 = 'short'
1101 gint32_modifier='h'
1102 gint32_format='hi'
1103 guint32_format='hu'
1104 guint32_align = short_align
1105 elif int_size == 4
1106 gint32 = 'int'
1107 gint32_modifier=''
1108 gint32_format='i'
1109 guint32_format='u'
1110 guint32_align = int_align
1111 elif long_size == 4
1112 gint32 = 'long'
1113 gint32_modifier='l'
1114 gint32_format='li'
1115 guint32_format='lu'
1116 guint32_align = long_align
1117 else
1118 error('Compiler provides no native 32-bit integer type')
1119 endif
1120 glibconfig_conf.set('gint32', gint32)
1121 glibconfig_conf.set_quoted('gint32_modifier', gint32_modifier)
1122 glibconfig_conf.set_quoted('gint32_format', gint32_format)
1123 glibconfig_conf.set_quoted('guint32_format', guint32_format)
1124 glib_conf.set('ALIGNOF_GUINT32', guint32_align)
1126 if int_size == 8
1127 gint64 = 'int'
1128 gint64_modifier=''
1129 gint64_format='i'
1130 guint64_format='u'
1131 glib_extension=''
1132 gint64_constant='(val)'
1133 guint64_constant='(val)'
1134 guint64_align = int_align
1135 elif long_size == 8
1136 gint64 = 'long'
1137 glib_extension=''
1138 gint64_modifier='l'
1139 gint64_format='li'
1140 guint64_format='lu'
1141 gint64_constant='(val##L)'
1142 guint64_constant='(val##UL)'
1143 guint64_align = long_align
1144 elif long_long_size == 8
1145 gint64 = 'long long'
1146 glib_extension='G_GNUC_EXTENSION '
1147 gint64_modifier=int64_m
1148 gint64_format=int64_m + 'i'
1149 guint64_format=int64_m + 'u'
1150 gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1151 guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
1152 guint64_align = long_long_align
1153 else
1154 error('Compiler provides no native 64-bit integer type')
1155 endif
1156 glibconfig_conf.set('glib_extension', glib_extension)
1157 glibconfig_conf.set('gint64', gint64)
1158 glibconfig_conf.set_quoted('gint64_modifier', gint64_modifier)
1159 glibconfig_conf.set_quoted('gint64_format', gint64_format)
1160 glibconfig_conf.set_quoted('guint64_format', guint64_format)
1161 glibconfig_conf.set('gint64_constant', gint64_constant)
1162 glibconfig_conf.set('guint64_constant', guint64_constant)
1163 glib_conf.set('ALIGNOF_GUINT64', guint64_align)
1165 if host_system == 'windows'
1166 glibconfig_conf.set('g_pid_type', 'void*')
1167 glibconfig_conf.set_quoted('g_pid_format', 'p')
1168 if host_machine.cpu_family() == 'x86_64'
1169 glibconfig_conf.set_quoted('g_pollfd_format', '%#' + int64_m + 'x')
1170 else
1171 glibconfig_conf.set_quoted('g_pollfd_format', '%#x')
1172 endif
1173 glibconfig_conf.set('g_dir_separator', '\\\\')
1174 glibconfig_conf.set('g_searchpath_separator', ';')
1175 else
1176 glibconfig_conf.set('g_pid_type', 'int')
1177 glibconfig_conf.set_quoted('g_pid_format', 'i')
1178 glibconfig_conf.set_quoted('g_pollfd_format', '%d')
1179 glibconfig_conf.set('g_dir_separator', '/')
1180 glibconfig_conf.set('g_searchpath_separator', ':')
1181 endif
1183 if sizet_size == short_size
1184 glibconfig_conf.set('glib_size_type_define', 'short')
1185 glibconfig_conf.set_quoted('gsize_modifier', 'h')
1186 glibconfig_conf.set_quoted('gssize_modifier', 'h')
1187 glibconfig_conf.set_quoted('gsize_format', 'hu')
1188 glibconfig_conf.set_quoted('gssize_format', 'hi')
1189 glibconfig_conf.set('glib_msize_type', 'SHRT')
1190 elif sizet_size == int_size
1191 glibconfig_conf.set('glib_size_type_define', 'int')
1192 glibconfig_conf.set_quoted('gsize_modifier', '')
1193 glibconfig_conf.set_quoted('gssize_modifier', '')
1194 glibconfig_conf.set_quoted('gsize_format', 'u')
1195 glibconfig_conf.set_quoted('gssize_format', 'i')
1196 glibconfig_conf.set('glib_msize_type', 'INT')
1197 elif sizet_size == long_size
1198 glibconfig_conf.set('glib_size_type_define', 'long')
1199 glibconfig_conf.set_quoted('gsize_modifier', 'l')
1200 glibconfig_conf.set_quoted('gssize_modifier', 'l')
1201 glibconfig_conf.set_quoted('gsize_format', 'lu')
1202 glibconfig_conf.set_quoted('gssize_format', 'li')
1203 glibconfig_conf.set('glib_msize_type', 'LONG')
1204 elif sizet_size == long_long_size
1205 glibconfig_conf.set('glib_size_type_define', 'long long')
1206 glibconfig_conf.set_quoted('gsize_modifier', int64_m)
1207 glibconfig_conf.set_quoted('gssize_modifier', int64_m)
1208 glibconfig_conf.set_quoted('gsize_format', int64_m + 'u')
1209 glibconfig_conf.set_quoted('gssize_format', int64_m + 'i')
1210 glibconfig_conf.set('glib_msize_type', 'INT64')
1211 else
1212 error('Could not determine size of size_t.')
1213 endif
1215 if voidp_size == int_size
1216 glibconfig_conf.set('glib_intptr_type_define', 'int')
1217 glibconfig_conf.set_quoted('gintptr_modifier', '')
1218 glibconfig_conf.set_quoted('gintptr_format', 'i')
1219 glibconfig_conf.set_quoted('guintptr_format', 'u')
1220 glibconfig_conf.set('glib_gpi_cast', '(gint)')
1221 glibconfig_conf.set('glib_gpui_cast', '(guint)')
1222 elif voidp_size == long_size
1223 glibconfig_conf.set('glib_intptr_type_define', 'long')
1224 glibconfig_conf.set_quoted('gintptr_modifier', 'l')
1225 glibconfig_conf.set_quoted('gintptr_format', 'li')
1226 glibconfig_conf.set_quoted('guintptr_format', 'lu')
1227 glibconfig_conf.set('glib_gpi_cast', '(glong)')
1228 glibconfig_conf.set('glib_gpui_cast', '(gulong)')
1229 elif voidp_size == long_long_size
1230 glibconfig_conf.set('glib_intptr_type_define', 'long long')
1231 glibconfig_conf.set_quoted('gintptr_modifier', int64_m)
1232 glibconfig_conf.set_quoted('gintptr_format', int64_m + 'i')
1233 glibconfig_conf.set_quoted('guintptr_format', int64_m + 'u')
1234 glibconfig_conf.set('glib_gpi_cast', '(gint64)')
1235 glibconfig_conf.set('glib_gpui_cast', '(guint64)')
1236 else
1237 error('Could not determine size of void *')
1238 endif
1240 if long_size != 8 and long_long_size != 8 and int_size != 8
1241 error('GLib requires a 64-bit type. You might want to consider using the GNU C compiler.')
1242 endif
1244 glibconfig_conf.set('gintbits', int_size * 8)
1245 glibconfig_conf.set('glongbits', long_size * 8)
1246 glibconfig_conf.set('gsizebits', sizet_size * 8)
1247 glibconfig_conf.set('gssizebits', ssizet_size * 8)
1249 # FIXME: maybe meson should tell us the libsuffix?
1250 if host_system == 'windows'
1251 g_module_suffix = 'dll'
1252 elif host_system == 'darwin'
1253 g_module_suffix = 'dylib'
1254 else
1255 g_module_suffix = 'so'
1256 endif
1257 glibconfig_conf.set('g_module_suffix', g_module_suffix)
1259 glibconfig_conf.set('GLIB_MAJOR_VERSION', major_version)
1260 glibconfig_conf.set('GLIB_MINOR_VERSION', minor_version)
1261 glibconfig_conf.set('GLIB_MICRO_VERSION', micro_version)
1262 glibconfig_conf.set('GLIB_VERSION', glib_version)
1264 glibconfig_conf.set('glib_void_p', voidp_size)
1265 glibconfig_conf.set('glib_long', long_size)
1266 glibconfig_conf.set('glib_size_t', sizet_size)
1267 glibconfig_conf.set('glib_ssize_t', ssizet_size)
1268 if host_machine.endian() == 'big'
1269 glibconfig_conf.set('g_byte_order', 'G_BIG_ENDIAN')
1270 glibconfig_conf.set('g_bs_native', 'BE')
1271 glibconfig_conf.set('g_bs_alien', 'LE')
1272 else
1273 glibconfig_conf.set('g_byte_order', 'G_LITTLE_ENDIAN')
1274 glibconfig_conf.set('g_bs_native', 'LE')
1275 glibconfig_conf.set('g_bs_alien', 'BE')
1276 endif
1278 # === va_copy checks ===
1279 # we currently check for all three va_copy possibilities, so we get
1280 # all results in config.log for bug reports.
1282 va_copy_func = ''
1283 foreach try_func : [ '__va_copy', 'va_copy' ]
1284 if cc.compiles('''#include <stdarg.h>
1285 #include <stdlib.h>
1286 #ifdef _MSC_VER
1287 # include "msvc_recommended_pragmas.h"
1288 #endif
1289 void f (int i, ...) {
1290 va_list args1, args2;
1291 va_start (args1, i);
1292 @0@ (args2, args1);
1293 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1294 exit (1);
1295 va_end (args1); va_end (args2);
1296 }
1297 int main() {
1298 f (0, 42);
1299 return 0;
1300 }'''.format(try_func),
1301 name : try_func + ' check')
1302 va_copy_func = try_func
1303 endif
1304 endforeach
1305 if va_copy_func != ''
1306 glib_conf.set('G_VA_COPY', va_copy_func)
1307 glib_vacopy = '#define G_VA_COPY ' + va_copy_func
1308 else
1309 glib_vacopy = '/* #undef G_VA_COPY */'
1310 endif
1312 va_list_val_copy_prog = '''
1313 #include <stdarg.h>
1314 #include <stdlib.h>
1315 void f (int i, ...) {
1316 va_list args1, args2;
1317 va_start (args1, i);
1318 args2 = args1;
1319 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1320 exit (1);
1321 va_end (args1); va_end (args2);
1322 }
1323 int main() {
1324 f (0, 42);
1325 return 0;
1326 }'''
1328 if cc_can_run
1329 rres = cc.run(va_list_val_copy_prog, name : 'va_lists can be copied as values')
1330 glib_va_val_copy = rres.returncode() == 0
1331 else
1332 glib_va_val_copy = meson.get_cross_property('va_val_copy', true)
1333 endif
1334 if not glib_va_val_copy
1335 glib_vacopy = glib_vacopy + '\n#define G_VA_COPY_AS_ARRAY 1'
1336 glib_conf.set('G_VA_COPY_AS_ARRAY', 1)
1337 endif
1338 glibconfig_conf.set('glib_vacopy', glib_vacopy)
1340 # check for flavours of varargs macros
1341 g_have_iso_c_varargs = cc.compiles('''
1342 void some_func (void) {
1343 int a(int p1, int p2, int p3);
1344 #define call_a(...) a(1,__VA_ARGS__)
1345 call_a(2,3);
1346 }''', name : 'ISO C99 varargs macros in C')
1348 if g_have_iso_c_varargs
1349 glibconfig_conf.set('g_have_iso_c_varargs', '''
1350 #ifndef __cplusplus
1351 # define G_HAVE_ISO_VARARGS 1
1352 #endif''')
1353 endif
1355 g_have_iso_cxx_varargs = cxx.compiles('''
1356 void some_func (void) {
1357 int a(int p1, int p2, int p3);
1358 #define call_a(...) a(1,__VA_ARGS__)
1359 call_a(2,3);
1360 }''', name : 'ISO C99 varargs macros in C++')
1362 if g_have_iso_cxx_varargs
1363 glibconfig_conf.set('g_have_iso_cxx_varargs', '''
1364 #ifdef __cplusplus
1365 # define G_HAVE_ISO_VARARGS 1
1366 #endif''')
1367 endif
1369 g_have_gnuc_varargs = cc.compiles('''
1370 void some_func (void) {
1371 int a(int p1, int p2, int p3);
1372 #define call_a(params...) a(1,params)
1373 call_a(2,3);
1374 }''', name : 'GNUC varargs macros')
1376 if cc.has_header('alloca.h')
1377 glibconfig_conf.set('GLIB_HAVE_ALLOCA_H', true)
1378 endif
1379 has_syspoll = cc.has_header('sys/poll.h')
1380 has_systypes = cc.has_header('sys/types.h')
1381 if has_syspoll
1382 glibconfig_conf.set('GLIB_HAVE_SYS_POLL_H', true)
1383 endif
1384 has_winsock2 = cc.has_header('winsock2.h')
1386 if has_syspoll and has_systypes
1387 poll_includes = '''
1388 #include<sys/poll.h>
1389 #include<sys/types.h>'''
1390 elif has_winsock2
1391 poll_includes = '''
1392 #define _WIN32_WINNT @0@
1393 #include <winsock2.h>'''.format(glib_conf.get('_WIN32_WINNT'))
1394 else
1395 # FIXME?
1396 error('FIX POLL* defines')
1397 endif
1399 poll_defines = [
1400 [ 'POLLIN', 'g_pollin', 1 ],
1401 [ 'POLLOUT', 'g_pollout', 4 ],
1402 [ 'POLLPRI', 'g_pollpri', 2 ],
1403 [ 'POLLERR', 'g_pollerr', 8 ],
1404 [ 'POLLHUP', 'g_pollhup', 16 ],
1405 [ 'POLLNVAL', 'g_pollnval', 32 ],
1406 ]
1408 if has_syspoll and has_systypes
1409 foreach d : poll_defines
1410 val = cc.compute_int(d[0], prefix: poll_includes)
1411 glibconfig_conf.set(d[1], val)
1412 endforeach
1413 elif has_winsock2
1414 # Due to a missed bug in configure.ac the poll test
1415 # never succeeded on Windows and used some pre-defined
1416 # values as a fallback. Keep using them to maintain
1417 # ABI compatibility with autotools builds of glibs
1418 # and with *any* glib-using code compiled against them,
1419 # since these values end up in a public header glibconfig.h.
1420 foreach d : poll_defines
1421 glibconfig_conf.set(d[1], d[2])
1422 endforeach
1423 endif
1425 # Internet address families
1426 # FIXME: what about Cygwin (G_WITH_CYGWIN)
1427 if host_system == 'windows'
1428 inet_includes = '''
1429 #include <winsock2.h>'''
1430 else
1431 inet_includes = '''
1432 #include <sys/types.h>
1433 #include <sys/socket.h>'''
1434 endif
1436 inet_defines = [
1437 [ 'AF_UNIX', 'g_af_unix' ],
1438 [ 'AF_INET', 'g_af_inet' ],
1439 [ 'AF_INET6', 'g_af_inet6' ],
1440 [ 'MSG_OOB', 'g_msg_oob' ],
1441 [ 'MSG_PEEK', 'g_msg_peek' ],
1442 [ 'MSG_DONTROUTE', 'g_msg_dontroute' ],
1443 ]
1444 foreach d : inet_defines
1445 val = cc.compute_int(d[0], prefix: inet_includes)
1446 glibconfig_conf.set(d[1], val)
1447 endforeach
1449 glibconfig_conf.set('GLIB_USING_SYSTEM_PRINTF', true) # FIXME!
1451 # We need a more robust approach here...
1452 host_cpu_family = host_machine.cpu_family()
1453 if host_cpu_family == 'x86' or host_cpu_family == 'x86_64' or host_cpu_family == 's390' or host_cpu_family == 's390x' or host_cpu_family.startswith('arm') or host_cpu_family.startswith('crisv32') or host_cpu_family.startswith('etrax')
1454 glib_memory_barrier_needed = false
1455 elif host_cpu_family.startswith('sparc') or host_cpu_family.startswith('alpha') or host_cpu_family.startswith('powerpc') or host_cpu_family == 'ia64'
1456 glib_memory_barrier_needed = true
1457 else
1458 warning('Unknown host cpu: ' + host_cpu_family)
1459 glib_memory_barrier_needed = true
1460 endif
1461 glibconfig_conf.set('G_ATOMIC_OP_MEMORY_BARRIER_NEEDED', glib_memory_barrier_needed)
1463 # We need to decide at configure time if GLib will use real atomic
1464 # operations ("lock free") or emulated ones with a mutex. This is
1465 # because we must put this information in glibconfig.h so we know if
1466 # it is safe or not to inline using compiler intrinsics directly from
1467 # the header.
1468 #
1469 # We also publish the information via G_ATOMIC_LOCK_FREE in case the
1470 # user is interested in knowing if they can use the atomic ops across
1471 # processes.
1472 #
1473 # We can currently support the atomic ops natively when building GLib
1474 # with recent versions of GCC or MSVC.
1475 #
1476 # Note that the atomic ops are only available with GCC on x86 when
1477 # using -march=i486 or higher. If we detect that the atomic ops are
1478 # not available but would be available given the right flags, we want
1479 # to abort and advise the user to fix their CFLAGS. It's better to do
1480 # that then to silently fall back on emulated atomic ops just because
1481 # the user had the wrong build environment.
1482 atomictest = '''int main() {
1483 volatile int atomic = 2;
1484 __sync_bool_compare_and_swap (&atomic, 2, 3);
1485 return 0;
1486 }
1487 '''
1489 atomicdefine = '''
1490 #ifndef __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4
1491 #error "compiler has atomic ops, but doesn't define __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4"
1492 #endif
1493 '''
1495 # We know that we can always use real ("lock free") atomic operations with MSVC
1496 if cc.get_id() == 'msvc' or cc.links(atomictest, name : 'atomic ops')
1497 have_atomic_lock_free = true
1498 if host_system == 'android' and not cc.compiles(atomicdefine, name : 'atomic ops define')
1499 # When building for armv5 on Android, gcc 4.9 provides
1500 # __sync_bool_compare_and_swap but doesn't define
1501 # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4
1502 glib_conf.set('__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4', true)
1503 endif
1504 else
1505 have_atomic_lock_free = false
1506 if host_machine.cpu_family() == 'x86' and cc.links(atomictest, args : '-march=i486')
1507 error('GLib must be built with -march=i486 or later.')
1508 endif
1509 endif
1510 glibconfig_conf.set('G_ATOMIC_LOCK_FREE', have_atomic_lock_free)
1512 # === Threads ===
1514 # Determination of thread implementation
1515 if host_system == 'windows' and not get_option('force_posix_threads')
1516 thread_dep = []
1517 threads_implementation = 'win32'
1518 glibconfig_conf.set('g_threads_impl_def', 'WIN32')
1519 glib_conf.set('THREADS_WIN32', 1)
1520 else
1521 thread_dep = dependency('threads')
1522 threads_implementation = 'posix'
1523 pthread_prefix = '''
1524 #ifndef _GNU_SOURCE
1525 # define _GNU_SOURCE
1526 #endif
1527 #include <pthread.h>'''
1528 glibconfig_conf.set('g_threads_impl_def', 'POSIX')
1529 glib_conf.set('THREADS_POSIX', 1)
1530 if cc.has_header_symbol('pthread.h', 'pthread_attr_setstacksize')
1531 glib_conf.set('HAVE_PTHREAD_ATTR_SETSTACKSIZE', 1)
1532 endif
1533 if cc.has_header_symbol('pthread.h', 'pthread_condattr_setclock')
1534 glib_conf.set('HAVE_PTHREAD_CONDATTR_SETCLOCK', 1)
1535 endif
1536 if cc.has_header_symbol('pthread.h', 'pthread_cond_timedwait_relative_np')
1537 glib_conf.set('HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP', 1)
1538 endif
1539 if cc.has_header_symbol('pthread.h', 'pthread_getname_np', prefix : pthread_prefix)
1540 glib_conf.set('HAVE_PTHREAD_GETNAME_NP', 1)
1541 endif
1542 # Assume that pthread_setname_np is available in some form; same as configure
1543 if cc.links(pthread_prefix + '''
1544 int main() {
1545 pthread_setname_np("example");
1546 return 0;
1547 }''',
1548 name : 'pthread_setname_np(const char*)',
1549 dependencies : thread_dep)
1550 # macOS and iOS
1551 glib_conf.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
1552 elif cc.links(pthread_prefix + '''
1553 int main() {
1554 pthread_setname_np(pthread_self(), "example");
1555 return 0;
1556 }''',
1557 name : 'pthread_setname_np(pthread_t, const char*)',
1558 dependencies : thread_dep)
1559 # Linux, Solaris, etc.
1560 glib_conf.set('HAVE_PTHREAD_SETNAME_NP_WITH_TID', 1)
1561 endif
1562 endif
1564 # FIXME: we should make it print the result and always return 0, so that
1565 # the output in meson shows up as green
1566 stack_grows_check_prog = '''
1567 volatile int *a = 0, *b = 0;
1568 void f (int i) {
1569 volatile int x = 5;
1570 if (i == 0)
1571 b = &x;
1572 else
1573 f (i - 1);
1574 }
1575 int main () {
1576 volatile int y = 7;
1577 a = &y;
1578 f (100);
1579 return b > a ? 0 : 1;
1580 }'''
1582 if cc_can_run
1583 rres = cc.run(stack_grows_check_prog, name : 'stack grows check')
1584 growing_stack = rres.returncode() == 0
1585 else
1586 growing_stack = meson.get_cross_property('growing_stack', false)
1587 endif
1589 glibconfig_conf.set('G_HAVE_GROWING_STACK', growing_stack)
1591 # Tests for iconv
1592 #
1593 # USE_LIBICONV_GNU: Using GNU libiconv
1594 # USE_LIBICONV_NATIVE: Using a native impl of iconv in a separate library
1595 #
1596 # We should never use the MinGW C library's iconv. On Windows we use the
1597 # GNU implementation that ships with MinGW.
1599 # On Windows, just always use the built-in implementation
1600 if host_system == 'windows'
1601 libiconv = []
1602 glib_conf.set('USE_LIBICONV_NATIVE', true)
1603 else
1604 found_iconv = false
1605 iconv_opt = get_option('iconv')
1606 if iconv_opt == 'libc'
1607 if cc.has_function('iconv_open')
1608 libiconv = []
1609 found_iconv = true
1610 endif
1611 elif iconv_opt == 'gnu'
1612 if cc.has_header_symbol('iconv.h', 'libiconv_open')
1613 glib_conf.set('USE_LIBICONV_GNU', true)
1614 libiconv = [cc.find_library('iconv')]
1615 found_iconv = true
1616 endif
1617 elif iconv_opt == 'native'
1618 if cc.has_header_symbol('iconv.h', 'iconv_open')
1619 glib_conf.set('USE_LIBICONV_NATIVE', true)
1620 libiconv = [cc.find_library('iconv')]
1621 found_iconv = true
1622 endif
1623 endif
1625 if not found_iconv
1626 error('iconv implementation "@0@" not found'.format(iconv_opt))
1627 endif
1629 endif
1631 if get_option('internal_pcre')
1632 pcre = []
1633 use_system_pcre = false
1634 else
1635 pcre = dependency('libpcre', version: '>= 8.31', required : false) # Should check for Unicode support, too. FIXME
1636 if not pcre.found()
1637 if cc.get_id() == 'msvc'
1638 # MSVC: Search for the PCRE library by the configuration, which corresponds
1639 # to the output of CMake builds of PCRE. Note that debugoptimized
1640 # is really a Release build with .PDB files.
1641 if buildtype == 'debug'
1642 pcre = cc.find_library('pcred', required : false)
1643 else
1644 pcre = cc.find_library('pcre', required : false)
1645 endif
1646 endif
1647 endif
1648 use_system_pcre = pcre.found()
1649 endif
1650 glib_conf.set('USE_SYSTEM_PCRE', use_system_pcre)
1652 use_pcre_static_flag = false
1654 if host_system == 'windows'
1655 if not use_system_pcre
1656 use_pcre_static_flag = true
1657 else
1658 pcre_static = cc.links('''#define PCRE_STATIC
1659 #include <pcre.h>
1660 int main() {
1661 void *p = NULL;
1662 pcre_free(p);
1663 return 0;
1664 }''',
1665 dependencies: pcre,
1666 name : 'Windows system PCRE is a static build')
1667 if pcre_static
1668 use_pcre_static_flag = true
1669 endif
1670 endif
1671 endif
1673 libm = cc.find_library('m', required : false)
1674 libffi_dep = dependency('libffi', version : '>= 3.0.0', fallback : ['libffi', 'ffi_dep'])
1675 if cc.get_id() != 'msvc'
1676 libz_dep = dependency('zlib', fallback : ['zlib', 'zlib_dep'])
1677 else
1678 # MSVC: Don't use the bundled ZLib sources until we are sure that we can't
1679 # find the ZLib .lib
1680 libz_dep = dependency('zlib', required : false)
1682 # MSVC: Search for the ZLib .lib, which corresponds to the results of
1683 # of using ZLib's win32/makefile.msc.
1684 if not libz_dep.found()
1685 libz_dep = cc.find_library('zlib1', required : false)
1686 if not libz_dep.found()
1687 libz_dep = cc.find_library('zlib', required : false)
1688 if not libz_dep.found()
1689 libz_dep = subproject('zlib').get_variable('zlib_dep')
1690 endif
1691 endif
1692 endif
1693 endif
1695 # First check in libc, fallback to libintl, and as last chance build
1696 # proxy-libintl subproject.
1697 # FIXME: glib-gettext.m4 has much more checks to detect broken/uncompatible
1698 # implementations. This could be extended if issues are found in some platforms.
1699 if cc.has_function('ngettext')
1700 libintl = []
1701 else
1702 libintl = cc.find_library('intl', required : false)
1703 if not libintl.found()
1704 libintl = subproject('proxy-libintl').get_variable('intl_dep')
1705 endif
1706 endif
1708 # We require gettext to always be present
1709 glib_conf.set('HAVE_DCGETTEXT', 1)
1710 glib_conf.set('HAVE_GETTEXT', 1)
1712 glib_conf.set_quoted('GLIB_LOCALE_DIR', join_paths(glib_datadir, 'locale'))
1713 # xgettext is optional (on Windows for instance)
1714 xgettext = find_program('xgettext', required : false)
1716 # libmount is only used by gio, but we need to fetch the libs to generate the
1717 # pkg-config file below
1718 libmount_dep = []
1719 if host_system == 'linux' and get_option('libmount')
1720 libmount_dep = [dependency('mount', version : '>=2.23', required : true)]
1721 glib_conf.set('HAVE_LIBMOUNT', 1)
1722 endif
1724 if host_system == 'windows'
1725 winsock2 = cc.find_library('ws2_32')
1726 endif
1728 selinux_dep = []
1729 if host_system == 'linux' and get_option('selinux')
1730 selinux_dep = [dependency('libselinux')]
1731 glib_conf.set('HAVE_SELINUX', 1)
1732 endif
1734 xattr_dep = []
1735 if host_system != 'windows' and get_option('xattr')
1736 # either glibc or libattr can provide xattr support
1737 # for both of them, we check for getxattr being in
1738 # the library and a valid xattr header.
1740 # try glibc
1741 if cc.has_function('getxattr') and cc.has_header('sys/xattr.h')
1742 glib_conf.set('HAVE_SYS_XATTR_H', 1)
1743 glib_conf_prefix = glib_conf_prefix + '#define @0@ 1\n'.format('HAVE_SYS_XATTR_H')
1744 #failure. try libattr
1745 elif cc.has_header_symbol('attr/xattr.h', 'getxattr')
1746 glib_conf.set('HAVE_ATTR_XATTR_H', 1)
1747 glib_conf_prefix = glib_conf_prefix + '#define @0@ 1\n'.format('HAVE_ATTR_XATTR_H')
1748 xattr_dep = [cc.find_library('xattr')]
1749 else
1750 error('No getxattr implementation found in C library or libxattr')
1751 endif
1753 glib_conf.set('HAVE_XATTR', 1)
1754 if cc.compiles(glib_conf_prefix + '''
1755 #include <stdio.h>
1756 #ifdef HAVE_SYS_TYPES_H
1757 #include <sys/types.h>
1758 #endif
1759 #ifdef HAVE_SYS_XATTR_H
1760 #include <sys/xattr.h>
1761 #elif HAVE_ATTR_XATTR_H
1762 #include <attr/xattr.h>
1763 #endif
1765 int main (void) {
1766 ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);
1767 return len;
1768 }''',
1769 name : 'XATTR_NOFOLLOW')
1770 glib_conf.set('HAVE_XATTR_NOFOLLOW', 1)
1771 endif
1772 endif
1774 # Test if we have strlcpy/strlcat with a compatible implementation:
1775 # https://bugzilla.gnome.org/show_bug.cgi?id=53933
1776 if cc_can_run
1777 rres = cc.run('''#include <stdlib.h>
1778 #include <string.h>
1779 int main() {
1780 char p[10];
1781 (void) strlcpy (p, "hi", 10);
1782 if (strlcat (p, "bye", 0) != 3)
1783 return 1;
1784 return 0;
1785 }''',
1786 name : 'OpenBSD strlcpy/strlcat')
1787 if rres.compiled() and rres.returncode() == 0
1788 glib_conf.set('HAVE_STRLCPY', 1)
1789 endif
1790 elif meson.get_cross_property('have_strlcpy', false)
1791 glib_conf.set('HAVE_STRLCPY', 1)
1792 endif
1794 python = import('python3').find_python()
1796 # Determine which user environment-dependent files that we want to install
1797 have_bash = find_program('bash', required : false).found() # For completion scripts
1798 have_m4 = find_program('m4', required : false).found() # For m4 macros
1799 have_sh = find_program('sh', required : false).found() # For glib-gettextize
1801 # FIXME: defines in config.h that are not actually used anywhere
1802 # (we add them for now to minimise the diff)
1803 glib_conf.set('HAVE_DLFCN_H', 1)
1804 glib_conf.set('STDC_HEADERS', 1)
1805 glib_conf.set('SIZEOF___INT64', 8)
1807 # FIXME: How to detect Solaris? https://github.com/mesonbuild/meson/issues/1578
1808 if host_system == 'sunos'
1809 glib_conf.set('_XOPEN_SOURCE_EXTENDED', 1)
1810 glib_conf.set('_XOPEN_SOURCE', 2)
1811 glib_conf.set('__EXTENSIONS__',1)
1812 endif
1814 # Sadly Meson does not expose this value:
1815 # https://github.com/mesonbuild/meson/pull/3460
1816 if host_system == 'windows'
1817 # Autotools explicitly removed --Wl,--export-all-symbols from windows builds,
1818 # with no explanation. Do the same here for now but this could be revisited if
1819 # if causes issues.
1820 export_dynamic_ldflags = []
1821 elif host_system == 'cygwin'
1822 export_dynamic_ldflags = ['-Wl,--export-all-symbols']
1823 elif host_system == 'darwin'
1824 export_dynamic_ldflags = []
1825 else
1826 export_dynamic_ldflags = ['-Wl,--export-dynamic']
1827 endif
1829 win32_cflags = []
1830 win32_ldflags = []
1831 if host_system == 'windows' and cc.get_id() != 'msvc'
1832 # Ensure MSVC-compatible struct packing convention is used when
1833 # compiling for Win32 with gcc. It is used for the whole project and exposed
1834 # in glib-2.0.pc.
1835 win32_cflags = ['-mms-bitfields']
1836 add_project_arguments(win32_cflags, language : 'c')
1838 # Win32 API libs, used only by libglib and exposed in glib-2.0.pc
1839 win32_ldflags = ['-lws2_32', '-lole32', '-lwinmm', '-lshlwapi']
1840 elif host_system == 'cygwin'
1841 win32_ldflags = ['-luser32', '-lkernel32']
1842 endif
1844 # Tracing: dtrace
1845 want_dtrace = get_option('dtrace')
1846 enable_dtrace = false
1848 # Since dtrace support is opt-in we just error out if it was requested but
1849 # is not available. We don't bother with autodetection yet.
1850 if want_dtrace
1851 if glib_have_carbon
1852 error('GLib dtrace support not yet compatible with macOS dtrace')
1853 endif
1854 dtrace = find_program('dtrace', required : true) # error out if not found
1855 if not cc.has_header('sys/sdt.h')
1856 error('dtrace support needs sys/sdt.h header')
1857 endif
1858 # FIXME: autotools build also passes -fPIC -DPIC but is it needed in this case?
1859 dtrace_obj_gen = generator(dtrace,
1860 output : '@BASENAME@.o',
1861 arguments : ['-G', '-s', '@INPUT@', '-o', '@OUTPUT@'])
1862 # FIXME: $(SED) -e "s,define STAP_HAS_SEMAPHORES 1,undef STAP_HAS_SEMAPHORES,"
1863 # -e "s,define _SDT_HAS_SEMAPHORES 1,undef _SDT_HAS_SEMAPHORES,"
1864 dtrace_hdr_gen = generator(dtrace,
1865 output : '@BASENAME@.h',
1866 arguments : ['-h', '-s', '@INPUT@', '-o', '@OUTPUT@'])
1867 glib_conf.set('HAVE_DTRACE', 1)
1868 enable_dtrace = true
1869 endif
1871 # systemtap
1872 want_systemtap = get_option('systemtap')
1873 enable_systemtap = false
1875 if want_systemtap and enable_dtrace
1876 tapset_install_dir = get_option('tapset_install_dir')
1877 if tapset_install_dir == ''
1878 tapset_install_dir = join_paths(get_option('datadir'), 'systemtap/tapset', host_machine.cpu_family())
1879 endif
1880 stp_cdata = configuration_data()
1881 stp_cdata.set('ABS_GLIB_RUNTIME_LIBDIR', glib_libdir)
1882 stp_cdata.set('LT_CURRENT', minor_version * 100)
1883 stp_cdata.set('LT_REVISION', micro_version)
1884 enable_systemtap = true
1885 endif
1888 pkg = import('pkgconfig')
1889 windows = import('windows')
1890 subdir('glib')
1891 subdir('gobject')
1892 subdir('gthread')
1893 subdir('gmodule')
1894 subdir('gio')
1895 if xgettext.found()
1896 subdir('po')
1897 endif
1898 subdir('tests')
1900 # Install glib-gettextize executable, if a UNIX-style shell is found
1901 if have_sh
1902 # These should not contain " quotes around the values
1903 gettexize_conf = configuration_data()
1904 gettexize_conf.set('PACKAGE', 'glib')
1905 gettexize_conf.set('VERSION', meson.project_version())
1906 gettexize_conf.set('prefix', glib_prefix)
1907 gettexize_conf.set('datarootdir', glib_datadir)
1908 gettexize_conf.set('datadir', glib_datadir)
1909 configure_file(input : 'glib-gettextize.in',
1910 install : true,
1911 install_dir : 'bin',
1912 output : 'glib-gettextize',
1913 configuration : gettexize_conf)
1914 endif
1916 if have_m4
1917 # Install m4 macros that other projects use
1918 install_data('m4macros/glib-2.0.m4', 'm4macros/glib-gettext.m4', 'm4macros/gsettings.m4',
1919 install_dir : join_paths(get_option('datadir'), 'aclocal'))
1920 endif
1922 if host_system != 'windows'
1923 # Install Valgrind suppression file (except on Windows,
1924 # as Valgrind is currently not supported on Windows)
1925 install_data('glib.supp',
1926 install_dir : join_paths(get_option('datadir'), 'glib-2.0', 'valgrind'))
1927 endif
1929 configure_file(output : 'config.h', configuration : glib_conf)
1931 if host_system == 'windows'
1932 install_headers([ 'msvc_recommended_pragmas.h' ], subdir : 'glib-2.0')
1933 endif
1935 if get_option('man')
1936 xsltproc = find_program('xsltproc', required : true)
1937 xsltproc_command = [
1938 xsltproc,
1939 '--nonet',
1940 '--stringparam', 'man.output.quietly', '1',
1941 '--stringparam', 'funcsynopsis.style', 'ansi',
1942 '--stringparam', 'man.th.extra1.suppress', '1',
1943 '--stringparam', 'man.authors.section.enabled', '0',
1944 '--stringparam', 'man.copyright.section.enabled', '0',
1945 '-o', '@OUTPUT@',
1946 'http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl',
1947 '@INPUT@',
1948 ]
1949 man1_dir = get_option('mandir') + '/man1'
1950 endif
1952 gnome = import('gnome')
1953 subdir('docs/reference/glib')
1954 subdir('docs/reference/gobject')
1955 subdir('docs/reference/gio')