gobject/meson.build

   1 gobject_install_headers = files([
   2   'gobject-autocleanups.h',
   3   'glib-types.h',
   4   'gbinding.h',
   5   'gboxed.h',
   6   'gclosure.h',
   7   'genums.h',
   8   'gmarshal.h',
   9   'gobject.h',
  10   'gparam.h',
  11   'gparamspecs.h',
  12   'gsignal.h',
  13   'gsourceclosure.h',
  14   'gtype.h',
  15   'gtypemodule.h',
  16   'gtypeplugin.h',
  17   'gvalue.h',
  18   'gvaluearray.h',
  19   'gvaluecollector.h',
  20   'gvaluetypes.h',
  21   'gobjectnotifyqueue.c', # sic
  22 ])
  23 install_headers(gobject_install_headers, subdir : 'glib-2.0/gobject')
  24
  25 gobject_c_sources = [
  26 #  'gobject_probes.d',
  27   'gatomicarray.c',
  28   'gbinding.c',
  29   'gboxed.c',
  30   'gclosure.c',
  31   'genums.c',
  32   'gmarshal.c',
  33   'gobject.c',
  34   'gobject_trace.h',
  35   'gparam.c',
  36   'gparamspecs.c',
  37   'gsignal.c',
  38   'gsourceclosure.c',
  39   'gtype.c',
  40   'gtypemodule.c',
  41   'gtypeplugin.c',
  42   'gvalue.c',
  43   'gvaluearray.c',
  44   'gvaluetransform.c',
  45   'gvaluetypes.c',
  46 ]
  47
  48 if enable_dtrace
  49   gobject_dtrace_obj = dtrace_obj_gen.process('gobject_probes.d')
  50   gobject_dtrace_hdr = dtrace_hdr_gen.process('gobject_probes.d')
  51 else
  52   gobject_dtrace_obj = []
  53   gobject_dtrace_hdr = []
  54 endif
  55
  56 libgobject = shared_library('gobject-2.0',
  57   gobject_dtrace_obj, gobject_dtrace_hdr,
  58   sources : [gobject_c_sources],
  59   version : library_version,
  60   soversion : soversion,
  61   install : true,
  62   include_directories : [configinc],
  63   dependencies : [libintl, libffi_dep, libglib_dep],
  64   c_args : ['-DG_LOG_DOMAIN="GLib-GObject"', '-DGOBJECT_COMPILATION'] + glib_hidden_visibility_args)
  65
  66 libgobject_dep = declare_dependency(link_with : libgobject,
  67   include_directories : gobjectinc)
  68
  69 python_tools = [
  70   'glib-genmarshal',
  71   'glib-mkenums',
  72 ]
  73
  74 python_tools_conf = configuration_data()
  75 python_tools_conf.set('VERSION', glib_version)
  76 python_tools_conf.set('PYTHON', python.path())
  77
  78 foreach tool: python_tools
  79   tool_bin = configure_file(
  80     input : tool + '.in',
  81     output : tool,
  82     configuration : python_tools_conf,
  83     install : true,
  84     install_dir : glib_bindir,
  85   )
  86
  87   # Set variables for later use
  88   set_variable(tool.underscorify(), tool_bin)
  89 endforeach
  90
  91 executable('gobject-query', 'gobject-query.c',
  92   install : true,
  93   c_args : ['-DHAVE_CONFIG_H=1'],
  94   dependencies : [libglib_dep, libgobject_dep])
  95
  96 install_data('gobject_gdb.py', install_dir : join_paths(glib_pkgdatadir, 'gdb'))
  97 gdb_conf = configuration_data()
  98 gdb_conf.set('datadir', glib_datadir)
  99 configure_file(
 100   input: 'libgobject-gdb.py.in',
 101   output: 'libgobject-2.0.so.@0@-gdb.py'.format(library_version),
 102   configuration: gdb_conf,
 103   install_dir: gdb_install_dir,
 104 )
 105
 106 if enable_systemtap
 107   gobject_stp = configure_file(input : 'gobject.stp.in',
 108     output : '@0@.stp'.format(libgobject.full_path().split('/').get(-1)),
 109     configuration : stp_cdata,
 110     install_dir : tapset_install_dir,
 111     install : true)
 112 endif
 113
 114 subdir('tests')