| blob | 11fde900f8f688e1ca5a04eed37a7ee399f61d6d |
1 # Process this file with autoconf to produce a configure script.
2 AC_PREREQ([2.62])
4 dnl ***********************************
5 dnl *** include special GLib macros ***
6 dnl ***********************************
8 m4_define(glib_configure_ac)
10 #
11 # The following version number definitions apply to GLib, GModule, GObject,
12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
13 # all treated with the same interface and binary age.
14 #
15 # Making releases:
16 # glib_micro_version += 1;
17 # glib_interface_age += 1;
18 # glib_binary_age += 1;
19 # if any functions have been added, set glib_interface_age to 0.
20 # if backwards compatibility has been broken,
21 # set glib_binary_age _and_ glib_interface_age to 0.
22 #
23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
25 # for that version - see gversion.h for further information.
26 #
27 # in easier to understand terms:
28 #
29 # <mclasen> on the stable branch, interface age == micro
30 # <mclasen> on the unstable (ie master), interface age = 0
32 m4_define([glib_major_version], [2])
33 m4_define([glib_minor_version], [57])
34 m4_define([glib_micro_version], [2])
35 m4_define([glib_interface_age], [0])
36 m4_define([glib_binary_age],
37 [m4_eval(100 * glib_minor_version + glib_micro_version)])
38 m4_define([glib_version],
39 [glib_major_version.glib_minor_version.glib_micro_version])
41 # libtool version related macros
42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
43 m4_define([glib_lt_current],
44 [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
45 m4_define([glib_lt_revision], [glib_interface_age])
46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
47 m4_define([glib_lt_current_minus_age],
48 [m4_eval(glib_lt_current - glib_lt_age)])
50 # if the minor version number is odd, then we want debugging. Otherwise
51 # we only want minimal debugging support.
52 m4_define([glib_debug_default],
53 [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
56 AC_INIT(glib, [glib_version],
57 [https://gitlab.gnome.org/GNOME/glib/issues/new])
59 AC_CONFIG_HEADERS([config.h])
60 AC_CONFIG_SRCDIR([glib/glib.h])
61 AC_CONFIG_MACRO_DIR([m4macros])
63 # Save this value here, since automake will set cflags later
64 cflags_set=${CFLAGS:+set}
66 AM_INIT_AUTOMAKE([1.13.3 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar subdir-objects])
67 AM_MAINTAINER_MODE([enable])
69 # Support silent build rules. Disable
70 # by either passing --disable-silent-rules to configure or passing V=1
71 # to make
72 AM_SILENT_RULES([yes])
74 GLIB_MAJOR_VERSION=glib_major_version
75 GLIB_MINOR_VERSION=glib_minor_version
76 GLIB_MICRO_VERSION=glib_micro_version
77 GLIB_INTERFACE_AGE=glib_interface_age
78 GLIB_BINARY_AGE=glib_binary_age
79 GLIB_VERSION=glib_version
81 AC_SUBST(GLIB_MAJOR_VERSION)
82 AC_SUBST(GLIB_MINOR_VERSION)
83 AC_SUBST(GLIB_MICRO_VERSION)
84 AC_SUBST(GLIB_VERSION)
85 AC_SUBST(GLIB_INTERFACE_AGE)
86 AC_SUBST(GLIB_BINARY_AGE)
88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
89 [Define to the GLIB major version])
90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
91 [Define to the GLIB minor version])
92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
93 [Define to the GLIB micro version])
94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
95 [Define to the GLIB interface age])
96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
97 [Define to the GLIB binary age])
99 # libtool versioning
100 LT_RELEASE=glib_lt_release
101 LT_CURRENT=glib_lt_current
102 LT_REVISION=glib_lt_revision
103 LT_AGE=glib_lt_age
104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
105 AC_SUBST(LT_RELEASE)
106 AC_SUBST(LT_CURRENT)
107 AC_SUBST(LT_REVISION)
108 AC_SUBST(LT_AGE)
109 AC_SUBST(LT_CURRENT_MINUS_AGE)
111 dnl Checks for programs.
112 AC_PROG_CC
113 AC_PROG_CPP
114 AC_USE_SYSTEM_EXTENSIONS
116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
118 AC_CANONICAL_HOST
120 dnl
122 AC_MSG_CHECKING([for Win32])
123 LIB_EXE_MACHINE_FLAG=X86
124 case "$host" in
125 *-*-mingw*)
126 glib_native_win32=yes
127 glib_pid_type='void *'
128 glib_pid_format='p'
129 glib_pollfd_format='%#x'
130 glib_dir_separator='\\\\'
131 glib_searchpath_separator=';'
132 glib_cv_stack_grows=no
133 # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
134 # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
135 # (Sorry, I don't know exactly what is the problem, but it is related to
136 # floating point formatting and decimal point vs. comma.)
137 # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
138 # rigorous enough to notice, though.
139 # So preset the autoconf cache variables.
140 ac_cv_func_vsnprintf_c99=no
141 ac_cv_func_snprintf_c99=no
142 case "$host" in
143 x86_64-*-*)
144 LIB_EXE_MACHINE_FLAG=X64
145 glib_pollfd_format='%#I64x'
146 ;;
147 esac
149 AC_DEFINE([_WIN32_WINNT], [0x0601], [Target the Windows 7 API])
150 ;;
151 *)
152 glib_native_win32=no
153 glib_pid_type=int
154 glib_pid_format='i'
155 glib_pollfd_format='%d'
156 glib_dir_separator='/'
157 glib_searchpath_separator=':'
158 ;;
159 esac
160 case $host in
161 *-*-linux*)
162 glib_os_linux=yes
163 ;;
164 esac
166 AC_MSG_RESULT([$glib_native_win32])
168 AC_MSG_CHECKING([for the Android])
169 case $host in
170 *android*)
171 glib_native_android="yes"
172 ;;
173 *)
174 glib_native_android="no"
175 ;;
176 esac
177 AC_MSG_RESULT([$glib_native_android])
179 AC_SUBST(LIB_EXE_MACHINE_FLAG)
181 glib_have_carbon=no
182 AC_MSG_CHECKING([for Mac OS X Carbon support])
183 AC_TRY_CPP([
184 #include <Carbon/Carbon.h>
185 #include <CoreServices/CoreServices.h>
186 ], glib_have_carbon=yes)
188 AC_MSG_RESULT([$glib_have_carbon])
190 glib_have_cocoa=no
191 AC_MSG_CHECKING([for Mac OS X Cocoa support])
192 AC_TRY_CPP([
193 #include <Cocoa/Cocoa.h>
194 #ifdef GNUSTEP_BASE_VERSION
195 #error "Detected GNUstep, not Cocoa"
196 #endif
197 ], glib_have_cocoa=yes)
199 AC_MSG_RESULT([$glib_have_cocoa])
201 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
202 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
203 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
204 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
205 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
206 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
208 AS_IF([test "$glib_native_win32" = "yes"], [
209 AC_CHECK_TOOL(WINDRES, windres, no)
210 if test "$WINDRES" = no; then
211 AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
212 fi
213 AC_CHECK_TOOL(NM, nm, no)
214 if test "$NM" = no; then
215 AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
216 fi
217 AC_CHECK_TOOL(RANLIB, ranlib, :)
218 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
219 AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
220 ])
221 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
223 AS_IF([test "x$glib_have_carbon" = "xyes"], [
224 AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
225 CARBON_LIBS="-Wl,-framework,Carbon"
226 LDFLAGS="$LDFLAGS $CARBON_LIBS"
227 ], [CARBON_LIBS=""])
229 AC_SUBST([CARBON_LIBS])
230 ac_cv_have_os_x_9_or_later="no"
231 AS_IF([test "x$glib_have_cocoa" = "xyes"], [
232 AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
233 COCOA_LIBS="-Wl,-framework,Foundation -Wl,-framework,AppKit"
234 LDFLAGS="$LDFLAGS $COCOA_LIBS"
235 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
236 #include <AvailabilityMacros.h>
237 #if MAC_OS_X_VERSION_MIN_REQUIRED < 1090
238 #error Compiling for minimum OS X version before 10.9
239 #endif
240 ]])],[ac_cv_have_os_x_9_or_later="yes"])
241 ], [COCOA_LIBS=""])
242 AM_CONDITIONAL([MAC_OS_X_9], [test "x$ac_cv_have_os_x_9_or_later" = xyes])
243 AC_SUBST([COCOA_LIBS])
245 dnl declare --enable-* args and collect ac_help strings
246 AC_ARG_ENABLE(debug,
247 AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
248 [turn on debugging @<:@default=glib_debug_default@:>@]),,
249 enable_debug=glib_debug_default)
251 GLIB_TESTS
253 dnl location to install runtime libraries, e.g. ../../lib to install
254 dnl to /lib if libdir is /usr/lib
255 AC_ARG_WITH(runtime-libdir,
256 [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
257 [install runtime libraries relative to libdir])],
258 [],
259 [with_runtime_libdir=""])
260 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
261 AC_SUBST(GLIB_RUNTIME_LIBDIR)
262 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
264 dnl Check for a working C++ compiler, but do not bail out, if none is found.
265 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
266 AC_LANG_SAVE
267 AC_LANG_CPLUSPLUS
268 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
269 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
270 AC_LANG_RESTORE
272 AM_PROG_CC_C_O
273 AC_PROG_INSTALL
275 AC_SYS_LARGEFILE
277 PKG_PROG_PKG_CONFIG(0.16)
279 if test "x$enable_debug" = "xyes"; then
280 if test "x$cflags_set" != "x" ; then
281 case " $CFLAGS " in
282 *[[\ \ ]]-g[[\ \ ]]*) ;;
283 *) CFLAGS="$CFLAGS -g" ;;
284 esac
285 fi
286 GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
287 else
288 GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
290 if test "x$enable_debug" = "xno"; then
291 GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
292 fi
293 fi
295 # Ensure MSVC-compatible struct packing convention is used when
296 # compiling for Win32 with gcc.
297 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
298 # gcc2 uses "-fnative-struct".
299 if test x"$glib_native_win32" = xyes; then
300 if test x"$GCC" = xyes; then
301 msnative_struct=''
302 AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
303 if test -z "$ac_cv_prog_CC"; then
304 our_gcc="$CC"
305 else
306 our_gcc="$ac_cv_prog_CC"
307 fi
308 case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
309 2.)
310 if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
311 msnative_struct='-fnative-struct'
312 fi
313 ;;
314 *)
315 if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
316 msnative_struct='-mms-bitfields'
317 fi
318 ;;
319 esac
320 if test x"$msnative_struct" = x ; then
321 AC_MSG_RESULT([no way])
322 AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
323 else
324 CFLAGS="$CFLAGS $msnative_struct"
325 AC_MSG_RESULT([${msnative_struct}])
326 fi
327 fi
328 fi
329 GLIB_EXTRA_CFLAGS="${msnative_struct}"
330 AC_SUBST(GLIB_EXTRA_CFLAGS)
332 AC_EXEEXT
334 AC_PROG_AWK
336 # option to specify python interpreter to use; this just sets $PYTHON, so that
337 # we will fallback to reading $PYTHON if --with-python is not given, and
338 # python.m4 will get the expected input
339 AC_ARG_WITH(python,
340 AS_HELP_STRING([--with-python=PATH],
341 [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
342 [PYTHON="$withval"], [])
343 if test x"$PYTHON" = xyes; then
344 AC_MSG_ERROR([--with-python option requires a path or program argument])
345 fi
346 AM_PATH_PYTHON(2.7,,PYTHON="python2.7")
349 dnl ***********************
350 dnl *** Tests for iconv ***
351 dnl ***********************
352 dnl
353 dnl We do this before the gettext checks, to avoid distortion
355 dnl On Windows we use a native implementation
357 AS_IF([ test x"$glib_native_win32" = xyes], [
358 with_libiconv=native
359 ], [
360 AC_ARG_WITH(libiconv,
361 [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
362 [use the libiconv library])],,
363 [with_libiconv=maybe])
365 found_iconv=no
366 case $with_libiconv in
367 maybe)
368 # Check in the C library first
369 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
370 # Check if we have GNU libiconv
371 if test $found_iconv = "no"; then
372 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
373 fi
374 # Check if we have a iconv in -liconv, possibly from vendor
375 if test $found_iconv = "no"; then
376 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
377 fi
378 ;;
379 no)
380 AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
381 ;;
382 gnu|yes)
383 AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
384 ;;
385 native)
386 AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
387 ;;
388 esac
390 if test "x$found_iconv" = "xno" ; then
391 AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
392 fi
393 ])
395 dnl
396 dnl zlib support
397 dnl
398 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
399 AS_IF([test "x$found_zlib" = "xno"], [
400 AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
401 if test "x$found_zlib" = "xno" ; then
402 AC_MSG_ERROR([*** Working zlib library and headers not found ***])
403 fi
404 ZLIB_LIBS='-lz'
405 AC_SUBST(ZLIB_LIBS)
406 ])
408 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
409 AC_SUBST(LIBFFI_CFLAGS)
410 AC_SUBST(LIBFFI_LIBS)
412 dnl
413 dnl gettext support
414 dnl
416 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
417 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
418 GLIB_GNU_GETTEXT
420 if test "$gt_cv_have_gettext" != "yes" ; then
421 AC_MSG_ERROR([
422 *** You must have either have gettext support in your C library, or use the
423 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html)
424 ])
425 fi
427 LIBS="$INTLLIBS $LIBS"
429 GETTEXT_PACKAGE=glib20
430 AC_SUBST(GETTEXT_PACKAGE)
431 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
432 [Define the gettext package to be used])
434 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
436 dnl
437 dnl Now we are done with gettext checks, figure out ICONV_LIBS
438 dnl
440 AS_IF([test x"$glib_native_win32" != xyes], [
441 if test x$with_libiconv != xno ; then
442 case " $INTLLIBS " in
443 *[[\ \ ]]-liconv[[\ \ ]]*) ;;
444 *) ICONV_LIBS="-liconv" ;;
445 esac
446 fi
447 ])
448 AC_SUBST(ICONV_LIBS)
450 case $with_libiconv in
451 gnu)
452 AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
453 ;;
454 native)
455 AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
456 ;;
457 esac
459 dnl Initialize libtool
460 LT_PREREQ([2.2])
461 LT_INIT([disable-static win32-dll])
462 dnl when using libtool 2.x create libtool early, because it's used in configure
463 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
466 AS_IF([test "$glib_native_win32" = "yes"], [
467 if test x$enable_static = xyes -a x$enable_shared = xyes; then
468 AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
469 fi
470 if test x$enable_static = xyes; then
471 glib_win32_static_compilation=yes
472 GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
473 #define GOBJECT_STATIC_COMPILATION 1"
474 AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
475 fi
476 ])
477 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
479 # Checks for library functions.
480 AC_FUNC_ALLOCA
481 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
482 AC_CHECK_FUNCS(timegm gmtime_r posix_spawn)
483 AC_FUNC_STRERROR_R()
485 AC_CHECK_SIZEOF(char)
486 AC_CHECK_SIZEOF(short)
487 AC_CHECK_SIZEOF(long)
488 AC_CHECK_SIZEOF(int)
489 AC_CHECK_SIZEOF(void *)
490 AC_CHECK_SIZEOF(long long)
491 AC_CHECK_SIZEOF(__int64)
493 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
494 [AC_TRY_LINK([#include <signal.h>
495 #include <sys/types.h>
496 sig_atomic_t val = 42;],
497 [return val == 42 ? 0 : 1],
498 ac_cv_type_sig_atomic_t=yes,
499 ac_cv_type_sig_atomic_t=no)])
500 if test x$ac_cv_type_sig_atomic_t = xyes; then
501 AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
502 [Define if you have the 'sig_atomic_t' type.])
503 fi
505 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
506 :
507 else
508 AC_MSG_ERROR([
509 *** GLib requires a 64 bit type. You might want to consider
510 *** using the GNU C compiler.
511 ])
512 fi
514 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
515 # long long is a 64 bit integer.
516 AC_MSG_CHECKING(for format to printf and scanf a guint64)
517 AC_CACHE_VAL(glib_cv_long_long_format,[
518 for format in ll q I64; do
519 AC_TRY_RUN([#include <stdio.h>
520 int main()
521 {
522 long long b, a = -0x3AFAFAFAFAFAFAFALL;
523 char buffer[1000];
524 sprintf (buffer, "%${format}u", a);
525 sscanf (buffer, "%${format}u", &b);
526 exit (b!=a);
527 }
528 ],
529 [glib_cv_long_long_format=${format}
530 break],
531 [],[:])
532 done])
533 AS_IF([ test -n "$glib_cv_long_long_format"], [
534 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
535 ], [AC_MSG_RESULT(none)])
536 ],[ test x$ac_cv_sizeof___int64 = x8], [
537 # __int64 is a 64 bit integer.
538 AC_MSG_CHECKING(for format to printf and scanf a guint64)
539 # We know this is MSVCRT.DLL, and what the formats are
540 glib_cv_long_long_format=I64
541 AC_MSG_RESULT(%${glib_cv_long_long_format}u)
542 ])
544 AC_C_CONST
546 dnl
547 dnl check in which direction the stack grows
548 dnl
549 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
550 AC_TRY_RUN([
551 volatile int *a = 0, *b = 0;
552 void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
553 int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
554 ],
555 glib_cv_stack_grows=yes
556 ,
557 glib_cv_stack_grows=no
558 ,)
559 ])
561 # check for flavours of varargs macros
562 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
563 AC_TRY_COMPILE([],[
564 int a(int p1, int p2, int p3);
565 #define call_a(...) a(1,__VA_ARGS__)
566 call_a(2,3);
567 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
568 AC_MSG_RESULT($g_have_iso_c_varargs)
570 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
571 AS_IF([test "$CXX" = ""], [
572 dnl No C++ compiler
573 g_have_iso_cxx_varargs=no
574 else
575 AC_LANG_CPLUSPLUS
576 AC_TRY_COMPILE([],[
577 int a(int p1, int p2, int p3);
578 #define call_a(...) a(1,__VA_ARGS__)
579 call_a(2,3);
580 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
581 AC_LANG_C
582 ])
583 AC_MSG_RESULT($g_have_iso_cxx_varargs)
585 AC_MSG_CHECKING(for GNUC varargs macros)
586 AC_TRY_COMPILE([],[
587 int a(int p1, int p2, int p3);
588 #define call_a(params...) a(1,params)
589 call_a(2,3);
590 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
591 AC_MSG_RESULT($g_have_gnuc_varargs)
593 # check for GNUC visibility support
594 AC_MSG_CHECKING(for GNUC visibility attribute)
595 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
596 void
597 __attribute__ ((visibility ("hidden")))
598 f_hidden (void)
599 {
600 }
601 void
602 __attribute__ ((visibility ("internal")))
603 f_internal (void)
604 {
605 }
606 void
607 __attribute__ ((visibility ("protected")))
608 f_protected (void)
609 {
610 }
611 void
612 __attribute__ ((visibility ("default")))
613 f_default (void)
614 {
615 }
616 int main (void)
617 {
618 f_hidden();
619 f_internal();
620 f_protected();
621 f_default();
622 return 0;
623 }
624 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
625 AC_MSG_RESULT($g_have_gnuc_visibility)
626 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
628 AC_MSG_CHECKING([whether using Sun Studio C compiler])
629 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
630 #else
631 # include "error: this is not Sun Studio."
632 #endif
633 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
634 AC_MSG_RESULT($g_have_sunstudio_visibility)
635 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
637 # check for bytesex stuff
638 AC_C_BIGENDIAN
639 if test x$ac_cv_c_bigendian = xuniversal ; then
640 AC_MSG_ERROR([Universal builds not supported: see https://bugzilla.gnome.org/show_bug.cgi?id=742548])
641 fi
644 # check for header files
645 AC_CHECK_HEADERS([sys/param.h sys/resource.h mach/mach_time.h])
646 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
647 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h sys/auxv.h])
648 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
649 AC_CHECK_HEADERS([linux/magic.h])
650 AC_CHECK_HEADERS([termios.h])
652 # Some versions of MSC lack these
653 AC_CHECK_HEADERS([dirent.h sys/time.h])
655 # We don't care about this, but we need to keep including it in
656 # glibconfig.h for backward compatibility
657 AC_CHECK_HEADERS([values.h])
659 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
660 [#if HAVE_SYS_PARAM_H
661 #include <sys/param.h>
662 #endif
663 ])
664 AC_CHECK_FUNCS(sysctlbyname)
666 AC_HEADER_MAJOR
667 AS_IF([test "$ac_cv_header_sys_types_h_makedev" = "yes"],
668 [AC_DEFINE([MAJOR_IN_TYPES], [1], [Define to 1 if `major', `minor', and `makedev' are declared in <sys/types.h>.])])
669 AC_CHECK_HEADERS([xlocale.h])
671 # check for structure fields
672 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec, struct stat.st_birthtime, struct stat.st_birthtimensec, struct stat.st_birthtim, struct stat.st_birthtim.tv_nsec])
673 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
674 #include <sys/stat.h>
675 #ifdef G_OS_UNIX
676 #include <unistd.h>
677 #endif
678 #ifdef HAVE_SYS_STATFS_H
679 #include <sys/statfs.h>
680 #endif
681 #ifdef HAVE_SYS_PARAM_H
682 #include <sys/param.h>
683 #endif
684 #ifdef HAVE_SYS_MOUNT_H
685 #include <sys/mount.h>
686 #endif])
687 # struct statvfs.f_basetype is available on Solaris but not for Linux.
688 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
689 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
690 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
692 AC_STRUCT_DIRENT_D_TYPE
694 # Checks for libcharset
695 AM_LANGINFO_CODESET
696 gl_GLIBC21
697 AC_ARG_WITH(charsetalias-dir,
698 AS_HELP_STRING([--with-charsetalias-dir=DIR], [directory for charset.alias file [LIBDIR]]),
699 [],
700 [with_charsetalias_dir='${libdir}'])
701 GLIB_CHARSETALIAS_DIR=$with_charsetalias_dir
702 AC_SUBST(GLIB_CHARSETALIAS_DIR)
704 # check additional type sizes
705 AC_CHECK_SIZEOF(size_t)
707 dnl Try to figure out whether gsize should be long or int
708 AC_MSG_CHECKING([for the appropriate definition for size_t])
710 case $ac_cv_sizeof_size_t in
711 $ac_cv_sizeof_short)
712 glib_size_type=short
713 ;;
714 $ac_cv_sizeof_int)
715 glib_size_type=int
716 ;;
717 $ac_cv_sizeof_long)
718 glib_size_type=long
719 ;;
720 $ac_cv_sizeof_long_long)
721 glib_size_type='long long'
722 ;;
723 $ac_cv_sizeof__int64)
724 glib_size_type='__int64'
725 ;;
726 *) AC_MSG_ERROR([No type matching size_t in size])
727 ;;
728 esac
730 dnl If int/long are the same size, we see which one produces
731 dnl warnings when used in the location as size_t. (This matters
732 dnl on AIX with xlc)
733 dnl
734 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
735 test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
736 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
737 #if defined(_AIX) && !defined(__GNUC__)
738 #pragma options langlvl=stdc89
739 #endif
740 #include <stddef.h>
741 int main ()
742 {
743 size_t s = 1;
744 unsigned int *size_int = &s;
745 return (int)*size_int;
746 }
747 ]])],glib_size_type=int,
748 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
749 #if defined(_AIX) && !defined(__GNUC__)
750 #pragma options langlvl=stdc89
751 #endif
752 #include <stddef.h>
753 int main ()
754 {
755 size_t s = 1;
756 unsigned long *size_long = &s;
757 return (int)*size_long;
758 }
759 ]])],glib_size_type=long)])
760 ])
762 AC_MSG_RESULT(unsigned $glib_size_type)
764 AC_CHECK_SIZEOF(ssize_t)
766 dnl Try to figure out whether gssize should be long or int
767 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
769 case $ac_cv_sizeof_ssize_t in
770 $ac_cv_sizeof_short)
771 glib_ssize_type=short
772 ;;
773 $ac_cv_sizeof_int)
774 glib_ssize_type=int
775 ;;
776 $ac_cv_sizeof_long)
777 glib_ssize_type=long
778 ;;
779 $ac_cv_sizeof_long_long)
780 glib_ssize_type='long long'
781 ;;
782 $ac_cv_sizeof__int64)
783 glib_ssize_type='__int64'
784 ;;
785 *) AC_MSG_ERROR([No type matching ssize_t in size])
786 ;;
787 esac
789 dnl If int/long are the same size, we see which one produces
790 dnl warnings when used in the location as ssize_t. (This matters
791 dnl on Android where ssize_t is long and size_t is unsigned int)
792 dnl
793 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
794 test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
795 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
796 #if defined(_AIX) && !defined(__GNUC__)
797 #pragma options langlvl=stdc89
798 #endif
799 #include <stddef.h>
800 #ifdef HAVE_INTTYPES_H
801 # include <inttypes.h>
802 #endif
803 #ifdef HAVE_STDINT_H
804 # include <stdint.h>
805 #endif
806 #include <sys/types.h>
807 int main ()
808 {
809 ssize_t s = 1;
810 int *size_int = &s;
811 return (int)*size_int;
812 }
813 ]])],glib_ssize_type=int,
814 [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
815 #if defined(_AIX) && !defined(__GNUC__)
816 #pragma options langlvl=stdc89
817 #endif
818 #include <stddef.h>
819 #ifdef HAVE_INTTYPES_H
820 # include <inttypes.h>
821 #endif
822 #ifdef HAVE_STDINT_H
823 # include <stdint.h>
824 #endif
825 #include <sys/types.h>
826 int main ()
827 {
828 ssize_t s = 1;
829 long *size_long = &s;
830 return (int)*size_long;
831 }
832 ]])],glib_ssize_type=long)])
833 ])
835 AC_MSG_RESULT($glib_ssize_type)
837 # Check for some functions
838 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk mkostemp link)
839 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
840 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
841 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
842 AC_CHECK_FUNCS(splice)
843 AC_CHECK_FUNCS(prlimit)
845 # To avoid finding a compatibility unusable statfs, which typically
846 # successfully compiles, but warns to use the newer statvfs interface:
847 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
848 AS_IF([test $ac_cv_header_sys_statfs_h = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
850 AC_MSG_CHECKING([whether to use statfs or statvfs])
851 # Some systems have both statfs and statvfs, pick the most "native" for these
852 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
853 [
854 # on solaris and irix, statfs doesn't even have the f_bavail field
855 AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
856 [ac_cv_func_statfs=no],
857 # else, at least on linux, statfs is the actual syscall
858 [ac_cv_func_statvfs=no])
859 ])
861 AS_IF([test x$ac_cv_func_statfs = xyes],
862 [
863 AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
864 AC_MSG_RESULT([statfs])
865 ],
866 [test x$ac_cv_func_statvfs = xyes],
867 [
868 AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
869 AC_MSG_RESULT([statvfs])
870 ],
871 [ AC_MSG_RESULT([neither])])
873 AC_CHECK_HEADERS(crt_externs.h)
874 AC_CHECK_FUNCS(_NSGetEnviron)
876 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
878 # Internet address families
879 if test $glib_native_win32 = yes; then
880 glib_inet_includes=["
881 #include <winsock2.h>
882 "]
883 else
884 glib_inet_includes=["
885 #include <sys/types.h>
886 #include <sys/socket.h>
887 "]
888 fi
890 glib_failed=false
891 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
892 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
893 # winsock defines this even though it doesn't support it
894 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
895 if $glib_failed ; then
896 AC_MSG_ERROR([Could not determine values for AF_INET* constants])
897 fi
899 glib_failed=false
900 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
901 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
902 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
903 if $glib_failed ; then
904 AC_MSG_ERROR([Could not determine values for MSG_* constants])
905 fi
907 AC_CHECK_FUNCS(endservent if_nametoindex if_indextoname sendmmsg recvmmsg)
909 AC_MSG_CHECKING([for SIOCGIFADDR])
910 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
911 [[
912 #include <sys/ioctl.h>
913 #include <net/if.h>
914 ]],
915 [[
916 struct ifreq ifr;
917 ioctl(0, SIOCGIFADDR, &ifr);
918 ]])], [
919 AC_MSG_RESULT(yes)
920 AC_DEFINE(HAVE_SIOCGIFADDR, 1, [SIOCGIFADDR is available])
921 ], [
922 AC_MSG_RESULT(no)
923 ])
925 AC_MSG_CHECKING([if ip_mreq_source.imr_interface has s_addr member])
926 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
927 [[
928 #include <netinet/in.h>
929 ]],
930 [[
931 struct ip_mreq_source mc_req_src;
932 mc_req_src.imr_interface.s_addr = 0;
933 ]])], [
934 AC_MSG_RESULT(yes)
935 ], [
936 AC_MSG_RESULT(no)
937 AC_DEFINE(BROKEN_IP_MREQ_SOURCE_STRUCT, 1, [struct ip_mreq_source definition is broken on Android NDK <= r16])
938 ])
940 AS_IF([test $glib_native_win32 = yes], [
941 # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
942 # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
943 # they aren't present at run-time (on Windows 2000).
944 AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
945 AC_SUBST(WSPIAPI_INCLUDE)
946 ], [
947 # Android does not have C_IN in public headers, we define it wherever necessary
948 AS_IF([test $glib_native_android != yes], [
949 AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
950 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
951 #include <arpa/nameser.h>],
952 [int qclass = C_IN;])],
953 [AC_MSG_RESULT([no])],
954 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
955 #include <arpa/nameser.h>
956 #include <arpa/nameser_compat.h>],
957 [int qclass = C_IN;])],
958 [AC_MSG_RESULT([yes])
959 NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
960 [AC_MSG_ERROR([could not compile test program either way])])])])
961 AC_SUBST(NAMESER_COMPAT_INCLUDE)
963 # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
964 NETWORK_LIBS=""
965 AC_MSG_CHECKING([for res_query])
966 AC_TRY_LINK([#include <sys/types.h>
967 #include <netinet/in.h>
968 #include <arpa/nameser.h>
969 #include <resolv.h>
970 ],[
971 res_query("test", 0, 0, (void *)0, 0);
972 ],[AC_MSG_RESULT([yes])],
973 [save_libs="$LIBS"
974 LIBS="-lresolv $LIBS"
975 AC_TRY_LINK([#include <sys/types.h>
976 #include <netinet/in.h>
977 #include <arpa/nameser.h>
978 #include <resolv.h>
979 ],[
980 res_query("test", 0, 0, (void *)0, 0);
981 ],[AC_MSG_RESULT([in -lresolv])
982 NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
983 [LIBS="-lbind $save_libs"
984 AC_TRY_LINK([#include <resolv.h>],
985 [res_query("test", 0, 0, (void *)0, 0);],
986 [AC_MSG_RESULT([in -lbind])
987 NETWORK_LIBS="-lbind $NETWORK_LIBS"],
988 [AC_MSG_ERROR(not found)])])
989 LIBS="$save_libs"])
990 AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
991 [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
992 [AC_MSG_ERROR(Could not find socket())]))
993 save_libs="$LIBS"
994 LIBS="$LIBS $NETWORK_LIBS"
996 AC_MSG_CHECKING([for res_init])
997 AC_TRY_LINK([#include <sys/types.h>
998 #include <netinet/in.h>
999 #include <arpa/nameser.h>
1000 #include <resolv.h>
1001 ],[
1002 res_init();
1003 ],[AC_MSG_RESULT([yes])
1004 AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1005 ],[AC_MSG_RESULT([no])])
1007 AC_MSG_CHECKING([for res_nclose])
1008 AC_TRY_LINK([#include <sys/types.h>
1009 #include <netinet/in.h>
1010 #include <arpa/nameser.h>
1011 #include <resolv.h>
1012 ],[
1013 struct __res_state res;
1014 res_nclose(&res);
1015 ],[AC_MSG_RESULT([yes])
1016 AC_DEFINE(HAVE_RES_NCLOSE, 1, [Define to 1 if you have the 'res_nclose' function.])
1017 ],[AC_MSG_RESULT([no])])
1019 AC_MSG_CHECKING([for res_ndestroy])
1020 AC_TRY_LINK([#include <sys/types.h>
1021 #include <netinet/in.h>
1022 #include <arpa/nameser.h>
1023 #include <resolv.h>
1024 ],[
1025 struct __res_state res;
1026 res_ndestroy(&res);
1027 ],[AC_MSG_RESULT([yes])
1028 AC_DEFINE(HAVE_RES_NDESTROY, 1, [Define to 1 if you have the 'res_ndestroy' function.])
1029 ],[AC_MSG_RESULT([no])])
1031 AC_MSG_CHECKING([for res_ninit])
1032 AC_TRY_LINK([#include <sys/types.h>
1033 #include <netinet/in.h>
1034 #include <arpa/nameser.h>
1035 #include <resolv.h>
1036 ],[
1037 struct __res_state res;
1038 res_ninit(&res);
1039 ],[AC_MSG_RESULT([yes])
1040 AC_DEFINE(HAVE_RES_NINIT, 1, [Define to 1 if you have the 'res_ninit' function.])
1041 ],[AC_MSG_RESULT([no])])
1043 AC_MSG_CHECKING([for res_nquery])
1044 AC_TRY_LINK([#include <sys/types.h>
1045 #include <netinet/in.h>
1046 #include <arpa/nameser.h>
1047 #include <resolv.h>
1048 ],[
1049 struct __res_state res;
1050 res_nquery(&res, "test", 0, 0, (void *)0, 0);
1051 ],[AC_MSG_RESULT([yes])
1052 AC_DEFINE(HAVE_RES_NQUERY, 1, [Define to 1 if you have the 'res_nquery' function.])
1053 ],[AC_MSG_RESULT([no])])
1054 LIBS="$save_libs"
1055 ])
1056 AC_SUBST(NETWORK_LIBS)
1058 AC_CHECK_HEADER([linux/netlink.h],
1059 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1060 [#include <sys/socket.h>])
1061 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1063 AC_CHECK_TYPE([struct ip_mreqn], [
1064 AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1065 [#include <netinet/in.h>])
1067 case $host in
1068 *-*-solaris* )
1069 AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1070 AC_DEFINE(_XOPEN_SOURCE, 2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1071 AC_DEFINE(__EXTENSIONS__, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1072 ;;
1073 esac
1075 dnl
1076 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1077 dnl
1078 AS_IF([test "$ac_cv_func_statfs" = yes], [
1079 AC_MSG_CHECKING([number of arguments to statfs()])
1080 AC_TRY_COMPILE([#include <unistd.h>
1081 #ifdef HAVE_SYS_PARAM_H
1082 #include <sys/param.h>
1083 #endif
1084 #ifdef HAVE_SYS_VFS_H
1085 #include <sys/vfs.h>
1086 #endif
1087 #ifdef HAVE_SYS_MOUNT_H
1088 #include <sys/mount.h>
1089 #endif
1090 #ifdef HAVE_SYS_STATFS_H
1091 #include <sys/statfs.h>
1092 #endif], [struct statfs st;
1093 statfs("/", &st);],[
1094 AC_MSG_RESULT([2])
1095 AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1096 AC_TRY_COMPILE([#include <unistd.h>
1097 #ifdef HAVE_SYS_PARAM_H
1098 #include <sys/param.h>
1099 #endif
1100 #ifdef HAVE_SYS_VFS_H
1101 #include <sys/vfs.h>
1102 #endif
1103 #ifdef HAVE_SYS_MOUNT_H
1104 #include <sys/mount.h>
1105 #endif
1106 #ifdef HAVE_SYS_STATFS_H
1107 #include <sys/statfs.h>
1108 #endif], [struct statfs st;
1109 statfs("/", &st, sizeof (st), 0);],[
1110 AC_MSG_RESULT([4])
1111 AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1112 AC_MSG_RESULT(unknown)
1113 AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1114 ])
1116 dnl
1117 dnl open takes O_DIRECTORY as an option
1118 dnl
1119 AC_MSG_CHECKING([open() option O_DIRECTORY])
1120 AC_TRY_COMPILE([#include <fcntl.h>
1121 #include <sys/types.h>
1122 #include <sys/stat.h>],
1123 [open(0, O_DIRECTORY, 0);],[
1124 AC_MSG_RESULT([yes])
1125 AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1126 AC_MSG_RESULT([no])])
1128 #
1129 # Check whether to use an included printf
1130 #
1131 AC_FUNC_VSNPRINTF_C99
1132 AC_FUNC_PRINTF_UNIX98
1134 AC_ARG_ENABLE(included-printf,
1135 [AS_HELP_STRING([--enable-included-printf],
1136 [use included printf [default=auto]])],
1137 enable_included_printf="$enableval")
1139 need_included_printf=no
1140 if test "x$enable_included_printf" = "xyes" ; then
1141 need_included_printf=yes
1142 fi
1143 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1144 need_included_printf=yes
1145 fi
1146 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1147 need_included_printf=yes
1148 fi
1149 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1150 test -z "$glib_cv_long_long_format" ; then
1151 need_included_printf=yes
1152 fi
1154 if test "x$enable_included_printf" = "xno" &&
1155 test "x$need_included_printf" = "xyes" ; then
1156 AC_MSG_ERROR([
1157 *** Your C library's printf doesn't appear to have the features that
1158 *** GLib needs, but you specified --enable-included-printf=no.])
1159 fi
1161 enable_included_printf=$need_included_printf
1163 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1164 AS_IF([test "$enable_included_printf" != "yes"], [
1165 AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1166 ], [
1167 if test -z "$glib_cv_long_long_format" ; then
1168 glib_cv_long_long_format="ll"
1169 fi
1170 AC_DEFINE(HAVE_VASPRINTF,1)
1171 ])
1173 # Checks needed for gnulib vasnprintf
1174 bh_C_SIGNED
1175 jm_AC_TYPE_LONG_LONG
1176 gt_TYPE_LONGDOUBLE
1177 gt_TYPE_WCHAR_T
1178 gt_TYPE_WINT_T
1179 AC_TYPE_SIZE_T
1180 AC_CHECK_TYPES(ptrdiff_t)
1181 jm_AC_TYPE_INTMAX_T
1182 AC_CHECK_FUNCS([snprintf strnlen wcslen wcsnlen mbrtowc wcrtomb])
1183 AC_FUNC_SNPRINTF_C99
1185 dnl Check for nl_langinfo and CODESET
1186 AC_LANG_SAVE
1187 AC_LANG_C
1188 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1189 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1190 [char *codeset = nl_langinfo (CODESET);])],
1191 [glib_cv_langinfo_codeset=yes],
1192 [glib_cv_langinfo_codeset=no])])
1193 if test x$glib_cv_langinfo_codeset = xyes; then
1194 AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1195 fi
1197 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1198 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1199 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1200 [char *str;
1201 str = nl_langinfo (PM_STR);
1202 str = nl_langinfo (D_T_FMT);
1203 str = nl_langinfo (D_FMT);
1204 str = nl_langinfo (T_FMT);
1205 str = nl_langinfo (T_FMT_AMPM);
1206 str = nl_langinfo (MON_1);
1207 str = nl_langinfo (ABMON_12);
1208 str = nl_langinfo (DAY_1);
1209 str = nl_langinfo (ABDAY_7);])],
1210 [glib_cv_langinfo_time=yes],
1211 [glib_cv_langinfo_time=no])])
1212 if test x$glib_cv_langinfo_time = xyes; then
1213 AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1214 fi
1216 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1217 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1218 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1219 [char *str;
1220 str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1221 str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1222 str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1223 str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1224 str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1225 str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1226 str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1227 str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1228 str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1229 str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1230 [glib_cv_langinfo_outdigit=yes],
1231 [glib_cv_langinfo_outdigit=no])])
1232 if test x$glib_cv_langinfo_outdigit = xyes; then
1233 AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1234 fi
1236 dnl Check for nl_langinfo and ALTMON_n
1237 AC_CACHE_CHECK([for nl_langinfo (ALTMON_n)], glib_cv_langinfo_altmon,[
1238 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1239 [char *str;
1240 str = nl_langinfo (ALTMON_1);
1241 str = nl_langinfo (ALTMON_2);
1242 str = nl_langinfo (ALTMON_3);
1243 str = nl_langinfo (ALTMON_4);
1244 str = nl_langinfo (ALTMON_5);
1245 str = nl_langinfo (ALTMON_6);
1246 str = nl_langinfo (ALTMON_7);
1247 str = nl_langinfo (ALTMON_8);
1248 str = nl_langinfo (ALTMON_9);
1249 str = nl_langinfo (ALTMON_10);
1250 str = nl_langinfo (ALTMON_11);
1251 str = nl_langinfo (ALTMON_12);])],
1252 [glib_cv_langinfo_altmon=yes],
1253 [glib_cv_langinfo_altmon=no])])
1254 if test x$glib_cv_langinfo_altmon = xyes; then
1255 AC_DEFINE(HAVE_LANGINFO_ALTMON,1,[Have nl_langinfo (ALTMON_n)])
1256 fi
1258 dnl Check for nl_langinfo and _NL_ABALTMON_n
1259 AC_CACHE_CHECK([for nl_langinfo (_NL_ABALTMON_n)], glib_cv_langinfo_abaltmon,[
1260 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1261 [char *str;
1262 str = nl_langinfo (_NL_ABALTMON_1);
1263 str = nl_langinfo (_NL_ABALTMON_2);
1264 str = nl_langinfo (_NL_ABALTMON_3);
1265 str = nl_langinfo (_NL_ABALTMON_4);
1266 str = nl_langinfo (_NL_ABALTMON_5);
1267 str = nl_langinfo (_NL_ABALTMON_6);
1268 str = nl_langinfo (_NL_ABALTMON_7);
1269 str = nl_langinfo (_NL_ABALTMON_8);
1270 str = nl_langinfo (_NL_ABALTMON_9);
1271 str = nl_langinfo (_NL_ABALTMON_10);
1272 str = nl_langinfo (_NL_ABALTMON_11);
1273 str = nl_langinfo (_NL_ABALTMON_12);])],
1274 [glib_cv_langinfo_abaltmon=yes],
1275 [glib_cv_langinfo_abaltmon=no])])
1276 if test x$glib_cv_langinfo_abaltmon = xyes; then
1277 AC_DEFINE(HAVE_LANGINFO_ABALTMON,1,[Have nl_langinfo (_NL_ABALTMON_n)])
1278 fi
1279 AC_LANG_RESTORE
1282 dnl ****************************************
1283 dnl *** strlcpy/strlcat ***
1284 dnl ****************************************
1285 # Check for strlcpy
1286 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1287 AC_TRY_RUN([#include <stdlib.h>
1288 #include <string.h>
1289 int main() {
1290 char p[10];
1291 (void) strlcpy (p, "hi", 10);
1292 if (strlcat (p, "bye", 0) != 3)
1293 return 1;
1294 return 0;
1295 }], glib_cv_have_strlcpy=yes,
1296 glib_cv_have_strlcpy=no,
1297 glib_cv_have_strlcpy=no)])
1298 if test "$glib_cv_have_strlcpy" = "yes"; then
1299 AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1300 fi
1303 dnl **********************
1304 dnl *** va_copy checks ***
1305 dnl **********************
1306 dnl we currently check for all three va_copy possibilities, so we get
1307 dnl all results in config.log for bug reports.
1308 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1309 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1310 #include <stdlib.h>
1311 void f (int i, ...) {
1312 va_list args1, args2;
1313 va_start (args1, i);
1314 va_copy (args2, args1);
1315 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1316 exit (1);
1317 va_end (args1); va_end (args2);
1318 }
1319 int main() {
1320 f (0, 42);
1321 return 0;
1322 }]])],
1323 [glib_cv_va_copy=yes],
1324 [glib_cv_va_copy=no])
1325 ])
1326 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1327 AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1328 #include <stdlib.h>
1329 void f (int i, ...) {
1330 va_list args1, args2;
1331 va_start (args1, i);
1332 __va_copy (args2, args1);
1333 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1334 exit (1);
1335 va_end (args1); va_end (args2);
1336 }
1337 int main() {
1338 f (0, 42);
1339 return 0;
1340 }]])],
1341 [glib_cv___va_copy=yes],
1342 [glib_cv___va_copy=no])
1343 ])
1345 if test "x$glib_cv_va_copy" = "xyes"; then
1346 g_va_copy_func=va_copy
1347 else if test "x$glib_cv___va_copy" = "xyes"; then
1348 g_va_copy_func=__va_copy
1349 fi
1350 fi
1352 if test -n "$g_va_copy_func"; then
1353 AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1354 fi
1356 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1357 AC_TRY_RUN([#include <stdarg.h>
1358 #include <stdlib.h>
1359 void f (int i, ...) {
1360 va_list args1, args2;
1361 va_start (args1, i);
1362 args2 = args1;
1363 if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1364 exit (1);
1365 va_end (args1); va_end (args2);
1366 }
1367 int main() {
1368 f (0, 42);
1369 return 0;
1370 }],
1371 [glib_cv_va_val_copy=yes],
1372 [glib_cv_va_val_copy=no],
1373 [glib_cv_va_val_copy=yes])
1374 ])
1376 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1377 AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1378 ])
1380 dnl ***********************
1381 dnl *** g_module checks ***
1382 dnl ***********************
1383 G_MODULE_LIBS=
1384 G_MODULE_LIBS_EXTRA=
1385 G_MODULE_PLUGIN_LIBS=
1386 if test x"$glib_native_win32" = xyes; then
1387 dnl No use for this on Win32
1388 G_MODULE_LDFLAGS=
1389 else
1390 export SED
1391 eval G_MODULE_LDFLAGS=$export_dynamic_flag_spec
1392 fi
1393 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1394 G_MODULE_NEED_USCORE=0
1395 G_MODULE_BROKEN_RTLD_GLOBAL=0
1396 G_MODULE_HAVE_DLERROR=0
1397 dnl *** force native WIN32 shared lib loader
1398 if test -z "$G_MODULE_IMPL"; then
1399 case "$host" in
1400 *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1401 esac
1402 fi
1403 dnl *** force native AIX library loader
1404 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1405 if test -z "$G_MODULE_IMPL"; then
1406 case "$host" in
1407 *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1408 esac
1409 fi
1410 dnl *** dlopen() and dlsym() in system libraries
1411 AS_IF([ test -z "$G_MODULE_IMPL"], [
1412 AC_CHECK_FUNC(dlopen,
1413 [AC_CHECK_FUNC(dlsym,
1414 [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1415 [])
1416 ])
1417 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1418 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1419 AC_CHECK_FUNC(NSLinkModule,
1420 [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1421 G_MODULE_NEED_USCORE=1],
1422 [])
1423 ])
1424 dnl *** dlopen() and dlsym() in libdl
1425 AS_IF([ test -z "$G_MODULE_IMPL"], [
1426 AC_CHECK_LIB(dl, dlopen,
1427 [AC_CHECK_LIB(dl, dlsym,
1428 [G_MODULE_LIBS=-ldl
1429 G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1430 [])
1431 ])
1432 dnl *** additional checks for G_MODULE_IMPL_DL
1433 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1434 LIBS_orig="$LIBS"
1435 LDFLAGS_orig="$LDFLAGS"
1436 LIBS="$G_MODULE_LIBS $LIBS"
1437 LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1438 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1439 echo "void glib_plugin_test(void) { }" > plugin.c
1440 ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1441 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1442 ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1443 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1444 -shrext ".o" -avoid-version plugin.lo \
1445 -rpath /dont/care >/dev/null 2>&1
1446 AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1447 glib_cv_rtldglobal_broken,[
1448 AC_TRY_RUN([
1449 #include <dlfcn.h>
1450 #ifndef RTLD_GLOBAL
1451 # define RTLD_GLOBAL 0
1452 #endif
1453 #ifndef RTLD_LAZY
1454 # define RTLD_LAZY 0
1455 #endif
1456 int glib_plugin_test;
1457 int main () {
1458 void *handle, *global, *local;
1459 global = &glib_plugin_test;
1460 handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1461 if (!handle) return 0;
1462 local = dlsym (handle, "glib_plugin_test");
1463 return global == local;
1464 } ],
1465 [glib_cv_rtldglobal_broken=no],
1466 [glib_cv_rtldglobal_broken=yes],
1467 [glib_cv_rtldglobal_broken=no])
1468 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1469 rmdir ${objdir} 2>/dev/null
1470 ])
1471 if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1472 G_MODULE_BROKEN_RTLD_GLOBAL=1
1473 else
1474 G_MODULE_BROKEN_RTLD_GLOBAL=0
1475 fi
1476 dnl *** check whether we need preceeding underscores
1477 AC_CACHE_CHECK([for preceeding underscore in symbols],
1478 glib_cv_uscore,[
1479 AC_TRY_RUN([#include <dlfcn.h>
1480 int glib_underscore_test (void) { return 42; }
1481 int main() {
1482 void *f1 = (void*)0, *f2 = (void*)0, *handle;
1483 handle = dlopen ((void*)0, 0);
1484 if (handle) {
1485 f1 = dlsym (handle, "glib_underscore_test");
1486 f2 = dlsym (handle, "_glib_underscore_test");
1487 } return (!f2 || f1);
1488 }],
1489 [glib_cv_uscore=yes],
1490 [glib_cv_uscore=no],
1491 [])
1492 rm -f plugin.c plugin.$ac_objext plugin.lo
1493 ])
1494 GLIB_ASSERT_SET(glib_cv_uscore)
1495 if test "x$glib_cv_uscore" = "xyes"; then
1496 G_MODULE_NEED_USCORE=1
1497 else
1498 G_MODULE_NEED_USCORE=0
1499 fi
1501 AC_CHECK_DECL([RTLD_LAZY],
1502 [AC_DEFINE(HAVE_RTLD_LAZY, 1, [Define to 1 if RTLD_LAZY is available])],
1503 [], [[#include <dlfcn.h>]])
1504 AC_CHECK_DECL([RTLD_NOW],
1505 [AC_DEFINE(HAVE_RTLD_NOW, 1, [Define to 1 if RTLD_NOW is available])],
1506 [], [[#include <dlfcn.h>]])
1507 AC_CHECK_DECL([RTLD_GLOBAL],
1508 [AC_DEFINE(HAVE_RTLD_GLOBAL, 1, [Define to 1 if RTLD_GLOBAL is available])],
1509 [], [[#include <dlfcn.h>]])
1511 LDFLAGS="$LDFLAGS_orig"
1512 dnl *** check for having dlerror()
1513 AC_CHECK_FUNC(dlerror,
1514 [G_MODULE_HAVE_DLERROR=1],
1515 [G_MODULE_HAVE_DLERROR=0])
1516 LIBS="$LIBS_orig"
1517 ])
1518 dnl *** done, have we got an implementation?
1519 if test -z "$G_MODULE_IMPL"; then
1520 G_MODULE_IMPL=0
1521 G_MODULE_SUPPORTED=false
1522 else
1523 G_MODULE_SUPPORTED=true
1524 fi
1526 AC_MSG_CHECKING(for the suffix of module shared libraries)
1527 export SED
1528 module=yes eval std_shrext=$shrext_cmds
1529 # chop the initial dot
1530 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1531 AC_MSG_RESULT(.$glib_gmodule_suffix)
1532 # any reason it may fail?
1533 if test "x$glib_gmodule_suffix" = x; then
1534 AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1535 fi
1537 AC_SUBST(G_MODULE_SUPPORTED)
1538 AC_SUBST(G_MODULE_IMPL)
1539 AC_SUBST(G_MODULE_LIBS)
1540 AC_SUBST(G_MODULE_LIBS_EXTRA)
1541 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1542 AC_SUBST(G_MODULE_LDFLAGS)
1543 AC_SUBST(G_MODULE_HAVE_DLERROR)
1544 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1545 AC_SUBST(G_MODULE_NEED_USCORE)
1546 AC_SUBST(GLIB_DEBUG_FLAGS)
1548 dnl **********************
1549 dnl *** g_spawn checks ***
1550 dnl **********************
1552 AC_MSG_CHECKING(for gspawn implementation)
1553 case "$host" in
1554 *-*-mingw*)
1555 g_spawn_impl=win32
1556 ;;
1557 *)
1558 g_spawn_impl=unix
1559 ;;
1560 esac
1561 AC_MSG_RESULT($g_spawn_impl)
1562 AM_CONDITIONAL(G_SPAWN_WIN32, [test "$g_spawn_impl" = "win32"])
1564 dnl *************************
1565 dnl *** GIOChannel checks ***
1566 dnl *************************
1568 AC_MSG_CHECKING(for GIOChannel implementation)
1569 case "$host" in
1570 *-*-mingw*)
1571 g_io_channel_impl=win32
1572 ;;
1573 *)
1574 g_io_channel_impl=unix
1575 ;;
1576 esac
1577 AC_MSG_RESULT($g_io_channel_impl)
1578 AM_CONDITIONAL(G_IO_CHANNEL_WIN32, [test "$g_io_channel_impl" = "win32"])
1580 dnl *********************************
1581 dnl *** Directory for GIO modules ***
1582 dnl *********************************
1584 AC_ARG_WITH(gio-module-dir,
1585 [AS_HELP_STRING([--with-gio-module-dir=DIR],
1586 [load gio modules from this directory [LIBDIR/gio/modules]])],
1587 [],
1588 [with_gio_module_dir='${libdir}/gio/modules'])
1589 GIO_MODULE_DIR=$with_gio_module_dir
1590 AC_SUBST(GIO_MODULE_DIR)
1592 dnl **********************************
1593 dnl *** Check for libselinux (GIO) ***
1594 dnl **********************************
1595 AC_ARG_ENABLE(selinux,
1596 AS_HELP_STRING([--disable-selinux],
1597 [build without selinux support]))
1598 msg_selinux=no
1599 SELINUX_LIBS=
1600 AS_IF([ test "x$enable_selinux" != "xno"], [
1602 AC_CHECK_LIB(selinux, is_selinux_enabled,
1603 [AC_CHECK_HEADERS(selinux/selinux.h,
1604 [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1605 [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1606 SELINUX_LIBS="-lselinux"
1607 msg_selinux=yes])
1608 ])
1609 ])
1610 ])
1611 AC_SUBST(SELINUX_LIBS)
1613 dnl *****************************
1614 dnl ** Check for inotify (GIO) **
1615 dnl *****************************
1616 inotify_support=no
1617 AC_CHECK_HEADERS([sys/inotify.h],
1618 [
1619 AC_CHECK_FUNCS(inotify_init1, [inotify_support=yes], [inotify_support=no])
1620 ])
1622 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1624 dnl ****************************
1625 dnl ** Check for kqueue (GIO) **
1626 dnl ****************************
1627 kqueue_support=no
1628 AC_CHECK_HEADERS([sys/event.h],
1629 [
1630 AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1631 ])
1633 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1635 dnl ****************************
1636 dnl *** Checks for FAM (GIO) ***
1637 dnl ****************************
1639 should_disable_fam=no
1641 AC_ARG_ENABLE(fam,
1642 AS_HELP_STRING([--disable-fam],
1643 [don't use fam for file system monitoring]),
1644 [
1645 if test "x$enable_fam" = "xno"; then
1646 should_disable_fam=yes
1647 fi
1648 ]
1649 )
1650 fam_support=no
1651 FAM_LIBS=
1652 if test "x$should_disable_fam" = "xno"; then
1653 AC_CHECK_LIB(fam, FAMOpen,
1654 [AC_CHECK_HEADERS(fam.h,
1655 [AC_CHECK_LIB(fam, FAMNoExists,
1656 AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1657 FAM_LIBS="-lfam"]
1658 fam_support=yes,
1659 AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1660 AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1661 AC_SUBST(FAM_LIBS)
1662 fi
1663 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1666 dnl *****************************
1667 dnl *** Check for xattr (GIO) ***
1668 dnl *****************************
1669 AC_ARG_ENABLE(xattr,
1670 AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1671 msg_xattr=no
1672 XATTR_LIBS=
1673 AS_IF([ test "x$enable_xattr" != "xno"], [
1675 dnl either glibc or libattr can provide xattr support
1677 dnl for both of them, we check for getxattr being in
1678 dnl the library and a valid xattr header.
1680 dnl try glibc
1681 AC_CHECK_LIB(c, getxattr,
1682 [AC_CHECK_HEADERS(sys/xattr.h,
1683 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1684 msg_xattr=yes])
1685 ])
1687 AS_IF([ test "x$msg_xattr" != "xyes"], [
1688 dnl failure. try libattr
1689 AC_CHECK_LIB(attr, getxattr,
1690 [AC_CHECK_HEADERS(attr/xattr.h,
1691 [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1692 XATTR_LIBS="-lattr"
1693 msg_xattr=yes])
1694 ])
1695 ])
1697 AS_IF([ test "x$msg_xattr" = "xyes"], [
1698 AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1699 AC_TRY_COMPILE([
1700 #include <stdio.h>
1701 #ifdef HAVE_SYS_TYPES_H
1702 #include <sys/types.h>
1703 #endif
1704 #ifdef HAVE_SYS_XATTR_H
1705 #include <sys/xattr.h>
1706 #elif HAVE_ATTR_XATTR_H
1707 #include <attr/xattr.h>
1708 #endif
1709 ],
1710 [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1711 [
1712 AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1713 AC_MSG_RESULT([yes])
1714 ],
1715 [AC_MSG_RESULT([no])]
1716 )
1717 ])
1718 ])
1719 AC_SUBST(XATTR_LIBS)
1721 dnl ************************
1722 dnl *** check for libelf ***
1723 dnl ************************
1724 AC_ARG_ENABLE(libelf,
1725 AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1726 AS_IF([ test "x$enable_libelf" != "xno"],[
1727 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1728 AS_IF([ test $have_libelf = maybe ], [
1729 glib_save_LIBS=$LIBS
1730 AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1731 AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1732 AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1733 AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1734 LIBS=$glib_save_LIBS
1736 if test $have_libelf != no; then
1737 LIBELF_LIBS=-lelf
1738 have_libelf=yes
1739 fi
1740 ])
1741 ])
1743 if test x$have_libelf = xyes; then
1744 AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1745 fi
1747 dnl ************************
1748 dnl *** check for libmount ***
1749 dnl ************************
1751 dnl The fallback code doesn't really implement the same behaviors - e.g.
1752 dnl so on linux we want to require libmount unless specifically disabled
1753 dnl
1754 enable_libmount_default=${glib_os_linux:-no}
1755 AC_ARG_ENABLE(libmount,
1756 [AS_HELP_STRING([--enable-libmount],
1757 [build with libmount support [default for Linux]])],,
1758 [enable_libmount=$enable_libmount_default])
1759 AS_IF([ test "x$enable_libmount" = "xyes"],[
1760 PKG_CHECK_MODULES([LIBMOUNT], [mount >= 2.23], [have_libmount=yes], [have_libmount=no])
1761 if test $have_libmount = no ; then
1762 AC_MSG_ERROR([*** Could not find libmount])
1763 fi
1764 ])
1766 if test x$have_libmount = xyes; then
1767 AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available])
1768 fi
1769 AM_CONDITIONAL(HAVE_LIBMOUNT, [test x$have_libmount = xyes])
1771 dnl ****************************************
1772 dnl *** platform dependent source checks ***
1773 dnl ****************************************
1775 AC_MSG_CHECKING([whether to compile timeloop])
1776 case "$host" in
1777 *-*-cygwin*|*-*-mingw*|*-*-minix)
1778 enable_timeloop=no
1779 ;;
1780 *)
1781 enable_timeloop=yes
1782 ;;
1783 esac
1784 AC_MSG_RESULT($enable_timeloop)
1785 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1787 AC_MSG_CHECKING([if building for some Win32 platform])
1788 case "$host" in
1789 *-*-mingw*|*-*-cygwin*)
1790 platform_win32=yes
1791 ;;
1792 *)
1793 platform_win32=no
1794 ;;
1795 esac
1796 AC_MSG_RESULT($platform_win32)
1797 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1799 dnl ***********************
1800 dnl *** g_thread checks ***
1801 dnl ***********************
1803 AC_ARG_WITH(threads,
1804 [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1805 [specify a thread implementation to use])],
1806 [],
1807 [with_threads=yes])
1809 dnl error and warning message
1810 dnl *************************
1812 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1814 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1815 platform (normally it's "_REENTRANT"). I'll not use any flag on
1816 compilation now, but then your programs might not work.
1817 Please provide information on how it is done on your system."
1819 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1820 "
1822 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1823 provide information on your thread implementation."
1825 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1826 functions will not be MT-safe during their first call because
1827 there is no working 'getpwuid_r' on your system."
1829 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1830 because there is no 'localtime_r' on your system."
1832 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1833 linking threaded applications. As GLib cannot do that
1834 automatically, you will get an linkg error everytime you are
1835 not using the right compiler. In that case you have to relink
1836 with the right compiler. Ususally just '_r' is appended
1837 to the compiler name."
1839 dnl determination of thread implementation
1840 dnl ***************************************
1842 AC_MSG_CHECKING(for thread implementation)
1844 have_threads=no
1845 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1846 AS_IF([ test "x$have_threads" = xno], [
1847 AC_TRY_COMPILE([#include <pthread.h>],
1848 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1849 have_threads=posix)
1850 ])
1851 # Tru64Unix requires -pthread to find pthread.h. See #103020
1852 if test "x$have_threads" = xno; then
1853 glib_save_CPPFLAGS="$CPPFLAGS"
1854 CPPFLAGS="$CPPFLAGS -pthread"
1855 AC_TRY_COMPILE([#include <pthread.h>],
1856 [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1857 have_threads=posix)
1858 CPPFLAGS="$glib_save_CPPFLAGS"
1859 fi
1860 ])
1861 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1862 case $host in
1863 *-*-mingw*)
1864 have_threads=win32
1865 ;;
1866 esac
1867 fi
1869 if test "x$have_threads" = xno; then
1870 AC_MSG_RESULT(none available)
1871 AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1872 else
1873 AC_MSG_RESULT($have_threads)
1874 fi
1877 dnl determination of G_THREAD_CFLAGS
1878 dnl ********************************
1880 G_THREAD_LIBS=
1881 G_THREAD_LIBS_EXTRA=
1882 G_THREAD_CFLAGS=
1884 dnl
1885 dnl Test program for basic POSIX threads functionality
1886 dnl
1887 m4_define([glib_thread_test],[
1888 #include <pthread.h>
1889 int check_me = 0;
1890 void* func(void* data) {check_me = 42; return &check_me;}
1891 int main()
1892 { pthread_t t;
1893 void *ret;
1894 pthread_create (&t, $1, func, 0);
1895 pthread_join (t, &ret);
1896 return (check_me != 42 || ret != &check_me);
1897 }])
1899 AS_IF([ test x"$have_threads" = xposix], [
1900 # First we test for posix, whether -pthread or -pthreads do the trick as
1901 # both CPPFLAG and LIBS.
1902 # One of them does for most gcc versions and some other platforms/compilers
1903 # too and could be considered as the canonical way to go.
1904 case $host in
1905 *-*-cygwin*|*-*-darwin*)
1906 # skip cygwin and darwin -pthread or -pthreads test
1907 ;;
1908 *-solaris*)
1909 # These compiler/linker flags work with both Sun Studio and gcc
1910 # Sun Studio expands -mt to -D_REENTRANT and -lthread
1911 # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1912 G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1913 G_THREAD_LIBS="-lpthread -lthread"
1914 ;;
1915 *)
1916 for flag in pthread pthreads mt; do
1917 glib_save_CFLAGS="$CFLAGS"
1918 CFLAGS="$CFLAGS -$flag"
1919 AC_TRY_RUN(glib_thread_test(0),
1920 glib_flag_works=yes,
1921 glib_flag_works=no,
1922 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1923 glib_flag_works=yes,
1924 glib_flag_works=no)])
1925 CFLAGS="$glib_save_CFLAGS"
1926 if test $glib_flag_works = yes ; then
1927 G_THREAD_CFLAGS=-$flag
1928 G_THREAD_LIBS=-$flag
1929 break;
1930 fi
1931 done
1932 ;;
1933 esac
1934 ])
1936 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
1938 # The canonical -pthread[s] does not work. Try something different.
1940 case $host in
1941 *-aix*)
1942 if test x"$GCC" = xyes; then
1943 # GCC 3.0 and above needs -pthread.
1944 # Should be coverd by the case above.
1945 # GCC 2.x and below needs -mthreads
1946 G_THREAD_CFLAGS="-mthreads"
1947 G_THREAD_LIBS=$G_THREAD_CFLAGS
1948 else
1949 # We are probably using the aix compiler. Normaly a
1950 # program would have to be compiled with the _r variant
1951 # of the corresponding compiler, but we as GLib cannot
1952 # do that: but the good news is that for compiling the
1953 # only difference is the added -D_THREAD_SAFE compile
1954 # option. This is according to the "C for AIX User's
1955 # Guide".
1956 G_THREAD_CFLAGS="-D_THREAD_SAFE"
1957 fi
1958 ;;
1959 *-sysv5uw7*) # UnixWare 7
1960 # We are not using gcc with -pthread. Catched above.
1961 G_THREAD_CFLAGS="-Kthread"
1962 G_THREAD_LIBS=$G_THREAD_CFLAGS
1963 ;;
1964 *-mingw*)
1965 # No flag needed when using MSVCRT.DLL
1966 G_THREAD_CFLAGS=""
1967 ;;
1968 *)
1969 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1970 ;;
1971 esac
1972 ])
1974 # if we are not finding the localtime_r function, then we probably are
1975 # not using the proper multithread flag
1977 glib_save_CPPFLAGS="$CPPFLAGS"
1978 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1980 # First we test, whether localtime_r is declared in time.h
1981 # directly. Then we test whether a macro localtime_r exists, in
1982 # which case localtime_r in the test program is replaced and thus
1983 # if we still find localtime_r in the output, it is not defined as
1984 # a macro.
1986 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1987 [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1988 localtime_r(a,b)],
1989 AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1991 CPPFLAGS="$glib_save_CPPFLAGS"
1993 AC_MSG_CHECKING(thread related cflags)
1994 AC_MSG_RESULT($G_THREAD_CFLAGS)
1995 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1997 dnl determination of G_THREAD_LIBS
1998 dnl ******************************
2000 AS_IF([test x$have_threads = xposix], [
2001 glib_save_CPPFLAGS="$CPPFLAGS"
2002 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2003 AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2004 case $host in
2005 *-aix*)
2006 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2007 # probably using the aix compiler.
2008 AC_MSG_WARN($AIX_COMPILE_INFO)
2009 ;;
2010 *)
2011 G_THREAD_LIBS=error
2012 glib_save_LIBS="$LIBS"
2013 for thread_lib in "" pthread pthread32 pthreads thread; do
2014 if test x"$thread_lib" = x; then
2015 add_thread_lib=""
2016 IN=""
2017 else
2018 add_thread_lib="-l$thread_lib"
2019 IN=" in -l$thread_lib"
2020 fi
2021 if test x"$have_threads" = xposix; then
2022 defattr=0
2023 else
2024 defattr=pthread_attr_default
2025 fi
2027 LIBS="$add_thread_lib $glib_save_LIBS"
2029 AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2030 AC_TRY_RUN(glib_thread_test($defattr),
2031 glib_result=yes,
2032 glib_result=no,
2033 [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2034 glib_result=yes,
2035 glib_result=no)])
2036 AC_MSG_RESULT($glib_result)
2038 if test "$glib_result" = "yes" ; then
2039 G_THREAD_LIBS="$add_thread_lib"
2040 break
2041 fi
2042 done
2043 if test "x$G_THREAD_LIBS" = xerror; then
2044 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2045 fi
2046 LIBS="$glib_save_LIBS"
2047 ;;
2048 esac
2049 ])
2051 g_threads_impl="POSIX"
2052 AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2053 AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2054 CPPFLAGS="$glib_save_CPPFLAGS"
2055 ], [test x$have_threads = xwin32], [
2056 AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2057 g_threads_impl="WIN32"
2058 ], [
2059 g_threads_impl="NONE"
2060 G_THREAD_LIBS=error
2061 ])
2062 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2063 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2065 if test "x$G_THREAD_LIBS" = xerror; then
2066 AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2067 fi
2069 AC_MSG_CHECKING(thread related libraries)
2070 AC_MSG_RESULT($G_THREAD_LIBS)
2072 dnl check for mt safe function variants and some posix functions
2073 dnl ************************************************************
2075 glib_save_LIBS="$LIBS"
2076 # we are not doing the following for now, as this might require glib
2077 # to always be linked with the thread libs on some platforms.
2078 # LIBS="$LIBS $G_THREAD_LIBS"
2079 AC_CHECK_FUNCS(localtime_r gmtime_r getpwuid_r getgrgid_r)
2081 LIBS="$G_THREAD_LIBS $LIBS"
2082 AS_IF([ test x"$have_threads" = xposix], [
2083 glib_save_CPPFLAGS="$CPPFLAGS"
2084 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2085 # This is not AC_CHECK_FUNC to also work with function
2086 # name mangling in header files.
2087 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2088 AC_LINK_IFELSE(
2089 [AC_LANG_PROGRAM(
2090 [#include <pthread.h>],
2091 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2092 [AC_MSG_RESULT(yes)
2093 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2094 [Have function pthread_attr_setstacksize])],
2095 [AC_MSG_RESULT(no)])
2096 AC_MSG_CHECKING(for pthread_condattr_setclock)
2097 AC_LINK_IFELSE(
2098 [AC_LANG_PROGRAM(
2099 [#include <pthread.h>],
2100 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2101 [AC_MSG_RESULT(yes)
2102 AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2103 [Have function pthread_condattr_setclock])],
2104 [AC_MSG_RESULT(no)])
2105 AC_MSG_CHECKING(for pthread_cond_timedwait_relative_np)
2106 AC_LINK_IFELSE(
2107 [AC_LANG_PROGRAM(
2108 [#include <pthread.h>],
2109 [pthread_cond_timedwait_relative_np(NULL, NULL, NULL)])],
2110 [AC_MSG_RESULT(yes)
2111 AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP,1,
2112 [Have function pthread_cond_timedwait_relative_np])],
2113 [AC_MSG_RESULT(no)])
2114 dnl Sets thread names on OS X 10.6, iOS 3.2 (and higher)
2115 AC_MSG_CHECKING(for pthread_setname_np(const char*))
2116 AC_LINK_IFELSE(
2117 [AC_LANG_PROGRAM(
2118 [#include <pthread.h>],
2119 [pthread_setname_np("example")])],
2120 [AC_MSG_RESULT(yes)
2121 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
2122 [Have function pthread_setname_np(const char*)])],
2123 [AC_MSG_RESULT(no)])
2124 dnl Sets thread names on Solaris 11.3 & higher
2125 AC_MSG_CHECKING(for pthread_setname_np(pthread_t, const char*))
2126 AC_LINK_IFELSE(
2127 [AC_LANG_PROGRAM(
2128 [#include <pthread.h>],
2129 [pthread_setname_np(pthread_self(), "example")])],
2130 [AC_MSG_RESULT(yes)
2131 AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITH_TID,1,
2132 [Have function pthread_setname_np(pthread_t, const char*)])],
2133 [AC_MSG_RESULT(no)])
2134 AC_MSG_CHECKING(for pthread_getname_np(pthread_t, name, len))
2135 AC_LINK_IFELSE(
2136 [AC_LANG_PROGRAM(
2137 [#include <pthread.h>],
2138 [[char name[16]; pthread_getname_np(pthread_self(), name, 16);]])],
2139 [AC_MSG_RESULT(yes)
2140 AC_DEFINE(HAVE_PTHREAD_GETNAME_NP,1,
2141 [Have function pthread_getname_np(pthread_t, name, len)])],
2142 [AC_MSG_RESULT(no)])
2143 CPPFLAGS="$glib_save_CPPFLAGS"
2144 ])
2146 LIBS="$glib_save_LIBS"
2148 # now spit out all the warnings.
2149 if test "$ac_cv_func_getpwuid_r" != "yes"; then
2150 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2151 fi
2152 if test "$ac_cv_func_localtime_r" != "yes"; then
2153 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2154 fi
2156 #
2157 # Hack to deal with:
2158 #
2159 # a) GCC < 3.3 for Linux doesn't include -lpthread when
2160 # building shared libraries with linux.
2161 # b) FreeBSD doesn't do this either.
2162 #
2163 case $host in
2164 *android*)
2165 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2166 ;;
2167 *-*-freebsd*|*-*-linux*)
2168 G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2169 ;;
2170 *)
2171 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2172 ;;
2173 esac
2175 AC_SUBST(G_THREAD_CFLAGS)
2176 AC_SUBST(G_THREAD_LIBS)
2177 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2178 AC_SUBST(G_THREAD_LIBS_EXTRA)
2180 AC_CHECK_FUNCS(clock_gettime, [], [
2181 AC_CHECK_LIB(rt, clock_gettime, [
2182 G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2183 G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2184 ])
2185 ])
2188 dnl ************************
2189 dnl *** g_atomic_* tests ***
2190 dnl ************************
2192 dnl We need to decide at configure time if GLib will use real atomic
2193 dnl operations ("lock free") or emulated ones with a mutex. This is
2194 dnl because we must put this information in glibconfig.h so we know if
2195 dnl it is safe or not to inline using compiler intrinsics directly from
2196 dnl the header.
2197 dnl
2198 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2199 dnl user is interested in knowing if they can use the atomic ops across
2200 dnl processes.
2201 dnl
2202 dnl We can currently support the atomic ops natively when building GLib
2203 dnl with recent versions of GCC or MSVC. MSVC doesn't run ./configure,
2204 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2205 dnl we are using GCC (and not mingw*).
2206 dnl
2207 dnl Note that the atomic ops are only available with GCC on x86 when
2208 dnl using -march=i486 or higher. If we detect that the atomic ops are
2209 dnl not available but would be available given the right flags, we want
2210 dnl to abort and advise the user to fix their CFLAGS. It's better to do
2211 dnl that then to silently fall back on emulated atomic ops just because
2212 dnl the user had the wrong build environment.
2214 dnl We may add other compilers here in the future...
2216 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2217 case $host in
2218 *-*-mingw*)
2219 glib_cv_g_atomic_lock_free=yes
2220 ;;
2221 *)
2222 AC_TRY_LINK([],
2223 [volatile int atomic = 2;\
2224 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2225 [glib_cv_g_atomic_lock_free=yes],
2226 [glib_cv_g_atomic_lock_free=no])
2227 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2228 SAVE_CFLAGS="${CFLAGS}"
2229 CFLAGS="-march=i486"
2230 AC_TRY_LINK([],
2231 [volatile int atomic = 2;\
2232 __sync_bool_compare_and_swap (&atomic, 2, 3);],
2233 [AC_MSG_ERROR([GLib must be built with -march=i486 or later.])],
2234 [])
2235 CFLAGS="${SAVE_CFLAGS}"
2236 fi
2237 ;;
2238 esac])
2241 case $host in
2242 *-*-mingw*)
2243 ;;
2244 *)
2245 # Some compilers support atomic operations but do not define
2246 # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2247 if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2248 AC_TRY_LINK([],
2249 [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2250 [],
2251 [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2252 fi
2253 ;;
2254 esac
2256 dnl We need a more robust approach here...
2257 case $host_cpu in
2258 i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2259 glib_memory_barrier_needed=no
2260 ;;
2261 sparc*|alpha*|powerpc*|ia64)
2262 glib_memory_barrier_needed=yes
2263 ;;
2264 *)
2265 glib_memory_barrier_needed=yes
2266 ;;
2267 esac
2269 dnl ************************
2270 dnl ** Check for futex(2) **
2271 dnl ************************
2272 AC_CACHE_CHECK(for futex(2) system call,
2273 glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2274 #include <linux/futex.h>
2275 #include <sys/syscall.h>
2276 #include <unistd.h>
2277 ],[
2278 syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2279 ])],glib_cv_futex=yes,glib_cv_futex=no))
2280 if test x"$glib_cv_futex" = xyes; then
2281 AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2282 fi
2284 AC_CACHE_CHECK(for eventfd(2) system call,
2285 glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2286 #include <sys/eventfd.h>
2287 #include <unistd.h>
2288 ],[
2289 eventfd (0, EFD_CLOEXEC);
2290 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2291 if test x"$glib_cv_eventfd" = x"yes"; then
2292 AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2293 fi
2294 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2296 dnl ****************************************
2297 dnl *** GLib POLL* compatibility defines ***
2298 dnl ****************************************
2300 glib_poll_includes=["
2301 #include <sys/types.h>
2302 #include <poll.h>
2303 "]
2305 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2306 test $ac_cv_func_poll = yes ], [
2307 glib_failed=false
2308 GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2309 GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2310 GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2311 GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2312 GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2313 GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2314 if $glib_failed ; then
2315 AC_MSG_ERROR([Could not determine values for POLL* constants])
2316 fi
2317 ], [
2318 glib_cv_value_POLLIN=1
2319 glib_cv_value_POLLOUT=4
2320 glib_cv_value_POLLPRI=2
2321 glib_cv_value_POLLERR=8
2322 glib_cv_value_POLLHUP=16
2323 glib_cv_value_POLLNVAL=32
2324 ])
2326 AC_MSG_CHECKING([for broken poll])
2327 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2328 #include <stdlib.h>
2329 #include <fcntl.h>
2330 #include <poll.h>
2331 int main(void) {
2332 struct pollfd fds[1];
2333 int fd;
2334 fd = open("/dev/null", 1);
2335 fds[0].fd = fd;
2336 fds[0].events = POLLIN;
2337 fds[0].revents = 0;
2338 if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2339 exit(1); /* Does not work for devices -- fail */
2340 }
2341 exit(0);
2342 }]])],
2343 [broken_poll=no],
2344 [broken_poll=yes
2345 AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2346 [broken_poll="no (cross compiling)"])
2347 AC_MSG_RESULT($broken_poll)
2349 dnl *********************
2350 dnl *** GRegex checks ***
2351 dnl *********************
2353 PCRE_REQUIRED_VERSION=8.31
2355 # Check if we should use the internal or the system-supplied pcre
2356 AC_ARG_WITH(pcre,
2357 [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2358 [whether to use system PCRE [default=system]])],
2359 [],
2360 [with_pcre=system])
2362 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2364 AS_IF([ test "x$with_pcre" = xsystem], [
2365 PKG_CHECK_MODULES(PCRE,
2366 libpcre >= $PCRE_REQUIRED_VERSION)
2367 AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2368 glib_save_CFLAGS="$CFLAGS"
2369 glib_save_LIBS="$LIBS"
2370 CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2371 AC_TRY_RUN([#include <pcre.h>
2372 int main () {
2373 int support;
2374 pcre_config (PCRE_CONFIG_UTF8, &support);
2375 if (!support)
2376 return 1;
2377 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2378 if (!support)
2379 return 1;
2380 return 0;
2381 }],
2382 glib_cv_pcre_has_unicode=yes,
2383 glib_cv_pcre_has_unicode=no,
2384 glib_cv_pcre_has_unicode=yes)
2385 CFLAGS="$glib_save_CFLAGS"
2386 LIBS="$glib_save_LIBS"
2387 ])
2388 if test "$glib_cv_pcre_has_unicode" = "no"; then
2389 AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2390 fi
2391 AC_SUBST(PCRE_CFLAGS)
2392 AC_SUBST(PCRE_LIBS)
2393 AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2394 PCRE_REQUIRES=libpcre
2395 AC_SUBST(PCRE_REQUIRES)
2396 ], [
2397 # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2398 AS_IF([ test x"$GCC" = xyes], [
2399 AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2400 save_CFLAGS="$CFLAGS"
2401 CFLAGS="$CFLAGS -Wno-pointer-sign"
2402 AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2403 AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2404 CFLAGS="$save_CFLAGS"
2405 ])
2406 ])
2407 AC_SUBST(PCRE_WARN_CFLAGS)
2409 dnl **********************
2410 dnl *** Win32 API libs ***
2411 dnl **********************
2413 case $host in
2414 *-*-cygwin*)
2415 G_LIBS_EXTRA="-luser32 -lkernel32"
2416 ;;
2417 *-*-mingw*)
2418 G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2419 ;;
2420 *)
2421 G_LIBS_EXTRA=""
2422 ;;
2423 esac
2424 AC_SUBST(G_LIBS_EXTRA)
2426 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2427 dnl since we need it for g_iconv()
2429 AC_MSG_CHECKING([for EILSEQ])
2430 AC_TRY_COMPILE([
2431 #include <errno.h>
2432 ],
2433 [
2434 int error = EILSEQ;
2435 ], have_eilseq=yes, have_eilseq=no);
2436 AC_MSG_RESULT($have_eilseq)
2438 dnl Add a conditional we can use when cross-compiling, so we avoid running
2439 dnl binaries
2440 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2442 dnl **************************
2443 dnl *** Checks for gtk-doc ***
2444 dnl **************************
2445 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2446 # it on it's own line.
2447 m4_ifdef([GTK_DOC_CHECK], [
2448 GTK_DOC_CHECK([1.20], [--flavour no-tmpl])
2449 ],[
2450 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2451 ])
2453 AC_ARG_ENABLE(man,
2454 [AS_HELP_STRING([--enable-man],
2455 [generate man pages [default=auto]])],,
2456 enable_man=maybe)
2458 AS_IF([test "$enable_man" != no], [
2459 AC_PATH_PROG([XSLTPROC], [xsltproc])
2460 AS_IF([test -z "$XSLTPROC"], [
2461 AS_IF([test "$enable_man" = yes], [
2462 AC_MSG_ERROR([xsltproc is required for --enable-man])
2463 ])
2464 enable_man=no
2465 ])
2466 ])
2468 AS_IF([ test "$enable_man" != no ], [
2469 dnl check for DocBook DTD in the local catalog
2470 JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2471 [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2472 AS_IF([test "$have_docbook_dtd" != yes], [
2473 AS_IF([test "$enable_man" = yes ], [
2474 AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2475 ])
2476 enable_man=no
2477 ])
2478 ])
2480 AS_IF([test "$enable_man" != no], [
2481 dnl check for DocBook XSL stylesheets in the local catalog
2482 JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2483 [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2484 AS_IF([ test "$have_docbook_style" != yes ], [
2485 AS_IF([ test "$enable_man" = yes ], [
2486 AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2487 ])
2488 enable_man=no
2489 ])
2490 ])
2492 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2494 AC_MSG_CHECKING([whether to generate man pages])
2495 AS_IF([ test "$enable_man" != no ], [
2496 AC_MSG_RESULT([yes])
2497 ], [
2498 AC_MSG_RESULT([no])
2499 ])
2501 dnl
2502 dnl Tracing
2503 dnl
2505 AC_ARG_ENABLE([dtrace],
2506 [AS_HELP_STRING([--enable-dtrace],
2507 [include tracing support for dtrace])])
2508 have_dtrace=no
2509 AC_MSG_CHECKING([whether to include dtrace tracing support])
2510 AS_IF([ test "x$enable_dtrace" != xno], [
2511 if test x$glib_have_carbon = xyes; then
2512 AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2513 else
2514 AC_MSG_RESULT([yes])
2515 AC_CHECK_PROGS(DTRACE, dtrace)
2516 if test -z "$DTRACE"; then
2517 if test "x$enable_dtrace" = xyes; then
2518 AC_MSG_ERROR([dtrace not found])
2519 fi
2520 else
2521 AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2522 [if test "x$enable_dtrace" = xyes; then
2523 AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2524 fi])
2525 fi
2526 fi
2527 ], [
2528 AC_MSG_RESULT([no])
2529 ])
2530 if test "x$have_dtrace" = xyes; then
2531 AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2532 fi
2533 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2535 AC_MSG_CHECKING([whether to include systemtap tracing support])
2536 AC_ARG_ENABLE([systemtap],
2537 [AS_HELP_STRING([--enable-systemtap],
2538 [include tracing support for systemtap])])
2539 have_systemtap=no
2540 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2541 have_systemtap=yes
2542 fi
2543 AC_MSG_RESULT(${have_systemtap})
2545 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2547 AC_ARG_WITH([tapset-install-dir],
2548 AS_HELP_STRING([--with-tapset-install-dir=DIR],
2549 [path where systemtap tapsets are installed [DATADIR/systemtap/tapset/HOST_CPU]]),
2550 [if test "x${withval}" = x; then
2551 ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset/${host_cpu}"
2552 else
2553 ABS_TAPSET_DIR="${withval}"
2554 fi],
2555 [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset/${host_cpu}"])
2556 AC_SUBST(ABS_TAPSET_DIR)
2558 dnl ************************************
2559 dnl *** Enable lcov coverage reports ***
2560 dnl ************************************
2562 AC_ARG_ENABLE(coverage,
2563 AS_HELP_STRING([--enable-coverage],
2564 [enable coverage testing with gcov]),
2565 [use_gcov=$enableval], [use_gcov=no])
2567 AS_IF([ test "x$use_gcov" = "xyes"], [
2568 dnl we need gcc:
2569 if test "$GCC" != "yes"; then
2570 AC_MSG_ERROR([GCC is required for --enable-coverage])
2571 fi
2573 dnl Check if ccache is being used
2574 AC_CHECK_PROG(SHTOOL, shtool, shtool)
2575 case `$SHTOOL path $CC` in
2576 *ccache*[)] gcc_ccache=yes;;
2577 *[)] gcc_ccache=no;;
2578 esac
2580 if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2581 AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2582 fi
2584 ltp_version_list="1.6 1.7 1.8 1.9 1.10 1.12"
2585 AC_CHECK_PROG(LTP, lcov, lcov)
2586 AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2588 AS_IF([ test "$LTP" ], [
2589 AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2590 glib_cv_ltp_version=invalid
2591 ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2592 for ltp_check_version in $ltp_version_list; do
2593 if test "$ltp_version" = "$ltp_check_version"; then
2594 glib_cv_ltp_version="$ltp_check_version (ok)"
2595 fi
2596 done
2597 ])
2598 ], [
2599 ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2600 AC_MSG_ERROR([$ltp_msg])
2601 ])
2603 case $glib_cv_ltp_version in
2604 ""|invalid[)]
2605 ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2606 AC_MSG_ERROR([$ltp_msg])
2607 LTP="exit 0;"
2608 ;;
2609 esac
2611 if test -z "$LTP_GENHTML"; then
2612 AC_MSG_ERROR([Could not find genhtml from the LTP package])
2613 fi
2615 dnl Remove all optimization flags from CFLAGS
2616 changequote({,})
2617 CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2618 changequote([,])
2620 dnl Add the special gcc flags
2621 CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2622 LDFLAGS="$LDFLAGS -lgcov"
2623 ])
2625 dnl *******************************
2626 dnl *** Disable strict aliasing ***
2627 dnl *******************************
2628 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=791622
2629 AS_IF([test "${GCC}" = "yes"],[
2630 CFLAGS="$CFLAGS -fno-strict-aliasing"
2631 ])
2633 dnl ******************************
2634 dnl *** output the whole stuff ***
2635 dnl ******************************
2637 dnl this section will only be run if config.status is invoked with no
2638 dnl arguments, or with "glib/glibconfig.h" as an argument.
2639 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2640 [
2641 outfile=glib/glibconfig.h-tmp
2642 cat > $outfile <<\_______EOF
2643 /* glibconfig.h
2644 *
2645 * This is a generated file. Please modify 'configure.ac'
2646 */
2648 #ifndef __GLIBCONFIG_H__
2649 #define __GLIBCONFIG_H__
2651 #include <glib/gmacros.h>
2653 _______EOF
2655 echo '#include <limits.h>' >> $outfile
2656 echo '#include <float.h>' >> $outfile
2657 if test x$glib_values_h = xyes; then
2658 echo '#include <values.h>' >> $outfile
2659 fi
2660 if test "$glib_header_alloca_h" = "yes"; then
2661 echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2662 fi
2663 if test x$glib_included_printf != xyes; then
2664 echo "
2665 /* Specifies that GLib's g_print*() functions wrap the
2666 * system printf functions. This is useful to know, for example,
2667 * when using glibc's register_printf_function().
2668 */" >> $outfile
2669 echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2670 fi
2672 cat >> $outfile <<_______EOF
2674 G_BEGIN_DECLS
2676 #define G_MINFLOAT FLT_MIN
2677 #define G_MAXFLOAT FLT_MAX
2678 #define G_MINDOUBLE DBL_MIN
2679 #define G_MAXDOUBLE DBL_MAX
2680 #define G_MINSHORT SHRT_MIN
2681 #define G_MAXSHORT SHRT_MAX
2682 #define G_MAXUSHORT USHRT_MAX
2683 #define G_MININT INT_MIN
2684 #define G_MAXINT INT_MAX
2685 #define G_MAXUINT UINT_MAX
2686 #define G_MINLONG LONG_MIN
2687 #define G_MAXLONG LONG_MAX
2688 #define G_MAXULONG ULONG_MAX
2690 _______EOF
2693 ### this should always be true in a modern C/C++ compiler
2694 ### and is statically asserted by glib-init.c
2695 cat >>$outfile <<_______EOF
2696 typedef signed char gint8;
2697 typedef unsigned char guint8;
2698 _______EOF
2701 if test -n "$gint16"; then
2702 cat >>$outfile <<_______EOF
2703 typedef signed $gint16 gint16;
2704 typedef unsigned $gint16 guint16;
2705 #define G_GINT16_MODIFIER $gint16_modifier
2706 #define G_GINT16_FORMAT $gint16_format
2707 #define G_GUINT16_FORMAT $guint16_format
2708 _______EOF
2709 fi
2712 if test -n "$gint32"; then
2713 cat >>$outfile <<_______EOF
2714 typedef signed $gint32 gint32;
2715 typedef unsigned $gint32 guint32;
2716 #define G_GINT32_MODIFIER $gint32_modifier
2717 #define G_GINT32_FORMAT $gint32_format
2718 #define G_GUINT32_FORMAT $guint32_format
2719 _______EOF
2720 fi
2722 cat >>$outfile <<_______EOF
2723 #define G_HAVE_GINT64 1 /* deprecated, always true */
2725 ${glib_extension}typedef signed $gint64 gint64;
2726 ${glib_extension}typedef unsigned $gint64 guint64;
2728 #define G_GINT64_CONSTANT(val) $gint64_constant
2729 #define G_GUINT64_CONSTANT(val) $guint64_constant
2730 _______EOF
2732 if test x$gint64_format != x ; then
2733 cat >>$outfile <<_______EOF
2734 #define G_GINT64_MODIFIER $gint64_modifier
2735 #define G_GINT64_FORMAT $gint64_format
2736 #define G_GUINT64_FORMAT $guint64_format
2737 _______EOF
2738 else
2739 cat >>$outfile <<_______EOF
2740 #undef G_GINT64_MODIFIER
2741 #undef G_GINT64_FORMAT
2742 #undef G_GUINT64_FORMAT
2743 _______EOF
2744 fi
2746 cat >>$outfile <<_______EOF
2748 #define GLIB_SIZEOF_VOID_P $glib_void_p
2749 #define GLIB_SIZEOF_LONG $glib_long
2750 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2751 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2753 _______EOF
2755 cat >>$outfile <<_______EOF
2756 typedef signed $glib_ssize_type_define gssize;
2757 typedef unsigned $glib_size_type_define gsize;
2758 #define G_GSIZE_MODIFIER $gsize_modifier
2759 #define G_GSSIZE_MODIFIER $gssize_modifier
2760 #define G_GSIZE_FORMAT $gsize_format
2761 #define G_GSSIZE_FORMAT $gssize_format
2763 #define G_MAXSIZE G_MAXU$glib_msize_type
2764 #define G_MINSSIZE G_MIN$glib_mssize_type
2765 #define G_MAXSSIZE G_MAX$glib_mssize_type
2767 typedef gint64 goffset;
2768 #define G_MINOFFSET G_MININT64
2769 #define G_MAXOFFSET G_MAXINT64
2771 #define G_GOFFSET_MODIFIER G_GINT64_MODIFIER
2772 #define G_GOFFSET_FORMAT G_GINT64_FORMAT
2773 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2775 #define G_POLLFD_FORMAT $g_pollfd_format
2777 _______EOF
2779 if test -z "$glib_unknown_void_p"; then
2780 cat >>$outfile <<_______EOF
2782 #define GPOINTER_TO_INT(p) ((gint) ${glib_gpi_cast} (p))
2783 #define GPOINTER_TO_UINT(p) ((guint) ${glib_gpui_cast} (p))
2785 #define GINT_TO_POINTER(i) ((gpointer) ${glib_gpi_cast} (i))
2786 #define GUINT_TO_POINTER(u) ((gpointer) ${glib_gpui_cast} (u))
2788 typedef signed $glib_intptr_type_define gintptr;
2789 typedef unsigned $glib_intptr_type_define guintptr;
2791 #define G_GINTPTR_MODIFIER $gintptr_modifier
2792 #define G_GINTPTR_FORMAT $gintptr_format
2793 #define G_GUINTPTR_FORMAT $guintptr_format
2794 _______EOF
2795 else
2796 echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2797 fi
2801 cat >>$outfile <<_______EOF
2802 #ifndef G_DISABLE_DEPRECATED
2803 #define g_ATEXIT(proc) (atexit (proc))
2804 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2805 #endif
2806 $glib_defines
2807 $glib_os
2808 $glib_static_compilation
2810 $glib_vacopy
2812 _______EOF
2814 if test x$g_have_iso_c_varargs = xyes ; then
2815 cat >>$outfile <<_______EOF
2816 #ifndef __cplusplus
2817 # define G_HAVE_ISO_VARARGS 1
2818 #endif
2819 _______EOF
2820 fi
2821 if test x$g_have_iso_cxx_varargs = xyes ; then
2822 cat >>$outfile <<_______EOF
2823 #ifdef __cplusplus
2824 # define G_HAVE_ISO_VARARGS 1
2825 #endif
2826 _______EOF
2827 fi
2828 if test x$g_have_gnuc_varargs = xyes ; then
2829 cat >>$outfile <<_______EOF
2831 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2832 * is passed ISO vararg support is turned off, and there is no work
2833 * around to turn it on, so we unconditionally turn it off.
2834 */
2835 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2836 # undef G_HAVE_ISO_VARARGS
2837 #endif
2839 #define G_HAVE_GNUC_VARARGS 1
2840 _______EOF
2841 fi
2843 case x$g_stack_grows in
2844 xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2845 *) echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2846 esac
2849 echo >>$outfile
2850 if test x$g_have_eilseq = xno; then
2851 cat >>$outfile <<_______EOF
2852 #ifndef EILSEQ
2853 /* On some pre-C99 systems, EILSEQ is not defined.
2854 * The correspondence between this and the corresponding definition
2855 * in libiconv is essential.
2856 */
2857 # define EILSEQ ENOENT
2858 #endif
2859 _______EOF
2861 fi
2863 if test x$g_have_gnuc_visibility = xyes; then
2864 cat >>$outfile <<_______EOF
2865 #define G_HAVE_GNUC_VISIBILITY 1
2866 _______EOF
2867 fi
2868 cat >>$outfile <<_______EOF
2869 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2870 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2871 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2872 #define G_GNUC_INTERNAL __hidden
2873 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2874 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2875 #else
2876 #define G_GNUC_INTERNAL
2877 #endif
2878 _______EOF
2880 echo >>$outfile
2881 cat >>$outfile <<_______EOF
2882 #define G_THREADS_ENABLED
2883 #define G_THREADS_IMPL_$g_threads_impl_def
2884 _______EOF
2886 if test x"$g_memory_barrier_needed" != xno; then
2887 echo >>$outfile
2888 echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2889 fi
2890 if test x"$g_atomic_lock_free" = xyes; then
2891 echo >>$outfile
2892 echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
2893 fi
2894 echo >>$outfile
2895 g_bit_sizes="16 32 64"
2896 for bits in $g_bit_sizes; do
2897 cat >>$outfile <<_______EOF
2898 #define GINT${bits}_TO_${g_bs_native}(val) ((gint${bits}) (val))
2899 #define GUINT${bits}_TO_${g_bs_native}(val) ((guint${bits}) (val))
2900 #define GINT${bits}_TO_${g_bs_alien}(val) ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2901 #define GUINT${bits}_TO_${g_bs_alien}(val) (GUINT${bits}_SWAP_LE_BE (val))
2902 _______EOF
2903 done
2905 cat >>$outfile <<_______EOF
2906 #define GLONG_TO_LE(val) ((glong) GINT${glongbits}_TO_LE (val))
2907 #define GULONG_TO_LE(val) ((gulong) GUINT${glongbits}_TO_LE (val))
2908 #define GLONG_TO_BE(val) ((glong) GINT${glongbits}_TO_BE (val))
2909 #define GULONG_TO_BE(val) ((gulong) GUINT${glongbits}_TO_BE (val))
2910 #define GINT_TO_LE(val) ((gint) GINT${gintbits}_TO_LE (val))
2911 #define GUINT_TO_LE(val) ((guint) GUINT${gintbits}_TO_LE (val))
2912 #define GINT_TO_BE(val) ((gint) GINT${gintbits}_TO_BE (val))
2913 #define GUINT_TO_BE(val) ((guint) GUINT${gintbits}_TO_BE (val))
2914 #define GSIZE_TO_LE(val) ((gsize) GUINT${gsizebits}_TO_LE (val))
2915 #define GSSIZE_TO_LE(val) ((gssize) GINT${gssizebits}_TO_LE (val))
2916 #define GSIZE_TO_BE(val) ((gsize) GUINT${gsizebits}_TO_BE (val))
2917 #define GSSIZE_TO_BE(val) ((gssize) GINT${gssizebits}_TO_BE (val))
2918 #define G_BYTE_ORDER $g_byte_order
2920 #define GLIB_SYSDEF_POLLIN =$g_pollin
2921 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2922 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2923 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2924 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2925 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2927 #define G_MODULE_SUFFIX "$g_module_suffix"
2929 typedef $g_pid_type GPid;
2930 #define G_PID_FORMAT $g_pid_format
2932 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
2933 #define GLIB_SYSDEF_AF_INET $g_af_inet
2934 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
2936 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
2937 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
2938 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
2940 #define G_DIR_SEPARATOR '$g_dir_separator'
2941 #define G_DIR_SEPARATOR_S "$g_dir_separator"
2942 #define G_SEARCHPATH_SEPARATOR '$g_searchpath_separator'
2943 #define G_SEARCHPATH_SEPARATOR_S "$g_searchpath_separator"
2945 G_END_DECLS
2947 #endif /* __GLIBCONFIG_H__ */
2948 _______EOF
2951 if cmp -s $outfile glib/glibconfig.h; then
2952 AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
2953 rm -f $outfile
2954 else
2955 mv $outfile glib/glibconfig.h
2956 fi
2957 ],[
2959 # Note that if two cases are the same, case goes with the first one.
2960 # Note also that this is inside an AC_OUTPUT_COMMAND. We do not depend
2961 # on variable expansion in case labels. Look at the generated config.status
2962 # for a hint.
2964 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2965 glib_header_alloca_h="$ac_cv_working_alloca_h"
2966 else
2967 glib_header_alloca_h="$ac_cv_header_alloca_h"
2968 fi
2970 if test x$enable_included_printf = xyes ; then
2971 glib_included_printf=yes
2972 fi
2974 case 2 in
2975 $ac_cv_sizeof_short)
2976 gint16=short
2977 gint16_modifier='"h"'
2978 gint16_format='"hi"'
2979 guint16_format='"hu"'
2980 ;;
2981 $ac_cv_sizeof_int)
2982 gint16=int
2983 gint16_modifier='""'
2984 gint16_format='"i"'
2985 guint16_format='"u"'
2986 ;;
2987 esac
2988 case 4 in
2989 $ac_cv_sizeof_short)
2990 gint32=short
2991 gint32_modifier='"h"'
2992 gint32_format='"hi"'
2993 guint32_format='"hu"'
2994 ;;
2995 $ac_cv_sizeof_int)
2996 gint32=int
2997 gint32_modifier='""'
2998 gint32_format='"i"'
2999 guint32_format='"u"'
3000 ;;
3001 $ac_cv_sizeof_long)
3002 gint32=long
3003 gint32_modifier='"l"'
3004 gint32_format='"li"'
3005 guint32_format='"lu"'
3006 ;;
3007 esac
3008 case 8 in
3009 $ac_cv_sizeof_int)
3010 gint64=int
3011 gint64_modifier='""'
3012 gint64_format='"i"'
3013 guint64_format='"u"'
3014 glib_extension=
3015 gint64_constant='(val)'
3016 guint64_constant='(val)'
3017 ;;
3018 $ac_cv_sizeof_long)
3019 gint64=long
3020 gint64_modifier='"l"'
3021 gint64_format='"li"'
3022 guint64_format='"lu"'
3023 glib_extension=
3024 gint64_constant='(val##L)'
3025 guint64_constant='(val##UL)'
3026 ;;
3027 $ac_cv_sizeof_long_long)
3028 gint64='long long'
3029 if test -n "$glib_cv_long_long_format"; then
3030 gint64_modifier='"'$glib_cv_long_long_format'"'
3031 gint64_format='"'$glib_cv_long_long_format'i"'
3032 guint64_format='"'$glib_cv_long_long_format'u"'
3033 fi
3034 glib_extension='G_GNUC_EXTENSION '
3035 gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3036 guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3037 ;;
3038 $ac_cv_sizeof___int64)
3039 gint64='__int64'
3040 if test -n "$glib_cv_long_long_format"; then
3041 gint64_modifier='"'$glib_cv_long_long_format'"'
3042 gint64_format='"'$glib_cv_long_long_format'i"'
3043 guint64_format='"'$glib_cv_long_long_format'u"'
3044 fi
3045 glib_extension=
3046 gint64_constant='(val##i64)'
3047 guint64_constant='(val##ui64)'
3048 ;;
3049 esac
3050 glib_size_t=$ac_cv_sizeof_size_t
3051 glib_ssize_t=$ac_cv_sizeof_ssize_t
3052 glib_size_type_define="$glib_size_type"
3053 glib_ssize_type_define="$glib_ssize_type"
3054 glib_void_p=$ac_cv_sizeof_void_p
3055 glib_long=$ac_cv_sizeof_long
3057 case "$glib_size_type" in
3058 short)
3059 gsize_modifier='"h"'
3060 gsize_format='"hu"'
3061 glib_msize_type='SHRT'
3062 ;;
3063 int)
3064 gsize_modifier='""'
3065 gsize_format='"u"'
3066 glib_msize_type='INT'
3067 ;;
3068 long)
3069 gsize_modifier='"l"'
3070 gsize_format='"lu"'
3071 glib_msize_type='LONG'
3072 ;;
3073 "long long"|__int64)
3074 gsize_modifier='"I64"'
3075 gsize_format='"I64u"'
3076 glib_msize_type='INT64'
3077 ;;
3078 esac
3080 case "$glib_ssize_type" in
3081 short)
3082 gssize_modifier='"h"'
3083 gssize_format='"hi"'
3084 glib_mssize_type='SHRT'
3085 ;;
3086 int)
3087 gssize_modifier='""'
3088 gssize_format='"i"'
3089 glib_mssize_type='INT'
3090 ;;
3091 long)
3092 gssize_modifier='"l"'
3093 gssize_format='"li"'
3094 glib_mssize_type='LONG'
3095 ;;
3096 "long long"|__int64)
3097 gssize_modifier='"I64"'
3098 gssize_format='"I64i"'
3099 glib_mssize_type='INT64'
3100 ;;
3101 esac
3103 gintbits=`expr $ac_cv_sizeof_int \* 8`
3104 glongbits=`expr $ac_cv_sizeof_long \* 8`
3105 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3106 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3108 case $ac_cv_sizeof_void_p in
3109 $ac_cv_sizeof_int)
3110 glib_intptr_type_define=int
3111 gintptr_modifier='""'
3112 gintptr_format='"i"'
3113 guintptr_format='"u"'
3114 glib_gpi_cast='(gint)'
3115 glib_gpui_cast='(guint)'
3116 ;;
3117 $ac_cv_sizeof_long)
3118 glib_intptr_type_define=long
3119 gintptr_modifier='"l"'
3120 gintptr_format='"li"'
3121 guintptr_format='"lu"'
3122 glib_gpi_cast='(glong)'
3123 glib_gpui_cast='(gulong)'
3124 ;;
3125 $ac_cv_sizeof_long_long)
3126 glib_intptr_type_define='long long'
3127 gintptr_modifier='"I64"'
3128 gintptr_format='"I64i"'
3129 guintptr_format='"I64u"'
3130 glib_gpi_cast='(gint64)'
3131 glib_gpui_cast='(guint64)'
3132 ;;
3133 $ac_cv_sizeof___int64)
3134 glib_intptr_type_define=__int64
3135 gintptr_modifier='"I64"'
3136 gintptr_format='"I64i"'
3137 guintptr_format='"I64u"'
3138 glib_gpi_cast='(gint64)'
3139 glib_gpui_cast='(guint64)'
3140 ;;
3141 *)
3142 glib_unknown_void_p=yes
3143 ;;
3144 esac
3147 glib_defines="
3148 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3149 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3150 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3151 "
3153 case xyes in
3154 x$glib_cv_va_copy) glib_vacopy='#define G_VA_COPY va_copy' ;;
3155 x$glib_cv___va_copy) glib_vacopy='#define G_VA_COPY __va_copy' ;;
3156 *) glib_vacopy=''
3157 esac
3159 if test x$glib_cv_va_val_copy = xno; then
3160 glib_vacopy="\$glib_vacopy
3161 #define G_VA_COPY_AS_ARRAY 1"
3162 fi
3164 g_have_gnuc_varargs=$g_have_gnuc_varargs
3165 g_have_iso_c_varargs=$g_have_iso_c_varargs
3166 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3168 g_have_gnuc_visibility=$g_have_gnuc_visibility
3169 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3171 if test x$ac_cv_c_bigendian = xyes; then
3172 g_byte_order=G_BIG_ENDIAN
3173 g_bs_native=BE
3174 g_bs_alien=LE
3175 else
3176 g_byte_order=G_LITTLE_ENDIAN
3177 g_bs_native=LE
3178 g_bs_alien=BE
3179 fi
3181 g_pollin=$glib_cv_value_POLLIN
3182 g_pollout=$glib_cv_value_POLLOUT
3183 g_pollpri=$glib_cv_value_POLLPRI
3184 g_pollhup=$glib_cv_value_POLLHUP
3185 g_pollerr=$glib_cv_value_POLLERR
3186 g_pollnval=$glib_cv_value_POLLNVAL
3188 # If a family is not found on the system, define that family to
3189 # a negative value, picking a different one for each undefined
3190 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3191 # This is needed because glib-mkenums doesn't handle optional
3192 # values in enums, and thus we have to have all existing values
3193 # defined in the enum.
3194 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3195 g_af_unix=$glib_cv_value_AF_UNIX
3196 else
3197 g_af_unix=-1
3198 fi
3199 g_af_inet=$glib_cv_value_AF_INET
3200 g_af_inet6=$glib_cv_value_AF_INET6
3202 g_msg_peek=$glib_cv_value_MSG_PEEK
3203 g_msg_oob=$glib_cv_value_MSG_OOB
3204 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3206 g_stack_grows=$glib_cv_stack_grows
3208 g_have_eilseq=$have_eilseq
3210 g_threads_impl_def=$g_threads_impl
3212 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3213 g_memory_barrier_needed="$glib_memory_barrier_needed"
3214 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3216 g_module_suffix="$glib_gmodule_suffix"
3217 g_dir_separator="$glib_dir_separator"
3218 g_searchpath_separator="$glib_searchpath_separator"
3220 g_pid_type="$glib_pid_type"
3221 g_pid_format="\"$glib_pid_format\""
3222 g_pollfd_format="\"$glib_pollfd_format\""
3224 case $host in
3225 *-*-cygwin*)
3226 glib_os="#define G_OS_UNIX
3227 #define G_PLATFORM_WIN32
3228 #define G_WITH_CYGWIN"
3229 ;;
3230 *-*-mingw*)
3231 glib_os="#define G_OS_WIN32
3232 #define G_PLATFORM_WIN32"
3233 ;;
3234 *)
3235 glib_os="#define G_OS_UNIX"
3236 ;;
3237 esac
3238 glib_static_compilation=""
3239 if test x$glib_win32_static_compilation = xyes; then
3240 glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3241 #define GOBJECT_STATIC_COMPILATION 1"
3242 fi
3243 ])
3245 # Redo enough to get guint32 and guint64 for the alignment checks below
3246 case 4 in
3247 $ac_cv_sizeof_short)
3248 gint32=short
3249 ;;
3250 $ac_cv_sizeof_int)
3251 gint32=int
3252 ;;
3253 $ac_cv_sizeof_long)
3254 gint32=long
3255 ;;
3256 esac
3257 case 8 in
3258 $ac_cv_sizeof_int)
3259 gint64=int
3260 ;;
3261 $ac_cv_sizeof_long)
3262 gint64=long
3263 ;;
3264 $ac_cv_sizeof_long_long)
3265 gint64='long long'
3266 ;;
3267 $ac_cv_sizeof___int64)
3268 gint64='__int64'
3269 ;;
3270 esac
3272 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3273 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3274 typedef unsigned $gint32 guint32;])
3275 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3276 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3277 typedef unsigned $gint64 guint64;])
3278 AC_CHECK_TYPE([unsigned long])
3279 AC_CHECK_ALIGNOF([unsigned long])
3281 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3282 #
3283 # 1.2.14 required for dbus_message_set_serial
3284 PKG_CHECK_MODULES(DBUS1,
3285 dbus-1 >= 1.2.14,
3286 [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3287 have_dbus1=no)
3288 AC_SUBST(DBUS1_CFLAGS)
3289 AC_SUBST(DBUS1_LIBS)
3290 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3292 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3293 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3295 # Check whether MSVC toolset is explicitly set
3296 AM_CONDITIONAL(MSVC_BASE_NO_TOOLSET_SET, [test x$MSVC_BASE_TOOLSET = x])
3297 AM_CONDITIONAL(MSVC_NO_TOOLSET_SET, [test x$MSVC_TOOLSET = x])
3299 dnl
3300 dnl Check for -Bsymbolic-functions linker flag used to avoid
3301 dnl intra-library PLT jumps, if available.
3302 dnl
3304 AC_ARG_ENABLE(Bsymbolic,
3305 [AS_HELP_STRING([--disable-Bsymbolic],
3306 [avoid linking with -Bsymbolic])],,
3307 [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3308 AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3309 LDFLAGS=-Wl,-Bsymbolic-functions
3310 LIBS=
3311 AC_TRY_LINK([], [return 0],
3312 AC_MSG_RESULT(yes)
3313 enable_Bsymbolic=yes,
3314 AC_MSG_RESULT(no)
3315 enable_Bsymbolic=no)
3316 LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3318 if test "x${enable_Bsymbolic}" = "xyes"; then
3319 GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3320 fi
3322 dnl
3323 dnl Check for -z,nodelete linker flag: the type system assumes that
3324 dnl libgobject stays loaded for the lifetime of the process.
3325 dnl Since ld.bfd does not treat wrong -z options as fatal by default,
3326 dnl we also try to check for the --fatal-warnings linker flag if
3327 dnl auto-detecting.
3328 dnl
3330 SAVED_CFLAGS="${CFLAGS}" SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3331 AC_MSG_CHECKING([for --fatal-warnings linker flag])
3332 CFLAGS="${SAVED_CFLAGS} ${shared_flag:- -shared}"
3333 LDFLAGS=-Wl,--fatal-warnings
3334 LIBS=
3335 AC_TRY_LINK([], [return 0],
3336 AC_MSG_RESULT(yes)
3337 [ldflags_fatal=-Wl,--fatal-warnings],
3338 AC_MSG_RESULT(no)
3339 ldflags_fatal=)
3341 AC_MSG_CHECKING([for -z,nodelete linker flag])
3342 LDFLAGS="$ldflags_fatal -Wl,-z,nodelete"
3343 AC_TRY_LINK([], [return 0],
3344 AC_MSG_RESULT(yes)
3345 enable_znodelete=yes,
3346 AC_MSG_RESULT(no)
3347 enable_znodelete=no)
3348 CFLAGS="${SAVED_CFLAGS}" LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"
3350 if test "x${enable_znodelete}" = "xyes"; then
3351 GLIB_LINK_FLAGS="$GLIB_LINK_FLAGS -Wl,-z,nodelete"
3352 fi
3354 AC_SUBST(GLIB_LINK_FLAGS)
3356 dnl
3357 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3358 dnl visibility attributes for symbol export control
3359 dnl
3360 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3361 case "$host" in
3362 *-*-mingw*)
3363 dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3364 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3365 [defines how to decorate public symbols while building])
3366 CFLAGS="${CFLAGS} -fvisibility=hidden"
3367 ;;
3368 *)
3369 dnl on other compilers, check if we can do -fvisibility=hidden
3370 SAVED_CFLAGS="${CFLAGS}"
3371 CFLAGS="-fvisibility=hidden"
3372 AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3373 AC_TRY_COMPILE([], [return 0],
3374 AC_MSG_RESULT(yes)
3375 enable_fvisibility_hidden=yes,
3376 AC_MSG_RESULT(no)
3377 enable_fvisibility_hidden=no)
3378 CFLAGS="${SAVED_CFLAGS}"
3380 AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3381 AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3382 [defines how to decorate public symbols while building])
3383 GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3384 ])
3385 ;;
3386 esac
3387 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3389 dnl Compiler flags; macro originates from systemd
3390 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3391 AC_ARG_ENABLE(compile-warnings,
3392 [AS_HELP_STRING([--disable-compile-warnings],
3393 [Don't use builtin compiler warnings])],,
3394 enable_compile_warnings=yes)
3395 AS_IF([test "x$enable_compile_warnings" != xno], [
3396 CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3397 -Wall -Wstrict-prototypes -Wduplicated-branches -Wmisleading-indentation \
3398 -Wno-bad-function-cast \
3399 -Werror=declaration-after-statement \
3400 -Werror=missing-prototypes -Werror=implicit-function-declaration \
3401 -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3402 -Werror=format=2 -Werror=missing-include-dirs])
3403 ])
3404 AC_SUBST(GLIB_WARN_CFLAGS)
3406 #
3407 # Define variables corresponding to the correct include paths to use for
3408 # in-tree building.
3409 #
3411 # for config.h:
3412 config_h_INCLUDES='-I$(top_builddir)'
3413 AC_SUBST(config_h_INCLUDES)
3415 # glib:
3416 # config.h
3417 # $(top_builddir)/glib: for glibconfig.h
3418 # $(top_srcdir)/glib: for glib.h
3419 # $(top_srcdir): for everything
3420 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3421 AC_SUBST(glib_INCLUDES)
3423 # gobject:
3424 # same as glib
3425 gobject_INCLUDES='$(glib_INCLUDES)'
3426 AC_SUBST(gobject_INCLUDES)
3428 # gmodule:
3429 # glib includes
3430 # $(top_srcdir)/gmodule: for gmodule.h
3431 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3432 AC_SUBST(gmodule_INCLUDES)
3434 # gio:
3435 # same as gmodule
3436 gio_INCLUDES='$(gmodule_INCLUDES)'
3437 AC_SUBST(gio_INCLUDES)
3440 AC_CONFIG_FILES([
3441 glib-2.0.pc
3442 gmodule-2.0.pc
3443 gmodule-export-2.0.pc
3444 gmodule-no-export-2.0.pc
3445 gthread-2.0.pc
3446 gobject-2.0.pc
3447 gio-2.0.pc
3448 gio-unix-2.0.pc
3449 gio-windows-2.0.pc
3450 glib-gettextize
3451 Makefile
3452 build/Makefile
3453 build/win32/Makefile
3454 build/win32/dirent/Makefile
3455 glib/Makefile
3456 glib/libcharset/Makefile
3457 glib/gnulib/Makefile
3458 glib/pcre/Makefile
3459 glib/update-pcre/Makefile
3460 glib/tests/Makefile
3461 gmodule/Makefile
3462 gmodule/gmoduleconf.h
3463 gobject/Makefile
3464 gobject/glib-genmarshal
3465 gobject/glib-mkenums
3466 gobject/tests/Makefile
3467 gthread/Makefile
3468 gio/Makefile
3469 gio/gdbus-2.0/codegen/Makefile
3470 gio/gdbus-2.0/codegen/config.py
3471 gio/gnetworking.h
3472 gio/xdgmime/Makefile
3473 gio/inotify/Makefile
3474 gio/kqueue/Makefile
3475 gio/fam/Makefile
3476 gio/win32/Makefile
3477 gio/tests/Makefile
3478 gio/tests/gdbus-object-manager-example/Makefile
3479 gio/tests/services/Makefile
3480 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3481 gio/tests/modules/Makefile
3482 po/Makefile.in
3483 docs/Makefile
3484 docs/reference/Makefile
3485 docs/reference/glib/Makefile
3486 docs/reference/glib/version.xml
3487 docs/reference/gobject/Makefile
3488 docs/reference/gobject/version.xml
3489 docs/reference/gio/Makefile
3490 docs/reference/gio/version.xml
3491 tests/Makefile
3492 tests/gobject/Makefile
3493 tests/refcount/Makefile
3494 m4macros/Makefile
3495 subprojects/Makefile
3496 ])
3498 # We need this command because the configure script will not preserve
3499 # the same attributes of the template files
3500 AC_CONFIG_COMMANDS([chmod-scripts],
3501 [chmod 0755 glib-gettextize
3502 chmod 0755 gobject/glib-genmarshal
3503 chmod 0755 gobject/glib-mkenums])
3505 # we want to invoke this macro solely so that the config.status script
3506 # and automake generated makefiles know about these generated files.
3507 # They are only needed to distcheck the package
3508 if false; then
3509 AC_CONFIG_FILES([
3510 INSTALL
3511 glib/glib.rc
3512 gmodule/gmodule.rc
3513 gobject/gobject.rc
3514 gthread/gthread.rc
3515 gio/gio.rc
3516 ])
3517 fi
3519 AC_OUTPUT