git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 $SIG{INT} = sub { print color("reset"), "\n"; exit };
  28
  29 package FakeTerm;
  30 sub new {
  31         my ($class, $reason) = @_;
  32         return bless \$reason, shift;
  33 }
  34 sub readline {
  35         my $self = shift;
  36         die "Cannot use readline on FakeTerm: $$self";
  37 }
  38 package main;
  39
  40
  41 sub usage {
  42         print <<EOT;
  43 git-send-email [options] <file | directory>...
  44 Options:
  45    --from         Specify the "From:" line of the email to be sent.
  46
  47    --to           Specify the primary "To:" line of the email.
  48
  49    --cc           Specify an initial "Cc:" list for the entire series
  50                   of emails.
  51
  52    --cc-cmd       Specify a command to execute per file which adds
  53                   per file specific cc address entries
  54
  55    --bcc          Specify a list of email addresses that should be Bcc:
  56                   on all the emails.
  57
  58    --compose      Use \$GIT_EDITOR, core.editor, \$EDITOR, or \$VISUAL to edit
  59                   an introductory message for the patch series.
  60
  61    --subject      Specify the initial "Subject:" line.
  62                   Only necessary if --compose is also set.  If --compose
  63                   is not set, this will be prompted for.
  64
  65    --in-reply-to  Specify the first "In-Reply-To:" header line.
  66                   Only used if --compose is also set.  If --compose is not
  67                   set, this will be prompted for.
  68
  69    --chain-reply-to If set, the replies will all be to the previous
  70                   email sent, rather than to the first email sent.
  71                   Defaults to on.
  72
  73    --signed-off-cc Automatically add email addresses that appear in
  74                  Signed-off-by: or Cc: lines to the cc: list. Defaults to on.
  75
  76    --identity     The configuration identity, a subsection to prioritise over
  77                   the default section.
  78
  79    --smtp-server  If set, specifies the outgoing SMTP server to use.
  80                   Defaults to localhost.
  81
  82    --smtp-user    The username for SMTP-AUTH.
  83
  84    --smtp-pass    The password for SMTP-AUTH.
  85
  86    --smtp-ssl     If set, connects to the SMTP server using SSL.
  87
  88    --suppress-from Suppress sending emails to yourself if your address
  89                   appears in a From: line. Defaults to off.
  90
  91    --thread       Specify that the "In-Reply-To:" header should be set on all
  92                   emails. Defaults to on.
  93
  94    --quiet        Make git-send-email less verbose.  One line per email
  95                   should be all that is output.
  96
  97    --dry-run      Do everything except actually send the emails.
  98
  99    --envelope-sender    Specify the envelope sender used to send the emails.
 100
 101 EOT
 102         exit(1);
 103 }
 104
 105 # most mail servers generate the Date: header, but not all...
 106 sub format_2822_time {
 107         my ($time) = @_;
 108         my @localtm = localtime($time);
 109         my @gmttm = gmtime($time);
 110         my $localmin = $localtm[1] + $localtm[2] * 60;
 111         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 112         if ($localtm[0] != $gmttm[0]) {
 113                 die "local zone differs from GMT by a non-minute interval\n";
 114         }
 115         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 116                 $localmin += 1440;
 117         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 118                 $localmin -= 1440;
 119         } elsif ($gmttm[6] != $localtm[6]) {
 120                 die "local time offset greater than or equal to 24 hours\n";
 121         }
 122         my $offset = $localmin - $gmtmin;
 123         my $offhour = $offset / 60;
 124         my $offmin = abs($offset % 60);
 125         if (abs($offhour) >= 24) {
 126                 die ("local time offset greater than or equal to 24 hours\n");
 127         }
 128
 129         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 130                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 131                        $localtm[3],
 132                        qw(Jan Feb Mar Apr May Jun
 133                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 134                        $localtm[5]+1900,
 135                        $localtm[2],
 136                        $localtm[1],
 137                        $localtm[0],
 138                        ($offset >= 0) ? '+' : '-',
 139                        abs($offhour),
 140                        $offmin,
 141                        );
 142 }
 143
 144 my $have_email_valid = eval { require Email::Valid; 1 };
 145 my $smtp;
 146
 147 sub unique_email_list(@);
 148 sub cleanup_compose_files();
 149
 150 # Constants (essentially)
 151 my $compose_filename = ".msg.$$";
 152
 153 # Variables we fill in automatically, or via prompting:
 154 my (@to,@cc,@initial_cc,@bcclist,@xh,
 155         $initial_reply_to,$initial_subject,@files,$author,$sender,$compose,$time);
 156
 157 my $envelope_sender;
 158
 159 # Example reply to:
 160 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 161
 162 my $repo = Git->repository();
 163 my $term = eval {
 164         new Term::ReadLine 'git-send-email';
 165 };
 166 if ($@) {
 167         $term = new FakeTerm "$@: going non-interactive";
 168 }
 169
 170 # Behavior modification variables
 171 my ($quiet, $dry_run) = (0, 0);
 172
 173 # Variables with corresponding config settings
 174 my ($thread, $chain_reply_to, $suppress_from, $signed_off_cc, $cc_cmd);
 175 my ($smtp_server, $smtp_authuser, $smtp_authpass, $smtp_ssl);
 176 my ($identity, $aliasfiletype, @alias_files);
 177
 178 my %config_bool_settings = (
 179     "thread" => [\$thread, 1],
 180     "chainreplyto" => [\$chain_reply_to, 1],
 181     "suppressfrom" => [\$suppress_from, 0],
 182     "signedoffcc" => [\$signed_off_cc, 1],
 183     "smtpssl" => [\$smtp_ssl, 0],
 184 );
 185
 186 my %config_settings = (
 187     "smtpserver" => \$smtp_server,
 188     "smtpuser" => \$smtp_authuser,
 189     "smtppass" => \$smtp_authpass,
 190     "cccmd" => \$cc_cmd,
 191     "aliasfiletype" => \$aliasfiletype,
 192     "bcc" => \@bcclist,
 193     "aliasesfile" => \@alias_files,
 194 );
 195
 196 # Begin by accumulating all the variables (defined above), that we will end up
 197 # needing, first, from the command line:
 198
 199 my $rc = GetOptions("sender|from=s" => \$sender,
 200                     "in-reply-to=s" => \$initial_reply_to,
 201                     "subject=s" => \$initial_subject,
 202                     "to=s" => \@to,
 203                     "cc=s" => \@initial_cc,
 204                     "bcc=s" => \@bcclist,
 205                     "chain-reply-to!" => \$chain_reply_to,
 206                     "smtp-server=s" => \$smtp_server,
 207                     "smtp-user=s" => \$smtp_authuser,
 208                     "smtp-pass=s" => \$smtp_authpass,
 209                     "smtp-ssl!" => \$smtp_ssl,
 210                     "identity=s" => \$identity,
 211                     "compose" => \$compose,
 212                     "quiet" => \$quiet,
 213                     "cc-cmd=s" => \$cc_cmd,
 214                     "suppress-from!" => \$suppress_from,
 215                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_cc,
 216                     "dry-run" => \$dry_run,
 217                     "envelope-sender=s" => \$envelope_sender,
 218                     "thread!" => \$thread,
 219          );
 220
 221 unless ($rc) {
 222     usage();
 223 }
 224
 225 # Now, let's fill any that aren't set in with defaults:
 226
 227 sub read_config {
 228         my ($prefix) = @_;
 229
 230         foreach my $setting (keys %config_bool_settings) {
 231                 my $target = $config_bool_settings{$setting}->[0];
 232                 $$target = $repo->config_bool("$prefix.$setting") unless (defined $$target);
 233         }
 234
 235         foreach my $setting (keys %config_settings) {
 236                 my $target = $config_settings{$setting};
 237                 if (ref($target) eq "ARRAY") {
 238                         unless (@$target) {
 239                                 my @values = $repo->config("$prefix.$setting");
 240                                 @$target = @values if (@values && defined $values[0]);
 241                         }
 242                 }
 243                 else {
 244                         $$target = $repo->config("$prefix.$setting") unless (defined $$target);
 245                 }
 246         }
 247 }
 248
 249 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 250 $identity = $repo->config("sendemail.identity") unless (defined $identity);
 251 read_config("sendemail.$identity") if (defined $identity);
 252 read_config("sendemail");
 253
 254 # fall back on builtin bool defaults
 255 foreach my $setting (values %config_bool_settings) {
 256         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 257 }
 258
 259 my ($repoauthor) = $repo->ident_person('author');
 260 my ($repocommitter) = $repo->ident_person('committer');
 261
 262 # Verify the user input
 263
 264 foreach my $entry (@to) {
 265         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 266 }
 267
 268 foreach my $entry (@initial_cc) {
 269         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 270 }
 271
 272 foreach my $entry (@bcclist) {
 273         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 274 }
 275
 276 my %aliases;
 277 my %parse_alias = (
 278         # multiline formats can be supported in the future
 279         mutt => sub { my $fh = shift; while (<$fh>) {
 280                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 281                         my ($alias, $addr) = ($1, $2);
 282                         $addr =~ s/#.*$//; # mutt allows # comments
 283                          # commas delimit multiple addresses
 284                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 285                 }}},
 286         mailrc => sub { my $fh = shift; while (<$fh>) {
 287                 if (/^alias\s+(\S+)\s+(.*)$/) {
 288                         # spaces delimit multiple addresses
 289                         $aliases{$1} = [ split(/\s+/, $2) ];
 290                 }}},
 291         pine => sub { my $fh = shift; while (<$fh>) {
 292                 if (/^(\S+)\t.*\t(.*)$/) {
 293                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 294                 }}},
 295         gnus => sub { my $fh = shift; while (<$fh>) {
 296                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 297                         $aliases{$1} = [ $2 ];
 298                 }}}
 299 );
 300
 301 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 302         foreach my $file (@alias_files) {
 303                 open my $fh, '<', $file or die "opening $file: $!\n";
 304                 $parse_alias{$aliasfiletype}->($fh);
 305                 close $fh;
 306         }
 307 }
 308
 309 ($sender) = expand_aliases($sender) if defined $sender;
 310
 311 my $prompting = 0;
 312 if (!defined $sender) {
 313         $sender = $repoauthor || $repocommitter;
 314         do {
 315                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 316         } while (!defined $_);
 317
 318         $sender = $_ if ($_);
 319         print "Emails will be sent from: ", $sender, "\n";
 320         $prompting++;
 321 }
 322
 323 if (!@to) {
 324         do {
 325                 $_ = $term->readline("Who should the emails be sent to? ",
 326                                 "");
 327         } while (!defined $_);
 328         my $to = $_;
 329         push @to, split /,/, $to;
 330         $prompting++;
 331 }
 332
 333 sub expand_aliases {
 334         my @cur = @_;
 335         my @last;
 336         do {
 337                 @last = @cur;
 338                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 339         } while (join(',',@cur) ne join(',',@last));
 340         return @cur;
 341 }
 342
 343 @to = expand_aliases(@to);
 344 @to = (map { sanitize_address($_) } @to);
 345 @initial_cc = expand_aliases(@initial_cc);
 346 @bcclist = expand_aliases(@bcclist);
 347
 348 if (!defined $initial_subject && $compose) {
 349         do {
 350                 $_ = $term->readline("What subject should the emails start with? ",
 351                         $initial_subject);
 352         } while (!defined $_);
 353         $initial_subject = $_;
 354         $prompting++;
 355 }
 356
 357 if ($thread && !defined $initial_reply_to && $prompting) {
 358         do {
 359                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ",
 360                         $initial_reply_to);
 361         } while (!defined $_);
 362
 363         $initial_reply_to = $_;
 364         $initial_reply_to =~ s/(^\s+|\s+$)//g;
 365 }
 366
 367 if (!defined $smtp_server) {
 368         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 369                 if (-x $_) {
 370                         $smtp_server = $_;
 371                         last;
 372                 }
 373         }
 374         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 375 }
 376
 377 if ($compose) {
 378         # Note that this does not need to be secure, but we will make a small
 379         # effort to have it be unique
 380         open(C,">",$compose_filename)
 381                 or die "Failed to open for writing $compose_filename: $!";
 382         print C "From $sender # This line is ignored.\n";
 383         printf C "Subject: %s\n\n", $initial_subject;
 384         printf C <<EOT;
 385 GIT: Please enter your email below.
 386 GIT: Lines beginning in "GIT: " will be removed.
 387 GIT: Consider including an overall diffstat or table of contents
 388 GIT: for the patch you are writing.
 389
 390 EOT
 391         close(C);
 392
 393         my $editor = $ENV{GIT_EDITOR} || $repo->config("core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 394         system($editor, $compose_filename);
 395
 396         open(C2,">",$compose_filename . ".final")
 397                 or die "Failed to open $compose_filename.final : " . $!;
 398
 399         open(C,"<",$compose_filename)
 400                 or die "Failed to open $compose_filename : " . $!;
 401
 402         while(<C>) {
 403                 next if m/^GIT: /;
 404                 print C2 $_;
 405         }
 406         close(C);
 407         close(C2);
 408
 409         do {
 410                 $_ = $term->readline("Send this email? (y|n) ");
 411         } while (!defined $_);
 412
 413         if (uc substr($_,0,1) ne 'Y') {
 414                 cleanup_compose_files();
 415                 exit(0);
 416         }
 417
 418         @files = ($compose_filename . ".final");
 419 }
 420
 421
 422 # Now that all the defaults are set, process the rest of the command line
 423 # arguments and collect up the files that need to be processed.
 424 for my $f (@ARGV) {
 425         if (-d $f) {
 426                 opendir(DH,$f)
 427                         or die "Failed to opendir $f: $!";
 428
 429                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 430                                 sort readdir(DH);
 431
 432         } elsif (-f $f) {
 433                 push @files, $f;
 434
 435         } else {
 436                 print STDERR "Skipping $f - not found.\n";
 437         }
 438 }
 439
 440 if (@files) {
 441         unless ($quiet) {
 442                 print $_,"\n" for (@files);
 443         }
 444 } else {
 445         print STDERR "\nNo patch files specified!\n\n";
 446         usage();
 447 }
 448
 449 # Variables we set as part of the loop over files
 450 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 451
 452 sub extract_valid_address {
 453         my $address = shift;
 454         my $local_part_regexp = '[^<>"\s@]+';
 455         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 456
 457         # check for a local address:
 458         return $address if ($address =~ /^($local_part_regexp)$/);
 459
 460         $address =~ s/^\s*<(.*)>\s*$/$1/;
 461         if ($have_email_valid) {
 462                 return scalar Email::Valid->address($address);
 463         } else {
 464                 # less robust/correct than the monster regexp in Email::Valid,
 465                 # but still does a 99% job, and one less dependency
 466                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 467                 return $1;
 468         }
 469 }
 470
 471 # Usually don't need to change anything below here.
 472
 473 # we make a "fake" message id by taking the current number
 474 # of seconds since the beginning of Unix time and tacking on
 475 # a random number to the end, in case we are called quicker than
 476 # 1 second since the last time we were called.
 477
 478 # We'll setup a template for the message id, using the "from" address:
 479
 480 sub make_message_id
 481 {
 482         my $date = time;
 483         my $pseudo_rand = int (rand(4200));
 484         my $du_part;
 485         for ($sender, $repocommitter, $repoauthor) {
 486                 $du_part = extract_valid_address(sanitize_address($_));
 487                 last if (defined $du_part and $du_part ne '');
 488         }
 489         if (not defined $du_part or $du_part eq '') {
 490                 use Sys::Hostname qw();
 491                 $du_part = 'user@' . Sys::Hostname::hostname();
 492         }
 493         my $message_id_template = "<%s-git-send-email-$du_part>";
 494         $message_id = sprintf $message_id_template, "$date$pseudo_rand";
 495         #print "new message id = $message_id\n"; # Was useful for debugging
 496 }
 497
 498
 499
 500 $time = time - scalar $#files;
 501
 502 sub unquote_rfc2047 {
 503         local ($_) = @_;
 504         if (s/=\?utf-8\?q\?(.*)\?=/$1/g) {
 505                 s/_/ /g;
 506                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 507         }
 508         return "$_";
 509 }
 510
 511 # use the simplest quoting being able to handle the recipient
 512 sub sanitize_address
 513 {
 514         my ($recipient) = @_;
 515         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 516
 517         if (not $recipient_name) {
 518                 return "$recipient";
 519         }
 520
 521         # if recipient_name is already quoted, do nothing
 522         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 523                 return $recipient;
 524         }
 525
 526         # rfc2047 is needed if a non-ascii char is included
 527         if ($recipient_name =~ /[^[:ascii:]]/) {
 528                 $recipient_name =~ s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 529                 $recipient_name =~ s/(.*)/=\?utf-8\?q\?$1\?=/;
 530         }
 531
 532         # double quotes are needed if specials or CTLs are included
 533         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 534                 $recipient_name =~ s/(["\\\r])/\\$1/;
 535                 $recipient_name = "\"$recipient_name\"";
 536         }
 537
 538         return "$recipient_name $recipient_addr";
 539
 540 }
 541
 542 sub send_message
 543 {
 544         my @recipients = unique_email_list(@to);
 545         @cc = (map { sanitize_address($_) } @cc);
 546         my $to = join (",\n\t", @recipients);
 547         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 548         @recipients = (map { extract_valid_address($_) } @recipients);
 549         my $date = format_2822_time($time++);
 550         my $gitversion = '@@GIT_VERSION@@';
 551         if ($gitversion =~ m/..GIT_VERSION../) {
 552             $gitversion = Git::version();
 553         }
 554
 555         my $cc = join(", ", unique_email_list(@cc));
 556         my $ccline = "";
 557         if ($cc ne '') {
 558                 $ccline = "\nCc: $cc";
 559         }
 560         my $sanitized_sender = sanitize_address($sender);
 561         make_message_id();
 562
 563         my $header = "From: $sanitized_sender
 564 To: $to${ccline}
 565 Subject: $subject
 566 Date: $date
 567 Message-Id: $message_id
 568 X-Mailer: git-send-email $gitversion
 569 ";
 570         if ($thread && $reply_to) {
 571
 572                 $header .= "In-Reply-To: $reply_to\n";
 573                 $header .= "References: $references\n";
 574         }
 575         if (@xh) {
 576                 $header .= join("\n", @xh) . "\n";
 577         }
 578
 579         my @sendmail_parameters = ('-i', @recipients);
 580         my $raw_from = $sanitized_sender;
 581         $raw_from = $envelope_sender if (defined $envelope_sender);
 582         $raw_from = extract_valid_address($raw_from);
 583         unshift (@sendmail_parameters,
 584                         '-f', $raw_from) if(defined $envelope_sender);
 585
 586         if ($dry_run) {
 587                 # We don't want to send the email.
 588         } elsif ($smtp_server =~ m#^/#) {
 589                 my $pid = open my $sm, '|-';
 590                 defined $pid or die $!;
 591                 if (!$pid) {
 592                         exec($smtp_server, @sendmail_parameters) or die $!;
 593                 }
 594                 print $sm "$header\n$message";
 595                 close $sm or die $?;
 596         } else {
 597                 if ($smtp_ssl) {
 598                         require Net::SMTP::SSL;
 599                         $smtp ||= Net::SMTP::SSL->new( $smtp_server, Port => 465 );
 600                 }
 601                 else {
 602                         require Net::SMTP;
 603                         $smtp ||= Net::SMTP->new( $smtp_server );
 604                 }
 605                 $smtp->auth( $smtp_authuser, $smtp_authpass )
 606                         or die $smtp->message if (defined $smtp_authuser);
 607                 $smtp->mail( $raw_from ) or die $smtp->message;
 608                 $smtp->to( @recipients ) or die $smtp->message;
 609                 $smtp->data or die $smtp->message;
 610                 $smtp->datasend("$header\n$message") or die $smtp->message;
 611                 $smtp->dataend() or die $smtp->message;
 612                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 613         }
 614         if ($quiet) {
 615                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 616         } else {
 617                 print (($dry_run ? "Dry-" : "")."OK. Log says:\nDate: $date\n");
 618                 if ($smtp_server !~ m#^/#) {
 619                         print "Server: $smtp_server\n";
 620                         print "MAIL FROM:<$raw_from>\n";
 621                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 622                 } else {
 623                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 624                 }
 625                 print "From: $sanitized_sender\nSubject: $subject\nCc: $cc\nTo: $to\n\n";
 626                 if ($smtp) {
 627                         print "Result: ", $smtp->code, ' ',
 628                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 629                 } else {
 630                         print "Result: OK\n";
 631                 }
 632         }
 633 }
 634
 635 $reply_to = $initial_reply_to;
 636 $references = $initial_reply_to || '';
 637 $subject = $initial_subject;
 638
 639 foreach my $t (@files) {
 640         open(F,"<",$t) or die "can't open file $t";
 641
 642         my $author = undef;
 643         @cc = @initial_cc;
 644         @xh = ();
 645         my $input_format = undef;
 646         my $header_done = 0;
 647         $message = "";
 648         while(<F>) {
 649                 if (!$header_done) {
 650                         if (/^From /) {
 651                                 $input_format = 'mbox';
 652                                 next;
 653                         }
 654                         chomp;
 655                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 656                                 $input_format = 'mbox';
 657                         }
 658
 659                         if (defined $input_format && $input_format eq 'mbox') {
 660                                 if (/^Subject:\s+(.*)$/) {
 661                                         $subject = $1;
 662
 663                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 664                                         if (unquote_rfc2047($2) eq $sender) {
 665                                                 next if ($suppress_from);
 666                                         }
 667                                         elsif ($1 eq 'From') {
 668                                                 $author = unquote_rfc2047($2);
 669                                         }
 670                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 671                                                 $2, $_) unless $quiet;
 672                                         push @cc, $2;
 673                                 }
 674                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 675                                         push @xh, $_;
 676                                 }
 677
 678                         } else {
 679                                 # In the traditional
 680                                 # "send lots of email" format,
 681                                 # line 1 = cc
 682                                 # line 2 = subject
 683                                 # So let's support that, too.
 684                                 $input_format = 'lots';
 685                                 if (@cc == 0) {
 686                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 687                                                 $_, $_) unless $quiet;
 688
 689                                         push @cc, $_;
 690
 691                                 } elsif (!defined $subject) {
 692                                         $subject = $_;
 693                                 }
 694                         }
 695
 696                         # A whitespace line will terminate the headers
 697                         if (m/^\s*$/) {
 698                                 $header_done = 1;
 699                         }
 700                 } else {
 701                         $message .=  $_;
 702                         if (/^(Signed-off-by|Cc): (.*)$/i && $signed_off_cc) {
 703                                 my $c = $2;
 704                                 chomp $c;
 705                                 push @cc, $c;
 706                                 printf("(sob) Adding cc: %s from line '%s'\n",
 707                                         $c, $_) unless $quiet;
 708                         }
 709                 }
 710         }
 711         close F;
 712
 713         if (defined $cc_cmd) {
 714                 open(F, "$cc_cmd $t |")
 715                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 716                 while(<F>) {
 717                         my $c = $_;
 718                         $c =~ s/^\s*//g;
 719                         $c =~ s/\n$//g;
 720                         push @cc, $c;
 721                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 722                                 $c, $cc_cmd) unless $quiet;
 723                 }
 724                 close F
 725                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 726         }
 727
 728         if (defined $author) {
 729                 $message = "From: $author\n\n$message";
 730         }
 731
 732         send_message();
 733
 734         # set up for the next message
 735         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 736                 $reply_to = $message_id;
 737                 if (length $references > 0) {
 738                         $references .= "\n $message_id";
 739                 } else {
 740                         $references = "$message_id";
 741                 }
 742         }
 743 }
 744
 745 if ($compose) {
 746         cleanup_compose_files();
 747 }
 748
 749 sub cleanup_compose_files() {
 750         unlink($compose_filename, $compose_filename . ".final");
 751
 752 }
 753
 754 $smtp->quit if $smtp;
 755
 756 sub unique_email_list(@) {
 757         my %seen;
 758         my @emails;
 759
 760         foreach my $entry (@_) {
 761                 if (my $clean = extract_valid_address($entry)) {
 762                         $seen{$clean} ||= 0;
 763                         next if $seen{$clean}++;
 764                         push @emails, $entry;
 765                 } else {
 766                         print STDERR "W: unable to extract a valid address",
 767                                         " from: $entry\n";
 768                 }
 769         }
 770         return @emails;
 771 }