configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 AC_DEFUN([GIT_ARG_SET_PATH],
  27 [AC_ARG_WITH([$1],
  28  [AS_HELP_STRING([--with-$1=PATH],
  29                  [provide PATH to $1])],
  30  [GIT_CONF_APPEND_PATH($1)],[])
  31 ])# GIT_ARG_SET_PATH
  32 #
  33 # GIT_CONF_APPEND_PATH(PROGRAM)
  34 # ------------------------------
  35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36 # Used by GIT_ARG_SET_PATH(PROGRAM)
  37 AC_DEFUN([GIT_CONF_APPEND_PATH],
  38 [PROGRAM=m4_toupper($1); \
  39 if test "$withval" = "no"; then \
  40         AC_MSG_ERROR([You cannot use git without $1]); \
  41 else \
  42         if test "$withval" = "yes"; then \
  43                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44         else \
  45                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  46         fi; \
  47 fi; \
  48 ]) # GIT_CONF_APPEND_PATH
  49 #
  50 # GIT_PARSE_WITH(PACKAGE)
  51 # -----------------------
  52 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  53 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  54 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  55 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  56 AC_DEFUN([GIT_PARSE_WITH],
  57 [PACKAGE=m4_toupper($1); \
  58 if test "$withval" = "no"; then \
  59         m4_toupper(NO_$1)=YesPlease; \
  60 elif test "$withval" = "yes"; then \
  61         m4_toupper(NO_$1)=; \
  62 else \
  63         m4_toupper(NO_$1)=; \
  64         GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  65 fi \
  66 ])# GIT_PARSE_WITH
  67
  68
  69 ## Site configuration related to programs (before tests)
  70 ## --with-PACKAGE[=ARG] and --without-PACKAGE
  71 #
  72 # Define SHELL_PATH to provide path to shell.
  73 GIT_ARG_SET_PATH(shell)
  74 #
  75 # Define PERL_PATH to provide path to Perl.
  76 GIT_ARG_SET_PATH(perl)
  77 #
  78
  79
  80 ## Checks for programs.
  81 AC_MSG_NOTICE([CHECKS for programs])
  82 #
  83 AC_PROG_CC([cc gcc])
  84 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
  85 AC_CHECK_TOOL(AR, ar, :)
  86 AC_CHECK_PROGS(TAR, [gtar tar])
  87
  88 ## Checks for libraries.
  89 AC_MSG_NOTICE([CHECKS for libraries])
  90 #
  91 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
  92 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
  93 AC_CHECK_LIB([crypto], [SHA1_Init],
  94 [NEEDS_SSL_WITH_CRYPTO=],
  95 [AC_CHECK_LIB([ssl], [SHA1_Init],
  96  [NEEDS_SSL_WITH_CRYPTO=YesPlease
  97   NEEDS_SSL_WITH_CRYPTO=],
  98  [NO_OPENSSL=YesPlease])])
  99 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 100 AC_SUBST(NO_OPENSSL)
 101 #
 102 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 103 # git-http-push are not built, and you cannot use http:// and https://
 104 # transports.
 105 AC_CHECK_LIB([curl], [curl_global_init],
 106 [NO_CURL=],
 107 [NO_CURL=YesPlease])
 108 AC_SUBST(NO_CURL)
 109 #
 110 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 111 # not built, and you cannot push using http:// and https:// transports.
 112 AC_CHECK_LIB([expat], [XML_ParserCreate],
 113 [NO_EXPAT=],
 114 [NO_EXPAT=YesPlease])
 115 AC_SUBST(NO_EXPAT)
 116 #
 117 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 118 # some Solaris installations).
 119 # Define NO_ICONV if neither libc nor libiconv support iconv.
 120 AC_DEFUN([ICONVTEST_SRC], [
 121 #include <iconv.h>
 122
 123 int main(void)
 124 {
 125         iconv_open("", "");
 126         return 0;
 127 }
 128 ])
 129 AC_MSG_CHECKING([for iconv in -lc])
 130 AC_LINK_IFELSE(ICONVTEST_SRC,
 131         [AC_MSG_RESULT([yes])
 132         NEEDS_LIBICONV=],
 133         [AC_MSG_RESULT([no])
 134         old_LIBS="$LIBS"
 135         LIBS="$LIBS -liconv"
 136         AC_MSG_CHECKING([for iconv in -liconv])
 137         AC_LINK_IFELSE(ICONVTEST_SRC,
 138                 [AC_MSG_RESULT([yes])
 139                 NEEDS_LIBICONV=YesPlease],
 140                 [AC_MSG_RESULT([no])
 141                 NO_ICONV=YesPlease])
 142         LIBS="$old_LIBS"])
 143 AC_SUBST(NEEDS_LIBICONV)
 144 AC_SUBST(NO_ICONV)
 145 test -n "$NEEDS_LIBICONV" && LIBS="$LIBS -liconv"
 146 #
 147 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 148 # Patrick Mauritz).
 149 AC_CHECK_LIB([c], [socket],
 150 [NEEDS_SOCKET=],
 151 [NEEDS_SOCKET=YesPlease])
 152 AC_SUBST(NEEDS_SOCKET)
 153 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 154
 155
 156 ## Checks for header files.
 157
 158
 159 ## Checks for typedefs, structures, and compiler characteristics.
 160 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 161 #
 162 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 163 AC_CHECK_MEMBER(struct dirent.d_ino,
 164 [NO_D_INO_IN_DIRENT=],
 165 [NO_D_INO_IN_DIRENT=YesPlease],
 166 [#include <dirent.h>])
 167 AC_SUBST(NO_D_INO_IN_DIRENT)
 168 #
 169 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 170 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 171 AC_CHECK_MEMBER(struct dirent.d_type,
 172 [NO_D_TYPE_IN_DIRENT=],
 173 [NO_D_TYPE_IN_DIRENT=YesPlease],
 174 [#include <dirent.h>])
 175 AC_SUBST(NO_D_TYPE_IN_DIRENT)
 176 #
 177 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 178 # sockaddr_storage.
 179 AC_CHECK_TYPE(struct sockaddr_storage,
 180 [NO_SOCKADDR_STORAGE=],
 181 [NO_SOCKADDR_STORAGE=YesPlease],[
 182 #include <sys/types.h>
 183 #include <sys/socket.h>
 184 ])
 185 AC_SUBST(NO_SOCKADDR_STORAGE)
 186 #
 187 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 188 AC_CHECK_TYPE([struct addrinfo],[
 189  AC_CHECK_FUNC([getaddrinfo],
 190   [NO_IPV6=],
 191   [NO_IPV6=YesPlease])
 192 ],[NO_IPV6=YesPlease],[
 193 #include <sys/types.h>
 194 #include <sys/socket.h>
 195 #include <netdb.h>
 196 ])
 197 AC_SUBST(NO_IPV6)
 198 #
 199 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 200 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
 201 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 202 # some C compilers supported these specifiers prior to C99 as an extension.
 203 AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 204  [ac_cv_c_c99_format],
 205 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 206 AC_RUN_IFELSE(
 207         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 208                 [[char buf[64];
 209                 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 210                   exit(1);
 211                 else if (strcmp(buf, "12345"))
 212                   exit(2);]])],
 213         [ac_cv_c_c99_format=yes],
 214         [ac_cv_c_c99_format=no])
 215 ])
 216 if test $ac_cv_c_c99_format = no; then
 217         NO_C99_FORMAT=YesPlease
 218 else
 219         NO_C99_FORMAT=
 220 fi
 221 AC_SUBST(NO_C99_FORMAT)
 222
 223
 224 ## Checks for library functions.
 225 ## (in default C library and libraries checked by AC_CHECK_LIB)
 226 AC_MSG_NOTICE([CHECKS for library functions])
 227 #
 228 # Define NO_STRCASESTR if you don't have strcasestr.
 229 AC_CHECK_FUNC(strcasestr,
 230 [NO_STRCASESTR=],
 231 [NO_STRCASESTR=YesPlease])
 232 AC_SUBST(NO_STRCASESTR)
 233 #
 234 # Define NO_STRLCPY if you don't have strlcpy.
 235 AC_CHECK_FUNC(strlcpy,
 236 [NO_STRLCPY=],
 237 [NO_STRLCPY=YesPlease])
 238 AC_SUBST(NO_STRLCPY)
 239 #
 240 # Define NO_SETENV if you don't have setenv in the C library.
 241 AC_CHECK_FUNC(setenv,
 242 [NO_SETENV=],
 243 [NO_SETENV=YesPlease])
 244 AC_SUBST(NO_SETENV)
 245 #
 246 # Define NO_MMAP if you want to avoid mmap.
 247 #
 248 # Define NO_ICONV if your libc does not properly support iconv.
 249
 250
 251 ## Other checks.
 252 # Define USE_PIC if you need the main git objects to be built with -fPIC
 253 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 254 #
 255 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 256 # Enable it on Windows.  By default, symrefs are still used.
 257
 258 ## Site configuration (override autodetection)
 259 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 260 AC_MSG_NOTICE([CHECKS for site configuration])
 261 #
 262 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 263 # tests.  These tests take up a significant amount of the total test time
 264 # but are not needed unless you plan to talk to SVN repos.
 265 #
 266 # Define MOZILLA_SHA1 environment variable when running make to make use of
 267 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 268 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 269 # choice) has very fast version optimized for i586.
 270 #
 271 # Define PPC_SHA1 environment variable when running make to make use of
 272 # a bundled SHA1 routine optimized for PowerPC.
 273 #
 274 # Define ARM_SHA1 environment variable when running make to make use of
 275 # a bundled SHA1 routine optimized for ARM.
 276 #
 277 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 278 # This also implies MOZILLA_SHA1.
 279 #
 280 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 281 # /foo/bar/include and /foo/bar/lib directories.
 282 AC_ARG_WITH(openssl,
 283 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 284 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 285 GIT_PARSE_WITH(openssl))
 286 #
 287 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 288 # git-http-push are not built, and you cannot use http:// and https://
 289 # transports.
 290 #
 291 # Define CURLDIR=/foo/bar if your curl header and library files are in
 292 # /foo/bar/include and /foo/bar/lib directories.
 293 AC_ARG_WITH(curl,
 294 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 295 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 296 GIT_PARSE_WITH(curl))
 297 #
 298 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 299 # not built, and you cannot push using http:// and https:// transports.
 300 #
 301 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 302 # /foo/bar/include and /foo/bar/lib directories.
 303 AC_ARG_WITH(expat,
 304 AS_HELP_STRING([--with-expat],
 305 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 306 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 307 GIT_PARSE_WITH(expat))
 308 #
 309 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 310 # installed in /sw, but don't want GIT to link against any libraries
 311 # installed there.  If defined you may specify your own (or Fink's)
 312 # include directories and library directories by defining CFLAGS
 313 # and LDFLAGS appropriately.
 314 #
 315 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 316 # have DarwinPorts installed in /opt/local, but don't want GIT to
 317 # link against any libraries installed there.  If defined you may
 318 # specify your own (or DarwinPort's) include directories and
 319 # library directories by defining CFLAGS and LDFLAGS appropriately.
 320 #
 321 # Define NO_MMAP if you want to avoid mmap.
 322 #
 323 # Define NO_ICONV if your libc does not properly support iconv.
 324 AC_ARG_WITH(iconv,
 325 AS_HELP_STRING([--without-iconv],
 326 [if your architecture doesn't properly support iconv])
 327 AS_HELP_STRING([--with-iconv=PATH],
 328 [PATH is prefix for libiconv library and headers])
 329 AS_HELP_STRING([],
 330 [used only if you need linking with libiconv]),
 331 GIT_PARSE_WITH(iconv))
 332
 333 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 334 #
 335 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 336 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 337 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 338 # randomly break unless your underlying filesystem supports those sub-second
 339 # times (my ext3 doesn't).
 340 #
 341 # Define USE_STDEV below if you want git to care about the underlying device
 342 # change being considered an inode change from the update-cache perspective.
 343
 344
 345 ## Output files
 346 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 347 AC_OUTPUT
 348
 349
 350 ## Cleanup
 351 rm -f "${config_append}"