configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 AC_DEFUN([GIT_ARG_SET_PATH],
  27 [AC_ARG_WITH([$1],
  28  [AS_HELP_STRING([--with-$1=PATH],
  29                  [provide PATH to $1])],
  30  [GIT_CONF_APPEND_PATH($1)],[])
  31 ])# GIT_ARG_SET_PATH
  32 #
  33 # GIT_CONF_APPEND_PATH(PROGRAM)
  34 # ------------------------------
  35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36 # Used by GIT_ARG_SET_PATH(PROGRAM)
  37 AC_DEFUN([GIT_CONF_APPEND_PATH],
  38 [PROGRAM=m4_toupper($1); \
  39 if test "$withval" = "no"; then \
  40         AC_MSG_ERROR([You cannot use git without $1]); \
  41 else \
  42         if test "$withval" = "yes"; then \
  43                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44         else \
  45                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  46         fi; \
  47 fi; \
  48 ]) # GIT_CONF_APPEND_PATH
  49 #
  50 # GIT_PARSE_WITH(PACKAGE)
  51 # -----------------------
  52 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  53 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  54 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  55 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  56 AC_DEFUN([GIT_PARSE_WITH],
  57 [PACKAGE=m4_toupper($1); \
  58 if test "$withval" = "no"; then \
  59         m4_toupper(NO_$1)=YesPlease; \
  60 elif test "$withval" = "yes"; then \
  61         m4_toupper(NO_$1)=; \
  62 else \
  63         m4_toupper(NO_$1)=; \
  64         GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  65 fi \
  66 ])# GIT_PARSE_WITH
  67
  68
  69 ## Site configuration related to programs (before tests)
  70 ## --with-PACKAGE[=ARG] and --without-PACKAGE
  71 #
  72 # Define SHELL_PATH to provide path to shell.
  73 GIT_ARG_SET_PATH(shell)
  74 #
  75 # Define PERL_PATH to provide path to Perl.
  76 GIT_ARG_SET_PATH(perl)
  77 #
  78 # Declare the with-tcltk/without-tcltk options.
  79 AC_ARG_WITH(tcltk,
  80 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
  81 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
  82 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
  83 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
  84 GIT_PARSE_WITH(tcltk))
  85 #
  86
  87
  88 ## Checks for programs.
  89 AC_MSG_NOTICE([CHECKS for programs])
  90 #
  91 AC_PROG_CC([cc gcc])
  92 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
  93 AC_CHECK_TOOL(AR, ar, :)
  94 AC_CHECK_PROGS(TAR, [gtar tar])
  95 # TCLTK_PATH will be set to some value if we want Tcl/Tk
  96 # or will be empty otherwise.
  97 if test -z "$NO_TCLTK"; then
  98   if test "$with_tcltk" = ""; then
  99   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 100     TCLTK_PATH=wish
 101     AC_SUBST(TCLTK_PATH)
 102   elif test "$with_tcltk" = "yes"; then
 103   # Tcl/Tk check requested.
 104     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 105   else
 106     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 107     TCLTK_PATH="$with_tcltk"
 108     AC_SUBST(TCLTK_PATH)
 109   fi
 110 fi
 111
 112 ## Checks for libraries.
 113 AC_MSG_NOTICE([CHECKS for libraries])
 114 #
 115 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 116 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 117 AC_CHECK_LIB([crypto], [SHA1_Init],
 118 [NEEDS_SSL_WITH_CRYPTO=],
 119 [AC_CHECK_LIB([ssl], [SHA1_Init],
 120  [NEEDS_SSL_WITH_CRYPTO=YesPlease
 121   NEEDS_SSL_WITH_CRYPTO=],
 122  [NO_OPENSSL=YesPlease])])
 123 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 124 AC_SUBST(NO_OPENSSL)
 125 #
 126 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 127 # git-http-push are not built, and you cannot use http:// and https://
 128 # transports.
 129 AC_CHECK_LIB([curl], [curl_global_init],
 130 [NO_CURL=],
 131 [NO_CURL=YesPlease])
 132 AC_SUBST(NO_CURL)
 133 #
 134 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 135 # not built, and you cannot push using http:// and https:// transports.
 136 AC_CHECK_LIB([expat], [XML_ParserCreate],
 137 [NO_EXPAT=],
 138 [NO_EXPAT=YesPlease])
 139 AC_SUBST(NO_EXPAT)
 140 #
 141 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 142 # some Solaris installations).
 143 # Define NO_ICONV if neither libc nor libiconv support iconv.
 144 AC_DEFUN([ICONVTEST_SRC], [
 145 #include <iconv.h>
 146
 147 int main(void)
 148 {
 149         iconv_open("", "");
 150         return 0;
 151 }
 152 ])
 153 AC_MSG_CHECKING([for iconv in -lc])
 154 AC_LINK_IFELSE(ICONVTEST_SRC,
 155         [AC_MSG_RESULT([yes])
 156         NEEDS_LIBICONV=],
 157         [AC_MSG_RESULT([no])
 158         old_LIBS="$LIBS"
 159         LIBS="$LIBS -liconv"
 160         AC_MSG_CHECKING([for iconv in -liconv])
 161         AC_LINK_IFELSE(ICONVTEST_SRC,
 162                 [AC_MSG_RESULT([yes])
 163                 NEEDS_LIBICONV=YesPlease],
 164                 [AC_MSG_RESULT([no])
 165                 NO_ICONV=YesPlease])
 166         LIBS="$old_LIBS"])
 167 AC_SUBST(NEEDS_LIBICONV)
 168 AC_SUBST(NO_ICONV)
 169 test -n "$NEEDS_LIBICONV" && LIBS="$LIBS -liconv"
 170 #
 171 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 172 # Patrick Mauritz).
 173 AC_CHECK_LIB([c], [socket],
 174 [NEEDS_SOCKET=],
 175 [NEEDS_SOCKET=YesPlease])
 176 AC_SUBST(NEEDS_SOCKET)
 177 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 178
 179
 180 ## Checks for header files.
 181
 182
 183 ## Checks for typedefs, structures, and compiler characteristics.
 184 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 185 #
 186 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 187 AC_CHECK_MEMBER(struct dirent.d_ino,
 188 [NO_D_INO_IN_DIRENT=],
 189 [NO_D_INO_IN_DIRENT=YesPlease],
 190 [#include <dirent.h>])
 191 AC_SUBST(NO_D_INO_IN_DIRENT)
 192 #
 193 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 194 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 195 AC_CHECK_MEMBER(struct dirent.d_type,
 196 [NO_D_TYPE_IN_DIRENT=],
 197 [NO_D_TYPE_IN_DIRENT=YesPlease],
 198 [#include <dirent.h>])
 199 AC_SUBST(NO_D_TYPE_IN_DIRENT)
 200 #
 201 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 202 # sockaddr_storage.
 203 AC_CHECK_TYPE(struct sockaddr_storage,
 204 [NO_SOCKADDR_STORAGE=],
 205 [NO_SOCKADDR_STORAGE=YesPlease],[
 206 #include <sys/types.h>
 207 #include <sys/socket.h>
 208 ])
 209 AC_SUBST(NO_SOCKADDR_STORAGE)
 210 #
 211 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 212 AC_CHECK_TYPE([struct addrinfo],[
 213  AC_CHECK_FUNC([getaddrinfo],
 214   [NO_IPV6=],
 215   [NO_IPV6=YesPlease])
 216 ],[NO_IPV6=YesPlease],[
 217 #include <sys/types.h>
 218 #include <sys/socket.h>
 219 #include <netdb.h>
 220 ])
 221 AC_SUBST(NO_IPV6)
 222 #
 223 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 224 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
 225 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 226 # some C compilers supported these specifiers prior to C99 as an extension.
 227 AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 228  [ac_cv_c_c99_format],
 229 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 230 AC_RUN_IFELSE(
 231         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 232                 [[char buf[64];
 233                 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 234                   exit(1);
 235                 else if (strcmp(buf, "12345"))
 236                   exit(2);]])],
 237         [ac_cv_c_c99_format=yes],
 238         [ac_cv_c_c99_format=no])
 239 ])
 240 if test $ac_cv_c_c99_format = no; then
 241         NO_C99_FORMAT=YesPlease
 242 else
 243         NO_C99_FORMAT=
 244 fi
 245 AC_SUBST(NO_C99_FORMAT)
 246
 247
 248 ## Checks for library functions.
 249 ## (in default C library and libraries checked by AC_CHECK_LIB)
 250 AC_MSG_NOTICE([CHECKS for library functions])
 251 #
 252 # Define NO_STRCASESTR if you don't have strcasestr.
 253 AC_CHECK_FUNC(strcasestr,
 254 [NO_STRCASESTR=],
 255 [NO_STRCASESTR=YesPlease])
 256 AC_SUBST(NO_STRCASESTR)
 257 #
 258 # Define NO_STRLCPY if you don't have strlcpy.
 259 AC_CHECK_FUNC(strlcpy,
 260 [NO_STRLCPY=],
 261 [NO_STRLCPY=YesPlease])
 262 AC_SUBST(NO_STRLCPY)
 263 #
 264 # Define NO_SETENV if you don't have setenv in the C library.
 265 AC_CHECK_FUNC(setenv,
 266 [NO_SETENV=],
 267 [NO_SETENV=YesPlease])
 268 AC_SUBST(NO_SETENV)
 269 #
 270 # Define NO_MMAP if you want to avoid mmap.
 271 #
 272 # Define NO_ICONV if your libc does not properly support iconv.
 273
 274
 275 ## Other checks.
 276 # Define USE_PIC if you need the main git objects to be built with -fPIC
 277 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 278 #
 279 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 280 # Enable it on Windows.  By default, symrefs are still used.
 281
 282 ## Site configuration (override autodetection)
 283 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 284 AC_MSG_NOTICE([CHECKS for site configuration])
 285 #
 286 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 287 # tests.  These tests take up a significant amount of the total test time
 288 # but are not needed unless you plan to talk to SVN repos.
 289 #
 290 # Define MOZILLA_SHA1 environment variable when running make to make use of
 291 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 292 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 293 # choice) has very fast version optimized for i586.
 294 #
 295 # Define PPC_SHA1 environment variable when running make to make use of
 296 # a bundled SHA1 routine optimized for PowerPC.
 297 #
 298 # Define ARM_SHA1 environment variable when running make to make use of
 299 # a bundled SHA1 routine optimized for ARM.
 300 #
 301 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 302 # This also implies MOZILLA_SHA1.
 303 #
 304 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 305 # /foo/bar/include and /foo/bar/lib directories.
 306 AC_ARG_WITH(openssl,
 307 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 308 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 309 GIT_PARSE_WITH(openssl))
 310 #
 311 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 312 # git-http-push are not built, and you cannot use http:// and https://
 313 # transports.
 314 #
 315 # Define CURLDIR=/foo/bar if your curl header and library files are in
 316 # /foo/bar/include and /foo/bar/lib directories.
 317 AC_ARG_WITH(curl,
 318 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 319 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 320 GIT_PARSE_WITH(curl))
 321 #
 322 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 323 # not built, and you cannot push using http:// and https:// transports.
 324 #
 325 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 326 # /foo/bar/include and /foo/bar/lib directories.
 327 AC_ARG_WITH(expat,
 328 AS_HELP_STRING([--with-expat],
 329 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 330 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 331 GIT_PARSE_WITH(expat))
 332 #
 333 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 334 # installed in /sw, but don't want GIT to link against any libraries
 335 # installed there.  If defined you may specify your own (or Fink's)
 336 # include directories and library directories by defining CFLAGS
 337 # and LDFLAGS appropriately.
 338 #
 339 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 340 # have DarwinPorts installed in /opt/local, but don't want GIT to
 341 # link against any libraries installed there.  If defined you may
 342 # specify your own (or DarwinPort's) include directories and
 343 # library directories by defining CFLAGS and LDFLAGS appropriately.
 344 #
 345 # Define NO_MMAP if you want to avoid mmap.
 346 #
 347 # Define NO_ICONV if your libc does not properly support iconv.
 348 AC_ARG_WITH(iconv,
 349 AS_HELP_STRING([--without-iconv],
 350 [if your architecture doesn't properly support iconv])
 351 AS_HELP_STRING([--with-iconv=PATH],
 352 [PATH is prefix for libiconv library and headers])
 353 AS_HELP_STRING([],
 354 [used only if you need linking with libiconv]),
 355 GIT_PARSE_WITH(iconv))
 356
 357 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 358 #
 359 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 360 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 361 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 362 # randomly break unless your underlying filesystem supports those sub-second
 363 # times (my ext3 doesn't).
 364 #
 365 # Define USE_STDEV below if you want git to care about the underlying device
 366 # change being considered an inode change from the update-cache perspective.
 367
 368
 369 ## Output files
 370 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 371 AC_OUTPUT
 372
 373
 374 ## Cleanup
 375 rm -f "${config_append}"