git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 $SIG{INT} = sub { print color("reset"), "\n"; exit };
  28
  29 package FakeTerm;
  30 sub new {
  31         my ($class, $reason) = @_;
  32         return bless \$reason, shift;
  33 }
  34 sub readline {
  35         my $self = shift;
  36         die "Cannot use readline on FakeTerm: $$self";
  37 }
  38 package main;
  39
  40
  41 sub usage {
  42         print <<EOT;
  43 git-send-email [options] <file | directory>...
  44 Options:
  45    --from         Specify the "From:" line of the email to be sent.
  46
  47    --to           Specify the primary "To:" line of the email.
  48
  49    --cc           Specify an initial "Cc:" list for the entire series
  50                   of emails.
  51
  52    --cc-cmd       Specify a command to execute per file which adds
  53                   per file specific cc address entries
  54
  55    --bcc          Specify a list of email addresses that should be Bcc:
  56                   on all the emails.
  57
  58    --compose      Use \$GIT_EDITOR, core.editor, \$EDITOR, or \$VISUAL to edit
  59                   an introductory message for the patch series.
  60
  61    --subject      Specify the initial "Subject:" line.
  62                   Only necessary if --compose is also set.  If --compose
  63                   is not set, this will be prompted for.
  64
  65    --in-reply-to  Specify the first "In-Reply-To:" header line.
  66                   Only used if --compose is also set.  If --compose is not
  67                   set, this will be prompted for.
  68
  69    --chain-reply-to If set, the replies will all be to the previous
  70                   email sent, rather than to the first email sent.
  71                   Defaults to on.
  72
  73    --signed-off-cc Automatically add email addresses that appear in
  74                  Signed-off-by: or Cc: lines to the cc: list. Defaults to on.
  75
  76    --identity     The configuration identity, a subsection to prioritise over
  77                   the default section.
  78
  79    --smtp-server  If set, specifies the outgoing SMTP server to use.
  80                   Defaults to localhost.  Port number can be specified here with
  81                   hostname:port format or by using --smtp-server-port option.
  82
  83    --smtp-server-port Specify a port on the outgoing SMTP server to connect to.
  84
  85    --smtp-user    The username for SMTP-AUTH.
  86
  87    --smtp-pass    The password for SMTP-AUTH.
  88
  89    --smtp-ssl     If set, connects to the SMTP server using SSL.
  90
  91    --suppress-from Suppress sending emails to yourself. Defaults to off.
  92
  93    --thread       Specify that the "In-Reply-To:" header should be set on all
  94                   emails. Defaults to on.
  95
  96    --quiet        Make git-send-email less verbose.  One line per email
  97                   should be all that is output.
  98
  99    --dry-run      Do everything except actually send the emails.
 100
 101    --envelope-sender    Specify the envelope sender used to send the emails.
 102
 103 EOT
 104         exit(1);
 105 }
 106
 107 # most mail servers generate the Date: header, but not all...
 108 sub format_2822_time {
 109         my ($time) = @_;
 110         my @localtm = localtime($time);
 111         my @gmttm = gmtime($time);
 112         my $localmin = $localtm[1] + $localtm[2] * 60;
 113         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 114         if ($localtm[0] != $gmttm[0]) {
 115                 die "local zone differs from GMT by a non-minute interval\n";
 116         }
 117         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 118                 $localmin += 1440;
 119         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 120                 $localmin -= 1440;
 121         } elsif ($gmttm[6] != $localtm[6]) {
 122                 die "local time offset greater than or equal to 24 hours\n";
 123         }
 124         my $offset = $localmin - $gmtmin;
 125         my $offhour = $offset / 60;
 126         my $offmin = abs($offset % 60);
 127         if (abs($offhour) >= 24) {
 128                 die ("local time offset greater than or equal to 24 hours\n");
 129         }
 130
 131         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 132                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 133                        $localtm[3],
 134                        qw(Jan Feb Mar Apr May Jun
 135                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 136                        $localtm[5]+1900,
 137                        $localtm[2],
 138                        $localtm[1],
 139                        $localtm[0],
 140                        ($offset >= 0) ? '+' : '-',
 141                        abs($offhour),
 142                        $offmin,
 143                        );
 144 }
 145
 146 my $have_email_valid = eval { require Email::Valid; 1 };
 147 my $smtp;
 148
 149 sub unique_email_list(@);
 150 sub cleanup_compose_files();
 151
 152 # Constants (essentially)
 153 my $compose_filename = ".msg.$$";
 154
 155 # Variables we fill in automatically, or via prompting:
 156 my (@to,@cc,@initial_cc,@bcclist,@xh,
 157         $initial_reply_to,$initial_subject,@files,$author,$sender,$compose,$time);
 158
 159 my $envelope_sender;
 160
 161 # Example reply to:
 162 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 163
 164 my $repo = Git->repository();
 165 my $term = eval {
 166         new Term::ReadLine 'git-send-email';
 167 };
 168 if ($@) {
 169         $term = new FakeTerm "$@: going non-interactive";
 170 }
 171
 172 # Behavior modification variables
 173 my ($quiet, $dry_run) = (0, 0);
 174
 175 # Variables with corresponding config settings
 176 my ($thread, $chain_reply_to, $suppress_from, $signed_off_cc, $cc_cmd);
 177 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_authpass, $smtp_ssl);
 178 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 179
 180 my %config_bool_settings = (
 181     "thread" => [\$thread, 1],
 182     "chainreplyto" => [\$chain_reply_to, 1],
 183     "suppressfrom" => [\$suppress_from, 0],
 184     "signedoffcc" => [\$signed_off_cc, 1],
 185     "smtpssl" => [\$smtp_ssl, 0],
 186 );
 187
 188 my %config_settings = (
 189     "smtpserver" => \$smtp_server,
 190     "smtpserverport" => \$smtp_server_port,
 191     "smtpuser" => \$smtp_authuser,
 192     "smtppass" => \$smtp_authpass,
 193     "to" => \@to,
 194     "cccmd" => \$cc_cmd,
 195     "aliasfiletype" => \$aliasfiletype,
 196     "bcc" => \@bcclist,
 197     "aliasesfile" => \@alias_files,
 198 );
 199
 200 # Begin by accumulating all the variables (defined above), that we will end up
 201 # needing, first, from the command line:
 202
 203 my $rc = GetOptions("sender|from=s" => \$sender,
 204                     "in-reply-to=s" => \$initial_reply_to,
 205                     "subject=s" => \$initial_subject,
 206                     "to=s" => \@to,
 207                     "cc=s" => \@initial_cc,
 208                     "bcc=s" => \@bcclist,
 209                     "chain-reply-to!" => \$chain_reply_to,
 210                     "smtp-server=s" => \$smtp_server,
 211                     "smtp-server-port=s" => \$smtp_server_port,
 212                     "smtp-user=s" => \$smtp_authuser,
 213                     "smtp-pass=s" => \$smtp_authpass,
 214                     "smtp-ssl!" => \$smtp_ssl,
 215                     "identity=s" => \$identity,
 216                     "compose" => \$compose,
 217                     "quiet" => \$quiet,
 218                     "cc-cmd=s" => \$cc_cmd,
 219                     "suppress-from!" => \$suppress_from,
 220                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_cc,
 221                     "dry-run" => \$dry_run,
 222                     "envelope-sender=s" => \$envelope_sender,
 223                     "thread!" => \$thread,
 224          );
 225
 226 unless ($rc) {
 227     usage();
 228 }
 229
 230 # Now, let's fill any that aren't set in with defaults:
 231
 232 sub read_config {
 233         my ($prefix) = @_;
 234
 235         foreach my $setting (keys %config_bool_settings) {
 236                 my $target = $config_bool_settings{$setting}->[0];
 237                 $$target = $repo->config_bool("$prefix.$setting") unless (defined $$target);
 238         }
 239
 240         foreach my $setting (keys %config_settings) {
 241                 my $target = $config_settings{$setting};
 242                 if (ref($target) eq "ARRAY") {
 243                         unless (@$target) {
 244                                 my @values = $repo->config("$prefix.$setting");
 245                                 @$target = @values if (@values && defined $values[0]);
 246                         }
 247                 }
 248                 else {
 249                         $$target = $repo->config("$prefix.$setting") unless (defined $$target);
 250                 }
 251         }
 252 }
 253
 254 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 255 $identity = $repo->config("sendemail.identity") unless (defined $identity);
 256 read_config("sendemail.$identity") if (defined $identity);
 257 read_config("sendemail");
 258
 259 # fall back on builtin bool defaults
 260 foreach my $setting (values %config_bool_settings) {
 261         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 262 }
 263
 264 my ($repoauthor) = $repo->ident_person('author');
 265 my ($repocommitter) = $repo->ident_person('committer');
 266
 267 # Verify the user input
 268
 269 foreach my $entry (@to) {
 270         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 271 }
 272
 273 foreach my $entry (@initial_cc) {
 274         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 275 }
 276
 277 foreach my $entry (@bcclist) {
 278         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 279 }
 280
 281 my %aliases;
 282 my %parse_alias = (
 283         # multiline formats can be supported in the future
 284         mutt => sub { my $fh = shift; while (<$fh>) {
 285                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 286                         my ($alias, $addr) = ($1, $2);
 287                         $addr =~ s/#.*$//; # mutt allows # comments
 288                          # commas delimit multiple addresses
 289                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 290                 }}},
 291         mailrc => sub { my $fh = shift; while (<$fh>) {
 292                 if (/^alias\s+(\S+)\s+(.*)$/) {
 293                         # spaces delimit multiple addresses
 294                         $aliases{$1} = [ split(/\s+/, $2) ];
 295                 }}},
 296         pine => sub { my $fh = shift; while (<$fh>) {
 297                 if (/^(\S+)\t.*\t(.*)$/) {
 298                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 299                 }}},
 300         gnus => sub { my $fh = shift; while (<$fh>) {
 301                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 302                         $aliases{$1} = [ $2 ];
 303                 }}}
 304 );
 305
 306 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 307         foreach my $file (@alias_files) {
 308                 open my $fh, '<', $file or die "opening $file: $!\n";
 309                 $parse_alias{$aliasfiletype}->($fh);
 310                 close $fh;
 311         }
 312 }
 313
 314 ($sender) = expand_aliases($sender) if defined $sender;
 315
 316 my $prompting = 0;
 317 if (!defined $sender) {
 318         $sender = $repoauthor || $repocommitter;
 319         do {
 320                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 321         } while (!defined $_);
 322
 323         $sender = $_ if ($_);
 324         print "Emails will be sent from: ", $sender, "\n";
 325         $prompting++;
 326 }
 327
 328 if (!@to) {
 329         do {
 330                 $_ = $term->readline("Who should the emails be sent to? ",
 331                                 "");
 332         } while (!defined $_);
 333         my $to = $_;
 334         push @to, split /,/, $to;
 335         $prompting++;
 336 }
 337
 338 sub expand_aliases {
 339         my @cur = @_;
 340         my @last;
 341         do {
 342                 @last = @cur;
 343                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 344         } while (join(',',@cur) ne join(',',@last));
 345         return @cur;
 346 }
 347
 348 @to = expand_aliases(@to);
 349 @to = (map { sanitize_address($_) } @to);
 350 @initial_cc = expand_aliases(@initial_cc);
 351 @bcclist = expand_aliases(@bcclist);
 352
 353 if (!defined $initial_subject && $compose) {
 354         do {
 355                 $_ = $term->readline("What subject should the initial email start with? ",
 356                         $initial_subject);
 357         } while (!defined $_);
 358         $initial_subject = $_;
 359         $prompting++;
 360 }
 361
 362 if ($thread && !defined $initial_reply_to && $prompting) {
 363         do {
 364                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ",
 365                         $initial_reply_to);
 366         } while (!defined $_);
 367
 368         $initial_reply_to = $_;
 369         $initial_reply_to =~ s/^\s+<?/</;
 370         $initial_reply_to =~ s/>?\s+$/>/;
 371 }
 372
 373 if (!defined $smtp_server) {
 374         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 375                 if (-x $_) {
 376                         $smtp_server = $_;
 377                         last;
 378                 }
 379         }
 380         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 381 }
 382
 383 if ($compose) {
 384         # Note that this does not need to be secure, but we will make a small
 385         # effort to have it be unique
 386         open(C,">",$compose_filename)
 387                 or die "Failed to open for writing $compose_filename: $!";
 388         print C "From $sender # This line is ignored.\n";
 389         printf C "Subject: %s\n\n", $initial_subject;
 390         printf C <<EOT;
 391 GIT: Please enter your email below.
 392 GIT: Lines beginning in "GIT: " will be removed.
 393 GIT: Consider including an overall diffstat or table of contents
 394 GIT: for the patch you are writing.
 395
 396 EOT
 397         close(C);
 398
 399         my $editor = $ENV{GIT_EDITOR} || $repo->config("core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 400         system($editor, $compose_filename);
 401
 402         open(C2,">",$compose_filename . ".final")
 403                 or die "Failed to open $compose_filename.final : " . $!;
 404
 405         open(C,"<",$compose_filename)
 406                 or die "Failed to open $compose_filename : " . $!;
 407
 408         while(<C>) {
 409                 next if m/^GIT: /;
 410                 print C2 $_;
 411         }
 412         close(C);
 413         close(C2);
 414
 415         do {
 416                 $_ = $term->readline("Send this email? (y|n) ");
 417         } while (!defined $_);
 418
 419         if (uc substr($_,0,1) ne 'Y') {
 420                 cleanup_compose_files();
 421                 exit(0);
 422         }
 423
 424         @files = ($compose_filename . ".final");
 425 }
 426
 427
 428 # Now that all the defaults are set, process the rest of the command line
 429 # arguments and collect up the files that need to be processed.
 430 for my $f (@ARGV) {
 431         if (-d $f) {
 432                 opendir(DH,$f)
 433                         or die "Failed to opendir $f: $!";
 434
 435                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 436                                 sort readdir(DH);
 437
 438         } elsif (-f $f) {
 439                 push @files, $f;
 440
 441         } else {
 442                 print STDERR "Skipping $f - not found.\n";
 443         }
 444 }
 445
 446 if (@files) {
 447         unless ($quiet) {
 448                 print $_,"\n" for (@files);
 449         }
 450 } else {
 451         print STDERR "\nNo patch files specified!\n\n";
 452         usage();
 453 }
 454
 455 # Variables we set as part of the loop over files
 456 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 457
 458 sub extract_valid_address {
 459         my $address = shift;
 460         my $local_part_regexp = '[^<>"\s@]+';
 461         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 462
 463         # check for a local address:
 464         return $address if ($address =~ /^($local_part_regexp)$/);
 465
 466         $address =~ s/^\s*<(.*)>\s*$/$1/;
 467         if ($have_email_valid) {
 468                 return scalar Email::Valid->address($address);
 469         } else {
 470                 # less robust/correct than the monster regexp in Email::Valid,
 471                 # but still does a 99% job, and one less dependency
 472                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 473                 return $1;
 474         }
 475 }
 476
 477 # Usually don't need to change anything below here.
 478
 479 # we make a "fake" message id by taking the current number
 480 # of seconds since the beginning of Unix time and tacking on
 481 # a random number to the end, in case we are called quicker than
 482 # 1 second since the last time we were called.
 483
 484 # We'll setup a template for the message id, using the "from" address:
 485
 486 my ($message_id_stamp, $message_id_serial);
 487 sub make_message_id
 488 {
 489         my $uniq;
 490         if (!defined $message_id_stamp) {
 491                 $message_id_stamp = sprintf("%s-%s", time, $$);
 492                 $message_id_serial = 0;
 493         }
 494         $message_id_serial++;
 495         $uniq = "$message_id_stamp-$message_id_serial";
 496
 497         my $du_part;
 498         for ($sender, $repocommitter, $repoauthor) {
 499                 $du_part = extract_valid_address(sanitize_address($_));
 500                 last if (defined $du_part and $du_part ne '');
 501         }
 502         if (not defined $du_part or $du_part eq '') {
 503                 use Sys::Hostname qw();
 504                 $du_part = 'user@' . Sys::Hostname::hostname();
 505         }
 506         my $message_id_template = "<%s-git-send-email-%s>";
 507         $message_id = sprintf($message_id_template, $uniq, $du_part);
 508         #print "new message id = $message_id\n"; # Was useful for debugging
 509 }
 510
 511
 512
 513 $time = time - scalar $#files;
 514
 515 sub unquote_rfc2047 {
 516         local ($_) = @_;
 517         if (s/=\?utf-8\?q\?(.*)\?=/$1/g) {
 518                 s/_/ /g;
 519                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 520         }
 521         return "$_";
 522 }
 523
 524 # use the simplest quoting being able to handle the recipient
 525 sub sanitize_address
 526 {
 527         my ($recipient) = @_;
 528         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 529
 530         if (not $recipient_name) {
 531                 return "$recipient";
 532         }
 533
 534         # if recipient_name is already quoted, do nothing
 535         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 536                 return $recipient;
 537         }
 538
 539         # rfc2047 is needed if a non-ascii char is included
 540         if ($recipient_name =~ /[^[:ascii:]]/) {
 541                 $recipient_name =~ s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 542                 $recipient_name =~ s/(.*)/=\?utf-8\?q\?$1\?=/;
 543         }
 544
 545         # double quotes are needed if specials or CTLs are included
 546         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 547                 $recipient_name =~ s/(["\\\r])/\\$1/;
 548                 $recipient_name = "\"$recipient_name\"";
 549         }
 550
 551         return "$recipient_name $recipient_addr";
 552
 553 }
 554
 555 sub send_message
 556 {
 557         my @recipients = unique_email_list(@to);
 558         @cc = (map { sanitize_address($_) } @cc);
 559         my $to = join (",\n\t", @recipients);
 560         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 561         @recipients = (map { extract_valid_address($_) } @recipients);
 562         my $date = format_2822_time($time++);
 563         my $gitversion = '@@GIT_VERSION@@';
 564         if ($gitversion =~ m/..GIT_VERSION../) {
 565             $gitversion = Git::version();
 566         }
 567
 568         my $cc = join(", ", unique_email_list(@cc));
 569         my $ccline = "";
 570         if ($cc ne '') {
 571                 $ccline = "\nCc: $cc";
 572         }
 573         my $sanitized_sender = sanitize_address($sender);
 574         make_message_id();
 575
 576         my $header = "From: $sanitized_sender
 577 To: $to${ccline}
 578 Subject: $subject
 579 Date: $date
 580 Message-Id: $message_id
 581 X-Mailer: git-send-email $gitversion
 582 ";
 583         if ($thread && $reply_to) {
 584
 585                 $header .= "In-Reply-To: $reply_to\n";
 586                 $header .= "References: $references\n";
 587         }
 588         if (@xh) {
 589                 $header .= join("\n", @xh) . "\n";
 590         }
 591
 592         my @sendmail_parameters = ('-i', @recipients);
 593         my $raw_from = $sanitized_sender;
 594         $raw_from = $envelope_sender if (defined $envelope_sender);
 595         $raw_from = extract_valid_address($raw_from);
 596         unshift (@sendmail_parameters,
 597                         '-f', $raw_from) if(defined $envelope_sender);
 598
 599         if ($dry_run) {
 600                 # We don't want to send the email.
 601         } elsif ($smtp_server =~ m#^/#) {
 602                 my $pid = open my $sm, '|-';
 603                 defined $pid or die $!;
 604                 if (!$pid) {
 605                         exec($smtp_server, @sendmail_parameters) or die $!;
 606                 }
 607                 print $sm "$header\n$message";
 608                 close $sm or die $?;
 609         } else {
 610
 611                 if (!defined $smtp_server) {
 612                         die "The required SMTP server is not properly defined."
 613                 }
 614
 615                 if ($smtp_ssl) {
 616                         $smtp_server_port ||= 465; # ssmtp
 617                         require Net::SMTP::SSL;
 618                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 619                 }
 620                 else {
 621                         require Net::SMTP;
 622                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 623                                                  ? "$smtp_server:$smtp_server_port"
 624                                                  : $smtp_server);
 625                 }
 626
 627                 if (!$smtp) {
 628                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 629                 }
 630
 631                 if ((defined $smtp_authuser) && (defined $smtp_authpass)) {
 632                         $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 633                 }
 634                 $smtp->mail( $raw_from ) or die $smtp->message;
 635                 $smtp->to( @recipients ) or die $smtp->message;
 636                 $smtp->data or die $smtp->message;
 637                 $smtp->datasend("$header\n$message") or die $smtp->message;
 638                 $smtp->dataend() or die $smtp->message;
 639                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 640         }
 641         if ($quiet) {
 642                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 643         } else {
 644                 print (($dry_run ? "Dry-" : "")."OK. Log says:\nDate: $date\n");
 645                 if ($smtp_server !~ m#^/#) {
 646                         print "Server: $smtp_server\n";
 647                         print "MAIL FROM:<$raw_from>\n";
 648                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 649                 } else {
 650                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 651                 }
 652                 print "From: $sanitized_sender\nSubject: $subject\nCc: $cc\nTo: $to\n\n";
 653                 if ($smtp) {
 654                         print "Result: ", $smtp->code, ' ',
 655                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 656                 } else {
 657                         print "Result: OK\n";
 658                 }
 659         }
 660 }
 661
 662 $reply_to = $initial_reply_to;
 663 $references = $initial_reply_to || '';
 664 $subject = $initial_subject;
 665
 666 foreach my $t (@files) {
 667         open(F,"<",$t) or die "can't open file $t";
 668
 669         my $author = undef;
 670         @cc = @initial_cc;
 671         @xh = ();
 672         my $input_format = undef;
 673         my $header_done = 0;
 674         $message = "";
 675         while(<F>) {
 676                 if (!$header_done) {
 677                         if (/^From /) {
 678                                 $input_format = 'mbox';
 679                                 next;
 680                         }
 681                         chomp;
 682                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 683                                 $input_format = 'mbox';
 684                         }
 685
 686                         if (defined $input_format && $input_format eq 'mbox') {
 687                                 if (/^Subject:\s+(.*)$/) {
 688                                         $subject = $1;
 689
 690                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 691                                         if (unquote_rfc2047($2) eq $sender) {
 692                                                 next if ($suppress_from);
 693                                         }
 694                                         elsif ($1 eq 'From') {
 695                                                 $author = unquote_rfc2047($2);
 696                                         }
 697                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 698                                                 $2, $_) unless $quiet;
 699                                         push @cc, $2;
 700                                 }
 701                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 702                                         push @xh, $_;
 703                                 }
 704
 705                         } else {
 706                                 # In the traditional
 707                                 # "send lots of email" format,
 708                                 # line 1 = cc
 709                                 # line 2 = subject
 710                                 # So let's support that, too.
 711                                 $input_format = 'lots';
 712                                 if (@cc == 0) {
 713                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 714                                                 $_, $_) unless $quiet;
 715
 716                                         push @cc, $_;
 717
 718                                 } elsif (!defined $subject) {
 719                                         $subject = $_;
 720                                 }
 721                         }
 722
 723                         # A whitespace line will terminate the headers
 724                         if (m/^\s*$/) {
 725                                 $header_done = 1;
 726                         }
 727                 } else {
 728                         $message .=  $_;
 729                         if (/^(Signed-off-by|Cc): (.*)$/i && $signed_off_cc) {
 730                                 my $c = $2;
 731                                 chomp $c;
 732                                 next if ($c eq $sender and $suppress_from);
 733                                 push @cc, $c;
 734                                 printf("(sob) Adding cc: %s from line '%s'\n",
 735                                         $c, $_) unless $quiet;
 736                         }
 737                 }
 738         }
 739         close F;
 740
 741         if (defined $cc_cmd) {
 742                 open(F, "$cc_cmd $t |")
 743                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 744                 while(<F>) {
 745                         my $c = $_;
 746                         $c =~ s/^\s*//g;
 747                         $c =~ s/\n$//g;
 748                         next if ($c eq $sender and $suppress_from);
 749                         push @cc, $c;
 750                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 751                                 $c, $cc_cmd) unless $quiet;
 752                 }
 753                 close F
 754                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 755         }
 756
 757         if (defined $author) {
 758                 $message = "From: $author\n\n$message";
 759         }
 760
 761         send_message();
 762
 763         # set up for the next message
 764         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 765                 $reply_to = $message_id;
 766                 if (length $references > 0) {
 767                         $references .= "\n $message_id";
 768                 } else {
 769                         $references = "$message_id";
 770                 }
 771         }
 772 }
 773
 774 if ($compose) {
 775         cleanup_compose_files();
 776 }
 777
 778 sub cleanup_compose_files() {
 779         unlink($compose_filename, $compose_filename . ".final");
 780
 781 }
 782
 783 $smtp->quit if $smtp;
 784
 785 sub unique_email_list(@) {
 786         my %seen;
 787         my @emails;
 788
 789         foreach my $entry (@_) {
 790                 if (my $clean = extract_valid_address($entry)) {
 791                         $seen{$clean} ||= 0;
 792                         next if $seen{$clean}++;
 793                         push @emails, $entry;
 794                 } else {
 795                         print STDERR "W: unable to extract a valid address",
 796                                         " from: $entry\n";
 797                 }
 798         }
 799         return @emails;
 800 }