git-cvsimport.perl

   1 #!/usr/bin/perl -w
   2
   3 # This tool is copyright (c) 2005, Matthias Urlichs.
   4 # It is released under the Gnu Public License, version 2.
   5 #
   6 # The basic idea is to aggregate CVS check-ins into related changes.
   7 # Fortunately, "cvsps" does that for us; all we have to do is to parse
   8 # its output.
   9 #
  10 # Checking out the files is done by a single long-running CVS connection
  11 # / server process.
  12 #
  13 # The head revision is on branch "origin" by default.
  14 # You can change that with the '-o' option.
  15
  16 use strict;
  17 use warnings;
  18 use Getopt::Std;
  19 use File::Spec;
  20 use File::Temp qw(tempfile tmpnam);
  21 use File::Path qw(mkpath);
  22 use File::Basename qw(basename dirname);
  23 use Time::Local;
  24 use IO::Socket;
  25 use IO::Pipe;
  26 use POSIX qw(strftime dup2 ENOENT);
  27 use IPC::Open2;
  28
  29 $SIG{'PIPE'}="IGNORE";
  30 $ENV{'TZ'}="UTC";
  31
  32 our ($opt_h,$opt_o,$opt_v,$opt_k,$opt_u,$opt_d,$opt_p,$opt_C,$opt_z,$opt_i,$opt_P, $opt_s,$opt_m,$opt_M,$opt_A,$opt_S,$opt_L, $opt_a, $opt_r);
  33 my (%conv_author_name, %conv_author_email);
  34
  35 sub usage(;$) {
  36         my $msg = shift;
  37         print(STDERR "Error: $msg\n") if $msg;
  38         print STDERR <<END;
  39 Usage: ${\basename $0}     # fetch/update GIT from CVS
  40        [-o branch-for-HEAD] [-h] [-v] [-d CVSROOT] [-A author-conv-file]
  41        [-p opts-for-cvsps] [-P file] [-C GIT_repository] [-z fuzz] [-i] [-k]
  42        [-u] [-s subst] [-a] [-m] [-M regex] [-S regex] [-L commitlimit]
  43        [-r remote] [CVS_module]
  44 END
  45         exit(1);
  46 }
  47
  48 sub read_author_info($) {
  49         my ($file) = @_;
  50         my $user;
  51         open my $f, '<', "$file" or die("Failed to open $file: $!\n");
  52
  53         while (<$f>) {
  54                 # Expected format is this:
  55                 #   exon=Andreas Ericsson <ae@op5.se>
  56                 if (m/^(\S+?)\s*=\s*(.+?)\s*<(.+)>\s*$/) {
  57                         $user = $1;
  58                         $conv_author_name{$user} = $2;
  59                         $conv_author_email{$user} = $3;
  60                 }
  61                 # However, we also read from CVSROOT/users format
  62                 # to ease migration.
  63                 elsif (/^(\w+):(['"]?)(.+?)\2\s*$/) {
  64                         my $mapped;
  65                         ($user, $mapped) = ($1, $3);
  66                         if ($mapped =~ /^\s*(.*?)\s*<(.*)>\s*$/) {
  67                                 $conv_author_name{$user} = $1;
  68                                 $conv_author_email{$user} = $2;
  69                         }
  70                         elsif ($mapped =~ /^<?(.*)>?$/) {
  71                                 $conv_author_name{$user} = $user;
  72                                 $conv_author_email{$user} = $1;
  73                         }
  74                 }
  75                 # NEEDSWORK: Maybe warn on unrecognized lines?
  76         }
  77         close ($f);
  78 }
  79
  80 sub write_author_info($) {
  81         my ($file) = @_;
  82         open my $f, '>', $file or
  83           die("Failed to open $file for writing: $!");
  84
  85         foreach (keys %conv_author_name) {
  86                 print $f "$_=$conv_author_name{$_} <$conv_author_email{$_}>\n";
  87         }
  88         close ($f);
  89 }
  90
  91 # convert getopts specs for use by git-repo-config
  92 sub read_repo_config {
  93     # Split the string between characters, unless there is a ':'
  94     # So "abc:de" becomes ["a", "b", "c:", "d", "e"]
  95         my @opts = split(/ *(?!:)/, shift);
  96         foreach my $o (@opts) {
  97                 my $key = $o;
  98                 $key =~ s/://g;
  99                 my $arg = 'git-repo-config';
 100                 $arg .= ' --bool' if ($o !~ /:$/);
 101
 102         chomp(my $tmp = `$arg --get cvsimport.$key`);
 103                 if ($tmp && !($arg =~ /--bool/ && $tmp eq 'false')) {
 104             no strict 'refs';
 105             my $opt_name = "opt_" . $key;
 106             if (!$$opt_name) {
 107                 $$opt_name = $tmp;
 108             }
 109                 }
 110         }
 111     if (@ARGV == 0) {
 112         chomp(my $module = `git-repo-config --get cvsimport.module`);
 113         push(@ARGV, $module);
 114     }
 115 }
 116
 117 my $opts = "haivmkuo:d:p:r:C:z:s:M:P:A:S:L:";
 118 read_repo_config($opts);
 119 getopts($opts) or usage();
 120 usage if $opt_h;
 121
 122 @ARGV <= 1 or usage("You can't specify more than one CVS module");
 123
 124 if ($opt_d) {
 125         $ENV{"CVSROOT"} = $opt_d;
 126 } elsif (-f 'CVS/Root') {
 127         open my $f, '<', 'CVS/Root' or die 'Failed to open CVS/Root';
 128         $opt_d = <$f>;
 129         chomp $opt_d;
 130         close $f;
 131         $ENV{"CVSROOT"} = $opt_d;
 132 } elsif ($ENV{"CVSROOT"}) {
 133         $opt_d = $ENV{"CVSROOT"};
 134 } else {
 135         usage("CVSROOT needs to be set");
 136 }
 137 $opt_s ||= "-";
 138 $opt_a ||= 0;
 139
 140 my $git_tree = $opt_C;
 141 $git_tree ||= ".";
 142
 143 my $remote;
 144 if (defined $opt_r) {
 145         $remote = 'refs/remotes/' . $opt_r;
 146         $opt_o ||= "master";
 147 } else {
 148         $opt_o ||= "origin";
 149         $remote = 'refs/heads';
 150 }
 151
 152 my $cvs_tree;
 153 if ($#ARGV == 0) {
 154         $cvs_tree = $ARGV[0];
 155 } elsif (-f 'CVS/Repository') {
 156         open my $f, '<', 'CVS/Repository' or
 157             die 'Failed to open CVS/Repository';
 158         $cvs_tree = <$f>;
 159         chomp $cvs_tree;
 160         close $f;
 161 } else {
 162         usage("CVS module has to be specified");
 163 }
 164
 165 our @mergerx = ();
 166 if ($opt_m) {
 167         @mergerx = ( qr/\W(?:from|of|merge|merging|merged) (\w+)/i );
 168 }
 169 if ($opt_M) {
 170         push (@mergerx, qr/$opt_M/);
 171 }
 172
 173 # Remember UTC of our starting time
 174 # we'll want to avoid importing commits
 175 # that are too recent
 176 our $starttime = time();
 177
 178 select(STDERR); $|=1; select(STDOUT);
 179
 180
 181 package CVSconn;
 182 # Basic CVS dialog.
 183 # We're only interested in connecting and downloading, so ...
 184
 185 use File::Spec;
 186 use File::Temp qw(tempfile);
 187 use POSIX qw(strftime dup2);
 188
 189 sub new {
 190         my ($what,$repo,$subdir) = @_;
 191         $what=ref($what) if ref($what);
 192
 193         my $self = {};
 194         $self->{'buffer'} = "";
 195         bless($self,$what);
 196
 197         $repo =~ s#/+$##;
 198         $self->{'fullrep'} = $repo;
 199         $self->conn();
 200
 201         $self->{'subdir'} = $subdir;
 202         $self->{'lines'} = undef;
 203
 204         return $self;
 205 }
 206
 207 sub conn {
 208         my $self = shift;
 209         my $repo = $self->{'fullrep'};
 210         if ($repo =~ s/^:pserver(?:([^:]*)):(?:(.*?)(?::(.*?))?@)?([^:\/]*)(?::(\d*))?//) {
 211                 my ($param,$user,$pass,$serv,$port) = ($1,$2,$3,$4,$5);
 212
 213                 my ($proxyhost,$proxyport);
 214                 if ($param && ($param =~ m/proxy=([^;]+)/)) {
 215                         $proxyhost = $1;
 216                         # Default proxyport, if not specified, is 8080.
 217                         $proxyport = 8080;
 218                         if ($ENV{"CVS_PROXY_PORT"}) {
 219                                 $proxyport = $ENV{"CVS_PROXY_PORT"};
 220                         }
 221                         if ($param =~ m/proxyport=([^;]+)/) {
 222                                 $proxyport = $1;
 223                         }
 224                 }
 225
 226                 # if username is not explicit in CVSROOT, then use current user, as cvs would
 227                 $user=(getlogin() || $ENV{'LOGNAME'} || $ENV{'USER'} || "anonymous") unless $user;
 228                 my $rr2 = "-";
 229                 unless ($port) {
 230                         $rr2 = ":pserver:$user\@$serv:$repo";
 231                         $port=2401;
 232                 }
 233                 my $rr = ":pserver:$user\@$serv:$port$repo";
 234
 235                 unless ($pass) {
 236                         open(H,$ENV{'HOME'}."/.cvspass") and do {
 237                                 # :pserver:cvs@mea.tmt.tele.fi:/cvsroot/zmailer Ah<Z
 238                                 while (<H>) {
 239                                         chomp;
 240                                         s/^\/\d+\s+//;
 241                                         my ($w,$p) = split(/\s/,$_,2);
 242                                         if ($w eq $rr or $w eq $rr2) {
 243                                                 $pass = $p;
 244                                                 last;
 245                                         }
 246                                 }
 247                         };
 248                 }
 249                 $pass="A" unless $pass;
 250
 251                 my ($s, $rep);
 252                 if ($proxyhost) {
 253
 254                         # Use a HTTP Proxy. Only works for HTTP proxies that
 255                         # don't require user authentication
 256                         #
 257                         # See: http://www.ietf.org/rfc/rfc2817.txt
 258
 259                         $s = IO::Socket::INET->new(PeerHost => $proxyhost, PeerPort => $proxyport);
 260                         die "Socket to $proxyhost: $!\n" unless defined $s;
 261                         $s->write("CONNECT $serv:$port HTTP/1.1\r\nHost: $serv:$port\r\n\r\n")
 262                                 or die "Write to $proxyhost: $!\n";
 263                         $s->flush();
 264
 265                         $rep = <$s>;
 266
 267                         # The answer should look like 'HTTP/1.x 2yy ....'
 268                         if (!($rep =~ m#^HTTP/1\.. 2[0-9][0-9]#)) {
 269                                 die "Proxy connect: $rep\n";
 270                         }
 271                         # Skip up to the empty line of the proxy server output
 272                         # including the response headers.
 273                         while ($rep = <$s>) {
 274                                 last if (!defined $rep ||
 275                                          $rep eq "\n" ||
 276                                          $rep eq "\r\n");
 277                         }
 278                 } else {
 279                         $s = IO::Socket::INET->new(PeerHost => $serv, PeerPort => $port);
 280                         die "Socket to $serv: $!\n" unless defined $s;
 281                 }
 282
 283                 $s->write("BEGIN AUTH REQUEST\n$repo\n$user\n$pass\nEND AUTH REQUEST\n")
 284                         or die "Write to $serv: $!\n";
 285                 $s->flush();
 286
 287                 $rep = <$s>;
 288
 289                 if ($rep ne "I LOVE YOU\n") {
 290                         $rep="<unknown>" unless $rep;
 291                         die "AuthReply: $rep\n";
 292                 }
 293                 $self->{'socketo'} = $s;
 294                 $self->{'socketi'} = $s;
 295         } else { # local or ext: Fork off our own cvs server.
 296                 my $pr = IO::Pipe->new();
 297                 my $pw = IO::Pipe->new();
 298                 my $pid = fork();
 299                 die "Fork: $!\n" unless defined $pid;
 300                 my $cvs = 'cvs';
 301                 $cvs = $ENV{CVS_SERVER} if exists $ENV{CVS_SERVER};
 302                 my $rsh = 'rsh';
 303                 $rsh = $ENV{CVS_RSH} if exists $ENV{CVS_RSH};
 304
 305                 my @cvs = ($cvs, 'server');
 306                 my ($local, $user, $host);
 307                 $local = $repo =~ s/:local://;
 308                 if (!$local) {
 309                     $repo =~ s/:ext://;
 310                     $local = !($repo =~ s/^(?:([^\@:]+)\@)?([^:]+)://);
 311                     ($user, $host) = ($1, $2);
 312                 }
 313                 if (!$local) {
 314                     if ($user) {
 315                         unshift @cvs, $rsh, '-l', $user, $host;
 316                     } else {
 317                         unshift @cvs, $rsh, $host;
 318                     }
 319                 }
 320
 321                 unless ($pid) {
 322                         $pr->writer();
 323                         $pw->reader();
 324                         dup2($pw->fileno(),0);
 325                         dup2($pr->fileno(),1);
 326                         $pr->close();
 327                         $pw->close();
 328                         exec(@cvs);
 329                 }
 330                 $pw->writer();
 331                 $pr->reader();
 332                 $self->{'socketo'} = $pw;
 333                 $self->{'socketi'} = $pr;
 334         }
 335         $self->{'socketo'}->write("Root $repo\n");
 336
 337         # Trial and error says that this probably is the minimum set
 338         $self->{'socketo'}->write("Valid-responses ok error Valid-requests Mode M Mbinary E Checked-in Created Updated Merged Removed\n");
 339
 340         $self->{'socketo'}->write("valid-requests\n");
 341         $self->{'socketo'}->flush();
 342
 343         chomp(my $rep=$self->readline());
 344         if ($rep !~ s/^Valid-requests\s*//) {
 345                 $rep="<unknown>" unless $rep;
 346                 die "Expected Valid-requests from server, but got: $rep\n";
 347         }
 348         chomp(my $res=$self->readline());
 349         die "validReply: $res\n" if $res ne "ok";
 350
 351         $self->{'socketo'}->write("UseUnchanged\n") if $rep =~ /\bUseUnchanged\b/;
 352         $self->{'repo'} = $repo;
 353 }
 354
 355 sub readline {
 356         my ($self) = @_;
 357         return $self->{'socketi'}->getline();
 358 }
 359
 360 sub _file {
 361         # Request a file with a given revision.
 362         # Trial and error says this is a good way to do it. :-/
 363         my ($self,$fn,$rev) = @_;
 364         $self->{'socketo'}->write("Argument -N\n") or return undef;
 365         $self->{'socketo'}->write("Argument -P\n") or return undef;
 366         # -kk: Linus' version doesn't use it - defaults to off
 367         if ($opt_k) {
 368             $self->{'socketo'}->write("Argument -kk\n") or return undef;
 369         }
 370         $self->{'socketo'}->write("Argument -r\n") or return undef;
 371         $self->{'socketo'}->write("Argument $rev\n") or return undef;
 372         $self->{'socketo'}->write("Argument --\n") or return undef;
 373         $self->{'socketo'}->write("Argument $self->{'subdir'}/$fn\n") or return undef;
 374         $self->{'socketo'}->write("Directory .\n") or return undef;
 375         $self->{'socketo'}->write("$self->{'repo'}\n") or return undef;
 376         # $self->{'socketo'}->write("Sticky T1.0\n") or return undef;
 377         $self->{'socketo'}->write("co\n") or return undef;
 378         $self->{'socketo'}->flush() or return undef;
 379         $self->{'lines'} = 0;
 380         return 1;
 381 }
 382 sub _line {
 383         # Read a line from the server.
 384         # ... except that 'line' may be an entire file. ;-)
 385         my ($self, $fh) = @_;
 386         die "Not in lines" unless defined $self->{'lines'};
 387
 388         my $line;
 389         my $res=0;
 390         while (defined($line = $self->readline())) {
 391                 # M U gnupg-cvs-rep/AUTHORS
 392                 # Updated gnupg-cvs-rep/
 393                 # /daten/src/rsync/gnupg-cvs-rep/AUTHORS
 394                 # /AUTHORS/1.1///T1.1
 395                 # u=rw,g=rw,o=rw
 396                 # 0
 397                 # ok
 398
 399                 if ($line =~ s/^(?:Created|Updated) //) {
 400                         $line = $self->readline(); # path
 401                         $line = $self->readline(); # Entries line
 402                         my $mode = $self->readline(); chomp $mode;
 403                         $self->{'mode'} = $mode;
 404                         defined (my $cnt = $self->readline())
 405                                 or die "EOF from server after 'Changed'\n";
 406                         chomp $cnt;
 407                         die "Duh: Filesize $cnt" if $cnt !~ /^\d+$/;
 408                         $line="";
 409                         $res = $self->_fetchfile($fh, $cnt);
 410                 } elsif ($line =~ s/^ //) {
 411                         print $fh $line;
 412                         $res += length($line);
 413                 } elsif ($line =~ /^M\b/) {
 414                         # output, do nothing
 415                 } elsif ($line =~ /^Mbinary\b/) {
 416                         my $cnt;
 417                         die "EOF from server after 'Mbinary'" unless defined ($cnt = $self->readline());
 418                         chomp $cnt;
 419                         die "Duh: Mbinary $cnt" if $cnt !~ /^\d+$/ or $cnt<1;
 420                         $line="";
 421                         $res += $self->_fetchfile($fh, $cnt);
 422                 } else {
 423                         chomp $line;
 424                         if ($line eq "ok") {
 425                                 # print STDERR "S: ok (".length($res).")\n";
 426                                 return $res;
 427                         } elsif ($line =~ s/^E //) {
 428                                 # print STDERR "S: $line\n";
 429                         } elsif ($line =~ /^(Remove-entry|Removed) /i) {
 430                                 $line = $self->readline(); # filename
 431                                 $line = $self->readline(); # OK
 432                                 chomp $line;
 433                                 die "Unknown: $line" if $line ne "ok";
 434                                 return -1;
 435                         } else {
 436                                 die "Unknown: $line\n";
 437                         }
 438                 }
 439         }
 440         return undef;
 441 }
 442 sub file {
 443         my ($self,$fn,$rev) = @_;
 444         my $res;
 445
 446         my ($fh, $name) = tempfile('gitcvs.XXXXXX',
 447                     DIR => File::Spec->tmpdir(), UNLINK => 1);
 448
 449         $self->_file($fn,$rev) and $res = $self->_line($fh);
 450
 451         if (!defined $res) {
 452             print STDERR "Server has gone away while fetching $fn $rev, retrying...\n";
 453             truncate $fh, 0;
 454             $self->conn();
 455             $self->_file($fn,$rev) or die "No file command send";
 456             $res = $self->_line($fh);
 457             die "Retry failed" unless defined $res;
 458         }
 459         close ($fh);
 460
 461         return ($name, $res);
 462 }
 463 sub _fetchfile {
 464         my ($self, $fh, $cnt) = @_;
 465         my $res = 0;
 466         my $bufsize = 1024 * 1024;
 467         while ($cnt) {
 468             if ($bufsize > $cnt) {
 469                 $bufsize = $cnt;
 470             }
 471             my $buf;
 472             my $num = $self->{'socketi'}->read($buf,$bufsize);
 473             die "Server: Filesize $cnt: $num: $!\n" if not defined $num or $num<=0;
 474             print $fh $buf;
 475             $res += $num;
 476             $cnt -= $num;
 477         }
 478         return $res;
 479 }
 480
 481
 482 package main;
 483
 484 my $cvs = CVSconn->new($opt_d, $cvs_tree);
 485
 486
 487 sub pdate($) {
 488         my ($d) = @_;
 489         m#(\d{2,4})/(\d\d)/(\d\d)\s(\d\d):(\d\d)(?::(\d\d))?#
 490                 or die "Unparseable date: $d\n";
 491         my $y=$1; $y-=1900 if $y>1900;
 492         return timegm($6||0,$5,$4,$3,$2-1,$y);
 493 }
 494
 495 sub pmode($) {
 496         my ($mode) = @_;
 497         my $m = 0;
 498         my $mm = 0;
 499         my $um = 0;
 500         for my $x(split(//,$mode)) {
 501                 if ($x eq ",") {
 502                         $m |= $mm&$um;
 503                         $mm = 0;
 504                         $um = 0;
 505                 } elsif ($x eq "u") { $um |= 0700;
 506                 } elsif ($x eq "g") { $um |= 0070;
 507                 } elsif ($x eq "o") { $um |= 0007;
 508                 } elsif ($x eq "r") { $mm |= 0444;
 509                 } elsif ($x eq "w") { $mm |= 0222;
 510                 } elsif ($x eq "x") { $mm |= 0111;
 511                 } elsif ($x eq "=") { # do nothing
 512                 } else { die "Unknown mode: $mode\n";
 513                 }
 514         }
 515         $m |= $mm&$um;
 516         return $m;
 517 }
 518
 519 sub getwd() {
 520         my $pwd = `pwd`;
 521         chomp $pwd;
 522         return $pwd;
 523 }
 524
 525 sub is_sha1 {
 526         my $s = shift;
 527         return $s =~ /^[a-f0-9]{40}$/;
 528 }
 529
 530 sub get_headref ($$) {
 531     my $name    = shift;
 532     my $git_dir = shift;
 533
 534     my $f = "$git_dir/$remote/$name";
 535     if (open(my $fh, $f)) {
 536             chomp(my $r = <$fh>);
 537             is_sha1($r) or die "Cannot get head id for $name ($r): $!";
 538             return $r;
 539     }
 540     die "unable to open $f: $!" unless $! == POSIX::ENOENT;
 541     return undef;
 542 }
 543
 544 -d $git_tree
 545         or mkdir($git_tree,0777)
 546         or die "Could not create $git_tree: $!";
 547 chdir($git_tree);
 548
 549 my $last_branch = "";
 550 my $orig_branch = "";
 551 my %branch_date;
 552 my $tip_at_start = undef;
 553
 554 my $git_dir = $ENV{"GIT_DIR"} || ".git";
 555 $git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
 556 $ENV{"GIT_DIR"} = $git_dir;
 557 my $orig_git_index;
 558 $orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
 559
 560 my %index; # holds filenames of one index per branch
 561
 562 unless (-d $git_dir) {
 563         system("git-init");
 564         die "Cannot init the GIT db at $git_tree: $?\n" if $?;
 565         system("git-read-tree");
 566         die "Cannot init an empty tree: $?\n" if $?;
 567
 568         $last_branch = $opt_o;
 569         $orig_branch = "";
 570 } else {
 571         open(F, "git-symbolic-ref HEAD |") or
 572                 die "Cannot run git-symbolic-ref: $!\n";
 573         chomp ($last_branch = <F>);
 574         $last_branch = basename($last_branch);
 575         close(F);
 576         unless ($last_branch) {
 577                 warn "Cannot read the last branch name: $! -- assuming 'master'\n";
 578                 $last_branch = "master";
 579         }
 580         $orig_branch = $last_branch;
 581         $tip_at_start = `git-rev-parse --verify HEAD`;
 582
 583         # Get the last import timestamps
 584         my $fmt = '($ref, $author) = (%(refname), %(author));';
 585         open(H, "git-for-each-ref --perl --format='$fmt' $remote |") or
 586                 die "Cannot run git-for-each-ref: $!\n";
 587         while (defined(my $entry = <H>)) {
 588                 my ($ref, $author);
 589                 eval($entry) || die "cannot eval refs list: $@";
 590                 my ($head) = ($ref =~ m|^$remote/(.*)|);
 591                 $author =~ /^.*\s(\d+)\s[-+]\d{4}$/;
 592                 $branch_date{$head} = $1;
 593         }
 594         close(H);
 595         if (!exists $branch_date{$opt_o}) {
 596                 die "Branch '$opt_o' does not exist.\n".
 597                        "Either use the correct '-o branch' option,\n".
 598                        "or import to a new repository.\n";
 599         }
 600 }
 601
 602 -d $git_dir
 603         or die "Could not create git subdir ($git_dir).\n";
 604
 605 # now we read (and possibly save) author-info as well
 606 -f "$git_dir/cvs-authors" and
 607   read_author_info("$git_dir/cvs-authors");
 608 if ($opt_A) {
 609         read_author_info($opt_A);
 610         write_author_info("$git_dir/cvs-authors");
 611 }
 612
 613
 614 #
 615 # run cvsps into a file unless we are getting
 616 # it passed as a file via $opt_P
 617 #
 618 my $cvspsfile;
 619 unless ($opt_P) {
 620         print "Running cvsps...\n" if $opt_v;
 621         my $pid = open(CVSPS,"-|");
 622         my $cvspsfh;
 623         die "Cannot fork: $!\n" unless defined $pid;
 624         unless ($pid) {
 625                 my @opt;
 626                 @opt = split(/,/,$opt_p) if defined $opt_p;
 627                 unshift @opt, '-z', $opt_z if defined $opt_z;
 628                 unshift @opt, '-q'         unless defined $opt_v;
 629                 unless (defined($opt_p) && $opt_p =~ m/--no-cvs-direct/) {
 630                         push @opt, '--cvs-direct';
 631                 }
 632                 exec("cvsps","--norc",@opt,"-u","-A",'--root',$opt_d,$cvs_tree);
 633                 die "Could not start cvsps: $!\n";
 634         }
 635         ($cvspsfh, $cvspsfile) = tempfile('gitXXXXXX', SUFFIX => '.cvsps',
 636                                           DIR => File::Spec->tmpdir());
 637         while (<CVSPS>) {
 638             print $cvspsfh $_;
 639         }
 640         close CVSPS;
 641         close $cvspsfh;
 642 } else {
 643         $cvspsfile = $opt_P;
 644 }
 645
 646 open(CVS, "<$cvspsfile") or die $!;
 647
 648 ## cvsps output:
 649 #---------------------
 650 #PatchSet 314
 651 #Date: 1999/09/18 13:03:59
 652 #Author: wkoch
 653 #Branch: STABLE-BRANCH-1-0
 654 #Ancestor branch: HEAD
 655 #Tag: (none)
 656 #Log:
 657 #    See ChangeLog: Sat Sep 18 13:03:28 CEST 1999  Werner Koch
 658 #Members:
 659 #       README:1.57->1.57.2.1
 660 #       VERSION:1.96->1.96.2.1
 661 #
 662 #---------------------
 663
 664 my $state = 0;
 665
 666 sub update_index (\@\@) {
 667         my $old = shift;
 668         my $new = shift;
 669         open(my $fh, '|-', qw(git-update-index -z --index-info))
 670                 or die "unable to open git-update-index: $!";
 671         print $fh
 672                 (map { "0 0000000000000000000000000000000000000000\t$_\0" }
 673                         @$old),
 674                 (map { '100' . sprintf('%o', $_->[0]) . " $_->[1]\t$_->[2]\0" }
 675                         @$new)
 676                 or die "unable to write to git-update-index: $!";
 677         close $fh
 678                 or die "unable to write to git-update-index: $!";
 679         $? and die "git-update-index reported error: $?";
 680 }
 681
 682 sub write_tree () {
 683         open(my $fh, '-|', qw(git-write-tree))
 684                 or die "unable to open git-write-tree: $!";
 685         chomp(my $tree = <$fh>);
 686         is_sha1($tree)
 687                 or die "Cannot get tree id ($tree): $!";
 688         close($fh)
 689                 or die "Error running git-write-tree: $?\n";
 690         print "Tree ID $tree\n" if $opt_v;
 691         return $tree;
 692 }
 693
 694 my ($patchset,$date,$author_name,$author_email,$branch,$ancestor,$tag,$logmsg);
 695 my (@old,@new,@skipped,%ignorebranch);
 696
 697 # commits that cvsps cannot place anywhere...
 698 $ignorebranch{'#CVSPS_NO_BRANCH'} = 1;
 699
 700 sub commit {
 701         if ($branch eq $opt_o && !$index{branch} && !get_headref($branch, $git_dir)) {
 702             # looks like an initial commit
 703             # use the index primed by git-init
 704             $ENV{GIT_INDEX_FILE} = "$git_dir/index";
 705             $index{$branch} = "$git_dir/index";
 706         } else {
 707             # use an index per branch to speed up
 708             # imports of projects with many branches
 709             unless ($index{$branch}) {
 710                 $index{$branch} = tmpnam();
 711                 $ENV{GIT_INDEX_FILE} = $index{$branch};
 712                 if ($ancestor) {
 713                     system("git-read-tree", "$remote/$ancestor");
 714                 } else {
 715                     system("git-read-tree", "$remote/$branch");
 716                 }
 717                 die "read-tree failed: $?\n" if $?;
 718             }
 719         }
 720         $ENV{GIT_INDEX_FILE} = $index{$branch};
 721
 722         update_index(@old, @new);
 723         @old = @new = ();
 724         my $tree = write_tree();
 725         my $parent = get_headref($last_branch, $git_dir);
 726         print "Parent ID " . ($parent ? $parent : "(empty)") . "\n" if $opt_v;
 727
 728         my @commit_args;
 729         push @commit_args, ("-p", $parent) if $parent;
 730
 731         # loose detection of merges
 732         # based on the commit msg
 733         foreach my $rx (@mergerx) {
 734                 next unless $logmsg =~ $rx && $1;
 735                 my $mparent = $1 eq 'HEAD' ? $opt_o : $1;
 736                 if (my $sha1 = get_headref($mparent, $git_dir)) {
 737                         push @commit_args, '-p', $mparent;
 738                         print "Merge parent branch: $mparent\n" if $opt_v;
 739                 }
 740         }
 741
 742         my $commit_date = strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date));
 743         $ENV{GIT_AUTHOR_NAME} = $author_name;
 744         $ENV{GIT_AUTHOR_EMAIL} = $author_email;
 745         $ENV{GIT_AUTHOR_DATE} = $commit_date;
 746         $ENV{GIT_COMMITTER_NAME} = $author_name;
 747         $ENV{GIT_COMMITTER_EMAIL} = $author_email;
 748         $ENV{GIT_COMMITTER_DATE} = $commit_date;
 749         my $pid = open2(my $commit_read, my $commit_write,
 750                 'git-commit-tree', $tree, @commit_args);
 751
 752         # compatibility with git2cvs
 753         substr($logmsg,32767) = "" if length($logmsg) > 32767;
 754         $logmsg =~ s/[\s\n]+\z//;
 755
 756         if (@skipped) {
 757             $logmsg .= "\n\n\nSKIPPED:\n\t";
 758             $logmsg .= join("\n\t", @skipped) . "\n";
 759             @skipped = ();
 760         }
 761
 762         print($commit_write "$logmsg\n") && close($commit_write)
 763                 or die "Error writing to git-commit-tree: $!\n";
 764
 765         print "Committed patch $patchset ($branch $commit_date)\n" if $opt_v;
 766         chomp(my $cid = <$commit_read>);
 767         is_sha1($cid) or die "Cannot get commit id ($cid): $!\n";
 768         print "Commit ID $cid\n" if $opt_v;
 769         close($commit_read);
 770
 771         waitpid($pid,0);
 772         die "Error running git-commit-tree: $?\n" if $?;
 773
 774         system("git-update-ref $remote/$branch $cid") == 0
 775                 or die "Cannot write branch $branch for update: $!\n";
 776
 777         if ($tag) {
 778                 my ($xtag) = $tag;
 779                 $xtag =~ s/\s+\*\*.*$//; # Remove stuff like ** INVALID ** and ** FUNKY **
 780                 $xtag =~ tr/_/\./ if ( $opt_u );
 781                 $xtag =~ s/[\/]/$opt_s/g;
 782
 783                 system('git-tag', '-f', $xtag, $cid) == 0
 784                         or die "Cannot create tag $xtag: $!\n";
 785
 786                 print "Created tag '$xtag' on '$branch'\n" if $opt_v;
 787         }
 788 };
 789
 790 my $commitcount = 1;
 791 while (<CVS>) {
 792         chomp;
 793         if ($state == 0 and /^-+$/) {
 794                 $state = 1;
 795         } elsif ($state == 0) {
 796                 $state = 1;
 797                 redo;
 798         } elsif (($state==0 or $state==1) and s/^PatchSet\s+//) {
 799                 $patchset = 0+$_;
 800                 $state=2;
 801         } elsif ($state == 2 and s/^Date:\s+//) {
 802                 $date = pdate($_);
 803                 unless ($date) {
 804                         print STDERR "Could not parse date: $_\n";
 805                         $state=0;
 806                         next;
 807                 }
 808                 $state=3;
 809         } elsif ($state == 3 and s/^Author:\s+//) {
 810                 s/\s+$//;
 811                 if (/^(.*?)\s+<(.*)>/) {
 812                     ($author_name, $author_email) = ($1, $2);
 813                 } elsif ($conv_author_name{$_}) {
 814                         $author_name = $conv_author_name{$_};
 815                         $author_email = $conv_author_email{$_};
 816                 } else {
 817                     $author_name = $author_email = $_;
 818                 }
 819                 $state = 4;
 820         } elsif ($state == 4 and s/^Branch:\s+//) {
 821                 s/\s+$//;
 822                 tr/_/\./ if ( $opt_u );
 823                 s/[\/]/$opt_s/g;
 824                 $branch = $_;
 825                 $state = 5;
 826         } elsif ($state == 5 and s/^Ancestor branch:\s+//) {
 827                 s/\s+$//;
 828                 $ancestor = $_;
 829                 $ancestor = $opt_o if $ancestor eq "HEAD";
 830                 $state = 6;
 831         } elsif ($state == 5) {
 832                 $ancestor = undef;
 833                 $state = 6;
 834                 redo;
 835         } elsif ($state == 6 and s/^Tag:\s+//) {
 836                 s/\s+$//;
 837                 if ($_ eq "(none)") {
 838                         $tag = undef;
 839                 } else {
 840                         $tag = $_;
 841                 }
 842                 $state = 7;
 843         } elsif ($state == 7 and /^Log:/) {
 844                 $logmsg = "";
 845                 $state = 8;
 846         } elsif ($state == 8 and /^Members:/) {
 847                 $branch = $opt_o if $branch eq "HEAD";
 848                 if (defined $branch_date{$branch} and $branch_date{$branch} >= $date) {
 849                         # skip
 850                         print "skip patchset $patchset: $date before $branch_date{$branch}\n" if $opt_v;
 851                         $state = 11;
 852                         next;
 853                 }
 854                 if (!$opt_a && $starttime - 300 - (defined $opt_z ? $opt_z : 300) <= $date) {
 855                         # skip if the commit is too recent
 856                         # that the cvsps default fuzz is 300s, we give ourselves another
 857                         # 300s just in case -- this also prevents skipping commits
 858                         # due to server clock drift
 859                         print "skip patchset $patchset: $date too recent\n" if $opt_v;
 860                         $state = 11;
 861                         next;
 862                 }
 863                 if (exists $ignorebranch{$branch}) {
 864                         print STDERR "Skipping $branch\n";
 865                         $state = 11;
 866                         next;
 867                 }
 868                 if ($ancestor) {
 869                         if ($ancestor eq $branch) {
 870                                 print STDERR "Branch $branch erroneously stems from itself -- changed ancestor to $opt_o\n";
 871                                 $ancestor = $opt_o;
 872                         }
 873                         if (-f "$git_dir/$remote/$branch") {
 874                                 print STDERR "Branch $branch already exists!\n";
 875                                 $state=11;
 876                                 next;
 877                         }
 878                         unless (open(H,"$git_dir/$remote/$ancestor")) {
 879                                 print STDERR "Branch $ancestor does not exist!\n";
 880                                 $ignorebranch{$branch} = 1;
 881                                 $state=11;
 882                                 next;
 883                         }
 884                         chomp(my $id = <H>);
 885                         close(H);
 886                         unless (open(H,"> $git_dir/$remote/$branch")) {
 887                                 print STDERR "Could not create branch $branch: $!\n";
 888                                 $ignorebranch{$branch} = 1;
 889                                 $state=11;
 890                                 next;
 891                         }
 892                         print H "$id\n"
 893                                 or die "Could not write branch $branch: $!";
 894                         close(H)
 895                                 or die "Could not write branch $branch: $!";
 896                 }
 897                 $last_branch = $branch if $branch ne $last_branch;
 898                 $state = 9;
 899         } elsif ($state == 8) {
 900                 $logmsg .= "$_\n";
 901         } elsif ($state == 9 and /^\s+(.+?):(INITIAL|\d+(?:\.\d+)+)->(\d+(?:\.\d+)+)\s*$/) {
 902 #       VERSION:1.96->1.96.2.1
 903                 my $init = ($2 eq "INITIAL");
 904                 my $fn = $1;
 905                 my $rev = $3;
 906                 $fn =~ s#^/+##;
 907                 if ($opt_S && $fn =~ m/$opt_S/) {
 908                     print "SKIPPING $fn v $rev\n";
 909                     push(@skipped, $fn);
 910                     next;
 911                 }
 912                 print "Fetching $fn   v $rev\n" if $opt_v;
 913                 my ($tmpname, $size) = $cvs->file($fn,$rev);
 914                 if ($size == -1) {
 915                         push(@old,$fn);
 916                         print "Drop $fn\n" if $opt_v;
 917                 } else {
 918                         print "".($init ? "New" : "Update")." $fn: $size bytes\n" if $opt_v;
 919                         my $pid = open(my $F, '-|');
 920                         die $! unless defined $pid;
 921                         if (!$pid) {
 922                             exec("git-hash-object", "-w", $tmpname)
 923                                 or die "Cannot create object: $!\n";
 924                         }
 925                         my $sha = <$F>;
 926                         chomp $sha;
 927                         close $F;
 928                         my $mode = pmode($cvs->{'mode'});
 929                         push(@new,[$mode, $sha, $fn]); # may be resurrected!
 930                 }
 931                 unlink($tmpname);
 932         } elsif ($state == 9 and /^\s+(.+?):\d+(?:\.\d+)+->(\d+(?:\.\d+)+)\(DEAD\)\s*$/) {
 933                 my $fn = $1;
 934                 $fn =~ s#^/+##;
 935                 push(@old,$fn);
 936                 print "Delete $fn\n" if $opt_v;
 937         } elsif ($state == 9 and /^\s*$/) {
 938                 $state = 10;
 939         } elsif (($state == 9 or $state == 10) and /^-+$/) {
 940                 $commitcount++;
 941                 if ($opt_L && $commitcount > $opt_L) {
 942                         last;
 943                 }
 944                 commit();
 945                 if (($commitcount & 1023) == 0) {
 946                         system("git repack -a -d");
 947                 }
 948                 $state = 1;
 949         } elsif ($state == 11 and /^-+$/) {
 950                 $state = 1;
 951         } elsif (/^-+$/) { # end of unknown-line processing
 952                 $state = 1;
 953         } elsif ($state != 11) { # ignore stuff when skipping
 954                 print "* UNKNOWN LINE * $_\n";
 955         }
 956 }
 957 commit() if $branch and $state != 11;
 958
 959 unless ($opt_P) {
 960         unlink($cvspsfile);
 961 }
 962
 963 # The heuristic of repacking every 1024 commits can leave a
 964 # lot of unpacked data.  If there is more than 1MB worth of
 965 # not-packed objects, repack once more.
 966 my $line = `git-count-objects`;
 967 if ($line =~ /^(\d+) objects, (\d+) kilobytes$/) {
 968   my ($n_objects, $kb) = ($1, $2);
 969   1024 < $kb
 970     and system("git repack -a -d");
 971 }
 972
 973 foreach my $git_index (values %index) {
 974     if ($git_index ne "$git_dir/index") {
 975         unlink($git_index);
 976     }
 977 }
 978
 979 if (defined $orig_git_index) {
 980         $ENV{GIT_INDEX_FILE} = $orig_git_index;
 981 } else {
 982         delete $ENV{GIT_INDEX_FILE};
 983 }
 984
 985 # Now switch back to the branch we were in before all of this happened
 986 if ($orig_branch) {
 987         print "DONE.\n" if $opt_v;
 988         if ($opt_i) {
 989                 exit 0;
 990         }
 991         my $tip_at_end = `git-rev-parse --verify HEAD`;
 992         if ($tip_at_start ne $tip_at_end) {
 993                 for ($tip_at_start, $tip_at_end) { chomp; }
 994                 print "Fetched into the current branch.\n" if $opt_v;
 995                 system(qw(git-read-tree -u -m),
 996                        $tip_at_start, $tip_at_end);
 997                 die "Fast-forward update failed: $?\n" if $?;
 998         }
 999         else {
1000                 system(qw(git-merge cvsimport HEAD), "$remote/$opt_o");
1001                 die "Could not merge $opt_o into the current branch.\n" if $?;
1002         }
1003 } else {
1004         $orig_branch = "master";
1005         print "DONE; creating $orig_branch branch\n" if $opt_v;
1006         system("git-update-ref", "refs/heads/master", "$remote/$opt_o")
1007                 unless -f "$git_dir/refs/heads/master";
1008         system("git-symbolic-ref", "$remote/HEAD", "$remote/$opt_o")
1009                 if ($opt_r && $opt_o ne 'HEAD');
1010         system('git-update-ref', 'HEAD', "$orig_branch");
1011         unless ($opt_i) {
1012                 system('git checkout -f');
1013                 die "checkout failed: $?\n" if $?;
1014         }
1015 }