git-remote.perl

   1 #!/usr/bin/perl -w
   2
   3 use Git;
   4 my $git = Git->repository();
   5
   6 sub add_remote_config {
   7         my ($hash, $name, $what, $value) = @_;
   8         if ($what eq 'url') {
   9                 if (exists $hash->{$name}{'URL'}) {
  10                         print STDERR "Warning: more than one remote.$name.url\n";
  11                 }
  12                 $hash->{$name}{'URL'} = $value;
  13         }
  14         elsif ($what eq 'fetch') {
  15                 $hash->{$name}{'FETCH'} ||= [];
  16                 push @{$hash->{$name}{'FETCH'}}, $value;
  17         }
  18         elsif ($what eq 'push') {
  19                 $hash->{$name}{'PUSH'} ||= [];
  20                 push @{$hash->{$name}{'PUSH'}}, $value;
  21         }
  22         if (!exists $hash->{$name}{'SOURCE'}) {
  23                 $hash->{$name}{'SOURCE'} = 'config';
  24         }
  25 }
  26
  27 sub add_remote_remotes {
  28         my ($hash, $file, $name) = @_;
  29
  30         if (exists $hash->{$name}) {
  31                 $hash->{$name}{'WARNING'} = 'ignored due to config';
  32                 return;
  33         }
  34
  35         my $fh;
  36         if (!open($fh, '<', $file)) {
  37                 print STDERR "Warning: cannot open $file\n";
  38                 return;
  39         }
  40         my $it = { 'SOURCE' => 'remotes' };
  41         $hash->{$name} = $it;
  42         while (<$fh>) {
  43                 chomp;
  44                 if (/^URL:\s*(.*)$/) {
  45                         # Having more than one is Ok -- it is used for push.
  46                         if (! exists $it->{'URL'}) {
  47                                 $it->{'URL'} = $1;
  48                         }
  49                 }
  50                 elsif (/^Push:\s*(.*)$/) {
  51                         $it->{'PUSH'} ||= [];
  52                         push @{$it->{'PUSH'}}, $1;
  53                 }
  54                 elsif (/^Pull:\s*(.*)$/) {
  55                         $it->{'FETCH'} ||= [];
  56                         push @{$it->{'FETCH'}}, $1;
  57                 }
  58                 elsif (/^\#/) {
  59                         ; # ignore
  60                 }
  61                 else {
  62                         print STDERR "Warning: funny line in $file: $_\n";
  63                 }
  64         }
  65         close($fh);
  66 }
  67
  68 sub list_remote {
  69         my ($git) = @_;
  70         my %seen = ();
  71         my @remotes = eval {
  72                 $git->command(qw(config --get-regexp), '^remote\.');
  73         };
  74         for (@remotes) {
  75                 if (/^remote\.(\S+?)\.([^.\s]+)\s+(.*)$/) {
  76                         add_remote_config(\%seen, $1, $2, $3);
  77                 }
  78         }
  79
  80         my $dir = $git->repo_path() . "/remotes";
  81         if (opendir(my $dh, $dir)) {
  82                 local $_;
  83                 while ($_ = readdir($dh)) {
  84                         chomp;
  85                         next if (! -f "$dir/$_" || ! -r _);
  86                         add_remote_remotes(\%seen, "$dir/$_", $_);
  87                 }
  88         }
  89
  90         return \%seen;
  91 }
  92
  93 sub add_branch_config {
  94         my ($hash, $name, $what, $value) = @_;
  95         if ($what eq 'remote') {
  96                 if (exists $hash->{$name}{'REMOTE'}) {
  97                         print STDERR "Warning: more than one branch.$name.remote\n";
  98                 }
  99                 $hash->{$name}{'REMOTE'} = $value;
 100         }
 101         elsif ($what eq 'merge') {
 102                 $hash->{$name}{'MERGE'} ||= [];
 103                 push @{$hash->{$name}{'MERGE'}}, $value;
 104         }
 105 }
 106
 107 sub list_branch {
 108         my ($git) = @_;
 109         my %seen = ();
 110         my @branches = eval {
 111                 $git->command(qw(config --get-regexp), '^branch\.');
 112         };
 113         for (@branches) {
 114                 if (/^branch\.([^.]*)\.(\S*)\s+(.*)$/) {
 115                         add_branch_config(\%seen, $1, $2, $3);
 116                 }
 117         }
 118
 119         return \%seen;
 120 }
 121
 122 my $remote = list_remote($git);
 123 my $branch = list_branch($git);
 124
 125 sub update_ls_remote {
 126         my ($harder, $info) = @_;
 127
 128         return if (($harder == 0) ||
 129                    (($harder == 1) && exists $info->{'LS_REMOTE'}));
 130
 131         my @ref = map {
 132                 s|^[0-9a-f]{40}\s+refs/heads/||;
 133                 $_;
 134         } $git->command(qw(ls-remote --heads), $info->{'URL'});
 135         $info->{'LS_REMOTE'} = \@ref;
 136 }
 137
 138 sub list_wildcard_mapping {
 139         my ($forced, $ours, $ls) = @_;
 140         my %refs;
 141         for (@$ls) {
 142                 $refs{$_} = 01; # bit #0 to say "they have"
 143         }
 144         for ($git->command('for-each-ref', "refs/remotes/$ours")) {
 145                 chomp;
 146                 next unless (s|^[0-9a-f]{40}\s[a-z]+\srefs/remotes/$ours/||);
 147                 next if ($_ eq 'HEAD');
 148                 $refs{$_} ||= 0;
 149                 $refs{$_} |= 02; # bit #1 to say "we have"
 150         }
 151         my (@new, @stale, @tracked);
 152         for (sort keys %refs) {
 153                 my $have = $refs{$_};
 154                 if ($have == 1) {
 155                         push @new, $_;
 156                 }
 157                 elsif ($have == 2) {
 158                         push @stale, $_;
 159                 }
 160                 elsif ($have == 3) {
 161                         push @tracked, $_;
 162                 }
 163         }
 164         return \@new, \@stale, \@tracked;
 165 }
 166
 167 sub list_mapping {
 168         my ($name, $info) = @_;
 169         my $fetch = $info->{'FETCH'};
 170         my $ls = $info->{'LS_REMOTE'};
 171         my (@new, @stale, @tracked);
 172
 173         for (@$fetch) {
 174                 next unless (/(\+)?([^:]+):(.*)/);
 175                 my ($forced, $theirs, $ours) = ($1, $2, $3);
 176                 if ($theirs eq 'refs/heads/*' &&
 177                     $ours =~ /^refs\/remotes\/(.*)\/\*$/) {
 178                         # wildcard mapping
 179                         my ($w_new, $w_stale, $w_tracked)
 180                                 = list_wildcard_mapping($forced, $1, $ls);
 181                         push @new, @$w_new;
 182                         push @stale, @$w_stale;
 183                         push @tracked, @$w_tracked;
 184                 }
 185                 elsif ($theirs =~ /\*/ || $ours =~ /\*/) {
 186                         print STDERR "Warning: unrecognized mapping in remotes.$name.fetch: $_\n";
 187                 }
 188                 elsif ($theirs =~ s|^refs/heads/||) {
 189                         if (!grep { $_ eq $theirs } @$ls) {
 190                                 push @stale, $theirs;
 191                         }
 192                         elsif ($ours ne '') {
 193                                 push @tracked, $theirs;
 194                         }
 195                 }
 196         }
 197         return \@new, \@stale, \@tracked;
 198 }
 199
 200 sub show_mapping {
 201         my ($name, $info) = @_;
 202         my ($new, $stale, $tracked) = list_mapping($name, $info);
 203         if (@$new) {
 204                 print "  New remote branches (next fetch will store in remotes/$name)\n";
 205                 print "    @$new\n";
 206         }
 207         if (@$stale) {
 208                 print "  Stale tracking branches in remotes/$name (use 'git remote prune')\n";
 209                 print "    @$stale\n";
 210         }
 211         if (@$tracked) {
 212                 print "  Tracked remote branches\n";
 213                 print "    @$tracked\n";
 214         }
 215 }
 216
 217 sub prune_remote {
 218         my ($name, $ls_remote) = @_;
 219         if (!exists $remote->{$name}) {
 220                 print STDERR "No such remote $name\n";
 221                 return 1;
 222         }
 223         my $info = $remote->{$name};
 224         update_ls_remote($ls_remote, $info);
 225
 226         my ($new, $stale, $tracked) = list_mapping($name, $info);
 227         my $prefix = "refs/remotes/$name";
 228         foreach my $to_prune (@$stale) {
 229                 my @v = $git->command(qw(rev-parse --verify), "$prefix/$to_prune");
 230                 $git->command(qw(update-ref -d), "$prefix/$to_prune", $v[0]);
 231         }
 232         return 0;
 233 }
 234
 235 sub show_remote {
 236         my ($name, $ls_remote) = @_;
 237         if (!exists $remote->{$name}) {
 238                 print STDERR "No such remote $name\n";
 239                 return 1;
 240         }
 241         my $info = $remote->{$name};
 242         update_ls_remote($ls_remote, $info);
 243
 244         print "* remote $name\n";
 245         print "  URL: $info->{'URL'}\n";
 246         for my $branchname (sort keys %$branch) {
 247                 next if ($branch->{$branchname}{'REMOTE'} ne $name);
 248                 my @merged = map {
 249                         s|^refs/heads/||;
 250                         $_;
 251                 } split(' ',"@{$branch->{$branchname}{'MERGE'}}");
 252                 next unless (@merged);
 253                 print "  Remote branch(es) merged with 'git pull' while on branch $branchname\n";
 254                 print "    @merged\n";
 255         }
 256         if ($info->{'LS_REMOTE'}) {
 257                 show_mapping($name, $info);
 258         }
 259         if ($info->{'PUSH'}) {
 260                 my @pushed = map {
 261                         s|^refs/heads/||;
 262                         s|^\+refs/heads/|+|;
 263                         s|:refs/heads/|:|;
 264                         $_;
 265                 } @{$info->{'PUSH'}};
 266                 print "  Local branch(es) pushed with 'git push'\n";
 267                 print "    @pushed\n";
 268         }
 269         return 0;
 270 }
 271
 272 sub add_remote {
 273         my ($name, $url, $opts) = @_;
 274         if (exists $remote->{$name}) {
 275                 print STDERR "remote $name already exists.\n";
 276                 exit(1);
 277         }
 278         $git->command('config', "remote.$name.url", $url);
 279         my $track = $opts->{'track'} || ["*"];
 280
 281         for (@$track) {
 282                 $git->command('config', '--add', "remote.$name.fetch",
 283                                 $opts->{'mirror'} ?
 284                                 "+refs/$_:refs/$_" :
 285                                 "+refs/heads/$_:refs/remotes/$name/$_");
 286         }
 287         if ($opts->{'fetch'}) {
 288                 $git->command('fetch', $name);
 289         }
 290         if (exists $opts->{'master'}) {
 291                 $git->command('symbolic-ref', "refs/remotes/$name/HEAD",
 292                               "refs/remotes/$name/$opts->{'master'}");
 293         }
 294 }
 295
 296 sub update_remote {
 297         my ($name) = @_;
 298
 299         my $conf = $git->config("remotes." . $name);
 300         if (defined($conf)) {
 301                 @remotes = split(' ', $conf);
 302         } elsif ($name eq 'default') {
 303                 undef @remotes;
 304                 for (sort keys %$remote) {
 305                         my $do_fetch = $git->config_bool("remote." . $_ .
 306                                                     ".skipDefaultUpdate");
 307                         unless ($do_fetch) {
 308                                 push @remotes, $_;
 309                         }
 310                 }
 311         } else {
 312                 print STDERR "Remote group $name does not exists.\n";
 313                 exit(1);
 314         }
 315         for (@remotes) {
 316                 print "Updating $_\n";
 317                 $git->command('fetch', "$_");
 318         }
 319 }
 320
 321 sub rm_remote {
 322         my ($name) = @_;
 323         if (!exists $remote->{$name}) {
 324                 print STDERR "No such remote $name\n";
 325                 return 1;
 326         }
 327
 328         $git->command('config', '--remove-section', "remote.$name");
 329
 330         eval {
 331             my @trackers = $git->command('config', '--get-regexp',
 332                         'branch.*.remote', $name);
 333                 for (@trackers) {
 334                         /^branch\.(.*)?\.remote/;
 335                         $git->config('--unset', "branch.$1.remote");
 336                         $git->config('--unset', "branch.$1.merge");
 337                 }
 338         };
 339
 340         my @refs = $git->command('for-each-ref',
 341                 '--format=%(refname) %(objectname)', "refs/remotes/$name");
 342         for (@refs) {
 343                 ($ref, $object) = split;
 344                 $git->command(qw(update-ref -d), $ref, $object);
 345         }
 346         return 0;
 347 }
 348
 349 sub add_usage {
 350         print STDERR "Usage: git remote add [-f] [-t track]* [-m master] <name> <url>\n";
 351         exit(1);
 352 }
 353
 354 local $VERBOSE = 0;
 355 @ARGV = grep {
 356         if ($_ eq '-v' or $_ eq '--verbose') {
 357                 $VERBOSE=1;
 358                 0
 359         } else {
 360                 1
 361         }
 362 } @ARGV;
 363
 364 if (!@ARGV) {
 365         for (sort keys %$remote) {
 366                 print "$_";
 367                 print "\t$remote->{$_}->{URL}" if $VERBOSE;
 368                 print "\n";
 369         }
 370 }
 371 elsif ($ARGV[0] eq 'show') {
 372         my $ls_remote = 1;
 373         my $i;
 374         for ($i = 1; $i < @ARGV; $i++) {
 375                 if ($ARGV[$i] eq '-n') {
 376                         $ls_remote = 0;
 377                 }
 378                 else {
 379                         last;
 380                 }
 381         }
 382         if ($i >= @ARGV) {
 383                 print STDERR "Usage: git remote show <remote>\n";
 384                 exit(1);
 385         }
 386         my $status = 0;
 387         for (; $i < @ARGV; $i++) {
 388                 $status |= show_remote($ARGV[$i], $ls_remote);
 389         }
 390         exit($status);
 391 }
 392 elsif ($ARGV[0] eq 'update') {
 393         if (@ARGV <= 1) {
 394                 update_remote("default");
 395                 exit(1);
 396         }
 397         for ($i = 1; $i < @ARGV; $i++) {
 398                 update_remote($ARGV[$i]);
 399         }
 400 }
 401 elsif ($ARGV[0] eq 'prune') {
 402         my $ls_remote = 1;
 403         my $i;
 404         for ($i = 1; $i < @ARGV; $i++) {
 405                 if ($ARGV[$i] eq '-n') {
 406                         $ls_remote = 0;
 407                 }
 408                 else {
 409                         last;
 410                 }
 411         }
 412         if ($i >= @ARGV) {
 413                 print STDERR "Usage: git remote prune <remote>\n";
 414                 exit(1);
 415         }
 416         my $status = 0;
 417         for (; $i < @ARGV; $i++) {
 418                 $status |= prune_remote($ARGV[$i], $ls_remote);
 419         }
 420         exit($status);
 421 }
 422 elsif ($ARGV[0] eq 'add') {
 423         my %opts = ();
 424         while (1 < @ARGV && $ARGV[1] =~ /^-/) {
 425                 my $opt = $ARGV[1];
 426                 shift @ARGV;
 427                 if ($opt eq '-f' || $opt eq '--fetch') {
 428                         $opts{'fetch'} = 1;
 429                         next;
 430                 }
 431                 if ($opt eq '-t' || $opt eq '--track') {
 432                         if (@ARGV < 1) {
 433                                 add_usage();
 434                         }
 435                         $opts{'track'} ||= [];
 436                         push @{$opts{'track'}}, $ARGV[1];
 437                         shift @ARGV;
 438                         next;
 439                 }
 440                 if ($opt eq '-m' || $opt eq '--master') {
 441                         if ((@ARGV < 1) || exists $opts{'master'}) {
 442                                 add_usage();
 443                         }
 444                         $opts{'master'} = $ARGV[1];
 445                         shift @ARGV;
 446                         next;
 447                 }
 448                 if ($opt eq '--mirror') {
 449                         $opts{'mirror'} = 1;
 450                         next;
 451                 }
 452                 add_usage();
 453         }
 454         if (@ARGV != 3) {
 455                 add_usage();
 456         }
 457         add_remote($ARGV[1], $ARGV[2], \%opts);
 458 }
 459 elsif ($ARGV[0] eq 'rm') {
 460         if (@ARGV <= 1) {
 461                 print STDERR "Usage: git remote rm <remote>\n";
 462                 exit(1);
 463         }
 464         exit(rm_remote($ARGV[1]));
 465 }
 466 else {
 467         print STDERR "Usage: git remote\n";
 468         print STDERR "       git remote add <name> <url>\n";
 469         print STDERR "       git remote rm <name>\n";
 470         print STDERR "       git remote show <name>\n";
 471         print STDERR "       git remote prune <name>\n";
 472         print STDERR "       git remote update [group]\n";
 473         exit(1);
 474 }