git-send-email.perl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use 5.008;
  20 use strict;
  21 use warnings;
  22 use Term::ReadLine;
  23 use Getopt::Long;
  24 use Text::ParseWords;
  25 use Data::Dumper;
  26 use Term::ANSIColor;
  27 use File::Temp qw/ tempdir tempfile /;
  28 use File::Spec::Functions qw(catfile);
  29 use Error qw(:try);
  30 use Git;
  31
  32 Getopt::Long::Configure qw/ pass_through /;
  33
  34 package FakeTerm;
  35 sub new {
  36         my ($class, $reason) = @_;
  37         return bless \$reason, shift;
  38 }
  39 sub readline {
  40         my $self = shift;
  41         die "Cannot use readline on FakeTerm: $$self";
  42 }
  43 package main;
  44
  45
  46 sub usage {
  47         print <<EOT;
  48 git send-email [options] <file | directory | rev-list options >
  49
  50   Composing:
  51     --from                  <str>  * Email From:
  52     --[no-]to               <str>  * Email To:
  53     --[no-]cc               <str>  * Email Cc:
  54     --[no-]bcc              <str>  * Email Bcc:
  55     --subject               <str>  * Email "Subject:"
  56     --in-reply-to           <str>  * Email "In-Reply-To:"
  57     --annotate                     * Review each patch that will be sent in an editor.
  58     --compose                      * Open an editor for introduction.
  59     --compose-encoding      <str>  * Encoding to assume for introduction.
  60     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  61
  62   Sending:
  63     --envelope-sender       <str>  * Email envelope sender.
  64     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  65                                      is optional. Default 'localhost'.
  66     --smtp-server-option    <str>  * Outgoing SMTP server option to use.
  67     --smtp-server-port      <int>  * Outgoing SMTP server port.
  68     --smtp-user             <str>  * Username for SMTP-AUTH.
  69     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  70     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  71     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  72     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  73     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  74
  75   Automating:
  76     --identity              <str>  * Use the sendemail.<id> options.
  77     --to-cmd                <str>  * Email To: via `<str> \$patch_path`
  78     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  79     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  80     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  81     --[no-]suppress-from           * Send to self. Default off.
  82     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  83     --[no-]thread                  * Use In-Reply-To: field. Default on.
  84
  85   Administering:
  86     --confirm               <str>  * Confirm recipients before sending;
  87                                      auto, cc, compose, always, or never.
  88     --quiet                        * Output one line of info per email.
  89     --dry-run                      * Don't actually send the emails.
  90     --[no-]validate                * Perform patch sanity checks. Default on.
  91     --[no-]format-patch            * understand any non optional arguments as
  92                                      `git format-patch` ones.
  93     --force                        * Send even if safety checks would prevent it.
  94
  95 EOT
  96         exit(1);
  97 }
  98
  99 # most mail servers generate the Date: header, but not all...
 100 sub format_2822_time {
 101         my ($time) = @_;
 102         my @localtm = localtime($time);
 103         my @gmttm = gmtime($time);
 104         my $localmin = $localtm[1] + $localtm[2] * 60;
 105         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 106         if ($localtm[0] != $gmttm[0]) {
 107                 die "local zone differs from GMT by a non-minute interval\n";
 108         }
 109         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 110                 $localmin += 1440;
 111         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 112                 $localmin -= 1440;
 113         } elsif ($gmttm[6] != $localtm[6]) {
 114                 die "local time offset greater than or equal to 24 hours\n";
 115         }
 116         my $offset = $localmin - $gmtmin;
 117         my $offhour = $offset / 60;
 118         my $offmin = abs($offset % 60);
 119         if (abs($offhour) >= 24) {
 120                 die ("local time offset greater than or equal to 24 hours\n");
 121         }
 122
 123         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 124                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 125                        $localtm[3],
 126                        qw(Jan Feb Mar Apr May Jun
 127                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 128                        $localtm[5]+1900,
 129                        $localtm[2],
 130                        $localtm[1],
 131                        $localtm[0],
 132                        ($offset >= 0) ? '+' : '-',
 133                        abs($offhour),
 134                        $offmin,
 135                        );
 136 }
 137
 138 my $have_email_valid = eval { require Email::Valid; 1 };
 139 my $have_mail_address = eval { require Mail::Address; 1 };
 140 my $smtp;
 141 my $auth;
 142
 143 # Variables we fill in automatically, or via prompting:
 144 my (@to,$no_to,@initial_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 145         $initial_reply_to,$initial_subject,@files,
 146         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 147
 148 my $envelope_sender;
 149
 150 # Example reply to:
 151 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 152
 153 my $repo = eval { Git->repository() };
 154 my @repo = $repo ? ($repo) : ();
 155 my $term = eval {
 156         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 157                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 158                 : new Term::ReadLine 'git-send-email';
 159 };
 160 if ($@) {
 161         $term = new FakeTerm "$@: going non-interactive";
 162 }
 163
 164 # Behavior modification variables
 165 my ($quiet, $dry_run) = (0, 0);
 166 my $format_patch;
 167 my $compose_filename;
 168 my $force = 0;
 169
 170 # Handle interactive edition of files.
 171 my $multiedit;
 172 my $editor;
 173
 174 sub do_edit {
 175         if (!defined($editor)) {
 176                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 177         }
 178         if (defined($multiedit) && !$multiedit) {
 179                 map {
 180                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 181                         if (($? & 127) || ($? >> 8)) {
 182                                 die("the editor exited uncleanly, aborting everything");
 183                         }
 184                 } @_;
 185         } else {
 186                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 187                 if (($? & 127) || ($? >> 8)) {
 188                         die("the editor exited uncleanly, aborting everything");
 189                 }
 190         }
 191 }
 192
 193 # Variables with corresponding config settings
 194 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc);
 195 my ($to_cmd, $cc_cmd);
 196 my ($smtp_server, $smtp_server_port, @smtp_server_options);
 197 my ($smtp_authuser, $smtp_encryption);
 198 my ($identity, $aliasfiletype, @alias_files, $smtp_domain);
 199 my ($validate, $confirm);
 200 my (@suppress_cc);
 201 my ($auto_8bit_encoding);
 202 my ($compose_encoding);
 203
 204 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 205
 206 my $not_set_by_user = "true but not set by the user";
 207
 208 my %config_bool_settings = (
 209     "thread" => [\$thread, 1],
 210     "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
 211     "suppressfrom" => [\$suppress_from, undef],
 212     "signedoffbycc" => [\$signed_off_by_cc, undef],
 213     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 214     "validate" => [\$validate, 1],
 215     "multiedit" => [\$multiedit, undef]
 216 );
 217
 218 my %config_settings = (
 219     "smtpserver" => \$smtp_server,
 220     "smtpserverport" => \$smtp_server_port,
 221     "smtpserveroption" => \@smtp_server_options,
 222     "smtpuser" => \$smtp_authuser,
 223     "smtppass" => \$smtp_authpass,
 224     "smtpdomain" => \$smtp_domain,
 225     "to" => \@initial_to,
 226     "tocmd" => \$to_cmd,
 227     "cc" => \@initial_cc,
 228     "cccmd" => \$cc_cmd,
 229     "aliasfiletype" => \$aliasfiletype,
 230     "bcc" => \@bcclist,
 231     "suppresscc" => \@suppress_cc,
 232     "envelopesender" => \$envelope_sender,
 233     "confirm"   => \$confirm,
 234     "from" => \$sender,
 235     "assume8bitencoding" => \$auto_8bit_encoding,
 236     "composeencoding" => \$compose_encoding,
 237 );
 238
 239 my %config_path_settings = (
 240     "aliasesfile" => \@alias_files,
 241 );
 242
 243 # Help users prepare for 1.7.0
 244 sub chain_reply_to {
 245         if (defined $chain_reply_to &&
 246             $chain_reply_to eq $not_set_by_user) {
 247                 print STDERR
 248                     "In git 1.7.0, the default has changed to --no-chain-reply-to\n" .
 249                     "Set sendemail.chainreplyto configuration variable to true if\n" .
 250                     "you want to keep --chain-reply-to as your default.\n";
 251                 $chain_reply_to = 0;
 252         }
 253         return $chain_reply_to;
 254 }
 255
 256 # Handle Uncouth Termination
 257 sub signal_handler {
 258
 259         # Make text normal
 260         print color("reset"), "\n";
 261
 262         # SMTP password masked
 263         system "stty echo";
 264
 265         # tmp files from --compose
 266         if (defined $compose_filename) {
 267                 if (-e $compose_filename) {
 268                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 269                 }
 270                 if (-e ($compose_filename . ".final")) {
 271                         print "'$compose_filename.final' contains the composed email.\n"
 272                 }
 273         }
 274
 275         exit;
 276 };
 277
 278 $SIG{TERM} = \&signal_handler;
 279 $SIG{INT}  = \&signal_handler;
 280
 281 # Begin by accumulating all the variables (defined above), that we will end up
 282 # needing, first, from the command line:
 283
 284 my $help;
 285 my $rc = GetOptions("h" => \$help,
 286                     "sender|from=s" => \$sender,
 287                     "in-reply-to=s" => \$initial_reply_to,
 288                     "subject=s" => \$initial_subject,
 289                     "to=s" => \@initial_to,
 290                     "to-cmd=s" => \$to_cmd,
 291                     "no-to" => \$no_to,
 292                     "cc=s" => \@initial_cc,
 293                     "no-cc" => \$no_cc,
 294                     "bcc=s" => \@bcclist,
 295                     "no-bcc" => \$no_bcc,
 296                     "chain-reply-to!" => \$chain_reply_to,
 297                     "smtp-server=s" => \$smtp_server,
 298                     "smtp-server-option=s" => \@smtp_server_options,
 299                     "smtp-server-port=s" => \$smtp_server_port,
 300                     "smtp-user=s" => \$smtp_authuser,
 301                     "smtp-pass:s" => \$smtp_authpass,
 302                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 303                     "smtp-encryption=s" => \$smtp_encryption,
 304                     "smtp-debug:i" => \$debug_net_smtp,
 305                     "smtp-domain:s" => \$smtp_domain,
 306                     "identity=s" => \$identity,
 307                     "annotate" => \$annotate,
 308                     "compose" => \$compose,
 309                     "quiet" => \$quiet,
 310                     "cc-cmd=s" => \$cc_cmd,
 311                     "suppress-from!" => \$suppress_from,
 312                     "suppress-cc=s" => \@suppress_cc,
 313                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 314                     "confirm=s" => \$confirm,
 315                     "dry-run" => \$dry_run,
 316                     "envelope-sender=s" => \$envelope_sender,
 317                     "thread!" => \$thread,
 318                     "validate!" => \$validate,
 319                     "format-patch!" => \$format_patch,
 320                     "8bit-encoding=s" => \$auto_8bit_encoding,
 321                     "compose-encoding=s" => \$compose_encoding,
 322                     "force" => \$force,
 323          );
 324
 325 usage() if $help;
 326 unless ($rc) {
 327     usage();
 328 }
 329
 330 die "Cannot run git format-patch from outside a repository\n"
 331         if $format_patch and not $repo;
 332
 333 # Now, let's fill any that aren't set in with defaults:
 334
 335 sub read_config {
 336         my ($prefix) = @_;
 337
 338         foreach my $setting (keys %config_bool_settings) {
 339                 my $target = $config_bool_settings{$setting}->[0];
 340                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 341         }
 342
 343         foreach my $setting (keys %config_path_settings) {
 344                 my $target = $config_path_settings{$setting};
 345                 if (ref($target) eq "ARRAY") {
 346                         unless (@$target) {
 347                                 my @values = Git::config_path(@repo, "$prefix.$setting");
 348                                 @$target = @values if (@values && defined $values[0]);
 349                         }
 350                 }
 351                 else {
 352                         $$target = Git::config_path(@repo, "$prefix.$setting") unless (defined $$target);
 353                 }
 354         }
 355
 356         foreach my $setting (keys %config_settings) {
 357                 my $target = $config_settings{$setting};
 358                 next if $setting eq "to" and defined $no_to;
 359                 next if $setting eq "cc" and defined $no_cc;
 360                 next if $setting eq "bcc" and defined $no_bcc;
 361                 if (ref($target) eq "ARRAY") {
 362                         unless (@$target) {
 363                                 my @values = Git::config(@repo, "$prefix.$setting");
 364                                 @$target = @values if (@values && defined $values[0]);
 365                         }
 366                 }
 367                 else {
 368                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 369                 }
 370         }
 371
 372         if (!defined $smtp_encryption) {
 373                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 374                 if (defined $enc) {
 375                         $smtp_encryption = $enc;
 376                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 377                         $smtp_encryption = 'ssl';
 378                 }
 379         }
 380 }
 381
 382 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 383 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 384 read_config("sendemail.$identity") if (defined $identity);
 385 read_config("sendemail");
 386
 387 # fall back on builtin bool defaults
 388 foreach my $setting (values %config_bool_settings) {
 389         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 390 }
 391
 392 # 'default' encryption is none -- this only prevents a warning
 393 $smtp_encryption = '' unless (defined $smtp_encryption);
 394
 395 # Set CC suppressions
 396 my(%suppress_cc);
 397 if (@suppress_cc) {
 398         foreach my $entry (@suppress_cc) {
 399                 die "Unknown --suppress-cc field: '$entry'\n"
 400                         unless $entry =~ /^(?:all|cccmd|cc|author|self|sob|body|bodycc)$/;
 401                 $suppress_cc{$entry} = 1;
 402         }
 403 }
 404
 405 if ($suppress_cc{'all'}) {
 406         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 407                 $suppress_cc{$entry} = 1;
 408         }
 409         delete $suppress_cc{'all'};
 410 }
 411
 412 # If explicit old-style ones are specified, they trump --suppress-cc.
 413 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 414 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 415
 416 if ($suppress_cc{'body'}) {
 417         foreach my $entry (qw (sob bodycc)) {
 418                 $suppress_cc{$entry} = 1;
 419         }
 420         delete $suppress_cc{'body'};
 421 }
 422
 423 # Set confirm's default value
 424 my $confirm_unconfigured = !defined $confirm;
 425 if ($confirm_unconfigured) {
 426         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 427 };
 428 die "Unknown --confirm setting: '$confirm'\n"
 429         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 430
 431 # Debugging, print out the suppressions.
 432 if (0) {
 433         print "suppressions:\n";
 434         foreach my $entry (keys %suppress_cc) {
 435                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 436         }
 437 }
 438
 439 my ($repoauthor, $repocommitter);
 440 ($repoauthor) = Git::ident_person(@repo, 'author');
 441 ($repocommitter) = Git::ident_person(@repo, 'committer');
 442
 443 # Verify the user input
 444
 445 foreach my $entry (@initial_to) {
 446         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 447 }
 448
 449 foreach my $entry (@initial_cc) {
 450         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 451 }
 452
 453 foreach my $entry (@bcclist) {
 454         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 455 }
 456
 457 sub parse_address_line {
 458         if ($have_mail_address) {
 459                 return map { $_->format } Mail::Address->parse($_[0]);
 460         } else {
 461                 return split_addrs($_[0]);
 462         }
 463 }
 464
 465 sub split_addrs {
 466         return quotewords('\s*,\s*', 1, @_);
 467 }
 468
 469 my %aliases;
 470 my %parse_alias = (
 471         # multiline formats can be supported in the future
 472         mutt => sub { my $fh = shift; while (<$fh>) {
 473                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 474                         my ($alias, $addr) = ($1, $2);
 475                         $addr =~ s/#.*$//; # mutt allows # comments
 476                          # commas delimit multiple addresses
 477                         $aliases{$alias} = [ split_addrs($addr) ];
 478                 }}},
 479         mailrc => sub { my $fh = shift; while (<$fh>) {
 480                 if (/^alias\s+(\S+)\s+(.*)$/) {
 481                         # spaces delimit multiple addresses
 482                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 483                 }}},
 484         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 485                 for (my $x = ''; defined($x); $x = $_) {
 486                         chomp $x;
 487                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 488                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 489                         $aliases{$1} = [ split_addrs($2) ];
 490                 }},
 491         elm => sub  { my $fh = shift;
 492                       while (<$fh>) {
 493                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 494                               my ($alias, $addr) = ($1, $2);
 495                                $aliases{$alias} = [ split_addrs($addr) ];
 496                           }
 497                       } },
 498
 499         gnus => sub { my $fh = shift; while (<$fh>) {
 500                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 501                         $aliases{$1} = [ $2 ];
 502                 }}}
 503 );
 504
 505 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 506         foreach my $file (@alias_files) {
 507                 open my $fh, '<', $file or die "opening $file: $!\n";
 508                 $parse_alias{$aliasfiletype}->($fh);
 509                 close $fh;
 510         }
 511 }
 512
 513 ($sender) = expand_aliases($sender) if defined $sender;
 514
 515 # is_format_patch_arg($f) returns 0 if $f names a patch, or 1 if
 516 # $f is a revision list specification to be passed to format-patch.
 517 sub is_format_patch_arg {
 518         return unless $repo;
 519         my $f = shift;
 520         try {
 521                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 522                 if (defined($format_patch)) {
 523                         return $format_patch;
 524                 }
 525                 die(<<EOF);
 526 File '$f' exists but it could also be the range of commits
 527 to produce patches for.  Please disambiguate by...
 528
 529     * Saying "./$f" if you mean a file; or
 530     * Giving --format-patch option if you mean a range.
 531 EOF
 532         } catch Git::Error::Command with {
 533                 # Not a valid revision.  Treat it as a filename.
 534                 return 0;
 535         }
 536 }
 537
 538 # Now that all the defaults are set, process the rest of the command line
 539 # arguments and collect up the files that need to be processed.
 540 my @rev_list_opts;
 541 while (defined(my $f = shift @ARGV)) {
 542         if ($f eq "--") {
 543                 push @rev_list_opts, "--", @ARGV;
 544                 @ARGV = ();
 545         } elsif (-d $f and !is_format_patch_arg($f)) {
 546                 opendir my $dh, $f
 547                         or die "Failed to opendir $f: $!";
 548
 549                 push @files, grep { -f $_ } map { catfile($f, $_) }
 550                                 sort readdir $dh;
 551                 closedir $dh;
 552         } elsif ((-f $f or -p $f) and !is_format_patch_arg($f)) {
 553                 push @files, $f;
 554         } else {
 555                 push @rev_list_opts, $f;
 556         }
 557 }
 558
 559 if (@rev_list_opts) {
 560         die "Cannot run git format-patch from outside a repository\n"
 561                 unless $repo;
 562         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 563 }
 564
 565 if ($validate) {
 566         foreach my $f (@files) {
 567                 unless (-p $f) {
 568                         my $error = validate_patch($f);
 569                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 570                 }
 571         }
 572 }
 573
 574 if (@files) {
 575         unless ($quiet) {
 576                 print $_,"\n" for (@files);
 577         }
 578 } else {
 579         print STDERR "\nNo patch files specified!\n\n";
 580         usage();
 581 }
 582
 583 sub get_patch_subject {
 584         my $fn = shift;
 585         open (my $fh, '<', $fn);
 586         while (my $line = <$fh>) {
 587                 next unless ($line =~ /^Subject: (.*)$/);
 588                 close $fh;
 589                 return "GIT: $1\n";
 590         }
 591         close $fh;
 592         die "No subject line in $fn ?";
 593 }
 594
 595 if ($compose) {
 596         # Note that this does not need to be secure, but we will make a small
 597         # effort to have it be unique
 598         $compose_filename = ($repo ?
 599                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 600                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 601         open my $c, ">", $compose_filename
 602                 or die "Failed to open for writing $compose_filename: $!";
 603
 604
 605         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 606         my $tpl_subject = $initial_subject || '';
 607         my $tpl_reply_to = $initial_reply_to || '';
 608
 609         print $c <<EOT;
 610 From $tpl_sender # This line is ignored.
 611 GIT: Lines beginning in "GIT:" will be removed.
 612 GIT: Consider including an overall diffstat or table of contents
 613 GIT: for the patch you are writing.
 614 GIT:
 615 GIT: Clear the body content if you don't wish to send a summary.
 616 From: $tpl_sender
 617 Subject: $tpl_subject
 618 In-Reply-To: $tpl_reply_to
 619
 620 EOT
 621         for my $f (@files) {
 622                 print $c get_patch_subject($f);
 623         }
 624         close $c;
 625
 626         if ($annotate) {
 627                 do_edit($compose_filename, @files);
 628         } else {
 629                 do_edit($compose_filename);
 630         }
 631
 632         open my $c2, ">", $compose_filename . ".final"
 633                 or die "Failed to open $compose_filename.final : " . $!;
 634
 635         open $c, "<", $compose_filename
 636                 or die "Failed to open $compose_filename : " . $!;
 637
 638         my $need_8bit_cte = file_has_nonascii($compose_filename);
 639         my $in_body = 0;
 640         my $summary_empty = 1;
 641         if (!defined $compose_encoding) {
 642                 $compose_encoding = "UTF-8";
 643         }
 644         while(<$c>) {
 645                 next if m/^GIT:/;
 646                 if ($in_body) {
 647                         $summary_empty = 0 unless (/^\n$/);
 648                 } elsif (/^\n$/) {
 649                         $in_body = 1;
 650                         if ($need_8bit_cte) {
 651                                 print $c2 "MIME-Version: 1.0\n",
 652                                          "Content-Type: text/plain; ",
 653                                            "charset=$compose_encoding\n",
 654                                          "Content-Transfer-Encoding: 8bit\n";
 655                         }
 656                 } elsif (/^MIME-Version:/i) {
 657                         $need_8bit_cte = 0;
 658                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 659                         $initial_subject = $1;
 660                         my $subject = $initial_subject;
 661                         $_ = "Subject: " .
 662                                 quote_subject($subject, $compose_encoding) .
 663                                 "\n";
 664                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 665                         $initial_reply_to = $1;
 666                         next;
 667                 } elsif (/^From:\s*(.+)\s*$/i) {
 668                         $sender = $1;
 669                         next;
 670                 } elsif (/^(?:To|Cc|Bcc):/i) {
 671                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 672                         next;
 673                 }
 674                 print $c2 $_;
 675         }
 676         close $c;
 677         close $c2;
 678
 679         if ($summary_empty) {
 680                 print "Summary email is empty, skipping it\n";
 681                 $compose = -1;
 682         }
 683 } elsif ($annotate) {
 684         do_edit(@files);
 685 }
 686
 687 sub ask {
 688         my ($prompt, %arg) = @_;
 689         my $valid_re = $arg{valid_re};
 690         my $default = $arg{default};
 691         my $confirm_only = $arg{confirm_only};
 692         my $resp;
 693         my $i = 0;
 694         return defined $default ? $default : undef
 695                 unless defined $term->IN and defined fileno($term->IN) and
 696                        defined $term->OUT and defined fileno($term->OUT);
 697         while ($i++ < 10) {
 698                 $resp = $term->readline($prompt);
 699                 if (!defined $resp) { # EOF
 700                         print "\n";
 701                         return defined $default ? $default : undef;
 702                 }
 703                 if ($resp eq '' and defined $default) {
 704                         return $default;
 705                 }
 706                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 707                         return $resp;
 708                 }
 709                 if ($confirm_only) {
 710                         my $yesno = $term->readline("Are you sure you want to use <$resp> [y/N]? ");
 711                         if (defined $yesno && $yesno =~ /y/i) {
 712                                 return $resp;
 713                         }
 714                 }
 715         }
 716         return;
 717 }
 718
 719 my %broken_encoding;
 720
 721 sub file_declares_8bit_cte {
 722         my $fn = shift;
 723         open (my $fh, '<', $fn);
 724         while (my $line = <$fh>) {
 725                 last if ($line =~ /^$/);
 726                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 727         }
 728         close $fh;
 729         return 0;
 730 }
 731
 732 foreach my $f (@files) {
 733         next unless (body_or_subject_has_nonascii($f)
 734                      && !file_declares_8bit_cte($f));
 735         $broken_encoding{$f} = 1;
 736 }
 737
 738 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 739         print "The following files are 8bit, but do not declare " .
 740                 "a Content-Transfer-Encoding.\n";
 741         foreach my $f (sort keys %broken_encoding) {
 742                 print "    $f\n";
 743         }
 744         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 745                                   default => "UTF-8");
 746 }
 747
 748 if (!$force) {
 749         for my $f (@files) {
 750                 if (get_patch_subject($f) =~ /\Q*** SUBJECT HERE ***\E/) {
 751                         die "Refusing to send because the patch\n\t$f\n"
 752                                 . "has the template subject '*** SUBJECT HERE ***'. "
 753                                 . "Pass --force if you really want to send.\n";
 754                 }
 755         }
 756 }
 757
 758 if (!defined $sender) {
 759         $sender = $repoauthor || $repocommitter || '';
 760 }
 761
 762 # $sender could be an already sanitized address
 763 # (e.g. sendemail.from could be manually sanitized by user).
 764 # But it's a no-op to run sanitize_address on an already sanitized address.
 765 $sender = sanitize_address($sender);
 766
 767 my $prompting = 0;
 768 if (!@initial_to && !defined $to_cmd) {
 769         my $to = ask("Who should the emails be sent to (if any)? ",
 770                      default => "",
 771                      valid_re => qr/\@.*\./, confirm_only => 1);
 772         push @initial_to, parse_address_line($to) if defined $to; # sanitized/validated later
 773         $prompting++;
 774 }
 775
 776 sub expand_aliases {
 777         return map { expand_one_alias($_) } @_;
 778 }
 779
 780 my %EXPANDED_ALIASES;
 781 sub expand_one_alias {
 782         my $alias = shift;
 783         if ($EXPANDED_ALIASES{$alias}) {
 784                 die "fatal: alias '$alias' expands to itself\n";
 785         }
 786         local $EXPANDED_ALIASES{$alias} = 1;
 787         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 788 }
 789
 790 @initial_to = expand_aliases(@initial_to);
 791 @initial_to = validate_address_list(sanitize_address_list(@initial_to));
 792 @initial_cc = expand_aliases(@initial_cc);
 793 @initial_cc = validate_address_list(sanitize_address_list(@initial_cc));
 794 @bcclist = expand_aliases(@bcclist);
 795 @bcclist = validate_address_list(sanitize_address_list(@bcclist));
 796
 797 if ($thread && !defined $initial_reply_to && $prompting) {
 798         $initial_reply_to = ask(
 799                 "Message-ID to be used as In-Reply-To for the first email (if any)? ",
 800                 default => "",
 801                 valid_re => qr/\@.*\./, confirm_only => 1);
 802 }
 803 if (defined $initial_reply_to) {
 804         $initial_reply_to =~ s/^\s*<?//;
 805         $initial_reply_to =~ s/>?\s*$//;
 806         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 807 }
 808
 809 if (!defined $smtp_server) {
 810         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 811                 if (-x $_) {
 812                         $smtp_server = $_;
 813                         last;
 814                 }
 815         }
 816         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 817 }
 818
 819 if ($compose && $compose > 0) {
 820         @files = ($compose_filename . ".final", @files);
 821 }
 822
 823 # Variables we set as part of the loop over files
 824 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 825         $needs_confirm, $message_num, $ask_default);
 826
 827 sub extract_valid_address {
 828         my $address = shift;
 829         my $local_part_regexp = qr/[^<>"\s@]+/;
 830         my $domain_regexp = qr/[^.<>"\s@]+(?:\.[^.<>"\s@]+)+/;
 831
 832         # check for a local address:
 833         return $address if ($address =~ /^($local_part_regexp)$/);
 834
 835         $address =~ s/^\s*<(.*)>\s*$/$1/;
 836         if ($have_email_valid) {
 837                 return scalar Email::Valid->address($address);
 838         }
 839
 840         # less robust/correct than the monster regexp in Email::Valid,
 841         # but still does a 99% job, and one less dependency
 842         return $1 if $address =~ /($local_part_regexp\@$domain_regexp)/;
 843         return;
 844 }
 845
 846 sub extract_valid_address_or_die {
 847         my $address = shift;
 848         $address = extract_valid_address($address);
 849         die "error: unable to extract a valid address from: $address\n"
 850                 if !$address;
 851         return $address;
 852 }
 853
 854 sub validate_address {
 855         my $address = shift;
 856         while (!extract_valid_address($address)) {
 857                 print STDERR "error: unable to extract a valid address from: $address\n";
 858                 $_ = ask("What to do with this address? ([q]uit|[d]rop|[e]dit): ",
 859                         valid_re => qr/^(?:quit|q|drop|d|edit|e)/i,
 860                         default => 'q');
 861                 if (/^d/i) {
 862                         return undef;
 863                 } elsif (/^q/i) {
 864                         cleanup_compose_files();
 865                         exit(0);
 866                 }
 867                 $address = ask("Who should the email be sent to (if any)? ",
 868                         default => "",
 869                         valid_re => qr/\@.*\./, confirm_only => 1);
 870         }
 871         return $address;
 872 }
 873
 874 sub validate_address_list {
 875         return (grep { defined $_ }
 876                 map { validate_address($_) } @_);
 877 }
 878
 879 # Usually don't need to change anything below here.
 880
 881 # we make a "fake" message id by taking the current number
 882 # of seconds since the beginning of Unix time and tacking on
 883 # a random number to the end, in case we are called quicker than
 884 # 1 second since the last time we were called.
 885
 886 # We'll setup a template for the message id, using the "from" address:
 887
 888 my ($message_id_stamp, $message_id_serial);
 889 sub make_message_id {
 890         my $uniq;
 891         if (!defined $message_id_stamp) {
 892                 $message_id_stamp = sprintf("%s-%s", time, $$);
 893                 $message_id_serial = 0;
 894         }
 895         $message_id_serial++;
 896         $uniq = "$message_id_stamp-$message_id_serial";
 897
 898         my $du_part;
 899         for ($sender, $repocommitter, $repoauthor) {
 900                 $du_part = extract_valid_address(sanitize_address($_));
 901                 last if (defined $du_part and $du_part ne '');
 902         }
 903         if (not defined $du_part or $du_part eq '') {
 904                 require Sys::Hostname;
 905                 $du_part = 'user@' . Sys::Hostname::hostname();
 906         }
 907         my $message_id_template = "<%s-git-send-email-%s>";
 908         $message_id = sprintf($message_id_template, $uniq, $du_part);
 909         #print "new message id = $message_id\n"; # Was useful for debugging
 910 }
 911
 912
 913
 914 $time = time - scalar $#files;
 915
 916 sub unquote_rfc2047 {
 917         local ($_) = @_;
 918         my $encoding;
 919         s{=\?([^?]+)\?q\?(.*?)\?=}{
 920                 $encoding = $1;
 921                 my $e = $2;
 922                 $e =~ s/_/ /g;
 923                 $e =~ s/=([0-9A-F]{2})/chr(hex($1))/eg;
 924                 $e;
 925         }eg;
 926         return wantarray ? ($_, $encoding) : $_;
 927 }
 928
 929 sub quote_rfc2047 {
 930         local $_ = shift;
 931         my $encoding = shift || 'UTF-8';
 932         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 933         s/(.*)/=\?$encoding\?q\?$1\?=/;
 934         return $_;
 935 }
 936
 937 sub is_rfc2047_quoted {
 938         my $s = shift;
 939         my $token = qr/[^][()<>@,;:"\/?.= \000-\037\177-\377]+/;
 940         my $encoded_text = qr/[!->@-~]+/;
 941         length($s) <= 75 &&
 942         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 943 }
 944
 945 sub subject_needs_rfc2047_quoting {
 946         my $s = shift;
 947
 948         return ($s =~ /[^[:ascii:]]/) || ($s =~ /=\?/);
 949 }
 950
 951 sub quote_subject {
 952         local $subject = shift;
 953         my $encoding = shift || 'UTF-8';
 954
 955         if (subject_needs_rfc2047_quoting($subject)) {
 956                 return quote_rfc2047($subject, $encoding);
 957         }
 958         return $subject;
 959 }
 960
 961 # use the simplest quoting being able to handle the recipient
 962 sub sanitize_address {
 963         my ($recipient) = @_;
 964
 965         # remove garbage after email address
 966         $recipient =~ s/(.*>).*$/$1/;
 967
 968         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 969
 970         if (not $recipient_name) {
 971                 return $recipient;
 972         }
 973
 974         # if recipient_name is already quoted, do nothing
 975         if (is_rfc2047_quoted($recipient_name)) {
 976                 return $recipient;
 977         }
 978
 979         # rfc2047 is needed if a non-ascii char is included
 980         if ($recipient_name =~ /[^[:ascii:]]/) {
 981                 $recipient_name =~ s/^"(.*)"$/$1/;
 982                 $recipient_name = quote_rfc2047($recipient_name);
 983         }
 984
 985         # double quotes are needed if specials or CTLs are included
 986         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 987                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 988                 $recipient_name = qq["$recipient_name"];
 989         }
 990
 991         return "$recipient_name $recipient_addr";
 992
 993 }
 994
 995 sub sanitize_address_list {
 996         return (map { sanitize_address($_) } @_);
 997 }
 998
 999 # Returns the local Fully Qualified Domain Name (FQDN) if available.
1000 #
1001 # Tightly configured MTAa require that a caller sends a real DNS
1002 # domain name that corresponds the IP address in the HELO/EHLO
1003 # handshake. This is used to verify the connection and prevent
1004 # spammers from trying to hide their identity. If the DNS and IP don't
1005 # match, the receiveing MTA may deny the connection.
1006 #
1007 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
1008 #
1009 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
1010 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
1011 #
1012 # This maildomain*() code is based on ideas in Perl library Test::Reporter
1013 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
1014
1015 sub valid_fqdn {
1016         my $domain = shift;
1017         return defined $domain && !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
1018 }
1019
1020 sub maildomain_net {
1021         my $maildomain;
1022
1023         if (eval { require Net::Domain; 1 }) {
1024                 my $domain = Net::Domain::domainname();
1025                 $maildomain = $domain if valid_fqdn($domain);
1026         }
1027
1028         return $maildomain;
1029 }
1030
1031 sub maildomain_mta {
1032         my $maildomain;
1033
1034         if (eval { require Net::SMTP; 1 }) {
1035                 for my $host (qw(mailhost localhost)) {
1036                         my $smtp = Net::SMTP->new($host);
1037                         if (defined $smtp) {
1038                                 my $domain = $smtp->domain;
1039                                 $smtp->quit;
1040
1041                                 $maildomain = $domain if valid_fqdn($domain);
1042
1043                                 last if $maildomain;
1044                         }
1045                 }
1046         }
1047
1048         return $maildomain;
1049 }
1050
1051 sub maildomain {
1052         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
1053 }
1054
1055 # Returns 1 if the message was sent, and 0 otherwise.
1056 # In actuality, the whole program dies when there
1057 # is an error sending a message.
1058
1059 sub send_message {
1060         my @recipients = unique_email_list(@to);
1061         @cc = (grep { my $cc = extract_valid_address_or_die($_);
1062                       not grep { $cc eq $_ || $_ =~ /<\Q${cc}\E>$/ } @recipients
1063                     }
1064                @cc);
1065         my $to = join (",\n\t", @recipients);
1066         @recipients = unique_email_list(@recipients,@cc,@bcclist);
1067         @recipients = (map { extract_valid_address_or_die($_) } @recipients);
1068         my $date = format_2822_time($time++);
1069         my $gitversion = '@@GIT_VERSION@@';
1070         if ($gitversion =~ m/..GIT_VERSION../) {
1071             $gitversion = Git::version();
1072         }
1073
1074         my $cc = join(",\n\t", unique_email_list(@cc));
1075         my $ccline = "";
1076         if ($cc ne '') {
1077                 $ccline = "\nCc: $cc";
1078         }
1079         make_message_id() unless defined($message_id);
1080
1081         my $header = "From: $sender
1082 To: $to${ccline}
1083 Subject: $subject
1084 Date: $date
1085 Message-Id: $message_id
1086 X-Mailer: git-send-email $gitversion
1087 ";
1088         if ($reply_to) {
1089
1090                 $header .= "In-Reply-To: $reply_to\n";
1091                 $header .= "References: $references\n";
1092         }
1093         if (@xh) {
1094                 $header .= join("\n", @xh) . "\n";
1095         }
1096
1097         my @sendmail_parameters = ('-i', @recipients);
1098         my $raw_from = $sender;
1099         if (defined $envelope_sender && $envelope_sender ne "auto") {
1100                 $raw_from = $envelope_sender;
1101         }
1102         $raw_from = extract_valid_address($raw_from);
1103         unshift (@sendmail_parameters,
1104                         '-f', $raw_from) if(defined $envelope_sender);
1105
1106         if ($needs_confirm && !$dry_run) {
1107                 print "\n$header\n";
1108                 if ($needs_confirm eq "inform") {
1109                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
1110                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
1111                         print "    The Cc list above has been expanded by additional\n";
1112                         print "    addresses found in the patch commit message. By default\n";
1113                         print "    send-email prompts before sending whenever this occurs.\n";
1114                         print "    This behavior is controlled by the sendemail.confirm\n";
1115                         print "    configuration setting.\n";
1116                         print "\n";
1117                         print "    For additional information, run 'git send-email --help'.\n";
1118                         print "    To retain the current behavior, but squelch this message,\n";
1119                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1120                 }
1121                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1122                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1123                          default => $ask_default);
1124                 die "Send this email reply required" unless defined $_;
1125                 if (/^n/i) {
1126                         return 0;
1127                 } elsif (/^q/i) {
1128                         cleanup_compose_files();
1129                         exit(0);
1130                 } elsif (/^a/i) {
1131                         $confirm = 'never';
1132                 }
1133         }
1134
1135         unshift (@sendmail_parameters, @smtp_server_options);
1136
1137         if ($dry_run) {
1138                 # We don't want to send the email.
1139         } elsif ($smtp_server =~ m#^/#) {
1140                 my $pid = open my $sm, '|-';
1141                 defined $pid or die $!;
1142                 if (!$pid) {
1143                         exec($smtp_server, @sendmail_parameters) or die $!;
1144                 }
1145                 print $sm "$header\n$message";
1146                 close $sm or die $!;
1147         } else {
1148
1149                 if (!defined $smtp_server) {
1150                         die "The required SMTP server is not properly defined."
1151                 }
1152
1153                 if ($smtp_encryption eq 'ssl') {
1154                         $smtp_server_port ||= 465; # ssmtp
1155                         require Net::SMTP::SSL;
1156                         $smtp_domain ||= maildomain();
1157                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1158                                                       Hello => $smtp_domain,
1159                                                       Port => $smtp_server_port);
1160                 }
1161                 else {
1162                         require Net::SMTP;
1163                         $smtp_domain ||= maildomain();
1164                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
1165                                                  ? "$smtp_server:$smtp_server_port"
1166                                                  : $smtp_server,
1167                                                  Hello => $smtp_domain,
1168                                                  Debug => $debug_net_smtp);
1169                         if ($smtp_encryption eq 'tls' && $smtp) {
1170                                 require Net::SMTP::SSL;
1171                                 $smtp->command('STARTTLS');
1172                                 $smtp->response();
1173                                 if ($smtp->code == 220) {
1174                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
1175                                                 or die "STARTTLS failed! ".$smtp->message;
1176                                         $smtp_encryption = '';
1177                                         # Send EHLO again to receive fresh
1178                                         # supported commands
1179                                         $smtp->hello($smtp_domain);
1180                                 } else {
1181                                         die "Server does not support STARTTLS! ".$smtp->message;
1182                                 }
1183                         }
1184                 }
1185
1186                 if (!$smtp) {
1187                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1188                             "VALUES: server=$smtp_server ",
1189                             "encryption=$smtp_encryption ",
1190                             "hello=$smtp_domain",
1191                             defined $smtp_server_port ? " port=$smtp_server_port" : "";
1192                 }
1193
1194                 if (defined $smtp_authuser) {
1195                         # Workaround AUTH PLAIN/LOGIN interaction defect
1196                         # with Authen::SASL::Cyrus
1197                         eval {
1198                                 require Authen::SASL;
1199                                 Authen::SASL->import(qw(Perl));
1200                         };
1201
1202                         if (!defined $smtp_authpass) {
1203
1204                                 system "stty -echo";
1205
1206                                 do {
1207                                         print "Password: ";
1208                                         $_ = <STDIN>;
1209                                         print "\n";
1210                                 } while (!defined $_);
1211
1212                                 chomp($smtp_authpass = $_);
1213
1214                                 system "stty echo";
1215                         }
1216
1217                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
1218                 }
1219
1220                 $smtp->mail( $raw_from ) or die $smtp->message;
1221                 $smtp->to( @recipients ) or die $smtp->message;
1222                 $smtp->data or die $smtp->message;
1223                 $smtp->datasend("$header\n$message") or die $smtp->message;
1224                 $smtp->dataend() or die $smtp->message;
1225                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1226         }
1227         if ($quiet) {
1228                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1229         } else {
1230                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1231                 if ($smtp_server !~ m#^/#) {
1232                         print "Server: $smtp_server\n";
1233                         print "MAIL FROM:<$raw_from>\n";
1234                         foreach my $entry (@recipients) {
1235                             print "RCPT TO:<$entry>\n";
1236                         }
1237                 } else {
1238                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1239                 }
1240                 print $header, "\n";
1241                 if ($smtp) {
1242                         print "Result: ", $smtp->code, ' ',
1243                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1244                 } else {
1245                         print "Result: OK\n";
1246                 }
1247         }
1248
1249         return 1;
1250 }
1251
1252 $reply_to = $initial_reply_to;
1253 $references = $initial_reply_to || '';
1254 $subject = $initial_subject;
1255 $message_num = 0;
1256
1257 foreach my $t (@files) {
1258         open my $fh, "<", $t or die "can't open file $t";
1259
1260         my $author = undef;
1261         my $author_encoding;
1262         my $has_content_type;
1263         my $body_encoding;
1264         @to = ();
1265         @cc = ();
1266         @xh = ();
1267         my $input_format = undef;
1268         my @header = ();
1269         $message = "";
1270         $message_num++;
1271         # First unfold multiline header fields
1272         while(<$fh>) {
1273                 last if /^\s*$/;
1274                 if (/^\s+\S/ and @header) {
1275                         chomp($header[$#header]);
1276                         s/^\s+/ /;
1277                         $header[$#header] .= $_;
1278             } else {
1279                         push(@header, $_);
1280                 }
1281         }
1282         # Now parse the header
1283         foreach(@header) {
1284                 if (/^From /) {
1285                         $input_format = 'mbox';
1286                         next;
1287                 }
1288                 chomp;
1289                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1290                         $input_format = 'mbox';
1291                 }
1292
1293                 if (defined $input_format && $input_format eq 'mbox') {
1294                         if (/^Subject:\s+(.*)$/i) {
1295                                 $subject = $1;
1296                         }
1297                         elsif (/^From:\s+(.*)$/i) {
1298                                 ($author, $author_encoding) = unquote_rfc2047($1);
1299                                 my $sauthor = sanitize_address($author);
1300                                 next if $suppress_cc{'author'};
1301                                 next if $suppress_cc{'self'} and $sauthor eq $sender;
1302                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1303                                         $1, $_) unless $quiet;
1304                                 push @cc, $1;
1305                         }
1306                         elsif (/^To:\s+(.*)$/i) {
1307                                 foreach my $addr (parse_address_line($1)) {
1308                                         printf("(mbox) Adding to: %s from line '%s'\n",
1309                                                 $addr, $_) unless $quiet;
1310                                         push @to, $addr;
1311                                 }
1312                         }
1313                         elsif (/^Cc:\s+(.*)$/i) {
1314                                 foreach my $addr (parse_address_line($1)) {
1315                                         my $qaddr = unquote_rfc2047($addr);
1316                                         my $saddr = sanitize_address($qaddr);
1317                                         if ($saddr eq $sender) {
1318                                                 next if ($suppress_cc{'self'});
1319                                         } else {
1320                                                 next if ($suppress_cc{'cc'});
1321                                         }
1322                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1323                                                 $addr, $_) unless $quiet;
1324                                         push @cc, $addr;
1325                                 }
1326                         }
1327                         elsif (/^Content-type:/i) {
1328                                 $has_content_type = 1;
1329                                 if (/charset="?([^ "]+)/) {
1330                                         $body_encoding = $1;
1331                                 }
1332                                 push @xh, $_;
1333                         }
1334                         elsif (/^Message-Id: (.*)/i) {
1335                                 $message_id = $1;
1336                         }
1337                         elsif (!/^Date:\s/i && /^[-A-Za-z]+:\s+\S/) {
1338                                 push @xh, $_;
1339                         }
1340
1341                 } else {
1342                         # In the traditional
1343                         # "send lots of email" format,
1344                         # line 1 = cc
1345                         # line 2 = subject
1346                         # So let's support that, too.
1347                         $input_format = 'lots';
1348                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1349                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1350                                         $_, $_) unless $quiet;
1351                                 push @cc, $_;
1352                         } elsif (!defined $subject) {
1353                                 $subject = $_;
1354                         }
1355                 }
1356         }
1357         # Now parse the message body
1358         while(<$fh>) {
1359                 $message .=  $_;
1360                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1361                         chomp;
1362                         my ($what, $c) = ($1, $2);
1363                         chomp $c;
1364                         my $sc = sanitize_address($c);
1365                         if ($sc eq $sender) {
1366                                 next if ($suppress_cc{'self'});
1367                         } else {
1368                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1369                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1370                         }
1371                         push @cc, $c;
1372                         printf("(body) Adding cc: %s from line '%s'\n",
1373                                 $c, $_) unless $quiet;
1374                 }
1375         }
1376         close $fh;
1377
1378         push @to, recipients_cmd("to-cmd", "to", $to_cmd, $t)
1379                 if defined $to_cmd;
1380         push @cc, recipients_cmd("cc-cmd", "cc", $cc_cmd, $t)
1381                 if defined $cc_cmd && !$suppress_cc{'cccmd'};
1382
1383         if ($broken_encoding{$t} && !$has_content_type) {
1384                 $has_content_type = 1;
1385                 push @xh, "MIME-Version: 1.0",
1386                         "Content-Type: text/plain; charset=$auto_8bit_encoding",
1387                         "Content-Transfer-Encoding: 8bit";
1388                 $body_encoding = $auto_8bit_encoding;
1389         }
1390
1391         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1392                 $subject = quote_subject($subject, $auto_8bit_encoding);
1393         }
1394
1395         if (defined $author and $author ne $sender) {
1396                 $message = "From: $author\n\n$message";
1397                 if (defined $author_encoding) {
1398                         if ($has_content_type) {
1399                                 if ($body_encoding eq $author_encoding) {
1400                                         # ok, we already have the right encoding
1401                                 }
1402                                 else {
1403                                         # uh oh, we should re-encode
1404                                 }
1405                         }
1406                         else {
1407                                 $has_content_type = 1;
1408                                 push @xh,
1409                                   'MIME-Version: 1.0',
1410                                   "Content-Type: text/plain; charset=$author_encoding",
1411                                   'Content-Transfer-Encoding: 8bit';
1412                         }
1413                 }
1414         }
1415
1416         $needs_confirm = (
1417                 $confirm eq "always" or
1418                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1419                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1420         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1421
1422         @to = validate_address_list(sanitize_address_list(@to));
1423         @cc = validate_address_list(sanitize_address_list(@cc));
1424
1425         @to = (@initial_to, @to);
1426         @cc = (@initial_cc, @cc);
1427
1428         my $message_was_sent = send_message();
1429
1430         # set up for the next message
1431         if ($thread && $message_was_sent &&
1432                 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0 ||
1433                 $message_num == 1)) {
1434                 $reply_to = $message_id;
1435                 if (length $references > 0) {
1436                         $references .= "\n $message_id";
1437                 } else {
1438                         $references = "$message_id";
1439                 }
1440         }
1441         $message_id = undef;
1442 }
1443
1444 # Execute a command (e.g. $to_cmd) to get a list of email addresses
1445 # and return a results array
1446 sub recipients_cmd {
1447         my ($prefix, $what, $cmd, $file) = @_;
1448
1449         my @addresses = ();
1450         open my $fh, "-|", "$cmd \Q$file\E"
1451             or die "($prefix) Could not execute '$cmd'";
1452         while (my $address = <$fh>) {
1453                 $address =~ s/^\s*//g;
1454                 $address =~ s/\s*$//g;
1455                 $address = sanitize_address($address);
1456                 next if ($address eq $sender and $suppress_cc{'self'});
1457                 push @addresses, $address;
1458                 printf("($prefix) Adding %s: %s from: '%s'\n",
1459                        $what, $address, $cmd) unless $quiet;
1460                 }
1461         close $fh
1462             or die "($prefix) failed to close pipe to '$cmd'";
1463         return @addresses;
1464 }
1465
1466 cleanup_compose_files();
1467
1468 sub cleanup_compose_files {
1469         unlink($compose_filename, $compose_filename . ".final") if $compose;
1470 }
1471
1472 $smtp->quit if $smtp;
1473
1474 sub unique_email_list {
1475         my %seen;
1476         my @emails;
1477
1478         foreach my $entry (@_) {
1479                 my $clean = extract_valid_address_or_die($entry);
1480                 $seen{$clean} ||= 0;
1481                 next if $seen{$clean}++;
1482                 push @emails, $entry;
1483         }
1484         return @emails;
1485 }
1486
1487 sub validate_patch {
1488         my $fn = shift;
1489         open(my $fh, '<', $fn)
1490                 or die "unable to open $fn: $!\n";
1491         while (my $line = <$fh>) {
1492                 if (length($line) > 998) {
1493                         return "$.: patch contains a line longer than 998 characters";
1494                 }
1495         }
1496         return;
1497 }
1498
1499 sub file_has_nonascii {
1500         my $fn = shift;
1501         open(my $fh, '<', $fn)
1502                 or die "unable to open $fn: $!\n";
1503         while (my $line = <$fh>) {
1504                 return 1 if $line =~ /[^[:ascii:]]/;
1505         }
1506         return 0;
1507 }
1508
1509 sub body_or_subject_has_nonascii {
1510         my $fn = shift;
1511         open(my $fh, '<', $fn)
1512                 or die "unable to open $fn: $!\n";
1513         while (my $line = <$fh>) {
1514                 last if $line =~ /^$/;
1515                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1516         }
1517         while (my $line = <$fh>) {
1518                 return 1 if $line =~ /[^[:ascii:]]/;
1519         }
1520         return 0;
1521 }