git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 package FakeTerm;
  28 sub new {
  29         my ($class, $reason) = @_;
  30         return bless \$reason, shift;
  31 }
  32 sub readline {
  33         my $self = shift;
  34         die "Cannot use readline on FakeTerm: $$self";
  35 }
  36 package main;
  37
  38
  39 sub usage {
  40         print <<EOT;
  41 git send-email [options] <file | directory>...
  42
  43   Composing:
  44     --from                  <str>  * Email From:
  45     --to                    <str>  * Email To:
  46     --cc                    <str>  * Email Cc:
  47     --bcc                   <str>  * Email Bcc:
  48     --subject               <str>  * Email "Subject:"
  49     --in-reply-to           <str>  * Email "In-Reply-To:"
  50     --compose                      * Open an editor for introduction.
  51
  52   Sending:
  53     --envelope-sender       <str>  * Email envelope sender.
  54     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  55                                      is optional. Default 'localhost'.
  56     --smtp-server-port      <int>  * Outgoing SMTP server port.
  57     --smtp-user             <str>  * Username for SMTP-AUTH.
  58     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  59     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  60     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  61
  62   Automating:
  63     --identity              <str>  * Use the sendemail.<id> options.
  64     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  65     --suppress-cc           <str>  * author, self, sob, cccmd, all.
  66     --[no-]signed-off-by-cc        * Send to Cc: and Signed-off-by:
  67                                      addresses. Default on.
  68     --[no-]suppress-from           * Send to self. Default off.
  69     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default on.
  70     --[no-]thread                  * Use In-Reply-To: field. Default on.
  71
  72   Administering:
  73     --quiet                        * Output one line of info per email.
  74     --dry-run                      * Don't actually send the emails.
  75     --[no-]validate                * Perform patch sanity checks. Default on.
  76
  77 EOT
  78         exit(1);
  79 }
  80
  81 # most mail servers generate the Date: header, but not all...
  82 sub format_2822_time {
  83         my ($time) = @_;
  84         my @localtm = localtime($time);
  85         my @gmttm = gmtime($time);
  86         my $localmin = $localtm[1] + $localtm[2] * 60;
  87         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
  88         if ($localtm[0] != $gmttm[0]) {
  89                 die "local zone differs from GMT by a non-minute interval\n";
  90         }
  91         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
  92                 $localmin += 1440;
  93         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
  94                 $localmin -= 1440;
  95         } elsif ($gmttm[6] != $localtm[6]) {
  96                 die "local time offset greater than or equal to 24 hours\n";
  97         }
  98         my $offset = $localmin - $gmtmin;
  99         my $offhour = $offset / 60;
 100         my $offmin = abs($offset % 60);
 101         if (abs($offhour) >= 24) {
 102                 die ("local time offset greater than or equal to 24 hours\n");
 103         }
 104
 105         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 106                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 107                        $localtm[3],
 108                        qw(Jan Feb Mar Apr May Jun
 109                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 110                        $localtm[5]+1900,
 111                        $localtm[2],
 112                        $localtm[1],
 113                        $localtm[0],
 114                        ($offset >= 0) ? '+' : '-',
 115                        abs($offhour),
 116                        $offmin,
 117                        );
 118 }
 119
 120 my $have_email_valid = eval { require Email::Valid; 1 };
 121 my $smtp;
 122 my $auth;
 123
 124 sub unique_email_list(@);
 125 sub cleanup_compose_files();
 126
 127 # Constants (essentially)
 128 my $compose_filename = ".msg.$$";
 129
 130 # Variables we fill in automatically, or via prompting:
 131 my (@to,@cc,@initial_cc,@bcclist,@xh,
 132         $initial_reply_to,$initial_subject,@files,$author,$sender,$smtp_authpass,$compose,$time);
 133
 134 my $envelope_sender;
 135
 136 # Example reply to:
 137 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 138
 139 my $repo = eval { Git->repository() };
 140 my @repo = $repo ? ($repo) : ();
 141 my $term = eval {
 142         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 143                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 144                 : new Term::ReadLine 'git-send-email';
 145 };
 146 if ($@) {
 147         $term = new FakeTerm "$@: going non-interactive";
 148 }
 149
 150 # Behavior modification variables
 151 my ($quiet, $dry_run) = (0, 0);
 152
 153 # Variables with corresponding config settings
 154 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 155 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 156 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 157 my ($validate);
 158 my (@suppress_cc);
 159
 160 my %config_bool_settings = (
 161     "thread" => [\$thread, 1],
 162     "chainreplyto" => [\$chain_reply_to, 1],
 163     "suppressfrom" => [\$suppress_from, undef],
 164     "signedoffbycc" => [\$signed_off_by_cc, undef],
 165     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 166     "validate" => [\$validate, 1],
 167 );
 168
 169 my %config_settings = (
 170     "smtpserver" => \$smtp_server,
 171     "smtpserverport" => \$smtp_server_port,
 172     "smtpuser" => \$smtp_authuser,
 173     "smtppass" => \$smtp_authpass,
 174     "to" => \@to,
 175     "cc" => \@initial_cc,
 176     "cccmd" => \$cc_cmd,
 177     "aliasfiletype" => \$aliasfiletype,
 178     "bcc" => \@bcclist,
 179     "aliasesfile" => \@alias_files,
 180     "suppresscc" => \@suppress_cc,
 181     "envelopesender" => \$envelope_sender,
 182 );
 183
 184 # Handle Uncouth Termination
 185 sub signal_handler {
 186
 187         # Make text normal
 188         print color("reset"), "\n";
 189
 190         # SMTP password masked
 191         system "stty echo";
 192
 193         # tmp files from --compose
 194         if (-e $compose_filename) {
 195                 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 196         }
 197         if (-e ($compose_filename . ".final")) {
 198                 print "'$compose_filename.final' contains the composed email.\n"
 199         }
 200
 201         exit;
 202 };
 203
 204 $SIG{TERM} = \&signal_handler;
 205 $SIG{INT}  = \&signal_handler;
 206
 207 # Begin by accumulating all the variables (defined above), that we will end up
 208 # needing, first, from the command line:
 209
 210 my $rc = GetOptions("sender|from=s" => \$sender,
 211                     "in-reply-to=s" => \$initial_reply_to,
 212                     "subject=s" => \$initial_subject,
 213                     "to=s" => \@to,
 214                     "cc=s" => \@initial_cc,
 215                     "bcc=s" => \@bcclist,
 216                     "chain-reply-to!" => \$chain_reply_to,
 217                     "smtp-server=s" => \$smtp_server,
 218                     "smtp-server-port=s" => \$smtp_server_port,
 219                     "smtp-user=s" => \$smtp_authuser,
 220                     "smtp-pass:s" => \$smtp_authpass,
 221                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 222                     "smtp-encryption=s" => \$smtp_encryption,
 223                     "identity=s" => \$identity,
 224                     "compose" => \$compose,
 225                     "quiet" => \$quiet,
 226                     "cc-cmd=s" => \$cc_cmd,
 227                     "suppress-from!" => \$suppress_from,
 228                     "suppress-cc=s" => \@suppress_cc,
 229                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 230                     "dry-run" => \$dry_run,
 231                     "envelope-sender=s" => \$envelope_sender,
 232                     "thread!" => \$thread,
 233                     "validate!" => \$validate,
 234          );
 235
 236 unless ($rc) {
 237     usage();
 238 }
 239
 240 # Now, let's fill any that aren't set in with defaults:
 241
 242 sub read_config {
 243         my ($prefix) = @_;
 244
 245         foreach my $setting (keys %config_bool_settings) {
 246                 my $target = $config_bool_settings{$setting}->[0];
 247                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 248         }
 249
 250         foreach my $setting (keys %config_settings) {
 251                 my $target = $config_settings{$setting};
 252                 if (ref($target) eq "ARRAY") {
 253                         unless (@$target) {
 254                                 my @values = Git::config(@repo, "$prefix.$setting");
 255                                 @$target = @values if (@values && defined $values[0]);
 256                         }
 257                 }
 258                 else {
 259                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 260                 }
 261         }
 262
 263         if (!defined $smtp_encryption) {
 264                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 265                 if (defined $enc) {
 266                         $smtp_encryption = $enc;
 267                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 268                         $smtp_encryption = 'ssl';
 269                 }
 270         }
 271 }
 272
 273 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 274 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 275 read_config("sendemail.$identity") if (defined $identity);
 276 read_config("sendemail");
 277
 278 # fall back on builtin bool defaults
 279 foreach my $setting (values %config_bool_settings) {
 280         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 281 }
 282
 283 # 'default' encryption is none -- this only prevents a warning
 284 $smtp_encryption = '' unless (defined $smtp_encryption);
 285
 286 # Set CC suppressions
 287 my(%suppress_cc);
 288 if (@suppress_cc) {
 289         foreach my $entry (@suppress_cc) {
 290                 die "Unknown --suppress-cc field: '$entry'\n"
 291                         unless $entry =~ /^(all|cccmd|cc|author|self|sob)$/;
 292                 $suppress_cc{$entry} = 1;
 293         }
 294 }
 295
 296 if ($suppress_cc{'all'}) {
 297         foreach my $entry (qw (ccmd cc author self sob)) {
 298                 $suppress_cc{$entry} = 1;
 299         }
 300         delete $suppress_cc{'all'};
 301 }
 302
 303 # If explicit old-style ones are specified, they trump --suppress-cc.
 304 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 305 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 306
 307 # Debugging, print out the suppressions.
 308 if (0) {
 309         print "suppressions:\n";
 310         foreach my $entry (keys %suppress_cc) {
 311                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 312         }
 313 }
 314
 315 my ($repoauthor, $repocommitter);
 316 ($repoauthor) = Git::ident_person(@repo, 'author');
 317 ($repocommitter) = Git::ident_person(@repo, 'committer');
 318
 319 # Verify the user input
 320
 321 foreach my $entry (@to) {
 322         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 323 }
 324
 325 foreach my $entry (@initial_cc) {
 326         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 327 }
 328
 329 foreach my $entry (@bcclist) {
 330         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 331 }
 332
 333 my %aliases;
 334 my %parse_alias = (
 335         # multiline formats can be supported in the future
 336         mutt => sub { my $fh = shift; while (<$fh>) {
 337                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 338                         my ($alias, $addr) = ($1, $2);
 339                         $addr =~ s/#.*$//; # mutt allows # comments
 340                          # commas delimit multiple addresses
 341                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 342                 }}},
 343         mailrc => sub { my $fh = shift; while (<$fh>) {
 344                 if (/^alias\s+(\S+)\s+(.*)$/) {
 345                         # spaces delimit multiple addresses
 346                         $aliases{$1} = [ split(/\s+/, $2) ];
 347                 }}},
 348         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 349                 for (my $x = ''; defined($x); $x = $_) {
 350                         chomp $x;
 351                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 352                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 353                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 354                 }},
 355         gnus => sub { my $fh = shift; while (<$fh>) {
 356                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 357                         $aliases{$1} = [ $2 ];
 358                 }}}
 359 );
 360
 361 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 362         foreach my $file (@alias_files) {
 363                 open my $fh, '<', $file or die "opening $file: $!\n";
 364                 $parse_alias{$aliasfiletype}->($fh);
 365                 close $fh;
 366         }
 367 }
 368
 369 ($sender) = expand_aliases($sender) if defined $sender;
 370
 371 # Now that all the defaults are set, process the rest of the command line
 372 # arguments and collect up the files that need to be processed.
 373 for my $f (@ARGV) {
 374         if (-d $f) {
 375                 opendir(DH,$f)
 376                         or die "Failed to opendir $f: $!";
 377
 378                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 379                                 sort readdir(DH);
 380                 closedir(DH);
 381         } elsif (-f $f or -p $f) {
 382                 push @files, $f;
 383         } else {
 384                 print STDERR "Skipping $f - not found.\n";
 385         }
 386 }
 387
 388 if ($validate) {
 389         foreach my $f (@files) {
 390                 unless (-p $f) {
 391                         my $error = validate_patch($f);
 392                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 393                 }
 394         }
 395 }
 396
 397 if (@files) {
 398         unless ($quiet) {
 399                 print $_,"\n" for (@files);
 400         }
 401 } else {
 402         print STDERR "\nNo patch files specified!\n\n";
 403         usage();
 404 }
 405
 406 my $prompting = 0;
 407 if (!defined $sender) {
 408         $sender = $repoauthor || $repocommitter || '';
 409
 410         while (1) {
 411                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 412                 last if defined $_;
 413                 print "\n";
 414         }
 415
 416         $sender = $_ if ($_);
 417         print "Emails will be sent from: ", $sender, "\n";
 418         $prompting++;
 419 }
 420
 421 if (!@to) {
 422
 423
 424         while (1) {
 425                 $_ = $term->readline("Who should the emails be sent to? ", "");
 426                 last if defined $_;
 427                 print "\n";
 428         }
 429
 430         my $to = $_;
 431         push @to, split /,\s*/, $to;
 432         $prompting++;
 433 }
 434
 435 sub expand_aliases {
 436         my @cur = @_;
 437         my @last;
 438         do {
 439                 @last = @cur;
 440                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 441         } while (join(',',@cur) ne join(',',@last));
 442         return @cur;
 443 }
 444
 445 @to = expand_aliases(@to);
 446 @to = (map { sanitize_address($_) } @to);
 447 @initial_cc = expand_aliases(@initial_cc);
 448 @bcclist = expand_aliases(@bcclist);
 449
 450 if (!defined $initial_subject && $compose) {
 451         while (1) {
 452                 $_ = $term->readline("What subject should the initial email start with? ", $initial_subject);
 453                 last if defined $_;
 454                 print "\n";
 455         }
 456
 457         $initial_subject = $_;
 458         $prompting++;
 459 }
 460
 461 if ($thread && !defined $initial_reply_to && $prompting) {
 462         while (1) {
 463                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ", $initial_reply_to);
 464                 last if defined $_;
 465                 print "\n";
 466         }
 467
 468         $initial_reply_to = $_;
 469 }
 470 if (defined $initial_reply_to) {
 471         $initial_reply_to =~ s/^\s*<?//;
 472         $initial_reply_to =~ s/>?\s*$//;
 473         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 474 }
 475
 476 if (!defined $smtp_server) {
 477         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 478                 if (-x $_) {
 479                         $smtp_server = $_;
 480                         last;
 481                 }
 482         }
 483         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 484 }
 485
 486 if ($compose) {
 487         # Note that this does not need to be secure, but we will make a small
 488         # effort to have it be unique
 489         open(C,">",$compose_filename)
 490                 or die "Failed to open for writing $compose_filename: $!";
 491         print C "From $sender # This line is ignored.\n";
 492         printf C "Subject: %s\n\n", $initial_subject;
 493         printf C <<EOT;
 494 GIT: Please enter your email below.
 495 GIT: Lines beginning in "GIT: " will be removed.
 496 GIT: Consider including an overall diffstat or table of contents
 497 GIT: for the patch you are writing.
 498
 499 EOT
 500         close(C);
 501
 502         my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 503         system('sh', '-c', $editor.' "$@"', $editor, $compose_filename);
 504
 505         open(C2,">",$compose_filename . ".final")
 506                 or die "Failed to open $compose_filename.final : " . $!;
 507
 508         open(C,"<",$compose_filename)
 509                 or die "Failed to open $compose_filename : " . $!;
 510
 511         my $need_8bit_cte = file_has_nonascii($compose_filename);
 512         my $in_body = 0;
 513         while(<C>) {
 514                 next if m/^GIT: /;
 515                 if (!$in_body && /^\n$/) {
 516                         $in_body = 1;
 517                         if ($need_8bit_cte) {
 518                                 print C2 "MIME-Version: 1.0\n",
 519                                          "Content-Type: text/plain; ",
 520                                            "charset=utf-8\n",
 521                                          "Content-Transfer-Encoding: 8bit\n";
 522                         }
 523                 }
 524                 if (!$in_body && /^MIME-Version:/i) {
 525                         $need_8bit_cte = 0;
 526                 }
 527                 if (!$in_body && /^Subject: ?(.*)/i) {
 528                         my $subject = $1;
 529                         $_ = "Subject: " .
 530                                 ($subject =~ /[^[:ascii:]]/ ?
 531                                  quote_rfc2047($subject) :
 532                                  $subject) .
 533                                 "\n";
 534                 }
 535                 print C2 $_;
 536         }
 537         close(C);
 538         close(C2);
 539
 540         while (1) {
 541                 $_ = $term->readline("Send this email? (y|n) ");
 542                 last if defined $_;
 543                 print "\n";
 544         }
 545
 546         if (uc substr($_,0,1) ne 'Y') {
 547                 cleanup_compose_files();
 548                 exit(0);
 549         }
 550
 551         @files = ($compose_filename . ".final", @files);
 552 }
 553
 554 # Variables we set as part of the loop over files
 555 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 556
 557 sub extract_valid_address {
 558         my $address = shift;
 559         my $local_part_regexp = '[^<>"\s@]+';
 560         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 561
 562         # check for a local address:
 563         return $address if ($address =~ /^($local_part_regexp)$/);
 564
 565         $address =~ s/^\s*<(.*)>\s*$/$1/;
 566         if ($have_email_valid) {
 567                 return scalar Email::Valid->address($address);
 568         } else {
 569                 # less robust/correct than the monster regexp in Email::Valid,
 570                 # but still does a 99% job, and one less dependency
 571                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 572                 return $1;
 573         }
 574 }
 575
 576 # Usually don't need to change anything below here.
 577
 578 # we make a "fake" message id by taking the current number
 579 # of seconds since the beginning of Unix time and tacking on
 580 # a random number to the end, in case we are called quicker than
 581 # 1 second since the last time we were called.
 582
 583 # We'll setup a template for the message id, using the "from" address:
 584
 585 my ($message_id_stamp, $message_id_serial);
 586 sub make_message_id
 587 {
 588         my $uniq;
 589         if (!defined $message_id_stamp) {
 590                 $message_id_stamp = sprintf("%s-%s", time, $$);
 591                 $message_id_serial = 0;
 592         }
 593         $message_id_serial++;
 594         $uniq = "$message_id_stamp-$message_id_serial";
 595
 596         my $du_part;
 597         for ($sender, $repocommitter, $repoauthor) {
 598                 $du_part = extract_valid_address(sanitize_address($_));
 599                 last if (defined $du_part and $du_part ne '');
 600         }
 601         if (not defined $du_part or $du_part eq '') {
 602                 use Sys::Hostname qw();
 603                 $du_part = 'user@' . Sys::Hostname::hostname();
 604         }
 605         my $message_id_template = "<%s-git-send-email-%s>";
 606         $message_id = sprintf($message_id_template, $uniq, $du_part);
 607         #print "new message id = $message_id\n"; # Was useful for debugging
 608 }
 609
 610
 611
 612 $time = time - scalar $#files;
 613
 614 sub unquote_rfc2047 {
 615         local ($_) = @_;
 616         my $encoding;
 617         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 618                 $encoding = $1;
 619                 s/_/ /g;
 620                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 621         }
 622         return wantarray ? ($_, $encoding) : $_;
 623 }
 624
 625 sub quote_rfc2047 {
 626         local $_ = shift;
 627         my $encoding = shift || 'utf-8';
 628         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 629         s/(.*)/=\?$encoding\?q\?$1\?=/;
 630         return $_;
 631 }
 632
 633 # use the simplest quoting being able to handle the recipient
 634 sub sanitize_address
 635 {
 636         my ($recipient) = @_;
 637         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 638
 639         if (not $recipient_name) {
 640                 return "$recipient";
 641         }
 642
 643         # if recipient_name is already quoted, do nothing
 644         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 645                 return $recipient;
 646         }
 647
 648         # rfc2047 is needed if a non-ascii char is included
 649         if ($recipient_name =~ /[^[:ascii:]]/) {
 650                 $recipient_name = quote_rfc2047($recipient_name);
 651         }
 652
 653         # double quotes are needed if specials or CTLs are included
 654         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 655                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 656                 $recipient_name = "\"$recipient_name\"";
 657         }
 658
 659         return "$recipient_name $recipient_addr";
 660
 661 }
 662
 663 sub send_message
 664 {
 665         my @recipients = unique_email_list(@to);
 666         @cc = (grep { my $cc = extract_valid_address($_);
 667                       not grep { $cc eq $_ } @recipients
 668                     }
 669                map { sanitize_address($_) }
 670                @cc);
 671         my $to = join (",\n\t", @recipients);
 672         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 673         @recipients = (map { extract_valid_address($_) } @recipients);
 674         my $date = format_2822_time($time++);
 675         my $gitversion = '@@GIT_VERSION@@';
 676         if ($gitversion =~ m/..GIT_VERSION../) {
 677             $gitversion = Git::version();
 678         }
 679
 680         my $cc = join(", ", unique_email_list(@cc));
 681         my $ccline = "";
 682         if ($cc ne '') {
 683                 $ccline = "\nCc: $cc";
 684         }
 685         my $sanitized_sender = sanitize_address($sender);
 686         make_message_id() unless defined($message_id);
 687
 688         my $header = "From: $sanitized_sender
 689 To: $to${ccline}
 690 Subject: $subject
 691 Date: $date
 692 Message-Id: $message_id
 693 X-Mailer: git-send-email $gitversion
 694 ";
 695         if ($thread && $reply_to) {
 696
 697                 $header .= "In-Reply-To: $reply_to\n";
 698                 $header .= "References: $references\n";
 699         }
 700         if (@xh) {
 701                 $header .= join("\n", @xh) . "\n";
 702         }
 703
 704         my @sendmail_parameters = ('-i', @recipients);
 705         my $raw_from = $sanitized_sender;
 706         $raw_from = $envelope_sender if (defined $envelope_sender);
 707         $raw_from = extract_valid_address($raw_from);
 708         unshift (@sendmail_parameters,
 709                         '-f', $raw_from) if(defined $envelope_sender);
 710
 711         if ($dry_run) {
 712                 # We don't want to send the email.
 713         } elsif ($smtp_server =~ m#^/#) {
 714                 my $pid = open my $sm, '|-';
 715                 defined $pid or die $!;
 716                 if (!$pid) {
 717                         exec($smtp_server, @sendmail_parameters) or die $!;
 718                 }
 719                 print $sm "$header\n$message";
 720                 close $sm or die $?;
 721         } else {
 722
 723                 if (!defined $smtp_server) {
 724                         die "The required SMTP server is not properly defined."
 725                 }
 726
 727                 if ($smtp_encryption eq 'ssl') {
 728                         $smtp_server_port ||= 465; # ssmtp
 729                         require Net::SMTP::SSL;
 730                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 731                 }
 732                 else {
 733                         require Net::SMTP;
 734                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 735                                                  ? "$smtp_server:$smtp_server_port"
 736                                                  : $smtp_server);
 737                         if ($smtp_encryption eq 'tls') {
 738                                 require Net::SMTP::SSL;
 739                                 $smtp->command('STARTTLS');
 740                                 $smtp->response();
 741                                 if ($smtp->code == 220) {
 742                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
 743                                                 or die "STARTTLS failed! ".$smtp->message;
 744                                         $smtp_encryption = '';
 745                                         # Send EHLO again to receive fresh
 746                                         # supported commands
 747                                         $smtp->hello();
 748                                 } else {
 749                                         die "Server does not support STARTTLS! ".$smtp->message;
 750                                 }
 751                         }
 752                 }
 753
 754                 if (!$smtp) {
 755                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 756                 }
 757
 758                 if (defined $smtp_authuser) {
 759
 760                         if (!defined $smtp_authpass) {
 761
 762                                 system "stty -echo";
 763
 764                                 do {
 765                                         print "Password: ";
 766                                         $_ = <STDIN>;
 767                                         print "\n";
 768                                 } while (!defined $_);
 769
 770                                 chomp($smtp_authpass = $_);
 771
 772                                 system "stty echo";
 773                         }
 774
 775                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 776                 }
 777
 778                 $smtp->mail( $raw_from ) or die $smtp->message;
 779                 $smtp->to( @recipients ) or die $smtp->message;
 780                 $smtp->data or die $smtp->message;
 781                 $smtp->datasend("$header\n$message") or die $smtp->message;
 782                 $smtp->dataend() or die $smtp->message;
 783                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 784         }
 785         if ($quiet) {
 786                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 787         } else {
 788                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 789                 if ($smtp_server !~ m#^/#) {
 790                         print "Server: $smtp_server\n";
 791                         print "MAIL FROM:<$raw_from>\n";
 792                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 793                 } else {
 794                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 795                 }
 796                 print $header, "\n";
 797                 if ($smtp) {
 798                         print "Result: ", $smtp->code, ' ',
 799                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 800                 } else {
 801                         print "Result: OK\n";
 802                 }
 803         }
 804 }
 805
 806 $reply_to = $initial_reply_to;
 807 $references = $initial_reply_to || '';
 808 $subject = $initial_subject;
 809
 810 foreach my $t (@files) {
 811         open(F,"<",$t) or die "can't open file $t";
 812
 813         my $author = undef;
 814         my $author_encoding;
 815         my $has_content_type;
 816         my $body_encoding;
 817         @cc = @initial_cc;
 818         @xh = ();
 819         my $input_format = undef;
 820         my $header_done = 0;
 821         $message = "";
 822         while(<F>) {
 823                 if (!$header_done) {
 824                         if (/^From /) {
 825                                 $input_format = 'mbox';
 826                                 next;
 827                         }
 828                         chomp;
 829                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 830                                 $input_format = 'mbox';
 831                         }
 832
 833                         if (defined $input_format && $input_format eq 'mbox') {
 834                                 if (/^Subject:\s+(.*)$/) {
 835                                         $subject = $1;
 836
 837                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 838                                         if (unquote_rfc2047($2) eq $sender) {
 839                                                 next if ($suppress_cc{'self'});
 840                                         }
 841                                         elsif ($1 eq 'From') {
 842                                                 ($author, $author_encoding)
 843                                                   = unquote_rfc2047($2);
 844                                                 next if ($suppress_cc{'author'});
 845                                         } else {
 846                                                 next if ($suppress_cc{'cc'});
 847                                         }
 848                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 849                                                 $2, $_) unless $quiet;
 850                                         push @cc, $2;
 851                                 }
 852                                 elsif (/^Content-type:/i) {
 853                                         $has_content_type = 1;
 854                                         if (/charset="?([^ "]+)/) {
 855                                                 $body_encoding = $1;
 856                                         }
 857                                         push @xh, $_;
 858                                 }
 859                                 elsif (/^Message-Id: (.*)/i) {
 860                                         $message_id = $1;
 861                                 }
 862                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 863                                         push @xh, $_;
 864                                 }
 865
 866                         } else {
 867                                 # In the traditional
 868                                 # "send lots of email" format,
 869                                 # line 1 = cc
 870                                 # line 2 = subject
 871                                 # So let's support that, too.
 872                                 $input_format = 'lots';
 873                                 if (@cc == 0 && !$suppress_cc{'cc'}) {
 874                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 875                                                 $_, $_) unless $quiet;
 876
 877                                         push @cc, $_;
 878
 879                                 } elsif (!defined $subject) {
 880                                         $subject = $_;
 881                                 }
 882                         }
 883
 884                         # A whitespace line will terminate the headers
 885                         if (m/^\s*$/) {
 886                                 $header_done = 1;
 887                         }
 888                 } else {
 889                         $message .=  $_;
 890                         if (/^(Signed-off-by|Cc): (.*)$/i) {
 891                                 next if ($suppress_cc{'sob'});
 892                                 chomp;
 893                                 my $c = $2;
 894                                 chomp $c;
 895                                 next if ($c eq $sender and $suppress_cc{'self'});
 896                                 push @cc, $c;
 897                                 printf("(sob) Adding cc: %s from line '%s'\n",
 898                                         $c, $_) unless $quiet;
 899                         }
 900                 }
 901         }
 902         close F;
 903
 904         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
 905                 open(F, "$cc_cmd $t |")
 906                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 907                 while(<F>) {
 908                         my $c = $_;
 909                         $c =~ s/^\s*//g;
 910                         $c =~ s/\n$//g;
 911                         next if ($c eq $sender and $suppress_from);
 912                         push @cc, $c;
 913                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 914                                 $c, $cc_cmd) unless $quiet;
 915                 }
 916                 close F
 917                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 918         }
 919
 920         if (defined $author) {
 921                 $message = "From: $author\n\n$message";
 922                 if (defined $author_encoding) {
 923                         if ($has_content_type) {
 924                                 if ($body_encoding eq $author_encoding) {
 925                                         # ok, we already have the right encoding
 926                                 }
 927                                 else {
 928                                         # uh oh, we should re-encode
 929                                 }
 930                         }
 931                         else {
 932                                 push @xh,
 933                                   'MIME-Version: 1.0',
 934                                   "Content-Type: text/plain; charset=$author_encoding",
 935                                   'Content-Transfer-Encoding: 8bit';
 936                         }
 937                 }
 938         }
 939
 940         send_message();
 941
 942         # set up for the next message
 943         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 944                 $reply_to = $message_id;
 945                 if (length $references > 0) {
 946                         $references .= "\n $message_id";
 947                 } else {
 948                         $references = "$message_id";
 949                 }
 950         }
 951         $message_id = undef;
 952 }
 953
 954 if ($compose) {
 955         cleanup_compose_files();
 956 }
 957
 958 sub cleanup_compose_files() {
 959         unlink($compose_filename, $compose_filename . ".final");
 960
 961 }
 962
 963 $smtp->quit if $smtp;
 964
 965 sub unique_email_list(@) {
 966         my %seen;
 967         my @emails;
 968
 969         foreach my $entry (@_) {
 970                 if (my $clean = extract_valid_address($entry)) {
 971                         $seen{$clean} ||= 0;
 972                         next if $seen{$clean}++;
 973                         push @emails, $entry;
 974                 } else {
 975                         print STDERR "W: unable to extract a valid address",
 976                                         " from: $entry\n";
 977                 }
 978         }
 979         return @emails;
 980 }
 981
 982 sub validate_patch {
 983         my $fn = shift;
 984         open(my $fh, '<', $fn)
 985                 or die "unable to open $fn: $!\n";
 986         while (my $line = <$fh>) {
 987                 if (length($line) > 998) {
 988                         return "$.: patch contains a line longer than 998 characters";
 989                 }
 990         }
 991         return undef;
 992 }
 993
 994 sub file_has_nonascii {
 995         my $fn = shift;
 996         open(my $fh, '<', $fn)
 997                 or die "unable to open $fn: $!\n";
 998         while (my $line = <$fh>) {
 999                 return 1 if $line =~ /[^[:ascii:]]/;
1000         }
1001         return 0;
1002 }