git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 $SIG{INT} = sub { print color("reset"), "\n"; exit };
  28
  29 package FakeTerm;
  30 sub new {
  31         my ($class, $reason) = @_;
  32         return bless \$reason, shift;
  33 }
  34 sub readline {
  35         my $self = shift;
  36         die "Cannot use readline on FakeTerm: $$self";
  37 }
  38 package main;
  39
  40
  41 sub usage {
  42         print <<EOT;
  43 git-send-email [options] <file | directory>...
  44 Options:
  45    --from         Specify the "From:" line of the email to be sent.
  46
  47    --to           Specify the primary "To:" line of the email.
  48
  49    --cc           Specify an initial "Cc:" list for the entire series
  50                   of emails.
  51
  52    --cc-cmd       Specify a command to execute per file which adds
  53                   per file specific cc address entries
  54
  55    --bcc          Specify a list of email addresses that should be Bcc:
  56                   on all the emails.
  57
  58    --compose      Use \$GIT_EDITOR, core.editor, \$EDITOR, or \$VISUAL to edit
  59                   an introductory message for the patch series.
  60
  61    --subject      Specify the initial "Subject:" line.
  62                   Only necessary if --compose is also set.  If --compose
  63                   is not set, this will be prompted for.
  64
  65    --in-reply-to  Specify the first "In-Reply-To:" header line.
  66                   Only used if --compose is also set.  If --compose is not
  67                   set, this will be prompted for.
  68
  69    --chain-reply-to If set, the replies will all be to the previous
  70                   email sent, rather than to the first email sent.
  71                   Defaults to on.
  72
  73    --signed-off-cc Automatically add email addresses that appear in
  74                  Signed-off-by: or Cc: lines to the cc: list. Defaults to on.
  75
  76    --identity     The configuration identity, a subsection to prioritise over
  77                   the default section.
  78
  79    --smtp-server  If set, specifies the outgoing SMTP server to use.
  80                   Defaults to localhost.
  81
  82    --smtp-user    The username for SMTP-AUTH.
  83
  84    --smtp-pass    The password for SMTP-AUTH.
  85
  86    --smtp-ssl     If set, connects to the SMTP server using SSL.
  87
  88    --suppress-from Suppress sending emails to yourself if your address
  89                   appears in a From: line. Defaults to off.
  90
  91    --thread       Specify that the "In-Reply-To:" header should be set on all
  92                   emails. Defaults to on.
  93
  94    --quiet        Make git-send-email less verbose.  One line per email
  95                   should be all that is output.
  96
  97    --dry-run      Do everything except actually send the emails.
  98
  99    --envelope-sender    Specify the envelope sender used to send the emails.
 100
 101 EOT
 102         exit(1);
 103 }
 104
 105 # most mail servers generate the Date: header, but not all...
 106 sub format_2822_time {
 107         my ($time) = @_;
 108         my @localtm = localtime($time);
 109         my @gmttm = gmtime($time);
 110         my $localmin = $localtm[1] + $localtm[2] * 60;
 111         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 112         if ($localtm[0] != $gmttm[0]) {
 113                 die "local zone differs from GMT by a non-minute interval\n";
 114         }
 115         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 116                 $localmin += 1440;
 117         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 118                 $localmin -= 1440;
 119         } elsif ($gmttm[6] != $localtm[6]) {
 120                 die "local time offset greater than or equal to 24 hours\n";
 121         }
 122         my $offset = $localmin - $gmtmin;
 123         my $offhour = $offset / 60;
 124         my $offmin = abs($offset % 60);
 125         if (abs($offhour) >= 24) {
 126                 die ("local time offset greater than or equal to 24 hours\n");
 127         }
 128
 129         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 130                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 131                        $localtm[3],
 132                        qw(Jan Feb Mar Apr May Jun
 133                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 134                        $localtm[5]+1900,
 135                        $localtm[2],
 136                        $localtm[1],
 137                        $localtm[0],
 138                        ($offset >= 0) ? '+' : '-',
 139                        abs($offhour),
 140                        $offmin,
 141                        );
 142 }
 143
 144 my $have_email_valid = eval { require Email::Valid; 1 };
 145 my $smtp;
 146
 147 sub unique_email_list(@);
 148 sub cleanup_compose_files();
 149
 150 # Constants (essentially)
 151 my $compose_filename = ".msg.$$";
 152
 153 # Variables we fill in automatically, or via prompting:
 154 my (@to,@cc,@initial_cc,@bcclist,@xh,
 155         $initial_reply_to,$initial_subject,@files,$author,$sender,$compose,$time);
 156
 157 my $envelope_sender;
 158
 159 # Example reply to:
 160 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 161
 162 my $repo = Git->repository();
 163 my $term = eval {
 164         new Term::ReadLine 'git-send-email';
 165 };
 166 if ($@) {
 167         $term = new FakeTerm "$@: going non-interactive";
 168 }
 169
 170 # Behavior modification variables
 171 my ($quiet, $dry_run) = (0, 0);
 172
 173 # Variables with corresponding config settings
 174 my ($thread, $chain_reply_to, $suppress_from, $signed_off_cc, $cc_cmd);
 175 my ($smtp_server, $smtp_authuser, $smtp_authpass, $smtp_ssl);
 176 my ($identity, $aliasfiletype, @alias_files);
 177
 178 my %config_bool_settings = (
 179     "thread" => [\$thread, 1],
 180     "chainreplyto" => [\$chain_reply_to, 1],
 181     "suppressfrom" => [\$suppress_from, 0],
 182     "signedoffcc" => [\$signed_off_cc, 1],
 183     "smtpssl" => [\$smtp_ssl, 0],
 184 );
 185
 186 my %config_settings = (
 187     "smtpserver" => \$smtp_server,
 188     "smtpuser" => \$smtp_authuser,
 189     "smtppass" => \$smtp_authpass,
 190     "cccmd" => \$cc_cmd,
 191     "aliasfiletype" => \$aliasfiletype,
 192     "bcc" => \@bcclist,
 193     "aliasesfile" => \@alias_files,
 194 );
 195
 196 # Begin by accumulating all the variables (defined above), that we will end up
 197 # needing, first, from the command line:
 198
 199 my $rc = GetOptions("sender|from=s" => \$sender,
 200                     "in-reply-to=s" => \$initial_reply_to,
 201                     "subject=s" => \$initial_subject,
 202                     "to=s" => \@to,
 203                     "cc=s" => \@initial_cc,
 204                     "bcc=s" => \@bcclist,
 205                     "chain-reply-to!" => \$chain_reply_to,
 206                     "smtp-server=s" => \$smtp_server,
 207                     "smtp-user=s" => \$smtp_authuser,
 208                     "smtp-pass=s" => \$smtp_authpass,
 209                     "smtp-ssl!" => \$smtp_ssl,
 210                     "identity=s" => \$identity,
 211                     "compose" => \$compose,
 212                     "quiet" => \$quiet,
 213                     "cc-cmd=s" => \$cc_cmd,
 214                     "suppress-from!" => \$suppress_from,
 215                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_cc,
 216                     "dry-run" => \$dry_run,
 217                     "envelope-sender=s" => \$envelope_sender,
 218                     "thread!" => \$thread,
 219          );
 220
 221 unless ($rc) {
 222     usage();
 223 }
 224
 225 # Now, let's fill any that aren't set in with defaults:
 226
 227 sub read_config {
 228         my ($prefix) = @_;
 229
 230         foreach my $setting (keys %config_bool_settings) {
 231                 my $target = $config_bool_settings{$setting}->[0];
 232                 $$target = $repo->config_bool("$prefix.$setting") unless (defined $$target);
 233         }
 234
 235         foreach my $setting (keys %config_settings) {
 236                 my $target = $config_settings{$setting};
 237                 if (ref($target) eq "ARRAY") {
 238                         unless (@$target) {
 239                                 my @values = $repo->config("$prefix.$setting");
 240                                 @$target = @values if (@values && defined $values[0]);
 241                         }
 242                 }
 243                 else {
 244                         $$target = $repo->config("$prefix.$setting") unless (defined $$target);
 245                 }
 246         }
 247 }
 248
 249 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 250 $identity = $repo->config("sendemail.identity") unless (defined $identity);
 251 read_config("sendemail.$identity") if (defined $identity);
 252 read_config("sendemail");
 253
 254 # fall back on builtin bool defaults
 255 foreach my $setting (values %config_bool_settings) {
 256         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 257 }
 258
 259 my ($repoauthor) = $repo->ident_person('author');
 260 my ($repocommitter) = $repo->ident_person('committer');
 261
 262 # Verify the user input
 263
 264 foreach my $entry (@to) {
 265         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 266 }
 267
 268 foreach my $entry (@initial_cc) {
 269         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 270 }
 271
 272 foreach my $entry (@bcclist) {
 273         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 274 }
 275
 276 my %aliases;
 277 my %parse_alias = (
 278         # multiline formats can be supported in the future
 279         mutt => sub { my $fh = shift; while (<$fh>) {
 280                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 281                         my ($alias, $addr) = ($1, $2);
 282                         $addr =~ s/#.*$//; # mutt allows # comments
 283                          # commas delimit multiple addresses
 284                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 285                 }}},
 286         mailrc => sub { my $fh = shift; while (<$fh>) {
 287                 if (/^alias\s+(\S+)\s+(.*)$/) {
 288                         # spaces delimit multiple addresses
 289                         $aliases{$1} = [ split(/\s+/, $2) ];
 290                 }}},
 291         pine => sub { my $fh = shift; while (<$fh>) {
 292                 if (/^(\S+)\t.*\t(.*)$/) {
 293                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 294                 }}},
 295         gnus => sub { my $fh = shift; while (<$fh>) {
 296                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 297                         $aliases{$1} = [ $2 ];
 298                 }}}
 299 );
 300
 301 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 302         foreach my $file (@alias_files) {
 303                 open my $fh, '<', $file or die "opening $file: $!\n";
 304                 $parse_alias{$aliasfiletype}->($fh);
 305                 close $fh;
 306         }
 307 }
 308
 309 ($sender) = expand_aliases($sender) if defined $sender;
 310
 311 my $prompting = 0;
 312 if (!defined $sender) {
 313         $sender = $repoauthor || $repocommitter;
 314         do {
 315                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 316         } while (!defined $_);
 317
 318         $sender = $_ if ($_);
 319         print "Emails will be sent from: ", $sender, "\n";
 320         $prompting++;
 321 }
 322
 323 if (!@to) {
 324         do {
 325                 $_ = $term->readline("Who should the emails be sent to? ",
 326                                 "");
 327         } while (!defined $_);
 328         my $to = $_;
 329         push @to, split /,/, $to;
 330         $prompting++;
 331 }
 332
 333 sub expand_aliases {
 334         my @cur = @_;
 335         my @last;
 336         do {
 337                 @last = @cur;
 338                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 339         } while (join(',',@cur) ne join(',',@last));
 340         return @cur;
 341 }
 342
 343 @to = expand_aliases(@to);
 344 @to = (map { sanitize_address($_) } @to);
 345 @initial_cc = expand_aliases(@initial_cc);
 346 @bcclist = expand_aliases(@bcclist);
 347
 348 if (!defined $initial_subject && $compose) {
 349         do {
 350                 $_ = $term->readline("What subject should the emails start with? ",
 351                         $initial_subject);
 352         } while (!defined $_);
 353         $initial_subject = $_;
 354         $prompting++;
 355 }
 356
 357 if ($thread && !defined $initial_reply_to && $prompting) {
 358         do {
 359                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ",
 360                         $initial_reply_to);
 361         } while (!defined $_);
 362
 363         $initial_reply_to = $_;
 364         $initial_reply_to =~ s/^\s+<?/</;
 365         $initial_reply_to =~ s/>?\s+$/>/;
 366 }
 367
 368 if (!defined $smtp_server) {
 369         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 370                 if (-x $_) {
 371                         $smtp_server = $_;
 372                         last;
 373                 }
 374         }
 375         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 376 }
 377
 378 if ($compose) {
 379         # Note that this does not need to be secure, but we will make a small
 380         # effort to have it be unique
 381         open(C,">",$compose_filename)
 382                 or die "Failed to open for writing $compose_filename: $!";
 383         print C "From $sender # This line is ignored.\n";
 384         printf C "Subject: %s\n\n", $initial_subject;
 385         printf C <<EOT;
 386 GIT: Please enter your email below.
 387 GIT: Lines beginning in "GIT: " will be removed.
 388 GIT: Consider including an overall diffstat or table of contents
 389 GIT: for the patch you are writing.
 390
 391 EOT
 392         close(C);
 393
 394         my $editor = $ENV{GIT_EDITOR} || $repo->config("core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 395         system($editor, $compose_filename);
 396
 397         open(C2,">",$compose_filename . ".final")
 398                 or die "Failed to open $compose_filename.final : " . $!;
 399
 400         open(C,"<",$compose_filename)
 401                 or die "Failed to open $compose_filename : " . $!;
 402
 403         while(<C>) {
 404                 next if m/^GIT: /;
 405                 print C2 $_;
 406         }
 407         close(C);
 408         close(C2);
 409
 410         do {
 411                 $_ = $term->readline("Send this email? (y|n) ");
 412         } while (!defined $_);
 413
 414         if (uc substr($_,0,1) ne 'Y') {
 415                 cleanup_compose_files();
 416                 exit(0);
 417         }
 418
 419         @files = ($compose_filename . ".final");
 420 }
 421
 422
 423 # Now that all the defaults are set, process the rest of the command line
 424 # arguments and collect up the files that need to be processed.
 425 for my $f (@ARGV) {
 426         if (-d $f) {
 427                 opendir(DH,$f)
 428                         or die "Failed to opendir $f: $!";
 429
 430                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 431                                 sort readdir(DH);
 432
 433         } elsif (-f $f) {
 434                 push @files, $f;
 435
 436         } else {
 437                 print STDERR "Skipping $f - not found.\n";
 438         }
 439 }
 440
 441 if (@files) {
 442         unless ($quiet) {
 443                 print $_,"\n" for (@files);
 444         }
 445 } else {
 446         print STDERR "\nNo patch files specified!\n\n";
 447         usage();
 448 }
 449
 450 # Variables we set as part of the loop over files
 451 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 452
 453 sub extract_valid_address {
 454         my $address = shift;
 455         my $local_part_regexp = '[^<>"\s@]+';
 456         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 457
 458         # check for a local address:
 459         return $address if ($address =~ /^($local_part_regexp)$/);
 460
 461         $address =~ s/^\s*<(.*)>\s*$/$1/;
 462         if ($have_email_valid) {
 463                 return scalar Email::Valid->address($address);
 464         } else {
 465                 # less robust/correct than the monster regexp in Email::Valid,
 466                 # but still does a 99% job, and one less dependency
 467                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 468                 return $1;
 469         }
 470 }
 471
 472 # Usually don't need to change anything below here.
 473
 474 # we make a "fake" message id by taking the current number
 475 # of seconds since the beginning of Unix time and tacking on
 476 # a random number to the end, in case we are called quicker than
 477 # 1 second since the last time we were called.
 478
 479 # We'll setup a template for the message id, using the "from" address:
 480
 481 sub make_message_id
 482 {
 483         my $date = time;
 484         my $pseudo_rand = int (rand(4200));
 485         my $du_part;
 486         for ($sender, $repocommitter, $repoauthor) {
 487                 $du_part = extract_valid_address(sanitize_address($_));
 488                 last if (defined $du_part and $du_part ne '');
 489         }
 490         if (not defined $du_part or $du_part eq '') {
 491                 use Sys::Hostname qw();
 492                 $du_part = 'user@' . Sys::Hostname::hostname();
 493         }
 494         my $message_id_template = "<%s-git-send-email-$du_part>";
 495         $message_id = sprintf $message_id_template, "$date$pseudo_rand";
 496         #print "new message id = $message_id\n"; # Was useful for debugging
 497 }
 498
 499
 500
 501 $time = time - scalar $#files;
 502
 503 sub unquote_rfc2047 {
 504         local ($_) = @_;
 505         if (s/=\?utf-8\?q\?(.*)\?=/$1/g) {
 506                 s/_/ /g;
 507                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 508         }
 509         return "$_";
 510 }
 511
 512 # use the simplest quoting being able to handle the recipient
 513 sub sanitize_address
 514 {
 515         my ($recipient) = @_;
 516         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 517
 518         if (not $recipient_name) {
 519                 return "$recipient";
 520         }
 521
 522         # if recipient_name is already quoted, do nothing
 523         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 524                 return $recipient;
 525         }
 526
 527         # rfc2047 is needed if a non-ascii char is included
 528         if ($recipient_name =~ /[^[:ascii:]]/) {
 529                 $recipient_name =~ s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 530                 $recipient_name =~ s/(.*)/=\?utf-8\?q\?$1\?=/;
 531         }
 532
 533         # double quotes are needed if specials or CTLs are included
 534         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 535                 $recipient_name =~ s/(["\\\r])/\\$1/;
 536                 $recipient_name = "\"$recipient_name\"";
 537         }
 538
 539         return "$recipient_name $recipient_addr";
 540
 541 }
 542
 543 sub send_message
 544 {
 545         my @recipients = unique_email_list(@to);
 546         @cc = (map { sanitize_address($_) } @cc);
 547         my $to = join (",\n\t", @recipients);
 548         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 549         @recipients = (map { extract_valid_address($_) } @recipients);
 550         my $date = format_2822_time($time++);
 551         my $gitversion = '@@GIT_VERSION@@';
 552         if ($gitversion =~ m/..GIT_VERSION../) {
 553             $gitversion = Git::version();
 554         }
 555
 556         my $cc = join(", ", unique_email_list(@cc));
 557         my $ccline = "";
 558         if ($cc ne '') {
 559                 $ccline = "\nCc: $cc";
 560         }
 561         my $sanitized_sender = sanitize_address($sender);
 562         make_message_id();
 563
 564         my $header = "From: $sanitized_sender
 565 To: $to${ccline}
 566 Subject: $subject
 567 Date: $date
 568 Message-Id: $message_id
 569 X-Mailer: git-send-email $gitversion
 570 ";
 571         if ($thread && $reply_to) {
 572
 573                 $header .= "In-Reply-To: $reply_to\n";
 574                 $header .= "References: $references\n";
 575         }
 576         if (@xh) {
 577                 $header .= join("\n", @xh) . "\n";
 578         }
 579
 580         my @sendmail_parameters = ('-i', @recipients);
 581         my $raw_from = $sanitized_sender;
 582         $raw_from = $envelope_sender if (defined $envelope_sender);
 583         $raw_from = extract_valid_address($raw_from);
 584         unshift (@sendmail_parameters,
 585                         '-f', $raw_from) if(defined $envelope_sender);
 586
 587         if ($dry_run) {
 588                 # We don't want to send the email.
 589         } elsif ($smtp_server =~ m#^/#) {
 590                 my $pid = open my $sm, '|-';
 591                 defined $pid or die $!;
 592                 if (!$pid) {
 593                         exec($smtp_server, @sendmail_parameters) or die $!;
 594                 }
 595                 print $sm "$header\n$message";
 596                 close $sm or die $?;
 597         } else {
 598                 if ($smtp_ssl) {
 599                         require Net::SMTP::SSL;
 600                         $smtp ||= Net::SMTP::SSL->new( $smtp_server, Port => 465 );
 601                 }
 602                 else {
 603                         require Net::SMTP;
 604                         $smtp ||= Net::SMTP->new( $smtp_server );
 605                 }
 606                 $smtp->auth( $smtp_authuser, $smtp_authpass )
 607                         or die $smtp->message if (defined $smtp_authuser);
 608                 $smtp->mail( $raw_from ) or die $smtp->message;
 609                 $smtp->to( @recipients ) or die $smtp->message;
 610                 $smtp->data or die $smtp->message;
 611                 $smtp->datasend("$header\n$message") or die $smtp->message;
 612                 $smtp->dataend() or die $smtp->message;
 613                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 614         }
 615         if ($quiet) {
 616                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 617         } else {
 618                 print (($dry_run ? "Dry-" : "")."OK. Log says:\nDate: $date\n");
 619                 if ($smtp_server !~ m#^/#) {
 620                         print "Server: $smtp_server\n";
 621                         print "MAIL FROM:<$raw_from>\n";
 622                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 623                 } else {
 624                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 625                 }
 626                 print "From: $sanitized_sender\nSubject: $subject\nCc: $cc\nTo: $to\n\n";
 627                 if ($smtp) {
 628                         print "Result: ", $smtp->code, ' ',
 629                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 630                 } else {
 631                         print "Result: OK\n";
 632                 }
 633         }
 634 }
 635
 636 $reply_to = $initial_reply_to;
 637 $references = $initial_reply_to || '';
 638 $subject = $initial_subject;
 639
 640 foreach my $t (@files) {
 641         open(F,"<",$t) or die "can't open file $t";
 642
 643         my $author = undef;
 644         @cc = @initial_cc;
 645         @xh = ();
 646         my $input_format = undef;
 647         my $header_done = 0;
 648         $message = "";
 649         while(<F>) {
 650                 if (!$header_done) {
 651                         if (/^From /) {
 652                                 $input_format = 'mbox';
 653                                 next;
 654                         }
 655                         chomp;
 656                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 657                                 $input_format = 'mbox';
 658                         }
 659
 660                         if (defined $input_format && $input_format eq 'mbox') {
 661                                 if (/^Subject:\s+(.*)$/) {
 662                                         $subject = $1;
 663
 664                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 665                                         if (unquote_rfc2047($2) eq $sender) {
 666                                                 next if ($suppress_from);
 667                                         }
 668                                         elsif ($1 eq 'From') {
 669                                                 $author = unquote_rfc2047($2);
 670                                         }
 671                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 672                                                 $2, $_) unless $quiet;
 673                                         push @cc, $2;
 674                                 }
 675                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 676                                         push @xh, $_;
 677                                 }
 678
 679                         } else {
 680                                 # In the traditional
 681                                 # "send lots of email" format,
 682                                 # line 1 = cc
 683                                 # line 2 = subject
 684                                 # So let's support that, too.
 685                                 $input_format = 'lots';
 686                                 if (@cc == 0) {
 687                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 688                                                 $_, $_) unless $quiet;
 689
 690                                         push @cc, $_;
 691
 692                                 } elsif (!defined $subject) {
 693                                         $subject = $_;
 694                                 }
 695                         }
 696
 697                         # A whitespace line will terminate the headers
 698                         if (m/^\s*$/) {
 699                                 $header_done = 1;
 700                         }
 701                 } else {
 702                         $message .=  $_;
 703                         if (/^(Signed-off-by|Cc): (.*)$/i && $signed_off_cc) {
 704                                 my $c = $2;
 705                                 chomp $c;
 706                                 push @cc, $c;
 707                                 printf("(sob) Adding cc: %s from line '%s'\n",
 708                                         $c, $_) unless $quiet;
 709                         }
 710                 }
 711         }
 712         close F;
 713
 714         if (defined $cc_cmd) {
 715                 open(F, "$cc_cmd $t |")
 716                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 717                 while(<F>) {
 718                         my $c = $_;
 719                         $c =~ s/^\s*//g;
 720                         $c =~ s/\n$//g;
 721                         push @cc, $c;
 722                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 723                                 $c, $cc_cmd) unless $quiet;
 724                 }
 725                 close F
 726                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 727         }
 728
 729         if (defined $author) {
 730                 $message = "From: $author\n\n$message";
 731         }
 732
 733         send_message();
 734
 735         # set up for the next message
 736         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 737                 $reply_to = $message_id;
 738                 if (length $references > 0) {
 739                         $references .= "\n $message_id";
 740                 } else {
 741                         $references = "$message_id";
 742                 }
 743         }
 744 }
 745
 746 if ($compose) {
 747         cleanup_compose_files();
 748 }
 749
 750 sub cleanup_compose_files() {
 751         unlink($compose_filename, $compose_filename . ".final");
 752
 753 }
 754
 755 $smtp->quit if $smtp;
 756
 757 sub unique_email_list(@) {
 758         my %seen;
 759         my @emails;
 760
 761         foreach my $entry (@_) {
 762                 if (my $clean = extract_valid_address($entry)) {
 763                         $seen{$clean} ||= 0;
 764                         next if $seen{$clean}++;
 765                         push @emails, $entry;
 766                 } else {
 767                         print STDERR "W: unable to extract a valid address",
 768                                         " from: $entry\n";
 769                 }
 770         }
 771         return @emails;
 772 }