git-difftool.perl

   1 #!/usr/bin/perl
   2 # Copyright (c) 2009, 2010 David Aguilar
   3 # Copyright (c) 2012 Tim Henigan
   4 #
   5 # This is a wrapper around the GIT_EXTERNAL_DIFF-compatible
   6 # git-difftool--helper script.
   7 #
   8 # This script exports GIT_EXTERNAL_DIFF and GIT_PAGER for use by git.
   9 # The GIT_DIFF* variables are exported for use by git-difftool--helper.
  10 #
  11 # Any arguments that are unknown to this script are forwarded to 'git diff'.
  12
  13 use 5.008;
  14 use strict;
  15 use warnings;
  16 use File::Basename qw(dirname);
  17 use File::Copy;
  18 use File::Compare;
  19 use File::Find;
  20 use File::stat;
  21 use File::Path qw(mkpath rmtree);
  22 use File::Temp qw(tempdir);
  23 use Getopt::Long qw(:config pass_through);
  24 use Git;
  25
  26 sub usage
  27 {
  28         my $exitcode = shift;
  29         print << 'USAGE';
  30 usage: git difftool [-t|--tool=<tool>] [--tool-help]
  31                     [-x|--extcmd=<cmd>]
  32                     [-g|--gui] [--no-gui]
  33                     [--prompt] [-y|--no-prompt]
  34                     [-d|--dir-diff]
  35                     ['git diff' options]
  36 USAGE
  37         exit($exitcode);
  38 }
  39
  40 sub find_worktree
  41 {
  42         my ($repo) = @_;
  43
  44         # Git->repository->wc_path() does not honor changes to the working
  45         # tree location made by $ENV{GIT_WORK_TREE} or the 'core.worktree'
  46         # config variable.
  47         my $worktree;
  48         my $env_worktree = $ENV{GIT_WORK_TREE};
  49         my $core_worktree = Git::config('core.worktree');
  50
  51         if (defined($env_worktree) and (length($env_worktree) > 0)) {
  52                 $worktree = $env_worktree;
  53         } elsif (defined($core_worktree) and (length($core_worktree) > 0)) {
  54                 $worktree = $core_worktree;
  55         } else {
  56                 $worktree = $repo->wc_path();
  57         }
  58
  59         return $worktree;
  60 }
  61
  62 sub filter_tool_scripts
  63 {
  64         my ($tools) = @_;
  65         if (-d $_) {
  66                 if ($_ ne ".") {
  67                         # Ignore files in subdirectories
  68                         $File::Find::prune = 1;
  69                 }
  70         } else {
  71                 if ((-f $_) && ($_ ne "defaults")) {
  72                         push(@$tools, $_);
  73                 }
  74         }
  75 }
  76
  77 sub print_tool_help
  78 {
  79         my ($cmd, @found, @notfound, @tools);
  80         my $gitpath = Git::exec_path();
  81
  82         find(sub { filter_tool_scripts(\@tools) }, "$gitpath/mergetools");
  83
  84         foreach my $tool (@tools) {
  85                 $cmd  = "TOOL_MODE=diff";
  86                 $cmd .= ' && . "$(git --exec-path)/git-mergetool--lib"';
  87                 $cmd .= " && get_merge_tool_path $tool >/dev/null 2>&1";
  88                 $cmd .= " && can_diff >/dev/null 2>&1";
  89                 if (system('sh', '-c', $cmd) == 0) {
  90                         push(@found, $tool);
  91                 } else {
  92                         push(@notfound, $tool);
  93                 }
  94         }
  95
  96         print << 'EOF';
  97 'git difftool --tool=<tool>' may be set to one of the following:
  98 EOF
  99         print "\t$_\n" for (sort(@found));
 100
 101         print << 'EOF';
 102
 103 The following tools are valid, but not currently available:
 104 EOF
 105         print "\t$_\n" for (sort(@notfound));
 106
 107         print << 'EOF';
 108
 109 NOTE: Some of the tools listed above only work in a windowed
 110 environment. If run in a terminal-only session, they will fail.
 111 EOF
 112         exit(0);
 113 }
 114
 115 sub exit_cleanup
 116 {
 117         my ($tmpdir, $status) = @_;
 118         my $errno = $!;
 119         rmtree($tmpdir);
 120         if ($status and $errno) {
 121                 my ($package, $file, $line) = caller();
 122                 warn "$file line $line: $errno\n";
 123         }
 124         exit($status | ($status >> 8));
 125 }
 126
 127 sub setup_dir_diff
 128 {
 129         my ($repo, $workdir, $symlinks) = @_;
 130
 131         # Run the diff; exit immediately if no diff found
 132         # 'Repository' and 'WorkingCopy' must be explicitly set to insure that
 133         # if $GIT_DIR and $GIT_WORK_TREE are set in ENV, they are actually used
 134         # by Git->repository->command*.
 135         my $repo_path = $repo->repo_path();
 136         my %repo_args = (Repository => $repo_path, WorkingCopy => $workdir);
 137         my $diffrepo = Git->repository(%repo_args);
 138
 139         my @gitargs = ('diff', '--raw', '--no-abbrev', '-z', @ARGV);
 140         my $diffrtn = $diffrepo->command_oneline(@gitargs);
 141         exit(0) unless defined($diffrtn);
 142
 143         # Build index info for left and right sides of the diff
 144         my $submodule_mode = '160000';
 145         my $symlink_mode = '120000';
 146         my $null_mode = '0' x 6;
 147         my $null_sha1 = '0' x 40;
 148         my $lindex = '';
 149         my $rindex = '';
 150         my %submodule;
 151         my %symlink;
 152         my @working_tree = ();
 153         my @rawdiff = split('\0', $diffrtn);
 154
 155         my $i = 0;
 156         while ($i < $#rawdiff) {
 157                 if ($rawdiff[$i] =~ /^::/) {
 158                         warn << 'EOF';
 159 Combined diff formats ('-c' and '--cc') are not supported in
 160 directory diff mode ('-d' and '--dir-diff').
 161 EOF
 162                         exit(1);
 163                 }
 164
 165                 my ($lmode, $rmode, $lsha1, $rsha1, $status) =
 166                         split(' ', substr($rawdiff[$i], 1));
 167                 my $src_path = $rawdiff[$i + 1];
 168                 my $dst_path;
 169
 170                 if ($status =~ /^[CR]/) {
 171                         $dst_path = $rawdiff[$i + 2];
 172                         $i += 3;
 173                 } else {
 174                         $dst_path = $src_path;
 175                         $i += 2;
 176                 }
 177
 178                 if ($lmode eq $submodule_mode or $rmode eq $submodule_mode) {
 179                         $submodule{$src_path}{left} = $lsha1;
 180                         if ($lsha1 ne $rsha1) {
 181                                 $submodule{$dst_path}{right} = $rsha1;
 182                         } else {
 183                                 $submodule{$dst_path}{right} = "$rsha1-dirty";
 184                         }
 185                         next;
 186                 }
 187
 188                 if ($lmode eq $symlink_mode) {
 189                         $symlink{$src_path}{left} =
 190                                 $diffrepo->command_oneline('show', "$lsha1");
 191                 }
 192
 193                 if ($rmode eq $symlink_mode) {
 194                         $symlink{$dst_path}{right} =
 195                                 $diffrepo->command_oneline('show', "$rsha1");
 196                 }
 197
 198                 if ($lmode ne $null_mode and $status !~ /^C/) {
 199                         $lindex .= "$lmode $lsha1\t$src_path\0";
 200                 }
 201
 202                 if ($rmode ne $null_mode) {
 203                         if ($rsha1 ne $null_sha1) {
 204                                 $rindex .= "$rmode $rsha1\t$dst_path\0";
 205                         } else {
 206                                 push(@working_tree, $dst_path);
 207                         }
 208                 }
 209         }
 210
 211         # Setup temp directories
 212         my $tmpdir = tempdir('git-difftool.XXXXX', CLEANUP => 0, TMPDIR => 1);
 213         my $ldir = "$tmpdir/left";
 214         my $rdir = "$tmpdir/right";
 215         mkpath($ldir) or exit_cleanup($tmpdir, 1);
 216         mkpath($rdir) or exit_cleanup($tmpdir, 1);
 217
 218         # If $GIT_DIR is not set prior to calling 'git update-index' and
 219         # 'git checkout-index', then those commands will fail if difftool
 220         # is called from a directory other than the repo root.
 221         my $must_unset_git_dir = 0;
 222         if (not defined($ENV{GIT_DIR})) {
 223                 $must_unset_git_dir = 1;
 224                 $ENV{GIT_DIR} = $repo_path;
 225         }
 226
 227         # Populate the left and right directories based on each index file
 228         my ($inpipe, $ctx);
 229         $ENV{GIT_INDEX_FILE} = "$tmpdir/lindex";
 230         ($inpipe, $ctx) =
 231                 $repo->command_input_pipe(qw(update-index -z --index-info));
 232         print($inpipe $lindex);
 233         $repo->command_close_pipe($inpipe, $ctx);
 234
 235         my $rc = system('git', 'checkout-index', '--all', "--prefix=$ldir/");
 236         exit_cleanup($tmpdir, $rc) if $rc != 0;
 237
 238         $ENV{GIT_INDEX_FILE} = "$tmpdir/rindex";
 239         ($inpipe, $ctx) =
 240                 $repo->command_input_pipe(qw(update-index -z --index-info));
 241         print($inpipe $rindex);
 242         $repo->command_close_pipe($inpipe, $ctx);
 243
 244         $rc = system('git', 'checkout-index', '--all', "--prefix=$rdir/");
 245         exit_cleanup($tmpdir, $rc) if $rc != 0;
 246
 247         # If $GIT_DIR was explicitly set just for the update/checkout
 248         # commands, then it should be unset before continuing.
 249         delete($ENV{GIT_DIR}) if ($must_unset_git_dir);
 250         delete($ENV{GIT_INDEX_FILE});
 251
 252         # Changes in the working tree need special treatment since they are
 253         # not part of the index
 254         for my $file (@working_tree) {
 255                 my $dir = dirname($file);
 256                 unless (-d "$rdir/$dir") {
 257                         mkpath("$rdir/$dir") or
 258                         exit_cleanup($tmpdir, 1);
 259                 }
 260                 if ($symlinks) {
 261                         symlink("$workdir/$file", "$rdir/$file") or
 262                         exit_cleanup($tmpdir, 1);
 263                 } else {
 264                         copy("$workdir/$file", "$rdir/$file") or
 265                         exit_cleanup($tmpdir, 1);
 266
 267                         my $mode = stat("$workdir/$file")->mode;
 268                         chmod($mode, "$rdir/$file") or
 269                         exit_cleanup($tmpdir, 1);
 270                 }
 271         }
 272
 273         # Changes to submodules require special treatment. This loop writes a
 274         # temporary file to both the left and right directories to show the
 275         # change in the recorded SHA1 for the submodule.
 276         for my $path (keys %submodule) {
 277                 my $ok;
 278                 if (defined($submodule{$path}{left})) {
 279                         $ok = write_to_file("$ldir/$path",
 280                                 "Subproject commit $submodule{$path}{left}");
 281                 }
 282                 if (defined($submodule{$path}{right})) {
 283                         $ok = write_to_file("$rdir/$path",
 284                                 "Subproject commit $submodule{$path}{right}");
 285                 }
 286                 exit_cleanup($tmpdir, 1) if not $ok;
 287         }
 288
 289         # Symbolic links require special treatment. The standard "git diff"
 290         # shows only the link itself, not the contents of the link target.
 291         # This loop replicates that behavior.
 292         for my $path (keys %symlink) {
 293                 my $ok;
 294                 if (defined($symlink{$path}{left})) {
 295                         $ok = write_to_file("$ldir/$path",
 296                                         $symlink{$path}{left});
 297                 }
 298                 if (defined($symlink{$path}{right})) {
 299                         $ok = write_to_file("$rdir/$path",
 300                                         $symlink{$path}{right});
 301                 }
 302                 exit_cleanup($tmpdir, 1) if not $ok;
 303         }
 304
 305         return ($ldir, $rdir, $tmpdir, @working_tree);
 306 }
 307
 308 sub write_to_file
 309 {
 310         my $path = shift;
 311         my $value = shift;
 312
 313         # Make sure the path to the file exists
 314         my $dir = dirname($path);
 315         unless (-d "$dir") {
 316                 mkpath("$dir") or return 0;
 317         }
 318
 319         # If the file already exists in that location, delete it.  This
 320         # is required in the case of symbolic links.
 321         unlink($path);
 322
 323         open(my $fh, '>', $path) or return 0;
 324         print($fh $value);
 325         close($fh);
 326
 327         return 1;
 328 }
 329
 330 sub main
 331 {
 332         # parse command-line options. all unrecognized options and arguments
 333         # are passed through to the 'git diff' command.
 334         my %opts = (
 335                 difftool_cmd => undef,
 336                 dirdiff => undef,
 337                 extcmd => undef,
 338                 gui => undef,
 339                 help => undef,
 340                 prompt => undef,
 341                 symlinks => $^O ne 'cygwin' &&
 342                                 $^O ne 'MSWin32' && $^O ne 'msys',
 343                 tool_help => undef,
 344         );
 345         GetOptions('g|gui!' => \$opts{gui},
 346                 'd|dir-diff' => \$opts{dirdiff},
 347                 'h' => \$opts{help},
 348                 'prompt!' => \$opts{prompt},
 349                 'y' => sub { $opts{prompt} = 0; },
 350                 'symlinks' => \$opts{symlinks},
 351                 'no-symlinks' => sub { $opts{symlinks} = 0; },
 352                 't|tool:s' => \$opts{difftool_cmd},
 353                 'tool-help' => \$opts{tool_help},
 354                 'x|extcmd:s' => \$opts{extcmd});
 355
 356         if (defined($opts{help})) {
 357                 usage(0);
 358         }
 359         if (defined($opts{tool_help})) {
 360                 print_tool_help();
 361         }
 362         if (defined($opts{difftool_cmd})) {
 363                 if (length($opts{difftool_cmd}) > 0) {
 364                         $ENV{GIT_DIFF_TOOL} = $opts{difftool_cmd};
 365                 } else {
 366                         print "No <tool> given for --tool=<tool>\n";
 367                         usage(1);
 368                 }
 369         }
 370         if (defined($opts{extcmd})) {
 371                 if (length($opts{extcmd}) > 0) {
 372                         $ENV{GIT_DIFFTOOL_EXTCMD} = $opts{extcmd};
 373                 } else {
 374                         print "No <cmd> given for --extcmd=<cmd>\n";
 375                         usage(1);
 376                 }
 377         }
 378         if ($opts{gui}) {
 379                 my $guitool = Git::config('diff.guitool');
 380                 if (length($guitool) > 0) {
 381                         $ENV{GIT_DIFF_TOOL} = $guitool;
 382                 }
 383         }
 384
 385         # In directory diff mode, 'git-difftool--helper' is called once
 386         # to compare the a/b directories.  In file diff mode, 'git diff'
 387         # will invoke a separate instance of 'git-difftool--helper' for
 388         # each file that changed.
 389         if (defined($opts{dirdiff})) {
 390                 dir_diff($opts{extcmd}, $opts{symlinks});
 391         } else {
 392                 file_diff($opts{prompt});
 393         }
 394 }
 395
 396 sub dir_diff
 397 {
 398         my ($extcmd, $symlinks) = @_;
 399         my $rc;
 400         my $error = 0;
 401         my $repo = Git->repository();
 402         my $workdir = find_worktree($repo);
 403         my ($a, $b, $tmpdir, @worktree) =
 404                 setup_dir_diff($repo, $workdir, $symlinks);
 405
 406         if (defined($extcmd)) {
 407                 $rc = system($extcmd, $a, $b);
 408         } else {
 409                 $ENV{GIT_DIFFTOOL_DIRDIFF} = 'true';
 410                 $rc = system('git', 'difftool--helper', $a, $b);
 411         }
 412         # If the diff including working copy files and those
 413         # files were modified during the diff, then the changes
 414         # should be copied back to the working tree.
 415         # Do not copy back files when symlinks are used and the
 416         # external tool did not replace the original link with a file.
 417         for my $file (@worktree) {
 418                 next if $symlinks && -l "$b/$file";
 419                 next if ! -f "$b/$file";
 420
 421                 my $diff = compare("$b/$file", "$workdir/$file");
 422                 if ($diff == 0) {
 423                         next;
 424                 } elsif ($diff == -1) {
 425                         my $errmsg = "warning: Could not compare ";
 426                         $errmsg += "'$b/$file' with '$workdir/$file'\n";
 427                         warn $errmsg;
 428                         $error = 1;
 429                 } elsif ($diff == 1) {
 430                         my $mode = stat("$b/$file")->mode;
 431                         copy("$b/$file", "$workdir/$file") or
 432                         exit_cleanup($tmpdir, 1);
 433
 434                         chmod($mode, "$workdir/$file") or
 435                         exit_cleanup($tmpdir, 1);
 436                 }
 437         }
 438         if ($error) {
 439                 warn "warning: Temporary files exist in '$tmpdir'.\n";
 440                 warn "warning: You may want to cleanup or recover these.\n";
 441                 exit(1);
 442         } else {
 443                 exit_cleanup($tmpdir, $rc);
 444         }
 445 }
 446
 447 sub file_diff
 448 {
 449         my ($prompt) = @_;
 450
 451         if (defined($prompt)) {
 452                 if ($prompt) {
 453                         $ENV{GIT_DIFFTOOL_PROMPT} = 'true';
 454                 } else {
 455                         $ENV{GIT_DIFFTOOL_NO_PROMPT} = 'true';
 456                 }
 457         }
 458
 459         $ENV{GIT_PAGER} = '';
 460         $ENV{GIT_EXTERNAL_DIFF} = 'git-difftool--helper';
 461
 462         # ActiveState Perl for Win32 does not implement POSIX semantics of
 463         # exec* system call. It just spawns the given executable and finishes
 464         # the starting program, exiting with code 0.
 465         # system will at least catch the errors returned by git diff,
 466         # allowing the caller of git difftool better handling of failures.
 467         my $rc = system('git', 'diff', @ARGV);
 468         exit($rc | ($rc >> 8));
 469 }
 470
 471 main();